qcsrc/server/cl_client.qc

   1 #include "waypointsprites.qh"
   2
   3 #include "cl_impulse.qh"
   4 #include "cl_player.qh"
   5 #include "ent_cs.qh"
   6 #include "g_subs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "secret.qh"
  13
  14 #include "bot/bot.qh"
  15 #include "bot/navigation.qh"
  16
  17 #include "weapons/hitplot.qh"
  18 #include "weapons/weaponsystem.qh"
  19
  20 #include "../common/net_notice.qh"
  21
  22 #include "../common/minigames/sv_minigames.qh"
  23
  24 #include "../common/monsters/sv_monsters.qh"
  25
  26 #include "../warpzonelib/server.qh"
  27
  28 float c1, c2, c3, c4;
  29
  30 void send_CSQC_teamnagger() {
  31         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  32         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  33 }
  34
  35 float ClientData_Send(entity to, int sf)
  36 {
  37         if(to != self.owner)
  38         {
  39                 error("wtf");
  40                 return false;
  41         }
  42
  43         entity e;
  44
  45         e = to;
  46         if(IS_SPEC(to))
  47                 e = to.enemy;
  48
  49         sf = 0;
  50
  51         if(e.race_completed)
  52                 sf |= 1; // forced scoreboard
  53         if(to.spectatee_status)
  54                 sf |= 2; // spectator ent number follows
  55         if(e.zoomstate)
  56                 sf |= 4; // zoomed
  57         if(e.porto_v_angle_held)
  58                 sf |= 8; // angles held
  59
  60         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  61         WriteByte(MSG_ENTITY, sf);
  62
  63         if(sf & 2)
  64                 WriteByte(MSG_ENTITY, to.spectatee_status);
  65
  66         if(sf & 8)
  67         {
  68                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  69                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  70         }
  71
  72         return true;
  73 }
  74
  75 void ClientData_Attach()
  76 {
  77         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  78         self.clientdata.drawonlytoclient = self;
  79         self.clientdata.owner = self;
  80 }
  81
  82 void ClientData_Detach()
  83 {
  84         remove(self.clientdata);
  85         self.clientdata = world;
  86 }
  87
  88 void ClientData_Touch(entity e)
  89 {
  90         e.clientdata.SendFlags = 1;
  91
  92         // make it spectatable
  93         entity e2;
  94         FOR_EACH_REALCLIENT(e2)
  95         {
  96                 if(e2 != e)
  97                         if(IS_SPEC(e2))
  98                                 if(e2.enemy == e)
  99                                         e2.clientdata.SendFlags = 1;
 100         }
 101 }
 102
 103 .string netname_previous;
 104
 105 void SetSpectator(entity player, entity spectatee);
 106
 107
 108 /*
 109 =============
 110 CheckPlayerModel
 111
 112 Checks if the argument string can be a valid playermodel.
 113 Returns a valid one in doubt.
 114 =============
 115 */
 116 string FallbackPlayerModel;
 117 string CheckPlayerModel(string plyermodel) {
 118         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 119         {
 120                 // note: we cannot summon Don Strunzone here, some player may
 121                 // still have the model string set. In case anyone manages how
 122                 // to change a cvar default, we'll have a small leak here.
 123                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 124         }
 125         // only in right path
 126         if( substring(plyermodel,0,14) != "models/player/")
 127                 return FallbackPlayerModel;
 128         // only good file extensions
 129         if(substring(plyermodel,-4,4) != ".zym")
 130         if(substring(plyermodel,-4,4) != ".dpm")
 131         if(substring(plyermodel,-4,4) != ".iqm")
 132         if(substring(plyermodel,-4,4) != ".md3")
 133         if(substring(plyermodel,-4,4) != ".psk")
 134                 return FallbackPlayerModel;
 135         // forbid the LOD models
 136         if(substring(plyermodel, -9,5) == "_lod1")
 137                 return FallbackPlayerModel;
 138         if(substring(plyermodel, -9,5) == "_lod2")
 139                 return FallbackPlayerModel;
 140         if(plyermodel != strtolower(plyermodel))
 141                 return FallbackPlayerModel;
 142         // also, restrict to server models
 143         if(autocvar_sv_servermodelsonly)
 144         {
 145                 if(!fexists(plyermodel))
 146                         return FallbackPlayerModel;
 147         }
 148         return plyermodel;
 149 }
 150
 151 void setplayermodel(entity e, string modelname)
 152 {
 153         precache_model(modelname);
 154         setmodel(e, modelname);
 155         player_setupanimsformodel();
 156         UpdatePlayerSounds();
 157 }
 158
 159 /*
 160 =============
 161 PutObserverInServer
 162
 163 putting a client as observer in the server
 164 =============
 165 */
 166 void FixPlayermodel();
 167 void PutObserverInServer (void)
 168 {
 169         entity  spot;
 170     self.hud = HUD_NORMAL;
 171
 172         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 173
 174         spot = SelectSpawnPoint (true);
 175         if(!spot)
 176                 error("No spawnpoints for observers?!?\n");
 177         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 178
 179         if(IS_REAL_CLIENT(self))
 180         {
 181                 msg_entity = self;
 182                 WriteByte(MSG_ONE, SVC_SETVIEW);
 183                 WriteEntity(MSG_ONE, self);
 184         }
 185
 186         self.frags = FRAGS_SPECTATOR;
 187
 188         MUTATOR_CALLHOOK(MakePlayerObserver);
 189
 190         Portal_ClearAll(self);
 191
 192         Unfreeze(self);
 193
 194         if(self.alivetime)
 195         {
 196                 if(!warmup_stage)
 197                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 198                 self.alivetime = 0;
 199         }
 200
 201         if(self.vehicle)
 202                 vehicles_exit(VHEF_RELESE);
 203
 204         WaypointSprite_PlayerDead();
 205
 206         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 207                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 208
 209         if(self.killcount != -666)
 210         {
 211                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 212                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 213                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 214
 215                 if(self.just_joined == false) {
 216                         LogTeamchange(self.playerid, -1, 4);
 217                 } else
 218                         self.just_joined = false;
 219         }
 220
 221         PlayerScore_Clear(self); // clear scores when needed
 222
 223         accuracy_resend(self);
 224
 225         self.spectatortime = time;
 226
 227         self.classname = "observer";
 228         self.iscreature = false;
 229         self.teleportable = TELEPORT_SIMPLE;
 230         self.damagedbycontents = false;
 231         self.health = -666;
 232         self.takedamage = DAMAGE_NO;
 233         self.solid = SOLID_NOT;
 234         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 235         self.flags = FL_CLIENT | FL_NOTARGET;
 236         self.armorvalue = 666;
 237         self.effects = 0;
 238         self.armorvalue = autocvar_g_balance_armor_start;
 239         self.pauserotarmor_finished = 0;
 240         self.pauserothealth_finished = 0;
 241         self.pauseregen_finished = 0;
 242         self.damageforcescale = 0;
 243         self.death_time = 0;
 244         self.respawn_flags = 0;
 245         self.respawn_time = 0;
 246         self.stat_respawn_time = 0;
 247         self.alpha = 0;
 248         self.scale = 0;
 249         self.fade_time = 0;
 250         self.pain_frame = 0;
 251         self.pain_finished = 0;
 252         self.strength_finished = 0;
 253         self.invincible_finished = 0;
 254         self.superweapons_finished = 0;
 255         self.pushltime = 0;
 256         self.istypefrag = 0;
 257         self.think = func_null;
 258         self.nextthink = 0;
 259         self.hook_time = 0;
 260         self.deadflag = DEAD_NO;
 261         self.angles = spot.angles;
 262         self.angles_z = 0;
 263         self.fixangle = true;
 264         self.crouch = false;
 265         self.revival_time = 0;
 266
 267         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 268         self.prevorigin = self.origin;
 269         self.items = 0;
 270         self.weapons = '0 0 0';
 271         self.model = "";
 272         FixPlayermodel();
 273         setmodel(self, "null");
 274         self.drawonlytoclient = self;
 275
 276         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 277         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 278
 279         self.weapon = 0;
 280         self.weaponname = "";
 281         self.switchingweapon = 0;
 282         self.weaponmodel = "";
 283         self.weaponentity = world;
 284         self.exteriorweaponentity = world;
 285         self.killcount = -666;
 286         self.velocity = '0 0 0';
 287         self.avelocity = '0 0 0';
 288         self.punchangle = '0 0 0';
 289         self.punchvector = '0 0 0';
 290         self.oldvelocity = self.velocity;
 291         self.fire_endtime = -1;
 292         self.event_damage = func_null;
 293 }
 294
 295 .float model_randomizer;
 296 void FixPlayermodel()
 297 {
 298         string defaultmodel;
 299         float defaultskin, chmdl, oldskin, n, i;
 300         vector m1, m2;
 301
 302         defaultmodel = "";
 303         defaultskin = 0;
 304         chmdl = false;
 305
 306         if(autocvar_sv_defaultcharacter)
 307         {
 308                 if(teamplay)
 309                 {
 310                         string s;
 311                         s = Static_Team_ColorName_Lower(self.team);
 312                         if(s != "neutral")
 313                         {
 314                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 315                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 316                         }
 317                 }
 318
 319                 if(defaultmodel == "")
 320                 {
 321                         defaultmodel = autocvar_sv_defaultplayermodel;
 322                         defaultskin = autocvar_sv_defaultplayerskin;
 323                 }
 324
 325                 n = tokenize_console(defaultmodel);
 326                 if(n > 0)
 327                 {
 328                         defaultmodel = argv(floor(n * self.model_randomizer));
 329                         // However, do NOT randomize if the player-selected model is in the list.
 330                         for (i = 0; i < n; ++i)
 331                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 332                                         defaultmodel = argv(i);
 333                 }
 334
 335                 i = strstrofs(defaultmodel, ":", 0);
 336                 if(i >= 0)
 337                 {
 338                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 339                         defaultmodel = substring(defaultmodel, 0, i);
 340                 }
 341         }
 342
 343         if(defaultmodel != "")
 344         {
 345                 if (defaultmodel != self.model)
 346                 {
 347                         m1 = self.mins;
 348                         m2 = self.maxs;
 349                         setplayermodel (self, defaultmodel);
 350                         setsize (self, m1, m2);
 351                         chmdl = true;
 352                 }
 353
 354                 oldskin = self.skin;
 355                 self.skin = defaultskin;
 356         } else {
 357                 if (self.playermodel != self.model || self.playermodel == "")
 358                 {
 359                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 360                         m1 = self.mins;
 361                         m2 = self.maxs;
 362                         setplayermodel (self, self.playermodel);
 363                         setsize (self, m1, m2);
 364                         chmdl = true;
 365                 }
 366
 367                 oldskin = self.skin;
 368                 self.skin = stof(self.playerskin);
 369         }
 370
 371         if(chmdl || oldskin != self.skin) // model or skin has changed
 372         {
 373                 self.species = player_getspecies(); // update species
 374                 UpdatePlayerSounds(); // update skin sounds
 375         }
 376
 377         if(!teamplay)
 378                 if(strlen(autocvar_sv_defaultplayercolors))
 379                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 380                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 381 }
 382
 383 /*
 384 =============
 385 PutClientInServer
 386
 387 Called when a client spawns in the server
 388 =============
 389 */
 390 void PutClientInServer (void)
 391 {
 392         if(IS_BOT_CLIENT(self))
 393                 self.classname = "player";
 394         else if(IS_REAL_CLIENT(self))
 395         {
 396                 msg_entity = self;
 397                 WriteByte(MSG_ONE, SVC_SETVIEW);
 398                 WriteEntity(MSG_ONE, self);
 399         }
 400
 401         SetSpectator(self, world);
 402
 403         // reset player keys
 404         self.itemkeys = 0;
 405
 406         MUTATOR_CALLHOOK(PutClientInServer);
 407
 408         if(gameover)
 409                 self.classname = "observer";
 410
 411         if(IS_PLAYER(self))
 412         {
 413                 entity spot, oldself;
 414                 float j;
 415
 416                 accuracy_resend(self);
 417
 418                 if(self.team < 0)
 419                         JoinBestTeam(self, false, true);
 420
 421                 spot = SelectSpawnPoint (false);
 422                 if(!spot)
 423                 {
 424                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 425                         return; // spawn failed
 426                 }
 427
 428                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 429
 430                 if(self.vehicle)
 431                         vehicles_exit(VHEF_RELESE);
 432
 433                 self.classname = "player";
 434                 self.wasplayer = true;
 435                 self.iscreature = true;
 436                 self.teleportable = TELEPORT_NORMAL;
 437                 self.damagedbycontents = true;
 438                 self.movetype = MOVETYPE_WALK;
 439                 self.solid = SOLID_SLIDEBOX;
 440                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 441                 if(autocvar_g_playerclip_collisions)
 442                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 443                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 444                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 445                 self.frags = FRAGS_PLAYER;
 446                 if(INDEPENDENT_PLAYERS)
 447                         MAKE_INDEPENDENT_PLAYER(self);
 448                 self.flags = FL_CLIENT;
 449                 if(autocvar__notarget)
 450                         self.flags |= FL_NOTARGET;
 451                 self.takedamage = DAMAGE_AIM;
 452                 self.effects = 0;
 453                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 454                 self.air_finished = time + 12;
 455                 self.dmg = 2;
 456                 if(WEP_CVAR(vortex, charge))
 457                 {
 458                         if(WEP_CVAR_SEC(vortex, chargepool))
 459                                 self.vortex_chargepool_ammo = 1;
 460                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 461                 }
 462
 463                 if(warmup_stage)
 464                 {
 465                         self.ammo_shells = warmup_start_ammo_shells;
 466                         self.ammo_nails = warmup_start_ammo_nails;
 467                         self.ammo_rockets = warmup_start_ammo_rockets;
 468                         self.ammo_cells = warmup_start_ammo_cells;
 469                         self.ammo_plasma = warmup_start_ammo_plasma;
 470                         self.ammo_fuel = warmup_start_ammo_fuel;
 471                         self.health = warmup_start_health;
 472                         self.armorvalue = warmup_start_armorvalue;
 473                         self.weapons = WARMUP_START_WEAPONS;
 474                 }
 475                 else
 476                 {
 477                         self.ammo_shells = start_ammo_shells;
 478                         self.ammo_nails = start_ammo_nails;
 479                         self.ammo_rockets = start_ammo_rockets;
 480                         self.ammo_cells = start_ammo_cells;
 481                         self.ammo_plasma = start_ammo_plasma;
 482                         self.ammo_fuel = start_ammo_fuel;
 483                         self.health = start_health;
 484                         self.armorvalue = start_armorvalue;
 485                         self.weapons = start_weapons;
 486                 }
 487
 488                 if(self.weapons & WEPSET_SUPERWEAPONS)
 489                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 490                 else
 491                         self.superweapons_finished = 0;
 492
 493                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 494                 {
 495                         if(g_weaponarena_random_with_blaster)
 496                                 self.weapons &= ~WEPSET_BLASTER;
 497                         W_RandomWeapons(self, g_weaponarena_random);
 498                         if(g_weaponarena_random_with_blaster)
 499                                 self.weapons |= WEPSET_BLASTER;
 500                 }
 501
 502                 self.items = start_items;
 503
 504                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 505                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 506                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 507                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 508                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 509                 //extend the pause of rotting if client was reset at the beginning of the countdown
 510                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 511                         self.spawnshieldtime += game_starttime - time;
 512                         self.pauserotarmor_finished += game_starttime - time;
 513                         self.pauserothealth_finished += game_starttime - time;
 514                         self.pauseregen_finished += game_starttime - time;
 515                 }
 516                 self.damageforcescale = 2;
 517                 self.death_time = 0;
 518                 self.respawn_flags = 0;
 519                 self.respawn_time = 0;
 520                 self.stat_respawn_time = 0;
 521                 self.scale = 0;
 522                 self.fade_time = 0;
 523                 self.pain_frame = 0;
 524                 self.pain_finished = 0;
 525                 self.strength_finished = 0;
 526                 self.invincible_finished = 0;
 527                 self.pushltime = 0;
 528                 // players have no think function
 529                 self.think = func_null;
 530                 self.nextthink = 0;
 531                 self.hook_time = 0;
 532                 self.dmg_team = 0;
 533                 self.ballistics_density = autocvar_g_ballistics_density_player;
 534
 535                 self.metertime = 0;
 536
 537                 self.deadflag = DEAD_NO;
 538
 539                 self.angles = spot.angles;
 540
 541                 self.angles_z = 0; // never spawn tilted even if the spot says to
 542                 if(IS_BOT_CLIENT(self))
 543                         self.v_angle = self.angles;
 544                 self.fixangle = true; // turn this way immediately
 545                 self.velocity = '0 0 0';
 546                 self.avelocity = '0 0 0';
 547                 self.punchangle = '0 0 0';
 548                 self.punchvector = '0 0 0';
 549                 self.oldvelocity = self.velocity;
 550                 self.fire_endtime = -1;
 551                 self.revival_time = 0;
 552
 553                 entity spawnevent = spawn();
 554                 spawnevent.owner = self;
 555                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 556
 557                 // Cut off any still running player sounds.
 558                 stopsound(self, CH_PLAYER_SINGLE);
 559
 560                 self.model = "";
 561                 FixPlayermodel();
 562                 self.drawonlytoclient = world;
 563
 564                 self.crouch = false;
 565                 self.view_ofs = PL_VIEW_OFS;
 566                 setsize (self, PL_MIN, PL_MAX);
 567                 self.spawnorigin = spot.origin;
 568                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 569                 // don't reset back to last position, even if new position is stuck in solid
 570                 self.oldorigin = self.origin;
 571                 self.prevorigin = self.origin;
 572                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 573                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 574         self.hud = HUD_NORMAL;
 575
 576                 self.event_damage = PlayerDamage;
 577
 578                 self.bot_attack = true;
 579                 self.monster_attack = true;
 580
 581                 self.spider_slowness = 0;
 582
 583                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 584
 585                 if(self.killcount == -666) {
 586                         PlayerScore_Clear(self);
 587                         self.killcount = 0;
 588                 }
 589
 590                 CL_SpawnWeaponentity();
 591                 self.alpha = default_player_alpha;
 592                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 593                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 594
 595                 self.speedrunning = false;
 596
 597                 //stuffcmd(self, "chase_active 0");
 598                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 599
 600                 target_voicescript_clear(self);
 601
 602                 // reset fields the weapons may use
 603                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 604                 {
 605                         WEP_ACTION(j, WR_RESETPLAYER);
 606
 607                         // all weapons must be fully loaded when we spawn
 608                         entity e = get_weaponinfo(j);
 609                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 610                                 self.(weapon_load[j]) = e.reloading_ammo;
 611                 }
 612
 613                 oldself = self;
 614                 self = spot;
 615                         activator = oldself;
 616                                 string s;
 617                                 s = self.target;
 618                                 self.target = string_null;
 619                                 SUB_UseTargets();
 620                                 self.target = s;
 621                         activator = world;
 622                 self = oldself;
 623
 624                 Unfreeze(self);
 625
 626                 spawn_spot = spot;
 627                 MUTATOR_CALLHOOK(PlayerSpawn);
 628
 629                 if(autocvar_spawn_debug)
 630                 {
 631                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 632                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 633                 }
 634
 635                 self.switchweapon = w_getbestweapon(self);
 636                 self.cnt = -1; // W_LastWeapon will not complain
 637                 self.weapon = 0;
 638                 self.weaponname = "";
 639                 self.switchingweapon = 0;
 640
 641                 if(!warmup_stage)
 642                         if(!self.alivetime)
 643                                 self.alivetime = time;
 644
 645                 antilag_clear(self);
 646         }
 647         else if(IS_OBSERVER(self))
 648         {
 649                 PutObserverInServer ();
 650         }
 651 }
 652
 653 .float ebouncefactor, ebouncestop; // electro's values
 654 // TODO do we need all these fields, or should we stop autodetecting runtime
 655 // changes and just have a console command to update this?
 656 float ClientInit_SendEntity(entity to, int sf)
 657 {
 658         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 659         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 660         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 661         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 662         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 663         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 664         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 665         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 666         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 667         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 668
 669         if(sv_foginterval && world.fog != "")
 670                 WriteString(MSG_ENTITY, world.fog);
 671         else
 672                 WriteString(MSG_ENTITY, "");
 673         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 674         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 675         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 676         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 677         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 678         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 679         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 680         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 681         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 682         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 683         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 684         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 685         return true;
 686 }
 687
 688 void ClientInit_CheckUpdate()
 689 {
 690         self.nextthink = time;
 691         if(self.count != autocvar_g_balance_armor_blockpercent)
 692         {
 693                 self.count = autocvar_g_balance_armor_blockpercent;
 694                 self.SendFlags |= 1;
 695         }
 696         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 697         {
 698                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 699                 self.SendFlags |= 1;
 700         }
 701         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 702         {
 703                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 704                 self.SendFlags |= 1;
 705         }
 706         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 707         {
 708                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 709                 self.SendFlags |= 1;
 710         }
 711         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 712         {
 713                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 714                 self.SendFlags |= 1;
 715         }
 716 }
 717
 718 void ClientInit_Spawn()
 719 {
 720         entity o;
 721         entity e;
 722         e = spawn();
 723         e.classname = "clientinit";
 724         e.think = ClientInit_CheckUpdate;
 725         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 726
 727         o = self;
 728         self = e;
 729         ClientInit_CheckUpdate();
 730         self = o;
 731 }
 732
 733 /*
 734 =============
 735 SetNewParms
 736 =============
 737 */
 738 void SetNewParms (void)
 739 {
 740         // initialize parms for a new player
 741         parm1 = -(86400 * 366);
 742 }
 743
 744 /*
 745 =============
 746 SetChangeParms
 747 =============
 748 */
 749 void SetChangeParms (void)
 750 {
 751         // save parms for level change
 752         parm1 = self.parm_idlesince - time;
 753 }
 754
 755 /*
 756 =============
 757 DecodeLevelParms
 758 =============
 759 */
 760 void DecodeLevelParms (void)
 761 {
 762         // load parms
 763         self.parm_idlesince = parm1;
 764         if(self.parm_idlesince == -(86400 * 366))
 765                 self.parm_idlesince = time;
 766
 767         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 768         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 769 }
 770
 771 /*
 772 =============
 773 ClientKill
 774
 775 Called when a client types 'kill' in the console
 776 =============
 777 */
 778
 779 .float clientkill_nexttime;
 780 void ClientKill_Now_TeamChange()
 781 {
 782         if(self.killindicator_teamchange == -1)
 783         {
 784                 JoinBestTeam( self, false, true );
 785         }
 786         else if(self.killindicator_teamchange == -2)
 787         {
 788                 if(blockSpectators)
 789                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 790                 PutObserverInServer();
 791         }
 792         else
 793                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 794         self.killindicator_teamchange = 0;
 795 }
 796
 797 void ClientKill_Now()
 798 {
 799         if(self.vehicle)
 800         {
 801             vehicles_exit(VHEF_RELESE);
 802             if(!self.killindicator_teamchange)
 803             {
 804             self.vehicle_health = -1;
 805             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 806             }
 807         }
 808
 809         if(self.killindicator && !wasfreed(self.killindicator))
 810                 remove(self.killindicator);
 811
 812         self.killindicator = world;
 813
 814         if(self.killindicator_teamchange)
 815                 ClientKill_Now_TeamChange();
 816
 817         if(IS_PLAYER(self))
 818                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 819
 820         // now I am sure the player IS dead
 821 }
 822 void KillIndicator_Think()
 823 {
 824         if (gameover)
 825         {
 826                 self.owner.killindicator = world;
 827                 remove(self);
 828                 return;
 829         }
 830
 831         if (self.owner.alpha < 0 && !self.owner.vehicle)
 832         {
 833                 self.owner.killindicator = world;
 834                 remove(self);
 835                 return;
 836         }
 837
 838         if(self.cnt <= 0)
 839         {
 840                 self = self.owner;
 841                 ClientKill_Now(); // no oldself needed
 842                 return;
 843         }
 844     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 845     {
 846         self.nextthink = time + 1;
 847         self.cnt -= 1;
 848     }
 849         else
 850         {
 851                 if(self.cnt <= 10)
 852                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 853                 if(IS_REAL_CLIENT(self.owner))
 854                 {
 855                         if(self.cnt <= 10)
 856                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 857                 }
 858                 self.nextthink = time + 1;
 859                 self.cnt -= 1;
 860         }
 861 }
 862
 863 float clientkilltime;
 864 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 865 {
 866         float killtime;
 867         float starttime;
 868         entity e;
 869
 870         if (gameover)
 871                 return;
 872
 873         killtime = autocvar_g_balance_kill_delay;
 874
 875         if(g_race_qualifying || g_cts)
 876                 killtime = 0;
 877
 878     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 879     {
 880                 remove(self.killindicator);
 881                 self.killindicator = world;
 882
 883         ClientKill_Now(); // allow instant kill in this case
 884         return;
 885     }
 886
 887         self.killindicator_teamchange = targetteam;
 888
 889     if(!self.killindicator)
 890         {
 891                 if(self.deadflag == DEAD_NO)
 892                 {
 893                         killtime = max(killtime, self.clientkill_nexttime - time);
 894                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 895                 }
 896
 897                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 898                 {
 899                         ClientKill_Now();
 900                 }
 901                 else
 902                 {
 903                         starttime = max(time, clientkilltime);
 904
 905                         self.killindicator = spawn();
 906                         self.killindicator.owner = self;
 907                         self.killindicator.scale = 0.5;
 908                         setattachment(self.killindicator, self, "");
 909                         setorigin(self.killindicator, '0 0 52');
 910                         self.killindicator.think = KillIndicator_Think;
 911                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 912                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 913                         self.killindicator.cnt = ceil(killtime);
 914                         self.killindicator.count = bound(0, ceil(killtime), 10);
 915                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 916
 917                         for(e = world; (e = find(e, classname, "body")) != world; )
 918                         {
 919                                 if(e.enemy != self)
 920                                         continue;
 921                                 e.killindicator = spawn();
 922                                 e.killindicator.owner = e;
 923                                 e.killindicator.scale = 0.5;
 924                                 setattachment(e.killindicator, e, "");
 925                                 setorigin(e.killindicator, '0 0 52');
 926                                 e.killindicator.think = KillIndicator_Think;
 927                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 928                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 929                                 e.killindicator.cnt = ceil(killtime);
 930                         }
 931                         self.lip = 0;
 932                 }
 933         }
 934         if(self.killindicator)
 935         {
 936                 if(targetteam == 0) // just die
 937                 {
 938                         self.killindicator.colormod = '0 0 0';
 939                         if(IS_REAL_CLIENT(self))
 940                         if(self.killindicator.cnt > 0)
 941                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 942                 }
 943                 else if(targetteam == -1) // auto
 944                 {
 945                         self.killindicator.colormod = '0 1 0';
 946                         if(IS_REAL_CLIENT(self))
 947                         if(self.killindicator.cnt > 0)
 948                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 949                 }
 950                 else if(targetteam == -2) // spectate
 951                 {
 952                         self.killindicator.colormod = '0.5 0.5 0.5';
 953                         if(IS_REAL_CLIENT(self))
 954                         if(self.killindicator.cnt > 0)
 955                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 956                 }
 957                 else
 958                 {
 959                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 960                         if(IS_REAL_CLIENT(self))
 961                         if(self.killindicator.cnt > 0)
 962                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 963                 }
 964         }
 965
 966 }
 967
 968 void ClientKill (void)
 969 {
 970         if(gameover) return;
 971         if(self.player_blocked) return;
 972         if(self.frozen) return;
 973
 974         ClientKill_TeamChange(0);
 975 }
 976
 977 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 978 {
 979     e.killindicator = spawn();
 980     e.killindicator.owner = e;
 981     e.killindicator.think = KillIndicator_Think;
 982     e.killindicator.nextthink = time + (e.lip) * 0.05;
 983     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 984     e.killindicator.health = 1; // this is used to indicate that it should be silent
 985     e.lip = 0;
 986 }
 987
 988 void FixClientCvars(entity e)
 989 {
 990         // send prediction settings to the client
 991         stuffcmd(e, "\nin_bindmap 0 0\n");
 992         if(g_race || g_cts)
 993                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 994         if(autocvar_g_antilag == 3) // client side hitscan
 995                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 996         if(autocvar_sv_gentle)
 997                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 998 }
 999
1000 float PlayerInIDList(entity p, string idlist)
1001 {
1002         float n, i;
1003         string s;
1004
1005         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1006         if (!p.crypto_idfp)
1007                 return 0;
1008
1009         // this function allows abbreviated player IDs too!
1010         n = tokenize_console(idlist);
1011         for(i = 0; i < n; ++i)
1012         {
1013                 s = argv(i);
1014                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1015                         return 1;
1016         }
1017
1018         return 0;
1019 }
1020
1021 #ifdef DP_EXT_PRECONNECT
1022 /*
1023 =============
1024 ClientPreConnect
1025
1026 Called once (not at each match start) when a client begins a connection to the server
1027 =============
1028 */
1029 void ClientPreConnect (void)
1030 {
1031         if(autocvar_sv_eventlog)
1032         {
1033                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1034                         self.playerid,
1035                         num_for_edict(self),
1036                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1037                 ));
1038         }
1039 }
1040 #endif
1041
1042 /*
1043 =============
1044 ClientConnect
1045
1046 Called when a client connects to the server
1047 =============
1048 */
1049 void DecodeLevelParms (void);
1050 //void dom_player_join_team(entity pl);
1051 void set_dom_state(entity e);
1052 void ClientConnect (void)
1053 {
1054         float t;
1055
1056         if(IS_CLIENT(self))
1057         {
1058                 print("Warning: ClientConnect, but already connected!\n");
1059                 return;
1060         }
1061
1062         if(Ban_MaybeEnforceBanOnce(self))
1063                 return;
1064
1065         DecodeLevelParms();
1066
1067 #ifdef WATERMARK
1068         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1069 #endif
1070
1071         self.classname = "player_joining";
1072
1073         self.flags = FL_CLIENT;
1074         self.version_nagtime = time + 10 + random() * 10;
1075
1076         if(player_count<0)
1077         {
1078                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1079                 player_count = 0;
1080         }
1081
1082         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1083
1084         PlayerScore_Attach(self);
1085         ClientData_Attach();
1086         accuracy_init(self);
1087
1088         bot_clientconnect();
1089
1090         playerdemo_init();
1091
1092         anticheat_init();
1093
1094         // identify the right forced team
1095         if(autocvar_g_campaign)
1096         {
1097                 if(IS_REAL_CLIENT(self)) // only players, not bots
1098                 {
1099                         switch(autocvar_g_campaign_forceteam)
1100                         {
1101                                 case 1: self.team_forced = NUM_TEAM_1; break;
1102                                 case 2: self.team_forced = NUM_TEAM_2; break;
1103                                 case 3: self.team_forced = NUM_TEAM_3; break;
1104                                 case 4: self.team_forced = NUM_TEAM_4; break;
1105                                 default: self.team_forced = 0;
1106                         }
1107                 }
1108         }
1109         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1110                 self.team_forced = NUM_TEAM_1;
1111         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1112                 self.team_forced = NUM_TEAM_2;
1113         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1114                 self.team_forced = NUM_TEAM_3;
1115         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1116                 self.team_forced = NUM_TEAM_4;
1117         else if(autocvar_g_forced_team_otherwise == "red")
1118                 self.team_forced = NUM_TEAM_1;
1119         else if(autocvar_g_forced_team_otherwise == "blue")
1120                 self.team_forced = NUM_TEAM_2;
1121         else if(autocvar_g_forced_team_otherwise == "yellow")
1122                 self.team_forced = NUM_TEAM_3;
1123         else if(autocvar_g_forced_team_otherwise == "pink")
1124                 self.team_forced = NUM_TEAM_4;
1125         else if(autocvar_g_forced_team_otherwise == "spectate")
1126                 self.team_forced = -1;
1127         else if(autocvar_g_forced_team_otherwise == "spectator")
1128                 self.team_forced = -1;
1129         else
1130                 self.team_forced = 0;
1131
1132         if(!teamplay)
1133                 if(self.team_forced > 0)
1134                         self.team_forced = 0;
1135
1136         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1137
1138         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1139                 self.classname = "observer";
1140         } else {
1141                 if(teamplay)
1142                 {
1143                         if(autocvar_g_balance_teams)
1144                         {
1145                                 self.classname = "player";
1146                                 campaign_bots_may_start = 1;
1147                         }
1148                         else
1149                         {
1150                                 self.classname = "observer"; // do it anyway
1151                         }
1152                 }
1153                 else
1154                 {
1155                         self.classname = "player";
1156                         campaign_bots_may_start = 1;
1157                 }
1158         }
1159
1160         self.playerid = (playerid_last = playerid_last + 1);
1161
1162         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1163
1164     if(IS_BOT_CLIENT(self))
1165         PlayerStats_GameReport_AddPlayer(self);
1166
1167         if(autocvar_sv_eventlog)
1168                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1169
1170         LogTeamchange(self.playerid, self.team, 1);
1171
1172         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1173
1174         self.netname_previous = strzone(self.netname);
1175
1176         if(IS_PLAYER(self) && teamplay)
1177                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1178         else
1179                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1180
1181         stuffcmd(self, strcat(clientstuff, "\n"));
1182         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1183
1184         FixClientCvars(self);
1185
1186         // spawnfunc_waypoint sprites
1187         WaypointSprite_InitClient(self);
1188
1189         // Wazat's grappling hook
1190         SetGrappleHookBindings();
1191
1192         // Jetpack binds
1193         stuffcmd(self, "alias +jetpack +button10\n");
1194         stuffcmd(self, "alias -jetpack -button10\n");
1195
1196         // get version info from player
1197         stuffcmd(self, "cmd clientversion $gameversion\n");
1198
1199         // get other cvars from player
1200         GetCvars(0);
1201
1202         // notify about available teams
1203         if(teamplay)
1204         {
1205                 CheckAllowedTeams(self);
1206                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1207                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1208         }
1209         else
1210                 stuffcmd(self, "set _teams_available 0\n");
1211
1212         attach_entcs();
1213
1214         bot_relinkplayerlist();
1215
1216         self.spectatortime = time;
1217         if(blockSpectators)
1218         {
1219                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1220         }
1221
1222         self.jointime = time;
1223         self.allowed_timeouts = autocvar_sv_timeout_number;
1224
1225         if(IS_REAL_CLIENT(self))
1226         {
1227                 if(!autocvar_g_campaign)
1228                 {
1229                         self.motd_actived_time = -1;
1230                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1231                 }
1232
1233                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1234                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1235         }
1236
1237         if(!sv_foginterval && world.fog != "")
1238                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1239
1240         W_HitPlotOpen(self);
1241
1242         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1243                 send_CSQC_teamnagger();
1244
1245         CheatInitClient();
1246
1247         CSQCMODEL_AUTOINIT();
1248
1249         self.model_randomizer = random();
1250
1251         if(IS_REAL_CLIENT(self))
1252                 sv_notice_join();
1253
1254         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1255                 entity oldself = self;
1256                 self = e;
1257                 e.init_for_player(oldself);
1258                 self = oldself;
1259         }
1260
1261         MUTATOR_CALLHOOK(ClientConnect);
1262 }
1263 /*
1264 =============
1265 ClientDisconnect
1266
1267 Called when a client disconnects from the server
1268 =============
1269 */
1270 .entity chatbubbleentity;
1271 void ReadyCount();
1272 void ClientDisconnect (void)
1273 {
1274         if(self.vehicle)
1275             vehicles_exit(VHEF_RELESE);
1276
1277         if (!IS_CLIENT(self))
1278         {
1279                 print("Warning: ClientDisconnect without ClientConnect\n");
1280                 return;
1281         }
1282
1283         PlayerStats_GameReport_FinalizePlayer(self);
1284
1285         if ( self.active_minigame )
1286                 part_minigame(self);
1287
1288         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1289
1290         CheatShutdownClient();
1291
1292         W_HitPlotClose(self);
1293
1294         anticheat_report();
1295         anticheat_shutdown();
1296
1297         playerdemo_shutdown();
1298
1299         bot_clientdisconnect();
1300
1301         if(self.entcs)
1302                 detach_entcs();
1303
1304         if(autocvar_sv_eventlog)
1305                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1306
1307         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1308
1309         MUTATOR_CALLHOOK(ClientDisconnect);
1310
1311         Portal_ClearAll(self);
1312
1313         Unfreeze(self);
1314
1315         RemoveGrapplingHook(self);
1316
1317         // Here, everything has been done that requires this player to be a client.
1318
1319         self.flags &= ~FL_CLIENT;
1320
1321         if (self.chatbubbleentity)
1322                 remove (self.chatbubbleentity);
1323
1324         if (self.killindicator)
1325                 remove (self.killindicator);
1326
1327         WaypointSprite_PlayerGone();
1328
1329         bot_relinkplayerlist();
1330
1331         accuracy_free(self);
1332         ClientData_Detach();
1333         PlayerScore_Detach(self);
1334
1335         if(self.netname_previous)
1336                 strunzone(self.netname_previous);
1337         if(self.clientstatus)
1338                 strunzone(self.clientstatus);
1339         if(self.weaponorder_byimpulse)
1340                 strunzone(self.weaponorder_byimpulse);
1341
1342         ClearPlayerSounds();
1343
1344         if(self.personal)
1345                 remove(self.personal);
1346
1347         self.playerid = 0;
1348         ReadyCount();
1349
1350         // free cvars
1351         GetCvars(-1);
1352 }
1353
1354 .float BUTTON_CHAT;
1355 void ChatBubbleThink()
1356 {
1357         self.nextthink = time;
1358         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1359         {
1360                 if(self.owner) // but why can that ever be world?
1361                         self.owner.chatbubbleentity = world;
1362                 remove(self);
1363                 return;
1364         }
1365
1366         self.mdl = "";
1367
1368         if ( !self.owner.deadflag && IS_PLAYER(self.owner) )
1369         {
1370                 if ( self.owner.active_minigame )
1371                         self.mdl = "models/sprites/minigame_busy.iqm";
1372                 else if ( self.owner.BUTTON_CHAT )
1373                         self.mdl = "models/misc/chatbubble.spr";
1374         }
1375
1376         if ( self.model != self.mdl )
1377                 setmodel(self, self.mdl);
1378
1379 }
1380
1381 void UpdateChatBubble()
1382 {
1383         if (self.alpha < 0)
1384                 return;
1385         // spawn a chatbubble entity if needed
1386         if (!self.chatbubbleentity)
1387         {
1388                 self.chatbubbleentity = spawn();
1389                 self.chatbubbleentity.owner = self;
1390                 self.chatbubbleentity.exteriormodeltoclient = self;
1391                 self.chatbubbleentity.think = ChatBubbleThink;
1392                 self.chatbubbleentity.nextthink = time;
1393                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1394                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1395                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1396                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1397                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1398                 //self.chatbubbleentity.model = "";
1399                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1400         }
1401 }
1402
1403
1404 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1405 // added to the model skins
1406 /*void UpdateColorModHack()
1407 {
1408         float c;
1409         c = self.clientcolors & 15;
1410         // LordHavoc: only bothering to support white, green, red, yellow, blue
1411              if (!teamplay) self.colormod = '0 0 0';
1412         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1413         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1414         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1415         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1416         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1417         else self.colormod = '1 1 1';
1418 }*/
1419
1420 void respawn(void)
1421 {
1422         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1423         {
1424                 self.solid = SOLID_NOT;
1425                 self.takedamage = DAMAGE_NO;
1426                 self.movetype = MOVETYPE_FLY;
1427                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1428                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1429                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1430                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1431                 if(autocvar_g_respawn_ghosts_maxtime)
1432                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1433         }
1434
1435         CopyBody(1);
1436
1437         self.effects |= EF_NODRAW; // prevent another CopyBody
1438         PutClientInServer();
1439 }
1440
1441 void play_countdown(float finished, string samp)
1442 {
1443         if(IS_REAL_CLIENT(self))
1444                 if(floor(finished - time - frametime) != floor(finished - time))
1445                         if(finished - time < 6)
1446                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1447 }
1448
1449 void player_powerups (void)
1450 {
1451         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1452         olditems = self.items;
1453
1454         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1455                 self.modelflags |= MF_ROCKET;
1456         else
1457                 self.modelflags &= ~MF_ROCKET;
1458
1459         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1460
1461         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1462                 return;
1463
1464         Fire_ApplyDamage(self);
1465         Fire_ApplyEffect(self);
1466
1467         if (!g_instagib)
1468         {
1469                 if (self.items & IT_STRENGTH)
1470                 {
1471                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1472                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1473                         if (time > self.strength_finished)
1474                         {
1475                                 self.items = self.items - (self.items & IT_STRENGTH);
1476                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1477                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1478                         }
1479                 }
1480                 else
1481                 {
1482                         if (time < self.strength_finished)
1483                         {
1484                                 self.items = self.items | IT_STRENGTH;
1485                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1486                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1487                         }
1488                 }
1489                 if (self.items & IT_INVINCIBLE)
1490                 {
1491                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1492                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1493                         if (time > self.invincible_finished)
1494                         {
1495                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1496                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1497                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1498                         }
1499                 }
1500                 else
1501                 {
1502                         if (time < self.invincible_finished)
1503                         {
1504                                 self.items = self.items | IT_INVINCIBLE;
1505                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1506                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1507                         }
1508                 }
1509                 if (self.items & IT_SUPERWEAPON)
1510                 {
1511                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1512                         {
1513                                 self.superweapons_finished = 0;
1514                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1515                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1516                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1517                         }
1518                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1519                         {
1520                                 // don't let them run out
1521                         }
1522                         else
1523                         {
1524                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1525                                 if (time > self.superweapons_finished)
1526                                 {
1527                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1528                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1529                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1530                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1531                                 }
1532                         }
1533                 }
1534                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1535                 {
1536                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1537                         {
1538                                 self.items = self.items | IT_SUPERWEAPON;
1539                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1540                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1541                         }
1542                         else
1543                         {
1544                                 self.superweapons_finished = 0;
1545                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1546                         }
1547                 }
1548                 else
1549                 {
1550                         self.superweapons_finished = 0;
1551                 }
1552         }
1553
1554         if(autocvar_g_nodepthtestplayers)
1555                 self.effects = self.effects | EF_NODEPTHTEST;
1556
1557         if(autocvar_g_fullbrightplayers)
1558                 self.effects = self.effects | EF_FULLBRIGHT;
1559
1560         if (time >= game_starttime)
1561         if (time < self.spawnshieldtime)
1562                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1563
1564         MUTATOR_CALLHOOK(PlayerPowerups);
1565 }
1566
1567 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1568 {
1569         if(current > stable)
1570                 return current;
1571         else if(current > stable - 0.25) // when close enough, "snap"
1572                 return stable;
1573         else
1574                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1575 }
1576
1577 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1578 {
1579         if(current < stable)
1580                 return current;
1581         else if(current < stable + 0.25) // when close enough, "snap"
1582                 return stable;
1583         else
1584                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1585 }
1586
1587 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1588 {
1589         if(current > rotstable)
1590         {
1591                 if(rotframetime > 0)
1592                 {
1593                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1594                         current = max(rotstable, current - rotlinear * rotframetime);
1595                 }
1596         }
1597         else if(current < regenstable)
1598         {
1599                 if(regenframetime > 0)
1600                 {
1601                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1602                         current = min(regenstable, current + regenlinear * regenframetime);
1603                 }
1604         }
1605
1606         if(current > limit)
1607                 current = limit;
1608
1609         return current;
1610 }
1611
1612 void player_regen (void)
1613 {
1614         float max_mod, regen_mod, rot_mod, limit_mod;
1615         max_mod = regen_mod = rot_mod = limit_mod = 1;
1616         regen_mod_max = max_mod;
1617         regen_mod_regen = regen_mod;
1618         regen_mod_rot = rot_mod;
1619         regen_mod_limit = limit_mod;
1620         if(!MUTATOR_CALLHOOK(PlayerRegen))
1621         if(!self.frozen)
1622         {
1623                 float minh, mina, maxh, maxa, limith, limita;
1624                 maxh = autocvar_g_balance_health_rotstable;
1625                 maxa = autocvar_g_balance_armor_rotstable;
1626                 minh = autocvar_g_balance_health_regenstable;
1627                 mina = autocvar_g_balance_armor_regenstable;
1628                 limith = autocvar_g_balance_health_limit;
1629                 limita = autocvar_g_balance_armor_limit;
1630
1631                 max_mod = regen_mod_max;
1632                 regen_mod = regen_mod_regen;
1633                 rot_mod = regen_mod_rot;
1634                 limit_mod = regen_mod_limit;
1635
1636                 maxh = maxh * max_mod;
1637                 minh = minh * max_mod;
1638                 limith = limith * limit_mod;
1639                 limita = limita * limit_mod;
1640
1641                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1642                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1643         }
1644
1645         // if player rotted to death...  die!
1646         // check this outside above checks, as player may still be able to rot to death
1647         if(self.health < 1)
1648                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1649
1650         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1651         {
1652                 float minf, maxf, limitf;
1653
1654                 maxf = autocvar_g_balance_fuel_rotstable;
1655                 minf = autocvar_g_balance_fuel_regenstable;
1656                 limitf = autocvar_g_balance_fuel_limit;
1657
1658                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1659         }
1660 }
1661
1662 float zoomstate_set;
1663 void SetZoomState(float z)
1664 {
1665         if(z != self.zoomstate)
1666         {
1667                 self.zoomstate = z;
1668                 ClientData_Touch(self);
1669         }
1670         zoomstate_set = 1;
1671 }
1672
1673 void GetPressedKeys(void) {
1674         MUTATOR_CALLHOOK(GetPressedKeys);
1675         if (self.movement.x > 0) // get if movement keys are pressed
1676         {       // forward key pressed
1677                 self.pressedkeys |= KEY_FORWARD;
1678                 self.pressedkeys &= ~KEY_BACKWARD;
1679         }
1680         else if (self.movement.x < 0)
1681         {       // backward key pressed
1682                 self.pressedkeys |= KEY_BACKWARD;
1683                 self.pressedkeys &= ~KEY_FORWARD;
1684         }
1685         else
1686         {       // no x input
1687                 self.pressedkeys &= ~KEY_FORWARD;
1688                 self.pressedkeys &= ~KEY_BACKWARD;
1689         }
1690
1691         if (self.movement.y > 0)
1692         {       // right key pressed
1693                 self.pressedkeys |= KEY_RIGHT;
1694                 self.pressedkeys &= ~KEY_LEFT;
1695         }
1696         else if (self.movement.y < 0)
1697         {       // left key pressed
1698                 self.pressedkeys |= KEY_LEFT;
1699                 self.pressedkeys &= ~KEY_RIGHT;
1700         }
1701         else
1702         {       // no y input
1703                 self.pressedkeys &= ~KEY_RIGHT;
1704                 self.pressedkeys &= ~KEY_LEFT;
1705         }
1706
1707         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1708                 self.pressedkeys |= KEY_JUMP;
1709         else
1710                 self.pressedkeys &= ~KEY_JUMP;
1711         if (self.BUTTON_CROUCH)
1712                 self.pressedkeys |= KEY_CROUCH;
1713         else
1714                 self.pressedkeys &= ~KEY_CROUCH;
1715
1716         if (self.BUTTON_ATCK)
1717                 self.pressedkeys |= KEY_ATCK;
1718         else
1719                 self.pressedkeys &= ~KEY_ATCK;
1720         if (self.BUTTON_ATCK2)
1721                 self.pressedkeys |= KEY_ATCK2;
1722         else
1723                 self.pressedkeys &= ~KEY_ATCK2;
1724 }
1725
1726 /*
1727 ======================
1728 spectate mode routines
1729 ======================
1730 */
1731
1732 void SpectateCopy(entity spectatee) {
1733         other = spectatee;
1734         MUTATOR_CALLHOOK(SpectateCopy);
1735         self.armortype = spectatee.armortype;
1736         self.armorvalue = spectatee.armorvalue;
1737         self.ammo_cells = spectatee.ammo_cells;
1738         self.ammo_plasma = spectatee.ammo_plasma;
1739         self.ammo_shells = spectatee.ammo_shells;
1740         self.ammo_nails = spectatee.ammo_nails;
1741         self.ammo_rockets = spectatee.ammo_rockets;
1742         self.ammo_fuel = spectatee.ammo_fuel;
1743         self.clip_load = spectatee.clip_load;
1744         self.clip_size = spectatee.clip_size;
1745         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1746         self.health = spectatee.health;
1747         self.impulse = 0;
1748         self.items = spectatee.items;
1749         self.last_pickup = spectatee.last_pickup;
1750         self.hit_time = spectatee.hit_time;
1751         self.metertime = spectatee.metertime;
1752         self.strength_finished = spectatee.strength_finished;
1753         self.invincible_finished = spectatee.invincible_finished;
1754         self.pressedkeys = spectatee.pressedkeys;
1755         self.weapons = spectatee.weapons;
1756         self.switchweapon = spectatee.switchweapon;
1757         self.switchingweapon = spectatee.switchingweapon;
1758         self.weapon = spectatee.weapon;
1759         self.vortex_charge = spectatee.vortex_charge;
1760         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1761         self.hagar_load = spectatee.hagar_load;
1762         self.arc_heat_percent = spectatee.arc_heat_percent;
1763         self.minelayer_mines = spectatee.minelayer_mines;
1764         self.punchangle = spectatee.punchangle;
1765         self.view_ofs = spectatee.view_ofs;
1766         self.velocity = spectatee.velocity;
1767         self.dmg_take = spectatee.dmg_take;
1768         self.dmg_save = spectatee.dmg_save;
1769         self.dmg_inflictor = spectatee.dmg_inflictor;
1770         self.v_angle = spectatee.v_angle;
1771         self.angles = spectatee.v_angle;
1772         self.frozen = spectatee.frozen;
1773         self.revive_progress = spectatee.revive_progress;
1774         if(!self.BUTTON_USE)
1775                 self.fixangle = true;
1776         setorigin(self, spectatee.origin);
1777         setsize(self, spectatee.mins, spectatee.maxs);
1778         SetZoomState(spectatee.zoomstate);
1779
1780     anticheat_spectatecopy(spectatee);
1781         self.hud = spectatee.hud;
1782         if(spectatee.vehicle)
1783     {
1784         self.fixangle = false;
1785         //self.velocity = spectatee.vehicle.velocity;
1786         self.vehicle_health = spectatee.vehicle_health;
1787         self.vehicle_shield = spectatee.vehicle_shield;
1788         self.vehicle_energy = spectatee.vehicle_energy;
1789         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1790         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1791         self.vehicle_reload1 = spectatee.vehicle_reload1;
1792         self.vehicle_reload2 = spectatee.vehicle_reload2;
1793
1794         msg_entity = self;
1795
1796         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1797             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1798             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1799             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1800
1801         //WriteByte (MSG_ONE, SVC_SETVIEW);
1802         //    WriteEntity(MSG_ONE, self);
1803         //makevectors(spectatee.v_angle);
1804         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1805     }
1806 }
1807
1808 float SpectateUpdate()
1809 {
1810         if(!self.enemy)
1811             return 0;
1812
1813         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1814         {
1815                 SetSpectator(self, world);
1816                 return 0;
1817         }
1818
1819         SpectateCopy(self.enemy);
1820
1821         return 1;
1822 }
1823
1824 float SpectateSet()
1825 {
1826         if(self.enemy.classname != "player")
1827                 return false;
1828         /*if(self.enemy.vehicle)
1829         {
1830
1831                 msg_entity = self;
1832                 WriteByte(MSG_ONE, SVC_SETVIEW);
1833                 WriteEntity(MSG_ONE, self.enemy);
1834                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1835
1836                 self.movetype = MOVETYPE_NONE;
1837                 accuracy_resend(self);
1838         }
1839         else
1840         {*/
1841                 msg_entity = self;
1842                 WriteByte(MSG_ONE, SVC_SETVIEW);
1843                 WriteEntity(MSG_ONE, self.enemy);
1844                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1845                 self.movetype = MOVETYPE_NONE;
1846                 accuracy_resend(self);
1847
1848                 if(!SpectateUpdate())
1849                         PutObserverInServer();
1850         //}
1851         return true;
1852 }
1853
1854 void SetSpectator(entity player, entity spectatee)
1855 {
1856         entity old_spectatee = player.enemy;
1857
1858         player.enemy = spectatee;
1859
1860         // WEAPONTODO
1861         // these are required to fix the spectator bug with arc
1862         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1863         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1864 }
1865
1866 float Spectate(entity pl)
1867 {
1868         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1869         if(pl.team != self.team)
1870                 return 0;
1871
1872         SetSpectator(self, pl);
1873         return SpectateSet();
1874 }
1875
1876 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1877 entity CA_SpectateNext(entity start) {
1878         if (start.team == self.team) {
1879                 return start;
1880         }
1881
1882         other = start;
1883         // continue from current player
1884         while(other && other.team != self.team) {
1885                 other = find(other, classname, "player");
1886         }
1887
1888         if (!other) {
1889                 // restart from begining
1890                 other = find(other, classname, "player");
1891                 while(other && other.team != self.team) {
1892                         other = find(other, classname, "player");
1893                 }
1894         }
1895
1896         return other;
1897 }
1898
1899 float SpectateNext()
1900 {
1901         other = find(self.enemy, classname, "player");
1902
1903         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1904                 // CA and ca players when spectating enemies is forbidden
1905                 other = CA_SpectateNext(other);
1906         } else {
1907                 // other modes and ca spectators or spectating enemies is allowed
1908                 if (!other)
1909                         other = find(other, classname, "player");
1910         }
1911
1912         if(other) { SetSpectator(self, other); }
1913
1914         return SpectateSet();
1915 }
1916
1917 float SpectatePrev()
1918 {
1919         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1920         other = findchain(classname, "player");
1921         if (!other) // no player
1922                 return false;
1923
1924         entity first = other;
1925         // skip players until current spectated player
1926         if(self.enemy)
1927         while(other && other != self.enemy)
1928                 other = other.chain;
1929
1930         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1931         {
1932                 do { other = other.chain; }
1933                 while(other && other.team != self.team);
1934
1935                 if (!other)
1936                 {
1937                         other = first;
1938                         while(other.team != self.team)
1939                                 other = other.chain;
1940                         if(other == self.enemy)
1941                                 return true;
1942                 }
1943         }
1944         else
1945         {
1946                 if(other.chain)
1947                         other = other.chain;
1948                 else
1949                         other = first;
1950         }
1951         SetSpectator(self, other);
1952         return SpectateSet();
1953 }
1954
1955 /*
1956 =============
1957 ShowRespawnCountdown()
1958
1959 Update a respawn countdown display.
1960 =============
1961 */
1962 void ShowRespawnCountdown()
1963 {
1964         float number;
1965         if(self.deadflag == DEAD_NO) // just respawned?
1966                 return;
1967         else
1968         {
1969                 number = ceil(self.respawn_time - time);
1970                 if(number <= 0)
1971                         return;
1972                 if(number <= self.respawn_countdown)
1973                 {
1974                         self.respawn_countdown = number - 1;
1975                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1976                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1977                 }
1978         }
1979 }
1980
1981 void LeaveSpectatorMode()
1982 {
1983         if(self.caplayer)
1984                 return;
1985         if(nJoinAllowed(self))
1986         {
1987                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1988                 {
1989                         self.classname = "player";
1990                         nades_RemoveBonus(self);
1991
1992                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1993                                 { JoinBestTeam(self, false, true); }
1994
1995                         if(autocvar_g_campaign)
1996                                 { campaign_bots_may_start = 1; }
1997
1998                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1999
2000                         PutClientInServer();
2001
2002                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2003                 }
2004                 else
2005                         stuffcmd(self, "menu_showteamselect\n");
2006         }
2007         else
2008         {
2009                 // Player may not join because g_maxplayers is set
2010                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2011         }
2012 }
2013
2014 /**
2015  * Determines whether the player is allowed to join. This depends on cvar
2016  * g_maxplayers, if it isn't used this function always return true, otherwise
2017  * it checks whether the number of currently playing players exceeds g_maxplayers.
2018  * @return int number of free slots for players, 0 if none
2019  */
2020 float nJoinAllowed(entity ignore) {
2021         if(!ignore)
2022         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2023         // so report 0 free slots if restricted
2024         {
2025                 if(autocvar_g_forced_team_otherwise == "spectate")
2026                         return 0;
2027                 if(autocvar_g_forced_team_otherwise == "spectator")
2028                         return 0;
2029         }
2030
2031         if(self.team_forced < 0)
2032                 return 0; // forced spectators can never join
2033
2034         // TODO simplify this
2035         entity e;
2036         float totalClients = 0;
2037         FOR_EACH_CLIENT(e)
2038                 if(e != ignore)
2039                         totalClients += 1;
2040
2041         if (!autocvar_g_maxplayers)
2042                 return maxclients - totalClients;
2043
2044         float currentlyPlaying = 0;
2045         FOR_EACH_REALCLIENT(e)
2046                 if(IS_PLAYER(e) || e.caplayer)
2047                         currentlyPlaying += 1;
2048
2049         if(currentlyPlaying < autocvar_g_maxplayers)
2050                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2051
2052         return 0;
2053 }
2054
2055 /**
2056  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2057  * g_maxplayers_spectator_blocktime seconds
2058  */
2059 void checkSpectatorBlock() {
2060         if(IS_SPEC(self) || IS_OBSERVER(self))
2061         if(!self.caplayer)
2062         if(IS_REAL_CLIENT(self))
2063         {
2064                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2065                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2066                         dropclient(self);
2067                 }
2068         }
2069 }
2070
2071 void PrintWelcomeMessage()
2072 {
2073         if(self.motd_actived_time == 0)
2074         {
2075                 if (autocvar_g_campaign) {
2076                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2077                                 self.motd_actived_time = time;
2078                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2079                         }
2080                 } else {
2081                         if (self.BUTTON_INFO) {
2082                                 self.motd_actived_time = time;
2083                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2084                         }
2085                 }
2086         }
2087         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2088         {
2089                 if (autocvar_g_campaign) {
2090                         if (self.BUTTON_INFO)
2091                                 self.motd_actived_time = time;
2092                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2093                                 self.motd_actived_time = 0;
2094                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2095                         }
2096                 } else {
2097                         if (self.BUTTON_INFO)
2098                                 self.motd_actived_time = time;
2099                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2100                                 self.motd_actived_time = 0;
2101                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2102                         }
2103                 }
2104         }
2105         else //if(self.motd_actived_time < 0) // just connected, motd is active
2106         {
2107                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2108                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2109                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2110                 {
2111                         // instanctly hide MOTD
2112                         self.motd_actived_time = 0;
2113                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2114                 }
2115         }
2116 }
2117
2118 void ObserverThink()
2119 {
2120         if ( self.impulse )
2121         {
2122                 MinigameImpulse(self.impulse);
2123                 self.impulse = 0;
2124         }
2125         float prefered_movetype;
2126         if (self.flags & FL_JUMPRELEASED) {
2127                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2128                         self.flags &= ~FL_JUMPRELEASED;
2129                         self.flags |= FL_SPAWNING;
2130                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2131                         self.flags &= ~FL_JUMPRELEASED;
2132                         if(SpectateNext()) {
2133                                 self.classname = "spectator";
2134                         }
2135                 } else {
2136                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2137                         if (self.movetype != prefered_movetype)
2138                                 self.movetype = prefered_movetype;
2139                 }
2140         } else {
2141                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2142                         self.flags |= FL_JUMPRELEASED;
2143                         if(self.flags & FL_SPAWNING)
2144                         {
2145                                 self.flags &= ~FL_SPAWNING;
2146                                 LeaveSpectatorMode();
2147                                 return;
2148                         }
2149                 }
2150         }
2151 }
2152
2153 void SpectatorThink()
2154 {
2155         if ( self.impulse )
2156         {
2157                 MinigameImpulse(self.impulse);
2158                 self.impulse = 0;
2159         }
2160         if (self.flags & FL_JUMPRELEASED) {
2161                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2162                         self.flags &= ~FL_JUMPRELEASED;
2163                         self.flags |= FL_SPAWNING;
2164                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2165                         self.flags &= ~FL_JUMPRELEASED;
2166                         if(SpectateNext()) {
2167                                 self.classname = "spectator";
2168                         } else {
2169                                 self.classname = "observer";
2170                                 PutClientInServer();
2171                         }
2172                         self.impulse = 0;
2173                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2174                         self.flags &= ~FL_JUMPRELEASED;
2175                         if(SpectatePrev()) {
2176                                 self.classname = "spectator";
2177                         } else {
2178                                 self.classname = "observer";
2179                                 PutClientInServer();
2180                         }
2181                         self.impulse = 0;
2182                 } else if (self.BUTTON_ATCK2) {
2183                         self.flags &= ~FL_JUMPRELEASED;
2184                         self.classname = "observer";
2185                         PutClientInServer();
2186                 } else {
2187                         if(!SpectateUpdate())
2188                                 PutObserverInServer();
2189                 }
2190         } else {
2191                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2192                         self.flags |= FL_JUMPRELEASED;
2193                         if(self.flags & FL_SPAWNING)
2194                         {
2195                                 self.flags &= ~FL_SPAWNING;
2196                                 LeaveSpectatorMode();
2197                                 return;
2198                         }
2199                 }
2200                 if(!SpectateUpdate())
2201                         PutObserverInServer();
2202         }
2203
2204         self.flags |= FL_CLIENT | FL_NOTARGET;
2205 }
2206
2207 void PlayerUseKey()
2208 {
2209         if (!IS_PLAYER(self))
2210                 return;
2211
2212         if(self.vehicle)
2213         {
2214         vehicles_exit(VHEF_NORMAL);
2215         return;
2216         }
2217
2218         // a use key was pressed; call handlers
2219         MUTATOR_CALLHOOK(PlayerUseKey);
2220 }
2221
2222 float isInvisibleString(string s)
2223 {
2224         float i, n, c;
2225         s = strdecolorize(s);
2226         for((i = 0), (n = strlen(s)); i < n; ++i)
2227         {
2228                 c = str2chr(s, i);
2229                 switch(c)
2230                 {
2231                         case 0:
2232                         case 32: // space
2233                                 break;
2234                         case 192: // charmap space
2235                                 if (!autocvar_utf8_enable)
2236                                         break;
2237                                 return false;
2238                         case 160: // space in unicode fonts
2239                         case 0xE000 + 192: // utf8 charmap space
2240                                 if (autocvar_utf8_enable)
2241                                         break;
2242                         default:
2243                                 return false;
2244                 }
2245         }
2246         return true;
2247 }
2248
2249 /*
2250 =============
2251 PlayerPreThink
2252
2253 Called every frame for each client before the physics are run
2254 =============
2255 */
2256 .float usekeypressed;
2257 void() nexball_setstatus;
2258 .int items_added;
2259 void PlayerPreThink (void)
2260 {
2261         WarpZone_PlayerPhysics_FixVAngle();
2262
2263         self.stat_game_starttime = game_starttime;
2264         self.stat_round_starttime = round_starttime;
2265         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2266         self.stat_leadlimit = autocvar_leadlimit;
2267
2268         if(frametime)
2269         {
2270                 // physics frames: update anticheat stuff
2271                 anticheat_prethink();
2272         }
2273
2274         if(blockSpectators && frametime)
2275                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2276                 checkSpectatorBlock();
2277
2278         zoomstate_set = 0;
2279
2280         // Savage: Check for nameless players
2281         if (isInvisibleString(self.netname)) {
2282                 string new_name = strzone(strcat("Player@", self.netaddress));
2283                 if(autocvar_sv_eventlog)
2284                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2285                 if(self.netname_previous)
2286                         strunzone(self.netname_previous);
2287                 self.netname_previous = strzone(new_name);
2288                 self.netname = self.netname_previous;
2289                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2290         } else if(self.netname_previous != self.netname) {
2291                 if(autocvar_sv_eventlog)
2292                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2293                 if(self.netname_previous)
2294                         strunzone(self.netname_previous);
2295                 self.netname_previous = strzone(self.netname);
2296         }
2297
2298         // version nagging
2299         if(self.version_nagtime)
2300                 if(self.cvar_g_xonoticversion)
2301                         if(time > self.version_nagtime)
2302                         {
2303                                 // don't notify git users
2304                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2305                                 {
2306                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2307                                         {
2308                                                 // notify release users if connecting to git
2309                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2310                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2311                                         }
2312                                         else
2313                                         {
2314                                                 float r;
2315                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2316                                                 if(r < 0)
2317                                                 {
2318                                                         // give users new version
2319                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2320                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2321                                                 }
2322                                                 else if(r > 0)
2323                                                 {
2324                                                         // notify users about old server version
2325                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2326                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2327                                                 }
2328                                         }
2329                                 }
2330                                 self.version_nagtime = 0;
2331                         }
2332
2333         // GOD MODE info
2334         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2335         {
2336                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2337                 self.max_armorvalue = 0;
2338         }
2339
2340         if(self.frozen == 2)
2341         {
2342                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2343                 self.health = max(1, self.revive_progress * start_health);
2344                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2345
2346                 if(self.revive_progress >= 1)
2347                         Unfreeze(self);
2348         }
2349         else if(self.frozen == 3)
2350         {
2351                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2352                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2353
2354                 if(self.health < 1)
2355                 {
2356                         if(self.vehicle)
2357                                 vehicles_exit(VHEF_RELESE);
2358                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2359                 }
2360                 else if ( self.revive_progress <= 0 )
2361                         Unfreeze(self);
2362         }
2363
2364         MUTATOR_CALLHOOK(PlayerPreThink);
2365
2366         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2367         {
2368                 if(self.BUTTON_USE && !self.usekeypressed)
2369                         PlayerUseKey();
2370                 self.usekeypressed = self.BUTTON_USE;
2371         }
2372
2373         if(IS_REAL_CLIENT(self))
2374                 PrintWelcomeMessage();
2375
2376         if(IS_PLAYER(self))
2377         {
2378
2379                 CheckRules_Player();
2380
2381                 if (intermission_running)
2382                 {
2383                         IntermissionThink ();   // otherwise a button could be missed between
2384                         return;                                 // the think tics
2385                 }
2386
2387                 //don't allow the player to turn around while game is paused!
2388                 if(timeout_status == TIMEOUT_ACTIVE) {
2389                         // FIXME turn this into CSQC stuff
2390                         self.v_angle = self.lastV_angle;
2391                         self.angles = self.lastV_angle;
2392                         self.fixangle = true;
2393                 }
2394
2395                 if(frametime)
2396                 {
2397                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2398                         {
2399                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2400                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2401                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2402
2403                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2404                                 {
2405                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2406                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2407                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2408                                 }
2409                         }
2410                         else
2411                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2412
2413                         player_powerups();
2414                 }
2415
2416                 if (self.deadflag != DEAD_NO)
2417                 {
2418                         if(self.personal && g_race_qualifying)
2419                         {
2420                                 if(time > self.respawn_time)
2421                                 {
2422                                         self.respawn_time = time + 1; // only retry once a second
2423                                         self.stat_respawn_time = self.respawn_time;
2424                                         respawn();
2425                                         self.impulse = 141;
2426                                 }
2427                         }
2428                         else
2429                         {
2430                                 float button_pressed;
2431                                 if(frametime)
2432                                         player_anim();
2433                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2434
2435                                 if (self.deadflag == DEAD_DYING)
2436                                 {
2437                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2438                                                 self.deadflag = DEAD_RESPAWNING;
2439                                         else if(!button_pressed)
2440                                                 self.deadflag = DEAD_DEAD;
2441                                 }
2442                                 else if (self.deadflag == DEAD_DEAD)
2443                                 {
2444                                         if(button_pressed)
2445                                                 self.deadflag = DEAD_RESPAWNABLE;
2446                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2447                                                 self.deadflag = DEAD_RESPAWNING;
2448                                 }
2449                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2450                                 {
2451                                         if(!button_pressed)
2452                                                 self.deadflag = DEAD_RESPAWNING;
2453                                 }
2454                                 else if (self.deadflag == DEAD_RESPAWNING)
2455                                 {
2456                                         if(time > self.respawn_time)
2457                                         {
2458                                                 self.respawn_time = time + 1; // only retry once a second
2459                                                 self.respawn_time_max = self.respawn_time;
2460                                                 respawn();
2461                                         }
2462                                 }
2463
2464                                 ShowRespawnCountdown();
2465
2466                                 if(self.respawn_flags & RESPAWN_SILENT)
2467                                         self.stat_respawn_time = 0;
2468                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2469                                         self.stat_respawn_time = self.respawn_time_max;
2470                                 else
2471                                         self.stat_respawn_time = self.respawn_time;
2472                         }
2473
2474                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2475                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2476                                 self.stat_respawn_time *= -1;
2477
2478                         return;
2479                 }
2480
2481                 self.prevorigin = self.origin;
2482
2483                 float do_crouch = self.BUTTON_CROUCH;
2484                 if(self.hook.state)
2485                         do_crouch = 0;
2486                 if(self.vehicle)
2487                         do_crouch = 0;
2488                 if(self.frozen)
2489                         do_crouch = 0;
2490
2491                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2492                 // It cannot be predicted by the engine!
2493                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2494                         do_crouch = 0;
2495
2496                 if (do_crouch)
2497                 {
2498                         if (!self.crouch)
2499                         {
2500                                 self.crouch = true;
2501                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2502                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2503                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2504                         }
2505                 }
2506                 else
2507                 {
2508                         if (self.crouch)
2509                         {
2510                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, false, self);
2511                                 if (!trace_startsolid)
2512                                 {
2513                                         self.crouch = false;
2514                                         self.view_ofs = PL_VIEW_OFS;
2515                                         setsize (self, PL_MIN, PL_MAX);
2516                                 }
2517                         }
2518                 }
2519
2520                 FixPlayermodel();
2521
2522                 GrapplingHookFrame();
2523
2524                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2525                 //if(frametime)
2526                 {
2527                         self.items &= ~self.items_added;
2528
2529                         W_WeaponFrame();
2530
2531                         self.items_added = 0;
2532                         if(self.items & IT_JETPACK)
2533                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2534                                         self.items_added |= IT_FUEL;
2535
2536                         self.items |= self.items_added;
2537                 }
2538
2539                 player_regen();
2540
2541                 // WEAPONTODO: Add a weapon request for this
2542                 // rot vortex charge to the charge limit
2543                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2544                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2545
2546                 if(frametime)
2547                         player_anim();
2548
2549                 // secret status
2550                 secrets_setstatus();
2551
2552                 // monsters status
2553                 monsters_setstatus();
2554
2555                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2556
2557                 //self.angles_y=self.v_angle_y + 90;   // temp
2558         } else if(gameover) {
2559                 if (intermission_running)
2560                         IntermissionThink ();   // otherwise a button could be missed between
2561                 return;
2562         } else if(IS_OBSERVER(self)) {
2563                 ObserverThink();
2564         } else if(IS_SPEC(self)) {
2565                 SpectatorThink();
2566         }
2567
2568         // WEAPONTODO: Add weapon request for this
2569         if(!zoomstate_set)
2570                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2571
2572         float oldspectatee_status;
2573         oldspectatee_status = self.spectatee_status;
2574         if(IS_SPEC(self))
2575                 self.spectatee_status = num_for_edict(self.enemy);
2576         else if(IS_OBSERVER(self))
2577                 self.spectatee_status = num_for_edict(self);
2578         else
2579                 self.spectatee_status = 0;
2580         if(self.spectatee_status != oldspectatee_status)
2581         {
2582                 ClientData_Touch(self);
2583         }
2584
2585         if(self.teamkill_soundtime)
2586         if(time > self.teamkill_soundtime)
2587         {
2588                 self.teamkill_soundtime = 0;
2589
2590                 entity oldpusher, oldself;
2591
2592                 oldself = self; self = self.teamkill_soundsource;
2593                 oldpusher = self.pusher; self.pusher = oldself;
2594
2595                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2596
2597                 self.pusher = oldpusher;
2598                 self = oldself;
2599         }
2600
2601         if(self.taunt_soundtime)
2602         if(time > self.taunt_soundtime)
2603         {
2604                 self.taunt_soundtime = 0;
2605                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2606         }
2607
2608         target_voicescript_next(self);
2609
2610         // WEAPONTODO: Move into weaponsystem somehow
2611         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2612         if(!self.weapon)
2613                 self.clip_load = self.clip_size = 0;
2614 }
2615
2616 /*
2617 =============
2618 PlayerPostThink
2619
2620 Called every frame for each client after the physics are run
2621 =============
2622 */
2623 .float idlekick_lasttimeleft;
2624 void PlayerPostThink (void)
2625 {
2626         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2627         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2628         {
2629                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2630                 {
2631                         if(self.idlekick_lasttimeleft)
2632                         {
2633                                 self.idlekick_lasttimeleft = 0;
2634                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2635                         }
2636                 }
2637                 else
2638                 {
2639                         float timeleft;
2640                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2641                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2642                         {
2643                                 if(!self.idlekick_lasttimeleft)
2644                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2645                         }
2646                         if(timeleft <= 0)
2647                         {
2648                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2649                                 dropclient(self);
2650                                 return;
2651                         }
2652                         else if(timeleft <= 10)
2653                         {
2654                                 if(timeleft != self.idlekick_lasttimeleft)
2655                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2656                                 self.idlekick_lasttimeleft = timeleft;
2657                         }
2658                 }
2659         }
2660
2661         CheatFrame();
2662
2663         //CheckPlayerJump();
2664
2665         if(IS_PLAYER(self)) {
2666                 CheckRules_Player();
2667                 UpdateChatBubble();
2668                 if (self.impulse)
2669                         ImpulseCommands();
2670                 if (intermission_running)
2671                         return;         // intermission or finale
2672                 GetPressedKeys();
2673         }
2674
2675         /*
2676         float i;
2677         for(i = 0; i < 1000; ++i)
2678         {
2679                 vector end;
2680                 end = self.origin + '0 0 1024' + 512 * randomvec();
2681                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2682                 if(trace_fraction < 1)
2683                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2684                 {
2685                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2686                         break;
2687                 }
2688         }
2689         */
2690
2691         if(self.waypointsprite_attachedforcarrier)
2692                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2693
2694         playerdemo_write();
2695
2696         CSQCMODEL_AUTOUPDATE();
2697 }