qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (g_arena && arena_roundbased)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         if(g_lms)
 405         {
 406                 // Only if the player cannot play at all
 407                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 408                         self.frags = FRAGS_SPECTATOR;
 409                 else
 410                         self.frags = FRAGS_LMS_LOSER;
 411         }
 412         else
 413                 self.frags = FRAGS_SPECTATOR;
 414
 415         DropAllRunes(self);
 416         MUTATOR_CALLHOOK(MakePlayerObserver);
 417
 418         minstagib_stop_countdown(self);
 419
 420         Portal_ClearAll(self);
 421
 422         if(self.alivetime)
 423         {
 424                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 425                 self.alivetime = 0;
 426         }
 427
 428         if(self.vehicle)
 429                 vehicles_exit(VHEF_RELESE);
 430
 431         WaypointSprite_PlayerDead();
 432
 433         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 434                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 435
 436         if(self.killcount != -666) {
 437                 if(g_lms) {
 438                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 439                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 440                         else
 441                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 442                 } else
 443                         bprint ("^4", self.netname, "^4 is spectating now\n");
 444
 445                 if(self.just_joined == FALSE) {
 446                         LogTeamchange(self.playerid, -1, 4);
 447                 } else
 448                         self.just_joined = FALSE;
 449         }
 450
 451         PlayerScore_Clear(self); // clear scores when needed
 452
 453         accuracy_resend(self);
 454
 455         self.spectatortime = time;
 456
 457         self.classname = "observer";
 458         self.iscreature = FALSE;
 459         self.teleportable = TELEPORT_SIMPLE;
 460         self.damagedbycontents = FALSE;
 461         self.health = -666;
 462         self.takedamage = DAMAGE_NO;
 463         self.solid = SOLID_NOT;
 464         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 465         self.flags = FL_CLIENT | FL_NOTARGET;
 466         self.armorvalue = 666;
 467         self.effects = 0;
 468         self.armorvalue = autocvar_g_balance_armor_start;
 469         self.pauserotarmor_finished = 0;
 470         self.pauserothealth_finished = 0;
 471         self.pauseregen_finished = 0;
 472         self.damageforcescale = 0;
 473         self.death_time = 0;
 474         self.respawn_time = 0;
 475         self.alpha = 0;
 476         self.scale = 0;
 477         self.fade_time = 0;
 478         self.pain_frame = 0;
 479         self.pain_finished = 0;
 480         self.strength_finished = 0;
 481         self.invincible_finished = 0;
 482         self.superweapons_finished = 0;
 483         self.pushltime = 0;
 484         self.istypefrag = 0;
 485         self.think = SUB_Null;
 486         self.nextthink = 0;
 487         self.hook_time = 0;
 488         self.runes = 0;
 489         self.deadflag = DEAD_NO;
 490         self.angles = spot.angles;
 491         self.angles_z = 0;
 492         self.fixangle = TRUE;
 493         self.crouch = FALSE;
 494
 495         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 496         self.prevorigin = self.origin;
 497         self.items = 0;
 498         WEPSET_CLEAR_E(self);
 499         self.model = "";
 500         FixPlayermodel();
 501         setmodel(self, "null");
 502         self.drawonlytoclient = self;
 503
 504         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 505         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 506
 507         self.weapon = 0;
 508         self.weaponname = "";
 509         self.switchingweapon = 0;
 510         self.weaponmodel = "";
 511         self.weaponentity = world;
 512         self.exteriorweaponentity = world;
 513         self.killcount = -666;
 514         self.velocity = '0 0 0';
 515         self.avelocity = '0 0 0';
 516         self.punchangle = '0 0 0';
 517         self.punchvector = '0 0 0';
 518         self.oldvelocity = self.velocity;
 519         self.fire_endtime = -1;
 520 }
 521
 522 .float model_randomizer;
 523 void FixPlayermodel()
 524 {
 525         string defaultmodel;
 526         float defaultskin, chmdl, oldskin, n, i;
 527         vector m1, m2;
 528
 529         defaultmodel = "";
 530         defaultskin = 0;
 531         chmdl = FALSE;
 532
 533         if(autocvar_sv_defaultcharacter == 1)
 534         {
 535                 if(teamplay)
 536                 {
 537                         string s;
 538                         s = Team_ColorNameLowerCase(self.team);
 539                         if(s != "neutral")
 540                         {
 541                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 542                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 543                         }
 544                 }
 545
 546                 if(defaultmodel == "")
 547                 {
 548                         defaultmodel = autocvar_sv_defaultplayermodel;
 549                         defaultskin = autocvar_sv_defaultplayerskin;
 550                 }
 551
 552                 n = tokenize_console(defaultmodel);
 553                 if(n > 0)
 554                         defaultmodel = argv(floor(n * self.model_randomizer));
 555
 556                 i = strstrofs(defaultmodel, ":", 0);
 557                 if(i >= 0)
 558                 {
 559                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 560                         defaultmodel = substring(defaultmodel, 0, i);
 561                 }
 562         }
 563
 564         if(defaultmodel != "")
 565         {
 566                 if (defaultmodel != self.model)
 567                 {
 568                         m1 = self.mins;
 569                         m2 = self.maxs;
 570                         setplayermodel (self, defaultmodel);
 571                         setsize (self, m1, m2);
 572                         chmdl = TRUE;
 573                 }
 574
 575                 oldskin = self.skin;
 576                 self.skin = defaultskin;
 577         } else {
 578                 if (self.playermodel != self.model || self.playermodel == "")
 579                 {
 580                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 581                         m1 = self.mins;
 582                         m2 = self.maxs;
 583                         setplayermodel (self, self.playermodel);
 584                         setsize (self, m1, m2);
 585                         chmdl = TRUE;
 586                 }
 587
 588                 oldskin = self.skin;
 589                 self.skin = stof(self.playerskin);
 590         }
 591
 592         if(chmdl || oldskin != self.skin)
 593                 self.species = player_getspecies(); // model or skin has changed
 594
 595         if(!teamplay)
 596                 if(strlen(autocvar_sv_defaultplayercolors))
 597                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 598                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 599 }
 600
 601 void PlayerTouchExplode(entity p1, entity p2)
 602 {
 603         vector org;
 604         org = (p1.origin + p2.origin) * 0.5;
 605         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 606
 607         te_explosion(org);
 608
 609         entity e;
 610         e = spawn();
 611         setorigin(e, org);
 612         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 613         remove(e);
 614 }
 615
 616 /*
 617 =============
 618 PutClientInServer
 619
 620 Called when a client spawns in the server
 621 =============
 622 */
 623
 624 void PutClientInServer (void)
 625 {
 626         if(clienttype(self) == CLIENTTYPE_BOT)
 627                 self.classname = "player";
 628         else if(clienttype(self) == CLIENTTYPE_REAL)
 629         {
 630                 msg_entity = self;
 631                 WriteByte(MSG_ONE, SVC_SETVIEW);
 632                 WriteEntity(MSG_ONE, self);
 633         }
 634
 635         // reset player keys
 636         self.itemkeys = 0;
 637
 638         // player is dead and becomes observer
 639         // FIXME fix LMS scoring for new system
 640         if(g_lms)
 641         {
 642                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 643                         self.classname = "observer";
 644         }
 645
 646         MUTATOR_CALLHOOK(PutClientInServer);
 647
 648         if(gameover)
 649                 self.classname = "observer";
 650
 651         if(self.classname == "player") {
 652                 entity spot, oldself;
 653                 float j;
 654
 655                 accuracy_resend(self);
 656
 657                 if(self.team < 0)
 658                         JoinBestTeam(self, FALSE, TRUE);
 659
 660                 race_PreSpawn();
 661
 662                 spot = SelectSpawnPoint (FALSE);
 663                 if(!spot)
 664                 {
 665                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 666                         return; // spawn failed
 667                 }
 668
 669                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 670
 671                 self.classname = "player";
 672                 self.wasplayer = TRUE;
 673                 self.iscreature = TRUE;
 674                 self.teleportable = TELEPORT_NORMAL;
 675                 self.damagedbycontents = TRUE;
 676                 self.movetype = MOVETYPE_WALK;
 677                 self.solid = SOLID_SLIDEBOX;
 678                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 679                 if(autocvar_g_playerclip_collisions)
 680                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 681                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 682                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 683                 self.frags = FRAGS_PLAYER;
 684                 if(INDEPENDENT_PLAYERS)
 685                         MAKE_INDEPENDENT_PLAYER(self);
 686                 self.flags = FL_CLIENT;
 687                 if(autocvar__notarget)
 688                         self.flags |= FL_NOTARGET;
 689                 self.takedamage = DAMAGE_AIM;
 690                 if(g_minstagib)
 691                         self.effects = EF_FULLBRIGHT;
 692                 else
 693                         self.effects = 0;
 694                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 695                 self.air_finished = time + 12;
 696                 self.dmg = 2;
 697                 if(autocvar_g_balance_nex_charge)
 698                 {
 699                         if(autocvar_g_balance_nex_secondary_chargepool)
 700                                 self.nex_chargepool_ammo = 1;
 701                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 702                 }
 703
 704                 if(inWarmupStage)
 705                 {
 706                         self.ammo_shells = warmup_start_ammo_shells;
 707                         self.ammo_nails = warmup_start_ammo_nails;
 708                         self.ammo_rockets = warmup_start_ammo_rockets;
 709                         self.ammo_cells = warmup_start_ammo_cells;
 710                         self.ammo_fuel = warmup_start_ammo_fuel;
 711                         self.health = warmup_start_health;
 712                         self.armorvalue = warmup_start_armorvalue;
 713                         WEPSET_COPY_EA(self, warmup_start_weapons);
 714                 }
 715                 else
 716                 {
 717                         self.ammo_shells = start_ammo_shells;
 718                         self.ammo_nails = start_ammo_nails;
 719                         self.ammo_rockets = start_ammo_rockets;
 720                         self.ammo_cells = start_ammo_cells;
 721                         self.ammo_fuel = start_ammo_fuel;
 722                         self.health = start_health;
 723                         self.armorvalue = start_armorvalue;
 724                         WEPSET_COPY_EA(self, start_weapons);
 725                 }
 726
 727                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 728                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 729                 else
 730                         self.superweapons_finished = 0;
 731
 732                 if(g_weaponarena_random)
 733                 {
 734                         if(g_weaponarena_random_with_laser)
 735                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 736                         W_RandomWeapons(self, g_weaponarena_random);
 737                         if(g_weaponarena_random_with_laser)
 738                                 WEPSET_OR_EW(self, WEP_LASER);
 739                 }
 740
 741                 self.items = start_items;
 742
 743                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 744                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 745                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 746                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 747                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 748                 //extend the pause of rotting if client was reset at the beginning of the countdown
 749                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 750                         self.spawnshieldtime += game_starttime - time;
 751                         self.pauserotarmor_finished += game_starttime - time;
 752                         self.pauserothealth_finished += game_starttime - time;
 753                         self.pauseregen_finished += game_starttime - time;
 754                 }
 755                 self.damageforcescale = 2;
 756                 self.death_time = 0;
 757                 self.respawn_time = 0;
 758                 self.scale = 0;
 759                 self.fade_time = 0;
 760                 self.pain_frame = 0;
 761                 self.pain_finished = 0;
 762                 self.strength_finished = 0;
 763                 self.invincible_finished = 0;
 764                 self.pushltime = 0;
 765                 // players have no think function
 766                 self.think = SUB_Null;
 767                 self.nextthink = 0;
 768                 self.hook_time = 0;
 769                 self.dmg_team = 0;
 770                 self.ballistics_density = autocvar_g_ballistics_density_player;
 771
 772                 self.metertime = 0;
 773
 774                 self.runes = 0;
 775
 776                 self.deadflag = DEAD_NO;
 777
 778                 self.angles = spot.angles;
 779
 780                 self.angles_z = 0; // never spawn tilted even if the spot says to
 781                 self.fixangle = TRUE; // turn this way immediately
 782                 self.velocity = '0 0 0';
 783                 self.avelocity = '0 0 0';
 784                 self.punchangle = '0 0 0';
 785                 self.punchvector = '0 0 0';
 786                 self.oldvelocity = self.velocity;
 787                 self.fire_endtime = -1;
 788
 789                 msg_entity = self;
 790                 WRITESPECTATABLE_MSG_ONE({
 791                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 792                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 793                 });
 794
 795                 self.model = "";
 796                 FixPlayermodel();
 797                 self.drawonlytoclient = world;
 798
 799                 self.crouch = FALSE;
 800                 self.view_ofs = PL_VIEW_OFS;
 801                 setsize (self, PL_MIN, PL_MAX);
 802                 self.spawnorigin = spot.origin;
 803                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 804                 // don't reset back to last position, even if new position is stuck in solid
 805                 self.oldorigin = self.origin;
 806                 self.prevorigin = self.origin;
 807                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 808                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 809         self.hud = HUD_NORMAL;
 810
 811                 self.event_damage = PlayerDamage;
 812
 813                 self.bot_attack = TRUE;
 814
 815                 self.statdraintime = time + 5;
 816                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 817
 818                 if(self.killcount == -666) {
 819                         PlayerScore_Clear(self);
 820                         self.killcount = 0;
 821                 }
 822
 823                 CL_SpawnWeaponentity();
 824                 self.alpha = default_player_alpha;
 825                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 826                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 827
 828                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 829                 self.lms_traveled_distance = 0;
 830                 self.speedrunning = FALSE;
 831
 832                 race_PostSpawn(spot);
 833
 834                 //stuffcmd(self, "chase_active 0");
 835                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 836
 837                 if(g_assault) {
 838                         if(self.team == assault_attacker_team)
 839                                 centerprint(self, "You are attacking!");
 840                         else
 841                                 centerprint(self, "You are defending!");
 842                 }
 843
 844                 target_voicescript_clear(self);
 845
 846                 // reset fields the weapons may use
 847                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 848                 {
 849                         weapon_action(j, WR_RESETPLAYER);
 850
 851                         // all weapons must be fully loaded when we spawn
 852                         entity e;
 853                         e = get_weaponinfo(j);
 854                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 855                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 856                 }
 857
 858                 oldself = self;
 859                 self = spot;
 860                         activator = oldself;
 861                                 string s;
 862                                 s = self.target;
 863                                 self.target = string_null;
 864                                 SUB_UseTargets();
 865                                 self.target = s;
 866                         activator = world;
 867                 self = oldself;
 868
 869                 spawn_spot = spot;
 870                 MUTATOR_CALLHOOK(PlayerSpawn);
 871
 872                 if(autocvar_spawn_debug)
 873                 {
 874                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 875                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 876                 }
 877
 878                 self.switchweapon = w_getbestweapon(self);
 879                 self.cnt = -1; // W_LastWeapon will not complain
 880                 self.weapon = 0;
 881                 self.weaponname = "";
 882                 self.switchingweapon = 0;
 883
 884                 if(!self.alivetime)
 885                         self.alivetime = time;
 886
 887                 antilag_clear(self);
 888
 889                 if (autocvar_g_spawnsound)
 890                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 891         } else if(self.classname == "observer") {
 892                 PutObserverInServer ();
 893         }
 894 }
 895
 896 .float ebouncefactor, ebouncestop; // electro's values
 897 // TODO do we need all these fields, or should we stop autodetecting runtime
 898 // changes and just have a console command to update this?
 899 float ClientInit_SendEntity(entity to, float sf)
 900 {
 901         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 902         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 903         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 904         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 905         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 906         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 907         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 908         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 909         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 910         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 911         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 912         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 913         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 914         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 915         if(sv_foginterval && world.fog != "")
 916                 WriteString(MSG_ENTITY, world.fog);
 917         else
 918                 WriteString(MSG_ENTITY, "");
 919         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 920         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 921         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 922         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 923         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 924         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 925         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 926         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 927         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 928         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 929         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 930         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 931         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 932         return TRUE;
 933 }
 934
 935 void ClientInit_CheckUpdate()
 936 {
 937         self.nextthink = time;
 938         if(self.count != autocvar_g_balance_armor_blockpercent)
 939         {
 940                 self.count = autocvar_g_balance_armor_blockpercent;
 941                 self.SendFlags |= 1;
 942         }
 943         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 944         {
 945                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 946                 self.SendFlags |= 1;
 947         }
 948         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 949         {
 950                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 951                 self.SendFlags |= 1;
 952         }
 953         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 954         {
 955                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 956                 self.SendFlags |= 1;
 957         }
 958         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 959         {
 960                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 961                 self.SendFlags |= 1;
 962         }
 963         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 964         {
 965                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 966                 self.SendFlags |= 1;
 967         }
 968 }
 969
 970 void ClientInit_Spawn()
 971 {
 972         entity o;
 973         entity e;
 974         e = spawn();
 975         e.classname = "clientinit";
 976         e.think = ClientInit_CheckUpdate;
 977         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 978
 979         o = self;
 980         self = e;
 981         ClientInit_CheckUpdate();
 982         self = o;
 983 }
 984
 985 /*
 986 =============
 987 SetNewParms
 988 =============
 989 */
 990 void SetNewParms (void)
 991 {
 992         // initialize parms for a new player
 993         parm1 = -(86400 * 366);
 994 }
 995
 996 /*
 997 =============
 998 SetChangeParms
 999 =============
1000 */
1001 void SetChangeParms (void)
1002 {
1003         // save parms for level change
1004         parm1 = self.parm_idlesince - time;
1005 }
1006
1007 /*
1008 =============
1009 DecodeLevelParms
1010 =============
1011 */
1012 void DecodeLevelParms (void)
1013 {
1014         // load parms
1015         self.parm_idlesince = parm1;
1016         if(self.parm_idlesince == -(86400 * 366))
1017                 self.parm_idlesince = time;
1018
1019         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1020         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1021 }
1022
1023 /*
1024 =============
1025 ClientKill
1026
1027 Called when a client types 'kill' in the console
1028 =============
1029 */
1030
1031 .float clientkill_nexttime;
1032 void ClientKill_Now_TeamChange()
1033 {
1034         if(self.killindicator_teamchange == -1)
1035         {
1036                 JoinBestTeam( self, FALSE, TRUE );
1037         }
1038         else if(self.killindicator_teamchange == -2)
1039         {
1040                 if(g_ca)
1041                         self.caplayer = 0;
1042                 if(blockSpectators)
1043                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1044                 PutObserverInServer();
1045         }
1046         else
1047                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1048 }
1049
1050 void ClientKill_Now()
1051 {
1052         if(self.vehicle)
1053         {
1054             vehicles_exit(VHEF_RELESE);
1055             if(!self.killindicator_teamchange)
1056             {
1057             self.vehicle_health = -1;
1058             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1059             }
1060         }
1061
1062         if(self.killindicator && !wasfreed(self.killindicator))
1063                 remove(self.killindicator);
1064
1065         self.killindicator = world;
1066
1067         if(self.killindicator_teamchange)
1068                 ClientKill_Now_TeamChange();
1069
1070         // in any case:
1071         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1072
1073         // now I am sure the player IS dead
1074 }
1075 void KillIndicator_Think()
1076 {
1077         if (gameover)
1078         {
1079                 self.owner.killindicator = world;
1080                 remove(self);
1081                 return;
1082         }
1083
1084         if (self.owner.alpha < 0 && !self.owner.vehicle)
1085         {
1086                 self.owner.killindicator = world;
1087                 remove(self);
1088                 return;
1089         }
1090
1091         if(self.cnt <= 0)
1092         {
1093                 self = self.owner;
1094                 ClientKill_Now(); // no oldself needed
1095                 return;
1096         }
1097     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1098     {
1099         self.nextthink = time + 1;
1100         self.cnt -= 1;
1101     }
1102         else
1103         {
1104                 if(self.cnt <= 10)
1105                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1106                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1107                 {
1108                         if(self.cnt <= 10)
1109                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1110                 }
1111                 self.nextthink = time + 1;
1112                 self.cnt -= 1;
1113         }
1114 }
1115
1116 float clientkilltime;
1117 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1118 {
1119         float killtime;
1120         float starttime;
1121         entity e;
1122
1123         if (gameover)
1124                 return;
1125
1126         killtime = autocvar_g_balance_kill_delay;
1127
1128         if(g_race_qualifying || g_cts)
1129                 killtime = 0;
1130
1131     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1132     {
1133                 remove(self.killindicator);
1134                 self.killindicator = world;
1135
1136         ClientKill_Now(); // allow instant kill in this case
1137         return;
1138     }
1139
1140         self.killindicator_teamchange = targetteam;
1141
1142     if(!self.killindicator)
1143         {
1144                 if(self.deadflag == DEAD_NO)
1145                 {
1146                         killtime = max(killtime, self.clientkill_nexttime - time);
1147                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1148                 }
1149
1150                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1151                 {
1152                         ClientKill_Now();
1153                 }
1154                 else
1155                 {
1156                         starttime = max(time, clientkilltime);
1157
1158                         self.killindicator = spawn();
1159                         self.killindicator.owner = self;
1160                         self.killindicator.scale = 0.5;
1161                         setattachment(self.killindicator, self, "");
1162                         setorigin(self.killindicator, '0 0 52');
1163                         self.killindicator.think = KillIndicator_Think;
1164                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1165                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1166                         self.killindicator.cnt = ceil(killtime);
1167                         self.killindicator.count = bound(0, ceil(killtime), 10);
1168                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1169
1170                         for(e = world; (e = find(e, classname, "body")) != world; )
1171                         {
1172                                 if(e.enemy != self)
1173                                         continue;
1174                                 e.killindicator = spawn();
1175                                 e.killindicator.owner = e;
1176                                 e.killindicator.scale = 0.5;
1177                                 setattachment(e.killindicator, e, "");
1178                                 setorigin(e.killindicator, '0 0 52');
1179                                 e.killindicator.think = KillIndicator_Think;
1180                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1181                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1182                                 e.killindicator.cnt = ceil(killtime);
1183                         }
1184                         self.lip = 0;
1185                 }
1186         }
1187         if(self.killindicator)
1188         {
1189                 if(targetteam == 0) // just die
1190                 {
1191                         self.killindicator.colormod = '0 0 0';
1192                         if(clienttype(self) == CLIENTTYPE_REAL)
1193                         if(self.killindicator.cnt > 0)
1194                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1195                 }
1196                 else if(targetteam == -1) // auto
1197                 {
1198                         self.killindicator.colormod = '0 1 0';
1199                         if(clienttype(self) == CLIENTTYPE_REAL)
1200                         if(self.killindicator.cnt > 0)
1201                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1202                 }
1203                 else if(targetteam == -2) // spectate
1204                 {
1205                         self.killindicator.colormod = '0.5 0.5 0.5';
1206                         if(clienttype(self) == CLIENTTYPE_REAL)
1207                         if(self.killindicator.cnt > 0)
1208                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1209                 }
1210                 else
1211                 {
1212                         self.killindicator.colormod = TeamColor(targetteam);
1213                         if(clienttype(self) == CLIENTTYPE_REAL)
1214                         if(self.killindicator.cnt > 0)
1215                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1216                 }
1217         }
1218
1219 }
1220
1221 void ClientKill (void)
1222 {
1223         if(gameover) return;
1224         if(g_ca && player_count == 1) return;
1225         if(self.player_blocked) return;
1226         if(self.freezetag_frozen) return;
1227
1228         ClientKill_TeamChange(0);
1229 }
1230
1231 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1232 {
1233     e.killindicator = spawn();
1234     e.killindicator.owner = e;
1235     e.killindicator.think = KillIndicator_Think;
1236     e.killindicator.nextthink = time + (e.lip) * 0.05;
1237     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1238     e.killindicator.health = 1; // this is used to indicate that it should be silent
1239     e.lip = 0;
1240 }
1241
1242 void FixClientCvars(entity e)
1243 {
1244         // send prediction settings to the client
1245         stuffcmd(e, "\nin_bindmap 0 0\n");
1246         if(g_race || g_cts)
1247                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1248         if(autocvar_g_antilag == 3) // client side hitscan
1249                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1250         if(sv_gentle)
1251                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1252         /*
1253          * we no longer need to stuff this. Remove this comment block if you feel
1254          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1255         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1256         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1257         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1258         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1259         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1260         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1261         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1262         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1263         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1264         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1265         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1266         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1267         stuffcmd(e, "cl_movement_edgefriction 1\n");
1268          */
1269 }
1270
1271 float PlayerInIDList(entity p, string idlist)
1272 {
1273         float n, i;
1274         string s;
1275
1276         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1277         if not(p.crypto_idfp)
1278                 return 0;
1279
1280         // this function allows abbreviated player IDs too!
1281         n = tokenize_console(idlist);
1282         for(i = 0; i < n; ++i)
1283         {
1284                 s = argv(i);
1285                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1286                         return 1;
1287         }
1288
1289         return 0;
1290 }
1291
1292 /*
1293 =============
1294 ClientConnect
1295
1296 Called when a client connects to the server
1297 =============
1298 */
1299 string ColoredTeamName(float t);
1300 void DecodeLevelParms (void);
1301 //void dom_player_join_team(entity pl);
1302 void set_dom_state(entity e);
1303 void ClientConnect (void)
1304 {
1305         float t;
1306
1307         if(self.flags & FL_CLIENT)
1308         {
1309                 print("Warning: ClientConnect, but already connected!\n");
1310                 return;
1311         }
1312
1313         if(Ban_MaybeEnforceBanOnce(self))
1314                 return;
1315
1316         DecodeLevelParms();
1317
1318 #ifdef WATERMARK
1319         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1320 #endif
1321
1322         self.classname = "player_joining";
1323
1324         self.flags = FL_CLIENT;
1325         self.version_nagtime = time + 10 + random() * 10;
1326
1327         if(player_count<0)
1328         {
1329                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1330                 player_count = 0;
1331         }
1332
1333         PlayerScore_Attach(self);
1334         ClientData_Attach();
1335         accuracy_init(self);
1336
1337         bot_clientconnect();
1338
1339         playerdemo_init();
1340
1341         anticheat_init();
1342
1343         race_PreSpawnObserver();
1344
1345         //if(g_domination)
1346         //      dom_player_join_team(self);
1347
1348         // identify the right forced team
1349         if(autocvar_g_campaign)
1350         {
1351                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1352                 {
1353                         switch(autocvar_g_campaign_forceteam)
1354                         {
1355                                 case 1: self.team_forced = COLOR_TEAM1; break;
1356                                 case 2: self.team_forced = COLOR_TEAM2; break;
1357                                 case 3: self.team_forced = COLOR_TEAM3; break;
1358                                 case 4: self.team_forced = COLOR_TEAM4; break;
1359                                 default: self.team_forced = 0;
1360                         }
1361                 }
1362         }
1363         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1364                 self.team_forced = COLOR_TEAM1;
1365         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1366                 self.team_forced = COLOR_TEAM2;
1367         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1368                 self.team_forced = COLOR_TEAM3;
1369         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1370                 self.team_forced = COLOR_TEAM4;
1371         else if(autocvar_g_forced_team_otherwise == "red")
1372                 self.team_forced = COLOR_TEAM1;
1373         else if(autocvar_g_forced_team_otherwise == "blue")
1374                 self.team_forced = COLOR_TEAM2;
1375         else if(autocvar_g_forced_team_otherwise == "yellow")
1376                 self.team_forced = COLOR_TEAM3;
1377         else if(autocvar_g_forced_team_otherwise == "pink")
1378                 self.team_forced = COLOR_TEAM4;
1379         else if(autocvar_g_forced_team_otherwise == "spectate")
1380                 self.team_forced = -1;
1381         else if(autocvar_g_forced_team_otherwise == "spectator")
1382                 self.team_forced = -1;
1383         else
1384                 self.team_forced = 0;
1385
1386         if(!teamplay)
1387                 if(self.team_forced > 0)
1388                         self.team_forced = 0;
1389
1390         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1391
1392         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1393                 self.classname = "observer";
1394         } else {
1395                 if(teamplay)
1396                 {
1397                         if(autocvar_g_balance_teams)
1398                         {
1399                                 self.classname = "player";
1400                                 campaign_bots_may_start = 1;
1401                         }
1402                         else
1403                         {
1404                                 self.classname = "observer"; // do it anyway
1405                         }
1406                 }
1407                 else
1408                 {
1409                         self.classname = "player";
1410                         campaign_bots_may_start = 1;
1411                 }
1412         }
1413
1414         self.playerid = (playerid_last = playerid_last + 1);
1415
1416         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1417
1418     if(clienttype(self) == CLIENTTYPE_BOT)
1419         PlayerStats_AddPlayer(self);
1420
1421         if(autocvar_sv_eventlog)
1422                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1423
1424         LogTeamchange(self.playerid, self.team, 1);
1425
1426         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1427
1428         self.netname_previous = strzone(self.netname);
1429
1430         bprint("^4", self.netname, "^4 connected");
1431
1432         if(self.classname != "observer" && (g_domination || g_ctf))
1433                 bprint(" and joined the ", ColoredTeamName(self.team));
1434
1435         bprint("\n");
1436
1437         stuffcmd(self, strcat(clientstuff, "\n"));
1438         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1439
1440         FixClientCvars(self);
1441
1442         // spawnfunc_waypoint sprites
1443         WaypointSprite_InitClient(self);
1444
1445         // Wazat's grappling hook
1446         SetGrappleHookBindings();
1447
1448         // get version info from player
1449         stuffcmd(self, "cmd clientversion $gameversion\n");
1450
1451         // get other cvars from player
1452         GetCvars(0);
1453
1454         // notify about available teams
1455         if(teamplay)
1456         {
1457                 CheckAllowedTeams(self);
1458                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1459                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1460         }
1461         else
1462                 stuffcmd(self, "set _teams_available 0\n");
1463
1464         if(g_arena || g_ca)
1465         {
1466                 self.classname = "observer";
1467                 if(g_arena)
1468                         Spawnqueue_Insert(self);
1469         }
1470
1471         attach_entcs();
1472
1473         bot_relinkplayerlist();
1474
1475         self.spectatortime = time;
1476         if(blockSpectators)
1477         {
1478                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1479         }
1480
1481         self.jointime = time;
1482         self.allowed_timeouts = autocvar_sv_timeout_number;
1483
1484         if(clienttype(self) == CLIENTTYPE_REAL)
1485         {
1486                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1487                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1488         }
1489
1490         if(g_lms)
1491         {
1492                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1493                 {
1494                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1495                         self.frags = FRAGS_SPECTATOR;
1496                 }
1497         }
1498
1499         if(!sv_foginterval && world.fog != "")
1500                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1501
1502         SoundEntity_Attach(self);
1503
1504         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1505         {
1506                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1507                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1508         }
1509         else
1510                 self.hitplotfh = -1;
1511
1512         if(g_race || g_cts) {
1513                 string rr;
1514                 if(g_cts)
1515                         rr = CTS_RECORD;
1516                 else
1517                         rr = RACE_RECORD;
1518
1519                 msg_entity = self;
1520                 race_send_recordtime(MSG_ONE);
1521                 race_send_speedaward(MSG_ONE);
1522
1523                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1524                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1525                 race_send_speedaward_alltimebest(MSG_ONE);
1526
1527                 float i;
1528                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1529                         race_SendRankings(i, 0, 0, MSG_ONE);
1530                 }
1531         }
1532         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1533                 send_CSQC_teamnagger();
1534
1535         if (g_domination)
1536                 set_dom_state(self);
1537
1538         CheatInitClient();
1539
1540         if(!autocvar_g_campaign)
1541                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1542
1543         CSQCMODEL_AUTOINIT();
1544
1545         self.model_randomizer = random();
1546
1547     if(clienttype(self) != CLIENTTYPE_REAL)
1548         return;
1549
1550     sv_notice_join();
1551
1552     MUTATOR_CALLHOOK(ClientConnect);
1553 }
1554 /*
1555 =============
1556 ClientDisconnect
1557
1558 Called when a client disconnects from the server
1559 =============
1560 */
1561 .entity chatbubbleentity;
1562 void ReadyCount();
1563 void ClientDisconnect (void)
1564 {
1565         if(self.vehicle)
1566             vehicles_exit(VHEF_RELESE);
1567
1568         if not(self.flags & FL_CLIENT)
1569         {
1570                 print("Warning: ClientDisconnect without ClientConnect\n");
1571                 return;
1572         }
1573
1574         PlayerStats_AddGlobalInfo(self);
1575
1576         CheatShutdownClient();
1577
1578         if(self.hitplotfh >= 0)
1579         {
1580                 fclose(self.hitplotfh);
1581                 self.hitplotfh = -1;
1582         }
1583
1584         anticheat_report();
1585         anticheat_shutdown();
1586
1587         playerdemo_shutdown();
1588
1589         bot_clientdisconnect();
1590
1591         if(self.entcs)
1592                 detach_entcs();
1593
1594         if(autocvar_sv_eventlog)
1595                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1596         bprint ("^4",self.netname);
1597         bprint ("^4 disconnected\n");
1598
1599         SoundEntity_Detach(self);
1600
1601         DropAllRunes(self);
1602         MUTATOR_CALLHOOK(ClientDisconnect);
1603
1604         Portal_ClearAll(self);
1605
1606         RemoveGrapplingHook(self);
1607
1608         // Here, everything has been done that requires this player to be a client.
1609
1610         self.flags &~= FL_CLIENT;
1611
1612         if (self.chatbubbleentity)
1613                 remove (self.chatbubbleentity);
1614
1615         if (self.killindicator)
1616                 remove (self.killindicator);
1617
1618         WaypointSprite_PlayerGone();
1619
1620         bot_relinkplayerlist();
1621
1622         accuracy_free(self);
1623         ClientData_Detach();
1624         PlayerScore_Detach(self);
1625
1626         if(self.netname_previous)
1627                 strunzone(self.netname_previous);
1628         if(self.clientstatus)
1629                 strunzone(self.clientstatus);
1630         if(self.weaponorder_byimpulse)
1631                 strunzone(self.weaponorder_byimpulse);
1632
1633         ClearPlayerSounds();
1634
1635         if(self.personal)
1636                 remove(self.personal);
1637
1638         self.playerid = 0;
1639         ReadyCount();
1640
1641         // free cvars
1642         GetCvars(-1);
1643 }
1644
1645 .float BUTTON_CHAT;
1646 void ChatBubbleThink()
1647 {
1648         self.nextthink = time;
1649         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1650         {
1651                 if(self.owner) // but why can that ever be world?
1652                         self.owner.chatbubbleentity = world;
1653                 remove(self);
1654                 return;
1655         }
1656         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1657 #ifdef TETRIS
1658                 || self.owner.tetris_on
1659 #endif
1660         )
1661                 self.model = self.mdl;
1662         else
1663                 self.model = "";
1664 }
1665
1666 void UpdateChatBubble()
1667 {
1668         if (self.alpha < 0)
1669                 return;
1670         // spawn a chatbubble entity if needed
1671         if (!self.chatbubbleentity)
1672         {
1673                 self.chatbubbleentity = spawn();
1674                 self.chatbubbleentity.owner = self;
1675                 self.chatbubbleentity.exteriormodeltoclient = self;
1676                 self.chatbubbleentity.think = ChatBubbleThink;
1677                 self.chatbubbleentity.nextthink = time;
1678                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1679                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1680                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1681                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1682                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1683                 self.chatbubbleentity.model = "";
1684                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1685         }
1686 }
1687
1688
1689 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1690 // added to the model skins
1691 /*void UpdateColorModHack()
1692 {
1693         float c;
1694         c = self.clientcolors & 15;
1695         // LordHavoc: only bothering to support white, green, red, yellow, blue
1696              if (!teamplay) self.colormod = '0 0 0';
1697         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1698         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1699         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1700         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1701         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1702         else self.colormod = '1 1 1';
1703 }*/
1704
1705 void respawn(void)
1706 {
1707         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1708         {
1709                 self.solid = SOLID_NOT;
1710                 self.takedamage = DAMAGE_NO;
1711                 self.movetype = MOVETYPE_FLY;
1712                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1713                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1714                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1715                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1716                 if(autocvar_g_respawn_ghosts_maxtime)
1717                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1718         }
1719
1720         CopyBody(1);
1721
1722         self.effects |= EF_NODRAW; // prevent another CopyBody
1723         PutClientInServer();
1724 }
1725
1726 void play_countdown(float finished, string samp)
1727 {
1728         if(clienttype(self) == CLIENTTYPE_REAL)
1729                 if(floor(finished - time - frametime) != floor(finished - time))
1730                         if(finished - time < 6)
1731                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1732 }
1733
1734 void player_powerups (void)
1735 {
1736         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1737         olditems = self.items;
1738
1739         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1740         {
1741                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1742                 self.modelflags |= MF_ROCKET;
1743         }
1744         else
1745         {
1746                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1747                 self.modelflags &~= MF_ROCKET;
1748         }
1749
1750         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1751
1752         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1753                 return;
1754
1755         Fire_ApplyDamage(self);
1756         Fire_ApplyEffect(self);
1757
1758         if (g_minstagib)
1759         {
1760                 self.effects |= EF_FULLBRIGHT;
1761
1762                 if (self.items & IT_STRENGTH)
1763                 {
1764                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1765                         if (time > self.strength_finished)
1766                         {
1767                                 self.alpha = default_player_alpha;
1768                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1769                                 self.items &~= IT_STRENGTH;
1770                                 sprint(self, "^3Invisibility has worn off\n");
1771                         }
1772                 }
1773                 else
1774                 {
1775                         if (time < self.strength_finished)
1776                         {
1777                                 self.alpha = g_minstagib_invis_alpha;
1778                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1779                                 self.items |= IT_STRENGTH;
1780                                 sprint(self, "^3You are invisible\n");
1781                         }
1782                 }
1783
1784                 if (self.items & IT_INVINCIBLE)
1785                 {
1786                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1787                         if (time > self.invincible_finished)
1788                         {
1789                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1790                                 sprint(self, "^3Speed has worn off\n");
1791                         }
1792                 }
1793                 else
1794                 {
1795                         if (time < self.invincible_finished)
1796                         {
1797                                 self.items = self.items | IT_INVINCIBLE;
1798                                 sprint(self, "^3You are on speed\n");
1799                         }
1800                 }
1801         }
1802         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1803         {
1804                 if (self.items & IT_STRENGTH)
1805                 {
1806                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1807                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1808                         if (time > self.strength_finished)
1809                         {
1810                                 self.items = self.items - (self.items & IT_STRENGTH);
1811                                 sprint(self, "^3Strength has worn off\n");
1812                         }
1813                 }
1814                 else
1815                 {
1816                         if (time < self.strength_finished)
1817                         {
1818                                 self.items = self.items | IT_STRENGTH;
1819                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1820                         }
1821                 }
1822                 if (self.items & IT_INVINCIBLE)
1823                 {
1824                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1825                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1826                         if (time > self.invincible_finished)
1827                         {
1828                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1829                                 sprint(self, "^3Shield has worn off\n");
1830                         }
1831                 }
1832                 else
1833                 {
1834                         if (time < self.invincible_finished)
1835                         {
1836                                 self.items = self.items | IT_INVINCIBLE;
1837                                 sprint(self, "^3Shield surrounds you\n");
1838                         }
1839                 }
1840                 if (self.items & IT_SUPERWEAPON)
1841                 {
1842                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1843                         {
1844                                 self.superweapons_finished = 0;
1845                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1846                                 sprint(self, "^3Superweapons have been lost\n");
1847                         }
1848                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1849                         {
1850                                 // don't let them run out
1851                         }
1852                         else
1853                         {
1854                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1855                                 if (time > self.superweapons_finished)
1856                                 {
1857                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1858                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1859                                         sprint(self, "^3Superweapons have broken down\n");
1860                                 }
1861                         }
1862                 }
1863                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1864                 {
1865                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1866                         {
1867                                 self.items = self.items | IT_SUPERWEAPON;
1868                                 sprint(self, "^3You now have a superweapon\n");
1869                         }
1870                         else
1871                         {
1872                                 self.superweapons_finished = 0;
1873                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1874                         }
1875                 }
1876                 else
1877                 {
1878                         self.superweapons_finished = 0;
1879                 }
1880         }
1881
1882         if(autocvar_g_nodepthtestplayers)
1883                 self.effects = self.effects | EF_NODEPTHTEST;
1884
1885         if(autocvar_g_fullbrightplayers)
1886                 self.effects = self.effects | EF_FULLBRIGHT;
1887
1888         // midair gamemode: damage only while in the air
1889         // if in midair mode, being on ground grants temporary invulnerability
1890         // (this is so that multishot weapon don't clear the ground flag on the
1891         // first damage in the frame, leaving the player vulnerable to the
1892         // remaining hits in the same frame)
1893         if (self.flags & FL_ONGROUND)
1894         if (g_midair)
1895                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1896
1897         if (time >= game_starttime)
1898         if (time < self.spawnshieldtime)
1899                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1900
1901         MUTATOR_CALLHOOK(PlayerPowerups);
1902 }
1903
1904 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1905 {
1906         if(current > stable)
1907                 return current;
1908         else if(current > stable - 0.25) // when close enough, "snap"
1909                 return stable;
1910         else
1911                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1912 }
1913
1914 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1915 {
1916         if(current < stable)
1917                 return current;
1918         else if(current < stable + 0.25) // when close enough, "snap"
1919                 return stable;
1920         else
1921                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1922 }
1923
1924 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1925 {
1926         if(current > rotstable)
1927         {
1928                 if(rotframetime > 0)
1929                 {
1930                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1931                         current = max(rotstable, current - rotlinear * rotframetime);
1932                 }
1933         }
1934         else if(current < regenstable)
1935         {
1936                 if(regenframetime > 0)
1937                 {
1938                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1939                         current = min(regenstable, current + regenlinear * regenframetime);
1940                 }
1941         }
1942
1943         if(current > limit)
1944                 current = limit;
1945
1946         return current;
1947 }
1948
1949 void player_regen (void)
1950 {
1951         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1952         maxh = autocvar_g_balance_health_rotstable;
1953         maxa = autocvar_g_balance_armor_rotstable;
1954         maxf = autocvar_g_balance_fuel_rotstable;
1955         minh = autocvar_g_balance_health_regenstable;
1956         mina = autocvar_g_balance_armor_regenstable;
1957         minf = autocvar_g_balance_fuel_regenstable;
1958         limith = autocvar_g_balance_health_limit;
1959         limita = autocvar_g_balance_armor_limit;
1960         limitf = autocvar_g_balance_fuel_limit;
1961
1962         max_mod = regen_mod = rot_mod = limit_mod = 1;
1963
1964         if (self.runes & RUNE_REGEN)
1965         {
1966                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1967                 {
1968                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
1969                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
1970                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
1971                 }
1972                 else
1973                 {
1974                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
1975                         max_mod = autocvar_g_balance_rune_regen_hpmod;
1976                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
1977                 }
1978         }
1979         else if (self.runes & CURSE_VENOM)
1980         {
1981                 max_mod = autocvar_g_balance_curse_venom_hpmod;
1982                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1983                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
1984                 else
1985                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
1986                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
1987                 //if (!self.runes & RUNE_REGEN)
1988                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
1989         }
1990         maxh = maxh * max_mod;
1991         //maxa = maxa * max_mod;
1992         //maxf = maxf * max_mod;
1993         minh = minh * max_mod;
1994         //mina = mina * max_mod;
1995         //minf = minf * max_mod;
1996         limith = limith * limit_mod;
1997         limita = limita * limit_mod;
1998         //limitf = limitf * limit_mod;
1999
2000         if(g_lms || g_ca)
2001                 rot_mod = 0;
2002
2003         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2004         {
2005                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2006                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2007
2008                 // if player rotted to death...  die!
2009                 if(self.health < 1)
2010                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2011         }
2012
2013         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2014                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2015 }
2016
2017 float zoomstate_set;
2018 void SetZoomState(float z)
2019 {
2020         if(z != self.zoomstate)
2021         {
2022                 self.zoomstate = z;
2023                 ClientData_Touch(self);
2024         }
2025         zoomstate_set = 1;
2026 }
2027
2028 void GetPressedKeys(void) {
2029         MUTATOR_CALLHOOK(GetPressedKeys);
2030         if (self.movement_x > 0) // get if movement keys are pressed
2031         {       // forward key pressed
2032                 self.pressedkeys |= KEY_FORWARD;
2033                 self.pressedkeys &~= KEY_BACKWARD;
2034         }
2035         else if (self.movement_x < 0)
2036         {       // backward key pressed
2037                 self.pressedkeys |= KEY_BACKWARD;
2038                 self.pressedkeys &~= KEY_FORWARD;
2039         }
2040         else
2041         {       // no x input
2042                 self.pressedkeys &~= KEY_FORWARD;
2043                 self.pressedkeys &~= KEY_BACKWARD;
2044         }
2045
2046         if (self.movement_y > 0)
2047         {       // right key pressed
2048                 self.pressedkeys |= KEY_RIGHT;
2049                 self.pressedkeys &~= KEY_LEFT;
2050         }
2051         else if (self.movement_y < 0)
2052         {       // left key pressed
2053                 self.pressedkeys |= KEY_LEFT;
2054                 self.pressedkeys &~= KEY_RIGHT;
2055         }
2056         else
2057         {       // no y input
2058                 self.pressedkeys &~= KEY_RIGHT;
2059                 self.pressedkeys &~= KEY_LEFT;
2060         }
2061
2062         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2063                 self.pressedkeys |= KEY_JUMP;
2064         else
2065                 self.pressedkeys &~= KEY_JUMP;
2066         if (self.BUTTON_CROUCH)
2067                 self.pressedkeys |= KEY_CROUCH;
2068         else
2069                 self.pressedkeys &~= KEY_CROUCH;
2070
2071         if (self.BUTTON_ATCK)
2072                 self.pressedkeys |= KEY_ATCK;
2073         else
2074                 self.pressedkeys &~= KEY_ATCK;
2075         if (self.BUTTON_ATCK2)
2076                 self.pressedkeys |= KEY_ATCK2;
2077         else
2078                 self.pressedkeys &~= KEY_ATCK2;
2079 }
2080
2081 /*
2082 ======================
2083 spectate mode routines
2084 ======================
2085 */
2086
2087 void SpectateCopy(entity spectatee) {
2088         other = spectatee;
2089         MUTATOR_CALLHOOK(SpectateCopy);
2090         self.armortype = spectatee.armortype;
2091         self.armorvalue = spectatee.armorvalue;
2092         self.ammo_cells = spectatee.ammo_cells;
2093         self.ammo_shells = spectatee.ammo_shells;
2094         self.ammo_nails = spectatee.ammo_nails;
2095         self.ammo_rockets = spectatee.ammo_rockets;
2096         self.ammo_fuel = spectatee.ammo_fuel;
2097         self.clip_load = spectatee.clip_load;
2098         self.clip_size = spectatee.clip_size;
2099         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2100         self.health = spectatee.health;
2101         self.impulse = 0;
2102         self.items = spectatee.items;
2103         self.last_pickup = spectatee.last_pickup;
2104         self.hit_time = spectatee.hit_time;
2105         self.metertime = spectatee.metertime;
2106         self.strength_finished = spectatee.strength_finished;
2107         self.invincible_finished = spectatee.invincible_finished;
2108         self.pressedkeys = spectatee.pressedkeys;
2109         WEPSET_COPY_EE(self, spectatee);
2110         self.switchweapon = spectatee.switchweapon;
2111         self.switchingweapon = spectatee.switchingweapon;
2112         self.weapon = spectatee.weapon;
2113         self.nex_charge = spectatee.nex_charge;
2114         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2115         self.hagar_load = spectatee.hagar_load;
2116         self.minelayer_mines = spectatee.minelayer_mines;
2117         self.punchangle = spectatee.punchangle;
2118         self.view_ofs = spectatee.view_ofs;
2119         self.velocity = spectatee.velocity;
2120         self.dmg_take = spectatee.dmg_take;
2121         self.dmg_save = spectatee.dmg_save;
2122         self.dmg_inflictor = spectatee.dmg_inflictor;
2123         self.v_angle = spectatee.v_angle;
2124         self.angles = spectatee.v_angle;
2125         self.stat_respawn_time = spectatee.stat_respawn_time;
2126         if(!self.BUTTON_USE)
2127                 self.fixangle = TRUE;
2128         setorigin(self, spectatee.origin);
2129         setsize(self, spectatee.mins, spectatee.maxs);
2130         SetZoomState(spectatee.zoomstate);
2131
2132     anticheat_spectatecopy(spectatee);
2133         self.hud = spectatee.hud;
2134         if(spectatee.vehicle)
2135     {
2136         self.fixangle = FALSE;
2137         //self.velocity = spectatee.vehicle.velocity;
2138         self.vehicle_health = spectatee.vehicle_health;
2139         self.vehicle_shield = spectatee.vehicle_shield;
2140         self.vehicle_energy = spectatee.vehicle_energy;
2141         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2142         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2143         self.vehicle_reload1 = spectatee.vehicle_reload1;
2144         self.vehicle_reload2 = spectatee.vehicle_reload2;
2145
2146         msg_entity = self;
2147
2148         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2149             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2150             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2151             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2152
2153         //WriteByte (MSG_ONE, SVC_SETVIEW);
2154         //    WriteEntity(MSG_ONE, self);
2155         //makevectors(spectatee.v_angle);
2156         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2157     }
2158 }
2159
2160 float SpectateUpdate() {
2161         if(!self.enemy)
2162             return 0;
2163
2164         if (self == self.enemy)
2165                 return 0;
2166
2167         if(self.enemy.classname != "player")
2168                 return 0;
2169
2170         SpectateCopy(self.enemy);
2171
2172         return 1;
2173 }
2174
2175
2176 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2177 entity CA_SpectateNext(entity start) {
2178         if (start.team == self.team) {
2179                 return start;
2180         }
2181
2182         other = start;
2183         // continue from current player
2184         while(other && other.team != self.team) {
2185                 other = find(other, classname, "player");
2186         }
2187
2188         if (!other) {
2189                 // restart from begining
2190                 other = find(other, classname, "player");
2191                 while(other && other.team != self.team) {
2192                         other = find(other, classname, "player");
2193                 }
2194         }
2195
2196         return other;
2197 }
2198
2199 float SpectateNext(entity _prefer) {
2200
2201         if(_prefer)
2202                 other = _prefer;
2203         else
2204                 other = find(self.enemy, classname, "player");
2205
2206         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2207                 // CA and ca players when spectating enemies is forbidden
2208                 other = CA_SpectateNext(other);
2209         } else {
2210                 // other modes and ca spectators or spectating enemies is allowed
2211                 if (!other)
2212                         other = find(other, classname, "player");
2213         }
2214
2215         if (other)
2216                 self.enemy = other;
2217
2218         if(self.enemy.classname == "player") {
2219             /*if(self.enemy.vehicle)
2220             {
2221
2222             msg_entity = self;
2223             WriteByte(MSG_ONE, SVC_SETVIEW);
2224             WriteEntity(MSG_ONE, self.enemy);
2225             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2226
2227             self.movetype = MOVETYPE_NONE;
2228             accuracy_resend(self);
2229             }
2230             else
2231             {*/
2232             msg_entity = self;
2233             WriteByte(MSG_ONE, SVC_SETVIEW);
2234             WriteEntity(MSG_ONE, self.enemy);
2235             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2236             self.movetype = MOVETYPE_NONE;
2237             accuracy_resend(self);
2238
2239             if(!SpectateUpdate())
2240                 PutObserverInServer();
2241         //}
2242         return 1;
2243         } else {
2244                 return 0;
2245         }
2246 }
2247
2248 /*
2249 =============
2250 ShowRespawnCountdown()
2251
2252 Update a respawn countdown display.
2253 =============
2254 */
2255 void ShowRespawnCountdown()
2256 {
2257         float number;
2258         if(self.deadflag == DEAD_NO) // just respawned?
2259                 return;
2260         else
2261         {
2262                 number = ceil(self.respawn_time - time);
2263                 if(number <= 0)
2264                         return;
2265                 if(number <= self.respawn_countdown)
2266                 {
2267                         self.respawn_countdown = number - 1;
2268                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2269                                 AnnounceTo(self, strcat(ftos(number), ""));
2270                 }
2271         }
2272 }
2273
2274 .float prevent_join_msgtime;
2275 void LeaveSpectatorMode()
2276 {
2277         if(nJoinAllowed(self)) {
2278                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2279                         self.classname = "player";
2280
2281                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2282                                 JoinBestTeam(self, FALSE, TRUE);
2283
2284                         if(autocvar_g_campaign)
2285                                 campaign_bots_may_start = 1;
2286
2287                         PutClientInServer();
2288
2289                         if(self.classname == "player")
2290                                 bprint ("^4", self.netname, "^4 is playing now\n");
2291
2292                         if(!autocvar_g_campaign)
2293                         if (time < self.jointime + autocvar_welcome_message_time)
2294                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2295
2296                         if (self.prevent_join_msgtime)
2297                         {
2298                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2299                                 self.prevent_join_msgtime = 0;
2300                         }
2301
2302                         return;
2303                 } else {
2304                         if (g_ca && self.caplayer) {
2305                         }       // do nothing
2306                         else
2307                                 stuffcmd(self,"menu_showteamselect\n");
2308                         return;
2309                 }
2310         }
2311         else {
2312                 //player may not join because of g_maxplayers is set
2313                 if (time - self.prevent_join_msgtime > 2)
2314                 {
2315                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2316                         self.prevent_join_msgtime = time;
2317                 }
2318         }
2319 }
2320
2321 /**
2322  * Determines whether the player is allowed to join. This depends on cvar
2323  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2324  * it checks whether the number of currently playing players exceeds g_maxplayers.
2325  * @return int number of free slots for players, 0 if none
2326  */
2327 float nJoinAllowed(entity ignore) {
2328         if(!ignore)
2329         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2330         // so report 0 free slots if restricted
2331         {
2332                 if(autocvar_g_forced_team_otherwise == "spectate")
2333                         return 0;
2334                 if(autocvar_g_forced_team_otherwise == "spectator")
2335                         return 0;
2336         }
2337
2338         if(self.team_forced < 0)
2339                 return 0; // forced spectators can never join
2340
2341         // TODO simplify this
2342         entity e;
2343         float totalClients = 0;
2344         FOR_EACH_CLIENT(e)
2345                 if(e != ignore)
2346                         totalClients += 1;
2347
2348         if (!autocvar_g_maxplayers)
2349                 return maxclients - totalClients;
2350
2351         float currentlyPlaying = 0;
2352         FOR_EACH_REALPLAYER(e)
2353                 currentlyPlaying += 1;
2354
2355         if(currentlyPlaying < autocvar_g_maxplayers)
2356                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2357
2358         return 0;
2359 }
2360
2361 /**
2362  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2363  * g_maxplayers_spectator_blocktime seconds
2364  */
2365 void checkSpectatorBlock() {
2366         if(self.classname == "spectator" || self.classname == "observer") {
2367                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2368                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2369                         dropclient(self);
2370                 }
2371         }
2372 }
2373
2374 .float motd_actived_time; // used for both motd and campaign_message
2375 void PrintWelcomeMessage()
2376 {
2377         if (self.motd_actived_time == 0) { // is there already a message showing?
2378                 if (autocvar_g_campaign) {
2379                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2380                                 self.motd_actived_time = time;
2381                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2382                         }
2383                 } else {
2384                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2385                                 self.motd_actived_time = time;
2386                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2387                         }
2388                 }
2389         } else { // showing MOTD or campaign message
2390                 if (autocvar_g_campaign) {
2391                         if (self.BUTTON_INFO)
2392                                 self.motd_actived_time = time;
2393                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2394                                 self.motd_actived_time = 0;
2395                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2396                         }
2397                 } else {
2398                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2399                                 if (self.BUTTON_INFO)
2400                                         self.motd_actived_time = time;
2401                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2402                                         self.motd_actived_time = 0;
2403                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2404                                 }
2405                         }
2406                 }
2407         }
2408 }
2409
2410 void ObserverThink()
2411 {
2412         float prefered_movetype;
2413         if (self.flags & FL_JUMPRELEASED) {
2414                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2415                         self.flags &~= FL_JUMPRELEASED;
2416                         self.flags |= FL_SPAWNING;
2417                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2418                         self.flags &~= FL_JUMPRELEASED;
2419                         if(SpectateNext(world) == 1) {
2420                                 self.classname = "spectator";
2421                         }
2422                 } else {
2423                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2424                         if (self.movetype != prefered_movetype)
2425                                 self.movetype = prefered_movetype;
2426                 }
2427         } else {
2428                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2429                         self.flags |= FL_JUMPRELEASED;
2430                         if(self.flags & FL_SPAWNING)
2431                         {
2432                                 self.flags &~= FL_SPAWNING;
2433                                 LeaveSpectatorMode();
2434                                 return;
2435                         }
2436                 }
2437         }
2438
2439         PrintWelcomeMessage();
2440 }
2441
2442 void SpectatorThink()
2443 {
2444         if (self.flags & FL_JUMPRELEASED) {
2445                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2446                         self.flags &~= FL_JUMPRELEASED;
2447                         self.flags |= FL_SPAWNING;
2448                 } else if(self.BUTTON_ATCK) {
2449                         self.flags &~= FL_JUMPRELEASED;
2450                         if(SpectateNext(world) == 1) {
2451                                 self.classname = "spectator";
2452                         } else {
2453                                 self.classname = "observer";
2454                                 PutClientInServer();
2455                         }
2456                 } else if (self.BUTTON_ATCK2) {
2457                         self.flags &~= FL_JUMPRELEASED;
2458                         self.classname = "observer";
2459                         PutClientInServer();
2460                 } else {
2461                         if(!SpectateUpdate())
2462                                 PutObserverInServer();
2463                 }
2464         } else {
2465                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2466                         self.flags |= FL_JUMPRELEASED;
2467                         if(self.flags & FL_SPAWNING)
2468                         {
2469                                 self.flags &~= FL_SPAWNING;
2470                                 LeaveSpectatorMode();
2471                                 return;
2472                         }
2473                 }
2474                 if(!SpectateUpdate())
2475                         PutObserverInServer();
2476         }
2477
2478         PrintWelcomeMessage();
2479         self.flags |= FL_CLIENT | FL_NOTARGET;
2480 }
2481
2482 void PlayerUseKey()
2483 {
2484         if(self.classname != "player")
2485                 return;
2486
2487         if(self.vehicle)
2488         {
2489         vehicles_exit(VHEF_NORMAL);
2490         return;
2491         }
2492
2493         // a use key was pressed; call handlers
2494         MUTATOR_CALLHOOK(PlayerUseKey);
2495 }
2496
2497 .float touchexplode_time;
2498
2499 /*
2500 =============
2501 PlayerPreThink
2502
2503 Called every frame for each client before the physics are run
2504 =============
2505 */
2506 .float usekeypressed;
2507 void() nexball_setstatus;
2508 .float items_added;
2509 void PlayerPreThink (void)
2510 {
2511         WarpZone_PlayerPhysics_FixVAngle();
2512
2513         self.stat_game_starttime = game_starttime;
2514         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2515         self.stat_leadlimit = autocvar_leadlimit;
2516
2517         self.stat_respawn_time = self.respawn_time;
2518
2519         if(frametime)
2520         {
2521                 // physics frames: update anticheat stuff
2522                 anticheat_prethink();
2523         }
2524
2525         if(blockSpectators && frametime)
2526                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2527                 checkSpectatorBlock();
2528
2529         zoomstate_set = 0;
2530
2531         if(self.netname_previous != self.netname)
2532         {
2533                 if(autocvar_sv_eventlog)
2534                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2535                 if(self.netname_previous)
2536                         strunzone(self.netname_previous);
2537                 self.netname_previous = strzone(self.netname);
2538         }
2539
2540         // version nagging
2541         if(self.version_nagtime)
2542                 if(self.cvar_g_xonoticversion)
2543                         if(time > self.version_nagtime)
2544                         {
2545                                 // don't notify git users
2546                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2547                                 {
2548                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2549                                         {
2550                                                 // notify release users if connecting to git
2551                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2552                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2553                                         }
2554                                         else
2555                                         {
2556                                                 float r;
2557                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2558                                                 if(r < 0)
2559                                                 {
2560                                                         // give users new version
2561                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2562                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2563                                                 }
2564                                                 else if(r > 0)
2565                                                 {
2566                                                         // notify users about old server version
2567                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2568                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2569                                                 }
2570                                         }
2571                                 }
2572                                 self.version_nagtime = 0;
2573                         }
2574
2575         // GOD MODE info
2576         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2577         {
2578                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2579                 self.max_armorvalue = 0;
2580         }
2581
2582 #ifdef TETRIS
2583         if (TetrisPreFrame())
2584                 return;
2585 #endif
2586
2587         MUTATOR_CALLHOOK(PlayerPreThink);
2588
2589         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2590         {
2591                 if(self.BUTTON_USE && !self.usekeypressed)
2592                         PlayerUseKey();
2593                 self.usekeypressed = self.BUTTON_USE;
2594         }
2595
2596         PrintWelcomeMessage();
2597
2598         if(self.classname == "player") {
2599 //              if(self.netname == "Wazat")
2600 //                      bprint(self.classname, "\n");
2601
2602                 CheckRules_Player();
2603
2604                 if (intermission_running)
2605                 {
2606                         IntermissionThink ();   // otherwise a button could be missed between
2607                         return;                                 // the think tics
2608                 }
2609
2610                 //don't allow the player to turn around while game is paused!
2611                 if(timeout_status == TIMEOUT_ACTIVE) {
2612                         // FIXME turn this into CSQC stuff
2613                         self.v_angle = self.lastV_angle;
2614                         self.angles = self.lastV_angle;
2615                         self.fixangle = TRUE;
2616                 }
2617
2618                 if(frametime)
2619                 {
2620 #ifndef NO_LEGACY_NETWORKING
2621                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2622 #endif
2623
2624                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2625                         {
2626                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2627                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2628                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2629
2630                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2631                                 {
2632                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2633                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2634                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2635                                 }
2636                         }
2637                         else
2638                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2639
2640                         player_powerups();
2641                 }
2642
2643                 if (g_minstagib)
2644                         minstagib_ammocheck();
2645
2646                 if (self.deadflag != DEAD_NO)
2647                 {
2648                         float button_pressed, force_respawn;
2649                         if(self.personal && g_race_qualifying)
2650                         {
2651                                 if(time > self.respawn_time)
2652                                 {
2653                                         self.respawn_time = time + 1; // only retry once a second
2654                                         respawn();
2655                                         self.impulse = 141;
2656                                 }
2657                         }
2658                         else
2659                         {
2660                                 if(frametime)
2661                                         player_anim();
2662                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2663                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2664                                 if (self.deadflag == DEAD_DYING)
2665                                 {
2666                                         if(force_respawn)
2667                                                 self.deadflag = DEAD_RESPAWNING;
2668                                         else if(!button_pressed)
2669                                                 self.deadflag = DEAD_DEAD;
2670                                 }
2671                                 else if (self.deadflag == DEAD_DEAD)
2672                                 {
2673                                         if(button_pressed)
2674                                                 self.deadflag = DEAD_RESPAWNABLE;
2675                                 }
2676                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2677                                 {
2678                                         if(!button_pressed)
2679                                                 self.deadflag = DEAD_RESPAWNING;
2680                                 }
2681                                 else if (self.deadflag == DEAD_RESPAWNING)
2682                                 {
2683                                         if(time > self.respawn_time)
2684                                         {
2685                                                 self.respawn_time = time + 1; // only retry once a second
2686                                                 respawn();
2687                                         }
2688                                 }
2689                                 ShowRespawnCountdown();
2690                         }
2691
2692                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2693                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2694                                 self.stat_respawn_time *= -1;
2695
2696                         return;
2697                 }
2698                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2699                 // so (self.deadflag == DEAD_NO) is always true in the code below
2700
2701                 if(g_touchexplode)
2702                 if(time > self.touchexplode_time)
2703                 if(self.classname == "player")
2704                 if(self.deadflag == DEAD_NO)
2705                 if not(IS_INDEPENDENT_PLAYER(self))
2706                 FOR_EACH_PLAYER(other) if(self != other)
2707                 {
2708                         if(time > other.touchexplode_time)
2709                         if(other.deadflag == DEAD_NO)
2710                         if not(IS_INDEPENDENT_PLAYER(other))
2711                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2712                         {
2713                                 PlayerTouchExplode(self, other);
2714                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2715                         }
2716                 }
2717
2718                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2719                 {
2720                         vector dist;
2721
2722                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2723                         dist = self.prevorigin - self.origin;
2724                         dist_z = 0;
2725                         self.lms_traveled_distance += fabs(vlen(dist));
2726
2727                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2728                         {
2729                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2730                                 self.lms_traveled_distance = 0;
2731                         }
2732
2733                         if(time > self.lms_nextcheck)
2734                         {
2735                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2736                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2737                                 {
2738                                         centerprint(self, autocvar_g_lms_campcheck_message);
2739                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2740                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2741                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2742                                 }
2743                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2744                                 self.lms_traveled_distance = 0;
2745                         }
2746                 }
2747
2748                 self.prevorigin = self.origin;
2749
2750                 if (!self.vehicle)
2751                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x && !self.freezetag_frozen) // prevent crouching if using melee attack
2752                 {
2753                         if (!self.crouch)
2754                         {
2755                                 self.crouch = TRUE;
2756                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2757                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2758                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2759                         }
2760                 }
2761                 else
2762                 {
2763                         if (self.crouch)
2764                         {
2765                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2766                                 if (!trace_startsolid)
2767                                 {
2768                                         self.crouch = FALSE;
2769                                         self.view_ofs = PL_VIEW_OFS;
2770                                         setsize (self, PL_MIN, PL_MAX);
2771                                 }
2772                         }
2773                 }
2774
2775                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2776                 {
2777                         if(self.bloodloss_timer < time)
2778                         {
2779                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2780                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2781                         }
2782                 }
2783
2784                 FixPlayermodel();
2785
2786                 GrapplingHookFrame();
2787
2788                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2789                 //if(frametime)
2790                 {
2791                         self.items &~= self.items_added;
2792
2793                         W_WeaponFrame();
2794
2795                         self.items_added = 0;
2796                         if(self.items & IT_JETPACK)
2797                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2798                                         self.items_added |= IT_FUEL;
2799
2800                         self.items |= self.items_added;
2801                 }
2802
2803                 player_regen();
2804
2805                 // rot nex charge to the charge limit
2806                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2807                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2808
2809                 if(frametime)
2810                         player_anim();
2811
2812                 if(g_nexball)
2813                         nexball_setstatus();
2814
2815                 // secret status
2816                 secrets_setstatus();
2817
2818                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2819
2820                 //self.angles_y=self.v_angle_y + 90;   // temp
2821         } else if(gameover) {
2822                 if (intermission_running)
2823                         IntermissionThink ();   // otherwise a button could be missed between
2824                 return;
2825         } else if(self.classname == "observer") {
2826                 ObserverThink();
2827         } else if(self.classname == "spectator") {
2828                 SpectatorThink();
2829         }
2830
2831         if(!zoomstate_set)
2832                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2833
2834         float oldspectatee_status;
2835         oldspectatee_status = self.spectatee_status;
2836         if(self.classname == "spectator")
2837                 self.spectatee_status = num_for_edict(self.enemy);
2838         else if(self.classname == "observer")
2839                 self.spectatee_status = num_for_edict(self);
2840         else
2841                 self.spectatee_status = 0;
2842         if(self.spectatee_status != oldspectatee_status)
2843         {
2844                 ClientData_Touch(self);
2845                 if(g_race || g_cts)
2846                         race_InitSpectator();
2847         }
2848
2849         if(self.teamkill_soundtime)
2850         if(time > self.teamkill_soundtime)
2851         {
2852                 self.teamkill_soundtime = 0;
2853
2854                 entity oldpusher, oldself;
2855
2856                 oldself = self; self = self.teamkill_soundsource;
2857                 oldpusher = self.pusher; self.pusher = oldself;
2858
2859                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2860
2861                 self.pusher = oldpusher;
2862                 self = oldself;
2863         }
2864
2865         if(self.taunt_soundtime)
2866         if(time > self.taunt_soundtime)
2867         {
2868                 self.taunt_soundtime = 0;
2869                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2870         }
2871
2872         target_voicescript_next(self);
2873
2874         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2875         if(!self.weapon)
2876                 self.clip_load = self.clip_size = 0;
2877 }
2878
2879 float isInvisibleString(string s)
2880 {
2881         float i, n, c;
2882         s = strdecolorize(s);
2883         for((i = 0), (n = strlen(s)); i < n; ++i)
2884         {
2885                 c = str2chr(s, i);
2886                 switch(c)
2887                 {
2888                         case 0:
2889                         case 32: // space
2890                                 break;
2891                         case 192: // charmap space
2892                                 if (!autocvar_utf8_enable)
2893                                         break;
2894                                 return FALSE;
2895                         case 160: // space in unicode fonts
2896                         case 0xE000 + 192: // utf8 charmap space
2897                                 if (autocvar_utf8_enable)
2898                                         break;
2899                         default:
2900                                 return FALSE;
2901                 }
2902         }
2903         return TRUE;
2904 }
2905
2906 /*
2907 =============
2908 PlayerPostThink
2909
2910 Called every frame for each client after the physics are run
2911 =============
2912 */
2913 .float idlekick_lasttimeleft;
2914 .entity showheadshotbbox;
2915 void showheadshotbbox_think()
2916 {
2917         if(self.owner.showheadshotbbox != self)
2918         {
2919                 remove(self);
2920                 return;
2921         }
2922         self.nextthink = time;
2923         setorigin(self, self.owner.origin);
2924         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2925 }
2926 void PlayerPostThink (void)
2927 {
2928         // Savage: Check for nameless players
2929         if (isInvisibleString(self.netname)) {
2930                 self.netname = "Player";
2931                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2932         }
2933
2934         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2935         {
2936                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2937                 {
2938                         if(self.idlekick_lasttimeleft)
2939                         {
2940                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2941                                 self.idlekick_lasttimeleft = 0;
2942                         }
2943                 }
2944                 else
2945                 {
2946                         float timeleft;
2947                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2948                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2949                         {
2950                                 if(!self.idlekick_lasttimeleft)
2951                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2952                         }
2953                         if(timeleft <= 0)
2954                         {
2955                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2956                                 AnnounceTo(self, "terminated");
2957                                 dropclient(self);
2958                                 return;
2959                         }
2960                         else if(timeleft <= 10)
2961                         {
2962                                 if(timeleft != self.idlekick_lasttimeleft)
2963                                         AnnounceTo(self, ftos(timeleft));
2964                                 self.idlekick_lasttimeleft = timeleft;
2965                         }
2966                 }
2967         }
2968
2969 #ifdef TETRIS
2970         if(self.impulse == 100)
2971                 ImpulseCommands();
2972         if (!TetrisPostFrame())
2973         {
2974 #endif
2975
2976         CheatFrame();
2977
2978         //CheckPlayerJump();
2979
2980         if(self.classname == "player") {
2981                 CheckRules_Player();
2982                 UpdateChatBubble();
2983                 if (self.impulse)
2984                         ImpulseCommands();
2985                 if (intermission_running)
2986                         return;         // intermission or finale
2987                 GetPressedKeys();
2988         } else if (self.classname == "observer") {
2989                 //do nothing
2990         } else if (self.classname == "spectator") {
2991                 //do nothing
2992         }
2993
2994 #ifdef TETRIS
2995         }
2996 #endif
2997
2998         /*
2999         float i;
3000         for(i = 0; i < 1000; ++i)
3001         {
3002                 vector end;
3003                 end = self.origin + '0 0 1024' + 512 * randomvec();
3004                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3005                 if(trace_fraction < 1)
3006                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3007                 {
3008                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3009                         break;
3010                 }
3011         }
3012         */
3013
3014         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3015
3016         if(self.waypointsprite_attachedforcarrier)
3017                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3018
3019         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3020         {
3021                 if(!self.showheadshotbbox)
3022                 {
3023                         self.showheadshotbbox = spawn();
3024                         self.showheadshotbbox.classname = "headshotbbox";
3025                         self.showheadshotbbox.owner = self;
3026                         self.showheadshotbbox.think = showheadshotbbox_think;
3027                         self.showheadshotbbox.nextthink = time;
3028                         self = self.showheadshotbbox;
3029                         self.think();
3030                         self = self.owner;
3031                 }
3032         }
3033         else
3034         {
3035                 if(self.showheadshotbbox)
3036                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3037                 remove(self.showheadshotbbox);
3038         }
3039
3040         playerdemo_write();
3041
3042         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3043         {
3044                 if(!self.stored_netname)
3045                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3046                 if(self.stored_netname != self.netname)
3047                 {
3048                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3049                         strunzone(self.stored_netname);
3050                         self.stored_netname = strzone(self.netname);
3051                 }
3052         }
3053
3054         /*
3055         if(g_race)
3056                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3057         */
3058
3059         CSQCMODEL_AUTOUPDATE();
3060 }