qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         Portal_ClearAll(self);
 170
 171         if(self.alivetime)
 172         {
 173                 if(!inWarmupStage)
 174                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 175                 self.alivetime = 0;
 176         }
 177
 178         if(self.vehicle)
 179                 vehicles_exit(VHEF_RELESE);
 180
 181         WaypointSprite_PlayerDead();
 182
 183         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 184                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 185
 186         if(self.killcount != -666)
 187         {
 188                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 189
 190                 if(self.just_joined == FALSE) {
 191                         LogTeamchange(self.playerid, -1, 4);
 192                 } else
 193                         self.just_joined = FALSE;
 194         }
 195
 196         PlayerScore_Clear(self); // clear scores when needed
 197
 198         accuracy_resend(self);
 199
 200         self.spectatortime = time;
 201
 202         self.classname = "observer";
 203         self.iscreature = FALSE;
 204         self.teleportable = TELEPORT_SIMPLE;
 205         self.damagedbycontents = FALSE;
 206         self.health = -666;
 207         self.takedamage = DAMAGE_NO;
 208         self.solid = SOLID_NOT;
 209         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 210         self.flags = FL_CLIENT | FL_NOTARGET;
 211         self.armorvalue = 666;
 212         self.effects = 0;
 213         self.armorvalue = autocvar_g_balance_armor_start;
 214         self.pauserotarmor_finished = 0;
 215         self.pauserothealth_finished = 0;
 216         self.pauseregen_finished = 0;
 217         self.damageforcescale = 0;
 218         self.death_time = 0;
 219         self.respawn_flags = 0;
 220         self.respawn_time = 0;
 221         self.stat_respawn_time = 0;
 222         self.alpha = 0;
 223         self.scale = 0;
 224         self.fade_time = 0;
 225         self.pain_frame = 0;
 226         self.pain_finished = 0;
 227         self.strength_finished = 0;
 228         self.invincible_finished = 0;
 229         self.superweapons_finished = 0;
 230         self.pushltime = 0;
 231         self.istypefrag = 0;
 232         self.think = func_null;
 233         self.nextthink = 0;
 234         self.hook_time = 0;
 235         self.deadflag = DEAD_NO;
 236         self.angles = spot.angles;
 237         self.angles_z = 0;
 238         self.fixangle = TRUE;
 239         self.crouch = FALSE;
 240
 241         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 242         self.prevorigin = self.origin;
 243         self.items = 0;
 244         WEPSET_CLEAR_E(self);
 245         self.model = "";
 246         FixPlayermodel();
 247         setmodel(self, "null");
 248         self.drawonlytoclient = self;
 249
 250         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 251         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 252
 253         self.weapon = 0;
 254         self.weaponname = "";
 255         self.switchingweapon = 0;
 256         self.weaponmodel = "";
 257         self.weaponentity = world;
 258         self.exteriorweaponentity = world;
 259         self.killcount = -666;
 260         self.velocity = '0 0 0';
 261         self.avelocity = '0 0 0';
 262         self.punchangle = '0 0 0';
 263         self.punchvector = '0 0 0';
 264         self.oldvelocity = self.velocity;
 265         self.fire_endtime = -1;
 266 }
 267
 268 .float model_randomizer;
 269 void FixPlayermodel()
 270 {
 271         string defaultmodel;
 272         float defaultskin, chmdl, oldskin, n, i;
 273         vector m1, m2;
 274
 275         defaultmodel = "";
 276         defaultskin = 0;
 277         chmdl = FALSE;
 278
 279         if(autocvar_sv_defaultcharacter == 1)
 280         {
 281                 if(teamplay)
 282                 {
 283                         string s;
 284                         s = Team_ColorName_Lower(self.team);
 285                         if(s != "neutral")
 286                         {
 287                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 288                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 289                         }
 290                 }
 291
 292                 if(defaultmodel == "")
 293                 {
 294                         defaultmodel = autocvar_sv_defaultplayermodel;
 295                         defaultskin = autocvar_sv_defaultplayerskin;
 296                 }
 297
 298                 n = tokenize_console(defaultmodel);
 299                 if(n > 0)
 300                         defaultmodel = argv(floor(n * self.model_randomizer));
 301
 302                 i = strstrofs(defaultmodel, ":", 0);
 303                 if(i >= 0)
 304                 {
 305                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 306                         defaultmodel = substring(defaultmodel, 0, i);
 307                 }
 308         }
 309
 310         if(defaultmodel != "")
 311         {
 312                 if (defaultmodel != self.model)
 313                 {
 314                         m1 = self.mins;
 315                         m2 = self.maxs;
 316                         setplayermodel (self, defaultmodel);
 317                         setsize (self, m1, m2);
 318                         chmdl = TRUE;
 319                 }
 320
 321                 oldskin = self.skin;
 322                 self.skin = defaultskin;
 323         } else {
 324                 if (self.playermodel != self.model || self.playermodel == "")
 325                 {
 326                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 327                         m1 = self.mins;
 328                         m2 = self.maxs;
 329                         setplayermodel (self, self.playermodel);
 330                         setsize (self, m1, m2);
 331                         chmdl = TRUE;
 332                 }
 333
 334                 oldskin = self.skin;
 335                 self.skin = stof(self.playerskin);
 336         }
 337
 338         if(chmdl || oldskin != self.skin) // model or skin has changed
 339         {
 340                 self.species = player_getspecies(); // update species
 341                 UpdatePlayerSounds(); // update skin sounds
 342         }
 343
 344         if(!teamplay)
 345                 if(strlen(autocvar_sv_defaultplayercolors))
 346                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 347                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 348 }
 349
 350 /*
 351 =============
 352 PutClientInServer
 353
 354 Called when a client spawns in the server
 355 =============
 356 */
 357 void PutClientInServer (void)
 358 {
 359         if(IS_BOT_CLIENT(self))
 360                 self.classname = "player";
 361         else if(IS_REAL_CLIENT(self))
 362         {
 363                 msg_entity = self;
 364                 WriteByte(MSG_ONE, SVC_SETVIEW);
 365                 WriteEntity(MSG_ONE, self);
 366         }
 367
 368         // reset player keys
 369         self.itemkeys = 0;
 370
 371         MUTATOR_CALLHOOK(PutClientInServer);
 372
 373         if(gameover)
 374                 self.classname = "observer";
 375
 376         if(IS_PLAYER(self))
 377         {
 378                 entity spot, oldself;
 379                 float j;
 380
 381                 accuracy_resend(self);
 382
 383                 if(self.team < 0)
 384                         JoinBestTeam(self, FALSE, TRUE);
 385
 386                 race_PreSpawn();
 387
 388                 spot = SelectSpawnPoint (FALSE);
 389                 if(!spot)
 390                 {
 391                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 392                         return; // spawn failed
 393                 }
 394
 395                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397                 self.classname = "player";
 398                 self.wasplayer = TRUE;
 399                 self.iscreature = TRUE;
 400                 self.teleportable = TELEPORT_NORMAL;
 401                 self.damagedbycontents = TRUE;
 402                 self.movetype = MOVETYPE_WALK;
 403                 self.solid = SOLID_SLIDEBOX;
 404                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 405                 if(autocvar_g_playerclip_collisions)
 406                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 407                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 408                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 409                 self.frags = FRAGS_PLAYER;
 410                 if(INDEPENDENT_PLAYERS)
 411                         MAKE_INDEPENDENT_PLAYER(self);
 412                 self.flags = FL_CLIENT;
 413                 if(autocvar__notarget)
 414                         self.flags |= FL_NOTARGET;
 415                 self.takedamage = DAMAGE_AIM;
 416                 self.effects = 0;
 417                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 418                 self.air_finished = time + 12;
 419                 self.dmg = 2;
 420                 if(autocvar_g_balance_nex_charge)
 421                 {
 422                         if(autocvar_g_balance_nex_secondary_chargepool)
 423                                 self.nex_chargepool_ammo = 1;
 424                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 425                 }
 426
 427                 if(inWarmupStage)
 428                 {
 429                         self.ammo_shells = warmup_start_ammo_shells;
 430                         self.ammo_nails = warmup_start_ammo_nails;
 431                         self.ammo_rockets = warmup_start_ammo_rockets;
 432                         self.ammo_cells = warmup_start_ammo_cells;
 433                         self.ammo_fuel = warmup_start_ammo_fuel;
 434                         self.health = warmup_start_health;
 435                         self.armorvalue = warmup_start_armorvalue;
 436                         WEPSET_COPY_EA(self, warmup_start_weapons);
 437                 }
 438                 else
 439                 {
 440                         self.ammo_shells = start_ammo_shells;
 441                         self.ammo_nails = start_ammo_nails;
 442                         self.ammo_rockets = start_ammo_rockets;
 443                         self.ammo_cells = start_ammo_cells;
 444                         self.ammo_fuel = start_ammo_fuel;
 445                         self.health = start_health;
 446                         self.armorvalue = start_armorvalue;
 447                         WEPSET_COPY_EA(self, start_weapons);
 448                 }
 449
 450                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 451                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 452                 else
 453                         self.superweapons_finished = 0;
 454
 455                 if(g_weaponarena_random)
 456                 {
 457                         if(g_weaponarena_random_with_laser)
 458                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 459                         W_RandomWeapons(self, g_weaponarena_random);
 460                         if(g_weaponarena_random_with_laser)
 461                                 WEPSET_OR_EW(self, WEP_LASER);
 462                 }
 463
 464                 self.items = start_items;
 465
 466                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 467                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 468                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 469                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 470                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 471                 //extend the pause of rotting if client was reset at the beginning of the countdown
 472                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 473                         self.spawnshieldtime += game_starttime - time;
 474                         self.pauserotarmor_finished += game_starttime - time;
 475                         self.pauserothealth_finished += game_starttime - time;
 476                         self.pauseregen_finished += game_starttime - time;
 477                 }
 478                 self.damageforcescale = 2;
 479                 self.death_time = 0;
 480                 self.respawn_flags = 0;
 481                 self.respawn_time = 0;
 482                 self.stat_respawn_time = 0;
 483                 self.scale = 0;
 484                 self.fade_time = 0;
 485                 self.pain_frame = 0;
 486                 self.pain_finished = 0;
 487                 self.strength_finished = 0;
 488                 self.invincible_finished = 0;
 489                 self.pushltime = 0;
 490                 // players have no think function
 491                 self.think = func_null;
 492                 self.nextthink = 0;
 493                 self.hook_time = 0;
 494                 self.dmg_team = 0;
 495                 self.ballistics_density = autocvar_g_ballistics_density_player;
 496
 497                 self.metertime = 0;
 498
 499                 self.deadflag = DEAD_NO;
 500
 501                 self.angles = spot.angles;
 502
 503                 self.angles_z = 0; // never spawn tilted even if the spot says to
 504                 self.fixangle = TRUE; // turn this way immediately
 505                 self.velocity = '0 0 0';
 506                 self.avelocity = '0 0 0';
 507                 self.punchangle = '0 0 0';
 508                 self.punchvector = '0 0 0';
 509                 self.oldvelocity = self.velocity;
 510                 self.fire_endtime = -1;
 511
 512                 entity spawnevent = spawn();
 513                 spawnevent.owner = self;
 514                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 515
 516                 self.model = "";
 517                 FixPlayermodel();
 518                 self.drawonlytoclient = world;
 519
 520                 self.crouch = FALSE;
 521                 self.view_ofs = PL_VIEW_OFS;
 522                 setsize (self, PL_MIN, PL_MAX);
 523                 self.spawnorigin = spot.origin;
 524                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 525                 // don't reset back to last position, even if new position is stuck in solid
 526                 self.oldorigin = self.origin;
 527                 self.prevorigin = self.origin;
 528                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 529                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 530         self.hud = HUD_NORMAL;
 531
 532                 self.event_damage = PlayerDamage;
 533
 534                 self.bot_attack = TRUE;
 535
 536                 self.statdraintime = time + 5;
 537                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 538
 539                 if(self.killcount == -666) {
 540                         PlayerScore_Clear(self);
 541                         self.killcount = 0;
 542                 }
 543
 544                 CL_SpawnWeaponentity();
 545                 self.alpha = default_player_alpha;
 546                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 547                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 548
 549                 self.speedrunning = FALSE;
 550
 551                 race_PostSpawn(spot);
 552
 553                 //stuffcmd(self, "chase_active 0");
 554                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 555
 556                 target_voicescript_clear(self);
 557
 558                 // reset fields the weapons may use
 559                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 560                 {
 561                         weapon_action(j, WR_RESETPLAYER);
 562
 563                         // all weapons must be fully loaded when we spawn
 564                         entity e;
 565                         e = get_weaponinfo(j);
 566                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 567                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 568                 }
 569
 570                 oldself = self;
 571                 self = spot;
 572                         activator = oldself;
 573                                 string s;
 574                                 s = self.target;
 575                                 self.target = string_null;
 576                                 SUB_UseTargets();
 577                                 self.target = s;
 578                         activator = world;
 579                 self = oldself;
 580
 581                 spawn_spot = spot;
 582                 MUTATOR_CALLHOOK(PlayerSpawn);
 583
 584                 if(autocvar_spawn_debug)
 585                 {
 586                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 587                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 588                 }
 589
 590                 self.switchweapon = w_getbestweapon(self);
 591                 self.cnt = -1; // W_LastWeapon will not complain
 592                 self.weapon = 0;
 593                 self.weaponname = "";
 594                 self.switchingweapon = 0;
 595
 596                 if(!inWarmupStage)
 597                         if(!self.alivetime)
 598                                 self.alivetime = time;
 599
 600                 antilag_clear(self);
 601         }
 602         else if(IS_OBSERVER(self))
 603         {
 604                 PutObserverInServer ();
 605         }
 606 }
 607
 608 .float ebouncefactor, ebouncestop; // electro's values
 609 // TODO do we need all these fields, or should we stop autodetecting runtime
 610 // changes and just have a console command to update this?
 611 float ClientInit_SendEntity(entity to, float sf)
 612 {
 613         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 614         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 615         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 616         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 617         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 618         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 619         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 620         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 621         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 622         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(lightning_shotorigin[0]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(lightning_shotorigin[1]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(lightning_shotorigin[2]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(lightning_shotorigin[3]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 631         if(sv_foginterval && world.fog != "")
 632                 WriteString(MSG_ENTITY, world.fog);
 633         else
 634                 WriteString(MSG_ENTITY, "");
 635         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 636         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 637         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 638         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 639         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 640         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 641         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 642         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 643         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 644         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 645         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 646         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 647         return TRUE;
 648 }
 649
 650 void ClientInit_CheckUpdate()
 651 {
 652         self.nextthink = time;
 653         if(self.count != autocvar_g_balance_armor_blockpercent)
 654         {
 655                 self.count = autocvar_g_balance_armor_blockpercent;
 656                 self.SendFlags |= 1;
 657         }
 658         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 659         {
 660                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 661                 self.SendFlags |= 1;
 662         }
 663         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 664         {
 665                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 666                 self.SendFlags |= 1;
 667         }
 668         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 669         {
 670                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 671                 self.SendFlags |= 1;
 672         }
 673         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 674         {
 675                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 676                 self.SendFlags |= 1;
 677         }
 678 }
 679
 680 void ClientInit_Spawn()
 681 {
 682         entity o;
 683         entity e;
 684         e = spawn();
 685         e.classname = "clientinit";
 686         e.think = ClientInit_CheckUpdate;
 687         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 688
 689         o = self;
 690         self = e;
 691         ClientInit_CheckUpdate();
 692         self = o;
 693 }
 694
 695 /*
 696 =============
 697 SetNewParms
 698 =============
 699 */
 700 void SetNewParms (void)
 701 {
 702         // initialize parms for a new player
 703         parm1 = -(86400 * 366);
 704 }
 705
 706 /*
 707 =============
 708 SetChangeParms
 709 =============
 710 */
 711 void SetChangeParms (void)
 712 {
 713         // save parms for level change
 714         parm1 = self.parm_idlesince - time;
 715 }
 716
 717 /*
 718 =============
 719 DecodeLevelParms
 720 =============
 721 */
 722 void DecodeLevelParms (void)
 723 {
 724         // load parms
 725         self.parm_idlesince = parm1;
 726         if(self.parm_idlesince == -(86400 * 366))
 727                 self.parm_idlesince = time;
 728
 729         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 730         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 731 }
 732
 733 /*
 734 =============
 735 ClientKill
 736
 737 Called when a client types 'kill' in the console
 738 =============
 739 */
 740
 741 .float clientkill_nexttime;
 742 void ClientKill_Now_TeamChange()
 743 {
 744         if(self.killindicator_teamchange == -1)
 745         {
 746                 JoinBestTeam( self, FALSE, TRUE );
 747         }
 748         else if(self.killindicator_teamchange == -2)
 749         {
 750                 if(blockSpectators)
 751                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 752                 PutObserverInServer();
 753         }
 754         else
 755                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 756         self.killindicator_teamchange = 0;
 757 }
 758
 759 void ClientKill_Now()
 760 {
 761         if(self.vehicle)
 762         {
 763             vehicles_exit(VHEF_RELESE);
 764             if(!self.killindicator_teamchange)
 765             {
 766             self.vehicle_health = -1;
 767             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 768             }
 769         }
 770
 771         if(self.killindicator && !wasfreed(self.killindicator))
 772                 remove(self.killindicator);
 773
 774         self.killindicator = world;
 775
 776         if(self.killindicator_teamchange)
 777                 ClientKill_Now_TeamChange();
 778
 779         // in any case:
 780         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 781
 782         // now I am sure the player IS dead
 783 }
 784 void KillIndicator_Think()
 785 {
 786         if (gameover)
 787         {
 788                 self.owner.killindicator = world;
 789                 remove(self);
 790                 return;
 791         }
 792
 793         if (self.owner.alpha < 0 && !self.owner.vehicle)
 794         {
 795                 self.owner.killindicator = world;
 796                 remove(self);
 797                 return;
 798         }
 799
 800         if(self.cnt <= 0)
 801         {
 802                 self = self.owner;
 803                 ClientKill_Now(); // no oldself needed
 804                 return;
 805         }
 806     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 807     {
 808         self.nextthink = time + 1;
 809         self.cnt -= 1;
 810     }
 811         else
 812         {
 813                 if(self.cnt <= 10)
 814                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 815                 if(IS_REAL_CLIENT(self.owner))
 816                 {
 817                         if(self.cnt <= 10)
 818                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
 819                 }
 820                 self.nextthink = time + 1;
 821                 self.cnt -= 1;
 822         }
 823 }
 824
 825 float clientkilltime;
 826 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 827 {
 828         float killtime;
 829         float starttime;
 830         entity e;
 831
 832         if (gameover)
 833                 return;
 834
 835         killtime = autocvar_g_balance_kill_delay;
 836
 837         if(g_race_qualifying || g_cts)
 838                 killtime = 0;
 839
 840     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 841     {
 842                 remove(self.killindicator);
 843                 self.killindicator = world;
 844
 845         ClientKill_Now(); // allow instant kill in this case
 846         return;
 847     }
 848
 849         self.killindicator_teamchange = targetteam;
 850
 851     if(!self.killindicator)
 852         {
 853                 if(self.deadflag == DEAD_NO)
 854                 {
 855                         killtime = max(killtime, self.clientkill_nexttime - time);
 856                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 857                 }
 858
 859                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 860                 {
 861                         ClientKill_Now();
 862                 }
 863                 else
 864                 {
 865                         starttime = max(time, clientkilltime);
 866
 867                         self.killindicator = spawn();
 868                         self.killindicator.owner = self;
 869                         self.killindicator.scale = 0.5;
 870                         setattachment(self.killindicator, self, "");
 871                         setorigin(self.killindicator, '0 0 52');
 872                         self.killindicator.think = KillIndicator_Think;
 873                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 874                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 875                         self.killindicator.cnt = ceil(killtime);
 876                         self.killindicator.count = bound(0, ceil(killtime), 10);
 877                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 878
 879                         for(e = world; (e = find(e, classname, "body")) != world; )
 880                         {
 881                                 if(e.enemy != self)
 882                                         continue;
 883                                 e.killindicator = spawn();
 884                                 e.killindicator.owner = e;
 885                                 e.killindicator.scale = 0.5;
 886                                 setattachment(e.killindicator, e, "");
 887                                 setorigin(e.killindicator, '0 0 52');
 888                                 e.killindicator.think = KillIndicator_Think;
 889                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 890                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 891                                 e.killindicator.cnt = ceil(killtime);
 892                         }
 893                         self.lip = 0;
 894                 }
 895         }
 896         if(self.killindicator)
 897         {
 898                 if(targetteam == 0) // just die
 899                 {
 900                         self.killindicator.colormod = '0 0 0';
 901                         if(IS_REAL_CLIENT(self))
 902                         if(self.killindicator.cnt > 0)
 903                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 904                 }
 905                 else if(targetteam == -1) // auto
 906                 {
 907                         self.killindicator.colormod = '0 1 0';
 908                         if(IS_REAL_CLIENT(self))
 909                         if(self.killindicator.cnt > 0)
 910                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 911                 }
 912                 else if(targetteam == -2) // spectate
 913                 {
 914                         self.killindicator.colormod = '0.5 0.5 0.5';
 915                         if(IS_REAL_CLIENT(self))
 916                         if(self.killindicator.cnt > 0)
 917                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 918                 }
 919                 else
 920                 {
 921                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 922                         if(IS_REAL_CLIENT(self))
 923                         if(self.killindicator.cnt > 0)
 924                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 925                 }
 926         }
 927
 928 }
 929
 930 void ClientKill (void)
 931 {
 932         if(gameover) return;
 933         if(self.player_blocked) return;
 934         if(self.freezetag_frozen) return;
 935
 936         ClientKill_TeamChange(0);
 937 }
 938
 939 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 940 {
 941     e.killindicator = spawn();
 942     e.killindicator.owner = e;
 943     e.killindicator.think = KillIndicator_Think;
 944     e.killindicator.nextthink = time + (e.lip) * 0.05;
 945     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 946     e.killindicator.health = 1; // this is used to indicate that it should be silent
 947     e.lip = 0;
 948 }
 949
 950 void FixClientCvars(entity e)
 951 {
 952         // send prediction settings to the client
 953         stuffcmd(e, "\nin_bindmap 0 0\n");
 954         if(g_race || g_cts)
 955                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 956         if(autocvar_g_antilag == 3) // client side hitscan
 957                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 958         if(autocvar_sv_gentle)
 959                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 960         /*
 961          * we no longer need to stuff this. Remove this comment block if you feel
 962          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 963         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 964         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 965         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 966         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 967         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 968         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 969         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 970         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 971         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 972         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 973         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 974         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 975         stuffcmd(e, "cl_movement_edgefriction 1\n");
 976          */
 977 }
 978
 979 float PlayerInIDList(entity p, string idlist)
 980 {
 981         float n, i;
 982         string s;
 983
 984         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 985         if not(p.crypto_idfp)
 986                 return 0;
 987
 988         // this function allows abbreviated player IDs too!
 989         n = tokenize_console(idlist);
 990         for(i = 0; i < n; ++i)
 991         {
 992                 s = argv(i);
 993                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 994                         return 1;
 995         }
 996
 997         return 0;
 998 }
 999
1000 /*
1001 =============
1002 ClientConnect
1003
1004 Called when a client connects to the server
1005 =============
1006 */
1007 void DecodeLevelParms (void);
1008 //void dom_player_join_team(entity pl);
1009 void set_dom_state(entity e);
1010 void ClientConnect (void)
1011 {
1012         float t;
1013
1014         if(IS_CLIENT(self))
1015         {
1016                 print("Warning: ClientConnect, but already connected!\n");
1017                 return;
1018         }
1019
1020         if(Ban_MaybeEnforceBanOnce(self))
1021                 return;
1022
1023         DecodeLevelParms();
1024
1025 #ifdef WATERMARK
1026         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1027 #endif
1028
1029         self.classname = "player_joining";
1030
1031         self.flags = FL_CLIENT;
1032         self.version_nagtime = time + 10 + random() * 10;
1033
1034         if(player_count<0)
1035         {
1036                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1037                 player_count = 0;
1038         }
1039
1040         PlayerScore_Attach(self);
1041         ClientData_Attach();
1042         accuracy_init(self);
1043
1044         bot_clientconnect();
1045
1046         playerdemo_init();
1047
1048         anticheat_init();
1049
1050         race_PreSpawnObserver();
1051
1052         // identify the right forced team
1053         if(autocvar_g_campaign)
1054         {
1055                 if(IS_REAL_CLIENT(self)) // only players, not bots
1056                 {
1057                         switch(autocvar_g_campaign_forceteam)
1058                         {
1059                                 case 1: self.team_forced = NUM_TEAM_1; break;
1060                                 case 2: self.team_forced = NUM_TEAM_2; break;
1061                                 case 3: self.team_forced = NUM_TEAM_3; break;
1062                                 case 4: self.team_forced = NUM_TEAM_4; break;
1063                                 default: self.team_forced = 0;
1064                         }
1065                 }
1066         }
1067         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1068                 self.team_forced = NUM_TEAM_1;
1069         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1070                 self.team_forced = NUM_TEAM_2;
1071         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1072                 self.team_forced = NUM_TEAM_3;
1073         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1074                 self.team_forced = NUM_TEAM_4;
1075         else if(autocvar_g_forced_team_otherwise == "red")
1076                 self.team_forced = NUM_TEAM_1;
1077         else if(autocvar_g_forced_team_otherwise == "blue")
1078                 self.team_forced = NUM_TEAM_2;
1079         else if(autocvar_g_forced_team_otherwise == "yellow")
1080                 self.team_forced = NUM_TEAM_3;
1081         else if(autocvar_g_forced_team_otherwise == "pink")
1082                 self.team_forced = NUM_TEAM_4;
1083         else if(autocvar_g_forced_team_otherwise == "spectate")
1084                 self.team_forced = -1;
1085         else if(autocvar_g_forced_team_otherwise == "spectator")
1086                 self.team_forced = -1;
1087         else
1088                 self.team_forced = 0;
1089
1090         if(!teamplay)
1091                 if(self.team_forced > 0)
1092                         self.team_forced = 0;
1093
1094         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1095
1096         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1097                 self.classname = "observer";
1098         } else {
1099                 if(teamplay)
1100                 {
1101                         if(autocvar_g_balance_teams)
1102                         {
1103                                 self.classname = "player";
1104                                 campaign_bots_may_start = 1;
1105                         }
1106                         else
1107                         {
1108                                 self.classname = "observer"; // do it anyway
1109                         }
1110                 }
1111                 else
1112                 {
1113                         self.classname = "player";
1114                         campaign_bots_may_start = 1;
1115                 }
1116         }
1117
1118         self.playerid = (playerid_last = playerid_last + 1);
1119
1120         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1121
1122     if(IS_BOT_CLIENT(self))
1123         PlayerStats_AddPlayer(self);
1124
1125         if(autocvar_sv_eventlog)
1126                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1127
1128         LogTeamchange(self.playerid, self.team, 1);
1129
1130         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1131
1132         self.netname_previous = strzone(self.netname);
1133
1134         if(IS_PLAYER(self) && teamplay)
1135                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1136         else
1137                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1138
1139         stuffcmd(self, strcat(clientstuff, "\n"));
1140         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1141
1142         FixClientCvars(self);
1143
1144         // spawnfunc_waypoint sprites
1145         WaypointSprite_InitClient(self);
1146
1147         // Wazat's grappling hook
1148         SetGrappleHookBindings();
1149
1150         // get version info from player
1151         stuffcmd(self, "cmd clientversion $gameversion\n");
1152
1153         // get other cvars from player
1154         GetCvars(0);
1155
1156         // notify about available teams
1157         if(teamplay)
1158         {
1159                 CheckAllowedTeams(self);
1160                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1161                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1162         }
1163         else
1164                 stuffcmd(self, "set _teams_available 0\n");
1165
1166         attach_entcs();
1167
1168         bot_relinkplayerlist();
1169
1170         self.spectatortime = time;
1171         if(blockSpectators)
1172         {
1173                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1174         }
1175
1176         self.jointime = time;
1177         self.allowed_timeouts = autocvar_sv_timeout_number;
1178
1179         if(IS_REAL_CLIENT(self))
1180         {
1181                 if(!autocvar_g_campaign)
1182                 {
1183                         self.motd_actived_time = -1;
1184                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1185                 }
1186
1187                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1188                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1189         }
1190
1191         if(!sv_foginterval && world.fog != "")
1192                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1193
1194         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1195         {
1196                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1197                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1198         }
1199         else
1200                 self.hitplotfh = -1;
1201
1202         if(g_race || g_cts) {
1203                 string rr;
1204                 if(g_cts)
1205                         rr = CTS_RECORD;
1206                 else
1207                         rr = RACE_RECORD;
1208
1209                 msg_entity = self;
1210                 race_send_recordtime(MSG_ONE);
1211                 race_send_speedaward(MSG_ONE);
1212
1213                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1214                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1215                 race_send_speedaward_alltimebest(MSG_ONE);
1216
1217                 float i;
1218                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1219                         race_SendRankings(i, 0, 0, MSG_ONE);
1220                 }
1221         }
1222         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1223                 send_CSQC_teamnagger();
1224
1225         CheatInitClient();
1226
1227         CSQCMODEL_AUTOINIT();
1228
1229         self.model_randomizer = random();
1230
1231         if(IS_REAL_CLIENT(self))
1232                 sv_notice_join();
1233
1234         MUTATOR_CALLHOOK(ClientConnect);
1235 }
1236 /*
1237 =============
1238 ClientDisconnect
1239
1240 Called when a client disconnects from the server
1241 =============
1242 */
1243 .entity chatbubbleentity;
1244 void ReadyCount();
1245 void ClientDisconnect (void)
1246 {
1247         if(self.vehicle)
1248             vehicles_exit(VHEF_RELESE);
1249
1250         if not(IS_CLIENT(self))
1251         {
1252                 print("Warning: ClientDisconnect without ClientConnect\n");
1253                 return;
1254         }
1255
1256         PlayerStats_AddGlobalInfo(self);
1257
1258         CheatShutdownClient();
1259
1260         if(self.hitplotfh >= 0)
1261         {
1262                 fclose(self.hitplotfh);
1263                 self.hitplotfh = -1;
1264         }
1265
1266         anticheat_report();
1267         anticheat_shutdown();
1268
1269         playerdemo_shutdown();
1270
1271         bot_clientdisconnect();
1272
1273         if(self.entcs)
1274                 detach_entcs();
1275
1276         if(autocvar_sv_eventlog)
1277                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1278
1279         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1280
1281         MUTATOR_CALLHOOK(ClientDisconnect);
1282
1283         Portal_ClearAll(self);
1284
1285         RemoveGrapplingHook(self);
1286
1287         // Here, everything has been done that requires this player to be a client.
1288
1289         self.flags &~= FL_CLIENT;
1290
1291         if (self.chatbubbleentity)
1292                 remove (self.chatbubbleentity);
1293
1294         if (self.killindicator)
1295                 remove (self.killindicator);
1296
1297         WaypointSprite_PlayerGone();
1298
1299         bot_relinkplayerlist();
1300
1301         accuracy_free(self);
1302         ClientData_Detach();
1303         PlayerScore_Detach(self);
1304
1305         if(self.netname_previous)
1306                 strunzone(self.netname_previous);
1307         if(self.clientstatus)
1308                 strunzone(self.clientstatus);
1309         if(self.weaponorder_byimpulse)
1310                 strunzone(self.weaponorder_byimpulse);
1311
1312         ClearPlayerSounds();
1313
1314         if(self.personal)
1315                 remove(self.personal);
1316
1317         self.playerid = 0;
1318         ReadyCount();
1319
1320         // free cvars
1321         GetCvars(-1);
1322 }
1323
1324 .float BUTTON_CHAT;
1325 void ChatBubbleThink()
1326 {
1327         self.nextthink = time;
1328         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1329         {
1330                 if(self.owner) // but why can that ever be world?
1331                         self.owner.chatbubbleentity = world;
1332                 remove(self);
1333                 return;
1334         }
1335         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1336 #ifdef TETRIS
1337                 || self.owner.tetris_on
1338 #endif
1339         )
1340                 self.model = self.mdl;
1341         else
1342                 self.model = "";
1343 }
1344
1345 void UpdateChatBubble()
1346 {
1347         if (self.alpha < 0)
1348                 return;
1349         // spawn a chatbubble entity if needed
1350         if (!self.chatbubbleentity)
1351         {
1352                 self.chatbubbleentity = spawn();
1353                 self.chatbubbleentity.owner = self;
1354                 self.chatbubbleentity.exteriormodeltoclient = self;
1355                 self.chatbubbleentity.think = ChatBubbleThink;
1356                 self.chatbubbleentity.nextthink = time;
1357                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1358                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1359                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1360                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1361                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1362                 self.chatbubbleentity.model = "";
1363                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1364         }
1365 }
1366
1367
1368 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1369 // added to the model skins
1370 /*void UpdateColorModHack()
1371 {
1372         float c;
1373         c = self.clientcolors & 15;
1374         // LordHavoc: only bothering to support white, green, red, yellow, blue
1375              if (!teamplay) self.colormod = '0 0 0';
1376         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1377         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1378         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1379         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1380         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1381         else self.colormod = '1 1 1';
1382 }*/
1383
1384 void respawn(void)
1385 {
1386         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1387         {
1388                 self.solid = SOLID_NOT;
1389                 self.takedamage = DAMAGE_NO;
1390                 self.movetype = MOVETYPE_FLY;
1391                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1392                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1393                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1394                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1395                 if(autocvar_g_respawn_ghosts_maxtime)
1396                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1397         }
1398
1399         CopyBody(1);
1400
1401         self.effects |= EF_NODRAW; // prevent another CopyBody
1402         PutClientInServer();
1403 }
1404
1405 void play_countdown(float finished, string samp)
1406 {
1407         if(IS_REAL_CLIENT(self))
1408                 if(floor(finished - time - frametime) != floor(finished - time))
1409                         if(finished - time < 6)
1410                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1411 }
1412
1413 void player_powerups (void)
1414 {
1415         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1416         olditems = self.items;
1417
1418         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1419                 self.modelflags |= MF_ROCKET;
1420         else
1421                 self.modelflags &~= MF_ROCKET;
1422
1423         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1424
1425         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1426                 return;
1427
1428         Fire_ApplyDamage(self);
1429         Fire_ApplyEffect(self);
1430
1431         if not(g_minstagib)
1432         {
1433                 if (self.items & IT_STRENGTH)
1434                 {
1435                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1436                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1437                         if (time > self.strength_finished)
1438                         {
1439                                 self.items = self.items - (self.items & IT_STRENGTH);
1440                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1441                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1442                         }
1443                 }
1444                 else
1445                 {
1446                         if (time < self.strength_finished)
1447                         {
1448                                 self.items = self.items | IT_STRENGTH;
1449                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1450                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1451                         }
1452                 }
1453                 if (self.items & IT_INVINCIBLE)
1454                 {
1455                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1456                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1457                         if (time > self.invincible_finished)
1458                         {
1459                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1460                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1461                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1462                         }
1463                 }
1464                 else
1465                 {
1466                         if (time < self.invincible_finished)
1467                         {
1468                                 self.items = self.items | IT_INVINCIBLE;
1469                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1470                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1471                         }
1472                 }
1473                 if (self.items & IT_SUPERWEAPON)
1474                 {
1475                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1476                         {
1477                                 self.superweapons_finished = 0;
1478                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1479                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1480                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1481                         }
1482                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1483                         {
1484                                 // don't let them run out
1485                         }
1486                         else
1487                         {
1488                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1489                                 if (time > self.superweapons_finished)
1490                                 {
1491                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1492                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1493                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1494                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1495                                 }
1496                         }
1497                 }
1498                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1499                 {
1500                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1501                         {
1502                                 self.items = self.items | IT_SUPERWEAPON;
1503                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1504                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1505                         }
1506                         else
1507                         {
1508                                 self.superweapons_finished = 0;
1509                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1510                         }
1511                 }
1512                 else
1513                 {
1514                         self.superweapons_finished = 0;
1515                 }
1516         }
1517
1518         if(autocvar_g_nodepthtestplayers)
1519                 self.effects = self.effects | EF_NODEPTHTEST;
1520
1521         if(autocvar_g_fullbrightplayers)
1522                 self.effects = self.effects | EF_FULLBRIGHT;
1523
1524         // midair gamemode: damage only while in the air
1525         // if in midair mode, being on ground grants temporary invulnerability
1526         // (this is so that multishot weapon don't clear the ground flag on the
1527         // first damage in the frame, leaving the player vulnerable to the
1528         // remaining hits in the same frame)
1529         if (self.flags & FL_ONGROUND)
1530         if (g_midair)
1531                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1532
1533         if (time >= game_starttime)
1534         if (time < self.spawnshieldtime)
1535                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1536
1537         MUTATOR_CALLHOOK(PlayerPowerups);
1538 }
1539
1540 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1541 {
1542         if(current > stable)
1543                 return current;
1544         else if(current > stable - 0.25) // when close enough, "snap"
1545                 return stable;
1546         else
1547                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1548 }
1549
1550 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1551 {
1552         if(current < stable)
1553                 return current;
1554         else if(current < stable + 0.25) // when close enough, "snap"
1555                 return stable;
1556         else
1557                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1558 }
1559
1560 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1561 {
1562         if(current > rotstable)
1563         {
1564                 if(rotframetime > 0)
1565                 {
1566                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1567                         current = max(rotstable, current - rotlinear * rotframetime);
1568                 }
1569         }
1570         else if(current < regenstable)
1571         {
1572                 if(regenframetime > 0)
1573                 {
1574                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1575                         current = min(regenstable, current + regenlinear * regenframetime);
1576                 }
1577         }
1578
1579         if(current > limit)
1580                 current = limit;
1581
1582         return current;
1583 }
1584
1585 void player_regen (void)
1586 {
1587         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1588         maxh = autocvar_g_balance_health_rotstable;
1589         maxa = autocvar_g_balance_armor_rotstable;
1590         maxf = autocvar_g_balance_fuel_rotstable;
1591         minh = autocvar_g_balance_health_regenstable;
1592         mina = autocvar_g_balance_armor_regenstable;
1593         minf = autocvar_g_balance_fuel_regenstable;
1594         limith = autocvar_g_balance_health_limit;
1595         limita = autocvar_g_balance_armor_limit;
1596         limitf = autocvar_g_balance_fuel_limit;
1597
1598         max_mod = regen_mod = rot_mod = limit_mod = 1;
1599
1600         maxh = maxh * max_mod;
1601         //maxa = maxa * max_mod;
1602         //maxf = maxf * max_mod;
1603         minh = minh * max_mod;
1604         //mina = mina * max_mod;
1605         //minf = minf * max_mod;
1606         limith = limith * limit_mod;
1607         limita = limita * limit_mod;
1608         //limitf = limitf * limit_mod;
1609
1610         if(g_ca)
1611                 rot_mod = 0;
1612
1613         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1614         {
1615                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1616                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1617
1618                 // if player rotted to death...  die!
1619                 if(self.health < 1)
1620                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1621         }
1622
1623         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1624                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1625 }
1626
1627 float zoomstate_set;
1628 void SetZoomState(float z)
1629 {
1630         if(z != self.zoomstate)
1631         {
1632                 self.zoomstate = z;
1633                 ClientData_Touch(self);
1634         }
1635         zoomstate_set = 1;
1636 }
1637
1638 void GetPressedKeys(void) {
1639         MUTATOR_CALLHOOK(GetPressedKeys);
1640         if (self.movement_x > 0) // get if movement keys are pressed
1641         {       // forward key pressed
1642                 self.pressedkeys |= KEY_FORWARD;
1643                 self.pressedkeys &~= KEY_BACKWARD;
1644         }
1645         else if (self.movement_x < 0)
1646         {       // backward key pressed
1647                 self.pressedkeys |= KEY_BACKWARD;
1648                 self.pressedkeys &~= KEY_FORWARD;
1649         }
1650         else
1651         {       // no x input
1652                 self.pressedkeys &~= KEY_FORWARD;
1653                 self.pressedkeys &~= KEY_BACKWARD;
1654         }
1655
1656         if (self.movement_y > 0)
1657         {       // right key pressed
1658                 self.pressedkeys |= KEY_RIGHT;
1659                 self.pressedkeys &~= KEY_LEFT;
1660         }
1661         else if (self.movement_y < 0)
1662         {       // left key pressed
1663                 self.pressedkeys |= KEY_LEFT;
1664                 self.pressedkeys &~= KEY_RIGHT;
1665         }
1666         else
1667         {       // no y input
1668                 self.pressedkeys &~= KEY_RIGHT;
1669                 self.pressedkeys &~= KEY_LEFT;
1670         }
1671
1672         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1673                 self.pressedkeys |= KEY_JUMP;
1674         else
1675                 self.pressedkeys &~= KEY_JUMP;
1676         if (self.BUTTON_CROUCH)
1677                 self.pressedkeys |= KEY_CROUCH;
1678         else
1679                 self.pressedkeys &~= KEY_CROUCH;
1680
1681         if (self.BUTTON_ATCK)
1682                 self.pressedkeys |= KEY_ATCK;
1683         else
1684                 self.pressedkeys &~= KEY_ATCK;
1685         if (self.BUTTON_ATCK2)
1686                 self.pressedkeys |= KEY_ATCK2;
1687         else
1688                 self.pressedkeys &~= KEY_ATCK2;
1689 }
1690
1691 /*
1692 ======================
1693 spectate mode routines
1694 ======================
1695 */
1696
1697 void SpectateCopy(entity spectatee) {
1698         other = spectatee;
1699         MUTATOR_CALLHOOK(SpectateCopy);
1700         self.armortype = spectatee.armortype;
1701         self.armorvalue = spectatee.armorvalue;
1702         self.ammo_cells = spectatee.ammo_cells;
1703         self.ammo_shells = spectatee.ammo_shells;
1704         self.ammo_nails = spectatee.ammo_nails;
1705         self.ammo_rockets = spectatee.ammo_rockets;
1706         self.ammo_fuel = spectatee.ammo_fuel;
1707         self.clip_load = spectatee.clip_load;
1708         self.clip_size = spectatee.clip_size;
1709         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1710         self.health = spectatee.health;
1711         self.impulse = 0;
1712         self.items = spectatee.items;
1713         self.last_pickup = spectatee.last_pickup;
1714         self.hit_time = spectatee.hit_time;
1715         self.metertime = spectatee.metertime;
1716         self.strength_finished = spectatee.strength_finished;
1717         self.invincible_finished = spectatee.invincible_finished;
1718         self.pressedkeys = spectatee.pressedkeys;
1719         WEPSET_COPY_EE(self, spectatee);
1720         self.switchweapon = spectatee.switchweapon;
1721         self.switchingweapon = spectatee.switchingweapon;
1722         self.weapon = spectatee.weapon;
1723         self.nex_charge = spectatee.nex_charge;
1724         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1725         self.hagar_load = spectatee.hagar_load;
1726         self.minelayer_mines = spectatee.minelayer_mines;
1727         self.punchangle = spectatee.punchangle;
1728         self.view_ofs = spectatee.view_ofs;
1729         self.velocity = spectatee.velocity;
1730         self.dmg_take = spectatee.dmg_take;
1731         self.dmg_save = spectatee.dmg_save;
1732         self.dmg_inflictor = spectatee.dmg_inflictor;
1733         self.v_angle = spectatee.v_angle;
1734         self.angles = spectatee.v_angle;
1735         if(!self.BUTTON_USE)
1736                 self.fixangle = TRUE;
1737         setorigin(self, spectatee.origin);
1738         setsize(self, spectatee.mins, spectatee.maxs);
1739         SetZoomState(spectatee.zoomstate);
1740
1741     anticheat_spectatecopy(spectatee);
1742         self.hud = spectatee.hud;
1743         if(spectatee.vehicle)
1744     {
1745         self.fixangle = FALSE;
1746         //self.velocity = spectatee.vehicle.velocity;
1747         self.vehicle_health = spectatee.vehicle_health;
1748         self.vehicle_shield = spectatee.vehicle_shield;
1749         self.vehicle_energy = spectatee.vehicle_energy;
1750         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1751         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1752         self.vehicle_reload1 = spectatee.vehicle_reload1;
1753         self.vehicle_reload2 = spectatee.vehicle_reload2;
1754
1755         msg_entity = self;
1756
1757         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1758             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1759             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1760             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1761
1762         //WriteByte (MSG_ONE, SVC_SETVIEW);
1763         //    WriteEntity(MSG_ONE, self);
1764         //makevectors(spectatee.v_angle);
1765         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1766     }
1767 }
1768
1769 float SpectateUpdate() {
1770         if(!self.enemy)
1771             return 0;
1772
1773         if (self == self.enemy)
1774                 return 0;
1775
1776         if not(IS_PLAYER(self.enemy))
1777                 return 0;
1778
1779         SpectateCopy(self.enemy);
1780
1781         return 1;
1782 }
1783
1784
1785 float SpectateSet()
1786 {
1787         if(self.enemy.classname != "player")
1788                 return FALSE;
1789         /*if(self.enemy.vehicle)
1790         {
1791
1792                 msg_entity = self;
1793                 WriteByte(MSG_ONE, SVC_SETVIEW);
1794                 WriteEntity(MSG_ONE, self.enemy);
1795                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1796
1797                 self.movetype = MOVETYPE_NONE;
1798                 accuracy_resend(self);
1799         }
1800         else
1801         {*/
1802                 msg_entity = self;
1803                 WriteByte(MSG_ONE, SVC_SETVIEW);
1804                 WriteEntity(MSG_ONE, self.enemy);
1805                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1806                 self.movetype = MOVETYPE_NONE;
1807                 accuracy_resend(self);
1808
1809                 if(!SpectateUpdate())
1810                         PutObserverInServer();
1811         //}
1812         return TRUE;
1813 }
1814
1815 float Spectate(entity pl)
1816 {
1817         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1818         if(pl.team != self.team)
1819                 return 0;
1820
1821         self.enemy = pl;
1822         return SpectateSet();
1823 }
1824
1825 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1826 entity CA_SpectateNext(entity start) {
1827         if (start.team == self.team) {
1828                 return start;
1829         }
1830
1831         other = start;
1832         // continue from current player
1833         while(other && other.team != self.team) {
1834                 other = find(other, classname, "player");
1835         }
1836
1837         if (!other) {
1838                 // restart from begining
1839                 other = find(other, classname, "player");
1840                 while(other && other.team != self.team) {
1841                         other = find(other, classname, "player");
1842                 }
1843         }
1844
1845         return other;
1846 }
1847
1848 float SpectateNext()
1849 {
1850         other = find(self.enemy, classname, "player");
1851
1852         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1853                 // CA and ca players when spectating enemies is forbidden
1854                 other = CA_SpectateNext(other);
1855         } else {
1856                 // other modes and ca spectators or spectating enemies is allowed
1857                 if (!other)
1858                         other = find(other, classname, "player");
1859         }
1860
1861         if (other)
1862                 self.enemy = other;
1863
1864         return SpectateSet();
1865 }
1866
1867 float SpectatePrev()
1868 {
1869         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1870         other = findchain(classname, "player");
1871         if not(other) // no player
1872                 return FALSE;
1873
1874         entity first = other;
1875         // skip players until current spectated player
1876         if(self.enemy)
1877         while(other && other != self.enemy)
1878                 other = other.chain;
1879
1880         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1881         {
1882                 do { other = other.chain; }
1883                 while(other && other.team != self.team);
1884
1885                 if not(other)
1886                 {
1887                         other = first;
1888                         while(other.team != self.team)
1889                                 other = other.chain;
1890                         if(other == self.enemy)
1891                                 return TRUE;
1892                 }
1893         }
1894         else
1895         {
1896                 if(other.chain)
1897                         other = other.chain;
1898                 else
1899                         other = first;
1900         }
1901         self.enemy = other;
1902         return SpectateSet();
1903 }
1904
1905 /*
1906 =============
1907 ShowRespawnCountdown()
1908
1909 Update a respawn countdown display.
1910 =============
1911 */
1912 void ShowRespawnCountdown()
1913 {
1914         float number;
1915         if(self.deadflag == DEAD_NO) // just respawned?
1916                 return;
1917         else
1918         {
1919                 number = ceil(self.respawn_time - time);
1920                 if(number <= 0)
1921                         return;
1922                 if(number <= self.respawn_countdown)
1923                 {
1924                         self.respawn_countdown = number - 1;
1925                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1926                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number));
1927                 }
1928         }
1929 }
1930
1931 void LeaveSpectatorMode()
1932 {
1933         if(self.caplayer)
1934                 return;
1935         if(nJoinAllowed(self))
1936         {
1937                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1938                 {
1939                         self.classname = "player";
1940
1941                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1942                                 { JoinBestTeam(self, FALSE, TRUE); }
1943
1944                         if(autocvar_g_campaign)
1945                                 { campaign_bots_may_start = 1; }
1946
1947                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1948
1949                         PutClientInServer();
1950
1951                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1952                 }
1953                 else
1954                         stuffcmd(self, "menu_showteamselect\n");
1955         }
1956         else
1957         {
1958                 // Player may not join because g_maxplayers is set
1959                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1960         }
1961 }
1962
1963 /**
1964  * Determines whether the player is allowed to join. This depends on cvar
1965  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1966  * it checks whether the number of currently playing players exceeds g_maxplayers.
1967  * @return int number of free slots for players, 0 if none
1968  */
1969 float nJoinAllowed(entity ignore) {
1970         if(!ignore)
1971         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1972         // so report 0 free slots if restricted
1973         {
1974                 if(autocvar_g_forced_team_otherwise == "spectate")
1975                         return 0;
1976                 if(autocvar_g_forced_team_otherwise == "spectator")
1977                         return 0;
1978         }
1979
1980         if(self.team_forced < 0)
1981                 return 0; // forced spectators can never join
1982
1983         // TODO simplify this
1984         entity e;
1985         float totalClients = 0;
1986         FOR_EACH_CLIENT(e)
1987                 if(e != ignore)
1988                         totalClients += 1;
1989
1990         if (!autocvar_g_maxplayers)
1991                 return maxclients - totalClients;
1992
1993         float currentlyPlaying = 0;
1994         FOR_EACH_REALCLIENT(e)
1995                 if(IS_PLAYER(e) || e.caplayer == 1)
1996                         currentlyPlaying += 1;
1997
1998         if(currentlyPlaying < autocvar_g_maxplayers)
1999                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2000
2001         return 0;
2002 }
2003
2004 /**
2005  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2006  * g_maxplayers_spectator_blocktime seconds
2007  */
2008 void checkSpectatorBlock() {
2009         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2010                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2011                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2012                         dropclient(self);
2013                 }
2014         }
2015 }
2016
2017 void PrintWelcomeMessage()
2018 {
2019         if(self.motd_actived_time == 0)
2020         {
2021                 if (autocvar_g_campaign) {
2022                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2023                                 self.motd_actived_time = time;
2024                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2025                         }
2026                 } else {
2027                         if (self.BUTTON_INFO) {
2028                                 self.motd_actived_time = time;
2029                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2030                         }
2031                 }
2032         }
2033         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2034         {
2035                 if (autocvar_g_campaign) {
2036                         if (self.BUTTON_INFO)
2037                                 self.motd_actived_time = time;
2038                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2039                                 self.motd_actived_time = 0;
2040                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2041                         }
2042                 } else {
2043                         if (self.BUTTON_INFO)
2044                                 self.motd_actived_time = time;
2045                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2046                                 self.motd_actived_time = 0;
2047                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2048                         }
2049                 }
2050         }
2051         else //if(self.motd_actived_time < 0) // just connected, motd is active
2052         {
2053                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2054                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2055                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2056                 {
2057                         // instanctly hide MOTD
2058                         self.motd_actived_time = 0;
2059                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2060                 }
2061         }
2062 }
2063
2064 void ObserverThink()
2065 {
2066         float prefered_movetype;
2067         if (self.flags & FL_JUMPRELEASED) {
2068                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2069                         self.flags &~= FL_JUMPRELEASED;
2070                         self.flags |= FL_SPAWNING;
2071                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2072                         self.flags &~= FL_JUMPRELEASED;
2073                         if(SpectateNext()) {
2074                                 self.classname = "spectator";
2075                         }
2076                 } else {
2077                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2078                         if (self.movetype != prefered_movetype)
2079                                 self.movetype = prefered_movetype;
2080                 }
2081         } else {
2082                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2083                         self.flags |= FL_JUMPRELEASED;
2084                         if(self.flags & FL_SPAWNING)
2085                         {
2086                                 self.flags &~= FL_SPAWNING;
2087                                 LeaveSpectatorMode();
2088                                 return;
2089                         }
2090                 }
2091         }
2092 }
2093
2094 void SpectatorThink()
2095 {
2096         if (self.flags & FL_JUMPRELEASED) {
2097                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2098                         self.flags &~= FL_JUMPRELEASED;
2099                         self.flags |= FL_SPAWNING;
2100                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || self.impulse >= 200 && self.impulse <= 209) {
2101                         self.flags &~= FL_JUMPRELEASED;
2102                         if(SpectateNext()) {
2103                                 self.classname = "spectator";
2104                         } else {
2105                                 self.classname = "observer";
2106                                 PutClientInServer();
2107                         }
2108                         self.impulse = 0;
2109                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || self.impulse >= 220 && self.impulse <= 229) {
2110                         self.flags &~= FL_JUMPRELEASED;
2111                         if(SpectatePrev()) {
2112                                 self.classname = "spectator";
2113                         } else {
2114                                 self.classname = "observer";
2115                                 PutClientInServer();
2116                         }
2117                         self.impulse = 0;
2118                 } else if (self.BUTTON_ATCK2) {
2119                         self.flags &~= FL_JUMPRELEASED;
2120                         self.classname = "observer";
2121                         PutClientInServer();
2122                 } else {
2123                         if(!SpectateUpdate())
2124                                 PutObserverInServer();
2125                 }
2126         } else {
2127                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2128                         self.flags |= FL_JUMPRELEASED;
2129                         if(self.flags & FL_SPAWNING)
2130                         {
2131                                 self.flags &~= FL_SPAWNING;
2132                                 LeaveSpectatorMode();
2133                                 return;
2134                         }
2135                 }
2136                 if(!SpectateUpdate())
2137                         PutObserverInServer();
2138         }
2139
2140         self.flags |= FL_CLIENT | FL_NOTARGET;
2141 }
2142
2143 void PlayerUseKey()
2144 {
2145         if not(IS_PLAYER(self))
2146                 return;
2147
2148         if(self.vehicle)
2149         {
2150         vehicles_exit(VHEF_NORMAL);
2151         return;
2152         }
2153
2154         // a use key was pressed; call handlers
2155         MUTATOR_CALLHOOK(PlayerUseKey);
2156 }
2157
2158 /*
2159 =============
2160 PlayerPreThink
2161
2162 Called every frame for each client before the physics are run
2163 =============
2164 */
2165 .float usekeypressed;
2166 void() nexball_setstatus;
2167 .float items_added;
2168 void PlayerPreThink (void)
2169 {
2170         WarpZone_PlayerPhysics_FixVAngle();
2171
2172         self.stat_game_starttime = game_starttime;
2173         self.stat_round_starttime = round_starttime;
2174         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2175         self.stat_leadlimit = autocvar_leadlimit;
2176
2177         if(frametime)
2178         {
2179                 // physics frames: update anticheat stuff
2180                 anticheat_prethink();
2181         }
2182
2183         if(blockSpectators && frametime)
2184                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2185                 checkSpectatorBlock();
2186
2187         zoomstate_set = 0;
2188
2189         if(self.netname_previous != self.netname)
2190         {
2191                 if(autocvar_sv_eventlog)
2192                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2193                 if(self.netname_previous)
2194                         strunzone(self.netname_previous);
2195                 self.netname_previous = strzone(self.netname);
2196         }
2197
2198         // version nagging
2199         if(self.version_nagtime)
2200                 if(self.cvar_g_xonoticversion)
2201                         if(time > self.version_nagtime)
2202                         {
2203                                 // don't notify git users
2204                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2205                                 {
2206                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2207                                         {
2208                                                 // notify release users if connecting to git
2209                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2210                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2211                                         }
2212                                         else
2213                                         {
2214                                                 float r;
2215                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2216                                                 if(r < 0)
2217                                                 {
2218                                                         // give users new version
2219                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2220                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2221                                                 }
2222                                                 else if(r > 0)
2223                                                 {
2224                                                         // notify users about old server version
2225                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2226                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2227                                                 }
2228                                         }
2229                                 }
2230                                 self.version_nagtime = 0;
2231                         }
2232
2233         // GOD MODE info
2234         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2235         {
2236                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2237                 self.max_armorvalue = 0;
2238         }
2239
2240 #ifdef TETRIS
2241         if (TetrisPreFrame())
2242                 return;
2243 #endif
2244
2245         MUTATOR_CALLHOOK(PlayerPreThink);
2246
2247         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2248         {
2249                 if(self.BUTTON_USE && !self.usekeypressed)
2250                         PlayerUseKey();
2251                 self.usekeypressed = self.BUTTON_USE;
2252         }
2253
2254         if(IS_REAL_CLIENT(self))
2255                 PrintWelcomeMessage();
2256
2257         if(IS_PLAYER(self))
2258         {
2259
2260                 CheckRules_Player();
2261
2262                 if (intermission_running)
2263                 {
2264                         IntermissionThink ();   // otherwise a button could be missed between
2265                         return;                                 // the think tics
2266                 }
2267
2268                 //don't allow the player to turn around while game is paused!
2269                 if(timeout_status == TIMEOUT_ACTIVE) {
2270                         // FIXME turn this into CSQC stuff
2271                         self.v_angle = self.lastV_angle;
2272                         self.angles = self.lastV_angle;
2273                         self.fixangle = TRUE;
2274                 }
2275
2276                 if(frametime)
2277                 {
2278                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2279                         {
2280                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2281                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2282                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2283
2284                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2285                                 {
2286                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2287                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2288                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2289                                 }
2290                         }
2291                         else
2292                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2293
2294                         player_powerups();
2295                 }
2296
2297                 if (self.deadflag != DEAD_NO)
2298                 {
2299                         if(self.personal && g_race_qualifying)
2300                         {
2301                                 if(time > self.respawn_time)
2302                                 {
2303                                         self.respawn_time = time + 1; // only retry once a second
2304                                         self.stat_respawn_time = self.respawn_time;
2305                                         respawn();
2306                                         self.impulse = 141;
2307                                 }
2308                         }
2309                         else
2310                         {
2311                                 float button_pressed;
2312                                 if(frametime)
2313                                         player_anim();
2314                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2315
2316                                 if (self.deadflag == DEAD_DYING)
2317                                 {
2318                                         if(self.respawn_flags & RESPAWN_FORCE)
2319                                                 self.deadflag = DEAD_RESPAWNING;
2320                                         else if(!button_pressed)
2321                                                 self.deadflag = DEAD_DEAD;
2322                                 }
2323                                 else if (self.deadflag == DEAD_DEAD)
2324                                 {
2325                                         if(button_pressed)
2326                                                 self.deadflag = DEAD_RESPAWNABLE;
2327                                 }
2328                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2329                                 {
2330                                         if(!button_pressed)
2331                                                 self.deadflag = DEAD_RESPAWNING;
2332                                 }
2333                                 else if (self.deadflag == DEAD_RESPAWNING)
2334                                 {
2335                                         if(time > self.respawn_time)
2336                                         {
2337                                                 self.respawn_time = time + 1; // only retry once a second
2338                                                 respawn();
2339                                         }
2340                                 }
2341
2342                                 ShowRespawnCountdown();
2343
2344                                 if(self.respawn_flags & RESPAWN_SILENT)
2345                                         self.stat_respawn_time = 0;
2346                                 else
2347                                         self.stat_respawn_time = self.respawn_time;
2348                         }
2349
2350                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2351                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2352                                 self.stat_respawn_time *= -1;
2353
2354                         return;
2355                 }
2356
2357                 self.prevorigin = self.origin;
2358
2359                 float do_crouch = self.BUTTON_CROUCH;
2360                 if(self.hook.state)
2361                         do_crouch = 0;
2362                 if(self.health <= g_bloodloss)
2363                         do_crouch = 1;
2364                 if(self.vehicle)
2365                         do_crouch = 0;
2366                 if(self.freezetag_frozen)
2367                         do_crouch = 0;
2368                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2369                         do_crouch = 0;
2370
2371                 if (do_crouch)
2372                 {
2373                         if (!self.crouch)
2374                         {
2375                                 self.crouch = TRUE;
2376                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2377                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2378                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2379                         }
2380                 }
2381                 else
2382                 {
2383                         if (self.crouch)
2384                         {
2385                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2386                                 if (!trace_startsolid)
2387                                 {
2388                                         self.crouch = FALSE;
2389                                         self.view_ofs = PL_VIEW_OFS;
2390                                         setsize (self, PL_MIN, PL_MAX);
2391                                 }
2392                         }
2393                 }
2394
2395                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2396                 {
2397                         if(self.bloodloss_timer < time)
2398                         {
2399                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2400                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2401                         }
2402                 }
2403
2404                 FixPlayermodel();
2405
2406                 GrapplingHookFrame();
2407
2408                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2409                 //if(frametime)
2410                 {
2411                         self.items &~= self.items_added;
2412
2413                         W_WeaponFrame();
2414
2415                         self.items_added = 0;
2416                         if(self.items & IT_JETPACK)
2417                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2418                                         self.items_added |= IT_FUEL;
2419
2420                         self.items |= self.items_added;
2421                 }
2422
2423                 player_regen();
2424
2425                 // rot nex charge to the charge limit
2426                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2427                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2428
2429                 if(frametime)
2430                         player_anim();
2431
2432                 if(g_nexball)
2433                         nexball_setstatus();
2434
2435                 // secret status
2436                 secrets_setstatus();
2437
2438                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2439
2440                 //self.angles_y=self.v_angle_y + 90;   // temp
2441         } else if(gameover) {
2442                 if (intermission_running)
2443                         IntermissionThink ();   // otherwise a button could be missed between
2444                 return;
2445         } else if(IS_OBSERVER(self)) {
2446                 ObserverThink();
2447         } else if(IS_SPEC(self)) {
2448                 SpectatorThink();
2449         }
2450
2451         if(!zoomstate_set)
2452                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2453
2454         float oldspectatee_status;
2455         oldspectatee_status = self.spectatee_status;
2456         if(IS_SPEC(self))
2457                 self.spectatee_status = num_for_edict(self.enemy);
2458         else if(IS_OBSERVER(self))
2459                 self.spectatee_status = num_for_edict(self);
2460         else
2461                 self.spectatee_status = 0;
2462         if(self.spectatee_status != oldspectatee_status)
2463         {
2464                 ClientData_Touch(self);
2465                 if(g_race || g_cts)
2466                         race_InitSpectator();
2467         }
2468
2469         if(self.teamkill_soundtime)
2470         if(time > self.teamkill_soundtime)
2471         {
2472                 self.teamkill_soundtime = 0;
2473
2474                 entity oldpusher, oldself;
2475
2476                 oldself = self; self = self.teamkill_soundsource;
2477                 oldpusher = self.pusher; self.pusher = oldself;
2478
2479                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2480
2481                 self.pusher = oldpusher;
2482                 self = oldself;
2483         }
2484
2485         if(self.taunt_soundtime)
2486         if(time > self.taunt_soundtime)
2487         {
2488                 self.taunt_soundtime = 0;
2489                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2490         }
2491
2492         target_voicescript_next(self);
2493
2494         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2495         if(!self.weapon)
2496                 self.clip_load = self.clip_size = 0;
2497 }
2498
2499 float isInvisibleString(string s)
2500 {
2501         float i, n, c;
2502         s = strdecolorize(s);
2503         for((i = 0), (n = strlen(s)); i < n; ++i)
2504         {
2505                 c = str2chr(s, i);
2506                 switch(c)
2507                 {
2508                         case 0:
2509                         case 32: // space
2510                                 break;
2511                         case 192: // charmap space
2512                                 if (!autocvar_utf8_enable)
2513                                         break;
2514                                 return FALSE;
2515                         case 160: // space in unicode fonts
2516                         case 0xE000 + 192: // utf8 charmap space
2517                                 if (autocvar_utf8_enable)
2518                                         break;
2519                         default:
2520                                 return FALSE;
2521                 }
2522         }
2523         return TRUE;
2524 }
2525
2526 /*
2527 =============
2528 PlayerPostThink
2529
2530 Called every frame for each client after the physics are run
2531 =============
2532 */
2533 .float idlekick_lasttimeleft;
2534 void PlayerPostThink (void)
2535 {
2536         // Savage: Check for nameless players
2537         if (isInvisibleString(self.netname)) {
2538                 self.netname = "Player";
2539                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2540         }
2541
2542         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2543         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2544         {
2545                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2546                 {
2547                         if(self.idlekick_lasttimeleft)
2548                         {
2549                                 self.idlekick_lasttimeleft = 0;
2550                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2551                         }
2552                 }
2553                 else
2554                 {
2555                         float timeleft;
2556                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2557                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2558                         {
2559                                 if(!self.idlekick_lasttimeleft)
2560                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2561                         }
2562                         if(timeleft <= 0)
2563                         {
2564                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2565                                 dropclient(self);
2566                                 return;
2567                         }
2568                         else if(timeleft <= 10)
2569                         {
2570                                 if(timeleft != self.idlekick_lasttimeleft)
2571                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2572                                 self.idlekick_lasttimeleft = timeleft;
2573                         }
2574                 }
2575         }
2576
2577 #ifdef TETRIS
2578         if(self.impulse == 100)
2579                 ImpulseCommands();
2580         if (!TetrisPostFrame())
2581         {
2582 #endif
2583
2584         CheatFrame();
2585
2586         //CheckPlayerJump();
2587
2588         if(IS_PLAYER(self)) {
2589                 CheckRules_Player();
2590                 UpdateChatBubble();
2591                 if (self.impulse)
2592                         ImpulseCommands();
2593                 if (intermission_running)
2594                         return;         // intermission or finale
2595                 GetPressedKeys();
2596         }
2597
2598 #ifdef TETRIS
2599         }
2600 #endif
2601
2602         /*
2603         float i;
2604         for(i = 0; i < 1000; ++i)
2605         {
2606                 vector end;
2607                 end = self.origin + '0 0 1024' + 512 * randomvec();
2608                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2609                 if(trace_fraction < 1)
2610                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2611                 {
2612                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2613                         break;
2614                 }
2615         }
2616         */
2617
2618         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2619
2620         if(self.waypointsprite_attachedforcarrier)
2621                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2622
2623         playerdemo_write();
2624
2625         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2626         {
2627                 if not(self.stored_netname)
2628                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2629                 if(self.stored_netname != self.netname)
2630                 {
2631                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2632                         strunzone(self.stored_netname);
2633                         self.stored_netname = strzone(self.netname);
2634                 }
2635         }
2636
2637         /*
2638         if(g_race)
2639                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2640         */
2641
2642         CSQCMODEL_AUTOUPDATE();
2643 }