qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "waypointsprites.qh"
   4
   5 #include "anticheat.qh"
   6 #include "cl_impulse.qh"
   7 #include "cl_player.qh"
   8 #include "ent_cs.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "g_damage.qh"
  16 #include "g_hook.qh"
  17 #include "command/common.qh"
  18 #include "cheats.qh"
  19 #include "g_world.qh"
  20 #include "race.qh"
  21 #include "antilag.qh"
  22 #include "campaign.qh"
  23 #include "command/common.qh"
  24
  25 #include "bot/bot.qh"
  26 #include "bot/navigation.qh"
  27
  28 #include "vehicles/vehicle.qh"
  29
  30 #include "weapons/hitplot.qh"
  31 #include "weapons/weaponsystem.qh"
  32
  33 #include "../common/net_notice.qh"
  34 #include "../common/physics.qh"
  35
  36 #include "../common/triggers/subs.qh"
  37 #include "../common/triggers/triggers.qh"
  38 #include "../common/triggers/trigger/secret.qh"
  39
  40 #include "../common/items/inventory.qh"
  41
  42 #include "../common/monsters/sv_monsters.qh"
  43
  44 #include "../warpzonelib/server.qh"
  45
  46
  47 void send_CSQC_teamnagger() {
  48         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  49         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  50 }
  51
  52 float ClientData_Send(entity to, int sf)
  53 {
  54         if(to != self.owner)
  55         {
  56                 error("wtf");
  57                 return false;
  58         }
  59
  60         entity e;
  61
  62         e = to;
  63         if(IS_SPEC(to))
  64                 e = to.enemy;
  65
  66         sf = 0;
  67
  68         if(e.race_completed)
  69                 sf |= 1; // forced scoreboard
  70         if(to.spectatee_status)
  71                 sf |= 2; // spectator ent number follows
  72         if(e.zoomstate)
  73                 sf |= 4; // zoomed
  74         if(e.porto_v_angle_held)
  75                 sf |= 8; // angles held
  76
  77         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  78         WriteByte(MSG_ENTITY, sf);
  79
  80         if(sf & 2)
  81                 WriteByte(MSG_ENTITY, to.spectatee_status);
  82
  83         if(sf & 8)
  84         {
  85                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  86                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  87         }
  88
  89         return true;
  90 }
  91
  92 void ClientData_Attach()
  93 {
  94         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  95         self.clientdata.drawonlytoclient = self;
  96         self.clientdata.owner = self;
  97 }
  98
  99 void ClientData_Detach()
 100 {
 101         remove(self.clientdata);
 102         self.clientdata = world;
 103 }
 104
 105 void ClientData_Touch(entity e)
 106 {
 107         e.clientdata.SendFlags = 1;
 108
 109         // make it spectatable
 110         entity e2;
 111         FOR_EACH_REALCLIENT(e2)
 112         {
 113                 if(e2 != e)
 114                         if(IS_SPEC(e2))
 115                                 if(e2.enemy == e)
 116                                         e2.clientdata.SendFlags = 1;
 117         }
 118 }
 119
 120 .string netname_previous;
 121
 122 void SetSpectator(entity player, entity spectatee);
 123
 124
 125 /*
 126 =============
 127 CheckPlayerModel
 128
 129 Checks if the argument string can be a valid playermodel.
 130 Returns a valid one in doubt.
 131 =============
 132 */
 133 string FallbackPlayerModel;
 134 string CheckPlayerModel(string plyermodel) {
 135         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 136         {
 137                 // note: we cannot summon Don Strunzone here, some player may
 138                 // still have the model string set. In case anyone manages how
 139                 // to change a cvar default, we'll have a small leak here.
 140                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 141         }
 142         // only in right path
 143         if( substring(plyermodel,0,14) != "models/player/")
 144                 return FallbackPlayerModel;
 145         // only good file extensions
 146         if(substring(plyermodel,-4,4) != ".zym")
 147         if(substring(plyermodel,-4,4) != ".dpm")
 148         if(substring(plyermodel,-4,4) != ".iqm")
 149         if(substring(plyermodel,-4,4) != ".md3")
 150         if(substring(plyermodel,-4,4) != ".psk")
 151                 return FallbackPlayerModel;
 152         // forbid the LOD models
 153         if(substring(plyermodel, -9,5) == "_lod1")
 154                 return FallbackPlayerModel;
 155         if(substring(plyermodel, -9,5) == "_lod2")
 156                 return FallbackPlayerModel;
 157         if(plyermodel != strtolower(plyermodel))
 158                 return FallbackPlayerModel;
 159         // also, restrict to server models
 160         if(autocvar_sv_servermodelsonly)
 161         {
 162                 if(!fexists(plyermodel))
 163                         return FallbackPlayerModel;
 164         }
 165         return plyermodel;
 166 }
 167
 168 void setplayermodel(entity e, string modelname)
 169 {
 170         precache_model(modelname);
 171         setmodel(e, modelname);
 172         player_setupanimsformodel();
 173         UpdatePlayerSounds();
 174 }
 175
 176 /*
 177 =============
 178 PutObserverInServer
 179
 180 putting a client as observer in the server
 181 =============
 182 */
 183 void FixPlayermodel();
 184 void PutObserverInServer (void)
 185 {
 186         entity  spot;
 187     self.hud = HUD_NORMAL;
 188
 189         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 190
 191         spot = SelectSpawnPoint (true);
 192         if(!spot)
 193                 error("No spawnpoints for observers?!?\n");
 194         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 195
 196         if(IS_REAL_CLIENT(self))
 197         {
 198                 msg_entity = self;
 199                 WriteByte(MSG_ONE, SVC_SETVIEW);
 200                 WriteEntity(MSG_ONE, self);
 201         }
 202
 203         self.frags = FRAGS_SPECTATOR;
 204
 205         MUTATOR_CALLHOOK(MakePlayerObserver);
 206
 207         Portal_ClearAll(self);
 208
 209         Unfreeze(self);
 210
 211         if(self.alivetime)
 212         {
 213                 if(!warmup_stage)
 214                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 215                 self.alivetime = 0;
 216         }
 217
 218         if(self.vehicle)
 219                 vehicles_exit(VHEF_RELESE);
 220
 221         WaypointSprite_PlayerDead();
 222
 223         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 224                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 225
 226         if(self.killcount != -666)
 227         {
 228                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 229                 if(!intermission_running)
 230                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 231                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 232
 233                 if(self.just_joined == false) {
 234                         LogTeamchange(self.playerid, -1, 4);
 235                 } else
 236                         self.just_joined = false;
 237         }
 238
 239         PlayerScore_Clear(self); // clear scores when needed
 240
 241         accuracy_resend(self);
 242
 243         self.spectatortime = time;
 244
 245         self.classname = "observer";
 246         self.iscreature = false;
 247         self.teleportable = TELEPORT_SIMPLE;
 248         self.damagedbycontents = false;
 249         self.health = -666;
 250         self.takedamage = DAMAGE_NO;
 251         self.solid = SOLID_NOT;
 252         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 253         self.flags = FL_CLIENT | FL_NOTARGET;
 254         self.armorvalue = 666;
 255         self.effects = 0;
 256         self.armorvalue = autocvar_g_balance_armor_start;
 257         self.pauserotarmor_finished = 0;
 258         self.pauserothealth_finished = 0;
 259         self.pauseregen_finished = 0;
 260         self.damageforcescale = 0;
 261         self.death_time = 0;
 262         self.respawn_flags = 0;
 263         self.respawn_time = 0;
 264         self.stat_respawn_time = 0;
 265         self.alpha = 0;
 266         self.scale = 0;
 267         self.fade_time = 0;
 268         self.pain_frame = 0;
 269         self.pain_finished = 0;
 270         self.strength_finished = 0;
 271         self.invincible_finished = 0;
 272         self.superweapons_finished = 0;
 273         self.pushltime = 0;
 274         self.istypefrag = 0;
 275         self.think = func_null;
 276         self.nextthink = 0;
 277         self.hook_time = 0;
 278         self.deadflag = DEAD_NO;
 279         self.angles = spot.angles;
 280         self.angles_z = 0;
 281         self.fixangle = true;
 282         self.crouch = false;
 283         self.revival_time = 0;
 284
 285         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 286         self.prevorigin = self.origin;
 287         self.items = 0;
 288         self.weapons = '0 0 0';
 289         self.model = "";
 290         FixPlayermodel();
 291         setmodel(self, "null");
 292         self.drawonlytoclient = self;
 293
 294         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 295         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 296
 297         self.weapon = 0;
 298         self.weaponname = "";
 299         self.switchingweapon = 0;
 300         self.weaponmodel = "";
 301         self.weaponentity = world;
 302         self.exteriorweaponentity = world;
 303         self.killcount = -666;
 304         self.velocity = '0 0 0';
 305         self.avelocity = '0 0 0';
 306         self.punchangle = '0 0 0';
 307         self.punchvector = '0 0 0';
 308         self.oldvelocity = self.velocity;
 309         self.fire_endtime = -1;
 310         self.event_damage = func_null;
 311 }
 312
 313 .float model_randomizer;
 314 void FixPlayermodel()
 315 {
 316         string defaultmodel;
 317         float defaultskin, chmdl, oldskin, n, i;
 318         vector m1, m2;
 319
 320         defaultmodel = "";
 321         defaultskin = 0;
 322         chmdl = false;
 323
 324         if(autocvar_sv_defaultcharacter)
 325         {
 326                 if(teamplay)
 327                 {
 328                         string s;
 329                         s = Static_Team_ColorName_Lower(self.team);
 330                         if(s != "neutral")
 331                         {
 332                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 333                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 334                         }
 335                 }
 336
 337                 if(defaultmodel == "")
 338                 {
 339                         defaultmodel = autocvar_sv_defaultplayermodel;
 340                         defaultskin = autocvar_sv_defaultplayerskin;
 341                 }
 342
 343                 n = tokenize_console(defaultmodel);
 344                 if(n > 0)
 345                 {
 346                         defaultmodel = argv(floor(n * self.model_randomizer));
 347                         // However, do NOT randomize if the player-selected model is in the list.
 348                         for (i = 0; i < n; ++i)
 349                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 350                                         defaultmodel = argv(i);
 351                 }
 352
 353                 i = strstrofs(defaultmodel, ":", 0);
 354                 if(i >= 0)
 355                 {
 356                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 357                         defaultmodel = substring(defaultmodel, 0, i);
 358                 }
 359         }
 360
 361         if(defaultmodel != "")
 362         {
 363                 if (defaultmodel != self.model)
 364                 {
 365                         m1 = self.mins;
 366                         m2 = self.maxs;
 367                         setplayermodel (self, defaultmodel);
 368                         setsize (self, m1, m2);
 369                         chmdl = true;
 370                 }
 371
 372                 oldskin = self.skin;
 373                 self.skin = defaultskin;
 374         } else {
 375                 if (self.playermodel != self.model || self.playermodel == "")
 376                 {
 377                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 378                         m1 = self.mins;
 379                         m2 = self.maxs;
 380                         setplayermodel (self, self.playermodel);
 381                         setsize (self, m1, m2);
 382                         chmdl = true;
 383                 }
 384
 385                 oldskin = self.skin;
 386                 self.skin = stof(self.playerskin);
 387         }
 388
 389         if(chmdl || oldskin != self.skin) // model or skin has changed
 390         {
 391                 self.species = player_getspecies(); // update species
 392                 UpdatePlayerSounds(); // update skin sounds
 393         }
 394
 395         if(!teamplay)
 396                 if(strlen(autocvar_sv_defaultplayercolors))
 397                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 398                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 399 }
 400
 401 /*
 402 =============
 403 PutClientInServer
 404
 405 Called when a client spawns in the server
 406 =============
 407 */
 408 void PutClientInServer (void)
 409 {
 410         if(IS_BOT_CLIENT(self))
 411                 self.classname = "player";
 412         else if(IS_REAL_CLIENT(self))
 413         {
 414                 msg_entity = self;
 415                 WriteByte(MSG_ONE, SVC_SETVIEW);
 416                 WriteEntity(MSG_ONE, self);
 417         }
 418
 419         SetSpectator(self, world);
 420
 421         // reset player keys
 422         self.itemkeys = 0;
 423
 424         MUTATOR_CALLHOOK(PutClientInServer);
 425
 426         if(gameover)
 427                 self.classname = "observer";
 428
 429         if(IS_PLAYER(self))
 430         {
 431                 entity spot, oldself;
 432
 433                 accuracy_resend(self);
 434
 435                 if(self.team < 0)
 436                         JoinBestTeam(self, false, true);
 437
 438                 spot = SelectSpawnPoint (false);
 439                 if(!spot)
 440                 {
 441                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 442                         return; // spawn failed
 443                 }
 444
 445                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 446
 447                 if(self.vehicle)
 448                         vehicles_exit(VHEF_RELESE);
 449
 450                 self.classname = "player";
 451                 self.wasplayer = true;
 452                 self.iscreature = true;
 453                 self.teleportable = TELEPORT_NORMAL;
 454                 self.damagedbycontents = true;
 455                 self.movetype = MOVETYPE_WALK;
 456                 self.solid = SOLID_SLIDEBOX;
 457                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 458                 if(autocvar_g_playerclip_collisions)
 459                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 460                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 461                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 462                 self.frags = FRAGS_PLAYER;
 463                 if(INDEPENDENT_PLAYERS)
 464                         MAKE_INDEPENDENT_PLAYER(self);
 465                 self.flags = FL_CLIENT;
 466                 if(autocvar__notarget)
 467                         self.flags |= FL_NOTARGET;
 468                 self.takedamage = DAMAGE_AIM;
 469                 self.effects = 0;
 470                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 471                 self.air_finished = time + 12;
 472                 self.dmg = 2;
 473                 if(WEP_CVAR(vortex, charge))
 474                 {
 475                         if(WEP_CVAR_SEC(vortex, chargepool))
 476                                 self.vortex_chargepool_ammo = 1;
 477                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 478                 }
 479
 480                 if(warmup_stage)
 481                 {
 482                         self.ammo_shells = warmup_start_ammo_shells;
 483                         self.ammo_nails = warmup_start_ammo_nails;
 484                         self.ammo_rockets = warmup_start_ammo_rockets;
 485                         self.ammo_cells = warmup_start_ammo_cells;
 486                         self.ammo_plasma = warmup_start_ammo_plasma;
 487                         self.ammo_fuel = warmup_start_ammo_fuel;
 488                         self.health = warmup_start_health;
 489                         self.armorvalue = warmup_start_armorvalue;
 490                         self.weapons = WARMUP_START_WEAPONS;
 491                 }
 492                 else
 493                 {
 494                         self.ammo_shells = start_ammo_shells;
 495                         self.ammo_nails = start_ammo_nails;
 496                         self.ammo_rockets = start_ammo_rockets;
 497                         self.ammo_cells = start_ammo_cells;
 498                         self.ammo_plasma = start_ammo_plasma;
 499                         self.ammo_fuel = start_ammo_fuel;
 500                         self.health = start_health;
 501                         self.armorvalue = start_armorvalue;
 502                         self.weapons = start_weapons;
 503                 }
 504
 505                 if(self.weapons & WEPSET_SUPERWEAPONS)
 506                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 507                 else
 508                         self.superweapons_finished = 0;
 509
 510                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 511                 {
 512                         if(g_weaponarena_random_with_blaster)
 513                                 self.weapons &= ~WEPSET_BLASTER;
 514                         W_RandomWeapons(self, g_weaponarena_random);
 515                         if(g_weaponarena_random_with_blaster)
 516                                 self.weapons |= WEPSET_BLASTER;
 517                 }
 518
 519                 self.items = start_items;
 520
 521                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 522                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 523                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 524                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 525                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 526                 //extend the pause of rotting if client was reset at the beginning of the countdown
 527                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 528                         self.spawnshieldtime += game_starttime - time;
 529                         self.pauserotarmor_finished += game_starttime - time;
 530                         self.pauserothealth_finished += game_starttime - time;
 531                         self.pauseregen_finished += game_starttime - time;
 532                 }
 533                 self.damageforcescale = 2;
 534                 self.death_time = 0;
 535                 self.respawn_flags = 0;
 536                 self.respawn_time = 0;
 537                 self.stat_respawn_time = 0;
 538                 self.scale = autocvar_sv_player_scale;
 539                 self.fade_time = 0;
 540                 self.pain_frame = 0;
 541                 self.pain_finished = 0;
 542                 self.strength_finished = 0;
 543                 self.invincible_finished = 0;
 544                 self.pushltime = 0;
 545                 // players have no think function
 546                 self.think = func_null;
 547                 self.nextthink = 0;
 548                 self.hook_time = 0;
 549                 self.dmg_team = 0;
 550                 self.ballistics_density = autocvar_g_ballistics_density_player;
 551
 552                 self.metertime = 0;
 553
 554                 self.deadflag = DEAD_NO;
 555
 556                 self.angles = spot.angles;
 557
 558                 self.angles_z = 0; // never spawn tilted even if the spot says to
 559                 if(IS_BOT_CLIENT(self))
 560                         self.v_angle = self.angles;
 561                 self.fixangle = true; // turn this way immediately
 562                 self.velocity = '0 0 0';
 563                 self.avelocity = '0 0 0';
 564                 self.punchangle = '0 0 0';
 565                 self.punchvector = '0 0 0';
 566                 self.oldvelocity = self.velocity;
 567                 self.fire_endtime = -1;
 568                 self.revival_time = 0;
 569
 570                 entity spawnevent = spawn();
 571                 spawnevent.owner = self;
 572                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 573
 574                 // Cut off any still running player sounds.
 575                 stopsound(self, CH_PLAYER_SINGLE);
 576
 577                 self.model = "";
 578                 FixPlayermodel();
 579                 self.drawonlytoclient = world;
 580
 581                 self.crouch = false;
 582                 self.view_ofs = PL_VIEW_OFS;
 583                 setsize (self, PL_MIN, PL_MAX);
 584                 self.spawnorigin = spot.origin;
 585                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 586                 // don't reset back to last position, even if new position is stuck in solid
 587                 self.oldorigin = self.origin;
 588                 self.prevorigin = self.origin;
 589                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 590                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 591         self.hud = HUD_NORMAL;
 592
 593                 self.event_damage = PlayerDamage;
 594
 595                 self.bot_attack = true;
 596                 self.monster_attack = true;
 597
 598                 self.spider_slowness = 0;
 599
 600                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 601
 602                 if(self.killcount == -666) {
 603                         PlayerScore_Clear(self);
 604                         self.killcount = 0;
 605                 }
 606
 607                 CL_SpawnWeaponentity();
 608                 self.alpha = default_player_alpha;
 609                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 610                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 611
 612                 self.speedrunning = false;
 613
 614                 //stuffcmd(self, "chase_active 0");
 615                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 616
 617                 target_voicescript_clear(self);
 618
 619                 // reset fields the weapons may use
 620                 for (int j = WEP_FIRST; j <= WEP_LAST; ++j)
 621                 {
 622                         WEP_ACTION(j, WR_RESETPLAYER);
 623
 624                         // all weapons must be fully loaded when we spawn
 625                         entity e = get_weaponinfo(j);
 626                         if (e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 627                                 self.(weapon_load[j]) = e.reloading_ammo;
 628                 }
 629
 630                 oldself = self;
 631                 self = spot;
 632                         activator = oldself;
 633                                 string s;
 634                                 s = self.target;
 635                                 self.target = string_null;
 636                                 SUB_UseTargets();
 637                                 self.target = s;
 638                         activator = world;
 639                 self = oldself;
 640
 641                 Unfreeze(self);
 642
 643                 spawn_spot = spot;
 644                 MUTATOR_CALLHOOK(PlayerSpawn);
 645
 646                 if(autocvar_spawn_debug)
 647                 {
 648                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 649                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 650                 }
 651
 652                 self.switchweapon = w_getbestweapon(self);
 653                 self.cnt = -1; // W_LastWeapon will not complain
 654                 self.weapon = 0;
 655                 self.weaponname = "";
 656                 self.switchingweapon = 0;
 657
 658                 if(!warmup_stage)
 659                         if(!self.alivetime)
 660                                 self.alivetime = time;
 661
 662                 antilag_clear(self);
 663         }
 664         else if(IS_OBSERVER(self))
 665         {
 666                 PutObserverInServer ();
 667         }
 668 }
 669
 670 .float ebouncefactor, ebouncestop; // electro's values
 671 // TODO do we need all these fields, or should we stop autodetecting runtime
 672 // changes and just have a console command to update this?
 673 float ClientInit_SendEntity(entity to, int sf)
 674 {
 675         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 676         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 677         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 678         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 679         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 680         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 681         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 682         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 683         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 684         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 685
 686         if(sv_foginterval && world.fog != "")
 687                 WriteString(MSG_ENTITY, world.fog);
 688         else
 689                 WriteString(MSG_ENTITY, "");
 690         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 691         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 692         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 693         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 694         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 695         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 696         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 697         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 698         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 699         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 700         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 701         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 702         return true;
 703 }
 704
 705 void ClientInit_CheckUpdate()
 706 {
 707         self.nextthink = time;
 708         if(self.count != autocvar_g_balance_armor_blockpercent)
 709         {
 710                 self.count = autocvar_g_balance_armor_blockpercent;
 711                 self.SendFlags |= 1;
 712         }
 713         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 714         {
 715                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 716                 self.SendFlags |= 1;
 717         }
 718         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 719         {
 720                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 721                 self.SendFlags |= 1;
 722         }
 723         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 724         {
 725                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 726                 self.SendFlags |= 1;
 727         }
 728         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 729         {
 730                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 731                 self.SendFlags |= 1;
 732         }
 733 }
 734
 735 void ClientInit_Spawn()
 736 {
 737         entity o;
 738         entity e;
 739         e = spawn();
 740         e.classname = "clientinit";
 741         e.think = ClientInit_CheckUpdate;
 742         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 743
 744         o = self;
 745         self = e;
 746         ClientInit_CheckUpdate();
 747         self = o;
 748 }
 749
 750 /*
 751 =============
 752 SetNewParms
 753 =============
 754 */
 755 void SetNewParms (void)
 756 {
 757         // initialize parms for a new player
 758         parm1 = -(86400 * 366);
 759 }
 760
 761 /*
 762 =============
 763 SetChangeParms
 764 =============
 765 */
 766 void SetChangeParms (void)
 767 {
 768         // save parms for level change
 769         parm1 = self.parm_idlesince - time;
 770 }
 771
 772 /*
 773 =============
 774 DecodeLevelParms
 775 =============
 776 */
 777 void DecodeLevelParms (void)
 778 {
 779         // load parms
 780         self.parm_idlesince = parm1;
 781         if(self.parm_idlesince == -(86400 * 366))
 782                 self.parm_idlesince = time;
 783
 784         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 785         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 786 }
 787
 788 /*
 789 =============
 790 ClientKill
 791
 792 Called when a client types 'kill' in the console
 793 =============
 794 */
 795
 796 .float clientkill_nexttime;
 797 void ClientKill_Now_TeamChange()
 798 {
 799         if(self.killindicator_teamchange == -1)
 800         {
 801                 JoinBestTeam( self, false, true );
 802         }
 803         else if(self.killindicator_teamchange == -2)
 804         {
 805                 if(blockSpectators)
 806                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 807                 PutObserverInServer();
 808         }
 809         else
 810                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 811         self.killindicator_teamchange = 0;
 812 }
 813
 814 void ClientKill_Now()
 815 {
 816         if(self.vehicle)
 817         {
 818             vehicles_exit(VHEF_RELESE);
 819             if(!self.killindicator_teamchange)
 820             {
 821             self.vehicle_health = -1;
 822             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 823             }
 824         }
 825
 826         if(self.killindicator && !wasfreed(self.killindicator))
 827                 remove(self.killindicator);
 828
 829         self.killindicator = world;
 830
 831         if(self.killindicator_teamchange)
 832                 ClientKill_Now_TeamChange();
 833
 834         if(IS_PLAYER(self))
 835                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 836
 837         // now I am sure the player IS dead
 838 }
 839 void KillIndicator_Think()
 840 {
 841         if (gameover)
 842         {
 843                 self.owner.killindicator = world;
 844                 remove(self);
 845                 return;
 846         }
 847
 848         if (self.owner.alpha < 0 && !self.owner.vehicle)
 849         {
 850                 self.owner.killindicator = world;
 851                 remove(self);
 852                 return;
 853         }
 854
 855         if(self.cnt <= 0)
 856         {
 857                 self = self.owner;
 858                 ClientKill_Now(); // no oldself needed
 859                 return;
 860         }
 861     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 862     {
 863         self.nextthink = time + 1;
 864         self.cnt -= 1;
 865     }
 866         else
 867         {
 868                 if(self.cnt <= 10)
 869                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 870                 if(IS_REAL_CLIENT(self.owner))
 871                 {
 872                         if(self.cnt <= 10)
 873                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 874                 }
 875                 self.nextthink = time + 1;
 876                 self.cnt -= 1;
 877         }
 878 }
 879
 880 float clientkilltime;
 881 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 882 {
 883         float killtime;
 884         float starttime;
 885         entity e;
 886
 887         if (gameover)
 888                 return;
 889
 890         killtime = autocvar_g_balance_kill_delay;
 891
 892         if(g_race_qualifying || g_cts)
 893                 killtime = 0;
 894
 895     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 896     {
 897                 remove(self.killindicator);
 898                 self.killindicator = world;
 899
 900         ClientKill_Now(); // allow instant kill in this case
 901         return;
 902     }
 903
 904         self.killindicator_teamchange = targetteam;
 905
 906     if(!self.killindicator)
 907         {
 908                 if(self.deadflag == DEAD_NO)
 909                 {
 910                         killtime = max(killtime, self.clientkill_nexttime - time);
 911                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 912                 }
 913
 914                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 915                 {
 916                         ClientKill_Now();
 917                 }
 918                 else
 919                 {
 920                         starttime = max(time, clientkilltime);
 921
 922                         self.killindicator = spawn();
 923                         self.killindicator.owner = self;
 924                         self.killindicator.scale = 0.5;
 925                         setattachment(self.killindicator, self, "");
 926                         setorigin(self.killindicator, '0 0 52');
 927                         self.killindicator.think = KillIndicator_Think;
 928                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 929                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 930                         self.killindicator.cnt = ceil(killtime);
 931                         self.killindicator.count = bound(0, ceil(killtime), 10);
 932                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 933
 934                         for(e = world; (e = find(e, classname, "body")) != world; )
 935                         {
 936                                 if(e.enemy != self)
 937                                         continue;
 938                                 e.killindicator = spawn();
 939                                 e.killindicator.owner = e;
 940                                 e.killindicator.scale = 0.5;
 941                                 setattachment(e.killindicator, e, "");
 942                                 setorigin(e.killindicator, '0 0 52');
 943                                 e.killindicator.think = KillIndicator_Think;
 944                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 945                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 946                                 e.killindicator.cnt = ceil(killtime);
 947                         }
 948                         self.lip = 0;
 949                 }
 950         }
 951         if(self.killindicator)
 952         {
 953                 if(targetteam == 0) // just die
 954                 {
 955                         self.killindicator.colormod = '0 0 0';
 956                         if(IS_REAL_CLIENT(self))
 957                         if(self.killindicator.cnt > 0)
 958                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 959                 }
 960                 else if(targetteam == -1) // auto
 961                 {
 962                         self.killindicator.colormod = '0 1 0';
 963                         if(IS_REAL_CLIENT(self))
 964                         if(self.killindicator.cnt > 0)
 965                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 966                 }
 967                 else if(targetteam == -2) // spectate
 968                 {
 969                         self.killindicator.colormod = '0.5 0.5 0.5';
 970                         if(IS_REAL_CLIENT(self))
 971                         if(self.killindicator.cnt > 0)
 972                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 973                 }
 974                 else
 975                 {
 976                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 977                         if(IS_REAL_CLIENT(self))
 978                         if(self.killindicator.cnt > 0)
 979                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 980                 }
 981         }
 982
 983 }
 984
 985 void ClientKill (void)
 986 {
 987         if(gameover) return;
 988         if(self.player_blocked) return;
 989         if(self.frozen) return;
 990
 991         ClientKill_TeamChange(0);
 992 }
 993
 994 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 995 {
 996     e.killindicator = spawn();
 997     e.killindicator.owner = e;
 998     e.killindicator.think = KillIndicator_Think;
 999     e.killindicator.nextthink = time + (e.lip) * 0.05;
1000     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1001     e.killindicator.health = 1; // this is used to indicate that it should be silent
1002     e.lip = 0;
1003 }
1004
1005 void FixClientCvars(entity e)
1006 {
1007         // send prediction settings to the client
1008         stuffcmd(e, "\nin_bindmap 0 0\n");
1009         if(g_race || g_cts)
1010                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1011         if(autocvar_g_antilag == 3) // client side hitscan
1012                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1013         if(autocvar_sv_gentle)
1014                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1015 }
1016
1017 float PlayerInIDList(entity p, string idlist)
1018 {
1019         float n, i;
1020         string s;
1021
1022         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1023         if (!p.crypto_idfp)
1024                 return 0;
1025
1026         // this function allows abbreviated player IDs too!
1027         n = tokenize_console(idlist);
1028         for(i = 0; i < n; ++i)
1029         {
1030                 s = argv(i);
1031                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1032                         return 1;
1033         }
1034
1035         return 0;
1036 }
1037
1038 #ifdef DP_EXT_PRECONNECT
1039 /*
1040 =============
1041 ClientPreConnect
1042
1043 Called once (not at each match start) when a client begins a connection to the server
1044 =============
1045 */
1046 void ClientPreConnect (void)
1047 {
1048         if(autocvar_sv_eventlog)
1049         {
1050                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1051                         self.playerid,
1052                         num_for_edict(self),
1053                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1054                 ));
1055         }
1056 }
1057 #endif
1058
1059 /*
1060 =============
1061 ClientConnect
1062
1063 Called when a client connects to the server
1064 =============
1065 */
1066 void DecodeLevelParms (void);
1067 //void dom_player_join_team(entity pl);
1068 void set_dom_state(entity e);
1069 void ClientConnect (void)
1070 {
1071         float t;
1072
1073         if(IS_CLIENT(self))
1074         {
1075                 print("Warning: ClientConnect, but already connected!\n");
1076                 return;
1077         }
1078
1079         if(Ban_MaybeEnforceBanOnce(self))
1080                 return;
1081
1082         DecodeLevelParms();
1083
1084 #ifdef WATERMARK
1085         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1086 #endif
1087
1088         self.classname = "player_joining";
1089
1090         self.flags = FL_CLIENT;
1091         self.version_nagtime = time + 10 + random() * 10;
1092
1093         if(player_count<0)
1094         {
1095                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1096                 player_count = 0;
1097         }
1098
1099         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1100
1101         PlayerScore_Attach(self);
1102         ClientData_Attach();
1103         accuracy_init(self);
1104         Inventory_new(self);
1105
1106         bot_clientconnect();
1107
1108         playerdemo_init();
1109
1110         anticheat_init();
1111
1112         // identify the right forced team
1113         if(autocvar_g_campaign)
1114         {
1115                 if(IS_REAL_CLIENT(self)) // only players, not bots
1116                 {
1117                         switch(autocvar_g_campaign_forceteam)
1118                         {
1119                                 case 1: self.team_forced = NUM_TEAM_1; break;
1120                                 case 2: self.team_forced = NUM_TEAM_2; break;
1121                                 case 3: self.team_forced = NUM_TEAM_3; break;
1122                                 case 4: self.team_forced = NUM_TEAM_4; break;
1123                                 default: self.team_forced = 0;
1124                         }
1125                 }
1126         }
1127         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1128                 self.team_forced = NUM_TEAM_1;
1129         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1130                 self.team_forced = NUM_TEAM_2;
1131         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1132                 self.team_forced = NUM_TEAM_3;
1133         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1134                 self.team_forced = NUM_TEAM_4;
1135         else if(autocvar_g_forced_team_otherwise == "red")
1136                 self.team_forced = NUM_TEAM_1;
1137         else if(autocvar_g_forced_team_otherwise == "blue")
1138                 self.team_forced = NUM_TEAM_2;
1139         else if(autocvar_g_forced_team_otherwise == "yellow")
1140                 self.team_forced = NUM_TEAM_3;
1141         else if(autocvar_g_forced_team_otherwise == "pink")
1142                 self.team_forced = NUM_TEAM_4;
1143         else if(autocvar_g_forced_team_otherwise == "spectate")
1144                 self.team_forced = -1;
1145         else if(autocvar_g_forced_team_otherwise == "spectator")
1146                 self.team_forced = -1;
1147         else
1148                 self.team_forced = 0;
1149
1150         if(!teamplay)
1151                 if(self.team_forced > 0)
1152                         self.team_forced = 0;
1153
1154         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1155
1156         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1157                 self.classname = "observer";
1158         } else {
1159                 if(teamplay)
1160                 {
1161                         if(autocvar_g_balance_teams)
1162                         {
1163                                 self.classname = "player";
1164                                 campaign_bots_may_start = 1;
1165                         }
1166                         else
1167                         {
1168                                 self.classname = "observer"; // do it anyway
1169                         }
1170                 }
1171                 else
1172                 {
1173                         self.classname = "player";
1174                         campaign_bots_may_start = 1;
1175                 }
1176         }
1177
1178         self.playerid = (playerid_last = playerid_last + 1);
1179
1180         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1181
1182     if(IS_BOT_CLIENT(self))
1183         PlayerStats_GameReport_AddPlayer(self);
1184
1185         if(autocvar_sv_eventlog)
1186                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1187
1188         LogTeamchange(self.playerid, self.team, 1);
1189
1190         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1191
1192         self.netname_previous = strzone(self.netname);
1193
1194         if(IS_PLAYER(self) && teamplay)
1195                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1196         else
1197                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1198
1199         stuffcmd(self, strcat(clientstuff, "\n"));
1200         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1201
1202         FixClientCvars(self);
1203
1204         // spawnfunc_waypoint sprites
1205         WaypointSprite_InitClient(self);
1206
1207         // Wazat's grappling hook
1208         SetGrappleHookBindings();
1209
1210         // Jetpack binds
1211         stuffcmd(self, "alias +jetpack +button10\n");
1212         stuffcmd(self, "alias -jetpack -button10\n");
1213
1214         // get version info from player
1215         stuffcmd(self, "cmd clientversion $gameversion\n");
1216
1217         // get other cvars from player
1218         GetCvars(0);
1219
1220         // notify about available teams
1221         if(teamplay)
1222         {
1223                 CheckAllowedTeams(self);
1224                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1225                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1226         }
1227         else
1228                 stuffcmd(self, "set _teams_available 0\n");
1229
1230         attach_entcs();
1231
1232         bot_relinkplayerlist();
1233
1234         self.spectatortime = time;
1235         if(blockSpectators)
1236         {
1237                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1238         }
1239
1240         self.jointime = time;
1241         self.allowed_timeouts = autocvar_sv_timeout_number;
1242
1243         if(IS_REAL_CLIENT(self))
1244         {
1245                 if(!autocvar_g_campaign)
1246                 {
1247                         self.motd_actived_time = -1;
1248                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1249                 }
1250
1251                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1252                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1253         }
1254
1255         if(!sv_foginterval && world.fog != "")
1256                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1257
1258         W_HitPlotOpen(self);
1259
1260         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1261                 send_CSQC_teamnagger();
1262
1263         CheatInitClient();
1264
1265         CSQCMODEL_AUTOINIT();
1266
1267         self.model_randomizer = random();
1268
1269         if(IS_REAL_CLIENT(self))
1270                 sv_notice_join();
1271
1272         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1273                 entity oldself = self;
1274                 self = e;
1275                 e.init_for_player(oldself);
1276                 self = oldself;
1277         }
1278
1279         MUTATOR_CALLHOOK(ClientConnect);
1280 }
1281 /*
1282 =============
1283 ClientDisconnect
1284
1285 Called when a client disconnects from the server
1286 =============
1287 */
1288 .entity chatbubbleentity;
1289 void ReadyCount();
1290 void ClientDisconnect (void)
1291 {
1292         if(self.vehicle)
1293             vehicles_exit(VHEF_RELESE);
1294
1295         if (!IS_CLIENT(self))
1296         {
1297                 print("Warning: ClientDisconnect without ClientConnect\n");
1298                 return;
1299         }
1300
1301         PlayerStats_GameReport_FinalizePlayer(self);
1302
1303         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1304
1305         CheatShutdownClient();
1306
1307         W_HitPlotClose(self);
1308
1309         anticheat_report();
1310         anticheat_shutdown();
1311
1312         playerdemo_shutdown();
1313
1314         bot_clientdisconnect();
1315
1316         if(self.entcs)
1317                 detach_entcs();
1318
1319         if(autocvar_sv_eventlog)
1320                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1321
1322         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1323
1324         MUTATOR_CALLHOOK(ClientDisconnect);
1325
1326         Portal_ClearAll(self);
1327
1328         Unfreeze(self);
1329
1330         RemoveGrapplingHook(self);
1331
1332         // Here, everything has been done that requires this player to be a client.
1333
1334         self.flags &= ~FL_CLIENT;
1335
1336         if (self.chatbubbleentity)
1337                 remove (self.chatbubbleentity);
1338
1339         if (self.killindicator)
1340                 remove (self.killindicator);
1341
1342         WaypointSprite_PlayerGone();
1343
1344         bot_relinkplayerlist();
1345
1346         accuracy_free(self);
1347         Inventory_delete(self);
1348         ClientData_Detach();
1349         PlayerScore_Detach(self);
1350
1351         if(self.netname_previous)
1352                 strunzone(self.netname_previous);
1353         if(self.clientstatus)
1354                 strunzone(self.clientstatus);
1355         if(self.weaponorder_byimpulse)
1356                 strunzone(self.weaponorder_byimpulse);
1357
1358         ClearPlayerSounds();
1359
1360         if(self.personal)
1361                 remove(self.personal);
1362
1363         self.playerid = 0;
1364         ReadyCount();
1365
1366         // free cvars
1367         GetCvars(-1);
1368 }
1369
1370 .float BUTTON_CHAT;
1371 void ChatBubbleThink()
1372 {
1373         self.nextthink = time;
1374         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1375         {
1376                 if(self.owner) // but why can that ever be world?
1377                         self.owner.chatbubbleentity = world;
1378                 remove(self);
1379                 return;
1380         }
1381         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1382 #ifdef TETRIS
1383                 || self.owner.tetris_on
1384 #endif
1385         )
1386                 self.model = self.mdl;
1387         else
1388                 self.model = "";
1389 }
1390
1391 void UpdateChatBubble()
1392 {
1393         if (self.alpha < 0)
1394                 return;
1395         // spawn a chatbubble entity if needed
1396         if (!self.chatbubbleentity)
1397         {
1398                 self.chatbubbleentity = spawn();
1399                 self.chatbubbleentity.owner = self;
1400                 self.chatbubbleentity.exteriormodeltoclient = self;
1401                 self.chatbubbleentity.think = ChatBubbleThink;
1402                 self.chatbubbleentity.nextthink = time;
1403                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1404                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1405                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1406                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1407                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1408                 self.chatbubbleentity.model = "";
1409                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1410         }
1411 }
1412
1413
1414 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1415 // added to the model skins
1416 /*void UpdateColorModHack()
1417 {
1418         float c;
1419         c = self.clientcolors & 15;
1420         // LordHavoc: only bothering to support white, green, red, yellow, blue
1421              if (!teamplay) self.colormod = '0 0 0';
1422         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1423         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1424         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1425         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1426         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1427         else self.colormod = '1 1 1';
1428 }*/
1429
1430 void respawn(void)
1431 {
1432         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1433         {
1434                 self.solid = SOLID_NOT;
1435                 self.takedamage = DAMAGE_NO;
1436                 self.movetype = MOVETYPE_FLY;
1437                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1438                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1439                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1440                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1441                 if(autocvar_g_respawn_ghosts_maxtime)
1442                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1443         }
1444
1445         CopyBody(1);
1446
1447         self.effects |= EF_NODRAW; // prevent another CopyBody
1448         PutClientInServer();
1449 }
1450
1451 void play_countdown(float finished, string samp)
1452 {
1453         if(IS_REAL_CLIENT(self))
1454                 if(floor(finished - time - frametime) != floor(finished - time))
1455                         if(finished - time < 6)
1456                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1457 }
1458
1459 void player_powerups (void)
1460 {
1461         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1462         olditems = self.items;
1463
1464         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1465                 self.modelflags |= MF_ROCKET;
1466         else
1467                 self.modelflags &= ~MF_ROCKET;
1468
1469         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1470
1471         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1472                 return;
1473
1474         Fire_ApplyDamage(self);
1475         Fire_ApplyEffect(self);
1476
1477         if (!g_instagib)
1478         {
1479                 if (self.items & IT_STRENGTH)
1480                 {
1481                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1482                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1483                         if (time > self.strength_finished)
1484                         {
1485                                 self.items = self.items - (self.items & IT_STRENGTH);
1486                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1487                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1488                         }
1489                 }
1490                 else
1491                 {
1492                         if (time < self.strength_finished)
1493                         {
1494                                 self.items = self.items | IT_STRENGTH;
1495                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1496                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1497                         }
1498                 }
1499                 if (self.items & IT_INVINCIBLE)
1500                 {
1501                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1502                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1503                         if (time > self.invincible_finished)
1504                         {
1505                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1506                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1507                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1508                         }
1509                 }
1510                 else
1511                 {
1512                         if (time < self.invincible_finished)
1513                         {
1514                                 self.items = self.items | IT_INVINCIBLE;
1515                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1516                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1517                         }
1518                 }
1519                 if (self.items & IT_SUPERWEAPON)
1520                 {
1521                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1522                         {
1523                                 self.superweapons_finished = 0;
1524                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1525                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1526                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1527                         }
1528                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1529                         {
1530                                 // don't let them run out
1531                         }
1532                         else
1533                         {
1534                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1535                                 if (time > self.superweapons_finished)
1536                                 {
1537                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1538                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1539                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1540                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1541                                 }
1542                         }
1543                 }
1544                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1545                 {
1546                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1547                         {
1548                                 self.items = self.items | IT_SUPERWEAPON;
1549                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1550                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1551                         }
1552                         else
1553                         {
1554                                 self.superweapons_finished = 0;
1555                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1556                         }
1557                 }
1558                 else
1559                 {
1560                         self.superweapons_finished = 0;
1561                 }
1562         }
1563
1564         if(autocvar_g_nodepthtestplayers)
1565                 self.effects = self.effects | EF_NODEPTHTEST;
1566
1567         if(autocvar_g_fullbrightplayers)
1568                 self.effects = self.effects | EF_FULLBRIGHT;
1569
1570         if (time >= game_starttime)
1571         if (time < self.spawnshieldtime)
1572                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1573
1574         MUTATOR_CALLHOOK(PlayerPowerups);
1575 }
1576
1577 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1578 {
1579         if(current > stable)
1580                 return current;
1581         else if(current > stable - 0.25) // when close enough, "snap"
1582                 return stable;
1583         else
1584                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1585 }
1586
1587 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1588 {
1589         if(current < stable)
1590                 return current;
1591         else if(current < stable + 0.25) // when close enough, "snap"
1592                 return stable;
1593         else
1594                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1595 }
1596
1597 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1598 {
1599         if(current > rotstable)
1600         {
1601                 if(rotframetime > 0)
1602                 {
1603                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1604                         current = max(rotstable, current - rotlinear * rotframetime);
1605                 }
1606         }
1607         else if(current < regenstable)
1608         {
1609                 if(regenframetime > 0)
1610                 {
1611                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1612                         current = min(regenstable, current + regenlinear * regenframetime);
1613                 }
1614         }
1615
1616         if(current > limit)
1617                 current = limit;
1618
1619         return current;
1620 }
1621
1622 void player_regen (void)
1623 {
1624         float max_mod, regen_mod, rot_mod, limit_mod;
1625         max_mod = regen_mod = rot_mod = limit_mod = 1;
1626         regen_mod_max = max_mod;
1627         regen_mod_regen = regen_mod;
1628         regen_mod_rot = rot_mod;
1629         regen_mod_limit = limit_mod;
1630         if(!MUTATOR_CALLHOOK(PlayerRegen))
1631         if(!self.frozen)
1632         {
1633                 float minh, mina, maxh, maxa, limith, limita;
1634                 maxh = autocvar_g_balance_health_rotstable;
1635                 maxa = autocvar_g_balance_armor_rotstable;
1636                 minh = autocvar_g_balance_health_regenstable;
1637                 mina = autocvar_g_balance_armor_regenstable;
1638                 limith = autocvar_g_balance_health_limit;
1639                 limita = autocvar_g_balance_armor_limit;
1640
1641                 max_mod = regen_mod_max;
1642                 regen_mod = regen_mod_regen;
1643                 rot_mod = regen_mod_rot;
1644                 limit_mod = regen_mod_limit;
1645
1646                 maxh = maxh * max_mod;
1647                 minh = minh * max_mod;
1648                 limith = limith * limit_mod;
1649                 limita = limita * limit_mod;
1650
1651                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1652                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1653         }
1654
1655         // if player rotted to death...  die!
1656         // check this outside above checks, as player may still be able to rot to death
1657         if(self.health < 1)
1658                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1659
1660         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1661         {
1662                 float minf, maxf, limitf;
1663
1664                 maxf = autocvar_g_balance_fuel_rotstable;
1665                 minf = autocvar_g_balance_fuel_regenstable;
1666                 limitf = autocvar_g_balance_fuel_limit;
1667
1668                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1669         }
1670 }
1671
1672 float zoomstate_set;
1673 void SetZoomState(float z)
1674 {
1675         if(z != self.zoomstate)
1676         {
1677                 self.zoomstate = z;
1678                 ClientData_Touch(self);
1679         }
1680         zoomstate_set = 1;
1681 }
1682
1683 void GetPressedKeys(void) {
1684         MUTATOR_CALLHOOK(GetPressedKeys);
1685         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1686         X(self.pressedkeys, KEY_FORWARD,        self.movement_x > 0);
1687         X(self.pressedkeys, KEY_BACKWARD,       self.movement_x < 0);
1688         X(self.pressedkeys, KEY_RIGHT,          self.movement_y > 0);
1689         X(self.pressedkeys, KEY_LEFT,           self.movement_y < 0);
1690
1691         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1692         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1693         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1694         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1695         #undef X
1696 }
1697
1698 /*
1699 ======================
1700 spectate mode routines
1701 ======================
1702 */
1703
1704 void SpectateCopy(entity spectatee) {
1705         other = spectatee;
1706         MUTATOR_CALLHOOK(SpectateCopy);
1707         self.armortype = spectatee.armortype;
1708         self.armorvalue = spectatee.armorvalue;
1709         self.ammo_cells = spectatee.ammo_cells;
1710         self.ammo_plasma = spectatee.ammo_plasma;
1711         self.ammo_shells = spectatee.ammo_shells;
1712         self.ammo_nails = spectatee.ammo_nails;
1713         self.ammo_rockets = spectatee.ammo_rockets;
1714         self.ammo_fuel = spectatee.ammo_fuel;
1715         self.clip_load = spectatee.clip_load;
1716         self.clip_size = spectatee.clip_size;
1717         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1718         self.health = spectatee.health;
1719         self.impulse = 0;
1720         self.items = spectatee.items;
1721         self.last_pickup = spectatee.last_pickup;
1722         self.hit_time = spectatee.hit_time;
1723         self.metertime = spectatee.metertime;
1724         self.strength_finished = spectatee.strength_finished;
1725         self.invincible_finished = spectatee.invincible_finished;
1726         self.pressedkeys = spectatee.pressedkeys;
1727         self.weapons = spectatee.weapons;
1728         self.switchweapon = spectatee.switchweapon;
1729         self.switchingweapon = spectatee.switchingweapon;
1730         self.weapon = spectatee.weapon;
1731         self.vortex_charge = spectatee.vortex_charge;
1732         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1733         self.hagar_load = spectatee.hagar_load;
1734         self.arc_heat_percent = spectatee.arc_heat_percent;
1735         self.minelayer_mines = spectatee.minelayer_mines;
1736         self.punchangle = spectatee.punchangle;
1737         self.view_ofs = spectatee.view_ofs;
1738         self.velocity = spectatee.velocity;
1739         self.dmg_take = spectatee.dmg_take;
1740         self.dmg_save = spectatee.dmg_save;
1741         self.dmg_inflictor = spectatee.dmg_inflictor;
1742         self.v_angle = spectatee.v_angle;
1743         self.angles = spectatee.v_angle;
1744         self.frozen = spectatee.frozen;
1745         self.revive_progress = spectatee.revive_progress;
1746         if(!self.BUTTON_USE)
1747                 self.fixangle = true;
1748         setorigin(self, spectatee.origin);
1749         setsize(self, spectatee.mins, spectatee.maxs);
1750         SetZoomState(spectatee.zoomstate);
1751
1752     anticheat_spectatecopy(spectatee);
1753         self.hud = spectatee.hud;
1754         if(spectatee.vehicle)
1755     {
1756         self.fixangle = false;
1757         //self.velocity = spectatee.vehicle.velocity;
1758         self.vehicle_health = spectatee.vehicle_health;
1759         self.vehicle_shield = spectatee.vehicle_shield;
1760         self.vehicle_energy = spectatee.vehicle_energy;
1761         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1762         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1763         self.vehicle_reload1 = spectatee.vehicle_reload1;
1764         self.vehicle_reload2 = spectatee.vehicle_reload2;
1765
1766         msg_entity = self;
1767
1768         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1769             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1770             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1771             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1772
1773         //WriteByte (MSG_ONE, SVC_SETVIEW);
1774         //    WriteEntity(MSG_ONE, self);
1775         //makevectors(spectatee.v_angle);
1776         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1777     }
1778 }
1779
1780 float SpectateUpdate()
1781 {
1782         if(!self.enemy)
1783             return 0;
1784
1785         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1786         {
1787                 SetSpectator(self, world);
1788                 return 0;
1789         }
1790
1791         SpectateCopy(self.enemy);
1792
1793         return 1;
1794 }
1795
1796 float SpectateSet()
1797 {
1798         if(self.enemy.classname != "player")
1799                 return false;
1800         /*if(self.enemy.vehicle)
1801         {
1802
1803                 msg_entity = self;
1804                 WriteByte(MSG_ONE, SVC_SETVIEW);
1805                 WriteEntity(MSG_ONE, self.enemy);
1806                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1807
1808                 self.movetype = MOVETYPE_NONE;
1809                 accuracy_resend(self);
1810         }
1811         else
1812         {*/
1813                 msg_entity = self;
1814                 WriteByte(MSG_ONE, SVC_SETVIEW);
1815                 WriteEntity(MSG_ONE, self.enemy);
1816                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1817                 self.movetype = MOVETYPE_NONE;
1818                 accuracy_resend(self);
1819
1820                 if(!SpectateUpdate())
1821                         PutObserverInServer();
1822         //}
1823         return true;
1824 }
1825
1826 void SetSpectator(entity player, entity spectatee)
1827 {
1828         entity old_spectatee = player.enemy;
1829
1830         player.enemy = spectatee;
1831
1832         // WEAPONTODO
1833         // these are required to fix the spectator bug with arc
1834         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1835         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1836 }
1837
1838 float Spectate(entity pl)
1839 {
1840         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1841         if(pl.team != self.team)
1842                 return 0;
1843
1844         SetSpectator(self, pl);
1845         return SpectateSet();
1846 }
1847
1848 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1849 entity CA_SpectateNext(entity start) {
1850         if (start.team == self.team) {
1851                 return start;
1852         }
1853
1854         other = start;
1855         // continue from current player
1856         while(other && other.team != self.team) {
1857                 other = find(other, classname, "player");
1858         }
1859
1860         if (!other) {
1861                 // restart from begining
1862                 other = find(other, classname, "player");
1863                 while(other && other.team != self.team) {
1864                         other = find(other, classname, "player");
1865                 }
1866         }
1867
1868         return other;
1869 }
1870
1871 float SpectateNext()
1872 {
1873         other = find(self.enemy, classname, "player");
1874
1875         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1876                 // CA and ca players when spectating enemies is forbidden
1877                 other = CA_SpectateNext(other);
1878         } else {
1879                 // other modes and ca spectators or spectating enemies is allowed
1880                 if (!other)
1881                         other = find(other, classname, "player");
1882         }
1883
1884         if(other) { SetSpectator(self, other); }
1885
1886         return SpectateSet();
1887 }
1888
1889 float SpectatePrev()
1890 {
1891         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1892         other = findchain(classname, "player");
1893         if (!other) // no player
1894                 return false;
1895
1896         entity first = other;
1897         // skip players until current spectated player
1898         if(self.enemy)
1899         while(other && other != self.enemy)
1900                 other = other.chain;
1901
1902         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1903         {
1904                 do { other = other.chain; }
1905                 while(other && other.team != self.team);
1906
1907                 if (!other)
1908                 {
1909                         other = first;
1910                         while(other.team != self.team)
1911                                 other = other.chain;
1912                         if(other == self.enemy)
1913                                 return true;
1914                 }
1915         }
1916         else
1917         {
1918                 if(other.chain)
1919                         other = other.chain;
1920                 else
1921                         other = first;
1922         }
1923         SetSpectator(self, other);
1924         return SpectateSet();
1925 }
1926
1927 /*
1928 =============
1929 ShowRespawnCountdown()
1930
1931 Update a respawn countdown display.
1932 =============
1933 */
1934 void ShowRespawnCountdown()
1935 {
1936         float number;
1937         if(self.deadflag == DEAD_NO) // just respawned?
1938                 return;
1939         else
1940         {
1941                 number = ceil(self.respawn_time - time);
1942                 if(number <= 0)
1943                         return;
1944                 if(number <= self.respawn_countdown)
1945                 {
1946                         self.respawn_countdown = number - 1;
1947                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1948                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1949                 }
1950         }
1951 }
1952
1953 void LeaveSpectatorMode()
1954 {
1955         if(self.caplayer)
1956                 return;
1957         if(nJoinAllowed(self))
1958         {
1959                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1960                 {
1961                         self.classname = "player";
1962                         nades_RemoveBonus(self);
1963
1964                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1965                                 { JoinBestTeam(self, false, true); }
1966
1967                         if(autocvar_g_campaign)
1968                                 { campaign_bots_may_start = 1; }
1969
1970                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1971
1972                         PutClientInServer();
1973
1974                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1975                 }
1976                 else
1977                         stuffcmd(self, "menu_showteamselect\n");
1978         }
1979         else
1980         {
1981                 // Player may not join because g_maxplayers is set
1982                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1983         }
1984 }
1985
1986 /**
1987  * Determines whether the player is allowed to join. This depends on cvar
1988  * g_maxplayers, if it isn't used this function always return true, otherwise
1989  * it checks whether the number of currently playing players exceeds g_maxplayers.
1990  * @return int number of free slots for players, 0 if none
1991  */
1992 float nJoinAllowed(entity ignore) {
1993         if(!ignore)
1994         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1995         // so report 0 free slots if restricted
1996         {
1997                 if(autocvar_g_forced_team_otherwise == "spectate")
1998                         return 0;
1999                 if(autocvar_g_forced_team_otherwise == "spectator")
2000                         return 0;
2001         }
2002
2003         if(self.team_forced < 0)
2004                 return 0; // forced spectators can never join
2005
2006         // TODO simplify this
2007         entity e;
2008         float totalClients = 0;
2009         FOR_EACH_CLIENT(e)
2010                 if(e != ignore)
2011                         totalClients += 1;
2012
2013         if (!autocvar_g_maxplayers)
2014                 return maxclients - totalClients;
2015
2016         float currentlyPlaying = 0;
2017         FOR_EACH_REALCLIENT(e)
2018                 if(IS_PLAYER(e) || e.caplayer)
2019                         currentlyPlaying += 1;
2020
2021         if(currentlyPlaying < autocvar_g_maxplayers)
2022                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2023
2024         return 0;
2025 }
2026
2027 /**
2028  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2029  * g_maxplayers_spectator_blocktime seconds
2030  */
2031 void checkSpectatorBlock() {
2032         if(IS_SPEC(self) || IS_OBSERVER(self))
2033         if(!self.caplayer)
2034         if(IS_REAL_CLIENT(self))
2035         {
2036                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2037                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2038                         dropclient(self);
2039                 }
2040         }
2041 }
2042
2043 void PrintWelcomeMessage()
2044 {
2045         if(self.motd_actived_time == 0)
2046         {
2047                 if (autocvar_g_campaign) {
2048                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2049                                 self.motd_actived_time = time;
2050                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2051                         }
2052                 } else {
2053                         if (self.BUTTON_INFO) {
2054                                 self.motd_actived_time = time;
2055                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2056                         }
2057                 }
2058         }
2059         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2060         {
2061                 if (autocvar_g_campaign) {
2062                         if (self.BUTTON_INFO)
2063                                 self.motd_actived_time = time;
2064                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2065                                 self.motd_actived_time = 0;
2066                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2067                         }
2068                 } else {
2069                         if (self.BUTTON_INFO)
2070                                 self.motd_actived_time = time;
2071                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2072                                 self.motd_actived_time = 0;
2073                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2074                         }
2075                 }
2076         }
2077         else //if(self.motd_actived_time < 0) // just connected, motd is active
2078         {
2079                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2080                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2081                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2082                 {
2083                         // instanctly hide MOTD
2084                         self.motd_actived_time = 0;
2085                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2086                 }
2087         }
2088 }
2089
2090 void ObserverThink()
2091 {
2092         float prefered_movetype;
2093         if (self.flags & FL_JUMPRELEASED) {
2094                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2095                         self.flags &= ~FL_JUMPRELEASED;
2096                         self.flags |= FL_SPAWNING;
2097                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2098                         self.flags &= ~FL_JUMPRELEASED;
2099                         if(SpectateNext()) {
2100                                 self.classname = "spectator";
2101                         }
2102                 } else {
2103                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2104                         if (self.movetype != prefered_movetype)
2105                                 self.movetype = prefered_movetype;
2106                 }
2107         } else {
2108                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2109                         self.flags |= FL_JUMPRELEASED;
2110                         if(self.flags & FL_SPAWNING)
2111                         {
2112                                 self.flags &= ~FL_SPAWNING;
2113                                 LeaveSpectatorMode();
2114                                 return;
2115                         }
2116                 }
2117         }
2118 }
2119
2120 void SpectatorThink()
2121 {
2122         if (self.flags & FL_JUMPRELEASED) {
2123                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2124                         self.flags &= ~FL_JUMPRELEASED;
2125                         self.flags |= FL_SPAWNING;
2126                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2127                         self.flags &= ~FL_JUMPRELEASED;
2128                         if(SpectateNext()) {
2129                                 self.classname = "spectator";
2130                         } else {
2131                                 self.classname = "observer";
2132                                 PutClientInServer();
2133                         }
2134                         self.impulse = 0;
2135                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2136                         self.flags &= ~FL_JUMPRELEASED;
2137                         if(SpectatePrev()) {
2138                                 self.classname = "spectator";
2139                         } else {
2140                                 self.classname = "observer";
2141                                 PutClientInServer();
2142                         }
2143                         self.impulse = 0;
2144                 } else if (self.BUTTON_ATCK2) {
2145                         self.flags &= ~FL_JUMPRELEASED;
2146                         self.classname = "observer";
2147                         PutClientInServer();
2148                 } else {
2149                         if(!SpectateUpdate())
2150                                 PutObserverInServer();
2151                 }
2152         } else {
2153                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2154                         self.flags |= FL_JUMPRELEASED;
2155                         if(self.flags & FL_SPAWNING)
2156                         {
2157                                 self.flags &= ~FL_SPAWNING;
2158                                 LeaveSpectatorMode();
2159                                 return;
2160                         }
2161                 }
2162                 if(!SpectateUpdate())
2163                         PutObserverInServer();
2164         }
2165
2166         self.flags |= FL_CLIENT | FL_NOTARGET;
2167 }
2168
2169 void PlayerUseKey()
2170 {
2171         if (!IS_PLAYER(self))
2172                 return;
2173
2174         if(self.vehicle)
2175         {
2176         vehicles_exit(VHEF_NORMAL);
2177         return;
2178         }
2179
2180         // a use key was pressed; call handlers
2181         MUTATOR_CALLHOOK(PlayerUseKey);
2182 }
2183
2184 float isInvisibleString(string s)
2185 {
2186         float i, n, c;
2187         s = strdecolorize(s);
2188         for((i = 0), (n = strlen(s)); i < n; ++i)
2189         {
2190                 c = str2chr(s, i);
2191                 switch(c)
2192                 {
2193                         case 0:
2194                         case 32: // space
2195                                 break;
2196                         case 192: // charmap space
2197                                 if (!autocvar_utf8_enable)
2198                                         break;
2199                                 return false;
2200                         case 160: // space in unicode fonts
2201                         case 0xE000 + 192: // utf8 charmap space
2202                                 if (autocvar_utf8_enable)
2203                                         break;
2204                         default:
2205                                 return false;
2206                 }
2207         }
2208         return true;
2209 }
2210
2211 /*
2212 =============
2213 PlayerPreThink
2214
2215 Called every frame for each client before the physics are run
2216 =============
2217 */
2218 .float usekeypressed;
2219 void() nexball_setstatus;
2220 .int items_added;
2221 void PlayerPreThink (void)
2222 {
2223         WarpZone_PlayerPhysics_FixVAngle();
2224
2225         self.stat_game_starttime = game_starttime;
2226         self.stat_round_starttime = round_starttime;
2227         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2228         self.stat_leadlimit = autocvar_leadlimit;
2229
2230         self.weaponsinmap = weaponsInMap;
2231
2232         if(frametime)
2233         {
2234                 // physics frames: update anticheat stuff
2235                 anticheat_prethink();
2236         }
2237
2238         if(blockSpectators && frametime)
2239                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2240                 checkSpectatorBlock();
2241
2242         zoomstate_set = 0;
2243
2244         // Savage: Check for nameless players
2245         if (isInvisibleString(self.netname)) {
2246                 string new_name = strzone(strcat("Player@", self.netaddress));
2247                 if(autocvar_sv_eventlog)
2248                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2249                 if(self.netname_previous)
2250                         strunzone(self.netname_previous);
2251                 self.netname_previous = strzone(new_name);
2252                 self.netname = self.netname_previous;
2253                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2254         } else if(self.netname_previous != self.netname) {
2255                 if(autocvar_sv_eventlog)
2256                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2257                 if(self.netname_previous)
2258                         strunzone(self.netname_previous);
2259                 self.netname_previous = strzone(self.netname);
2260         }
2261
2262         // version nagging
2263         if(self.version_nagtime)
2264                 if(self.cvar_g_xonoticversion)
2265                         if(time > self.version_nagtime)
2266                         {
2267                                 // don't notify git users
2268                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2269                                 {
2270                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2271                                         {
2272                                                 // notify release users if connecting to git
2273                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2274                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2275                                         }
2276                                         else
2277                                         {
2278                                                 float r;
2279                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2280                                                 if(r < 0)
2281                                                 {
2282                                                         // give users new version
2283                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2284                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2285                                                 }
2286                                                 else if(r > 0)
2287                                                 {
2288                                                         // notify users about old server version
2289                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2290                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2291                                                 }
2292                                         }
2293                                 }
2294                                 self.version_nagtime = 0;
2295                         }
2296
2297         // GOD MODE info
2298         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2299         {
2300                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2301                 self.max_armorvalue = 0;
2302         }
2303
2304 #ifdef TETRIS
2305         if (TetrisPreFrame())
2306                 return;
2307 #endif
2308
2309         if(self.frozen == 2)
2310         {
2311                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2312                 self.health = max(1, self.revive_progress * start_health);
2313                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2314
2315                 if(self.revive_progress >= 1)
2316                         Unfreeze(self);
2317         }
2318         else if(self.frozen == 3)
2319         {
2320                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2321                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2322
2323                 if(self.health < 1)
2324                 {
2325                         if(self.vehicle)
2326                                 vehicles_exit(VHEF_RELESE);
2327                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2328                 }
2329                 else if ( self.revive_progress <= 0 )
2330                         Unfreeze(self);
2331         }
2332
2333         MUTATOR_CALLHOOK(PlayerPreThink);
2334
2335         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2336         {
2337                 if(self.BUTTON_USE && !self.usekeypressed)
2338                         PlayerUseKey();
2339                 self.usekeypressed = self.BUTTON_USE;
2340         }
2341
2342         if(IS_REAL_CLIENT(self))
2343                 PrintWelcomeMessage();
2344
2345         if(IS_PLAYER(self))
2346         {
2347
2348                 CheckRules_Player();
2349
2350                 if (intermission_running)
2351                 {
2352                         IntermissionThink ();   // otherwise a button could be missed between
2353                         return;                                 // the think tics
2354                 }
2355
2356                 //don't allow the player to turn around while game is paused!
2357                 if(timeout_status == TIMEOUT_ACTIVE) {
2358                         // FIXME turn this into CSQC stuff
2359                         self.v_angle = self.lastV_angle;
2360                         self.angles = self.lastV_angle;
2361                         self.fixangle = true;
2362                 }
2363
2364                 if(frametime)
2365                 {
2366                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2367                         {
2368                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2369                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2370                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2371
2372                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2373                                 {
2374                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2375                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2376                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2377                                 }
2378                         }
2379                         else
2380                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2381
2382                         player_powerups();
2383                 }
2384
2385                 if (self.deadflag != DEAD_NO)
2386                 {
2387                         if(self.personal && g_race_qualifying)
2388                         {
2389                                 if(time > self.respawn_time)
2390                                 {
2391                                         self.respawn_time = time + 1; // only retry once a second
2392                                         self.stat_respawn_time = self.respawn_time;
2393                                         respawn();
2394                                         self.impulse = 141;
2395                                 }
2396                         }
2397                         else
2398                         {
2399                                 float button_pressed;
2400                                 if(frametime)
2401                                         player_anim();
2402                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2403
2404                                 if (self.deadflag == DEAD_DYING)
2405                                 {
2406                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2407                                                 self.deadflag = DEAD_RESPAWNING;
2408                                         else if(!button_pressed)
2409                                                 self.deadflag = DEAD_DEAD;
2410                                 }
2411                                 else if (self.deadflag == DEAD_DEAD)
2412                                 {
2413                                         if(button_pressed)
2414                                                 self.deadflag = DEAD_RESPAWNABLE;
2415                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2416                                                 self.deadflag = DEAD_RESPAWNING;
2417                                 }
2418                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2419                                 {
2420                                         if(!button_pressed)
2421                                                 self.deadflag = DEAD_RESPAWNING;
2422                                 }
2423                                 else if (self.deadflag == DEAD_RESPAWNING)
2424                                 {
2425                                         if(time > self.respawn_time)
2426                                         {
2427                                                 self.respawn_time = time + 1; // only retry once a second
2428                                                 self.respawn_time_max = self.respawn_time;
2429                                                 respawn();
2430                                         }
2431                                 }
2432
2433                                 ShowRespawnCountdown();
2434
2435                                 if(self.respawn_flags & RESPAWN_SILENT)
2436                                         self.stat_respawn_time = 0;
2437                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2438                                         self.stat_respawn_time = self.respawn_time_max;
2439                                 else
2440                                         self.stat_respawn_time = self.respawn_time;
2441                         }
2442
2443                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2444                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2445                                 self.stat_respawn_time *= -1;
2446
2447                         return;
2448                 }
2449
2450                 self.prevorigin = self.origin;
2451
2452                 float do_crouch = self.BUTTON_CROUCH;
2453                 if(self.hook.state)
2454                         do_crouch = 0;
2455                 if(self.vehicle)
2456                         do_crouch = 0;
2457                 if(self.frozen)
2458                         do_crouch = 0;
2459
2460                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2461                 // It cannot be predicted by the engine!
2462                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2463                         do_crouch = 0;
2464
2465                 if (do_crouch)
2466                 {
2467                         if (!self.crouch)
2468                         {
2469                                 self.crouch = true;
2470                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2471                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2472                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2473                         }
2474                 }
2475                 else
2476                 {
2477                         if (self.crouch)
2478                         {
2479                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2480                                 if (!trace_startsolid)
2481                                 {
2482                                         self.crouch = false;
2483                                         self.view_ofs = self.stat_pl_view_ofs;
2484                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2485                                 }
2486                         }
2487                 }
2488
2489                 FixPlayermodel();
2490
2491                 GrapplingHookFrame();
2492
2493                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2494                 //if(frametime)
2495                 {
2496                         self.items &= ~self.items_added;
2497
2498                         W_WeaponFrame();
2499
2500                         self.items_added = 0;
2501                         if(self.items & IT_JETPACK)
2502                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2503                                         self.items_added |= IT_FUEL;
2504
2505                         self.items |= self.items_added;
2506                 }
2507
2508                 player_regen();
2509
2510                 // WEAPONTODO: Add a weapon request for this
2511                 // rot vortex charge to the charge limit
2512                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2513                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2514
2515                 if(frametime)
2516                         player_anim();
2517
2518                 // secret status
2519                 secrets_setstatus();
2520
2521                 // monsters status
2522                 monsters_setstatus();
2523
2524                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2525
2526                 //self.angles_y=self.v_angle_y + 90;   // temp
2527         } else if(gameover) {
2528                 if (intermission_running)
2529                         IntermissionThink ();   // otherwise a button could be missed between
2530                 return;
2531         } else if(IS_OBSERVER(self)) {
2532                 ObserverThink();
2533         } else if(IS_SPEC(self)) {
2534                 SpectatorThink();
2535         }
2536
2537         // WEAPONTODO: Add weapon request for this
2538         if(!zoomstate_set)
2539                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2540
2541         float oldspectatee_status;
2542         oldspectatee_status = self.spectatee_status;
2543         if(IS_SPEC(self))
2544                 self.spectatee_status = num_for_edict(self.enemy);
2545         else if(IS_OBSERVER(self))
2546                 self.spectatee_status = num_for_edict(self);
2547         else
2548                 self.spectatee_status = 0;
2549         if(self.spectatee_status != oldspectatee_status)
2550         {
2551                 ClientData_Touch(self);
2552         }
2553
2554         if(self.teamkill_soundtime)
2555         if(time > self.teamkill_soundtime)
2556         {
2557                 self.teamkill_soundtime = 0;
2558
2559                 entity oldpusher, oldself;
2560
2561                 oldself = self; self = self.teamkill_soundsource;
2562                 oldpusher = self.pusher; self.pusher = oldself;
2563
2564                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2565
2566                 self.pusher = oldpusher;
2567                 self = oldself;
2568         }
2569
2570         if(self.taunt_soundtime)
2571         if(time > self.taunt_soundtime)
2572         {
2573                 self.taunt_soundtime = 0;
2574                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2575         }
2576
2577         target_voicescript_next(self);
2578
2579         // WEAPONTODO: Move into weaponsystem somehow
2580         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2581         if(!self.weapon)
2582                 self.clip_load = self.clip_size = 0;
2583 }
2584
2585 /*
2586 =============
2587 PlayerPostThink
2588
2589 Called every frame for each client after the physics are run
2590 =============
2591 */
2592 .float idlekick_lasttimeleft;
2593 void PlayerPostThink (void)
2594 {
2595         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2596         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2597         {
2598                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2599                 {
2600                         if(self.idlekick_lasttimeleft)
2601                         {
2602                                 self.idlekick_lasttimeleft = 0;
2603                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2604                         }
2605                 }
2606                 else
2607                 {
2608                         float timeleft;
2609                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2610                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2611                         {
2612                                 if(!self.idlekick_lasttimeleft)
2613                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2614                         }
2615                         if(timeleft <= 0)
2616                         {
2617                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2618                                 dropclient(self);
2619                                 return;
2620                         }
2621                         else if(timeleft <= 10)
2622                         {
2623                                 if(timeleft != self.idlekick_lasttimeleft)
2624                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2625                                 self.idlekick_lasttimeleft = timeleft;
2626                         }
2627                 }
2628         }
2629
2630 #ifdef TETRIS
2631         if(self.impulse == 100)
2632                 ImpulseCommands();
2633         if (!TetrisPostFrame())
2634         {
2635 #endif
2636
2637         CheatFrame();
2638
2639         //CheckPlayerJump();
2640
2641         if(IS_PLAYER(self)) {
2642                 CheckRules_Player();
2643                 UpdateChatBubble();
2644                 if (self.impulse)
2645                         ImpulseCommands();
2646                 if (intermission_running)
2647                         return;         // intermission or finale
2648                 GetPressedKeys();
2649         }
2650
2651 #ifdef TETRIS
2652         }
2653 #endif
2654
2655         /*
2656         float i;
2657         for(i = 0; i < 1000; ++i)
2658         {
2659                 vector end;
2660                 end = self.origin + '0 0 1024' + 512 * randomvec();
2661                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2662                 if(trace_fraction < 1)
2663                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2664                 {
2665                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2666                         break;
2667                 }
2668         }
2669         */
2670
2671         if(self.waypointsprite_attachedforcarrier)
2672                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2673
2674         playerdemo_write();
2675
2676         CSQCMODEL_AUTOUPDATE();
2677 }