qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 Item_ItemsTime_Get(self);
 400                 msg_entity = self;
 401                 WriteByte(MSG_ONE, SVC_SETVIEW);
 402                 WriteEntity(MSG_ONE, self);
 403         }
 404
 405         DropAllRunes(self);
 406         MUTATOR_CALLHOOK(MakePlayerObserver);
 407
 408         minstagib_stop_countdown(self);
 409
 410         Portal_ClearAll(self);
 411
 412         if(self.alivetime)
 413         {
 414                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419             vehicles_exit(VHEF_RELESE);
 420
 421         if(self.flagcarried)
 422                 DropFlag(self.flagcarried, world, world);
 423
 424         WaypointSprite_PlayerDead();
 425
 426         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 427                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 428
 429         if(self.killcount != -666) {
 430                 if(g_lms) {
 431                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 432                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 433                         else
 434                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 435                 } else
 436                         bprint ("^4", self.netname, "^4 is spectating now\n");
 437
 438                 if(self.just_joined == FALSE) {
 439                         LogTeamchange(self.playerid, -1, 4);
 440                 } else
 441                         self.just_joined = FALSE;
 442         }
 443
 444         PlayerScore_Clear(self); // clear scores when needed
 445
 446         accuracy_resend(self);
 447
 448         self.spectatortime = time;
 449
 450         self.classname = "observer";
 451         self.iscreature = FALSE;
 452         self.damagedbycontents = FALSE;
 453         self.health = -666;
 454         self.takedamage = DAMAGE_NO;
 455         self.solid = SOLID_NOT;
 456         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 457         self.flags = FL_CLIENT | FL_NOTARGET;
 458         self.armorvalue = 666;
 459         self.effects = 0;
 460         self.armorvalue = autocvar_g_balance_armor_start;
 461         self.pauserotarmor_finished = 0;
 462         self.pauserothealth_finished = 0;
 463         self.pauseregen_finished = 0;
 464         self.damageforcescale = 0;
 465         self.death_time = 0;
 466         self.respawn_time = 0;
 467         self.alpha = 0;
 468         self.scale = 0;
 469         self.fade_time = 0;
 470         self.pain_frame = 0;
 471         self.pain_finished = 0;
 472         self.strength_finished = 0;
 473         self.invincible_finished = 0;
 474         self.superweapons_finished = 0;
 475         self.pushltime = 0;
 476         self.think = SUB_Null;
 477         self.nextthink = 0;
 478         self.hook_time = 0;
 479         self.runes = 0;
 480         self.deadflag = DEAD_NO;
 481         self.angles = spot.angles;
 482         self.angles_z = 0;
 483         self.fixangle = TRUE;
 484         self.crouch = FALSE;
 485
 486         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 487         self.prevorigin = self.origin;
 488         self.items = 0;
 489         WEPSET_CLEAR_E(self);
 490         self.model = "";
 491         FixPlayermodel();
 492         setmodel(self, "null");
 493         self.drawonlytoclient = self;
 494
 495         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 496         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 497
 498         self.weapon = 0;
 499         self.weaponname = "";
 500         self.switchingweapon = 0;
 501         self.weaponmodel = "";
 502         self.weaponentity = world;
 503         self.exteriorweaponentity = world;
 504         self.killcount = -666;
 505         self.velocity = '0 0 0';
 506         self.avelocity = '0 0 0';
 507         self.punchangle = '0 0 0';
 508         self.punchvector = '0 0 0';
 509         self.oldvelocity = self.velocity;
 510         self.fire_endtime = -1;
 511
 512         if(g_arena)
 513         {
 514                 if(self.version_mismatch)
 515                 {
 516                         Spawnqueue_Unmark(self);
 517                         Spawnqueue_Remove(self);
 518                 }
 519                 else
 520                 {
 521                         Spawnqueue_Insert(self);
 522                 }
 523         }
 524         else if(g_lms)
 525         {
 526                 // Only if the player cannot play at all
 527                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 528                         self.frags = FRAGS_SPECTATOR;
 529                 else
 530                         self.frags = FRAGS_LMS_LOSER;
 531         }
 532         else if(g_ca)
 533         {
 534                 if(self.caplayer)
 535                         self.frags = FRAGS_LMS_LOSER;
 536                 else
 537                         self.frags = FRAGS_SPECTATOR;
 538         }
 539         else
 540                 self.frags = FRAGS_SPECTATOR;
 541 }
 542
 543 .float model_randomizer;
 544 void FixPlayermodel()
 545 {
 546         string defaultmodel;
 547         float defaultskin, chmdl, oldskin, n, i;
 548         vector m1, m2;
 549
 550         defaultmodel = "";
 551         defaultskin = 0;
 552         chmdl = FALSE;
 553
 554         if(autocvar_sv_defaultcharacter == 1)
 555         {
 556                 if(teamplay)
 557                 {
 558                         string s;
 559                         s = Team_ColorNameLowerCase(self.team);
 560                         if(s != "neutral")
 561                         {
 562                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 563                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 564                         }
 565                 }
 566
 567                 if(defaultmodel == "")
 568                 {
 569                         defaultmodel = autocvar_sv_defaultplayermodel;
 570                         defaultskin = autocvar_sv_defaultplayerskin;
 571                 }
 572
 573                 n = tokenize_console(defaultmodel);
 574                 if(n > 0)
 575                         defaultmodel = argv(floor(n * self.model_randomizer));
 576
 577                 i = strstrofs(defaultmodel, ":", 0);
 578                 if(i >= 0)
 579                 {
 580                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 581                         defaultmodel = substring(defaultmodel, 0, i);
 582                 }
 583         }
 584
 585         if(defaultmodel != "")
 586         {
 587                 if (defaultmodel != self.model)
 588                 {
 589                         m1 = self.mins;
 590                         m2 = self.maxs;
 591                         setplayermodel (self, defaultmodel);
 592                         setsize (self, m1, m2);
 593                         chmdl = TRUE;
 594                 }
 595
 596                 oldskin = self.skin;
 597                 self.skin = defaultskin;
 598         } else {
 599                 if (self.playermodel != self.model || self.playermodel == "")
 600                 {
 601                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 602                         m1 = self.mins;
 603                         m2 = self.maxs;
 604                         setplayermodel (self, self.playermodel);
 605                         setsize (self, m1, m2);
 606                         chmdl = TRUE;
 607                 }
 608
 609                 oldskin = self.skin;
 610                 self.skin = stof(self.playerskin);
 611         }
 612
 613         if(chmdl || oldskin != self.skin)
 614                 self.species = player_getspecies(); // model or skin has changed
 615
 616         if(!teamplay)
 617                 if(strlen(autocvar_sv_defaultplayercolors))
 618                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 619                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 620 }
 621
 622 void PlayerTouchExplode(entity p1, entity p2)
 623 {
 624         vector org;
 625         org = (p1.origin + p2.origin) * 0.5;
 626         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 627
 628         te_explosion(org);
 629
 630         entity e;
 631         e = spawn();
 632         setorigin(e, org);
 633         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 634         remove(e);
 635 }
 636
 637 /*
 638 =============
 639 PutClientInServer
 640
 641 Called when a client spawns in the server
 642 =============
 643 */
 644 //void() ctf_playerchanged;
 645
 646 void PutClientInServer (void)
 647 {
 648         if(clienttype(self) == CLIENTTYPE_BOT)
 649         {
 650                 self.classname = "player";
 651                 if(g_ca)
 652                         self.caplayer = 1;
 653         }
 654         else if(clienttype(self) == CLIENTTYPE_REAL)
 655         {
 656                 msg_entity = self;
 657                 WriteByte(MSG_ONE, SVC_SETVIEW);
 658                 WriteEntity(MSG_ONE, self);
 659         }
 660
 661         // reset player keys
 662         self.itemkeys = 0;
 663
 664         // player is dead and becomes observer
 665         // FIXME fix LMS scoring for new system
 666         if(g_lms)
 667         {
 668                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 669                         self.classname = "observer";
 670         }
 671
 672         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 673                 self.classname = "observer";
 674
 675         if(gameover)
 676                 self.classname = "observer";
 677
 678         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 679                 entity spot, oldself;
 680                 float j;
 681
 682                 accuracy_resend(self);
 683
 684                 if(self.team < 0)
 685                         JoinBestTeam(self, FALSE, TRUE);
 686
 687                 race_PreSpawn();
 688
 689                 spot = SelectSpawnPoint (FALSE);
 690                 if(!spot)
 691                 {
 692                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 693                         return; // spawn failed
 694                 }
 695
 696                 Item_ItemsTime_Clear();
 697
 698                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 699
 700                 self.classname = "player";
 701                 self.wasplayer = TRUE;
 702                 self.iscreature = TRUE;
 703                 self.damagedbycontents = TRUE;
 704                 self.movetype = MOVETYPE_WALK;
 705                 self.solid = SOLID_SLIDEBOX;
 706                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 707                 if(autocvar_g_playerclip_collisions)
 708                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 709                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 710                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 711                 self.frags = FRAGS_PLAYER;
 712                 if(INDEPENDENT_PLAYERS)
 713                         MAKE_INDEPENDENT_PLAYER(self);
 714                 self.flags = FL_CLIENT;
 715                 if(autocvar__notarget)
 716                         self.flags |= FL_NOTARGET;
 717                 self.takedamage = DAMAGE_AIM;
 718                 if(g_minstagib)
 719                         self.effects = EF_FULLBRIGHT;
 720                 else
 721                         self.effects = 0;
 722                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 723                 self.air_finished = time + 12;
 724                 self.dmg = 2;
 725                 if(autocvar_g_balance_nex_charge)
 726                 {
 727                         if(autocvar_g_balance_nex_secondary_chargepool)
 728                                 self.nex_chargepool_ammo = 1;
 729                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 730                 }
 731
 732                 if(inWarmupStage)
 733                 {
 734                         self.ammo_shells = warmup_start_ammo_shells;
 735                         self.ammo_nails = warmup_start_ammo_nails;
 736                         self.ammo_rockets = warmup_start_ammo_rockets;
 737                         self.ammo_cells = warmup_start_ammo_cells;
 738                         self.ammo_fuel = warmup_start_ammo_fuel;
 739                         self.health = warmup_start_health;
 740                         self.armorvalue = warmup_start_armorvalue;
 741                         WEPSET_COPY_EA(self, warmup_start_weapons);
 742                 }
 743                 else
 744                 {
 745                         self.ammo_shells = start_ammo_shells;
 746                         self.ammo_nails = start_ammo_nails;
 747                         self.ammo_rockets = start_ammo_rockets;
 748                         self.ammo_cells = start_ammo_cells;
 749                         self.ammo_fuel = start_ammo_fuel;
 750                         self.health = start_health;
 751                         self.armorvalue = start_armorvalue;
 752                         WEPSET_COPY_EA(self, start_weapons);
 753                 }
 754
 755                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 756                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 757                 else
 758                         self.superweapons_finished = 0;
 759
 760                 if(g_weaponarena_random)
 761                 {
 762                         if(g_weaponarena_random_with_laser)
 763                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 764                         W_RandomWeapons(self, g_weaponarena_random);
 765                         if(g_weaponarena_random_with_laser)
 766                                 WEPSET_OR_EW(self, WEP_LASER);
 767                 }
 768
 769                 self.items = start_items;
 770
 771                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 772                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 773                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 774                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 775                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 776                 //extend the pause of rotting if client was reset at the beginning of the countdown
 777                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 778                         self.spawnshieldtime += game_starttime - time;
 779                         self.pauserotarmor_finished += game_starttime - time;
 780                         self.pauserothealth_finished += game_starttime - time;
 781                         self.pauseregen_finished += game_starttime - time;
 782                 }
 783                 self.damageforcescale = 2;
 784                 self.death_time = 0;
 785                 self.respawn_time = 0;
 786                 self.scale = 0;
 787                 self.fade_time = 0;
 788                 self.pain_frame = 0;
 789                 self.pain_finished = 0;
 790                 self.strength_finished = 0;
 791                 self.invincible_finished = 0;
 792                 self.pushltime = 0;
 793                 // players have no think function
 794                 self.think = SUB_Null;
 795                 self.nextthink = 0;
 796                 self.hook_time = 0;
 797                 self.dmg_team = 0;
 798                 self.ballistics_density = autocvar_g_ballistics_density_player;
 799
 800                 self.metertime = 0;
 801
 802                 self.runes = 0;
 803
 804                 self.deadflag = DEAD_NO;
 805
 806                 self.angles = spot.angles;
 807
 808                 self.angles_z = 0; // never spawn tilted even if the spot says to
 809                 self.fixangle = TRUE; // turn this way immediately
 810                 self.velocity = '0 0 0';
 811                 self.avelocity = '0 0 0';
 812                 self.punchangle = '0 0 0';
 813                 self.punchvector = '0 0 0';
 814                 self.oldvelocity = self.velocity;
 815                 self.fire_endtime = -1;
 816
 817                 msg_entity = self;
 818                 WRITESPECTATABLE_MSG_ONE({
 819                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 820                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 821                 });
 822
 823                 self.model = "";
 824                 FixPlayermodel();
 825                 self.drawonlytoclient = world;
 826
 827                 self.crouch = FALSE;
 828                 self.view_ofs = PL_VIEW_OFS;
 829                 setsize (self, PL_MIN, PL_MAX);
 830                 self.spawnorigin = spot.origin;
 831                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 832                 // don't reset back to last position, even if new position is stuck in solid
 833                 self.oldorigin = self.origin;
 834                 self.prevorigin = self.origin;
 835                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 836                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 837         self.hud = HUD_NORMAL;
 838
 839                 if(g_arena)
 840                 {
 841                         Spawnqueue_Remove(self);
 842                         Spawnqueue_Mark(self);
 843                 }
 844                 else if(g_ca)
 845                         self.caplayer = 1;
 846
 847                 self.event_damage = PlayerDamage;
 848
 849                 self.bot_attack = TRUE;
 850
 851                 self.statdraintime = time + 5;
 852                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 853
 854                 if(self.killcount == -666) {
 855                         PlayerScore_Clear(self);
 856                         self.killcount = 0;
 857                 }
 858
 859                 CL_SpawnWeaponentity();
 860                 self.alpha = default_player_alpha;
 861                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 862                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 863
 864                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 865                 self.lms_traveled_distance = 0;
 866                 self.speedrunning = FALSE;
 867
 868                 race_PostSpawn(spot);
 869
 870                 //stuffcmd(self, "chase_active 0");
 871                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 872
 873                 if(g_assault) {
 874                         if(self.team == assault_attacker_team)
 875                                 centerprint(self, "You are attacking!");
 876                         else
 877                                 centerprint(self, "You are defending!");
 878                 }
 879
 880                 target_voicescript_clear(self);
 881
 882                 // reset fields the weapons may use
 883                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 884                 {
 885                         weapon_action(j, WR_RESETPLAYER);
 886
 887                         // all weapons must be fully loaded when we spawn
 888                         entity e;
 889                         e = get_weaponinfo(j);
 890                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 891                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 892                 }
 893
 894                 oldself = self;
 895                 self = spot;
 896                         activator = oldself;
 897                                 string s;
 898                                 s = self.target;
 899                                 self.target = string_null;
 900                                 SUB_UseTargets();
 901                                 self.target = s;
 902                         activator = world;
 903                 self = oldself;
 904
 905                 spawn_spot = spot;
 906                 MUTATOR_CALLHOOK(PlayerSpawn);
 907
 908                 if(autocvar_spawn_debug)
 909                 {
 910                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 911                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 912                 }
 913
 914                 self.switchweapon = w_getbestweapon(self);
 915                 self.cnt = -1; // W_LastWeapon will not complain
 916                 self.weapon = 0;
 917                 self.weaponname = "";
 918                 self.switchingweapon = 0;
 919
 920                 if(!self.alivetime)
 921                         self.alivetime = time;
 922
 923                 antilag_clear(self);
 924
 925                 if (autocvar_g_spawnsound)
 926                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 927         } else if(self.classname == "observer") {
 928                 PutObserverInServer ();
 929         }
 930
 931         //if(g_ctf)
 932         //      ctf_playerchanged();
 933 }
 934
 935 .float ebouncefactor, ebouncestop; // electro's values
 936 // TODO do we need all these fields, or should we stop autodetecting runtime
 937 // changes and just have a console command to update this?
 938 float ClientInit_SendEntity(entity to, float sf)
 939 {
 940         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 941         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 948         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 949         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 950         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 951         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 952         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 953         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 954         if(sv_foginterval && world.fog != "")
 955                 WriteString(MSG_ENTITY, world.fog);
 956         else
 957                 WriteString(MSG_ENTITY, "");
 958         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 959         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 960         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 961         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 962         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 963         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 964         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 965         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 966         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 967         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 968         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 969         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 970         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 971         return TRUE;
 972 }
 973
 974 void ClientInit_CheckUpdate()
 975 {
 976         self.nextthink = time;
 977         if(self.count != autocvar_g_balance_armor_blockpercent)
 978         {
 979                 self.count = autocvar_g_balance_armor_blockpercent;
 980                 self.SendFlags |= 1;
 981         }
 982         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 983         {
 984                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 985                 self.SendFlags |= 1;
 986         }
 987         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 988         {
 989                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 990                 self.SendFlags |= 1;
 991         }
 992         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 993         {
 994                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 995                 self.SendFlags |= 1;
 996         }
 997         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 998         {
 999                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1000                 self.SendFlags |= 1;
1001         }
1002         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1003         {
1004                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1005                 self.SendFlags |= 1;
1006         }
1007 }
1008
1009 void ClientInit_Spawn()
1010 {
1011         entity o;
1012         entity e;
1013         e = spawn();
1014         e.classname = "clientinit";
1015         e.think = ClientInit_CheckUpdate;
1016         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1017
1018         o = self;
1019         self = e;
1020         ClientInit_CheckUpdate();
1021         self = o;
1022 }
1023
1024 /*
1025 =============
1026 SetNewParms
1027 =============
1028 */
1029 void SetNewParms (void)
1030 {
1031         // initialize parms for a new player
1032         parm1 = -(86400 * 366);
1033 }
1034
1035 /*
1036 =============
1037 SetChangeParms
1038 =============
1039 */
1040 void SetChangeParms (void)
1041 {
1042         // save parms for level change
1043         parm1 = self.parm_idlesince - time;
1044 }
1045
1046 /*
1047 =============
1048 DecodeLevelParms
1049 =============
1050 */
1051 void DecodeLevelParms (void)
1052 {
1053         // load parms
1054         self.parm_idlesince = parm1;
1055         if(self.parm_idlesince == -(86400 * 366))
1056                 self.parm_idlesince = time;
1057
1058         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1059         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1060 }
1061
1062 /*
1063 =============
1064 ClientKill
1065
1066 Called when a client types 'kill' in the console
1067 =============
1068 */
1069
1070 .float clientkill_nexttime;
1071 void ClientKill_Now_TeamChange()
1072 {
1073         if(self.killindicator_teamchange == -1)
1074         {
1075                 self.team = -1;
1076                 JoinBestTeam( self, FALSE, FALSE );
1077         }
1078         else if(self.killindicator_teamchange == -2)
1079         {
1080                 if(g_ca)
1081                         self.caplayer = 0;
1082                 if(blockSpectators)
1083                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1084                 PutObserverInServer();
1085         }
1086         else
1087                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1088 }
1089
1090 void ClientKill_Now()
1091 {
1092         if(self.vehicle)
1093         {
1094             vehicles_exit(VHEF_RELESE);
1095             if(!self.killindicator_teamchange)
1096             {
1097             self.vehicle_health = -1;
1098             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1099             }
1100         }
1101
1102         if(self.killindicator && !wasfreed(self.killindicator))
1103                 remove(self.killindicator);
1104
1105         self.killindicator = world;
1106
1107         if(self.killindicator_teamchange)
1108                 ClientKill_Now_TeamChange();
1109
1110         // in any case:
1111         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1112
1113         // now I am sure the player IS dead
1114 }
1115 void KillIndicator_Think()
1116 {
1117         if (gameover)
1118         {
1119                 self.owner.killindicator = world;
1120                 remove(self);
1121                 return;
1122         }
1123
1124         if (self.owner.alpha < 0)
1125         {
1126                 self.owner.killindicator = world;
1127                 remove(self);
1128                 return;
1129         }
1130
1131         if(self.cnt <= 0)
1132         {
1133                 self = self.owner;
1134                 ClientKill_Now(); // no oldself needed
1135                 return;
1136         }
1137     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1138     {
1139         self.nextthink = time + 1;
1140         self.cnt -= 1;
1141     }
1142         else
1143         {
1144                 if(self.cnt <= 10)
1145                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1146                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1147                 {
1148                         if(self.cnt <= 10)
1149                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1150                 }
1151                 self.nextthink = time + 1;
1152                 self.cnt -= 1;
1153         }
1154 }
1155
1156 float clientkilltime;
1157 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1158 {
1159         float killtime;
1160         float starttime;
1161         entity e;
1162
1163         if (gameover)
1164                 return;
1165
1166         killtime = autocvar_g_balance_kill_delay;
1167
1168         if(g_race_qualifying || g_cts)
1169                 killtime = 0;
1170
1171     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1172     {
1173                 remove(self.killindicator);
1174                 self.killindicator = world;
1175
1176         ClientKill_Now(); // allow instant kill in this case
1177         return;
1178     }
1179
1180         self.killindicator_teamchange = targetteam;
1181
1182     if(!self.killindicator)
1183         {
1184                 if(self.deadflag == DEAD_NO)
1185                 {
1186                         killtime = max(killtime, self.clientkill_nexttime - time);
1187                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1188                 }
1189
1190                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1191                 {
1192                         ClientKill_Now();
1193                 }
1194                 else
1195                 {
1196                         starttime = max(time, clientkilltime);
1197
1198                         self.killindicator = spawn();
1199                         self.killindicator.owner = self;
1200                         self.killindicator.scale = 0.5;
1201                         setattachment(self.killindicator, self, "");
1202                         setorigin(self.killindicator, '0 0 52');
1203                         self.killindicator.think = KillIndicator_Think;
1204                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1205                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1206                         self.killindicator.cnt = ceil(killtime);
1207                         self.killindicator.count = bound(0, ceil(killtime), 10);
1208                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1209
1210                         for(e = world; (e = find(e, classname, "body")) != world; )
1211                         {
1212                                 if(e.enemy != self)
1213                                         continue;
1214                                 e.killindicator = spawn();
1215                                 e.killindicator.owner = e;
1216                                 e.killindicator.scale = 0.5;
1217                                 setattachment(e.killindicator, e, "");
1218                                 setorigin(e.killindicator, '0 0 52');
1219                                 e.killindicator.think = KillIndicator_Think;
1220                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1221                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1222                                 e.killindicator.cnt = ceil(killtime);
1223                         }
1224                         self.lip = 0;
1225                 }
1226         }
1227         if(self.killindicator)
1228         {
1229                 if(targetteam == 0) // just die
1230                 {
1231                         self.killindicator.colormod = '0 0 0';
1232                         if(clienttype(self) == CLIENTTYPE_REAL)
1233                         if(self.killindicator.cnt > 0)
1234                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1235                 }
1236                 else if(targetteam == -1) // auto
1237                 {
1238                         self.killindicator.colormod = '0 1 0';
1239                         if(clienttype(self) == CLIENTTYPE_REAL)
1240                         if(self.killindicator.cnt > 0)
1241                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1242                 }
1243                 else if(targetteam == -2) // spectate
1244                 {
1245                         self.killindicator.colormod = '0.5 0.5 0.5';
1246                         if(clienttype(self) == CLIENTTYPE_REAL)
1247                         if(self.killindicator.cnt > 0)
1248                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1249                 }
1250                 else
1251                 {
1252                         self.killindicator.colormod = TeamColor(targetteam);
1253                         if(clienttype(self) == CLIENTTYPE_REAL)
1254                         if(self.killindicator.cnt > 0)
1255                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1256                 }
1257         }
1258
1259 }
1260
1261 void ClientKill (void)
1262 {
1263         if (gameover)
1264                 return;
1265
1266         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1267         {
1268                 // do nothing
1269         }
1270     else if(self.freezetag_frozen)
1271     {
1272         // do nothing
1273     }
1274         else
1275                 ClientKill_TeamChange(0);
1276 }
1277
1278 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1279 {
1280     e.killindicator = spawn();
1281     e.killindicator.owner = e;
1282     e.killindicator.think = KillIndicator_Think;
1283     e.killindicator.nextthink = time + (e.lip) * 0.05;
1284     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1285     e.killindicator.health = 1; // this is used to indicate that it should be silent
1286     e.lip = 0;
1287 }
1288
1289 void FixClientCvars(entity e)
1290 {
1291         // send prediction settings to the client
1292         stuffcmd(e, "\nin_bindmap 0 0\n");
1293         if(g_race || g_cts)
1294                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1295         if(autocvar_g_antilag == 3) // client side hitscan
1296                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1297         if(sv_gentle)
1298                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1299         /*
1300          * we no longer need to stuff this. Remove this comment block if you feel
1301          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1302         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1303         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1304         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1305         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1306         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1307         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1308         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1309         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1310         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1311         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1312         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1313         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1314         stuffcmd(e, "cl_movement_edgefriction 1\n");
1315          */
1316 }
1317
1318 float PlayerInIDList(entity p, string idlist)
1319 {
1320         float n, i;
1321         string s;
1322
1323         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1324         if not(p.crypto_idfp)
1325                 return 0;
1326
1327         // this function allows abbreviated player IDs too!
1328         n = tokenize_console(idlist);
1329         for(i = 0; i < n; ++i)
1330         {
1331                 s = argv(i);
1332                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1333                         return 1;
1334         }
1335
1336         return 0;
1337 }
1338
1339 /*
1340 =============
1341 ClientConnect
1342
1343 Called when a client connects to the server
1344 =============
1345 */
1346 //void ctf_clientconnect();
1347 string ColoredTeamName(float t);
1348 void DecodeLevelParms (void);
1349 //void dom_player_join_team(entity pl);
1350 void set_dom_state(entity e);
1351 void ClientConnect (void)
1352 {
1353         float t;
1354
1355         if(self.flags & FL_CLIENT)
1356         {
1357                 print("Warning: ClientConnect, but already connected!\n");
1358                 return;
1359         }
1360
1361         if(Ban_MaybeEnforceBanOnce(self))
1362                 return;
1363
1364         DecodeLevelParms();
1365
1366 #ifdef WATERMARK
1367         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1368 #endif
1369
1370         self.classname = "player_joining";
1371
1372         self.flags = FL_CLIENT;
1373         self.version_nagtime = time + 10 + random() * 10;
1374
1375         if(player_count<0)
1376         {
1377                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1378                 player_count = 0;
1379         }
1380
1381         PlayerScore_Attach(self);
1382         ClientData_Attach();
1383         accuracy_init(self);
1384
1385         bot_clientconnect();
1386
1387         playerdemo_init();
1388
1389         anticheat_init();
1390
1391         race_PreSpawnObserver();
1392
1393         //if(g_domination)
1394         //      dom_player_join_team(self);
1395
1396         // identify the right forced team
1397         if(autocvar_g_campaign)
1398         {
1399                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1400                 {
1401                         switch(autocvar_g_campaign_forceteam)
1402                         {
1403                                 case 1: self.team_forced = COLOR_TEAM1; break;
1404                                 case 2: self.team_forced = COLOR_TEAM2; break;
1405                                 case 3: self.team_forced = COLOR_TEAM3; break;
1406                                 case 4: self.team_forced = COLOR_TEAM4; break;
1407                                 default: self.team_forced = 0;
1408                         }
1409                 }
1410         }
1411         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1412                 self.team_forced = COLOR_TEAM1;
1413         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1414                 self.team_forced = COLOR_TEAM2;
1415         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1416                 self.team_forced = COLOR_TEAM3;
1417         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1418                 self.team_forced = COLOR_TEAM4;
1419         else if(autocvar_g_forced_team_otherwise == "red")
1420                 self.team_forced = COLOR_TEAM1;
1421         else if(autocvar_g_forced_team_otherwise == "blue")
1422                 self.team_forced = COLOR_TEAM2;
1423         else if(autocvar_g_forced_team_otherwise == "yellow")
1424                 self.team_forced = COLOR_TEAM3;
1425         else if(autocvar_g_forced_team_otherwise == "pink")
1426                 self.team_forced = COLOR_TEAM4;
1427         else if(autocvar_g_forced_team_otherwise == "spectate")
1428                 self.team_forced = -1;
1429         else if(autocvar_g_forced_team_otherwise == "spectator")
1430                 self.team_forced = -1;
1431         else
1432                 self.team_forced = 0;
1433
1434         if(!teamplay)
1435                 if(self.team_forced > 0)
1436                         self.team_forced = 0;
1437
1438         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1439
1440         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1441                 self.classname = "observer";
1442         } else {
1443                 if(teamplay)
1444                 {
1445                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1446                         {
1447                                 self.classname = "player";
1448                                 campaign_bots_may_start = 1;
1449                         }
1450                         else
1451                         {
1452                                 self.classname = "observer"; // do it anyway
1453                         }
1454                 }
1455                 else
1456                 {
1457                         self.classname = "player";
1458                         campaign_bots_may_start = 1;
1459                 }
1460         }
1461
1462         self.playerid = (playerid_last = playerid_last + 1);
1463
1464         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1465
1466     if(clienttype(self) == CLIENTTYPE_BOT)
1467         PlayerStats_AddPlayer(self);
1468
1469         if(autocvar_sv_eventlog)
1470                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1471
1472         LogTeamchange(self.playerid, self.team, 1);
1473
1474         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1475
1476         self.netname_previous = strzone(self.netname);
1477
1478         bprint("^4", self.netname, "^4 connected");
1479
1480         if(self.classname != "observer" && (g_domination || g_ctf))
1481                 bprint(" and joined the ", ColoredTeamName(self.team));
1482
1483         bprint("\n");
1484
1485         stuffcmd(self, strcat(clientstuff, "\n"));
1486         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1487
1488         FixClientCvars(self);
1489
1490         // spawnfunc_waypoint sprites
1491         WaypointSprite_InitClient(self);
1492
1493         // Wazat's grappling hook
1494         SetGrappleHookBindings();
1495
1496         // get version info from player
1497         stuffcmd(self, "cmd clientversion $gameversion\n");
1498
1499         // get other cvars from player
1500         GetCvars(0);
1501
1502         // notify about available teams
1503         if(teamplay)
1504         {
1505                 CheckAllowedTeams(self);
1506                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1507                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1508         }
1509         else
1510                 stuffcmd(self, "set _teams_available 0\n");
1511
1512         if(g_arena || g_ca)
1513         {
1514                 self.classname = "observer";
1515                 if(g_arena)
1516                         Spawnqueue_Insert(self);
1517         }
1518         /*else if(g_ctf)
1519         {
1520                 ctf_clientconnect();
1521         }*/
1522
1523         attach_entcs();
1524
1525         bot_relinkplayerlist();
1526
1527         self.spectatortime = time;
1528         if(blockSpectators)
1529         {
1530                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1531         }
1532
1533         self.jointime = time;
1534         self.allowed_timeouts = autocvar_sv_timeout_number;
1535
1536         if(clienttype(self) == CLIENTTYPE_REAL)
1537         {
1538                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1539                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1540         }
1541
1542         if(g_lms)
1543         {
1544                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1545                 {
1546                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1547                         self.frags = FRAGS_SPECTATOR;
1548                 }
1549         }
1550
1551         if(!sv_foginterval && world.fog != "")
1552                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1553
1554         SoundEntity_Attach(self);
1555
1556         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1557         {
1558                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1559                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1560         }
1561         else
1562                 self.hitplotfh = -1;
1563
1564         if(g_race || g_cts) {
1565                 string rr;
1566                 if(g_cts)
1567                         rr = CTS_RECORD;
1568                 else
1569                         rr = RACE_RECORD;
1570
1571                 msg_entity = self;
1572                 race_send_recordtime(MSG_ONE);
1573                 race_send_speedaward(MSG_ONE);
1574
1575                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1576                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1577                 race_send_speedaward_alltimebest(MSG_ONE);
1578
1579                 float i;
1580                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1581                         race_SendRankings(i, 0, 0, MSG_ONE);
1582                 }
1583         }
1584         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1585                 send_CSQC_teamnagger();
1586
1587         if (g_domination)
1588                 set_dom_state(self);
1589
1590         CheatInitClient();
1591
1592         if(!autocvar_g_campaign)
1593                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1594
1595         CSQCMODEL_AUTOINIT();
1596
1597         self.model_randomizer = random();
1598
1599     if(clienttype(self) != CLIENTTYPE_REAL)
1600         return;
1601
1602     sv_notice_join();
1603 }
1604 /*
1605 =============
1606 ClientDisconnect
1607
1608 Called when a client disconnects from the server
1609 =============
1610 */
1611 .entity chatbubbleentity;
1612 void ReadyCount();
1613 void ClientDisconnect (void)
1614 {
1615         if(self.vehicle)
1616             vehicles_exit(VHEF_RELESE);
1617
1618         if not(self.flags & FL_CLIENT)
1619         {
1620                 print("Warning: ClientDisconnect without ClientConnect\n");
1621                 return;
1622         }
1623
1624         PlayerStats_AddGlobalInfo(self);
1625
1626         CheatShutdownClient();
1627
1628         if(self.hitplotfh >= 0)
1629         {
1630                 fclose(self.hitplotfh);
1631                 self.hitplotfh = -1;
1632         }
1633
1634         anticheat_report();
1635         anticheat_shutdown();
1636
1637         playerdemo_shutdown();
1638
1639         bot_clientdisconnect();
1640
1641         if(self.entcs)
1642                 detach_entcs();
1643
1644         if(autocvar_sv_eventlog)
1645                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1646         bprint ("^4",self.netname);
1647         bprint ("^4 disconnected\n");
1648
1649         SoundEntity_Detach(self);
1650
1651         DropAllRunes(self);
1652         MUTATOR_CALLHOOK(ClientDisconnect);
1653
1654         Portal_ClearAll(self);
1655
1656         RemoveGrapplingHook(self);
1657         if(self.flagcarried)
1658                 DropFlag(self.flagcarried, world, world);
1659
1660         // Here, everything has been done that requires this player to be a client.
1661
1662         self.flags &~= FL_CLIENT;
1663
1664         if (self.chatbubbleentity)
1665                 remove (self.chatbubbleentity);
1666
1667         if (self.killindicator)
1668                 remove (self.killindicator);
1669
1670         WaypointSprite_PlayerGone();
1671
1672         bot_relinkplayerlist();
1673
1674         if(g_arena)
1675         {
1676                 Spawnqueue_Unmark(self);
1677                 Spawnqueue_Remove(self);
1678         }
1679
1680         accuracy_free(self);
1681         ClientData_Detach();
1682         PlayerScore_Detach(self);
1683
1684         if(self.netname_previous)
1685                 strunzone(self.netname_previous);
1686         if(self.clientstatus)
1687                 strunzone(self.clientstatus);
1688         if(self.weaponorder_byimpulse)
1689                 strunzone(self.weaponorder_byimpulse);
1690
1691         ClearPlayerSounds();
1692
1693         if(self.personal)
1694                 remove(self.personal);
1695
1696         self.playerid = 0;
1697         ReadyCount();
1698
1699         // free cvars
1700         GetCvars(-1);
1701 }
1702
1703 .float BUTTON_CHAT;
1704 void ChatBubbleThink()
1705 {
1706         self.nextthink = time;
1707         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1708         {
1709                 if(self.owner) // but why can that ever be world?
1710                         self.owner.chatbubbleentity = world;
1711                 remove(self);
1712                 return;
1713         }
1714         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1715 #ifdef TETRIS
1716                 || self.owner.tetris_on
1717 #endif
1718         )
1719                 self.model = self.mdl;
1720         else
1721                 self.model = "";
1722 }
1723
1724 void UpdateChatBubble()
1725 {
1726         if (self.alpha < 0)
1727                 return;
1728         // spawn a chatbubble entity if needed
1729         if (!self.chatbubbleentity)
1730         {
1731                 self.chatbubbleentity = spawn();
1732                 self.chatbubbleentity.owner = self;
1733                 self.chatbubbleentity.exteriormodeltoclient = self;
1734                 self.chatbubbleentity.think = ChatBubbleThink;
1735                 self.chatbubbleentity.nextthink = time;
1736                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1737                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1738                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1739                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1740                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1741                 self.chatbubbleentity.model = "";
1742                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1743         }
1744 }
1745
1746
1747 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1748 // added to the model skins
1749 /*void UpdateColorModHack()
1750 {
1751         float c;
1752         c = self.clientcolors & 15;
1753         // LordHavoc: only bothering to support white, green, red, yellow, blue
1754              if (!teamplay) self.colormod = '0 0 0';
1755         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1756         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1757         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1758         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1759         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1760         else self.colormod = '1 1 1';
1761 }*/
1762
1763 void respawn(void)
1764 {
1765         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1766         {
1767                 self.solid = SOLID_NOT;
1768                 self.takedamage = DAMAGE_NO;
1769                 self.movetype = MOVETYPE_FLY;
1770                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1771                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1772                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1773                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1774                 if(autocvar_g_respawn_ghosts_maxtime)
1775                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1776         }
1777
1778         CopyBody(1);
1779
1780         self.effects |= EF_NODRAW; // prevent another CopyBody
1781         PutClientInServer();
1782 }
1783
1784 void play_countdown(float finished, string samp)
1785 {
1786         if(clienttype(self) == CLIENTTYPE_REAL)
1787                 if(floor(finished - time - frametime) != floor(finished - time))
1788                         if(finished - time < 6)
1789                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1790 }
1791
1792 void player_powerups (void)
1793 {
1794         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1795         olditems = self.items;
1796
1797         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1798         {
1799                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1800                 self.modelflags |= MF_ROCKET;
1801         }
1802         else
1803         {
1804                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1805                 self.modelflags &~= MF_ROCKET;
1806         }
1807
1808         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1809
1810         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1811                 return;
1812
1813         Fire_ApplyDamage(self);
1814         Fire_ApplyEffect(self);
1815
1816         if (g_minstagib)
1817         {
1818                 self.effects |= EF_FULLBRIGHT;
1819
1820                 if (self.items & IT_STRENGTH)
1821                 {
1822                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1823                         if (time > self.strength_finished)
1824                         {
1825                                 self.alpha = default_player_alpha;
1826                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1827                                 self.items &~= IT_STRENGTH;
1828                                 sprint(self, "^3Invisibility has worn off\n");
1829                         }
1830                 }
1831                 else
1832                 {
1833                         if (time < self.strength_finished)
1834                         {
1835                                 self.alpha = g_minstagib_invis_alpha;
1836                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1837                                 self.items |= IT_STRENGTH;
1838                                 sprint(self, "^3You are invisible\n");
1839                         }
1840                 }
1841
1842                 if (self.items & IT_INVINCIBLE)
1843                 {
1844                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1845                         if (time > self.invincible_finished)
1846                         {
1847                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1848                                 sprint(self, "^3Speed has worn off\n");
1849                         }
1850                 }
1851                 else
1852                 {
1853                         if (time < self.invincible_finished)
1854                         {
1855                                 self.items = self.items | IT_INVINCIBLE;
1856                                 sprint(self, "^3You are on speed\n");
1857                         }
1858                 }
1859         }
1860         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1861         {
1862                 if (self.items & IT_STRENGTH)
1863                 {
1864                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1865                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1866                         if (time > self.strength_finished)
1867                         {
1868                                 self.items = self.items - (self.items & IT_STRENGTH);
1869                                 sprint(self, "^3Strength has worn off\n");
1870                         }
1871                 }
1872                 else
1873                 {
1874                         if (time < self.strength_finished)
1875                         {
1876                                 self.items = self.items | IT_STRENGTH;
1877                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1878                         }
1879                 }
1880                 if (self.items & IT_INVINCIBLE)
1881                 {
1882                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1883                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1884                         if (time > self.invincible_finished)
1885                         {
1886                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1887                                 sprint(self, "^3Shield has worn off\n");
1888                         }
1889                 }
1890                 else
1891                 {
1892                         if (time < self.invincible_finished)
1893                         {
1894                                 self.items = self.items | IT_INVINCIBLE;
1895                                 sprint(self, "^3Shield surrounds you\n");
1896                         }
1897                 }
1898                 if (self.items & IT_SUPERWEAPON)
1899                 {
1900                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1901                         {
1902                                 self.superweapons_finished = 0;
1903                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1904                                 sprint(self, "^3Superweapons have been lost\n");
1905                         }
1906                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1907                         {
1908                                 // don't let them run out
1909                         }
1910                         else
1911                         {
1912                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1913                                 if (time > self.superweapons_finished)
1914                                 {
1915                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1916                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1917                                         sprint(self, "^3Superweapons have broken down\n");
1918                                 }
1919                         }
1920                 }
1921                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1922                 {
1923                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1924                         {
1925                                 self.items = self.items | IT_SUPERWEAPON;
1926                                 sprint(self, "^3You now have a superweapon\n");
1927                         }
1928                         else
1929                         {
1930                                 self.superweapons_finished = 0;
1931                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1932                         }
1933                 }
1934                 else
1935                 {
1936                         self.superweapons_finished = 0;
1937                 }
1938         }
1939
1940         if(autocvar_g_nodepthtestplayers)
1941                 self.effects = self.effects | EF_NODEPTHTEST;
1942
1943         if(autocvar_g_fullbrightplayers)
1944                 self.effects = self.effects | EF_FULLBRIGHT;
1945
1946         // midair gamemode: damage only while in the air
1947         // if in midair mode, being on ground grants temporary invulnerability
1948         // (this is so that multishot weapon don't clear the ground flag on the
1949         // first damage in the frame, leaving the player vulnerable to the
1950         // remaining hits in the same frame)
1951         if (self.flags & FL_ONGROUND)
1952         if (g_midair)
1953                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1954
1955         if (time >= game_starttime)
1956         if (time < self.spawnshieldtime)
1957                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1958
1959         MUTATOR_CALLHOOK(PlayerPowerups);
1960 }
1961
1962 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1963 {
1964         if(current > stable)
1965                 return current;
1966         else if(current > stable - 0.25) // when close enough, "snap"
1967                 return stable;
1968         else
1969                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1970 }
1971
1972 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1973 {
1974         if(current < stable)
1975                 return current;
1976         else if(current < stable + 0.25) // when close enough, "snap"
1977                 return stable;
1978         else
1979                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1980 }
1981
1982 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1983 {
1984         if(current > rotstable)
1985         {
1986                 if(rotframetime > 0)
1987                 {
1988                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1989                         current = max(rotstable, current - rotlinear * rotframetime);
1990                 }
1991         }
1992         else if(current < regenstable)
1993         {
1994                 if(regenframetime > 0)
1995                 {
1996                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1997                         current = min(regenstable, current + regenlinear * regenframetime);
1998                 }
1999         }
2000
2001         if(current > limit)
2002                 current = limit;
2003
2004         return current;
2005 }
2006
2007 void player_regen (void)
2008 {
2009         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2010         maxh = autocvar_g_balance_health_rotstable;
2011         maxa = autocvar_g_balance_armor_rotstable;
2012         maxf = autocvar_g_balance_fuel_rotstable;
2013         minh = autocvar_g_balance_health_regenstable;
2014         mina = autocvar_g_balance_armor_regenstable;
2015         minf = autocvar_g_balance_fuel_regenstable;
2016         limith = autocvar_g_balance_health_limit;
2017         limita = autocvar_g_balance_armor_limit;
2018         limitf = autocvar_g_balance_fuel_limit;
2019
2020         max_mod = regen_mod = rot_mod = limit_mod = 1;
2021
2022         if (self.runes & RUNE_REGEN)
2023         {
2024                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2025                 {
2026                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2027                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2028                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2029                 }
2030                 else
2031                 {
2032                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2033                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2034                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2035                 }
2036         }
2037         else if (self.runes & CURSE_VENOM)
2038         {
2039                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2040                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2041                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2042                 else
2043                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2044                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2045                 //if (!self.runes & RUNE_REGEN)
2046                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2047         }
2048         maxh = maxh * max_mod;
2049         //maxa = maxa * max_mod;
2050         //maxf = maxf * max_mod;
2051         minh = minh * max_mod;
2052         //mina = mina * max_mod;
2053         //minf = minf * max_mod;
2054         limith = limith * limit_mod;
2055         limita = limita * limit_mod;
2056         //limitf = limitf * limit_mod;
2057
2058         if(g_lms && g_ca)
2059                 rot_mod = 0;
2060
2061         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2062         {
2063                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2064                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2065
2066                 // if player rotted to death...  die!
2067                 if(self.health < 1)
2068                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2069         }
2070
2071         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2072                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2073 }
2074
2075 float zoomstate_set;
2076 void SetZoomState(float z)
2077 {
2078         if(z != self.zoomstate)
2079         {
2080                 self.zoomstate = z;
2081                 ClientData_Touch(self);
2082         }
2083         zoomstate_set = 1;
2084 }
2085
2086 void GetPressedKeys(void) {
2087         MUTATOR_CALLHOOK(GetPressedKeys);
2088         if (self.movement_x > 0) // get if movement keys are pressed
2089         {       // forward key pressed
2090                 self.pressedkeys |= KEY_FORWARD;
2091                 self.pressedkeys &~= KEY_BACKWARD;
2092         }
2093         else if (self.movement_x < 0)
2094         {       // backward key pressed
2095                 self.pressedkeys |= KEY_BACKWARD;
2096                 self.pressedkeys &~= KEY_FORWARD;
2097         }
2098         else
2099         {       // no x input
2100                 self.pressedkeys &~= KEY_FORWARD;
2101                 self.pressedkeys &~= KEY_BACKWARD;
2102         }
2103
2104         if (self.movement_y > 0)
2105         {       // right key pressed
2106                 self.pressedkeys |= KEY_RIGHT;
2107                 self.pressedkeys &~= KEY_LEFT;
2108         }
2109         else if (self.movement_y < 0)
2110         {       // left key pressed
2111                 self.pressedkeys |= KEY_LEFT;
2112                 self.pressedkeys &~= KEY_RIGHT;
2113         }
2114         else
2115         {       // no y input
2116                 self.pressedkeys &~= KEY_RIGHT;
2117                 self.pressedkeys &~= KEY_LEFT;
2118         }
2119
2120         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2121                 self.pressedkeys |= KEY_JUMP;
2122         else
2123                 self.pressedkeys &~= KEY_JUMP;
2124         if (self.BUTTON_CROUCH)
2125                 self.pressedkeys |= KEY_CROUCH;
2126         else
2127                 self.pressedkeys &~= KEY_CROUCH;
2128
2129         if (self.BUTTON_ATCK)
2130                 self.pressedkeys |= KEY_ATCK;
2131         else
2132                 self.pressedkeys &~= KEY_ATCK;
2133         if (self.BUTTON_ATCK2)
2134                 self.pressedkeys |= KEY_ATCK2;
2135         else
2136                 self.pressedkeys &~= KEY_ATCK2;
2137 }
2138
2139 /*
2140 ======================
2141 spectate mode routines
2142 ======================
2143 */
2144
2145 void SpectateCopy(entity spectatee) {
2146         other = spectatee;
2147         MUTATOR_CALLHOOK(SpectateCopy);
2148         self.armortype = spectatee.armortype;
2149         self.armorvalue = spectatee.armorvalue;
2150         self.ammo_cells = spectatee.ammo_cells;
2151         self.ammo_shells = spectatee.ammo_shells;
2152         self.ammo_nails = spectatee.ammo_nails;
2153         self.ammo_rockets = spectatee.ammo_rockets;
2154         self.ammo_fuel = spectatee.ammo_fuel;
2155         self.clip_load = spectatee.clip_load;
2156         self.clip_size = spectatee.clip_size;
2157         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2158         self.health = spectatee.health;
2159         self.impulse = 0;
2160         self.items = spectatee.items;
2161         self.last_pickup = spectatee.last_pickup;
2162         self.hit_time = spectatee.hit_time;
2163         self.metertime = spectatee.metertime;
2164         self.strength_finished = spectatee.strength_finished;
2165         self.invincible_finished = spectatee.invincible_finished;
2166         self.pressedkeys = spectatee.pressedkeys;
2167         WEPSET_COPY_EE(self, spectatee);
2168         self.switchweapon = spectatee.switchweapon;
2169         self.switchingweapon = spectatee.switchingweapon;
2170         self.weapon = spectatee.weapon;
2171         self.nex_charge = spectatee.nex_charge;
2172         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2173         self.hagar_load = spectatee.hagar_load;
2174         self.minelayer_mines = spectatee.minelayer_mines;
2175         self.punchangle = spectatee.punchangle;
2176         self.view_ofs = spectatee.view_ofs;
2177         self.v_angle = spectatee.v_angle;
2178         self.velocity = spectatee.velocity;
2179         self.dmg_take = spectatee.dmg_take;
2180         self.dmg_save = spectatee.dmg_save;
2181         self.dmg_inflictor = spectatee.dmg_inflictor;
2182         self.angles = spectatee.v_angle;
2183         if(!self.BUTTON_USE)
2184                 self.fixangle = TRUE;
2185         setorigin(self, spectatee.origin);
2186         setsize(self, spectatee.mins, spectatee.maxs);
2187         SetZoomState(spectatee.zoomstate);
2188
2189         anticheat_spectatecopy(spectatee);
2190
2191         //self.vehicle = spectatee.vehicle;
2192
2193         self.hud = spectatee.hud;
2194         if(spectatee.vehicle)
2195     {
2196         setorigin(self, spectatee.origin);
2197         self.velocity = spectatee.vehicle.velocity;
2198         self.v_angle += spectatee.vehicle.angles;
2199         //self.v_angle_x *= -1;
2200         self.vehicle_health = spectatee.vehicle_health;
2201         self.vehicle_shield = spectatee.vehicle_shield;
2202         self.vehicle_energy = spectatee.vehicle_energy;
2203         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2204         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2205         self.vehicle_reload1 = spectatee.vehicle_reload1;
2206         self.vehicle_reload2 = spectatee.vehicle_reload2;
2207
2208         msg_entity = self;
2209         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2210         WriteEntity(MSG_ONE, spectatee);
2211         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2212     }
2213 }
2214
2215 float SpectateUpdate() {
2216         if(!self.enemy)
2217             return 0;
2218
2219         if (self == self.enemy)
2220                 return 0;
2221
2222         if(self.enemy.classname != "player")
2223                 return 0;
2224
2225         SpectateCopy(self.enemy);
2226
2227         return 1;
2228 }
2229
2230
2231 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2232 entity CA_SpectateNext(entity start) {
2233         if (start.team == self.team) {
2234                 return start;
2235         }
2236
2237         other = start;
2238         // continue from current player
2239         while(other && other.team != self.team) {
2240                 other = find(other, classname, "player");
2241         }
2242
2243         if (!other) {
2244                 // restart from begining
2245                 other = find(other, classname, "player");
2246                 while(other && other.team != self.team) {
2247                         other = find(other, classname, "player");
2248                 }
2249         }
2250
2251         return other;
2252 }
2253
2254 float SpectateNext() {
2255         other = find(self.enemy, classname, "player");
2256         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2257                 // CA and ca players when spectating enemies is forbidden
2258                 other = CA_SpectateNext(other);
2259         } else {
2260                 // other modes and ca spectators or spectating enemies is allowed
2261                 if (!other)
2262                         other = find(other, classname, "player");
2263         }
2264
2265         if (other)
2266                 self.enemy = other;
2267
2268         if(self.enemy.classname == "player") {
2269             if(self.enemy.vehicle)
2270             {
2271             msg_entity = self;
2272             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2273             WriteEntity(MSG_ONE, self.enemy);
2274             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2275             self.movetype = MOVETYPE_NONE;
2276             accuracy_resend(self);
2277             }
2278             else
2279             {
2280             msg_entity = self;
2281             WriteByte(MSG_ONE, SVC_SETVIEW);
2282             WriteEntity(MSG_ONE, self.enemy);
2283             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2284             self.movetype = MOVETYPE_NONE;
2285             accuracy_resend(self);
2286
2287             if(!SpectateUpdate())
2288                 PutObserverInServer();
2289         }
2290         return 1;
2291         } else {
2292                 return 0;
2293         }
2294 }
2295
2296 /*
2297 =============
2298 ShowRespawnCountdown()
2299
2300 Update a respawn countdown display.
2301 =============
2302 */
2303 void ShowRespawnCountdown()
2304 {
2305         float number;
2306         if(self.deadflag == DEAD_NO) // just respawned?
2307                 return;
2308         else
2309         {
2310                 number = ceil(self.respawn_time - time);
2311                 if(number <= 0)
2312                         return;
2313                 if(number <= self.respawn_countdown)
2314                 {
2315                         self.respawn_countdown = number - 1;
2316                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2317                                 AnnounceTo(self, strcat(ftos(number), ""));
2318                 }
2319         }
2320 }
2321
2322 .float prevent_join_msgtime;
2323 void LeaveSpectatorMode()
2324 {
2325         if(nJoinAllowed(self)) {
2326                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2327                         self.classname = "player";
2328
2329                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2330                                 JoinBestTeam(self, FALSE, TRUE);
2331
2332                         if(autocvar_g_campaign)
2333                                 campaign_bots_may_start = 1;
2334
2335                         PutClientInServer();
2336
2337                         if(self.classname == "player")
2338                                 bprint ("^4", self.netname, "^4 is playing now\n");
2339
2340                         if(!autocvar_g_campaign)
2341                         if (time < self.jointime + autocvar_welcome_message_time)
2342                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2343
2344                         if (self.prevent_join_msgtime)
2345                         {
2346                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2347                                 self.prevent_join_msgtime = 0;
2348                         }
2349
2350                         return;
2351                 } else {
2352                         if (g_ca && self.caplayer) {
2353                         }       // do nothing
2354                         else
2355                                 stuffcmd(self,"menu_showteamselect\n");
2356                         return;
2357                 }
2358         }
2359         else {
2360                 //player may not join because of g_maxplayers is set
2361                 if (time - self.prevent_join_msgtime > 2)
2362                 {
2363                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2364                         self.prevent_join_msgtime = time;
2365                 }
2366         }
2367 }
2368
2369 /**
2370  * Determines whether the player is allowed to join. This depends on cvar
2371  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2372  * it checks whether the number of currently playing players exceeds g_maxplayers.
2373  * @return int number of free slots for players, 0 if none
2374  */
2375 float nJoinAllowed(entity ignore) {
2376         if(!ignore)
2377         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2378         // so report 0 free slots if restricted
2379         {
2380                 if(autocvar_g_forced_team_otherwise == "spectate")
2381                         return 0;
2382                 if(autocvar_g_forced_team_otherwise == "spectator")
2383                         return 0;
2384         }
2385
2386         if(self.team_forced < 0)
2387                 return 0; // forced spectators can never join
2388
2389         // TODO simplify this
2390         entity e;
2391         float totalClients = 0;
2392         FOR_EACH_CLIENT(e)
2393                 if(e != ignore)
2394                         totalClients += 1;
2395
2396         if (!autocvar_g_maxplayers)
2397                 return maxclients - totalClients;
2398
2399         float currentlyPlaying = 0;
2400         FOR_EACH_REALPLAYER(e)
2401                 currentlyPlaying += 1;
2402
2403         if(currentlyPlaying < autocvar_g_maxplayers)
2404                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2405
2406         return 0;
2407 }
2408
2409 /**
2410  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2411  * g_maxplayers_spectator_blocktime seconds
2412  */
2413 void checkSpectatorBlock() {
2414         if(self.classname == "spectator" || self.classname == "observer") {
2415                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2416                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2417                         dropclient(self);
2418                 }
2419         }
2420 }
2421
2422 .float motd_actived_time; // used for both motd and campaign_message
2423 void PrintWelcomeMessage()
2424 {
2425         if (self.motd_actived_time == 0) { // is there already a message showing?
2426                 if (autocvar_g_campaign) {
2427                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2428                                 self.motd_actived_time = time;
2429                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2430                         }
2431                 } else {
2432                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2433                                 self.motd_actived_time = time;
2434                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2435                         }
2436                 }
2437         } else { // showing MOTD or campaign message
2438                 if (autocvar_g_campaign) {
2439                         if (self.BUTTON_INFO)
2440                                 self.motd_actived_time = time;
2441                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2442                                 self.motd_actived_time = 0;
2443                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2444                         }
2445                 } else {
2446                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2447                                 if (self.BUTTON_INFO)
2448                                         self.motd_actived_time = time;
2449                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2450                                         self.motd_actived_time = 0;
2451                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2452                                 }
2453                         }
2454                 }
2455         }
2456 }
2457
2458 void ObserverThink()
2459 {
2460         float prefered_movetype;
2461         if (self.flags & FL_JUMPRELEASED) {
2462                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2463                         self.flags &~= FL_JUMPRELEASED;
2464                         self.flags |= FL_SPAWNING;
2465                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2466                         self.flags &~= FL_JUMPRELEASED;
2467                         if(SpectateNext() == 1) {
2468                                 self.classname = "spectator";
2469                         }
2470                 } else {
2471                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2472                         if (self.movetype != prefered_movetype)
2473                                 self.movetype = prefered_movetype;
2474                 }
2475         } else {
2476                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2477                         self.flags |= FL_JUMPRELEASED;
2478                         if(self.flags & FL_SPAWNING)
2479                         {
2480                                 self.flags &~= FL_SPAWNING;
2481                                 LeaveSpectatorMode();
2482                                 return;
2483                         }
2484                 }
2485         }
2486
2487         PrintWelcomeMessage();
2488 }
2489
2490 void SpectatorThink()
2491 {
2492         if (self.flags & FL_JUMPRELEASED) {
2493                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2494                         self.flags &~= FL_JUMPRELEASED;
2495                         self.flags |= FL_SPAWNING;
2496                 } else if(self.BUTTON_ATCK) {
2497                         self.flags &~= FL_JUMPRELEASED;
2498                         if(SpectateNext() == 1) {
2499                                 self.classname = "spectator";
2500                         } else {
2501                                 self.classname = "observer";
2502                                 PutClientInServer();
2503                         }
2504                 } else if (self.BUTTON_ATCK2) {
2505                         self.flags &~= FL_JUMPRELEASED;
2506                         self.classname = "observer";
2507                         PutClientInServer();
2508                 } else {
2509                         if(!SpectateUpdate())
2510                                 PutObserverInServer();
2511                 }
2512         } else {
2513                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2514                         self.flags |= FL_JUMPRELEASED;
2515                         if(self.flags & FL_SPAWNING)
2516                         {
2517                                 self.flags &~= FL_SPAWNING;
2518                                 LeaveSpectatorMode();
2519                                 return;
2520                         }
2521                 }
2522                 if(!SpectateUpdate())
2523                         PutObserverInServer();
2524         }
2525
2526         PrintWelcomeMessage();
2527         self.flags |= FL_CLIENT | FL_NOTARGET;
2528 }
2529
2530 float ctf_usekey();
2531 void PlayerUseKey()
2532 {
2533         if(self.classname != "player")
2534                 return;
2535
2536         if(self.vehicle)
2537         {
2538         vehicles_exit(VHEF_NORMAL);
2539         return;
2540         }
2541
2542         // a use key was pressed; call handlers
2543         if(ctf_usekey())
2544                 return;
2545
2546         MUTATOR_CALLHOOK(PlayerUseKey);
2547 }
2548
2549 .float touchexplode_time;
2550
2551 /*
2552 =============
2553 PlayerPreThink
2554
2555 Called every frame for each client before the physics are run
2556 =============
2557 */
2558 .float usekeypressed;
2559 void() ctf_setstatus;
2560 void() nexball_setstatus;
2561 .float items_added;
2562 void PlayerPreThink (void)
2563 {
2564         WarpZone_PlayerPhysics_FixVAngle();
2565
2566         self.stat_game_starttime = game_starttime;
2567         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2568         self.stat_leadlimit = autocvar_leadlimit;
2569
2570         if(frametime)
2571         {
2572                 // physics frames: update anticheat stuff
2573                 anticheat_prethink();
2574         }
2575
2576         if(blockSpectators && frametime)
2577                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2578                 checkSpectatorBlock();
2579
2580         zoomstate_set = 0;
2581
2582         if(self.netname_previous != self.netname)
2583         {
2584                 if(autocvar_sv_eventlog)
2585                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2586                 if(self.netname_previous)
2587                         strunzone(self.netname_previous);
2588                 self.netname_previous = strzone(self.netname);
2589         }
2590
2591         // version nagging
2592         if(self.version_nagtime)
2593                 if(self.cvar_g_xonoticversion)
2594                         if(time > self.version_nagtime)
2595                         {
2596                                 // don't notify git users
2597                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2598                                 {
2599                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2600                                         {
2601                                                 // notify release users if connecting to git
2602                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2603                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2604                                         }
2605                                         else
2606                                         {
2607                                                 float r;
2608                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2609                                                 if(r < 0)
2610                                                 {
2611                                                         // give users new version
2612                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2613                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2614                                                 }
2615                                                 else if(r > 0)
2616                                                 {
2617                                                         // notify users about old server version
2618                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2619                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2620                                                 }
2621                                         }
2622                                 }
2623                                 self.version_nagtime = 0;
2624                         }
2625
2626         // GOD MODE info
2627         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2628         {
2629                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2630                 self.max_armorvalue = 0;
2631         }
2632
2633 #ifdef TETRIS
2634         if (TetrisPreFrame())
2635                 return;
2636 #endif
2637
2638         MUTATOR_CALLHOOK(PlayerPreThink);
2639
2640         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2641         {
2642                 if(self.BUTTON_USE && !self.usekeypressed)
2643                         PlayerUseKey();
2644                 self.usekeypressed = self.BUTTON_USE;
2645         }
2646
2647         PrintWelcomeMessage();
2648
2649         if(self.classname == "player") {
2650 //              if(self.netname == "Wazat")
2651 //                      bprint(self.classname, "\n");
2652
2653                 CheckRules_Player();
2654
2655                 if (intermission_running)
2656                 {
2657                         IntermissionThink ();   // otherwise a button could be missed between
2658                         return;                                 // the think tics
2659                 }
2660
2661                 //don't allow the player to turn around while game is paused!
2662                 if(timeout_status == TIMEOUT_ACTIVE) {
2663                         // FIXME turn this into CSQC stuff
2664                         self.v_angle = self.lastV_angle;
2665                         self.angles = self.lastV_angle;
2666                         self.fixangle = TRUE;
2667                 }
2668
2669                 if(frametime)
2670                 {
2671 #ifndef NO_LEGACY_NETWORKING
2672                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2673 #endif
2674
2675                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2676                         {
2677                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2678                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2679                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2680
2681                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2682                                 {
2683                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2684                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2685                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2686                                 }
2687                         }
2688                         else
2689                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2690
2691                         player_powerups();
2692                 }
2693
2694                 if (g_minstagib)
2695                         minstagib_ammocheck();
2696
2697                 if (self.deadflag != DEAD_NO)
2698                 {
2699                         float button_pressed, force_respawn;
2700                         if(self.personal && g_race_qualifying)
2701                         {
2702                                 if(time > self.respawn_time)
2703                                 {
2704                                         self.respawn_time = time + 1; // only retry once a second
2705                                         respawn();
2706                                         self.impulse = 141;
2707                                 }
2708                         }
2709                         else
2710                         {
2711                                 if(frametime)
2712                                         player_anim();
2713                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2714                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2715                                 if (self.deadflag == DEAD_DYING)
2716                                 {
2717                                         if(force_respawn)
2718                                                 self.deadflag = DEAD_RESPAWNING;
2719                                         else if(!button_pressed)
2720                                                 self.deadflag = DEAD_DEAD;
2721                                 }
2722                                 else if (self.deadflag == DEAD_DEAD)
2723                                 {
2724                                         if(button_pressed)
2725                                                 self.deadflag = DEAD_RESPAWNABLE;
2726                                 }
2727                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2728                                 {
2729                                         if(!button_pressed)
2730                                                 self.deadflag = DEAD_RESPAWNING;
2731                                 }
2732                                 else if (self.deadflag == DEAD_RESPAWNING)
2733                                 {
2734                                         if(time > self.respawn_time)
2735                                         {
2736                                                 self.respawn_time = time + 1; // only retry once a second
2737                                                 respawn();
2738                                         }
2739                                 }
2740                                 ShowRespawnCountdown();
2741                         }
2742                         return;
2743                 }
2744                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2745                 // so (self.deadflag == DEAD_NO) is always true in the code below
2746
2747                 if(g_touchexplode)
2748                 if(time > self.touchexplode_time)
2749                 if(self.classname == "player")
2750                 if(self.deadflag == DEAD_NO)
2751                 if not(IS_INDEPENDENT_PLAYER(self))
2752                 FOR_EACH_PLAYER(other) if(self != other)
2753                 {
2754                         if(time > other.touchexplode_time)
2755                         if(other.deadflag == DEAD_NO)
2756                         if not(IS_INDEPENDENT_PLAYER(other))
2757                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2758                         {
2759                                 PlayerTouchExplode(self, other);
2760                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2761                         }
2762                 }
2763
2764                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2765                 {
2766                         vector dist;
2767
2768                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2769                         dist = self.prevorigin - self.origin;
2770                         dist_z = 0;
2771                         self.lms_traveled_distance += fabs(vlen(dist));
2772
2773                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2774                         {
2775                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2776                                 self.lms_traveled_distance = 0;
2777                         }
2778
2779                         if(time > self.lms_nextcheck)
2780                         {
2781                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2782                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2783                                 {
2784                                         centerprint(self, autocvar_g_lms_campcheck_message);
2785                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2786                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2787                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2788                                 }
2789                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2790                                 self.lms_traveled_distance = 0;
2791                         }
2792                 }
2793
2794                 self.prevorigin = self.origin;
2795
2796                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2797                 {
2798                         if (!self.crouch)
2799                         {
2800                                 self.crouch = TRUE;
2801                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2802                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2803                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2804                         }
2805                 }
2806                 else
2807                 {
2808                         if (self.crouch)
2809                         {
2810                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2811                                 if (!trace_startsolid)
2812                                 {
2813                                         self.crouch = FALSE;
2814                                         self.view_ofs = PL_VIEW_OFS;
2815                                         setsize (self, PL_MIN, PL_MAX);
2816                                 }
2817                         }
2818                 }
2819
2820                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2821                 {
2822                         if(self.bloodloss_timer < time)
2823                         {
2824                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2825                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2826                         }
2827                 }
2828
2829                 FixPlayermodel();
2830
2831                 GrapplingHookFrame();
2832
2833                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2834                 //if(frametime)
2835                 {
2836                         self.items &~= self.items_added;
2837
2838                         W_WeaponFrame();
2839
2840                         self.items_added = 0;
2841                         if(self.items & IT_JETPACK)
2842                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2843                                         self.items_added |= IT_FUEL;
2844
2845                         self.items |= self.items_added;
2846                 }
2847
2848                 player_regen();
2849
2850                 // rot nex charge to the charge limit
2851                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2852                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2853
2854                 if(frametime)
2855                         player_anim();
2856
2857                 if(g_ctf)
2858                         ctf_setstatus();
2859
2860                 if(g_nexball)
2861                         nexball_setstatus();
2862
2863                 // secret status
2864                 secrets_setstatus();
2865
2866                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2867
2868                 //self.angles_y=self.v_angle_y + 90;   // temp
2869         } else if(gameover) {
2870                 if (intermission_running)
2871                         IntermissionThink ();   // otherwise a button could be missed between
2872                 return;
2873         } else if(self.classname == "observer") {
2874                 ObserverThink();
2875         } else if(self.classname == "spectator") {
2876                 SpectatorThink();
2877         }
2878
2879         if(!zoomstate_set)
2880                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2881
2882         float oldspectatee_status;
2883         oldspectatee_status = self.spectatee_status;
2884         if(self.classname == "spectator")
2885                 self.spectatee_status = num_for_edict(self.enemy);
2886         else if(self.classname == "observer")
2887                 self.spectatee_status = num_for_edict(self);
2888         else
2889                 self.spectatee_status = 0;
2890         if(self.spectatee_status != oldspectatee_status)
2891         {
2892                 ClientData_Touch(self);
2893                 if(g_race || g_cts)
2894                         race_InitSpectator();
2895         }
2896
2897         if(self.teamkill_soundtime)
2898         if(time > self.teamkill_soundtime)
2899         {
2900                 self.teamkill_soundtime = 0;
2901
2902                 entity oldpusher, oldself;
2903
2904                 oldself = self; self = self.teamkill_soundsource;
2905                 oldpusher = self.pusher; self.pusher = oldself;
2906
2907                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2908
2909                 self.pusher = oldpusher;
2910                 self = oldself;
2911         }
2912
2913         if(self.taunt_soundtime)
2914         if(time > self.taunt_soundtime)
2915         {
2916                 self.taunt_soundtime = 0;
2917                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2918         }
2919
2920         target_voicescript_next(self);
2921
2922         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2923         if(!self.weapon)
2924                 self.clip_load = self.clip_size = 0;
2925 }
2926
2927 float isInvisibleString(string s)
2928 {
2929         float i, n, c;
2930         s = strdecolorize(s);
2931         for((i = 0), (n = strlen(s)); i < n; ++i)
2932         {
2933                 c = str2chr(s, i);
2934                 switch(c)
2935                 {
2936                         case 0:
2937                         case 32: // space
2938                                 break;
2939                         case 192: // charmap space
2940                                 if (!autocvar_utf8_enable)
2941                                         break;
2942                                 return FALSE;
2943                         case 160: // space in unicode fonts
2944                         case 0xE000 + 192: // utf8 charmap space
2945                                 if (autocvar_utf8_enable)
2946                                         break;
2947                         default:
2948                                 return FALSE;
2949                 }
2950         }
2951         return TRUE;
2952 }
2953
2954 /*
2955 =============
2956 PlayerPostThink
2957
2958 Called every frame for each client after the physics are run
2959 =============
2960 */
2961 .float idlekick_lasttimeleft;
2962 .entity showheadshotbbox;
2963 void showheadshotbbox_think()
2964 {
2965         if(self.owner.showheadshotbbox != self)
2966         {
2967                 remove(self);
2968                 return;
2969         }
2970         self.nextthink = time;
2971         setorigin(self, self.owner.origin);
2972         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2973 }
2974 void PlayerPostThink (void)
2975 {
2976         // Savage: Check for nameless players
2977         if (isInvisibleString(self.netname)) {
2978                 self.netname = "Player";
2979                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2980         }
2981
2982         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2983         {
2984                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2985                 {
2986                         if(self.idlekick_lasttimeleft)
2987                         {
2988                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2989                                 self.idlekick_lasttimeleft = 0;
2990                         }
2991                 }
2992                 else
2993                 {
2994                         float timeleft;
2995                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2996                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2997                         {
2998                                 if(!self.idlekick_lasttimeleft)
2999                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3000                         }
3001                         if(timeleft <= 0)
3002                         {
3003                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
3004                                 AnnounceTo(self, "terminated");
3005                                 dropclient(self);
3006                                 return;
3007                         }
3008                         else if(timeleft <= 10)
3009                         {
3010                                 if(timeleft != self.idlekick_lasttimeleft)
3011                                         AnnounceTo(self, ftos(timeleft));
3012                                 self.idlekick_lasttimeleft = timeleft;
3013                         }
3014                 }
3015         }
3016
3017 #ifdef TETRIS
3018         if(self.impulse == 100)
3019                 ImpulseCommands();
3020         if (!TetrisPostFrame())
3021         {
3022 #endif
3023
3024         CheatFrame();
3025
3026         //CheckPlayerJump();
3027
3028         if(self.classname == "player") {
3029                 CheckRules_Player();
3030                 UpdateChatBubble();
3031                 if (self.impulse)
3032                         ImpulseCommands();
3033                 if (intermission_running)
3034                         return;         // intermission or finale
3035                 GetPressedKeys();
3036         } else if (self.classname == "observer") {
3037                 //do nothing
3038         } else if (self.classname == "spectator") {
3039                 //do nothing
3040         }
3041
3042 #ifdef TETRIS
3043         }
3044 #endif
3045
3046         /*
3047         float i;
3048         for(i = 0; i < 1000; ++i)
3049         {
3050                 vector end;
3051                 end = self.origin + '0 0 1024' + 512 * randomvec();
3052                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3053                 if(trace_fraction < 1)
3054                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3055                 {
3056                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3057                         break;
3058                 }
3059         }
3060         */
3061
3062         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3063
3064         if(self.waypointsprite_attachedforcarrier)
3065                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3066
3067         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3068         {
3069                 if(!self.showheadshotbbox)
3070                 {
3071                         self.showheadshotbbox = spawn();
3072                         self.showheadshotbbox.classname = "headshotbbox";
3073                         self.showheadshotbbox.owner = self;
3074                         self.showheadshotbbox.think = showheadshotbbox_think;
3075                         self.showheadshotbbox.nextthink = time;
3076                         self = self.showheadshotbbox;
3077                         self.think();
3078                         self = self.owner;
3079                 }
3080         }
3081         else
3082         {
3083                 if(self.showheadshotbbox)
3084                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3085                 remove(self.showheadshotbbox);
3086         }
3087
3088         playerdemo_write();
3089
3090         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3091         {
3092                 if(!self.stored_netname)
3093                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3094                 if(self.stored_netname != self.netname)
3095                 {
3096                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3097                         strunzone(self.stored_netname);
3098                         self.stored_netname = strzone(self.netname);
3099                 }
3100         }
3101
3102         /*
3103         if(g_race)
3104                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3105         */
3106
3107         CSQCMODEL_AUTOUPDATE();
3108 }