qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ent_cs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "spawnpoints.qh"
  13 #include "g_damage.qh"
  14 #include "g_hook.qh"
  15 #include "command/common.qh"
  16 #include "cheats.qh"
  17 #include "g_world.qh"
  18 #include "race.qh"
  19 #include "antilag.qh"
  20 #include "campaign.qh"
  21 #include "command/common.qh"
  22
  23 #include "bot/bot.qh"
  24 #include "bot/navigation.qh"
  25
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/triggers/teleporters.qh"
  28
  29 #include "weapons/hitplot.qh"
  30 #include "weapons/weaponsystem.qh"
  31
  32 #include "../common/net_notice.qh"
  33 #include "../common/physics.qh"
  34
  35 #include "../common/items/all.qc"
  36
  37 #include "../common/mutators/mutator/waypoints/all.qh"
  38
  39 #include "../common/triggers/subs.qh"
  40 #include "../common/triggers/triggers.qh"
  41 #include "../common/triggers/trigger/secret.qh"
  42
  43 #include "../common/minigames/sv_minigames.qh"
  44
  45 #include "../common/items/inventory.qh"
  46
  47 #include "../common/monsters/sv_monsters.qh"
  48
  49 #include "../lib/warpzone/server.qh"
  50
  51
  52 void send_CSQC_teamnagger() {
  53         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  54 }
  55
  56 bool ClientData_Send(entity this, entity to, int sf)
  57 {
  58         if(to != self.owner)
  59         {
  60                 error("wtf");
  61                 return false;
  62         }
  63
  64         entity e;
  65
  66         e = to;
  67         if(IS_SPEC(to))
  68                 e = to.enemy;
  69
  70         sf = 0;
  71
  72         if(e.race_completed)
  73                 sf |= 1; // forced scoreboard
  74         if(to.spectatee_status)
  75                 sf |= 2; // spectator ent number follows
  76         if(e.zoomstate)
  77                 sf |= 4; // zoomed
  78         if(e.porto_v_angle_held)
  79                 sf |= 8; // angles held
  80
  81         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  82         WriteByte(MSG_ENTITY, sf);
  83
  84         if(sf & 2)
  85                 WriteByte(MSG_ENTITY, to.spectatee_status);
  86
  87         if(sf & 8)
  88         {
  89                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  90                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  91         }
  92
  93         return true;
  94 }
  95
  96 void ClientData_Attach()
  97 {SELFPARAM();
  98         Net_LinkEntity(this.clientdata = new(clientdata), false, 0, ClientData_Send);
  99         make_pure(this.clientdata);
 100         self.clientdata.drawonlytoclient = this;
 101         self.clientdata.owner = this;
 102 }
 103
 104 void ClientData_Detach()
 105 {SELFPARAM();
 106         remove(self.clientdata);
 107         self.clientdata = world;
 108 }
 109
 110 void ClientData_Touch(entity e)
 111 {
 112         e.clientdata.SendFlags = 1;
 113
 114         // make it spectatable
 115         entity e2;
 116         FOR_EACH_REALCLIENT(e2)
 117         {
 118                 if(e2 != e)
 119                         if(IS_SPEC(e2))
 120                                 if(e2.enemy == e)
 121                                         e2.clientdata.SendFlags = 1;
 122         }
 123 }
 124
 125 .string netname_previous;
 126
 127 void SetSpectatee(entity player, entity spectatee);
 128
 129
 130 /*
 131 =============
 132 CheckPlayerModel
 133
 134 Checks if the argument string can be a valid playermodel.
 135 Returns a valid one in doubt.
 136 =============
 137 */
 138 string FallbackPlayerModel;
 139 string CheckPlayerModel(string plyermodel) {
 140         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 141         {
 142                 // note: we cannot summon Don Strunzone here, some player may
 143                 // still have the model string set. In case anyone manages how
 144                 // to change a cvar default, we'll have a small leak here.
 145                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 146         }
 147         // only in right path
 148         if( substring(plyermodel,0,14) != "models/player/")
 149                 return FallbackPlayerModel;
 150         // only good file extensions
 151         if(substring(plyermodel,-4,4) != ".zym")
 152         if(substring(plyermodel,-4,4) != ".dpm")
 153         if(substring(plyermodel,-4,4) != ".iqm")
 154         if(substring(plyermodel,-4,4) != ".md3")
 155         if(substring(plyermodel,-4,4) != ".psk")
 156                 return FallbackPlayerModel;
 157         // forbid the LOD models
 158         if(substring(plyermodel, -9,5) == "_lod1")
 159                 return FallbackPlayerModel;
 160         if(substring(plyermodel, -9,5) == "_lod2")
 161                 return FallbackPlayerModel;
 162         if(plyermodel != strtolower(plyermodel))
 163                 return FallbackPlayerModel;
 164         // also, restrict to server models
 165         if(autocvar_sv_servermodelsonly)
 166         {
 167                 if(!fexists(plyermodel))
 168                         return FallbackPlayerModel;
 169         }
 170         return plyermodel;
 171 }
 172
 173 void setplayermodel(entity e, string modelname)
 174 {
 175         precache_model(modelname);
 176         _setmodel(e, modelname);
 177         player_setupanimsformodel();
 178         UpdatePlayerSounds();
 179 }
 180
 181 /*
 182 =============
 183 PutObserverInServer
 184
 185 putting a client as observer in the server
 186 =============
 187 */
 188 void FixPlayermodel(entity player);
 189 void PutObserverInServer()
 190 {SELFPARAM();
 191         entity  spot;
 192     self.hud = HUD_NORMAL;
 193
 194         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
 195
 196         spot = SelectSpawnPoint (true);
 197         if(!spot)
 198                 error("No spawnpoints for observers?!?\n");
 199         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 200
 201         if(IS_REAL_CLIENT(self))
 202         {
 203                 msg_entity = self;
 204                 WriteByte(MSG_ONE, SVC_SETVIEW);
 205                 WriteEntity(MSG_ONE, self);
 206         }
 207
 208         self.frags = FRAGS_SPECTATOR;
 209         self.bot_attack = false;
 210
 211         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver);
 212
 213         Portal_ClearAll(self);
 214
 215         Unfreeze(self);
 216
 217         if(self.alivetime)
 218         {
 219                 if(!warmup_stage)
 220                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 221                 self.alivetime = 0;
 222         }
 223
 224         if(self.vehicle)
 225                 vehicles_exit(VHEF_RELEASE);
 226
 227         WaypointSprite_PlayerDead();
 228
 229         if(!mutator_returnvalue)  // mutator prevents resetting teams
 230                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 231
 232         if(self.killcount != FRAGS_SPECTATOR)
 233         {
 234                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 235                 if(!intermission_running)
 236                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 237                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 238
 239                 if(self.just_joined == false) {
 240                         LogTeamchange(self.playerid, -1, 4);
 241                 } else
 242                         self.just_joined = false;
 243         }
 244
 245         PlayerScore_Clear(self); // clear scores when needed
 246
 247         accuracy_resend(self);
 248
 249         self.spectatortime = time;
 250
 251         self.classname = STR_OBSERVER;
 252         self.iscreature = false;
 253         self.teleportable = TELEPORT_SIMPLE;
 254         self.damagedbycontents = false;
 255         self.health = FRAGS_SPECTATOR;
 256         self.takedamage = DAMAGE_NO;
 257         self.solid = SOLID_NOT;
 258         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 259         self.flags = FL_CLIENT | FL_NOTARGET;
 260         self.armorvalue = 666;
 261         self.effects = 0;
 262         self.armorvalue = autocvar_g_balance_armor_start;
 263         self.pauserotarmor_finished = 0;
 264         self.pauserothealth_finished = 0;
 265         self.pauseregen_finished = 0;
 266         self.damageforcescale = 0;
 267         self.death_time = 0;
 268         self.respawn_flags = 0;
 269         self.respawn_time = 0;
 270         self.stat_respawn_time = 0;
 271         self.alpha = 0;
 272         self.scale = 0;
 273         self.fade_time = 0;
 274         self.pain_frame = 0;
 275         self.pain_finished = 0;
 276         self.strength_finished = 0;
 277         self.invincible_finished = 0;
 278         self.superweapons_finished = 0;
 279         self.pushltime = 0;
 280         self.istypefrag = 0;
 281         self.think = func_null;
 282         self.nextthink = 0;
 283         self.hook_time = 0;
 284         self.deadflag = DEAD_NO;
 285         self.angles = spot.angles;
 286         self.angles_z = 0;
 287         self.fixangle = true;
 288         self.crouch = false;
 289         self.revival_time = 0;
 290
 291         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 292         self.prevorigin = self.origin;
 293         self.items = 0;
 294         self.weapons = '0 0 0';
 295         self.model = "";
 296         FixPlayermodel(self);
 297         setmodel(self, MDL_Null);
 298         self.drawonlytoclient = self;
 299
 300         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 301         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 302
 303         self.weapon = 0;
 304         self.weaponname = "";
 305         self.switchingweapon = 0;
 306         self.weaponmodel = "";
 307         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 308         {
 309                 self.weaponentities[slot] = NULL;
 310         }
 311         self.exteriorweaponentity = world;
 312         self.killcount = FRAGS_SPECTATOR;
 313         self.velocity = '0 0 0';
 314         self.avelocity = '0 0 0';
 315         self.punchangle = '0 0 0';
 316         self.punchvector = '0 0 0';
 317         self.oldvelocity = self.velocity;
 318         self.fire_endtime = -1;
 319         self.event_damage = func_null;
 320 }
 321
 322 .float model_randomizer;
 323 void FixPlayermodel(entity player)
 324 {
 325         string defaultmodel = "";
 326         int defaultskin = 0;
 327         if(autocvar_sv_defaultcharacter)
 328         {
 329                 if(teamplay)
 330                 {
 331                         string s = Static_Team_ColorName_Lower(player.team);
 332                         if (s != "neutral")
 333                         {
 334                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 335                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 336                         }
 337                 }
 338
 339                 if(defaultmodel == "")
 340                 {
 341                         defaultmodel = autocvar_sv_defaultplayermodel;
 342                         defaultskin = autocvar_sv_defaultplayerskin;
 343                 }
 344
 345                 int n = tokenize_console(defaultmodel);
 346                 if(n > 0)
 347                 {
 348                         defaultmodel = argv(floor(n * player.model_randomizer));
 349                         // However, do NOT randomize if the player-selected model is in the list.
 350                         for (int i = 0; i < n; ++i)
 351                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 352                                         defaultmodel = argv(i);
 353                 }
 354
 355                 int i = strstrofs(defaultmodel, ":", 0);
 356                 if(i >= 0)
 357                 {
 358                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 359                         defaultmodel = substring(defaultmodel, 0, i);
 360                 }
 361         }
 362         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin);
 363         defaultmodel = ret_string;
 364         defaultskin = ret_int;
 365
 366         bool chmdl = false;
 367         int oldskin;
 368         if(defaultmodel != "")
 369         {
 370                 if (defaultmodel != player.model)
 371                 {
 372                         vector m1 = player.mins;
 373                         vector m2 = player.maxs;
 374                         setplayermodel (player, defaultmodel);
 375                         setsize (player, m1, m2);
 376                         chmdl = true;
 377                 }
 378
 379                 oldskin = player.skin;
 380                 player.skin = defaultskin;
 381         } else {
 382                 if (player.playermodel != player.model || player.playermodel == "")
 383                 {
 384                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 385                         vector m1 = player.mins;
 386                         vector m2 = player.maxs;
 387                         setplayermodel (player, player.playermodel);
 388                         setsize (player, m1, m2);
 389                         chmdl = true;
 390                 }
 391
 392                 oldskin = player.skin;
 393                 player.skin = stof(player.playerskin);
 394         }
 395
 396         if(chmdl || oldskin != player.skin) // model or skin has changed
 397         {
 398                 player.species = player_getspecies(); // update species
 399                 UpdatePlayerSounds(); // update skin sounds
 400         }
 401
 402         if(!teamplay)
 403                 if(strlen(autocvar_sv_defaultplayercolors))
 404                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 405                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 406 }
 407
 408
 409 /** Called when a client spawns in the server */
 410 void PutClientInServer()
 411 {
 412         SELFPARAM();
 413         if (IS_BOT_CLIENT(this)) {
 414                 this.classname = STR_PLAYER;
 415         } else if (IS_REAL_CLIENT(this)) {
 416                 msg_entity = this;
 417                 WriteByte(MSG_ONE, SVC_SETVIEW);
 418                 WriteEntity(MSG_ONE, this);
 419         }
 420         if (gameover) {
 421                 this.classname = STR_OBSERVER;
 422         }
 423
 424         SetSpectatee(this, NULL);
 425
 426         // reset player keys
 427         this.itemkeys = 0;
 428
 429         MUTATOR_CALLHOOK(PutClientInServer, this);
 430
 431         if (IS_OBSERVER(this)) {
 432                 PutObserverInServer();
 433         } else if (IS_PLAYER(this)) {
 434                 accuracy_resend(this);
 435
 436                 if (this.team < 0)
 437                         JoinBestTeam(this, false, true);
 438
 439                 entity spot = SelectSpawnPoint(false);
 440                 if (!spot) {
 441                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 442                         return; // spawn failed
 443                 }
 444
 445                 this.classname = STR_PLAYER;
 446                 this.wasplayer = true;
 447                 this.iscreature = true;
 448                 this.teleportable = TELEPORT_NORMAL;
 449                 this.damagedbycontents = true;
 450                 this.movetype = MOVETYPE_WALK;
 451                 this.solid = SOLID_SLIDEBOX;
 452                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 453                 if (autocvar_g_playerclip_collisions)
 454                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 455                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 456                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 457                 this.frags = FRAGS_PLAYER;
 458                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 459                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 460                 if (autocvar__notarget)
 461                         this.flags |= FL_NOTARGET;
 462                 this.takedamage = DAMAGE_AIM;
 463                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 464                 this.dmg = 2; // WTF
 465
 466                 if (warmup_stage) {
 467                         this.ammo_shells = warmup_start_ammo_shells;
 468                         this.ammo_nails = warmup_start_ammo_nails;
 469                         this.ammo_rockets = warmup_start_ammo_rockets;
 470                         this.ammo_cells = warmup_start_ammo_cells;
 471                         this.ammo_plasma = warmup_start_ammo_plasma;
 472                         this.ammo_fuel = warmup_start_ammo_fuel;
 473                         this.health = warmup_start_health;
 474                         this.armorvalue = warmup_start_armorvalue;
 475                         this.weapons = WARMUP_START_WEAPONS;
 476                 } else {
 477                         this.ammo_shells = start_ammo_shells;
 478                         this.ammo_nails = start_ammo_nails;
 479                         this.ammo_rockets = start_ammo_rockets;
 480                         this.ammo_cells = start_ammo_cells;
 481                         this.ammo_plasma = start_ammo_plasma;
 482                         this.ammo_fuel = start_ammo_fuel;
 483                         this.health = start_health;
 484                         this.armorvalue = start_armorvalue;
 485                         this.weapons = start_weapons;
 486                 }
 487
 488                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 489
 490                 this.items = start_items;
 491
 492                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 493                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 494                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 495                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 496                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 497                 // extend the pause of rotting if client was reset at the beginning of the countdown
 498                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 499                         float f = game_starttime - time;
 500                         this.spawnshieldtime += f;
 501                         this.pauserotarmor_finished += f;
 502                         this.pauserothealth_finished += f;
 503                         this.pauseregen_finished += f;
 504                 }
 505                 this.damageforcescale = 2;
 506                 this.death_time = 0;
 507                 this.respawn_flags = 0;
 508                 this.respawn_time = 0;
 509                 this.stat_respawn_time = 0;
 510                 this.scale = autocvar_sv_player_scale;
 511                 this.fade_time = 0;
 512                 this.pain_frame = 0;
 513                 this.pain_finished = 0;
 514                 this.pushltime = 0;
 515                 this.think = func_null; // players have no think function
 516                 this.nextthink = 0;
 517                 this.dmg_team = 0;
 518                 this.ballistics_density = autocvar_g_ballistics_density_player;
 519
 520                 this.deadflag = DEAD_NO;
 521
 522                 this.angles = spot.angles;
 523                 this.angles_z = 0; // never spawn tilted even if the spot says to
 524                 if (IS_BOT_CLIENT(this))
 525                         this.v_angle = this.angles;
 526                 this.fixangle = true; // turn this way immediately
 527                 this.oldvelocity = this.velocity = '0 0 0';
 528                 this.avelocity = '0 0 0';
 529                 this.punchangle = '0 0 0';
 530                 this.punchvector = '0 0 0';
 531
 532                 this.strength_finished = 0;
 533                 this.invincible_finished = 0;
 534                 this.fire_endtime = -1;
 535                 this.revival_time = 0;
 536                 this.air_finished = time + 12;
 537
 538                 entity spawnevent = new(spawnevent);
 539                 make_pure(spawnevent);
 540                 spawnevent.owner = this;
 541                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 542
 543                 // Cut off any still running player sounds.
 544                 stopsound(this, CH_PLAYER_SINGLE);
 545
 546                 this.model = "";
 547                 FixPlayermodel(this);
 548                 this.drawonlytoclient = NULL;
 549
 550                 this.crouch = false;
 551                 this.view_ofs = PL_VIEW_OFS;
 552                 setsize(this, PL_MIN, PL_MAX);
 553                 this.spawnorigin = spot.origin;
 554                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 555                 // don't reset back to last position, even if new position is stuck in solid
 556                 this.oldorigin = this.origin;
 557                 this.prevorigin = this.origin;
 558                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 559         this.hud = HUD_NORMAL;
 560
 561                 this.event_damage = PlayerDamage;
 562
 563                 this.bot_attack = true;
 564                 this.monster_attack = true;
 565
 566                 this.spider_slowness = 0;
 567
 568                 this.BUTTON_ATCK = this.BUTTON_JUMP = this.BUTTON_ATCK2 = false;
 569
 570                 if (this.killcount == FRAGS_SPECTATOR) {
 571                         PlayerScore_Clear(this);
 572                         this.killcount = 0;
 573                 }
 574
 575                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 576                 {
 577                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 578                 }
 579                 this.alpha = default_player_alpha;
 580                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 581                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 582
 583                 this.speedrunning = false;
 584
 585                 target_voicescript_clear(this);
 586
 587                 // reset fields the weapons may use
 588                 FOREACH(Weapons, true, LAMBDA(
 589                         it.wr_resetplayer(it);
 590                         // reload all reloadable weapons
 591                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 592                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 593                         }
 594                 ));
 595
 596                 {
 597                         string s = spot.target;
 598                         spot.target = string_null;
 599                         WITH(entity, activator, this, LAMBDA(
 600                                 WITH(entity, self, spot, SUB_UseTargets())
 601                         ));
 602                         spot.target = s;
 603                 }
 604
 605                 Unfreeze(this);
 606
 607                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 608
 609                 if (autocvar_spawn_debug)
 610                 {
 611                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 612                         remove(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 613                 }
 614
 615                 this.switchweapon = w_getbestweapon(this);
 616                 this.cnt = -1; // W_LastWeapon will not complain
 617                 this.weapon = 0;
 618                 this.weaponname = "";
 619                 this.switchingweapon = 0;
 620
 621                 if (!warmup_stage && !this.alivetime)
 622                         this.alivetime = time;
 623
 624                 antilag_clear(this);
 625         }
 626 }
 627
 628 .float ebouncefactor, ebouncestop; // electro's values
 629 // TODO do we need all these fields, or should we stop autodetecting runtime
 630 // changes and just have a console command to update this?
 631 bool ClientInit_SendEntity(entity this, entity to, int sf)
 632 {
 633         WriteHeader(MSG_ENTITY, ENT_CLIENT_INIT);
 634         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 638         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 639         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 640         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 641         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 642         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 643
 644         if(sv_foginterval && world.fog != "")
 645                 WriteString(MSG_ENTITY, world.fog);
 646         else
 647                 WriteString(MSG_ENTITY, "");
 648         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 649         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 650         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 651         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 652         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 653         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 654         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 655         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 656         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 657         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 658         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 659         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 660
 661         MUTATOR_CALLHOOK(Ent_Init);
 662         return true;
 663 }
 664
 665 void ClientInit_CheckUpdate()
 666 {SELFPARAM();
 667         self.nextthink = time;
 668         if(self.count != autocvar_g_balance_armor_blockpercent)
 669         {
 670                 self.count = autocvar_g_balance_armor_blockpercent;
 671                 self.SendFlags |= 1;
 672         }
 673         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 674         {
 675                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 676                 self.SendFlags |= 1;
 677         }
 678         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 679         {
 680                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 681                 self.SendFlags |= 1;
 682         }
 683         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 684         {
 685                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 686                 self.SendFlags |= 1;
 687         }
 688         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 689         {
 690                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 691                 self.SendFlags |= 1;
 692         }
 693 }
 694
 695 void ClientInit_Spawn()
 696 {SELFPARAM();
 697
 698         entity e = new(clientinit);
 699         make_pure(e);
 700         e.think = ClientInit_CheckUpdate;
 701         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 702
 703         WITH(entity, self, e, ClientInit_CheckUpdate());
 704 }
 705
 706 /*
 707 =============
 708 SetNewParms
 709 =============
 710 */
 711 void SetNewParms ()
 712 {
 713         // initialize parms for a new player
 714         parm1 = -(86400 * 366);
 715
 716         MUTATOR_CALLHOOK(SetNewParms);
 717 }
 718
 719 /*
 720 =============
 721 SetChangeParms
 722 =============
 723 */
 724 void SetChangeParms ()
 725 {SELFPARAM();
 726         // save parms for level change
 727         parm1 = self.parm_idlesince - time;
 728
 729         MUTATOR_CALLHOOK(SetChangeParms);
 730 }
 731
 732 /*
 733 =============
 734 DecodeLevelParms
 735 =============
 736 */
 737 void DecodeLevelParms ()
 738 {SELFPARAM();
 739         // load parms
 740         self.parm_idlesince = parm1;
 741         if(self.parm_idlesince == -(86400 * 366))
 742                 self.parm_idlesince = time;
 743
 744         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 745         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 746
 747         MUTATOR_CALLHOOK(DecodeLevelParms);
 748 }
 749
 750 /*
 751 =============
 752 ClientKill
 753
 754 Called when a client types 'kill' in the console
 755 =============
 756 */
 757
 758 .float clientkill_nexttime;
 759 void ClientKill_Now_TeamChange()
 760 {SELFPARAM();
 761         if(self.killindicator_teamchange == -1)
 762         {
 763                 JoinBestTeam( self, false, true );
 764         }
 765         else if(self.killindicator_teamchange == -2)
 766         {
 767                 if(blockSpectators)
 768                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 769                 PutObserverInServer();
 770         }
 771         else
 772                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 773         self.killindicator_teamchange = 0;
 774 }
 775
 776 void ClientKill_Now()
 777 {SELFPARAM();
 778         if(self.vehicle)
 779         {
 780             vehicles_exit(VHEF_RELEASE);
 781             if(!self.killindicator_teamchange)
 782             {
 783             self.vehicle_health = -1;
 784             Damage(self, self, self, 1 , DEATH_KILL.m_id, self.origin, '0 0 0');
 785             }
 786         }
 787
 788         if(self.killindicator && !wasfreed(self.killindicator))
 789                 remove(self.killindicator);
 790
 791         self.killindicator = world;
 792
 793         if(self.killindicator_teamchange)
 794                 ClientKill_Now_TeamChange();
 795
 796         if(IS_PLAYER(self))
 797                 Damage(self, self, self, 100000, DEATH_KILL.m_id, self.origin, '0 0 0');
 798
 799         // now I am sure the player IS dead
 800 }
 801 void KillIndicator_Think()
 802 {SELFPARAM();
 803         if (gameover)
 804         {
 805                 self.owner.killindicator = world;
 806                 remove(self);
 807                 return;
 808         }
 809
 810         if (self.owner.alpha < 0 && !self.owner.vehicle)
 811         {
 812                 self.owner.killindicator = world;
 813                 remove(self);
 814                 return;
 815         }
 816
 817         if(self.cnt <= 0)
 818         {
 819                 WITH(entity, self, self.owner, ClientKill_Now());
 820                 return;
 821         }
 822     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 823     {
 824         self.nextthink = time + 1;
 825         self.cnt -= 1;
 826     }
 827         else
 828         {
 829                 if(self.cnt <= 10)
 830                         setmodel(self, MDL_NUM(self.cnt));
 831                 if(IS_REAL_CLIENT(self.owner))
 832                 {
 833                         if(self.cnt <= 10)
 834                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 835                 }
 836                 self.nextthink = time + 1;
 837                 self.cnt -= 1;
 838         }
 839 }
 840
 841 float clientkilltime;
 842 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 843 {SELFPARAM();
 844         float killtime;
 845         float starttime;
 846         entity e;
 847
 848         if (gameover)
 849                 return;
 850
 851         killtime = autocvar_g_balance_kill_delay;
 852
 853         if(g_race_qualifying || g_cts)
 854                 killtime = 0;
 855
 856     if(MUTATOR_CALLHOOK(ClientKill, self, killtime))
 857         return;
 858
 859         self.killindicator_teamchange = targetteam;
 860
 861     if(!self.killindicator)
 862         {
 863                 if(self.deadflag == DEAD_NO)
 864                 {
 865                         killtime = max(killtime, self.clientkill_nexttime - time);
 866                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 867                 }
 868
 869                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 870                 {
 871                         ClientKill_Now();
 872                 }
 873                 else
 874                 {
 875                         starttime = max(time, clientkilltime);
 876
 877                         self.killindicator = spawn();
 878                         self.killindicator.owner = self;
 879                         self.killindicator.scale = 0.5;
 880                         setattachment(self.killindicator, self, "");
 881                         setorigin(self.killindicator, '0 0 52');
 882                         self.killindicator.think = KillIndicator_Think;
 883                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 884                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 885                         self.killindicator.cnt = ceil(killtime);
 886                         self.killindicator.count = bound(0, ceil(killtime), 10);
 887                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 888
 889                         for(e = world; (e = find(e, classname, "body")) != world; )
 890                         {
 891                                 if(e.enemy != self)
 892                                         continue;
 893                                 e.killindicator = spawn();
 894                                 e.killindicator.owner = e;
 895                                 e.killindicator.scale = 0.5;
 896                                 setattachment(e.killindicator, e, "");
 897                                 setorigin(e.killindicator, '0 0 52');
 898                                 e.killindicator.think = KillIndicator_Think;
 899                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 900                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 901                                 e.killindicator.cnt = ceil(killtime);
 902                         }
 903                         self.lip = 0;
 904                 }
 905         }
 906         if(self.killindicator)
 907         {
 908                 if(targetteam == 0) // just die
 909                 {
 910                         self.killindicator.colormod = '0 0 0';
 911                         if(IS_REAL_CLIENT(self))
 912                         if(self.killindicator.cnt > 0)
 913                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 914                 }
 915                 else if(targetteam == -1) // auto
 916                 {
 917                         self.killindicator.colormod = '0 1 0';
 918                         if(IS_REAL_CLIENT(self))
 919                         if(self.killindicator.cnt > 0)
 920                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 921                 }
 922                 else if(targetteam == -2) // spectate
 923                 {
 924                         self.killindicator.colormod = '0.5 0.5 0.5';
 925                         if(IS_REAL_CLIENT(self))
 926                         if(self.killindicator.cnt > 0)
 927                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 928                 }
 929                 else
 930                 {
 931                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 932                         if(IS_REAL_CLIENT(self))
 933                         if(self.killindicator.cnt > 0)
 934                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 935                 }
 936         }
 937
 938 }
 939
 940 void ClientKill ()
 941 {SELFPARAM();
 942         if(gameover) return;
 943         if(self.player_blocked) return;
 944         if(self.frozen) return;
 945
 946         ClientKill_TeamChange(0);
 947 }
 948
 949 void FixClientCvars(entity e)
 950 {
 951         // send prediction settings to the client
 952         stuffcmd(e, "\nin_bindmap 0 0\n");
 953         if(autocvar_g_antilag == 3) // client side hitscan
 954                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 955         if(autocvar_sv_gentle)
 956                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 957 }
 958
 959 float PlayerInIDList(entity p, string idlist)
 960 {
 961         float n, i;
 962         string s;
 963
 964         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 965         if (!p.crypto_idfp)
 966                 return 0;
 967
 968         // this function allows abbreviated player IDs too!
 969         n = tokenize_console(idlist);
 970         for(i = 0; i < n; ++i)
 971         {
 972                 s = argv(i);
 973                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 974                         return 1;
 975         }
 976
 977         return 0;
 978 }
 979
 980 #ifdef DP_EXT_PRECONNECT
 981 /*
 982 =============
 983 ClientPreConnect
 984
 985 Called once (not at each match start) when a client begins a connection to the server
 986 =============
 987 */
 988 void ClientPreConnect ()
 989 {SELFPARAM();
 990         if(autocvar_sv_eventlog)
 991         {
 992                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 993                         self.playerid,
 994                         num_for_edict(self),
 995                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
 996                 ));
 997         }
 998 }
 999 #endif
1000
1001 /*
1002 =============
1003 ClientConnect
1004
1005 Called when a client connects to the server
1006 =============
1007 */
1008 void DecodeLevelParms ();
1009 void ClientConnect ()
1010 {SELFPARAM();
1011         float t;
1012
1013         if(IS_CLIENT(self))
1014         {
1015                 LOG_INFO("Warning: ClientConnect, but already connected!\n");
1016                 return;
1017         }
1018
1019         if(Ban_MaybeEnforceBanOnce(self))
1020                 return;
1021
1022         DecodeLevelParms();
1023
1024 #ifdef WATERMARK
1025         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1026 #endif
1027
1028         self.classname = "player_joining";
1029
1030         self.flags = FL_CLIENT;
1031         self.version_nagtime = time + 10 + random() * 10;
1032
1033         if(player_count<0)
1034         {
1035                 LOG_TRACE("BUG player count is lower than zero, this cannot happen!\n");
1036                 player_count = 0;
1037         }
1038
1039         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1040
1041         PlayerScore_Attach(self);
1042         ClientData_Attach();
1043         accuracy_init(self);
1044         Inventory_new(self);
1045
1046         bot_clientconnect();
1047
1048         playerdemo_init();
1049
1050         anticheat_init();
1051
1052         // identify the right forced team
1053         if(autocvar_g_campaign)
1054         {
1055                 if(IS_REAL_CLIENT(self)) // only players, not bots
1056                 {
1057                         switch(autocvar_g_campaign_forceteam)
1058                         {
1059                                 case 1: self.team_forced = NUM_TEAM_1; break;
1060                                 case 2: self.team_forced = NUM_TEAM_2; break;
1061                                 case 3: self.team_forced = NUM_TEAM_3; break;
1062                                 case 4: self.team_forced = NUM_TEAM_4; break;
1063                                 default: self.team_forced = 0;
1064                         }
1065                 }
1066         }
1067         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1068                 self.team_forced = NUM_TEAM_1;
1069         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1070                 self.team_forced = NUM_TEAM_2;
1071         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1072                 self.team_forced = NUM_TEAM_3;
1073         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1074                 self.team_forced = NUM_TEAM_4;
1075         else if(autocvar_g_forced_team_otherwise == "red")
1076                 self.team_forced = NUM_TEAM_1;
1077         else if(autocvar_g_forced_team_otherwise == "blue")
1078                 self.team_forced = NUM_TEAM_2;
1079         else if(autocvar_g_forced_team_otherwise == "yellow")
1080                 self.team_forced = NUM_TEAM_3;
1081         else if(autocvar_g_forced_team_otherwise == "pink")
1082                 self.team_forced = NUM_TEAM_4;
1083         else if(autocvar_g_forced_team_otherwise == "spectate")
1084                 self.team_forced = -1;
1085         else if(autocvar_g_forced_team_otherwise == "spectator")
1086                 self.team_forced = -1;
1087         else
1088                 self.team_forced = 0;
1089
1090         if(!teamplay)
1091                 if(self.team_forced > 0)
1092                         self.team_forced = 0;
1093
1094         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1095
1096         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1097                 self.classname = STR_OBSERVER;
1098         } else {
1099                 if(teamplay)
1100                 {
1101                         if(autocvar_g_balance_teams)
1102                         {
1103                                 self.classname = STR_PLAYER;
1104                                 campaign_bots_may_start = 1;
1105                         }
1106                         else
1107                         {
1108                                 self.classname = STR_OBSERVER; // do it anyway
1109                         }
1110                 }
1111                 else
1112                 {
1113                         self.classname = STR_PLAYER;
1114                         campaign_bots_may_start = 1;
1115                 }
1116         }
1117
1118         self.playerid = (playerid_last = playerid_last + 1);
1119
1120         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1121
1122     if(IS_BOT_CLIENT(self))
1123         PlayerStats_GameReport_AddPlayer(self);
1124
1125         if(autocvar_sv_eventlog)
1126                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1127
1128         LogTeamchange(self.playerid, self.team, 1);
1129
1130         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1131
1132         self.netname_previous = strzone(self.netname);
1133
1134         if(IS_PLAYER(self) && teamplay)
1135                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1136         else
1137                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1138
1139         stuffcmd(self, strcat(clientstuff, "\n"));
1140         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1141
1142         FixClientCvars(self);
1143
1144         // spawnfunc_waypoint sprites
1145         WaypointSprite_InitClient(self);
1146
1147         // Wazat's grappling hook
1148         SetGrappleHookBindings();
1149
1150         // Jetpack binds
1151         stuffcmd(self, "alias +jetpack +button10\n");
1152         stuffcmd(self, "alias -jetpack -button10\n");
1153
1154         // get version info from player
1155         stuffcmd(self, "cmd clientversion $gameversion\n");
1156
1157         // get other cvars from player
1158         GetCvars(0);
1159
1160         // notify about available teams
1161         if(teamplay)
1162         {
1163                 CheckAllowedTeams(self);
1164                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1165                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1166         }
1167         else
1168                 stuffcmd(self, "set _teams_available 0\n");
1169
1170         attach_entcs(self);
1171
1172         bot_relinkplayerlist();
1173
1174         self.spectatortime = time;
1175         if(blockSpectators)
1176         {
1177                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1178         }
1179
1180         self.jointime = time;
1181         self.allowed_timeouts = autocvar_sv_timeout_number;
1182
1183         if(IS_REAL_CLIENT(self))
1184         {
1185                 if(!autocvar_g_campaign)
1186                 {
1187                         self.motd_actived_time = -1;
1188                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1189                 }
1190
1191                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET(TUBA)))
1192                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1193         }
1194
1195         if(!sv_foginterval && world.fog != "")
1196                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1197
1198         W_HitPlotOpen(self);
1199
1200         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1201                 send_CSQC_teamnagger();
1202
1203         CheatInitClient();
1204
1205         CSQCMODEL_AUTOINIT(self);
1206
1207         self.model_randomizer = random();
1208
1209         if(IS_REAL_CLIENT(self))
1210                 sv_notice_join();
1211
1212         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1213                 WITH(entity, self, e, e.init_for_player(this));
1214         }
1215
1216         MUTATOR_CALLHOOK(ClientConnect, self);
1217 }
1218 /*
1219 =============
1220 ClientDisconnect
1221
1222 Called when a client disconnects from the server
1223 =============
1224 */
1225 .entity chatbubbleentity;
1226 void ReadyCount();
1227 void ClientDisconnect ()
1228 {SELFPARAM();
1229         if(self.vehicle)
1230             vehicles_exit(VHEF_RELEASE);
1231
1232         if (!IS_CLIENT(self))
1233         {
1234                 LOG_INFO("Warning: ClientDisconnect without ClientConnect\n");
1235                 return;
1236         }
1237
1238         PlayerStats_GameReport_FinalizePlayer(self);
1239
1240         if ( self.active_minigame )
1241                 part_minigame(self);
1242
1243         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
1244
1245         CheatShutdownClient();
1246
1247         W_HitPlotClose(self);
1248
1249         anticheat_report();
1250         anticheat_shutdown();
1251
1252         playerdemo_shutdown();
1253
1254         bot_clientdisconnect();
1255
1256         detach_entcs(self);
1257
1258         if(autocvar_sv_eventlog)
1259                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1260
1261         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1262
1263         MUTATOR_CALLHOOK(ClientDisconnect);
1264
1265         Portal_ClearAll(self);
1266
1267         Unfreeze(self);
1268
1269         RemoveGrapplingHook(self);
1270
1271         // Here, everything has been done that requires this player to be a client.
1272
1273         self.flags &= ~FL_CLIENT;
1274
1275         if (self.chatbubbleentity)
1276                 remove (self.chatbubbleentity);
1277
1278         if (self.killindicator)
1279                 remove (self.killindicator);
1280
1281         WaypointSprite_PlayerGone();
1282
1283         bot_relinkplayerlist();
1284
1285         accuracy_free(self);
1286         Inventory_delete(self);
1287         ClientData_Detach();
1288         PlayerScore_Detach(self);
1289
1290         if(self.netname_previous)
1291                 strunzone(self.netname_previous);
1292         if(self.clientstatus)
1293                 strunzone(self.clientstatus);
1294         if(self.weaponorder_byimpulse)
1295                 strunzone(self.weaponorder_byimpulse);
1296
1297         ClearPlayerSounds();
1298
1299         if(self.personal)
1300                 remove(self.personal);
1301
1302         self.playerid = 0;
1303         ReadyCount();
1304
1305         // free cvars
1306         GetCvars(-1);
1307 }
1308
1309 .float BUTTON_CHAT;
1310 void ChatBubbleThink()
1311 {SELFPARAM();
1312         self.nextthink = time;
1313         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1314         {
1315                 if(self.owner) // but why can that ever be world?
1316                         self.owner.chatbubbleentity = world;
1317                 remove(self);
1318                 return;
1319         }
1320
1321         self.mdl = "";
1322
1323         if ( !self.owner.deadflag && IS_PLAYER(self.owner) )
1324         {
1325                 if ( self.owner.active_minigame )
1326                         self.mdl = "models/sprites/minigame_busy.iqm";
1327                 else if ( self.owner.BUTTON_CHAT )
1328                         self.mdl = "models/misc/chatbubble.spr";
1329         }
1330
1331         if ( self.model != self.mdl )
1332                 _setmodel(self, self.mdl);
1333
1334 }
1335
1336 void UpdateChatBubble()
1337 {SELFPARAM();
1338         if (self.alpha < 0)
1339                 return;
1340         // spawn a chatbubble entity if needed
1341         if (!self.chatbubbleentity)
1342         {
1343                 self.chatbubbleentity = new(chatbubbleentity);
1344                 self.chatbubbleentity.owner = self;
1345                 self.chatbubbleentity.exteriormodeltoclient = self;
1346                 self.chatbubbleentity.think = ChatBubbleThink;
1347                 self.chatbubbleentity.nextthink = time;
1348                 setmodel(self.chatbubbleentity, MDL_CHAT); // precision set below
1349                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1350                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1351                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1352                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1353                 //self.chatbubbleentity.model = "";
1354                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1355         }
1356 }
1357
1358
1359 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1360 // added to the model skins
1361 /*void UpdateColorModHack()
1362 {
1363         float c;
1364         c = self.clientcolors & 15;
1365         // LordHavoc: only bothering to support white, green, red, yellow, blue
1366              if (!teamplay) self.colormod = '0 0 0';
1367         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1368         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1369         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1370         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1371         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1372         else self.colormod = '1 1 1';
1373 }*/
1374
1375 void respawn()
1376 {SELFPARAM();
1377         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1378         {
1379                 self.solid = SOLID_NOT;
1380                 self.takedamage = DAMAGE_NO;
1381                 self.movetype = MOVETYPE_FLY;
1382                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1383                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1384                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1385                 Send_Effect(EFFECT_RESPAWN_GHOST, self.origin, '0 0 0', 1);
1386                 if(autocvar_g_respawn_ghosts_maxtime)
1387                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1388         }
1389
1390         CopyBody(1);
1391
1392         self.effects |= EF_NODRAW; // prevent another CopyBody
1393         PutClientInServer();
1394 }
1395
1396 void play_countdown(float finished, string samp)
1397 {SELFPARAM();
1398         if(IS_REAL_CLIENT(self))
1399                 if(floor(finished - time - frametime) != floor(finished - time))
1400                         if(finished - time < 6)
1401                                 _sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1402 }
1403
1404 void player_powerups ()
1405 {SELFPARAM();
1406         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1407         int items_prev = self.items;
1408
1409         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1410                 self.modelflags |= MF_ROCKET;
1411         else
1412                 self.modelflags &= ~MF_ROCKET;
1413
1414         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1415
1416         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1417                 return;
1418
1419         Fire_ApplyDamage(self);
1420         Fire_ApplyEffect(self);
1421
1422         if (!g_instagib)
1423         {
1424                 if (self.items & ITEM_Strength.m_itemid)
1425                 {
1426                         play_countdown(self.strength_finished, SND(POWEROFF));
1427                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1428                         if (time > self.strength_finished)
1429                         {
1430                                 self.items = self.items - (self.items & ITEM_Strength.m_itemid);
1431                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1432                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1433                         }
1434                 }
1435                 else
1436                 {
1437                         if (time < self.strength_finished)
1438                         {
1439                                 self.items = self.items | ITEM_Strength.m_itemid;
1440                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1441                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1442                         }
1443                 }
1444                 if (self.items & ITEM_Shield.m_itemid)
1445                 {
1446                         play_countdown(self.invincible_finished, SND(POWEROFF));
1447                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1448                         if (time > self.invincible_finished)
1449                         {
1450                                 self.items = self.items - (self.items & ITEM_Shield.m_itemid);
1451                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1452                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1453                         }
1454                 }
1455                 else
1456                 {
1457                         if (time < self.invincible_finished)
1458                         {
1459                                 self.items = self.items | ITEM_Shield.m_itemid;
1460                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1461                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1462                         }
1463                 }
1464                 if (self.items & IT_SUPERWEAPON)
1465                 {
1466                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1467                         {
1468                                 self.superweapons_finished = 0;
1469                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1470                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1471                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1472                         }
1473                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1474                         {
1475                                 // don't let them run out
1476                         }
1477                         else
1478                         {
1479                                 play_countdown(self.superweapons_finished, SND(POWEROFF));
1480                                 if (time > self.superweapons_finished)
1481                                 {
1482                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1483                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1484                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1485                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1486                                 }
1487                         }
1488                 }
1489                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1490                 {
1491                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1492                         {
1493                                 self.items = self.items | IT_SUPERWEAPON;
1494                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1495                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1496                         }
1497                         else
1498                         {
1499                                 self.superweapons_finished = 0;
1500                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1501                         }
1502                 }
1503                 else
1504                 {
1505                         self.superweapons_finished = 0;
1506                 }
1507         }
1508
1509         if(autocvar_g_nodepthtestplayers)
1510                 self.effects = self.effects | EF_NODEPTHTEST;
1511
1512         if(autocvar_g_fullbrightplayers)
1513                 self.effects = self.effects | EF_FULLBRIGHT;
1514
1515         if (time >= game_starttime)
1516         if (time < self.spawnshieldtime)
1517                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1518
1519         MUTATOR_CALLHOOK(PlayerPowerups, self, items_prev);
1520 }
1521
1522 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1523 {
1524         if(current > stable)
1525                 return current;
1526         else if(current > stable - 0.25) // when close enough, "snap"
1527                 return stable;
1528         else
1529                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1530 }
1531
1532 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1533 {
1534         if(current < stable)
1535                 return current;
1536         else if(current < stable + 0.25) // when close enough, "snap"
1537                 return stable;
1538         else
1539                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1540 }
1541
1542 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1543 {
1544         if(current > rotstable)
1545         {
1546                 if(rotframetime > 0)
1547                 {
1548                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1549                         current = max(rotstable, current - rotlinear * rotframetime);
1550                 }
1551         }
1552         else if(current < regenstable)
1553         {
1554                 if(regenframetime > 0)
1555                 {
1556                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1557                         current = min(regenstable, current + regenlinear * regenframetime);
1558                 }
1559         }
1560
1561         if(current > limit)
1562                 current = limit;
1563
1564         return current;
1565 }
1566
1567 void player_regen ()
1568 {SELFPARAM();
1569         float max_mod, regen_mod, rot_mod, limit_mod;
1570         max_mod = regen_mod = rot_mod = limit_mod = 1;
1571         regen_mod_max = max_mod;
1572         regen_mod_regen = regen_mod;
1573         regen_mod_rot = rot_mod;
1574         regen_mod_limit = limit_mod;
1575
1576         regen_health = autocvar_g_balance_health_regen;
1577         regen_health_linear = autocvar_g_balance_health_regenlinear;
1578         regen_health_rot = autocvar_g_balance_health_rot;
1579         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1580         regen_health_stable = autocvar_g_balance_health_regenstable;
1581         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1582         if(!MUTATOR_CALLHOOK(PlayerRegen))
1583         if(!self.frozen)
1584         {
1585                 float mina, maxa, limith, limita;
1586                 maxa = autocvar_g_balance_armor_rotstable;
1587                 mina = autocvar_g_balance_armor_regenstable;
1588                 limith = autocvar_g_balance_health_limit;
1589                 limita = autocvar_g_balance_armor_limit;
1590
1591                 max_mod = regen_mod_max;
1592                 regen_mod = regen_mod_regen;
1593                 rot_mod = regen_mod_rot;
1594                 limit_mod = regen_mod_limit;
1595
1596                 regen_health_rotstable = regen_health_rotstable * max_mod;
1597                 regen_health_stable = regen_health_stable * max_mod;
1598                 limith = limith * limit_mod;
1599                 limita = limita * limit_mod;
1600
1601                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1602                 self.health = CalcRotRegen(self.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > self.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1603         }
1604
1605         // if player rotted to death...  die!
1606         // check this outside above checks, as player may still be able to rot to death
1607         if(self.health < 1)
1608         {
1609                 if(self.vehicle)
1610                         vehicles_exit(VHEF_RELEASE);
1611                 self.event_damage(self, self, 1, DEATH_ROT.m_id, self.origin, '0 0 0');
1612         }
1613
1614         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1615         {
1616                 float minf, maxf, limitf;
1617
1618                 maxf = autocvar_g_balance_fuel_rotstable;
1619                 minf = autocvar_g_balance_fuel_regenstable;
1620                 limitf = autocvar_g_balance_fuel_limit;
1621
1622                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1623         }
1624 }
1625
1626 float zoomstate_set;
1627 void SetZoomState(float z)
1628 {SELFPARAM();
1629         if(z != self.zoomstate)
1630         {
1631                 self.zoomstate = z;
1632                 ClientData_Touch(self);
1633         }
1634         zoomstate_set = 1;
1635 }
1636
1637 void GetPressedKeys()
1638 {
1639         SELFPARAM();
1640         MUTATOR_CALLHOOK(GetPressedKeys);
1641         int keys = this.pressedkeys;
1642         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1643         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1644         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1645         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1646
1647         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1648         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1649         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1650         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1651         this.pressedkeys = keys;
1652 }
1653
1654 /*
1655 ======================
1656 spectate mode routines
1657 ======================
1658 */
1659
1660 void SpectateCopy(entity spectatee)
1661 {SELFPARAM();
1662         MUTATOR_CALLHOOK(SpectateCopy, spectatee, self);
1663         self.armortype = spectatee.armortype;
1664         self.armorvalue = spectatee.armorvalue;
1665         self.ammo_cells = spectatee.ammo_cells;
1666         self.ammo_plasma = spectatee.ammo_plasma;
1667         self.ammo_shells = spectatee.ammo_shells;
1668         self.ammo_nails = spectatee.ammo_nails;
1669         self.ammo_rockets = spectatee.ammo_rockets;
1670         self.ammo_fuel = spectatee.ammo_fuel;
1671         self.clip_load = spectatee.clip_load;
1672         self.clip_size = spectatee.clip_size;
1673         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1674         self.health = spectatee.health;
1675         self.impulse = 0;
1676         self.items = spectatee.items;
1677         self.last_pickup = spectatee.last_pickup;
1678         self.hit_time = spectatee.hit_time;
1679         self.strength_finished = spectatee.strength_finished;
1680         self.invincible_finished = spectatee.invincible_finished;
1681         self.pressedkeys = spectatee.pressedkeys;
1682         self.weapons = spectatee.weapons;
1683         self.switchweapon = spectatee.switchweapon;
1684         self.switchingweapon = spectatee.switchingweapon;
1685         self.weapon = spectatee.weapon;
1686         self.vortex_charge = spectatee.vortex_charge;
1687         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1688         self.hagar_load = spectatee.hagar_load;
1689         self.arc_heat_percent = spectatee.arc_heat_percent;
1690         self.minelayer_mines = spectatee.minelayer_mines;
1691         self.punchangle = spectatee.punchangle;
1692         self.view_ofs = spectatee.view_ofs;
1693         self.velocity = spectatee.velocity;
1694         self.dmg_take = spectatee.dmg_take;
1695         self.dmg_save = spectatee.dmg_save;
1696         self.dmg_inflictor = spectatee.dmg_inflictor;
1697         self.v_angle = spectatee.v_angle;
1698         self.angles = spectatee.v_angle;
1699         self.frozen = spectatee.frozen;
1700         self.revive_progress = spectatee.revive_progress;
1701         if(!self.BUTTON_USE)
1702                 self.fixangle = true;
1703         setorigin(self, spectatee.origin);
1704         setsize(self, spectatee.mins, spectatee.maxs);
1705         SetZoomState(spectatee.zoomstate);
1706
1707     anticheat_spectatecopy(spectatee);
1708         self.hud = spectatee.hud;
1709         if(spectatee.vehicle)
1710     {
1711         self.fixangle = false;
1712         //self.velocity = spectatee.vehicle.velocity;
1713         self.vehicle_health = spectatee.vehicle_health;
1714         self.vehicle_shield = spectatee.vehicle_shield;
1715         self.vehicle_energy = spectatee.vehicle_energy;
1716         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1717         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1718         self.vehicle_reload1 = spectatee.vehicle_reload1;
1719         self.vehicle_reload2 = spectatee.vehicle_reload2;
1720
1721         msg_entity = self;
1722
1723         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1724             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1725             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1726             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1727
1728         //WriteByte (MSG_ONE, SVC_SETVIEW);
1729         //    WriteEntity(MSG_ONE, self);
1730         //makevectors(spectatee.v_angle);
1731         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1732     }
1733 }
1734
1735 bool SpectateUpdate()
1736 {SELFPARAM();
1737         if(!self.enemy)
1738             return false;
1739
1740         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1741         {
1742                 SetSpectatee(self, NULL);
1743                 return false;
1744         }
1745
1746         SpectateCopy(self.enemy);
1747
1748         return true;
1749 }
1750
1751 bool SpectateSet()
1752 {SELFPARAM();
1753         if(!IS_PLAYER(self.enemy))
1754                 return false;
1755
1756         msg_entity = self;
1757         WriteByte(MSG_ONE, SVC_SETVIEW);
1758         WriteEntity(MSG_ONE, self.enemy);
1759         self.movetype = MOVETYPE_NONE;
1760         accuracy_resend(self);
1761
1762         if(!SpectateUpdate())
1763                 PutObserverInServer();
1764
1765         return true;
1766 }
1767
1768 void SetSpectatee(entity player, entity spectatee)
1769 {
1770         entity old_spectatee = player.enemy;
1771
1772         player.enemy = spectatee;
1773
1774         // WEAPONTODO
1775         // these are required to fix the spectator bug with arc
1776         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1777         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1778 }
1779
1780 bool Spectate(entity pl)
1781 {SELFPARAM();
1782         if(MUTATOR_CALLHOOK(SpectateSet, self, pl))
1783                 return false;
1784         pl = spec_player;
1785
1786         SetSpectatee(self, pl);
1787         return SpectateSet();
1788 }
1789
1790 bool SpectateNext()
1791 {SELFPARAM();
1792         other = find(self.enemy, classname, "player");
1793
1794         if (MUTATOR_CALLHOOK(SpectateNext, self, other))
1795                 other = spec_player;
1796         else if (!other)
1797                 other = find(other, classname, "player");
1798
1799         if(other) { SetSpectatee(self, other); }
1800
1801         return SpectateSet();
1802 }
1803
1804 bool SpectatePrev()
1805 {SELFPARAM();
1806         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1807         other = findchain(classname, "player");
1808         if (!other) // no player
1809                 return false;
1810
1811         entity first = other;
1812         // skip players until current spectated player
1813         if(self.enemy)
1814         while(other && other != self.enemy)
1815                 other = other.chain;
1816
1817         switch (MUTATOR_CALLHOOK(SpectatePrev, self, other, first))
1818         {
1819                 case MUT_SPECPREV_FOUND:
1820                     other = spec_player;
1821                     break;
1822                 case MUT_SPECPREV_RETURN:
1823                     other = spec_player;
1824                     return true;
1825                 case MUT_SPECPREV_CONTINUE:
1826                 default:
1827                 {
1828                         if(other.chain)
1829                                 other = other.chain;
1830                         else
1831                                 other = first;
1832                         break;
1833                 }
1834         }
1835
1836         SetSpectatee(self, other);
1837         return SpectateSet();
1838 }
1839
1840 /*
1841 =============
1842 ShowRespawnCountdown()
1843
1844 Update a respawn countdown display.
1845 =============
1846 */
1847 void ShowRespawnCountdown()
1848 {SELFPARAM();
1849         float number;
1850         if(self.deadflag == DEAD_NO) // just respawned?
1851                 return;
1852         else
1853         {
1854                 number = ceil(self.respawn_time - time);
1855                 if(number <= 0)
1856                         return;
1857                 if(number <= self.respawn_countdown)
1858                 {
1859                         self.respawn_countdown = number - 1;
1860                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1861                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1862                 }
1863         }
1864 }
1865
1866 void LeaveSpectatorMode()
1867 {SELFPARAM();
1868         if(self.caplayer)
1869                 return;
1870         if(nJoinAllowed(self))
1871         {
1872                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1873                 {
1874                         self.classname = STR_PLAYER;
1875
1876                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1877                                 { JoinBestTeam(self, false, true); }
1878
1879                         if(autocvar_g_campaign)
1880                                 { campaign_bots_may_start = 1; }
1881
1882                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1883
1884                         PutClientInServer();
1885
1886                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1887                 }
1888                 else
1889                         stuffcmd(self, "menu_showteamselect\n");
1890         }
1891         else
1892         {
1893                 // Player may not join because g_maxplayers is set
1894                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1895         }
1896 }
1897
1898 /**
1899  * Determines whether the player is allowed to join. This depends on cvar
1900  * g_maxplayers, if it isn't used this function always return true, otherwise
1901  * it checks whether the number of currently playing players exceeds g_maxplayers.
1902  * @return int number of free slots for players, 0 if none
1903  */
1904 float nJoinAllowed(entity ignore)
1905 {SELFPARAM();
1906         if(!ignore)
1907         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1908         // so report 0 free slots if restricted
1909         {
1910                 if(autocvar_g_forced_team_otherwise == "spectate")
1911                         return 0;
1912                 if(autocvar_g_forced_team_otherwise == "spectator")
1913                         return 0;
1914         }
1915
1916         if(self.team_forced < 0)
1917                 return 0; // forced spectators can never join
1918
1919         // TODO simplify this
1920         entity e;
1921         float totalClients = 0;
1922         FOR_EACH_CLIENT(e)
1923                 if(e != ignore)
1924                         totalClients += 1;
1925
1926         if (!autocvar_g_maxplayers)
1927                 return maxclients - totalClients;
1928
1929         float currentlyPlaying = 0;
1930         FOR_EACH_REALCLIENT(e)
1931                 if(IS_PLAYER(e) || e.caplayer)
1932                         currentlyPlaying += 1;
1933
1934         if(currentlyPlaying < autocvar_g_maxplayers)
1935                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1936
1937         return 0;
1938 }
1939
1940 /**
1941  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1942  * g_maxplayers_spectator_blocktime seconds
1943  */
1944 void checkSpectatorBlock()
1945 {SELFPARAM();
1946         if(IS_SPEC(self) || IS_OBSERVER(self))
1947         if(!self.caplayer)
1948         if(IS_REAL_CLIENT(self))
1949         {
1950                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1951                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1952                         dropclient(self);
1953                 }
1954         }
1955 }
1956
1957 void PrintWelcomeMessage()
1958 {SELFPARAM();
1959         if(self.motd_actived_time == 0)
1960         {
1961                 if (autocvar_g_campaign) {
1962                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
1963                                 self.motd_actived_time = time;
1964                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
1965                         }
1966                 } else {
1967                         if (self.BUTTON_INFO) {
1968                                 self.motd_actived_time = time;
1969                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1970                         }
1971                 }
1972         }
1973         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
1974         {
1975                 if (autocvar_g_campaign) {
1976                         if (self.BUTTON_INFO)
1977                                 self.motd_actived_time = time;
1978                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
1979                                 self.motd_actived_time = 0;
1980                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
1981                         }
1982                 } else {
1983                         if (self.BUTTON_INFO)
1984                                 self.motd_actived_time = time;
1985                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1986                                 self.motd_actived_time = 0;
1987                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
1988                         }
1989                 }
1990         }
1991         else //if(self.motd_actived_time < 0) // just connected, motd is active
1992         {
1993                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
1994                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1995                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || IS_SPEC(self))
1996                 {
1997                         // instanctly hide MOTD
1998                         self.motd_actived_time = 0;
1999                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2000                 }
2001         }
2002 }
2003
2004 void ObserverThink()
2005 {SELFPARAM();
2006         if ( self.impulse )
2007         {
2008                 MinigameImpulse(self.impulse);
2009                 self.impulse = 0;
2010         }
2011         float prefered_movetype;
2012         if (self.flags & FL_JUMPRELEASED) {
2013                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2014                         self.flags &= ~FL_JUMPRELEASED;
2015                         self.flags |= FL_SPAWNING;
2016                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2017                         self.flags &= ~FL_JUMPRELEASED;
2018                         if(SpectateNext()) {
2019                                 self.classname = STR_SPECTATOR;
2020                         }
2021                 } else {
2022                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2023                         if (self.movetype != prefered_movetype)
2024                                 self.movetype = prefered_movetype;
2025                 }
2026         } else {
2027                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2028                         self.flags |= FL_JUMPRELEASED;
2029                         if(self.flags & FL_SPAWNING)
2030                         {
2031                                 self.flags &= ~FL_SPAWNING;
2032                                 LeaveSpectatorMode();
2033                                 return;
2034                         }
2035                 }
2036         }
2037 }
2038
2039 void SpectatorThink()
2040 {SELFPARAM();
2041         if ( self.impulse )
2042         {
2043                 if(MinigameImpulse(self.impulse))
2044                         self.impulse = 0;
2045         }
2046         if (self.flags & FL_JUMPRELEASED) {
2047                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2048                         self.flags &= ~FL_JUMPRELEASED;
2049                         self.flags |= FL_SPAWNING;
2050                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2051                         self.flags &= ~FL_JUMPRELEASED;
2052                         if(SpectateNext()) {
2053                                 self.classname = STR_SPECTATOR;
2054                         } else {
2055                                 self.classname = STR_OBSERVER;
2056                                 PutClientInServer();
2057                         }
2058                         self.impulse = 0;
2059                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2060                         self.flags &= ~FL_JUMPRELEASED;
2061                         if(SpectatePrev()) {
2062                                 self.classname = STR_SPECTATOR;
2063                         } else {
2064                                 self.classname = STR_OBSERVER;
2065                                 PutClientInServer();
2066                         }
2067                         self.impulse = 0;
2068                 } else if (self.BUTTON_ATCK2) {
2069                         self.flags &= ~FL_JUMPRELEASED;
2070                         self.classname = STR_OBSERVER;
2071                         PutClientInServer();
2072                 } else {
2073                         if(!SpectateUpdate())
2074                                 PutObserverInServer();
2075                 }
2076         } else {
2077                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2078                         self.flags |= FL_JUMPRELEASED;
2079                         if(self.flags & FL_SPAWNING)
2080                         {
2081                                 self.flags &= ~FL_SPAWNING;
2082                                 LeaveSpectatorMode();
2083                                 return;
2084                         }
2085                 }
2086                 if(!SpectateUpdate())
2087                         PutObserverInServer();
2088         }
2089
2090         self.flags |= FL_CLIENT | FL_NOTARGET;
2091 }
2092
2093 void vehicles_enter (entity pl, entity veh);
2094 void PlayerUseKey()
2095 {SELFPARAM();
2096         if (!IS_PLAYER(self))
2097                 return;
2098
2099         if(self.vehicle)
2100         {
2101                 if(!gameover)
2102                 {
2103                         vehicles_exit(VHEF_NORMAL);
2104                         return;
2105                 }
2106         }
2107         else if(autocvar_g_vehicles_enter)
2108         {
2109                 if(!self.frozen)
2110                 if(self.deadflag == DEAD_NO)
2111                 if(!gameover)
2112                 {
2113                         entity head, closest_target = world;
2114                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2115
2116                         while(head) // find the closest acceptable target to enter
2117                         {
2118                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2119                                 if(head.deadflag == DEAD_NO)
2120                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2121                                 if(head.takedamage != DAMAGE_NO)
2122                                 {
2123                                         if(closest_target)
2124                                         {
2125                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2126                                                 { closest_target = head; }
2127                                         }
2128                                         else { closest_target = head; }
2129                                 }
2130
2131                                 head = head.chain;
2132                         }
2133
2134                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2135                 }
2136         }
2137
2138         // a use key was pressed; call handlers
2139         MUTATOR_CALLHOOK(PlayerUseKey);
2140 }
2141
2142
2143 /*
2144 =============
2145 PlayerPreThink
2146
2147 Called every frame for each client before the physics are run
2148 =============
2149 */
2150 .float usekeypressed;
2151 void() nexball_setstatus;
2152 .float last_vehiclecheck;
2153 .int items_added;
2154 void PlayerPreThink ()
2155 {SELFPARAM();
2156         WarpZone_PlayerPhysics_FixVAngle();
2157
2158         self.stat_game_starttime = game_starttime;
2159         self.stat_round_starttime = round_starttime;
2160         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2161         self.stat_leadlimit = autocvar_leadlimit;
2162
2163         self.weaponsinmap = weaponsInMap;
2164
2165         if(frametime)
2166         {
2167                 // physics frames: update anticheat stuff
2168                 anticheat_prethink();
2169         }
2170
2171         if(blockSpectators && frametime)
2172                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2173                 checkSpectatorBlock();
2174
2175         zoomstate_set = 0;
2176
2177         // Savage: Check for nameless players
2178         if (isInvisibleString(self.netname)) {
2179                 string new_name = strzone(strcat("Player@", ftos(self.playerid)));
2180                 if(autocvar_sv_eventlog)
2181                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2182                 if(self.netname_previous)
2183                         strunzone(self.netname_previous);
2184                 self.netname_previous = strzone(new_name);
2185                 self.netname = self.netname_previous;
2186                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2187         } else if(self.netname_previous != self.netname) {
2188                 if(autocvar_sv_eventlog)
2189                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2190                 if(self.netname_previous)
2191                         strunzone(self.netname_previous);
2192                 self.netname_previous = strzone(self.netname);
2193         }
2194
2195         // version nagging
2196         if(self.version_nagtime)
2197                 if(self.cvar_g_xonoticversion)
2198                         if(time > self.version_nagtime)
2199                         {
2200                                 // don't notify git users
2201                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2202                                 {
2203                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2204                                         {
2205                                                 // notify release users if connecting to git
2206                                                 LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2207                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2208                                         }
2209                                         else
2210                                         {
2211                                                 float r;
2212                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2213                                                 if(r < 0)
2214                                                 {
2215                                                         // give users new version
2216                                                         LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2217                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2218                                                 }
2219                                                 else if(r > 0)
2220                                                 {
2221                                                         // notify users about old server version
2222                                                         LOG_INFO("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2223                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2224                                                 }
2225                                         }
2226                                 }
2227                                 self.version_nagtime = 0;
2228                         }
2229
2230         // GOD MODE info
2231         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2232         {
2233                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2234                 self.max_armorvalue = 0;
2235         }
2236
2237         if(self.frozen == 2)
2238         {
2239                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2240                 self.health = max(1, self.revive_progress * start_health);
2241                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2242
2243                 if(self.revive_progress >= 1)
2244                         Unfreeze(self);
2245         }
2246         else if(self.frozen == 3)
2247         {
2248                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2249                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2250
2251                 if(self.health < 1)
2252                 {
2253                         if(self.vehicle)
2254                                 vehicles_exit(VHEF_RELEASE);
2255                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, self.origin, '0 0 0');
2256                 }
2257                 else if ( self.revive_progress <= 0 )
2258                         Unfreeze(self);
2259         }
2260
2261         MUTATOR_CALLHOOK(PlayerPreThink);
2262
2263         if(autocvar_g_vehicles_enter)
2264         if(time > self.last_vehiclecheck)
2265         if(IS_PLAYER(self))
2266         if(!gameover)
2267         if(!self.frozen)
2268         if(!self.vehicle)
2269         if(self.deadflag == DEAD_NO)
2270         {
2271                 entity veh;
2272                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2273                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2274                 if(veh.deadflag == DEAD_NO)
2275                 if(veh.takedamage != DAMAGE_NO)
2276                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2277                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2278                 else if(!veh.owner)
2279                 if(!veh.team || SAME_TEAM(self, veh))
2280                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2281                 else if(autocvar_g_vehicles_steal)
2282                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2283
2284                 self.last_vehiclecheck = time + 1;
2285         }
2286
2287         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2288         {
2289                 if(self.BUTTON_USE && !self.usekeypressed)
2290                         PlayerUseKey();
2291                 self.usekeypressed = self.BUTTON_USE;
2292         }
2293
2294         if(IS_REAL_CLIENT(self))
2295                 PrintWelcomeMessage();
2296
2297         if(IS_PLAYER(self))
2298         {
2299
2300                 CheckRules_Player();
2301
2302                 if (intermission_running)
2303                 {
2304                         IntermissionThink ();   // otherwise a button could be missed between
2305                         return;                                 // the think tics
2306                 }
2307
2308                 //don't allow the player to turn around while game is paused!
2309                 if(timeout_status == TIMEOUT_ACTIVE) {
2310                         // FIXME turn this into CSQC stuff
2311                         self.v_angle = self.lastV_angle;
2312                         self.angles = self.lastV_angle;
2313                         self.fixangle = true;
2314                 }
2315
2316                 if(frametime)
2317                 {
2318                         if(self.weapon == WEP_VORTEX.m_id && WEP_CVAR(vortex, charge))
2319                         {
2320                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2321                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2322                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2323
2324                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2325                                 {
2326                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2327                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2328                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2329                                 }
2330                         }
2331                         else
2332                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2333
2334                         player_powerups();
2335                 }
2336
2337                 if (self.deadflag != DEAD_NO)
2338                 {
2339                         if(self.personal && g_race_qualifying)
2340                         {
2341                                 if(time > self.respawn_time)
2342                                 {
2343                                         self.respawn_time = time + 1; // only retry once a second
2344                                         self.stat_respawn_time = self.respawn_time;
2345                                         respawn();
2346                                         self.impulse = 141;
2347                                 }
2348                         }
2349                         else
2350                         {
2351                                 float button_pressed;
2352                                 if(frametime)
2353                                         player_anim();
2354                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2355
2356                                 if (self.deadflag == DEAD_DYING)
2357                                 {
2358                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2359                                                 self.deadflag = DEAD_RESPAWNING;
2360                                         else if(!button_pressed)
2361                                                 self.deadflag = DEAD_DEAD;
2362                                 }
2363                                 else if (self.deadflag == DEAD_DEAD)
2364                                 {
2365                                         if(button_pressed)
2366                                                 self.deadflag = DEAD_RESPAWNABLE;
2367                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2368                                                 self.deadflag = DEAD_RESPAWNING;
2369                                 }
2370                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2371                                 {
2372                                         if(!button_pressed)
2373                                                 self.deadflag = DEAD_RESPAWNING;
2374                                 }
2375                                 else if (self.deadflag == DEAD_RESPAWNING)
2376                                 {
2377                                         if(time > self.respawn_time)
2378                                         {
2379                                                 self.respawn_time = time + 1; // only retry once a second
2380                                                 self.respawn_time_max = self.respawn_time;
2381                                                 respawn();
2382                                         }
2383                                 }
2384
2385                                 ShowRespawnCountdown();
2386
2387                                 if(self.respawn_flags & RESPAWN_SILENT)
2388                                         self.stat_respawn_time = 0;
2389                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2390                                         self.stat_respawn_time = self.respawn_time_max;
2391                                 else
2392                                         self.stat_respawn_time = self.respawn_time;
2393                         }
2394
2395                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2396                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2397                                 self.stat_respawn_time *= -1;
2398
2399                         return;
2400                 }
2401
2402                 self.prevorigin = self.origin;
2403
2404                 float do_crouch = self.BUTTON_CROUCH;
2405                 if(self.hook.state)
2406                         do_crouch = 0;
2407                 if(self.vehicle)
2408                         do_crouch = 0;
2409                 if(self.frozen)
2410                         do_crouch = 0;
2411
2412                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2413                 // It cannot be predicted by the engine!
2414                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
2415                 if((self.weapon == WEP_SHOCKWAVE.m_id || self.weapon == WEP_SHOTGUN.m_id) && self.(weaponentity).wframe == WFRAME_FIRE2 && time < self.(weaponentity).weapon_nextthink)
2416                         do_crouch = 0;
2417
2418                 if (do_crouch)
2419                 {
2420                         if (!self.crouch)
2421                         {
2422                                 self.crouch = true;
2423                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2424                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2425                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2426                         }
2427                 }
2428                 else
2429                 {
2430                         if (self.crouch)
2431                         {
2432                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2433                                 if (!trace_startsolid)
2434                                 {
2435                                         self.crouch = false;
2436                                         self.view_ofs = self.stat_pl_view_ofs;
2437                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2438                                 }
2439                         }
2440                 }
2441
2442                 FixPlayermodel(self);
2443
2444                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2445                 //if(frametime)
2446                 {
2447                         self.items &= ~self.items_added;
2448
2449                         W_WeaponFrame(self);
2450
2451                         self.items_added = 0;
2452                         if(self.items & ITEM_Jetpack.m_itemid)
2453                                 if(self.items & ITEM_JetpackRegen.m_itemid || self.ammo_fuel >= 0.01)
2454                                         self.items_added |= IT_FUEL;
2455
2456                         self.items |= self.items_added;
2457                 }
2458
2459                 player_regen();
2460
2461                 // WEAPONTODO: Add a weapon request for this
2462                 // rot vortex charge to the charge limit
2463                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2464                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2465
2466                 if(frametime)
2467                         player_anim();
2468
2469                 // secret status
2470                 secrets_setstatus();
2471
2472                 // monsters status
2473                 monsters_setstatus();
2474
2475                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2476
2477                 //self.angles_y=self.v_angle_y + 90;   // temp
2478         } else if(gameover) {
2479                 if (intermission_running)
2480                         IntermissionThink ();   // otherwise a button could be missed between
2481                 return;
2482         } else if(IS_OBSERVER(self)) {
2483                 ObserverThink();
2484         } else if(IS_SPEC(self)) {
2485                 SpectatorThink();
2486         }
2487
2488         // WEAPONTODO: Add weapon request for this
2489         if(!zoomstate_set)
2490                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX.m_id) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE.m_id && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2491
2492         float oldspectatee_status;
2493         oldspectatee_status = self.spectatee_status;
2494         if(IS_SPEC(self))
2495                 self.spectatee_status = num_for_edict(self.enemy);
2496         else if(IS_OBSERVER(self))
2497                 self.spectatee_status = num_for_edict(self);
2498         else
2499                 self.spectatee_status = 0;
2500         if(self.spectatee_status != oldspectatee_status)
2501         {
2502                 ClientData_Touch(self);
2503         }
2504
2505         if(self.teamkill_soundtime)
2506         if(time > self.teamkill_soundtime)
2507         {
2508                 self.teamkill_soundtime = 0;
2509
2510                 setself(self.teamkill_soundsource);
2511                 entity oldpusher = self.pusher;
2512                 self.pusher = this;
2513
2514                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2515
2516                 self.pusher = oldpusher;
2517                 setself(this);
2518         }
2519
2520         if(self.taunt_soundtime)
2521         if(time > self.taunt_soundtime)
2522         {
2523                 self.taunt_soundtime = 0;
2524                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2525         }
2526
2527         target_voicescript_next(self);
2528
2529         // WEAPONTODO: Move into weaponsystem somehow
2530         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2531         if(!self.weapon)
2532                 self.clip_load = self.clip_size = 0;
2533 }
2534
2535 /*
2536 =============
2537 PlayerPostThink
2538
2539 Called every frame for each client after the physics are run
2540 =============
2541 */
2542 .float idlekick_lasttimeleft;
2543 void PlayerPostThink ()
2544 {SELFPARAM();
2545         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2546         if(IS_REAL_CLIENT(self))
2547         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2548         {
2549                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2550                 {
2551                         if(self.idlekick_lasttimeleft)
2552                         {
2553                                 self.idlekick_lasttimeleft = 0;
2554                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2555                         }
2556                 }
2557                 else
2558                 {
2559                         float timeleft;
2560                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2561                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2562                         {
2563                                 if(!self.idlekick_lasttimeleft)
2564                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2565                         }
2566                         if(timeleft <= 0)
2567                         {
2568                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2569                                 dropclient(self);
2570                                 return;
2571                         }
2572                         else if(timeleft <= 10)
2573                         {
2574                                 if(timeleft != self.idlekick_lasttimeleft)
2575                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2576                                 self.idlekick_lasttimeleft = timeleft;
2577                         }
2578                 }
2579         }
2580
2581         CheatFrame();
2582
2583         //CheckPlayerJump();
2584
2585         if(IS_PLAYER(self)) {
2586                 CheckRules_Player();
2587                 UpdateChatBubble();
2588                 if (self.impulse)
2589                         ImpulseCommands();
2590                 if (intermission_running)
2591                         return;         // intermission or finale
2592                 GetPressedKeys();
2593         }
2594
2595         /*
2596         float i;
2597         for(i = 0; i < 1000; ++i)
2598         {
2599                 vector end;
2600                 end = self.origin + '0 0 1024' + 512 * randomvec();
2601                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2602                 if(trace_fraction < 1)
2603                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2604                 {
2605                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2606                         break;
2607                 }
2608         }
2609         */
2610
2611         if(self.waypointsprite_attachedforcarrier)
2612                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id));
2613
2614         playerdemo_write();
2615
2616         CSQCMODEL_AUTOUPDATE(self);
2617 }