qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         Portal_ClearAll(self);
 170
 171         if(self.alivetime)
 172         {
 173                 if(!warmup_stage)
 174                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 175                 self.alivetime = 0;
 176         }
 177
 178         if(self.vehicle)
 179                 vehicles_exit(VHEF_RELESE);
 180
 181         WaypointSprite_PlayerDead();
 182
 183         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 184                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 185
 186         if(self.killcount != -666)
 187         {
 188                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 189
 190                 if(self.just_joined == FALSE) {
 191                         LogTeamchange(self.playerid, -1, 4);
 192                 } else
 193                         self.just_joined = FALSE;
 194         }
 195
 196         PlayerScore_Clear(self); // clear scores when needed
 197
 198         accuracy_resend(self);
 199
 200         self.spectatortime = time;
 201
 202         self.classname = "observer";
 203         self.iscreature = FALSE;
 204         self.teleportable = TELEPORT_SIMPLE;
 205         self.damagedbycontents = FALSE;
 206         self.health = -666;
 207         self.takedamage = DAMAGE_NO;
 208         self.solid = SOLID_NOT;
 209         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 210         self.flags = FL_CLIENT | FL_NOTARGET;
 211         self.armorvalue = 666;
 212         self.effects = 0;
 213         self.armorvalue = autocvar_g_balance_armor_start;
 214         self.pauserotarmor_finished = 0;
 215         self.pauserothealth_finished = 0;
 216         self.pauseregen_finished = 0;
 217         self.damageforcescale = 0;
 218         self.death_time = 0;
 219         self.respawn_flags = 0;
 220         self.respawn_time = 0;
 221         self.stat_respawn_time = 0;
 222         self.alpha = 0;
 223         self.scale = 0;
 224         self.fade_time = 0;
 225         self.pain_frame = 0;
 226         self.pain_finished = 0;
 227         self.strength_finished = 0;
 228         self.invincible_finished = 0;
 229         self.superweapons_finished = 0;
 230         self.pushltime = 0;
 231         self.istypefrag = 0;
 232         self.think = func_null;
 233         self.nextthink = 0;
 234         self.hook_time = 0;
 235         self.deadflag = DEAD_NO;
 236         self.angles = spot.angles;
 237         self.angles_z = 0;
 238         self.fixangle = TRUE;
 239         self.crouch = FALSE;
 240
 241         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 242         self.prevorigin = self.origin;
 243         self.items = 0;
 244         self.weapons = '0 0 0';
 245         self.model = "";
 246         FixPlayermodel();
 247         setmodel(self, "null");
 248         self.drawonlytoclient = self;
 249
 250         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 251         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 252
 253         self.weapon = 0;
 254         self.weaponname = "";
 255         self.switchingweapon = 0;
 256         self.weaponmodel = "";
 257         self.weaponentity = world;
 258         self.exteriorweaponentity = world;
 259         self.killcount = -666;
 260         self.velocity = '0 0 0';
 261         self.avelocity = '0 0 0';
 262         self.punchangle = '0 0 0';
 263         self.punchvector = '0 0 0';
 264         self.oldvelocity = self.velocity;
 265         self.fire_endtime = -1;
 266 }
 267
 268 .float model_randomizer;
 269 void FixPlayermodel()
 270 {
 271         string defaultmodel;
 272         float defaultskin, chmdl, oldskin, n, i;
 273         vector m1, m2;
 274
 275         defaultmodel = "";
 276         defaultskin = 0;
 277         chmdl = FALSE;
 278
 279         if(autocvar_sv_defaultcharacter == 1)
 280         {
 281                 if(teamplay)
 282                 {
 283                         string s;
 284                         s = Team_ColorName_Lower(self.team);
 285                         if(s != "neutral")
 286                         {
 287                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 288                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 289                         }
 290                 }
 291
 292                 if(defaultmodel == "")
 293                 {
 294                         defaultmodel = autocvar_sv_defaultplayermodel;
 295                         defaultskin = autocvar_sv_defaultplayerskin;
 296                 }
 297
 298                 n = tokenize_console(defaultmodel);
 299                 if(n > 0)
 300                         defaultmodel = argv(floor(n * self.model_randomizer));
 301
 302                 i = strstrofs(defaultmodel, ":", 0);
 303                 if(i >= 0)
 304                 {
 305                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 306                         defaultmodel = substring(defaultmodel, 0, i);
 307                 }
 308         }
 309
 310         if(defaultmodel != "")
 311         {
 312                 if (defaultmodel != self.model)
 313                 {
 314                         m1 = self.mins;
 315                         m2 = self.maxs;
 316                         setplayermodel (self, defaultmodel);
 317                         setsize (self, m1, m2);
 318                         chmdl = TRUE;
 319                 }
 320
 321                 oldskin = self.skin;
 322                 self.skin = defaultskin;
 323         } else {
 324                 if (self.playermodel != self.model || self.playermodel == "")
 325                 {
 326                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 327                         m1 = self.mins;
 328                         m2 = self.maxs;
 329                         setplayermodel (self, self.playermodel);
 330                         setsize (self, m1, m2);
 331                         chmdl = TRUE;
 332                 }
 333
 334                 oldskin = self.skin;
 335                 self.skin = stof(self.playerskin);
 336         }
 337
 338         if(chmdl || oldskin != self.skin) // model or skin has changed
 339         {
 340                 self.species = player_getspecies(); // update species
 341                 UpdatePlayerSounds(); // update skin sounds
 342         }
 343
 344         if(!teamplay)
 345                 if(strlen(autocvar_sv_defaultplayercolors))
 346                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 347                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 348 }
 349
 350 /*
 351 =============
 352 PutClientInServer
 353
 354 Called when a client spawns in the server
 355 =============
 356 */
 357 void PutClientInServer (void)
 358 {
 359         if(IS_BOT_CLIENT(self))
 360                 self.classname = "player";
 361         else if(IS_REAL_CLIENT(self))
 362         {
 363                 msg_entity = self;
 364                 WriteByte(MSG_ONE, SVC_SETVIEW);
 365                 WriteEntity(MSG_ONE, self);
 366         }
 367
 368         // reset player keys
 369         self.itemkeys = 0;
 370
 371         MUTATOR_CALLHOOK(PutClientInServer);
 372
 373         if(gameover)
 374                 self.classname = "observer";
 375
 376         if(IS_PLAYER(self))
 377         {
 378                 entity spot, oldself;
 379                 float j;
 380
 381                 accuracy_resend(self);
 382
 383                 if(self.team < 0)
 384                         JoinBestTeam(self, FALSE, TRUE);
 385
 386                 race_PreSpawn();
 387
 388                 spot = SelectSpawnPoint (FALSE);
 389                 if(!spot)
 390                 {
 391                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 392                         return; // spawn failed
 393                 }
 394
 395                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397                 self.classname = "player";
 398                 self.wasplayer = TRUE;
 399                 self.iscreature = TRUE;
 400                 self.teleportable = TELEPORT_NORMAL;
 401                 self.damagedbycontents = TRUE;
 402                 self.movetype = MOVETYPE_WALK;
 403                 self.solid = SOLID_SLIDEBOX;
 404                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 405                 if(autocvar_g_playerclip_collisions)
 406                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 407                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 408                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 409                 self.frags = FRAGS_PLAYER;
 410                 if(INDEPENDENT_PLAYERS)
 411                         MAKE_INDEPENDENT_PLAYER(self);
 412                 self.flags = FL_CLIENT;
 413                 if(autocvar__notarget)
 414                         self.flags |= FL_NOTARGET;
 415                 self.takedamage = DAMAGE_AIM;
 416                 self.effects = 0;
 417                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 418                 self.air_finished = time + 12;
 419                 self.dmg = 2;
 420                 if(WEP_CVAR(nex, charge))
 421                 {
 422                         if(WEP_CVAR_SEC(nex, chargepool))
 423                                 self.nex_chargepool_ammo = 1;
 424                         self.nex_charge = WEP_CVAR(nex, charge_start);
 425                 }
 426
 427                 if(warmup_stage)
 428                 {
 429                         self.ammo_shells = warmup_start_ammo_shells;
 430                         self.ammo_nails = warmup_start_ammo_nails;
 431                         self.ammo_rockets = warmup_start_ammo_rockets;
 432                         self.ammo_cells = warmup_start_ammo_cells;
 433                         self.ammo_fuel = warmup_start_ammo_fuel;
 434                         self.health = warmup_start_health;
 435                         self.armorvalue = warmup_start_armorvalue;
 436                         self.weapons = warmup_start_weapons;
 437                 }
 438                 else
 439                 {
 440                         self.ammo_shells = start_ammo_shells;
 441                         self.ammo_nails = start_ammo_nails;
 442                         self.ammo_rockets = start_ammo_rockets;
 443                         self.ammo_cells = start_ammo_cells;
 444                         self.ammo_fuel = start_ammo_fuel;
 445                         self.health = start_health;
 446                         self.armorvalue = start_armorvalue;
 447                         self.weapons = start_weapons;
 448                 }
 449
 450                 if(self.weapons & WEPSET_SUPERWEAPONS)
 451                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 452                 else
 453                         self.superweapons_finished = 0;
 454
 455                 if(g_weaponarena_random)
 456                 {
 457                         if(g_weaponarena_random_with_laser)
 458                                 self.weapons &= ~WEPSET_LASER;
 459                         W_RandomWeapons(self, g_weaponarena_random);
 460                         if(g_weaponarena_random_with_laser)
 461                                 self.weapons |= WEPSET_LASER;
 462                 }
 463
 464                 self.items = start_items;
 465
 466                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 467                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 468                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 469                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 470                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 471                 //extend the pause of rotting if client was reset at the beginning of the countdown
 472                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 473                         self.spawnshieldtime += game_starttime - time;
 474                         self.pauserotarmor_finished += game_starttime - time;
 475                         self.pauserothealth_finished += game_starttime - time;
 476                         self.pauseregen_finished += game_starttime - time;
 477                 }
 478                 self.damageforcescale = 2;
 479                 self.death_time = 0;
 480                 self.respawn_flags = 0;
 481                 self.respawn_time = 0;
 482                 self.stat_respawn_time = 0;
 483                 self.scale = 0;
 484                 self.fade_time = 0;
 485                 self.pain_frame = 0;
 486                 self.pain_finished = 0;
 487                 self.strength_finished = 0;
 488                 self.invincible_finished = 0;
 489                 self.pushltime = 0;
 490                 // players have no think function
 491                 self.think = func_null;
 492                 self.nextthink = 0;
 493                 self.hook_time = 0;
 494                 self.dmg_team = 0;
 495                 self.ballistics_density = autocvar_g_ballistics_density_player;
 496
 497                 self.metertime = 0;
 498
 499                 self.deadflag = DEAD_NO;
 500
 501                 self.angles = spot.angles;
 502
 503                 self.angles_z = 0; // never spawn tilted even if the spot says to
 504                 self.fixangle = TRUE; // turn this way immediately
 505                 self.velocity = '0 0 0';
 506                 self.avelocity = '0 0 0';
 507                 self.punchangle = '0 0 0';
 508                 self.punchvector = '0 0 0';
 509                 self.oldvelocity = self.velocity;
 510                 self.fire_endtime = -1;
 511
 512                 entity spawnevent = spawn();
 513                 spawnevent.owner = self;
 514                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 515
 516                 self.model = "";
 517                 FixPlayermodel();
 518                 self.drawonlytoclient = world;
 519
 520                 self.crouch = FALSE;
 521                 self.view_ofs = PL_VIEW_OFS;
 522                 setsize (self, PL_MIN, PL_MAX);
 523                 self.spawnorigin = spot.origin;
 524                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 525                 // don't reset back to last position, even if new position is stuck in solid
 526                 self.oldorigin = self.origin;
 527                 self.prevorigin = self.origin;
 528                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 529                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 530         self.hud = HUD_NORMAL;
 531
 532                 self.event_damage = PlayerDamage;
 533
 534                 self.bot_attack = TRUE;
 535
 536                 self.statdraintime = time + 5;
 537                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 538
 539                 if(self.killcount == -666) {
 540                         PlayerScore_Clear(self);
 541                         self.killcount = 0;
 542                 }
 543
 544                 CL_SpawnWeaponentity();
 545                 self.alpha = default_player_alpha;
 546                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 547                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 548
 549                 self.speedrunning = FALSE;
 550
 551                 race_PostSpawn(spot);
 552
 553                 //stuffcmd(self, "chase_active 0");
 554                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 555
 556                 target_voicescript_clear(self);
 557
 558                 // reset fields the weapons may use
 559                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 560                 {
 561                         WEP_ACTION(j, WR_RESETPLAYER);
 562
 563                         // all weapons must be fully loaded when we spawn
 564                         entity e;
 565                         e = get_weaponinfo(j);
 566                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 567                                 self.(weapon_load[j]) = e.reloading_ammo;
 568                 }
 569
 570                 oldself = self;
 571                 self = spot;
 572                         activator = oldself;
 573                                 string s;
 574                                 s = self.target;
 575                                 self.target = string_null;
 576                                 SUB_UseTargets();
 577                                 self.target = s;
 578                         activator = world;
 579                 self = oldself;
 580
 581                 spawn_spot = spot;
 582                 MUTATOR_CALLHOOK(PlayerSpawn);
 583
 584                 if(autocvar_spawn_debug)
 585                 {
 586                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 587                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 588                 }
 589
 590                 self.switchweapon = w_getbestweapon(self);
 591                 self.cnt = -1; // W_LastWeapon will not complain
 592                 self.weapon = 0;
 593                 self.weaponname = "";
 594                 self.switchingweapon = 0;
 595
 596                 if(!warmup_stage)
 597                         if(!self.alivetime)
 598                                 self.alivetime = time;
 599
 600                 antilag_clear(self);
 601         }
 602         else if(IS_OBSERVER(self))
 603         {
 604                 PutObserverInServer ();
 605         }
 606 }
 607
 608 .float ebouncefactor, ebouncestop; // electro's values
 609 // TODO do we need all these fields, or should we stop autodetecting runtime
 610 // changes and just have a console command to update this?
 611 float ClientInit_SendEntity(entity to, float sf)
 612 {
 613         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 614         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 615         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 616         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 617         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 618         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 619         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 620         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 621         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 622         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 627
 628         if(sv_foginterval && world.fog != "")
 629                 WriteString(MSG_ENTITY, world.fog);
 630         else
 631                 WriteString(MSG_ENTITY, "");
 632         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 633         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 634         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 635         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 636         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 637         WriteByte(MSG_ENTITY, WEP_CVAR(nex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 638         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 639         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 640         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 641         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 642         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 643         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 644         return TRUE;
 645 }
 646
 647 void ClientInit_CheckUpdate()
 648 {
 649         self.nextthink = time;
 650         if(self.count != autocvar_g_balance_armor_blockpercent)
 651         {
 652                 self.count = autocvar_g_balance_armor_blockpercent;
 653                 self.SendFlags |= 1;
 654         }
 655         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 656         {
 657                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 658                 self.SendFlags |= 1;
 659         }
 660         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 661         {
 662                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 663                 self.SendFlags |= 1;
 664         }
 665         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 666         {
 667                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 668                 self.SendFlags |= 1;
 669         }
 670         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 671         {
 672                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 673                 self.SendFlags |= 1;
 674         }
 675 }
 676
 677 void ClientInit_Spawn()
 678 {
 679         entity o;
 680         entity e;
 681         e = spawn();
 682         e.classname = "clientinit";
 683         e.think = ClientInit_CheckUpdate;
 684         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 685
 686         o = self;
 687         self = e;
 688         ClientInit_CheckUpdate();
 689         self = o;
 690 }
 691
 692 /*
 693 =============
 694 SetNewParms
 695 =============
 696 */
 697 void SetNewParms (void)
 698 {
 699         // initialize parms for a new player
 700         parm1 = -(86400 * 366);
 701 }
 702
 703 /*
 704 =============
 705 SetChangeParms
 706 =============
 707 */
 708 void SetChangeParms (void)
 709 {
 710         // save parms for level change
 711         parm1 = self.parm_idlesince - time;
 712 }
 713
 714 /*
 715 =============
 716 DecodeLevelParms
 717 =============
 718 */
 719 void DecodeLevelParms (void)
 720 {
 721         // load parms
 722         self.parm_idlesince = parm1;
 723         if(self.parm_idlesince == -(86400 * 366))
 724                 self.parm_idlesince = time;
 725
 726         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 727         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 728 }
 729
 730 /*
 731 =============
 732 ClientKill
 733
 734 Called when a client types 'kill' in the console
 735 =============
 736 */
 737
 738 .float clientkill_nexttime;
 739 void ClientKill_Now_TeamChange()
 740 {
 741         if(self.killindicator_teamchange == -1)
 742         {
 743                 JoinBestTeam( self, FALSE, TRUE );
 744         }
 745         else if(self.killindicator_teamchange == -2)
 746         {
 747                 if(blockSpectators)
 748                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 749                 PutObserverInServer();
 750         }
 751         else
 752                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 753         self.killindicator_teamchange = 0;
 754 }
 755
 756 void ClientKill_Now()
 757 {
 758         if(self.vehicle)
 759         {
 760             vehicles_exit(VHEF_RELESE);
 761             if(!self.killindicator_teamchange)
 762             {
 763             self.vehicle_health = -1;
 764             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 765             }
 766         }
 767
 768         if(self.killindicator && !wasfreed(self.killindicator))
 769                 remove(self.killindicator);
 770
 771         self.killindicator = world;
 772
 773         if(self.killindicator_teamchange)
 774                 ClientKill_Now_TeamChange();
 775
 776         // in any case:
 777         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 778
 779         // now I am sure the player IS dead
 780 }
 781 void KillIndicator_Think()
 782 {
 783         if (gameover)
 784         {
 785                 self.owner.killindicator = world;
 786                 remove(self);
 787                 return;
 788         }
 789
 790         if (self.owner.alpha < 0 && !self.owner.vehicle)
 791         {
 792                 self.owner.killindicator = world;
 793                 remove(self);
 794                 return;
 795         }
 796
 797         if(self.cnt <= 0)
 798         {
 799                 self = self.owner;
 800                 ClientKill_Now(); // no oldself needed
 801                 return;
 802         }
 803     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 804     {
 805         self.nextthink = time + 1;
 806         self.cnt -= 1;
 807     }
 808         else
 809         {
 810                 if(self.cnt <= 10)
 811                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 812                 if(IS_REAL_CLIENT(self.owner))
 813                 {
 814                         if(self.cnt <= 10)
 815                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 816                 }
 817                 self.nextthink = time + 1;
 818                 self.cnt -= 1;
 819         }
 820 }
 821
 822 float clientkilltime;
 823 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 824 {
 825         float killtime;
 826         float starttime;
 827         entity e;
 828
 829         if (gameover)
 830                 return;
 831
 832         killtime = autocvar_g_balance_kill_delay;
 833
 834         if(g_race_qualifying || g_cts)
 835                 killtime = 0;
 836
 837     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 838     {
 839                 remove(self.killindicator);
 840                 self.killindicator = world;
 841
 842         ClientKill_Now(); // allow instant kill in this case
 843         return;
 844     }
 845
 846         self.killindicator_teamchange = targetteam;
 847
 848     if(!self.killindicator)
 849         {
 850                 if(self.deadflag == DEAD_NO)
 851                 {
 852                         killtime = max(killtime, self.clientkill_nexttime - time);
 853                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 854                 }
 855
 856                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 857                 {
 858                         ClientKill_Now();
 859                 }
 860                 else
 861                 {
 862                         starttime = max(time, clientkilltime);
 863
 864                         self.killindicator = spawn();
 865                         self.killindicator.owner = self;
 866                         self.killindicator.scale = 0.5;
 867                         setattachment(self.killindicator, self, "");
 868                         setorigin(self.killindicator, '0 0 52');
 869                         self.killindicator.think = KillIndicator_Think;
 870                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 871                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 872                         self.killindicator.cnt = ceil(killtime);
 873                         self.killindicator.count = bound(0, ceil(killtime), 10);
 874                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 875
 876                         for(e = world; (e = find(e, classname, "body")) != world; )
 877                         {
 878                                 if(e.enemy != self)
 879                                         continue;
 880                                 e.killindicator = spawn();
 881                                 e.killindicator.owner = e;
 882                                 e.killindicator.scale = 0.5;
 883                                 setattachment(e.killindicator, e, "");
 884                                 setorigin(e.killindicator, '0 0 52');
 885                                 e.killindicator.think = KillIndicator_Think;
 886                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 887                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 888                                 e.killindicator.cnt = ceil(killtime);
 889                         }
 890                         self.lip = 0;
 891                 }
 892         }
 893         if(self.killindicator)
 894         {
 895                 if(targetteam == 0) // just die
 896                 {
 897                         self.killindicator.colormod = '0 0 0';
 898                         if(IS_REAL_CLIENT(self))
 899                         if(self.killindicator.cnt > 0)
 900                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 901                 }
 902                 else if(targetteam == -1) // auto
 903                 {
 904                         self.killindicator.colormod = '0 1 0';
 905                         if(IS_REAL_CLIENT(self))
 906                         if(self.killindicator.cnt > 0)
 907                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 908                 }
 909                 else if(targetteam == -2) // spectate
 910                 {
 911                         self.killindicator.colormod = '0.5 0.5 0.5';
 912                         if(IS_REAL_CLIENT(self))
 913                         if(self.killindicator.cnt > 0)
 914                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 915                 }
 916                 else
 917                 {
 918                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 919                         if(IS_REAL_CLIENT(self))
 920                         if(self.killindicator.cnt > 0)
 921                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 922                 }
 923         }
 924
 925 }
 926
 927 void ClientKill (void)
 928 {
 929         if(gameover) return;
 930         if(self.player_blocked) return;
 931         if(self.freezetag_frozen) return;
 932
 933         ClientKill_TeamChange(0);
 934 }
 935
 936 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 937 {
 938     e.killindicator = spawn();
 939     e.killindicator.owner = e;
 940     e.killindicator.think = KillIndicator_Think;
 941     e.killindicator.nextthink = time + (e.lip) * 0.05;
 942     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 943     e.killindicator.health = 1; // this is used to indicate that it should be silent
 944     e.lip = 0;
 945 }
 946
 947 void FixClientCvars(entity e)
 948 {
 949         // send prediction settings to the client
 950         stuffcmd(e, "\nin_bindmap 0 0\n");
 951         if(g_race || g_cts)
 952                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 953         if(autocvar_g_antilag == 3) // client side hitscan
 954                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 955         if(autocvar_sv_gentle)
 956                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 957         /*
 958          * we no longer need to stuff this. Remove this comment block if you feel
 959          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 960         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 961         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 962         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 963         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 964         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 965         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 966         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 967         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 968         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 969         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 970         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 971         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 972         stuffcmd(e, "cl_movement_edgefriction 1\n");
 973          */
 974 }
 975
 976 float PlayerInIDList(entity p, string idlist)
 977 {
 978         float n, i;
 979         string s;
 980
 981         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 982         if not(p.crypto_idfp)
 983                 return 0;
 984
 985         // this function allows abbreviated player IDs too!
 986         n = tokenize_console(idlist);
 987         for(i = 0; i < n; ++i)
 988         {
 989                 s = argv(i);
 990                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 991                         return 1;
 992         }
 993
 994         return 0;
 995 }
 996
 997 /*
 998 =============
 999 ClientConnect
1000
1001 Called when a client connects to the server
1002 =============
1003 */
1004 void DecodeLevelParms (void);
1005 //void dom_player_join_team(entity pl);
1006 void set_dom_state(entity e);
1007 void ClientConnect (void)
1008 {
1009         float t;
1010
1011         if(IS_CLIENT(self))
1012         {
1013                 print("Warning: ClientConnect, but already connected!\n");
1014                 return;
1015         }
1016
1017         if(Ban_MaybeEnforceBanOnce(self))
1018                 return;
1019
1020         DecodeLevelParms();
1021
1022 #ifdef WATERMARK
1023         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1024 #endif
1025
1026         self.classname = "player_joining";
1027
1028         self.flags = FL_CLIENT;
1029         self.version_nagtime = time + 10 + random() * 10;
1030
1031         if(player_count<0)
1032         {
1033                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1034                 player_count = 0;
1035         }
1036
1037         PlayerScore_Attach(self);
1038         ClientData_Attach();
1039         accuracy_init(self);
1040
1041         bot_clientconnect();
1042
1043         playerdemo_init();
1044
1045         anticheat_init();
1046
1047         race_PreSpawnObserver();
1048
1049         // identify the right forced team
1050         if(autocvar_g_campaign)
1051         {
1052                 if(IS_REAL_CLIENT(self)) // only players, not bots
1053                 {
1054                         switch(autocvar_g_campaign_forceteam)
1055                         {
1056                                 case 1: self.team_forced = NUM_TEAM_1; break;
1057                                 case 2: self.team_forced = NUM_TEAM_2; break;
1058                                 case 3: self.team_forced = NUM_TEAM_3; break;
1059                                 case 4: self.team_forced = NUM_TEAM_4; break;
1060                                 default: self.team_forced = 0;
1061                         }
1062                 }
1063         }
1064         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1065                 self.team_forced = NUM_TEAM_1;
1066         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1067                 self.team_forced = NUM_TEAM_2;
1068         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1069                 self.team_forced = NUM_TEAM_3;
1070         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1071                 self.team_forced = NUM_TEAM_4;
1072         else if(autocvar_g_forced_team_otherwise == "red")
1073                 self.team_forced = NUM_TEAM_1;
1074         else if(autocvar_g_forced_team_otherwise == "blue")
1075                 self.team_forced = NUM_TEAM_2;
1076         else if(autocvar_g_forced_team_otherwise == "yellow")
1077                 self.team_forced = NUM_TEAM_3;
1078         else if(autocvar_g_forced_team_otherwise == "pink")
1079                 self.team_forced = NUM_TEAM_4;
1080         else if(autocvar_g_forced_team_otherwise == "spectate")
1081                 self.team_forced = -1;
1082         else if(autocvar_g_forced_team_otherwise == "spectator")
1083                 self.team_forced = -1;
1084         else
1085                 self.team_forced = 0;
1086
1087         if(!teamplay)
1088                 if(self.team_forced > 0)
1089                         self.team_forced = 0;
1090
1091         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1092
1093         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1094                 self.classname = "observer";
1095         } else {
1096                 if(teamplay)
1097                 {
1098                         if(autocvar_g_balance_teams)
1099                         {
1100                                 self.classname = "player";
1101                                 campaign_bots_may_start = 1;
1102                         }
1103                         else
1104                         {
1105                                 self.classname = "observer"; // do it anyway
1106                         }
1107                 }
1108                 else
1109                 {
1110                         self.classname = "player";
1111                         campaign_bots_may_start = 1;
1112                 }
1113         }
1114
1115         self.playerid = (playerid_last = playerid_last + 1);
1116
1117         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1118
1119     if(IS_BOT_CLIENT(self))
1120         PlayerStats_AddPlayer(self);
1121
1122         if(autocvar_sv_eventlog)
1123                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1124
1125         LogTeamchange(self.playerid, self.team, 1);
1126
1127         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1128
1129         self.netname_previous = strzone(self.netname);
1130
1131         if(IS_PLAYER(self) && teamplay)
1132                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1133         else
1134                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1135
1136         stuffcmd(self, strcat(clientstuff, "\n"));
1137         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1138
1139         FixClientCvars(self);
1140
1141         // spawnfunc_waypoint sprites
1142         WaypointSprite_InitClient(self);
1143
1144         // Wazat's grappling hook
1145         SetGrappleHookBindings();
1146
1147         // get version info from player
1148         stuffcmd(self, "cmd clientversion $gameversion\n");
1149
1150         // get other cvars from player
1151         GetCvars(0);
1152
1153         // notify about available teams
1154         if(teamplay)
1155         {
1156                 CheckAllowedTeams(self);
1157                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1158                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1159         }
1160         else
1161                 stuffcmd(self, "set _teams_available 0\n");
1162
1163         attach_entcs();
1164
1165         bot_relinkplayerlist();
1166
1167         self.spectatortime = time;
1168         if(blockSpectators)
1169         {
1170                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1171         }
1172
1173         self.jointime = time;
1174         self.allowed_timeouts = autocvar_sv_timeout_number;
1175
1176         if(IS_REAL_CLIENT(self))
1177         {
1178                 if(!autocvar_g_campaign)
1179                 {
1180                         self.motd_actived_time = -1;
1181                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1182                 }
1183
1184                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1185                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1186         }
1187
1188         if(!sv_foginterval && world.fog != "")
1189                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1190
1191         W_HitPlotOpen(self);
1192
1193         if(g_race || g_cts) {
1194                 string rr;
1195                 if(g_cts)
1196                         rr = CTS_RECORD;
1197                 else
1198                         rr = RACE_RECORD;
1199
1200                 msg_entity = self;
1201                 race_send_recordtime(MSG_ONE);
1202                 race_send_speedaward(MSG_ONE);
1203
1204                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1205                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1206                 race_send_speedaward_alltimebest(MSG_ONE);
1207
1208                 float i;
1209                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1210                         race_SendRankings(i, 0, 0, MSG_ONE);
1211                 }
1212         }
1213         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1214                 send_CSQC_teamnagger();
1215
1216         CheatInitClient();
1217
1218         CSQCMODEL_AUTOINIT();
1219
1220         self.model_randomizer = random();
1221
1222         if(IS_REAL_CLIENT(self))
1223                 sv_notice_join();
1224
1225         MUTATOR_CALLHOOK(ClientConnect);
1226 }
1227 /*
1228 =============
1229 ClientDisconnect
1230
1231 Called when a client disconnects from the server
1232 =============
1233 */
1234 .entity chatbubbleentity;
1235 void ReadyCount();
1236 void ClientDisconnect (void)
1237 {
1238         if(self.vehicle)
1239             vehicles_exit(VHEF_RELESE);
1240
1241         if not(IS_CLIENT(self))
1242         {
1243                 print("Warning: ClientDisconnect without ClientConnect\n");
1244                 return;
1245         }
1246
1247         PlayerStats_AddGlobalInfo(self);
1248
1249         CheatShutdownClient();
1250
1251         W_HitPlotClose(self);
1252
1253         anticheat_report();
1254         anticheat_shutdown();
1255
1256         playerdemo_shutdown();
1257
1258         bot_clientdisconnect();
1259
1260         if(self.entcs)
1261                 detach_entcs();
1262
1263         if(autocvar_sv_eventlog)
1264                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1265
1266         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1267
1268         MUTATOR_CALLHOOK(ClientDisconnect);
1269
1270         Portal_ClearAll(self);
1271
1272         RemoveGrapplingHook(self);
1273
1274         // Here, everything has been done that requires this player to be a client.
1275
1276         self.flags &= ~FL_CLIENT;
1277
1278         if (self.chatbubbleentity)
1279                 remove (self.chatbubbleentity);
1280
1281         if (self.killindicator)
1282                 remove (self.killindicator);
1283
1284         WaypointSprite_PlayerGone();
1285
1286         bot_relinkplayerlist();
1287
1288         accuracy_free(self);
1289         ClientData_Detach();
1290         PlayerScore_Detach(self);
1291
1292         if(self.netname_previous)
1293                 strunzone(self.netname_previous);
1294         if(self.clientstatus)
1295                 strunzone(self.clientstatus);
1296         if(self.weaponorder_byimpulse)
1297                 strunzone(self.weaponorder_byimpulse);
1298
1299         ClearPlayerSounds();
1300
1301         if(self.personal)
1302                 remove(self.personal);
1303
1304         self.playerid = 0;
1305         ReadyCount();
1306
1307         // free cvars
1308         GetCvars(-1);
1309 }
1310
1311 .float BUTTON_CHAT;
1312 void ChatBubbleThink()
1313 {
1314         self.nextthink = time;
1315         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1316         {
1317                 if(self.owner) // but why can that ever be world?
1318                         self.owner.chatbubbleentity = world;
1319                 remove(self);
1320                 return;
1321         }
1322         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1323 #ifdef TETRIS
1324                 || self.owner.tetris_on
1325 #endif
1326         )
1327                 self.model = self.mdl;
1328         else
1329                 self.model = "";
1330 }
1331
1332 void UpdateChatBubble()
1333 {
1334         if (self.alpha < 0)
1335                 return;
1336         // spawn a chatbubble entity if needed
1337         if (!self.chatbubbleentity)
1338         {
1339                 self.chatbubbleentity = spawn();
1340                 self.chatbubbleentity.owner = self;
1341                 self.chatbubbleentity.exteriormodeltoclient = self;
1342                 self.chatbubbleentity.think = ChatBubbleThink;
1343                 self.chatbubbleentity.nextthink = time;
1344                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1345                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1346                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1347                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1348                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1349                 self.chatbubbleentity.model = "";
1350                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1351         }
1352 }
1353
1354
1355 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1356 // added to the model skins
1357 /*void UpdateColorModHack()
1358 {
1359         float c;
1360         c = self.clientcolors & 15;
1361         // LordHavoc: only bothering to support white, green, red, yellow, blue
1362              if (!teamplay) self.colormod = '0 0 0';
1363         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1364         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1365         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1366         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1367         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1368         else self.colormod = '1 1 1';
1369 }*/
1370
1371 void respawn(void)
1372 {
1373         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1374         {
1375                 self.solid = SOLID_NOT;
1376                 self.takedamage = DAMAGE_NO;
1377                 self.movetype = MOVETYPE_FLY;
1378                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1379                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1380                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1381                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1382                 if(autocvar_g_respawn_ghosts_maxtime)
1383                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1384         }
1385
1386         CopyBody(1);
1387
1388         self.effects |= EF_NODRAW; // prevent another CopyBody
1389         PutClientInServer();
1390 }
1391
1392 void play_countdown(float finished, string samp)
1393 {
1394         if(IS_REAL_CLIENT(self))
1395                 if(floor(finished - time - frametime) != floor(finished - time))
1396                         if(finished - time < 6)
1397                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1398 }
1399
1400 void player_powerups (void)
1401 {
1402         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1403         olditems = self.items;
1404
1405         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1406                 self.modelflags |= MF_ROCKET;
1407         else
1408                 self.modelflags &= ~MF_ROCKET;
1409
1410         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1411
1412         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1413                 return;
1414
1415         Fire_ApplyDamage(self);
1416         Fire_ApplyEffect(self);
1417
1418         if not(g_minstagib)
1419         {
1420                 if (self.items & IT_STRENGTH)
1421                 {
1422                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1423                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1424                         if (time > self.strength_finished)
1425                         {
1426                                 self.items = self.items - (self.items & IT_STRENGTH);
1427                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1428                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1429                         }
1430                 }
1431                 else
1432                 {
1433                         if (time < self.strength_finished)
1434                         {
1435                                 self.items = self.items | IT_STRENGTH;
1436                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1437                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1438                         }
1439                 }
1440                 if (self.items & IT_INVINCIBLE)
1441                 {
1442                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1443                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1444                         if (time > self.invincible_finished)
1445                         {
1446                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1447                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1448                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1449                         }
1450                 }
1451                 else
1452                 {
1453                         if (time < self.invincible_finished)
1454                         {
1455                                 self.items = self.items | IT_INVINCIBLE;
1456                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1457                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1458                         }
1459                 }
1460                 if (self.items & IT_SUPERWEAPON)
1461                 {
1462                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1463                         {
1464                                 self.superweapons_finished = 0;
1465                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1466                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1467                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1468                         }
1469                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1470                         {
1471                                 // don't let them run out
1472                         }
1473                         else
1474                         {
1475                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1476                                 if (time > self.superweapons_finished)
1477                                 {
1478                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1479                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1480                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1481                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1482                                 }
1483                         }
1484                 }
1485                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1486                 {
1487                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1488                         {
1489                                 self.items = self.items | IT_SUPERWEAPON;
1490                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1491                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1492                         }
1493                         else
1494                         {
1495                                 self.superweapons_finished = 0;
1496                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1497                         }
1498                 }
1499                 else
1500                 {
1501                         self.superweapons_finished = 0;
1502                 }
1503         }
1504
1505         if(autocvar_g_nodepthtestplayers)
1506                 self.effects = self.effects | EF_NODEPTHTEST;
1507
1508         if(autocvar_g_fullbrightplayers)
1509                 self.effects = self.effects | EF_FULLBRIGHT;
1510
1511         if (time >= game_starttime)
1512         if (time < self.spawnshieldtime)
1513                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1514
1515         MUTATOR_CALLHOOK(PlayerPowerups);
1516 }
1517
1518 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1519 {
1520         if(current > stable)
1521                 return current;
1522         else if(current > stable - 0.25) // when close enough, "snap"
1523                 return stable;
1524         else
1525                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1526 }
1527
1528 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1529 {
1530         if(current < stable)
1531                 return current;
1532         else if(current < stable + 0.25) // when close enough, "snap"
1533                 return stable;
1534         else
1535                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1536 }
1537
1538 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1539 {
1540         if(current > rotstable)
1541         {
1542                 if(rotframetime > 0)
1543                 {
1544                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1545                         current = max(rotstable, current - rotlinear * rotframetime);
1546                 }
1547         }
1548         else if(current < regenstable)
1549         {
1550                 if(regenframetime > 0)
1551                 {
1552                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1553                         current = min(regenstable, current + regenlinear * regenframetime);
1554                 }
1555         }
1556
1557         if(current > limit)
1558                 current = limit;
1559
1560         return current;
1561 }
1562
1563 void player_regen (void)
1564 {
1565         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1566         maxh = autocvar_g_balance_health_rotstable;
1567         maxa = autocvar_g_balance_armor_rotstable;
1568         maxf = autocvar_g_balance_fuel_rotstable;
1569         minh = autocvar_g_balance_health_regenstable;
1570         mina = autocvar_g_balance_armor_regenstable;
1571         minf = autocvar_g_balance_fuel_regenstable;
1572         limith = autocvar_g_balance_health_limit;
1573         limita = autocvar_g_balance_armor_limit;
1574         limitf = autocvar_g_balance_fuel_limit;
1575
1576         max_mod = regen_mod = rot_mod = limit_mod = 1;
1577
1578         maxh = maxh * max_mod;
1579         //maxa = maxa * max_mod;
1580         //maxf = maxf * max_mod;
1581         minh = minh * max_mod;
1582         //mina = mina * max_mod;
1583         //minf = minf * max_mod;
1584         limith = limith * limit_mod;
1585         limita = limita * limit_mod;
1586         //limitf = limitf * limit_mod;
1587
1588         if(g_ca)
1589                 rot_mod = 0;
1590
1591         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1592         {
1593                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1594                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1595
1596                 // if player rotted to death...  die!
1597                 if(self.health < 1)
1598                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1599         }
1600
1601         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1602                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1603 }
1604
1605 float zoomstate_set;
1606 void SetZoomState(float z)
1607 {
1608         if(z != self.zoomstate)
1609         {
1610                 self.zoomstate = z;
1611                 ClientData_Touch(self);
1612         }
1613         zoomstate_set = 1;
1614 }
1615
1616 void GetPressedKeys(void) {
1617         MUTATOR_CALLHOOK(GetPressedKeys);
1618         if (self.movement_x > 0) // get if movement keys are pressed
1619         {       // forward key pressed
1620                 self.pressedkeys |= KEY_FORWARD;
1621                 self.pressedkeys &= ~KEY_BACKWARD;
1622         }
1623         else if (self.movement_x < 0)
1624         {       // backward key pressed
1625                 self.pressedkeys |= KEY_BACKWARD;
1626                 self.pressedkeys &= ~KEY_FORWARD;
1627         }
1628         else
1629         {       // no x input
1630                 self.pressedkeys &= ~KEY_FORWARD;
1631                 self.pressedkeys &= ~KEY_BACKWARD;
1632         }
1633
1634         if (self.movement_y > 0)
1635         {       // right key pressed
1636                 self.pressedkeys |= KEY_RIGHT;
1637                 self.pressedkeys &= ~KEY_LEFT;
1638         }
1639         else if (self.movement_y < 0)
1640         {       // left key pressed
1641                 self.pressedkeys |= KEY_LEFT;
1642                 self.pressedkeys &= ~KEY_RIGHT;
1643         }
1644         else
1645         {       // no y input
1646                 self.pressedkeys &= ~KEY_RIGHT;
1647                 self.pressedkeys &= ~KEY_LEFT;
1648         }
1649
1650         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1651                 self.pressedkeys |= KEY_JUMP;
1652         else
1653                 self.pressedkeys &= ~KEY_JUMP;
1654         if (self.BUTTON_CROUCH)
1655                 self.pressedkeys |= KEY_CROUCH;
1656         else
1657                 self.pressedkeys &= ~KEY_CROUCH;
1658
1659         if (self.BUTTON_ATCK)
1660                 self.pressedkeys |= KEY_ATCK;
1661         else
1662                 self.pressedkeys &= ~KEY_ATCK;
1663         if (self.BUTTON_ATCK2)
1664                 self.pressedkeys |= KEY_ATCK2;
1665         else
1666                 self.pressedkeys &= ~KEY_ATCK2;
1667 }
1668
1669 /*
1670 ======================
1671 spectate mode routines
1672 ======================
1673 */
1674
1675 void SpectateCopy(entity spectatee) {
1676         other = spectatee;
1677         MUTATOR_CALLHOOK(SpectateCopy);
1678         self.armortype = spectatee.armortype;
1679         self.armorvalue = spectatee.armorvalue;
1680         self.ammo_cells = spectatee.ammo_cells;
1681         self.ammo_shells = spectatee.ammo_shells;
1682         self.ammo_nails = spectatee.ammo_nails;
1683         self.ammo_rockets = spectatee.ammo_rockets;
1684         self.ammo_fuel = spectatee.ammo_fuel;
1685         self.clip_load = spectatee.clip_load;
1686         self.clip_size = spectatee.clip_size;
1687         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1688         self.health = spectatee.health;
1689         self.impulse = 0;
1690         self.items = spectatee.items;
1691         self.last_pickup = spectatee.last_pickup;
1692         self.hit_time = spectatee.hit_time;
1693         self.metertime = spectatee.metertime;
1694         self.strength_finished = spectatee.strength_finished;
1695         self.invincible_finished = spectatee.invincible_finished;
1696         self.pressedkeys = spectatee.pressedkeys;
1697         self.weapons = spectatee.weapons;
1698         self.switchweapon = spectatee.switchweapon;
1699         self.switchingweapon = spectatee.switchingweapon;
1700         self.weapon = spectatee.weapon;
1701         self.nex_charge = spectatee.nex_charge;
1702         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1703         self.hagar_load = spectatee.hagar_load;
1704         self.minelayer_mines = spectatee.minelayer_mines;
1705         self.punchangle = spectatee.punchangle;
1706         self.view_ofs = spectatee.view_ofs;
1707         self.velocity = spectatee.velocity;
1708         self.dmg_take = spectatee.dmg_take;
1709         self.dmg_save = spectatee.dmg_save;
1710         self.dmg_inflictor = spectatee.dmg_inflictor;
1711         self.v_angle = spectatee.v_angle;
1712         self.angles = spectatee.v_angle;
1713         if(!self.BUTTON_USE)
1714                 self.fixangle = TRUE;
1715         setorigin(self, spectatee.origin);
1716         setsize(self, spectatee.mins, spectatee.maxs);
1717         SetZoomState(spectatee.zoomstate);
1718
1719     anticheat_spectatecopy(spectatee);
1720         self.hud = spectatee.hud;
1721         if(spectatee.vehicle)
1722     {
1723         self.fixangle = FALSE;
1724         //self.velocity = spectatee.vehicle.velocity;
1725         self.vehicle_health = spectatee.vehicle_health;
1726         self.vehicle_shield = spectatee.vehicle_shield;
1727         self.vehicle_energy = spectatee.vehicle_energy;
1728         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1729         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1730         self.vehicle_reload1 = spectatee.vehicle_reload1;
1731         self.vehicle_reload2 = spectatee.vehicle_reload2;
1732
1733         msg_entity = self;
1734
1735         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1736             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1737             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1738             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1739
1740         //WriteByte (MSG_ONE, SVC_SETVIEW);
1741         //    WriteEntity(MSG_ONE, self);
1742         //makevectors(spectatee.v_angle);
1743         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1744     }
1745 }
1746
1747 float SpectateUpdate() {
1748         if(!self.enemy)
1749             return 0;
1750
1751         if (self == self.enemy)
1752                 return 0;
1753
1754         if not(IS_PLAYER(self.enemy))
1755                 return 0;
1756
1757         SpectateCopy(self.enemy);
1758
1759         return 1;
1760 }
1761
1762
1763 float SpectateSet()
1764 {
1765         if(self.enemy.classname != "player")
1766                 return FALSE;
1767         /*if(self.enemy.vehicle)
1768         {
1769
1770                 msg_entity = self;
1771                 WriteByte(MSG_ONE, SVC_SETVIEW);
1772                 WriteEntity(MSG_ONE, self.enemy);
1773                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1774
1775                 self.movetype = MOVETYPE_NONE;
1776                 accuracy_resend(self);
1777         }
1778         else
1779         {*/
1780                 msg_entity = self;
1781                 WriteByte(MSG_ONE, SVC_SETVIEW);
1782                 WriteEntity(MSG_ONE, self.enemy);
1783                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1784                 self.movetype = MOVETYPE_NONE;
1785                 accuracy_resend(self);
1786
1787                 if(!SpectateUpdate())
1788                         PutObserverInServer();
1789         //}
1790         return TRUE;
1791 }
1792
1793 float Spectate(entity pl)
1794 {
1795         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1796         if(pl.team != self.team)
1797                 return 0;
1798
1799         self.enemy = pl;
1800         return SpectateSet();
1801 }
1802
1803 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1804 entity CA_SpectateNext(entity start) {
1805         if (start.team == self.team) {
1806                 return start;
1807         }
1808
1809         other = start;
1810         // continue from current player
1811         while(other && other.team != self.team) {
1812                 other = find(other, classname, "player");
1813         }
1814
1815         if (!other) {
1816                 // restart from begining
1817                 other = find(other, classname, "player");
1818                 while(other && other.team != self.team) {
1819                         other = find(other, classname, "player");
1820                 }
1821         }
1822
1823         return other;
1824 }
1825
1826 float SpectateNext()
1827 {
1828         other = find(self.enemy, classname, "player");
1829
1830         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1831                 // CA and ca players when spectating enemies is forbidden
1832                 other = CA_SpectateNext(other);
1833         } else {
1834                 // other modes and ca spectators or spectating enemies is allowed
1835                 if (!other)
1836                         other = find(other, classname, "player");
1837         }
1838
1839         if (other)
1840                 self.enemy = other;
1841
1842         return SpectateSet();
1843 }
1844
1845 float SpectatePrev()
1846 {
1847         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1848         other = findchain(classname, "player");
1849         if not(other) // no player
1850                 return FALSE;
1851
1852         entity first = other;
1853         // skip players until current spectated player
1854         if(self.enemy)
1855         while(other && other != self.enemy)
1856                 other = other.chain;
1857
1858         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1859         {
1860                 do { other = other.chain; }
1861                 while(other && other.team != self.team);
1862
1863                 if not(other)
1864                 {
1865                         other = first;
1866                         while(other.team != self.team)
1867                                 other = other.chain;
1868                         if(other == self.enemy)
1869                                 return TRUE;
1870                 }
1871         }
1872         else
1873         {
1874                 if(other.chain)
1875                         other = other.chain;
1876                 else
1877                         other = first;
1878         }
1879         self.enemy = other;
1880         return SpectateSet();
1881 }
1882
1883 /*
1884 =============
1885 ShowRespawnCountdown()
1886
1887 Update a respawn countdown display.
1888 =============
1889 */
1890 void ShowRespawnCountdown()
1891 {
1892         float number;
1893         if(self.deadflag == DEAD_NO) // just respawned?
1894                 return;
1895         else
1896         {
1897                 number = ceil(self.respawn_time - time);
1898                 if(number <= 0)
1899                         return;
1900                 if(number <= self.respawn_countdown)
1901                 {
1902                         self.respawn_countdown = number - 1;
1903                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1904                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1905                 }
1906         }
1907 }
1908
1909 void LeaveSpectatorMode()
1910 {
1911         if(self.caplayer)
1912                 return;
1913         if(nJoinAllowed(self))
1914         {
1915                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1916                 {
1917                         self.classname = "player";
1918
1919                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1920                                 { JoinBestTeam(self, FALSE, TRUE); }
1921
1922                         if(autocvar_g_campaign)
1923                                 { campaign_bots_may_start = 1; }
1924
1925                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1926
1927                         PutClientInServer();
1928
1929                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1930                 }
1931                 else
1932                         stuffcmd(self, "menu_showteamselect\n");
1933         }
1934         else
1935         {
1936                 // Player may not join because g_maxplayers is set
1937                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1938         }
1939 }
1940
1941 /**
1942  * Determines whether the player is allowed to join. This depends on cvar
1943  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1944  * it checks whether the number of currently playing players exceeds g_maxplayers.
1945  * @return int number of free slots for players, 0 if none
1946  */
1947 float nJoinAllowed(entity ignore) {
1948         if(!ignore)
1949         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1950         // so report 0 free slots if restricted
1951         {
1952                 if(autocvar_g_forced_team_otherwise == "spectate")
1953                         return 0;
1954                 if(autocvar_g_forced_team_otherwise == "spectator")
1955                         return 0;
1956         }
1957
1958         if(self.team_forced < 0)
1959                 return 0; // forced spectators can never join
1960
1961         // TODO simplify this
1962         entity e;
1963         float totalClients = 0;
1964         FOR_EACH_CLIENT(e)
1965                 if(e != ignore)
1966                         totalClients += 1;
1967
1968         if (!autocvar_g_maxplayers)
1969                 return maxclients - totalClients;
1970
1971         float currentlyPlaying = 0;
1972         FOR_EACH_REALCLIENT(e)
1973                 if(IS_PLAYER(e) || e.caplayer == 1)
1974                         currentlyPlaying += 1;
1975
1976         if(currentlyPlaying < autocvar_g_maxplayers)
1977                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1978
1979         return 0;
1980 }
1981
1982 /**
1983  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1984  * g_maxplayers_spectator_blocktime seconds
1985  */
1986 void checkSpectatorBlock() {
1987         if(IS_SPEC(self) || IS_OBSERVER(self)) {
1988                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1989                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1990                         dropclient(self);
1991                 }
1992         }
1993 }
1994
1995 void PrintWelcomeMessage()
1996 {
1997         if(self.motd_actived_time == 0)
1998         {
1999                 if (autocvar_g_campaign) {
2000                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2001                                 self.motd_actived_time = time;
2002                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2003                         }
2004                 } else {
2005                         if (self.BUTTON_INFO) {
2006                                 self.motd_actived_time = time;
2007                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2008                         }
2009                 }
2010         }
2011         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2012         {
2013                 if (autocvar_g_campaign) {
2014                         if (self.BUTTON_INFO)
2015                                 self.motd_actived_time = time;
2016                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2017                                 self.motd_actived_time = 0;
2018                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2019                         }
2020                 } else {
2021                         if (self.BUTTON_INFO)
2022                                 self.motd_actived_time = time;
2023                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2024                                 self.motd_actived_time = 0;
2025                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2026                         }
2027                 }
2028         }
2029         else //if(self.motd_actived_time < 0) // just connected, motd is active
2030         {
2031                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2032                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2033                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2034                 {
2035                         // instanctly hide MOTD
2036                         self.motd_actived_time = 0;
2037                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2038                 }
2039         }
2040 }
2041
2042 void ObserverThink()
2043 {
2044         float prefered_movetype;
2045         if (self.flags & FL_JUMPRELEASED) {
2046                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2047                         self.flags &= ~FL_JUMPRELEASED;
2048                         self.flags |= FL_SPAWNING;
2049                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2050                         self.flags &= ~FL_JUMPRELEASED;
2051                         if(SpectateNext()) {
2052                                 self.classname = "spectator";
2053                         }
2054                 } else {
2055                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2056                         if (self.movetype != prefered_movetype)
2057                                 self.movetype = prefered_movetype;
2058                 }
2059         } else {
2060                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2061                         self.flags |= FL_JUMPRELEASED;
2062                         if(self.flags & FL_SPAWNING)
2063                         {
2064                                 self.flags &= ~FL_SPAWNING;
2065                                 LeaveSpectatorMode();
2066                                 return;
2067                         }
2068                 }
2069         }
2070 }
2071
2072 void SpectatorThink()
2073 {
2074         if (self.flags & FL_JUMPRELEASED) {
2075                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2076                         self.flags &= ~FL_JUMPRELEASED;
2077                         self.flags |= FL_SPAWNING;
2078                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2079                         self.flags &= ~FL_JUMPRELEASED;
2080                         if(SpectateNext()) {
2081                                 self.classname = "spectator";
2082                         } else {
2083                                 self.classname = "observer";
2084                                 PutClientInServer();
2085                         }
2086                         self.impulse = 0;
2087                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2088                         self.flags &= ~FL_JUMPRELEASED;
2089                         if(SpectatePrev()) {
2090                                 self.classname = "spectator";
2091                         } else {
2092                                 self.classname = "observer";
2093                                 PutClientInServer();
2094                         }
2095                         self.impulse = 0;
2096                 } else if (self.BUTTON_ATCK2) {
2097                         self.flags &= ~FL_JUMPRELEASED;
2098                         self.classname = "observer";
2099                         PutClientInServer();
2100                 } else {
2101                         if(!SpectateUpdate())
2102                                 PutObserverInServer();
2103                 }
2104         } else {
2105                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2106                         self.flags |= FL_JUMPRELEASED;
2107                         if(self.flags & FL_SPAWNING)
2108                         {
2109                                 self.flags &= ~FL_SPAWNING;
2110                                 LeaveSpectatorMode();
2111                                 return;
2112                         }
2113                 }
2114                 if(!SpectateUpdate())
2115                         PutObserverInServer();
2116         }
2117
2118         self.flags |= FL_CLIENT | FL_NOTARGET;
2119 }
2120
2121 void PlayerUseKey()
2122 {
2123         if not(IS_PLAYER(self))
2124                 return;
2125
2126         if(self.vehicle)
2127         {
2128         vehicles_exit(VHEF_NORMAL);
2129         return;
2130         }
2131
2132         // a use key was pressed; call handlers
2133         MUTATOR_CALLHOOK(PlayerUseKey);
2134 }
2135
2136 /*
2137 =============
2138 PlayerPreThink
2139
2140 Called every frame for each client before the physics are run
2141 =============
2142 */
2143 .float usekeypressed;
2144 void() nexball_setstatus;
2145 .float items_added;
2146 void PlayerPreThink (void)
2147 {
2148         WarpZone_PlayerPhysics_FixVAngle();
2149
2150         self.stat_game_starttime = game_starttime;
2151         self.stat_round_starttime = round_starttime;
2152         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2153         self.stat_leadlimit = autocvar_leadlimit;
2154
2155         if(frametime)
2156         {
2157                 // physics frames: update anticheat stuff
2158                 anticheat_prethink();
2159         }
2160
2161         if(blockSpectators && frametime)
2162                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2163                 checkSpectatorBlock();
2164
2165         zoomstate_set = 0;
2166
2167         if(self.netname_previous != self.netname)
2168         {
2169                 if(autocvar_sv_eventlog)
2170                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2171                 if(self.netname_previous)
2172                         strunzone(self.netname_previous);
2173                 self.netname_previous = strzone(self.netname);
2174         }
2175
2176         // version nagging
2177         if(self.version_nagtime)
2178                 if(self.cvar_g_xonoticversion)
2179                         if(time > self.version_nagtime)
2180                         {
2181                                 // don't notify git users
2182                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2183                                 {
2184                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2185                                         {
2186                                                 // notify release users if connecting to git
2187                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2188                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2189                                         }
2190                                         else
2191                                         {
2192                                                 float r;
2193                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2194                                                 if(r < 0)
2195                                                 {
2196                                                         // give users new version
2197                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2198                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2199                                                 }
2200                                                 else if(r > 0)
2201                                                 {
2202                                                         // notify users about old server version
2203                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2204                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2205                                                 }
2206                                         }
2207                                 }
2208                                 self.version_nagtime = 0;
2209                         }
2210
2211         // GOD MODE info
2212         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2213         {
2214                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2215                 self.max_armorvalue = 0;
2216         }
2217
2218 #ifdef TETRIS
2219         if (TetrisPreFrame())
2220                 return;
2221 #endif
2222
2223         MUTATOR_CALLHOOK(PlayerPreThink);
2224
2225         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2226         {
2227                 if(self.BUTTON_USE && !self.usekeypressed)
2228                         PlayerUseKey();
2229                 self.usekeypressed = self.BUTTON_USE;
2230         }
2231
2232         if(IS_REAL_CLIENT(self))
2233                 PrintWelcomeMessage();
2234
2235         if(IS_PLAYER(self))
2236         {
2237
2238                 CheckRules_Player();
2239
2240                 if (intermission_running)
2241                 {
2242                         IntermissionThink ();   // otherwise a button could be missed between
2243                         return;                                 // the think tics
2244                 }
2245
2246                 //don't allow the player to turn around while game is paused!
2247                 if(timeout_status == TIMEOUT_ACTIVE) {
2248                         // FIXME turn this into CSQC stuff
2249                         self.v_angle = self.lastV_angle;
2250                         self.angles = self.lastV_angle;
2251                         self.fixangle = TRUE;
2252                 }
2253
2254                 if(frametime)
2255                 {
2256                         if(self.weapon == WEP_NEX && WEP_CVAR(nex, charge))
2257                         {
2258                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / WEP_CVAR(nex, charge_animlimit));
2259                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / WEP_CVAR(nex, charge_animlimit));
2260                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / WEP_CVAR(nex, charge_animlimit));
2261
2262                                 if(self.nex_charge > WEP_CVAR(nex, charge_animlimit))
2263                                 {
2264                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - WEP_CVAR(nex, charge_animlimit)) / (1 - WEP_CVAR(nex, charge_animlimit));
2265                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - WEP_CVAR(nex, charge_animlimit)) / (1 - WEP_CVAR(nex, charge_animlimit));
2266                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - WEP_CVAR(nex, charge_animlimit)) / (1 - WEP_CVAR(nex, charge_animlimit));
2267                                 }
2268                         }
2269                         else
2270                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2271
2272                         player_powerups();
2273                 }
2274
2275                 if (self.deadflag != DEAD_NO)
2276                 {
2277                         if(self.personal && g_race_qualifying)
2278                         {
2279                                 if(time > self.respawn_time)
2280                                 {
2281                                         self.respawn_time = time + 1; // only retry once a second
2282                                         self.stat_respawn_time = self.respawn_time;
2283                                         respawn();
2284                                         self.impulse = 141;
2285                                 }
2286                         }
2287                         else
2288                         {
2289                                 float button_pressed;
2290                                 if(frametime)
2291                                         player_anim();
2292                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2293
2294                                 if (self.deadflag == DEAD_DYING)
2295                                 {
2296                                         if(self.respawn_flags & RESPAWN_FORCE)
2297                                                 self.deadflag = DEAD_RESPAWNING;
2298                                         else if(!button_pressed)
2299                                                 self.deadflag = DEAD_DEAD;
2300                                 }
2301                                 else if (self.deadflag == DEAD_DEAD)
2302                                 {
2303                                         if(button_pressed)
2304                                                 self.deadflag = DEAD_RESPAWNABLE;
2305                                 }
2306                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2307                                 {
2308                                         if(!button_pressed)
2309                                                 self.deadflag = DEAD_RESPAWNING;
2310                                 }
2311                                 else if (self.deadflag == DEAD_RESPAWNING)
2312                                 {
2313                                         if(time > self.respawn_time)
2314                                         {
2315                                                 self.respawn_time = time + 1; // only retry once a second
2316                                                 respawn();
2317                                         }
2318                                 }
2319
2320                                 ShowRespawnCountdown();
2321
2322                                 if(self.respawn_flags & RESPAWN_SILENT)
2323                                         self.stat_respawn_time = 0;
2324                                 else
2325                                         self.stat_respawn_time = self.respawn_time;
2326                         }
2327
2328                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2329                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2330                                 self.stat_respawn_time *= -1;
2331
2332                         return;
2333                 }
2334
2335                 self.prevorigin = self.origin;
2336
2337                 float do_crouch = self.BUTTON_CROUCH;
2338                 if(self.hook.state)
2339                         do_crouch = 0;
2340                 if(self.vehicle)
2341                         do_crouch = 0;
2342                 if(self.freezetag_frozen)
2343                         do_crouch = 0;
2344                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2345                         do_crouch = 0;
2346
2347                 if (do_crouch)
2348                 {
2349                         if (!self.crouch)
2350                         {
2351                                 self.crouch = TRUE;
2352                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2353                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2354                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2355                         }
2356                 }
2357                 else
2358                 {
2359                         if (self.crouch)
2360                         {
2361                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2362                                 if (!trace_startsolid)
2363                                 {
2364                                         self.crouch = FALSE;
2365                                         self.view_ofs = PL_VIEW_OFS;
2366                                         setsize (self, PL_MIN, PL_MAX);
2367                                 }
2368                         }
2369                 }
2370
2371                 FixPlayermodel();
2372
2373                 GrapplingHookFrame();
2374
2375                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2376                 //if(frametime)
2377                 {
2378                         self.items &= ~self.items_added;
2379
2380                         W_WeaponFrame();
2381
2382                         self.items_added = 0;
2383                         if(self.items & IT_JETPACK)
2384                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2385                                         self.items_added |= IT_FUEL;
2386
2387                         self.items |= self.items_added;
2388                 }
2389
2390                 player_regen();
2391
2392                 // rot nex charge to the charge limit
2393                 if(WEP_CVAR(nex, charge_rot_rate) && self.nex_charge > WEP_CVAR(nex, charge_limit) && self.nex_charge_rottime < time)
2394                         self.nex_charge = bound(WEP_CVAR(nex, charge_limit), self.nex_charge - WEP_CVAR(nex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2395
2396                 if(frametime)
2397                         player_anim();
2398
2399                 // secret status
2400                 secrets_setstatus();
2401
2402                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2403
2404                 //self.angles_y=self.v_angle_y + 90;   // temp
2405         } else if(gameover) {
2406                 if (intermission_running)
2407                         IntermissionThink ();   // otherwise a button could be missed between
2408                 return;
2409         } else if(IS_OBSERVER(self)) {
2410                 ObserverThink();
2411         } else if(IS_SPEC(self)) {
2412                 SpectatorThink();
2413         }
2414
2415         if(!zoomstate_set)
2416                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2417
2418         float oldspectatee_status;
2419         oldspectatee_status = self.spectatee_status;
2420         if(IS_SPEC(self))
2421                 self.spectatee_status = num_for_edict(self.enemy);
2422         else if(IS_OBSERVER(self))
2423                 self.spectatee_status = num_for_edict(self);
2424         else
2425                 self.spectatee_status = 0;
2426         if(self.spectatee_status != oldspectatee_status)
2427         {
2428                 ClientData_Touch(self);
2429                 if(g_race || g_cts)
2430                         race_InitSpectator();
2431         }
2432
2433         if(self.teamkill_soundtime)
2434         if(time > self.teamkill_soundtime)
2435         {
2436                 self.teamkill_soundtime = 0;
2437
2438                 entity oldpusher, oldself;
2439
2440                 oldself = self; self = self.teamkill_soundsource;
2441                 oldpusher = self.pusher; self.pusher = oldself;
2442
2443                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2444
2445                 self.pusher = oldpusher;
2446                 self = oldself;
2447         }
2448
2449         if(self.taunt_soundtime)
2450         if(time > self.taunt_soundtime)
2451         {
2452                 self.taunt_soundtime = 0;
2453                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2454         }
2455
2456         target_voicescript_next(self);
2457
2458         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2459         if(!self.weapon)
2460                 self.clip_load = self.clip_size = 0;
2461 }
2462
2463 float isInvisibleString(string s)
2464 {
2465         float i, n, c;
2466         s = strdecolorize(s);
2467         for((i = 0), (n = strlen(s)); i < n; ++i)
2468         {
2469                 c = str2chr(s, i);
2470                 switch(c)
2471                 {
2472                         case 0:
2473                         case 32: // space
2474                                 break;
2475                         case 192: // charmap space
2476                                 if (!autocvar_utf8_enable)
2477                                         break;
2478                                 return FALSE;
2479                         case 160: // space in unicode fonts
2480                         case 0xE000 + 192: // utf8 charmap space
2481                                 if (autocvar_utf8_enable)
2482                                         break;
2483                         default:
2484                                 return FALSE;
2485                 }
2486         }
2487         return TRUE;
2488 }
2489
2490 /*
2491 =============
2492 PlayerPostThink
2493
2494 Called every frame for each client after the physics are run
2495 =============
2496 */
2497 .float idlekick_lasttimeleft;
2498 void PlayerPostThink (void)
2499 {
2500         // Savage: Check for nameless players
2501         if (isInvisibleString(self.netname)) {
2502                 self.netname = "Player";
2503                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2504         }
2505
2506         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2507         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2508         {
2509                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2510                 {
2511                         if(self.idlekick_lasttimeleft)
2512                         {
2513                                 self.idlekick_lasttimeleft = 0;
2514                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2515                         }
2516                 }
2517                 else
2518                 {
2519                         float timeleft;
2520                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2521                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2522                         {
2523                                 if(!self.idlekick_lasttimeleft)
2524                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2525                         }
2526                         if(timeleft <= 0)
2527                         {
2528                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2529                                 dropclient(self);
2530                                 return;
2531                         }
2532                         else if(timeleft <= 10)
2533                         {
2534                                 if(timeleft != self.idlekick_lasttimeleft)
2535                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2536                                 self.idlekick_lasttimeleft = timeleft;
2537                         }
2538                 }
2539         }
2540
2541 #ifdef TETRIS
2542         if(self.impulse == 100)
2543                 ImpulseCommands();
2544         if (!TetrisPostFrame())
2545         {
2546 #endif
2547
2548         CheatFrame();
2549
2550         //CheckPlayerJump();
2551
2552         if(IS_PLAYER(self)) {
2553                 CheckRules_Player();
2554                 UpdateChatBubble();
2555                 if (self.impulse)
2556                         ImpulseCommands();
2557                 if (intermission_running)
2558                         return;         // intermission or finale
2559                 GetPressedKeys();
2560         }
2561
2562 #ifdef TETRIS
2563         }
2564 #endif
2565
2566         /*
2567         float i;
2568         for(i = 0; i < 1000; ++i)
2569         {
2570                 vector end;
2571                 end = self.origin + '0 0 1024' + 512 * randomvec();
2572                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2573                 if(trace_fraction < 1)
2574                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2575                 {
2576                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2577                         break;
2578                 }
2579         }
2580         */
2581
2582         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2583
2584         if(self.waypointsprite_attachedforcarrier)
2585                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2586
2587         playerdemo_write();
2588
2589         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2590         {
2591                 if not(self.stored_netname)
2592                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2593                 if(self.stored_netname != self.netname)
2594                 {
2595                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2596                         strunzone(self.stored_netname);
2597                         self.stored_netname = strzone(self.netname);
2598                 }
2599         }
2600
2601         /*
2602         if(g_race)
2603                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2604         */
2605
2606         CSQCMODEL_AUTOUPDATE();
2607 }