qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > autocvar_g_spawn_furthest)
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(autocvar_spawn_debugview)
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(autocvar_spawn_debug)
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel;
 402 string CheckPlayerModel(string plyermodel) {
 403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 404         {
 405                 // note: we cannot summon Don Strunzone here, some player may
 406                 // still have the model string set. In case anyone manages how
 407                 // to change a cvar default, we'll have a small leak here.
 408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 409         }
 410         if(strlen(plyermodel) < 4)
 411                 return FallbackPlayerModel;
 412         if( substring(plyermodel,0,14) != "models/player/")
 413                 return FallbackPlayerModel;
 414         else if(autocvar_sv_servermodelsonly)
 415         {
 416                 if(substring(plyermodel,-4,4) != ".zym")
 417                 if(substring(plyermodel,-4,4) != ".dpm")
 418                 if(substring(plyermodel,-4,4) != ".iqm")
 419                 if(substring(plyermodel,-4,4) != ".md3")
 420                 if(substring(plyermodel,-4,4) != ".psk")
 421                         return FallbackPlayerModel;
 422                 // forbid the LOD models
 423                 if(substring(plyermodel, -9,5) == "_lod1")
 424                         return FallbackPlayerModel;
 425                 if(substring(plyermodel, -9,5) == "_lod2")
 426                         return FallbackPlayerModel;
 427                 if(plyermodel != strtolower(plyermodel))
 428                         return FallbackPlayerModel;
 429                 if(!fexists(plyermodel))
 430                         return FallbackPlayerModel;
 431         }
 432         return plyermodel;
 433 }
 434
 435 /*
 436 =============
 437 Client_customizeentityforclient
 438
 439 LOD reduction
 440 =============
 441 */
 442 void Client_uncustomizeentityforclient()
 443 {
 444         if(self.modelindex == 0) // no need to uncustomize then
 445                 return;
 446         self.modelindex = self.modelindex_lod0;
 447         self.skin = self.skinindex;
 448 }
 449
 450 float Client_customizeentityforclient()
 451 {
 452         entity modelsource;
 453
 454         if(self.modelindex == 0)
 455                 return TRUE;
 456
 457         // forcemodel stuff
 458
 459 #ifdef PROFILING
 460         float t0;
 461         t0 = gettime(GETTIME_HIRES); // reference
 462 #endif
 463
 464         modelsource = self;
 465
 466 #ifdef ALLOW_FORCEMODELS
 467         if(other.cvar_cl_forceplayermodelsfromxonotic)
 468                 if not(self.modelindex_lod0_from_xonotic)
 469                         modelsource = other;
 470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 471                 modelsource = other;
 472 #endif
 473
 474         self.skin = modelsource.skinindex;
 475
 476 #if 0
 477         if(modelsource == self)
 478                 self.skin = modelsource.skinindex;
 479         else
 480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 481 #endif
 482
 483         // self: me
 484         // other: the player viewing me
 485         float distance;
 486         float f;
 487
 488         if(other.cvar_cl_playerdetailreduction <= 0)
 489         {
 490                 if(other.cvar_cl_playerdetailreduction <= -2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(other.cvar_cl_playerdetailreduction <= -1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497         else
 498         {
 499                 distance = vlen(self.origin - other.origin);
 500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 501                 if(f > sv_loddistance2)
 502                         self.modelindex = modelsource.modelindex_lod2;
 503                 else if(f > sv_loddistance1)
 504                         self.modelindex = modelsource.modelindex_lod1;
 505                 else
 506                         self.modelindex = modelsource.modelindex_lod0;
 507         }
 508
 509 #ifdef PROFILING
 510         float t1;
 511         t1 = gettime(GETTIME_HIRES); // reference
 512         client_cefc_accumulator += (t1 - t0);
 513 #endif
 514
 515         return TRUE;
 516 }
 517
 518 void setmodel_lod(entity e, string modelname)
 519 {
 520         string s;
 521
 522         if(sv_loddistance1)
 523         {
 524                 // FIXME: this only supports 3-letter extensions
 525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 526                 if(fexists(s))
 527                 {
 528                         setmodel(e, s); // players have high precision
 529                         self.modelindex_lod1 = self.modelindex;
 530                 }
 531                 else
 532                         self.modelindex_lod1 = -1;
 533
 534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 535                 if(fexists(s))
 536                 {
 537                         setmodel(e, s); // players have high precision
 538                         self.modelindex_lod2 = self.modelindex;
 539                 }
 540                 else
 541                         self.modelindex_lod2 = -1;
 542
 543                 precache_model(modelname);
 544                 setmodel(e, modelname); // players have high precision
 545                 self.modelindex_lod0 = self.modelindex;
 546
 547                 if(self.modelindex_lod1 < 0)
 548                         self.modelindex_lod1 = self.modelindex;
 549
 550                 if(self.modelindex_lod2 < 0)
 551                         self.modelindex_lod2 = self.modelindex;
 552         }
 553         else
 554         {
 555                 precache_model(modelname);
 556                 setmodel(e, modelname); // players have high precision
 557                 self.modelindex_lod0 = self.modelindex;
 558                         // save it for possible player model forcing
 559         }
 560
 561         s = whichpack(self.model);
 562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 563
 564         player_setupanimsformodel();
 565         UpdatePlayerSounds();
 566 }
 567
 568 /*
 569 =============
 570 PutObserverInServer
 571
 572 putting a client as observer in the server
 573 =============
 574 */
 575 void FixPlayermodel();
 576 void PutObserverInServer (void)
 577 {
 578         entity  spot;
 579
 580         race_PreSpawnObserver();
 581
 582         spot = SelectSpawnPoint (TRUE);
 583         if(!spot)
 584                 error("No spawnpoints for observers?!?\n");
 585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 586
 587         if(clienttype(self) == CLIENTTYPE_REAL)
 588         {
 589                 msg_entity = self;
 590                 WriteByte(MSG_ONE, SVC_SETVIEW);
 591                 WriteEntity(MSG_ONE, self);
 592         }
 593
 594         DropAllRunes(self);
 595         MUTATOR_CALLHOOK(MakePlayerObserver);
 596
 597         Portal_ClearAll(self);
 598
 599         if(self.alivetime)
 600         {
 601                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 602                 self.alivetime = 0;
 603         }
 604
 605         if(self.flagcarried)
 606                 DropFlag(self.flagcarried, world, world);
 607
 608         if(self.ballcarried && g_nexball)
 609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 610
 611         WaypointSprite_PlayerDead();
 612
 613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 615
 616         if(self.killcount != -666) {
 617                 if(g_lms) {
 618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 620                         else
 621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 622                 } else
 623                         bprint ("^4", self.netname, "^4 is spectating now\n");
 624
 625                 if(self.just_joined == FALSE) {
 626                         LogTeamchange(self.playerid, -1, 4);
 627                 } else
 628                         self.just_joined = FALSE;
 629         }
 630
 631         PlayerScore_Clear(self); // clear scores when needed
 632
 633         accuracy_resend(self);
 634
 635         self.spectatortime = time;
 636
 637         self.classname = "observer";
 638         self.iscreature = FALSE;
 639         self.health = -666;
 640         self.takedamage = DAMAGE_NO;
 641         self.solid = SOLID_NOT;
 642         self.movetype = MOVETYPE_NOCLIP;
 643         self.flags = FL_CLIENT | FL_NOTARGET;
 644         self.armorvalue = 666;
 645         self.effects = 0;
 646         self.armorvalue = autocvar_g_balance_armor_start;
 647         self.pauserotarmor_finished = 0;
 648         self.pauserothealth_finished = 0;
 649         self.pauseregen_finished = 0;
 650         self.damageforcescale = 0;
 651         self.death_time = 0;
 652         self.dead_frame = 0;
 653         self.alpha = 0;
 654         self.scale = 0;
 655         self.fade_time = 0;
 656         self.pain_frame = 0;
 657         self.pain_finished = 0;
 658         self.strength_finished = 0;
 659         self.invincible_finished = 0;
 660         self.pushltime = 0;
 661         self.think = SUB_Null;
 662         self.nextthink = 0;
 663         self.hook_time = 0;
 664         self.runes = 0;
 665         self.deadflag = DEAD_NO;
 666         self.angles = spot.angles;
 667         self.angles_z = 0;
 668         self.fixangle = TRUE;
 669         self.crouch = FALSE;
 670
 671         self.view_ofs = PL_VIEW_OFS;
 672         setorigin (self, spot.origin);
 673         setsize (self, '0 0 0', '0 0 0');
 674         self.prevorigin = self.origin;
 675         self.items = 0;
 676         self.weapons = 0;
 677         self.model = "";
 678         FixPlayermodel();
 679         self.model = "";
 680         self.modelindex = 0;
 681         self.weapon = 0;
 682         self.weaponmodel = "";
 683         self.weaponentity = world;
 684         self.exteriorweaponentity = world;
 685         self.killcount = -666;
 686         self.velocity = '0 0 0';
 687         self.avelocity = '0 0 0';
 688         self.punchangle = '0 0 0';
 689         self.punchvector = '0 0 0';
 690         self.oldvelocity = self.velocity;
 691         self.fire_endtime = -1;
 692
 693         if(sv_loddistance1)
 694                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 695
 696         if(g_arena)
 697         {
 698                 if(self.version_mismatch)
 699                 {
 700                         Spawnqueue_Unmark(self);
 701                         Spawnqueue_Remove(self);
 702                 }
 703                 else
 704                 {
 705                         Spawnqueue_Insert(self);
 706                 }
 707         }
 708         else if(g_lms)
 709         {
 710                 // Only if the player cannot play at all
 711                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 712                         self.frags = FRAGS_SPECTATOR;
 713                 else
 714                         self.frags = FRAGS_LMS_LOSER;
 715         }
 716         else
 717                 self.frags = FRAGS_SPECTATOR;
 718 }
 719
 720 void FixPlayermodel()
 721 {
 722         local string defaultmodel;
 723         local float defaultskin, chmdl, oldskin;
 724         local vector m1, m2;
 725
 726         defaultmodel = "";
 727
 728         if(autocvar_sv_defaultcharacter == 1) {
 729                 defaultskin = 0;
 730
 731                 if(teams_matter)
 732                 {
 733                         string s;
 734                         s = Team_ColorNameLowerCase(self.team);
 735                         if(s != "neutral")
 736                         {
 737                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 738                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 739                         }
 740                 }
 741
 742                 if(defaultmodel == "")
 743                 {
 744                         defaultmodel = autocvar_sv_defaultplayermodel;
 745                         defaultskin = autocvar_sv_defaultplayerskin;
 746                 }
 747         }
 748
 749         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 750         {
 751                 if(self.model != "")
 752                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 753                 self.model = ""; // force the != checks to return true
 754         }
 755
 756         if(defaultmodel != "")
 757         {
 758                 if (defaultmodel != self.model)
 759                 {
 760                         m1 = self.mins;
 761                         m2 = self.maxs;
 762                         setmodel_lod (self, defaultmodel);
 763                         setsize (self, m1, m2);
 764                         chmdl = TRUE;
 765                 }
 766
 767                 oldskin = self.skinindex;
 768                 self.skinindex = defaultskin;
 769         } else {
 770                 if (self.playermodel != self.model || self.playermodel == "")
 771                 {
 772                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 773                         m1 = self.mins;
 774                         m2 = self.maxs;
 775                         setmodel_lod (self, self.playermodel);
 776                         setsize (self, m1, m2);
 777                         chmdl = TRUE;
 778                 }
 779
 780                 oldskin = self.skinindex;
 781                 self.skinindex = stof(self.playerskin);
 782         }
 783
 784         if(chmdl || oldskin != self.skinindex)
 785                 self.species = player_getspecies(); // model or skin has changed
 786
 787         if(!teams_matter)
 788                 if(strlen(autocvar_sv_defaultplayercolors))
 789                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 790                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 791 }
 792
 793 void PlayerTouchExplode(entity p1, entity p2)
 794 {
 795         vector org;
 796         org = (p1.origin + p2.origin) * 0.5;
 797         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 798
 799         te_explosion(org);
 800
 801         entity e;
 802         e = spawn();
 803         setorigin(e, org);
 804         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 805         remove(e);
 806 }
 807
 808 /*
 809 =============
 810 PutClientInServer
 811
 812 Called when a client spawns in the server
 813 =============
 814 */
 815 //void() ctf_playerchanged;
 816 void PutClientInServer (void)
 817 {
 818         if(clienttype(self) == CLIENTTYPE_BOT)
 819         {
 820                 self.classname = "player";
 821         }
 822         else if(clienttype(self) == CLIENTTYPE_REAL)
 823         {
 824                 msg_entity = self;
 825                 WriteByte(MSG_ONE, SVC_SETVIEW);
 826                 WriteEntity(MSG_ONE, self);
 827         }
 828
 829         // player is dead and becomes observer
 830         // FIXME fix LMS scoring for new system
 831         if(g_lms)
 832         {
 833                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 834                         self.classname = "observer";
 835         }
 836
 837         if(g_arena || (g_ca && !allowed_to_spawn))
 838         if(!self.spawned)
 839                 self.classname = "observer";
 840
 841         if(gameover)
 842                 self.classname = "observer";
 843
 844         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 845                 entity spot, oldself;
 846                 float j;
 847
 848                 accuracy_resend(self);
 849
 850                 if(self.team < 0)
 851                         JoinBestTeam(self, FALSE, TRUE);
 852
 853                 race_PreSpawn();
 854
 855                 spot = SelectSpawnPoint (FALSE);
 856                 if(!spot)
 857                 {
 858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 859                         return; // spawn failed
 860                 }
 861
 862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 863
 864                 self.classname = "player";
 865                 self.wasplayer = TRUE;
 866                 self.iscreature = TRUE;
 867                 self.movetype = MOVETYPE_WALK;
 868                 self.solid = SOLID_SLIDEBOX;
 869                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 870                 if(autocvar_g_playerclip_collisions)
 871                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 872                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 873                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 874                 self.frags = FRAGS_PLAYER;
 875                 if(independent_players)
 876                         MAKE_INDEPENDENT_PLAYER(self);
 877                 self.flags = FL_CLIENT;
 878                 self.takedamage = DAMAGE_AIM;
 879                 if(g_minstagib)
 880                         self.effects = EF_FULLBRIGHT;
 881                 else
 882                         self.effects = 0;
 883                 self.air_finished = time + 12;
 884                 self.dmg = 2;
 885                 if(autocvar_g_balance_nex_charge)
 886                 {
 887                         if(autocvar_g_balance_nex_secondary_chargepool)
 888                                 self.nex_chargepool_ammo = 1;
 889                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 890                 }
 891
 892                 if(inWarmupStage)
 893                 {
 894                         self.ammo_shells = warmup_start_ammo_shells;
 895                         self.ammo_nails = warmup_start_ammo_nails;
 896                         self.ammo_rockets = warmup_start_ammo_rockets;
 897                         self.ammo_cells = warmup_start_ammo_cells;
 898                         self.ammo_fuel = warmup_start_ammo_fuel;
 899                         self.health = warmup_start_health;
 900                         self.armorvalue = warmup_start_armorvalue;
 901                         self.weapons = warmup_start_weapons;
 902                 }
 903                 else
 904                 {
 905                         self.ammo_shells = start_ammo_shells;
 906                         self.ammo_nails = start_ammo_nails;
 907                         self.ammo_rockets = start_ammo_rockets;
 908                         self.ammo_cells = start_ammo_cells;
 909                         self.ammo_fuel = start_ammo_fuel;
 910                         self.health = start_health;
 911                         self.armorvalue = start_armorvalue;
 912                         self.weapons = start_weapons;
 913                 }
 914
 915                 if(g_weaponarena_random)
 916                 {
 917                         if(g_weaponarena_random_with_laser)
 918                                 self.weapons &~= WEPBIT_LASER;
 919                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 920                         if(g_weaponarena_random_with_laser)
 921                                 self.weapons |= WEPBIT_LASER;
 922                 }
 923
 924                 self.items = start_items;
 925                 self.jump_interval = time;
 926
 927                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 928                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 929                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 930                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 931                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 932                 //extend the pause of rotting if client was reset at the beginning of the countdown
 933                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 934                         self.spawnshieldtime += game_starttime - time;
 935                         self.pauserotarmor_finished += game_starttime - time;
 936                         self.pauserothealth_finished += game_starttime - time;
 937                         self.pauseregen_finished += game_starttime - time;
 938                 }
 939                 self.damageforcescale = 2;
 940                 self.death_time = 0;
 941                 self.dead_frame = 0;
 942                 self.alpha = 0;
 943                 self.scale = 0;
 944                 self.fade_time = 0;
 945                 self.pain_frame = 0;
 946                 self.pain_finished = 0;
 947                 self.strength_finished = 0;
 948                 self.invincible_finished = 0;
 949                 self.pushltime = 0;
 950                 // players have no think function
 951                 self.think = SUB_Null;
 952                 self.nextthink = 0;
 953                 self.hook_time = 0;
 954                 self.dmg_team = 0;
 955                 self.ballistics_density = autocvar_g_ballistics_density_player;
 956
 957                 self.metertime = 0;
 958
 959                 self.runes = 0;
 960
 961                 self.deadflag = DEAD_NO;
 962
 963                 self.angles = spot.angles;
 964
 965                 self.angles_z = 0; // never spawn tilted even if the spot says to
 966                 self.fixangle = TRUE; // turn this way immediately
 967                 self.velocity = '0 0 0';
 968                 self.avelocity = '0 0 0';
 969                 self.punchangle = '0 0 0';
 970                 self.punchvector = '0 0 0';
 971                 self.oldvelocity = self.velocity;
 972                 self.fire_endtime = -1;
 973
 974                 msg_entity = self;
 975                 WRITESPECTATABLE_MSG_ONE({
 976                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 977                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 978                 });
 979
 980                 if(sv_loddistance1)
 981                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 982
 983                 self.model = "";
 984                 FixPlayermodel();
 985
 986                 self.crouch = FALSE;
 987                 self.view_ofs = PL_VIEW_OFS;
 988                 setsize (self, PL_MIN, PL_MAX);
 989                 self.spawnorigin = spot.origin;
 990                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 991                 // don't reset back to last position, even if new position is stuck in solid
 992                 self.oldorigin = self.origin;
 993                 self.prevorigin = self.origin;
 994                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 995
 996                 if(g_arena)
 997                 {
 998                         Spawnqueue_Remove(self);
 999                         Spawnqueue_Mark(self);
1000                 }
1001
1002                 else if(g_ca)
1003                         self.caplayer = 1;
1004
1005                 self.event_damage = PlayerDamage;
1006
1007                 self.bot_attack = TRUE;
1008
1009                 self.statdraintime = time + 5;
1010                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1011
1012                 if(self.killcount == -666) {
1013                         PlayerScore_Clear(self);
1014                         self.killcount = 0;
1015                 }
1016
1017                 self.cnt = WEP_LASER;
1018
1019                 CL_SpawnWeaponentity();
1020                 self.alpha = default_player_alpha;
1021                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1022                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1023
1024                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1025                 self.lms_traveled_distance = 0;
1026                 self.speedrunning = FALSE;
1027
1028                 race_PostSpawn(spot);
1029
1030                 if(autocvar_spawn_debug)
1031                 {
1032                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1033                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1034                 }
1035
1036                 //stuffcmd(self, "chase_active 0");
1037                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1038
1039                 if (autocvar_g_spawnsound)
1040                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1041
1042                 if(g_assault) {
1043                         if(self.team == assault_attacker_team)
1044                                 centerprint(self, "You are attacking!");
1045                         else
1046                                 centerprint(self, "You are defending!");
1047                 }
1048
1049                 target_voicescript_clear(self);
1050
1051                 // reset fields the weapons may use
1052                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1053                 {
1054                         weapon_action(j, WR_RESETPLAYER);
1055
1056                         // all weapons must be fully loaded when we spawn
1057                         entity e;
1058                         e = get_weaponinfo(j);
1059                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1060                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1061                 }
1062
1063                 oldself = self;
1064                 self = spot;
1065                         activator = oldself;
1066                                 SUB_UseTargets();
1067                         activator = world;
1068                 self = oldself;
1069
1070                 MUTATOR_CALLHOOK(PlayerSpawn);
1071
1072                 self.switchweapon = w_getbestweapon(self);
1073                 self.cnt = self.switchweapon;
1074                 self.weapon = 0;
1075
1076                 if(!self.alivetime)
1077                         self.alivetime = time;
1078         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1079                 PutObserverInServer ();
1080         }
1081
1082         //if(g_ctf)
1083         //      ctf_playerchanged();
1084 }
1085
1086 .float ebouncefactor, ebouncestop; // electro's values
1087 // TODO do we need all these fields, or should we stop autodetecting runtime
1088 // changes and just have a console command to update this?
1089 float ClientInit_SendEntity(entity to, float sf)
1090 {
1091         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1092         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1093         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1094         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1095         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1096         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1097         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1098         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1099         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1100         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1105         if(sv_foginterval && world.fog != "")
1106                 WriteString(MSG_ENTITY, world.fog);
1107         else
1108                 WriteString(MSG_ENTITY, "");
1109         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1110         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1111         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1112         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1113         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1114         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1115         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1116         WriteByte(MSG_ENTITY, autocvar_g_balance_sniperrifle_secondary); // client has to know if it should zoom or not
1117         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1118         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1119         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1120         return TRUE;
1121 }
1122
1123 void ClientInit_CheckUpdate()
1124 {
1125         self.nextthink = time;
1126         if(self.count != autocvar_g_balance_armor_blockpercent)
1127         {
1128                 self.count = autocvar_g_balance_armor_blockpercent;
1129                 self.SendFlags |= 1;
1130         }
1131         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1132         {
1133                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1134                 self.SendFlags |= 1;
1135         }
1136         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1137         {
1138                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1139                 self.SendFlags |= 1;
1140         }
1141         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1142         {
1143                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1144                 self.SendFlags |= 1;
1145         }
1146         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1147         {
1148                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1149                 self.SendFlags |= 1;
1150         }
1151         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1152         {
1153                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1154                 self.SendFlags |= 1;
1155         }
1156 }
1157
1158 void ClientInit_Spawn()
1159 {
1160         entity o;
1161         entity e;
1162         e = spawn();
1163         e.classname = "clientinit";
1164         e.think = ClientInit_CheckUpdate;
1165         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1166
1167         o = self;
1168         self = e;
1169         ClientInit_CheckUpdate();
1170         self = o;
1171 }
1172
1173 /*
1174 =============
1175 SetNewParms
1176 =============
1177 */
1178 void SetNewParms (void)
1179 {
1180         // initialize parms for a new player
1181         parm1 = -(86400 * 366);
1182 }
1183
1184 /*
1185 =============
1186 SetChangeParms
1187 =============
1188 */
1189 void SetChangeParms (void)
1190 {
1191         // save parms for level change
1192         parm1 = self.parm_idlesince - time;
1193 }
1194
1195 /*
1196 =============
1197 DecodeLevelParms
1198 =============
1199 */
1200 void DecodeLevelParms (void)
1201 {
1202         // load parms
1203         self.parm_idlesince = parm1;
1204         if(self.parm_idlesince == -(86400 * 366))
1205                 self.parm_idlesince = time;
1206
1207         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1208         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1209 }
1210
1211 /*
1212 =============
1213 ClientKill
1214
1215 Called when a client types 'kill' in the console
1216 =============
1217 */
1218
1219 .float clientkill_nexttime;
1220 void ClientKill_Now_TeamChange()
1221 {
1222         if(self.killindicator_teamchange == -1)
1223         {
1224                 self.team = -1;
1225                 JoinBestTeam( self, FALSE, FALSE );
1226         }
1227         else if(self.killindicator_teamchange == -2)
1228         {
1229                 if(g_ca)
1230                         self.caplayer = 0;
1231                 if(blockSpectators)
1232                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1233                 PutObserverInServer();
1234         }
1235         else
1236                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1237 }
1238
1239 void ClientKill_Now()
1240 {
1241         remove(self.killindicator);
1242         self.killindicator = world;
1243
1244         if(self.killindicator_teamchange)
1245                 ClientKill_Now_TeamChange();
1246
1247         // in any case:
1248         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1249
1250         // now I am sure the player IS dead
1251 }
1252 void KillIndicator_Think()
1253 {
1254         if (!self.owner.modelindex)
1255         {
1256                 self.owner.killindicator = world;
1257                 remove(self);
1258                 return;
1259         }
1260
1261         if(self.cnt <= 0)
1262         {
1263                 self = self.owner;
1264                 ClientKill_Now(); // no oldself needed
1265                 return;
1266         }
1267     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1268     {
1269         self.nextthink = time + 1;
1270         self.cnt -= 1;
1271     }
1272         else
1273         {
1274                 if(self.cnt <= 10)
1275                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1276                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1277                 {
1278                         if(self.cnt <= 10)
1279                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1280                         if(self.owner.killindicator_teamchange)
1281                         {
1282                                 if(self.owner.killindicator_teamchange == -1)
1283                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1284                                 else if(self.owner.killindicator_teamchange == -2)
1285                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1286                                 else
1287                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1288                         }
1289                         else
1290                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1291                 }
1292                 self.nextthink = time + 1;
1293                 self.cnt -= 1;
1294         }
1295 }
1296
1297 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1298 {
1299         float killtime;
1300         entity e;
1301         killtime = autocvar_g_balance_kill_delay;
1302
1303         if(g_race_qualifying || g_cts)
1304                 killtime = 0;
1305
1306     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1307     {
1308                 remove(self.killindicator);
1309                 self.killindicator = world;
1310
1311         ClientKill_Now(); // allow instant kill in this case
1312         return;
1313     }
1314
1315         self.killindicator_teamchange = targetteam;
1316
1317     if(!self.killindicator)
1318         {
1319                 if(self.modelindex && self.deadflag == DEAD_NO)
1320                 {
1321                         killtime = max(killtime, self.clientkill_nexttime - time);
1322                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1323                 }
1324
1325                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1326                 {
1327                         ClientKill_Now();
1328                 }
1329                 else
1330                 {
1331                         self.killindicator = spawn();
1332                         self.killindicator.owner = self;
1333                         self.killindicator.scale = 0.5;
1334                         setattachment(self.killindicator, self, "");
1335                         setorigin(self.killindicator, '0 0 52');
1336                         self.killindicator.think = KillIndicator_Think;
1337                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1338                         self.killindicator.cnt = ceil(killtime);
1339                         self.killindicator.count = bound(0, ceil(killtime), 10);
1340                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1341
1342                         for(e = world; (e = find(e, classname, "body")) != world; )
1343                         {
1344                                 if(e.enemy != self)
1345                                         continue;
1346                                 e.killindicator = spawn();
1347                                 e.killindicator.owner = e;
1348                                 e.killindicator.scale = 0.5;
1349                                 setattachment(e.killindicator, e, "");
1350                                 setorigin(e.killindicator, '0 0 52');
1351                                 e.killindicator.think = KillIndicator_Think;
1352                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1353                                 e.killindicator.cnt = ceil(killtime);
1354                         }
1355                         self.lip = 0;
1356                 }
1357         }
1358         if(self.killindicator)
1359         {
1360                 if(targetteam == 0) // just die
1361                         self.killindicator.colormod = '0 0 0';
1362                 else if(targetteam == -1) // auto
1363                         self.killindicator.colormod = '0 1 0';
1364                 else if(targetteam == -2) // spectate
1365                         self.killindicator.colormod = '0.5 0.5 0.5';
1366                 else
1367                         self.killindicator.colormod = TeamColor(targetteam);
1368         }
1369 }
1370
1371 void ClientKill (void)
1372 {
1373         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1374         {
1375                 // do nothing
1376         }
1377     else if(self.freezetag_frozen)
1378     {
1379         // do nothing
1380     }
1381         else
1382                 ClientKill_TeamChange(0);
1383 }
1384
1385 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1386 {
1387     e.killindicator = spawn();
1388     e.killindicator.owner = e;
1389     e.killindicator.think = KillIndicator_Think;
1390     e.killindicator.nextthink = time + (e.lip) * 0.05;
1391     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1392     e.killindicator.health = 1; // this is used to indicate that it should be silent
1393     e.lip = 0;
1394 }
1395
1396 void DoTeamChange(float destteam)
1397 {
1398         float t, c0;
1399         if(!teams_matter)
1400         {
1401                 if(destteam >= 0)
1402                         SetPlayerColors(self, destteam);
1403                 return;
1404         }
1405         if(self.classname == "player")
1406         if(destteam == -1)
1407         {
1408                 CheckAllowedTeams(self);
1409                 t = FindSmallestTeam(self, TRUE);
1410                 switch(self.team)
1411                 {
1412                         case COLOR_TEAM1: c0 = c1; break;
1413                         case COLOR_TEAM2: c0 = c2; break;
1414                         case COLOR_TEAM3: c0 = c3; break;
1415                         case COLOR_TEAM4: c0 = c4; break;
1416                         default:          c0 = 999;
1417                 }
1418                 switch(t)
1419                 {
1420                         case 1:
1421                                 if(c0 > c1)
1422                                         destteam = COLOR_TEAM1;
1423                                 break;
1424                         case 2:
1425                                 if(c0 > c2)
1426                                         destteam = COLOR_TEAM2;
1427                                 break;
1428                         case 3:
1429                                 if(c0 > c3)
1430                                         destteam = COLOR_TEAM3;
1431                                 break;
1432                         case 4:
1433                                 if(c0 > c4)
1434                                         destteam = COLOR_TEAM4;
1435                                 break;
1436                 }
1437                 if(destteam == -1)
1438                         return;
1439         }
1440         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1441                 return;
1442         ClientKill_TeamChange(destteam);
1443 }
1444
1445 void FixClientCvars(entity e)
1446 {
1447         // send prediction settings to the client
1448         stuffcmd(e, "\nin_bindmap 0 0\n");
1449         if(g_race || g_cts)
1450                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1451         if(autocvar_g_antilag == 3) // client side hitscan
1452                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1453         if(sv_gentle)
1454                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1455         /*
1456          * we no longer need to stuff this. Remove this comment block if you feel
1457          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1458         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1459         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1460         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1461         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1462         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1463         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1464         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1465         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1466         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1467         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1468         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1469         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1470         stuffcmd(e, "cl_movement_edgefriction 1\n");
1471          */
1472 }
1473
1474 float PlayerInIDList(entity p, string idlist)
1475 {
1476         float n, i;
1477         string s;
1478
1479         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1480         if not(p.crypto_idfp)
1481                 return 0;
1482
1483         // this function allows abbreviated player IDs too!
1484         n = tokenize_console(idlist);
1485         for(i = 0; i < n; ++i)
1486         {
1487                 s = argv(i);
1488                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1489                         return 1;
1490         }
1491
1492         return 0;
1493 }
1494
1495 /*
1496 =============
1497 ClientConnect
1498
1499 Called when a client connects to the server
1500 =============
1501 */
1502 //void ctf_clientconnect();
1503 string ColoredTeamName(float t);
1504 void DecodeLevelParms (void);
1505 //void dom_player_join_team(entity pl);
1506 void ClientConnect (void)
1507 {
1508         float t;
1509
1510         if(self.flags & FL_CLIENT)
1511         {
1512                 print("Warning: ClientConnect, but already connected!\n");
1513                 return;
1514         }
1515
1516         if(Ban_MaybeEnforceBan(self))
1517                 return;
1518
1519         DecodeLevelParms();
1520
1521 #ifdef WATERMARK
1522         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1523 #endif
1524
1525         self.classname = "player_joining";
1526
1527         self.flags = FL_CLIENT;
1528         self.version_nagtime = time + 10 + random() * 10;
1529
1530         if(player_count<0)
1531         {
1532                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1533                 player_count = 0;
1534         }
1535
1536         PlayerScore_Attach(self);
1537         ClientData_Attach();
1538         accuracy_init(self);
1539
1540         bot_clientconnect();
1541
1542         playerdemo_init();
1543
1544         anticheat_init();
1545
1546         race_PreSpawnObserver();
1547
1548         //if(g_domination)
1549         //      dom_player_join_team(self);
1550
1551         // identify the right forced team
1552         if(autocvar_g_campaign)
1553         {
1554                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1555                 {
1556                         switch(autocvar_g_campaign_forceteam)
1557                         {
1558                                 case 1: self.team_forced = COLOR_TEAM1; break;
1559                                 case 2: self.team_forced = COLOR_TEAM2; break;
1560                                 case 3: self.team_forced = COLOR_TEAM3; break;
1561                                 case 4: self.team_forced = COLOR_TEAM4; break;
1562                                 default: self.team_forced = 0;
1563                         }
1564                 }
1565         }
1566         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1567                 self.team_forced = COLOR_TEAM1;
1568         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1569                 self.team_forced = COLOR_TEAM2;
1570         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1571                 self.team_forced = COLOR_TEAM3;
1572         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1573                 self.team_forced = COLOR_TEAM4;
1574         else if(autocvar_g_forced_team_otherwise == "red")
1575                 self.team_forced = COLOR_TEAM1;
1576         else if(autocvar_g_forced_team_otherwise == "blue")
1577                 self.team_forced = COLOR_TEAM2;
1578         else if(autocvar_g_forced_team_otherwise == "yellow")
1579                 self.team_forced = COLOR_TEAM3;
1580         else if(autocvar_g_forced_team_otherwise == "pink")
1581                 self.team_forced = COLOR_TEAM4;
1582         else if(autocvar_g_forced_team_otherwise == "spectate")
1583                 self.team_forced = -1;
1584         else if(autocvar_g_forced_team_otherwise == "spectator")
1585                 self.team_forced = -1;
1586         else
1587                 self.team_forced = 0;
1588
1589         if(!teams_matter)
1590                 if(self.team_forced > 0)
1591                         self.team_forced = 0;
1592
1593         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1594
1595         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1596                 self.classname = "observer";
1597         } else {
1598                 if(teams_matter)
1599                 {
1600                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1601                         {
1602                                 self.classname = "player";
1603                                 campaign_bots_may_start = 1;
1604                         }
1605                         else
1606                         {
1607                                 self.classname = "observer"; // do it anyway
1608                         }
1609                 }
1610                 else
1611                 {
1612                         self.classname = "player";
1613                         campaign_bots_may_start = 1;
1614                 }
1615         }
1616
1617         self.playerid = (playerid_last = playerid_last + 1);
1618
1619         if(autocvar_sv_eventlog)
1620                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1621
1622         LogTeamchange(self.playerid, self.team, 1);
1623
1624         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1625
1626         self.netname_previous = strzone(self.netname);
1627
1628         bprint("^4", self.netname, "^4 connected");
1629
1630         if(self.classname != "observer" && (g_domination || g_ctf))
1631                 bprint(" and joined the ", ColoredTeamName(self.team));
1632
1633         bprint("\n");
1634
1635         self.welcomemessage_time = 0;
1636
1637         stuffcmd(self, strcat(clientstuff, "\n"));
1638         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1639         stuffcmd(self, "cl_particles_reloadeffects\n");
1640
1641         FixClientCvars(self);
1642
1643         // spawnfunc_waypoint sprites
1644         WaypointSprite_InitClient(self);
1645
1646         // Wazat's grappling hook
1647         SetGrappleHookBindings();
1648
1649         // get autoswitch state from player when he toggles it
1650         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1651
1652         // get version info from player
1653         stuffcmd(self, "cmd clientversion $gameversion\n");
1654
1655         // get other cvars from player
1656         GetCvars(0);
1657
1658         // notify about available teams
1659         if(teams_matter)
1660         {
1661                 CheckAllowedTeams(self);
1662                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1663                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1664         }
1665         else
1666                 stuffcmd(self, "set _teams_available 0\n");
1667
1668         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1669
1670         if(g_arena || g_ca)
1671         {
1672                 self.classname = "observer";
1673                 if(g_arena)
1674                         Spawnqueue_Insert(self);
1675         }
1676         /*else if(g_ctf)
1677         {
1678                 ctf_clientconnect();
1679         }*/
1680
1681         if(teams_matter || radar_showennemies)
1682                 attach_entcs();
1683
1684         bot_relinkplayerlist();
1685
1686         self.spectatortime = time;
1687         if(blockSpectators)
1688         {
1689                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1690         }
1691
1692         self.jointime = time;
1693         self.allowedTimeouts = autocvar_sv_timeout_number;
1694
1695         if(clienttype(self) == CLIENTTYPE_REAL)
1696         {
1697                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1698                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1699         }
1700
1701         if(g_lms)
1702         {
1703                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1704                 {
1705                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1706                         self.frags = FRAGS_SPECTATOR;
1707                 }
1708         }
1709
1710         if(!sv_foginterval && world.fog != "")
1711                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1712
1713         SoundEntity_Attach(self);
1714
1715         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1716         {
1717                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1718                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1719         }
1720         else
1721                 self.hitplotfh = -1;
1722
1723         if(g_race || g_cts) {
1724                 string rr;
1725                 if(g_cts)
1726                         rr = CTS_RECORD;
1727                 else
1728                         rr = RACE_RECORD;
1729                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1730
1731                 msg_entity = self;
1732                 race_send_recordtime(MSG_ONE);
1733                 race_send_speedaward(MSG_ONE);
1734
1735                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1736                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1737                 race_send_speedaward_alltimebest(MSG_ONE);
1738
1739                 float i;
1740                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1741                         race_SendRankings(i, 0, 0, MSG_ONE);
1742                 }
1743         }
1744         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1745                 send_CSQC_teamnagger();
1746
1747         CheatInitClient();
1748
1749         PlayerStats_AddPlayer(self);
1750 }
1751
1752 /*
1753 =============
1754 ClientDisconnect
1755
1756 Called when a client disconnects from the server
1757 =============
1758 */
1759 .entity chatbubbleentity;
1760 .entity teambubbleentity;
1761 void ReadyCount();
1762 void ClientDisconnect (void)
1763 {
1764         if(self.vehicle)
1765         {
1766             entity oldself;
1767             oldself = self;
1768             self = self.vehicle;
1769             self.vehicle_exit(VHEF_RELESE);
1770             self = oldself;
1771         }
1772
1773         if not(self.flags & FL_CLIENT)
1774         {
1775                 print("Warning: ClientDisconnect without ClientConnect\n");
1776                 return;
1777         }
1778
1779         PlayerStats_AddGlobalInfo(self);
1780
1781         CheatShutdownClient();
1782
1783         if(self.hitplotfh >= 0)
1784         {
1785                 fclose(self.hitplotfh);
1786                 self.hitplotfh = -1;
1787         }
1788
1789         anticheat_report();
1790         anticheat_shutdown();
1791
1792         playerdemo_shutdown();
1793
1794         bot_clientdisconnect();
1795
1796         if(self.entcs)
1797                 detach_entcs();
1798
1799         if(autocvar_sv_eventlog)
1800                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1801         bprint ("^4",self.netname);
1802         bprint ("^4 disconnected\n");
1803
1804         SoundEntity_Detach(self);
1805
1806         DropAllRunes(self);
1807         MUTATOR_CALLHOOK(ClientDisconnect);
1808
1809         Portal_ClearAll(self);
1810
1811         if(self.flagcarried)
1812                 DropFlag(self.flagcarried, world, world);
1813         if(self.ballcarried && g_nexball)
1814                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1815
1816         // Here, everything has been done that requires this player to be a client.
1817
1818         self.flags &~= FL_CLIENT;
1819
1820         if (self.chatbubbleentity)
1821                 remove (self.chatbubbleentity);
1822
1823         if (self.teambubbleentity)
1824                 remove (self.teambubbleentity);
1825
1826         if (self.killindicator)
1827                 remove (self.killindicator);
1828
1829         WaypointSprite_PlayerGone();
1830
1831         bot_relinkplayerlist();
1832
1833         if(g_arena)
1834         {
1835                 Spawnqueue_Unmark(self);
1836                 Spawnqueue_Remove(self);
1837         }
1838
1839         accuracy_free(self);
1840         ClientData_Detach();
1841         PlayerScore_Detach(self);
1842
1843         if(self.netname_previous)
1844                 strunzone(self.netname_previous);
1845         if(self.clientstatus)
1846                 strunzone(self.clientstatus);
1847         if(self.weaponorder_byimpulse)
1848                 strunzone(self.weaponorder_byimpulse);
1849
1850         ClearPlayerSounds();
1851
1852         if(self.personal)
1853                 remove(self.personal);
1854
1855         self.playerid = 0;
1856         ReadyCount();
1857
1858         // free cvars
1859         GetCvars(-1);
1860 }
1861
1862 .float BUTTON_CHAT;
1863 void ChatBubbleThink()
1864 {
1865         self.nextthink = time;
1866         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1867         {
1868                 if(self.owner) // but why can that ever be world?
1869                         self.owner.chatbubbleentity = world;
1870                 remove(self);
1871                 return;
1872         }
1873         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1874 #ifdef TETRIS
1875                 || self.owner.tetris_on
1876 #endif
1877         )
1878                 self.model = self.mdl;
1879         else
1880                 self.model = "";
1881 };
1882
1883 void UpdateChatBubble()
1884 {
1885         if (!self.modelindex)
1886                 return;
1887         // spawn a chatbubble entity if needed
1888         if (!self.chatbubbleentity)
1889         {
1890                 self.chatbubbleentity = spawn();
1891                 self.chatbubbleentity.owner = self;
1892                 self.chatbubbleentity.exteriormodeltoclient = self;
1893                 self.chatbubbleentity.think = ChatBubbleThink;
1894                 self.chatbubbleentity.nextthink = time;
1895                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1896                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1897                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1898                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1899                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1900                 self.chatbubbleentity.model = "";
1901                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1902         }
1903 }
1904
1905
1906 void TeamBubbleThink()
1907 {
1908         self.nextthink = time;
1909         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1910         {
1911                 if(self.owner) // but why can that ever be world?
1912                         self.owner.teambubbleentity = world;
1913                 remove(self);
1914                 return;
1915         }
1916 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1917         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1918                 self.model = "";
1919         else
1920                 self.model = self.mdl;
1921
1922 };
1923
1924 float TeamBubble_customizeentityforclient()
1925 {
1926         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1927 }
1928
1929 void UpdateTeamBubble()
1930 {
1931         if (!self.modelindex || !teams_matter)
1932                 return;
1933         // spawn a teambubble entity if needed
1934         if (!self.teambubbleentity && teams_matter)
1935         {
1936                 self.teambubbleentity = spawn();
1937                 self.teambubbleentity.owner = self;
1938                 self.teambubbleentity.exteriormodeltoclient = self;
1939                 self.teambubbleentity.think = TeamBubbleThink;
1940                 self.teambubbleentity.nextthink = time;
1941                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1942 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1943                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1944                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1945                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1946                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1947                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1948                 self.teambubbleentity.effects = EF_LOWPRECISION;
1949         }
1950 }
1951
1952 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1953 // added to the model skins
1954 /*void UpdateColorModHack()
1955 {
1956         local float c;
1957         c = self.clientcolors & 15;
1958         // LordHavoc: only bothering to support white, green, red, yellow, blue
1959              if (!teams_matter) self.colormod = '0 0 0';
1960         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1961         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1962         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1963         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1964         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1965         else self.colormod = '1 1 1';
1966 };*/
1967
1968 .float oldcolormap;
1969 void respawn(void)
1970 {
1971         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1972         {
1973                 self.solid = SOLID_NOT;
1974                 self.takedamage = DAMAGE_NO;
1975                 self.movetype = MOVETYPE_FLY;
1976                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1977                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1978                 self.effects |= EF_ADDITIVE;
1979                 self.oldcolormap = self.colormap;
1980                 self.colormap = 512;
1981                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1982                 if(autocvar_g_respawn_ghosts_maxtime)
1983                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1984         }
1985
1986         CopyBody(1);
1987         self.effects |= EF_NODRAW; // prevent another CopyBody
1988         if(self.oldcolormap)
1989         {
1990                 self.colormap = self.oldcolormap;
1991                 self.oldcolormap = 0;
1992         }
1993         PutClientInServer();
1994 }
1995
1996 void play_countdown(float finished, string samp)
1997 {
1998         if(clienttype(self) == CLIENTTYPE_REAL)
1999                 if(floor(finished - time - frametime) != floor(finished - time))
2000                         if(finished - time < 6)
2001                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
2002 }
2003
2004 /**
2005  * When sv_timeout is used this function returs strings like
2006  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
2007  * Called by centerprint functions
2008  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
2009  */
2010 string getTimeoutText(float addOneSecond) {
2011         if (!autocvar_sv_timeout || !timeoutStatus)
2012                 return "";
2013
2014         local string retStr;
2015         if (timeoutStatus == 1) {
2016                 if (addOneSecond == 1) {
2017                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2018                 }
2019                 else {
2020                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2021                 }
2022                 return retStr;
2023         }
2024         else if (timeoutStatus == 2) {
2025                 if (addOneSecond) {
2026                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2027                         //don't show messages like "Timeout ends in 0 seconds"...
2028                         if ((remainingTimeoutTime + 1) > 0)
2029                                 return retStr;
2030                         else
2031                                 return "";
2032                 }
2033                 else {
2034                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2035                         //don't show messages like "Timeout ends in 0 seconds"...
2036                         if (remainingTimeoutTime > 0)
2037                                 return retStr;
2038                         else
2039                                 return "";
2040                 }
2041         }
2042         else return "";
2043 }
2044
2045 void player_powerups (void)
2046 {
2047         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2048         olditems = self.items;
2049
2050         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2051         {
2052                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2053                 self.modelflags |= MF_ROCKET;
2054         }
2055         else
2056         {
2057                 SoundEntity_StopSound(self, CHAN_PLAYER);
2058                 self.modelflags &~= MF_ROCKET;
2059         }
2060
2061         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2062
2063         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2064                 return;
2065
2066         Fire_ApplyDamage(self);
2067         Fire_ApplyEffect(self);
2068
2069         if (g_minstagib)
2070         {
2071                 self.effects |= EF_FULLBRIGHT;
2072
2073                 if (self.items & IT_STRENGTH)
2074                 {
2075                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2076                         if (time > self.strength_finished)
2077                         {
2078                                 self.alpha = default_player_alpha;
2079                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2080                                 self.items &~= IT_STRENGTH;
2081                                 sprint(self, "^3Invisibility has worn off\n");
2082                         }
2083                 }
2084                 else
2085                 {
2086                         if (time < self.strength_finished)
2087                         {
2088                                 self.alpha = g_minstagib_invis_alpha;
2089                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2090                                 self.items |= IT_STRENGTH;
2091                                 sprint(self, "^3You are invisible\n");
2092                         }
2093                 }
2094
2095                 if (self.items & IT_INVINCIBLE)
2096                 {
2097                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2098                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2099                         {
2100                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2101                                 sprint(self, "^3Speed has worn off\n");
2102                         }
2103                 }
2104                 else
2105                 {
2106                         if (time < self.invincible_finished)
2107                         {
2108                                 self.items = self.items | IT_INVINCIBLE;
2109                                 sprint(self, "^3You are on speed\n");
2110                         }
2111                 }
2112         }
2113         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2114         {
2115                 if (self.items & IT_STRENGTH)
2116                 {
2117                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2118                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2119                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2120                         {
2121                                 self.items = self.items - (self.items & IT_STRENGTH);
2122                                 sprint(self, "^3Strength has worn off\n");
2123                         }
2124                 }
2125                 else
2126                 {
2127                         if (time < self.strength_finished)
2128                         {
2129                                 self.items = self.items | IT_STRENGTH;
2130                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2131                         }
2132                 }
2133                 if (self.items & IT_INVINCIBLE)
2134                 {
2135                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2136                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2137                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2138                         {
2139                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2140                                 sprint(self, "^3Shield has worn off\n");
2141                         }
2142                 }
2143                 else
2144                 {
2145                         if (time < self.invincible_finished)
2146                         {
2147                                 self.items = self.items | IT_INVINCIBLE;
2148                                 sprint(self, "^3Shield surrounds you\n");
2149                         }
2150                 }
2151
2152                 if(autocvar_g_nodepthtestplayers)
2153                         self.effects = self.effects | EF_NODEPTHTEST;
2154
2155                 if(autocvar_g_fullbrightplayers)
2156                         self.effects = self.effects | EF_FULLBRIGHT;
2157
2158                 // midair gamemode: damage only while in the air
2159                 // if in midair mode, being on ground grants temporary invulnerability
2160                 // (this is so that multishot weapon don't clear the ground flag on the
2161                 // first damage in the frame, leaving the player vulnerable to the
2162                 // remaining hits in the same frame)
2163                 if (self.flags & FL_ONGROUND)
2164                 if (g_midair)
2165                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2166
2167                 if (time >= game_starttime)
2168                 if (time < self.spawnshieldtime)
2169                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2170         }
2171
2172         MUTATOR_CALLHOOK(PlayerPowerups);
2173 }
2174
2175 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2176 {
2177         if(current > stable)
2178                 return current;
2179         else if(current > stable - 0.25) // when close enough, "snap"
2180                 return stable;
2181         else
2182                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2183 }
2184
2185 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2186 {
2187         if(current < stable)
2188                 return current;
2189         else if(current < stable + 0.25) // when close enough, "snap"
2190                 return stable;
2191         else
2192                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2193 }
2194
2195 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2196 {
2197         if(current > rotstable)
2198         {
2199                 if(rotframetime > 0)
2200                 {
2201                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2202                         current = max(rotstable, current - rotlinear * rotframetime);
2203                 }
2204         }
2205         else if(current < regenstable)
2206         {
2207                 if(regenframetime > 0)
2208                 {
2209                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2210                         current = min(regenstable, current + regenlinear * regenframetime);
2211                 }
2212         }
2213
2214         if(current > limit)
2215                 current = limit;
2216
2217         return current;
2218 }
2219
2220 void player_regen (void)
2221 {
2222         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2223         maxh = autocvar_g_balance_health_rotstable;
2224         maxa = autocvar_g_balance_armor_rotstable;
2225         maxf = autocvar_g_balance_fuel_rotstable;
2226         minh = autocvar_g_balance_health_regenstable;
2227         mina = autocvar_g_balance_armor_regenstable;
2228         minf = autocvar_g_balance_fuel_regenstable;
2229         limith = autocvar_g_balance_health_limit;
2230         limita = autocvar_g_balance_armor_limit;
2231         limitf = autocvar_g_balance_fuel_limit;
2232
2233         max_mod = regen_mod = rot_mod = limit_mod = 1;
2234
2235         if (self.runes & RUNE_REGEN)
2236         {
2237                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2238                 {
2239                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2240                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2241                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2242                 }
2243                 else
2244                 {
2245                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2246                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2247                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2248                 }
2249         }
2250         else if (self.runes & CURSE_VENOM)
2251         {
2252                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2253                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2254                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2255                 else
2256                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2257                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2258                 //if (!self.runes & RUNE_REGEN)
2259                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2260         }
2261         maxh = maxh * max_mod;
2262         //maxa = maxa * max_mod;
2263         //maxf = maxf * max_mod;
2264         minh = minh * max_mod;
2265         //mina = mina * max_mod;
2266         //minf = minf * max_mod;
2267         limith = limith * limit_mod;
2268         limita = limita * limit_mod;
2269         //limitf = limitf * limit_mod;
2270
2271         if(g_lms && g_ca)
2272                 rot_mod = 0;
2273
2274         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2275         {
2276                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2277                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2278
2279                 // if player rotted to death...  die!
2280                 if(self.health < 1)
2281                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2282         }
2283
2284         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2285                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2286 }
2287
2288 float zoomstate_set;
2289 void SetZoomState(float z)
2290 {
2291         if(z != self.zoomstate)
2292         {
2293                 self.zoomstate = z;
2294                 ClientData_Touch(self);
2295         }
2296         zoomstate_set = 1;
2297 }
2298
2299 void GetPressedKeys(void) {
2300         MUTATOR_CALLHOOK(GetPressedKeys);
2301         if (self.movement_x > 0) // get if movement keys are pressed
2302         {       // forward key pressed
2303                 self.pressedkeys |= KEY_FORWARD;
2304                 self.pressedkeys &~= KEY_BACKWARD;
2305         }
2306         else if (self.movement_x < 0)
2307         {       // backward key pressed
2308                 self.pressedkeys |= KEY_BACKWARD;
2309                 self.pressedkeys &~= KEY_FORWARD;
2310         }
2311         else
2312         {       // no x input
2313                 self.pressedkeys &~= KEY_FORWARD;
2314                 self.pressedkeys &~= KEY_BACKWARD;
2315         }
2316
2317         if (self.movement_y > 0)
2318         {       // right key pressed
2319                 self.pressedkeys |= KEY_RIGHT;
2320                 self.pressedkeys &~= KEY_LEFT;
2321         }
2322         else if (self.movement_y < 0)
2323         {       // left key pressed
2324                 self.pressedkeys |= KEY_LEFT;
2325                 self.pressedkeys &~= KEY_RIGHT;
2326         }
2327         else
2328         {       // no y input
2329                 self.pressedkeys &~= KEY_RIGHT;
2330                 self.pressedkeys &~= KEY_LEFT;
2331         }
2332
2333         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2334                 self.pressedkeys |= KEY_JUMP;
2335         else
2336                 self.pressedkeys &~= KEY_JUMP;
2337         if (self.BUTTON_CROUCH)
2338                 self.pressedkeys |= KEY_CROUCH;
2339         else
2340                 self.pressedkeys &~= KEY_CROUCH;
2341 }
2342
2343 /*
2344 ======================
2345 spectate mode routines
2346 ======================
2347 */
2348
2349 void SpectateCopy(entity spectatee) {
2350         other = spectatee;
2351         MUTATOR_CALLHOOK(SpectateCopy);
2352         self.armortype = spectatee.armortype;
2353         self.armorvalue = spectatee.armorvalue;
2354         self.ammo_cells = spectatee.ammo_cells;
2355         self.ammo_shells = spectatee.ammo_shells;
2356         self.ammo_nails = spectatee.ammo_nails;
2357         self.ammo_rockets = spectatee.ammo_rockets;
2358         self.ammo_fuel = spectatee.ammo_fuel;
2359         self.clip_load = spectatee.clip_load;
2360         self.clip_size = spectatee.clip_size;
2361         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2362         self.health = spectatee.health;
2363         self.impulse = 0;
2364         self.items = spectatee.items;
2365         self.last_pickup = spectatee.last_pickup;
2366         self.hit_time = spectatee.hit_time;
2367         self.metertime = spectatee.metertime;
2368         self.strength_finished = spectatee.strength_finished;
2369         self.invincible_finished = spectatee.invincible_finished;
2370         self.pressedkeys = spectatee.pressedkeys;
2371         self.weapons = spectatee.weapons;
2372         self.switchweapon = spectatee.switchweapon;
2373         self.weapon = spectatee.weapon;
2374         self.nex_charge = spectatee.nex_charge;
2375         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2376         self.minelayer_mines = spectatee.minelayer_mines;
2377         self.punchangle = spectatee.punchangle;
2378         self.view_ofs = spectatee.view_ofs;
2379         self.v_angle = spectatee.v_angle;
2380         self.velocity = spectatee.velocity;
2381         self.dmg_take = spectatee.dmg_take;
2382         self.dmg_save = spectatee.dmg_save;
2383         self.dmg_inflictor = spectatee.dmg_inflictor;
2384         self.angles = spectatee.v_angle;
2385         self.fixangle = TRUE;
2386         setorigin(self, spectatee.origin);
2387         setsize(self, spectatee.mins, spectatee.maxs);
2388         SetZoomState(spectatee.zoomstate);
2389
2390         anticheat_spectatecopy(spectatee);
2391
2392         //self.vehicle = spectatee.vehicle;
2393
2394         self.hud = spectatee.hud;
2395         if(spectatee.vehicle)
2396     {
2397         self.vehicle_health = spectatee.vehicle_health;
2398         self.vehicle_shield = spectatee.vehicle_shield;
2399         self.vehicle_energy = spectatee.vehicle_energy;
2400         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2401         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2402         self.vehicle_reload1 = spectatee.vehicle_reload1;
2403         self.vehicle_reload2 = spectatee.vehicle_reload2;
2404         msg_entity = self;
2405         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2406         WriteEntity(MSG_ONE, spectatee.vehicle.vehicle_viewport);
2407     }
2408 }
2409
2410 float SpectateUpdate() {
2411         if(!self.enemy)
2412                 return 0;
2413
2414         if (self == self.enemy)
2415                 return 0;
2416
2417         if(self.enemy.classname != "player")
2418                 return 0;
2419
2420         SpectateCopy(self.enemy);
2421
2422         return 1;
2423 }
2424
2425 float SpectateNext() {
2426         other = find(self.enemy, classname, "player");
2427
2428         if (!other)
2429                 other = find(other, classname, "player");
2430
2431         if (other)
2432                 self.enemy = other;
2433
2434         if(self.enemy.classname == "player") {
2435                 msg_entity = self;
2436                 WriteByte(MSG_ONE, SVC_SETVIEW);
2437                 WriteEntity(MSG_ONE, self.enemy);
2438                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2439                 self.movetype = MOVETYPE_NONE;
2440                 accuracy_resend(self);
2441
2442                 if(!SpectateUpdate())
2443                         PutObserverInServer();
2444
2445                 return 1;
2446         } else {
2447                 return 0;
2448         }
2449 }
2450
2451 /*
2452 =============
2453 ShowRespawnCountdown()
2454
2455 Update a respawn countdown display.
2456 =============
2457 */
2458 void ShowRespawnCountdown()
2459 {
2460         float number;
2461         if(self.deadflag == DEAD_NO) // just respawned?
2462                 return;
2463         else
2464         {
2465                 number = ceil(self.death_time - time);
2466                 if(number <= 0)
2467                         return;
2468                 if(number <= self.respawn_countdown)
2469                 {
2470                         self.respawn_countdown = number - 1;
2471                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2472                                 AnnounceTo(self, strcat(ftos(number), ""));
2473                 }
2474         }
2475 }
2476
2477 void LeaveSpectatorMode()
2478 {
2479         if(nJoinAllowed(1)) {
2480                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2481                         self.classname = "player";
2482
2483                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2484                                 JoinBestTeam(self, FALSE, TRUE);
2485
2486                         if(autocvar_g_campaign)
2487                                 campaign_bots_may_start = 1;
2488
2489                         PutClientInServer();
2490
2491                         if(self.classname == "player")
2492                                 bprint ("^4", self.netname, "^4 is playing now\n");
2493
2494                         if(!autocvar_g_campaign)
2495                                 centerprint(self,""); // clear MOTD
2496
2497                         return;
2498                 } else {
2499                         if (g_ca && self.caplayer) {
2500                         }       // do nothing
2501                         else
2502                                 stuffcmd(self,"menu_showteamselect\n");
2503                         return;
2504                 }
2505         }
2506         else {
2507                 //player may not join because of g_maxplayers is set
2508                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2509         }
2510 }
2511
2512 /**
2513  * Determines whether the player is allowed to join. This depends on cvar
2514  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2515  * it checks whether the number of currently playing players exceeds g_maxplayers.
2516  * @return int number of free slots for players, 0 if none
2517  */
2518 float nJoinAllowed(float includeMe) {
2519         if(self.team_forced < 0)
2520                 return FALSE; // forced spectators can never join
2521
2522         // TODO simplify this
2523         local entity e;
2524
2525         local float totalClients;
2526         FOR_EACH_CLIENT(e)
2527                 totalClients += 1;
2528
2529         if (!autocvar_g_maxplayers)
2530                 return maxclients - totalClients + includeMe;
2531
2532         local float currentlyPlaying;
2533         FOR_EACH_REALPLAYER(e)
2534                 currentlyPlaying += 1;
2535
2536         if(currentlyPlaying < autocvar_g_maxplayers)
2537                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2538
2539         return 0;
2540 }
2541
2542 /**
2543  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2544  * g_maxplayers_spectator_blocktime seconds
2545  */
2546 void checkSpectatorBlock() {
2547         if(self.classname == "spectator" || self.classname == "observer") {
2548                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2549                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2550                         dropclient(self);
2551                 }
2552         }
2553 }
2554
2555 void ObserverThink()
2556 {
2557         if (self.flags & FL_JUMPRELEASED) {
2558                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2559                         self.welcomemessage_time = 0;
2560                         self.flags &~= FL_JUMPRELEASED;
2561                         self.flags |= FL_SPAWNING;
2562                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2563                         self.welcomemessage_time = 0;
2564                         self.flags &~= FL_JUMPRELEASED;
2565                         if(SpectateNext() == 1) {
2566                                 self.classname = "spectator";
2567                         }
2568                 }
2569         } else {
2570                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2571                         self.flags |= FL_JUMPRELEASED;
2572                         if(self.flags & FL_SPAWNING)
2573                         {
2574                                 self.flags &~= FL_SPAWNING;
2575                                 LeaveSpectatorMode();
2576                                 return;
2577                         }
2578                 }
2579         }
2580         PrintWelcomeMessage(self);
2581 }
2582
2583 void SpectatorThink()
2584 {
2585         if (self.flags & FL_JUMPRELEASED) {
2586                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2587                         self.welcomemessage_time = 0;
2588                         self.flags &~= FL_JUMPRELEASED;
2589                         self.flags |= FL_SPAWNING;
2590                 } else if(self.BUTTON_ATCK) {
2591                         self.welcomemessage_time = 0;
2592                         self.flags &~= FL_JUMPRELEASED;
2593                         if(SpectateNext() == 1) {
2594                                 self.classname = "spectator";
2595                         } else {
2596                                 self.classname = "observer";
2597                                 PutClientInServer();
2598                         }
2599                 } else if (self.BUTTON_ATCK2) {
2600                         self.welcomemessage_time = 0;
2601                         self.flags &~= FL_JUMPRELEASED;
2602                         self.classname = "observer";
2603                         PutClientInServer();
2604                 } else {
2605                         if(!SpectateUpdate())
2606                                 PutObserverInServer();
2607                 }
2608         } else {
2609                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2610                         self.flags |= FL_JUMPRELEASED;
2611                         if(self.flags & FL_SPAWNING)
2612                         {
2613                                 self.flags &~= FL_SPAWNING;
2614                                 LeaveSpectatorMode();
2615                                 return;
2616                         }
2617                 }
2618         }
2619
2620         PrintWelcomeMessage(self);
2621         self.flags |= FL_CLIENT | FL_NOTARGET;
2622 }
2623
2624 .float touchexplode_time;
2625
2626 /*
2627 =============
2628 PlayerPreThink
2629
2630 Called every frame for each client before the physics are run
2631 =============
2632 */
2633 void() ctf_setstatus;
2634 void() nexball_setstatus;
2635 .float items_added;
2636 void PlayerPreThink (void)
2637 {
2638         self.stat_game_starttime = game_starttime;
2639         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2640         self.stat_leadlimit = autocvar_leadlimit;
2641
2642         if(frametime)
2643         {
2644                 // physics frames: update anticheat stuff
2645                 anticheat_prethink();
2646         }
2647
2648         if(blockSpectators && frametime)
2649                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2650                 checkSpectatorBlock();
2651
2652         zoomstate_set = 0;
2653
2654         if(self.netname_previous != self.netname)
2655         {
2656                 if(autocvar_sv_eventlog)
2657                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2658                 if(self.netname_previous)
2659                         strunzone(self.netname_previous);
2660                 self.netname_previous = strzone(self.netname);
2661         }
2662
2663         // version nagging
2664         if(self.version_nagtime)
2665                 if(self.cvar_g_xonoticversion)
2666                         if(time > self.version_nagtime)
2667                         {
2668                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2669                                 {
2670                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2671                                         {
2672                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2673                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2674                                         }
2675                                         else
2676                                         {
2677                                                 float r;
2678                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2679                                                 if(r < 0)
2680                                                 {
2681                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2682                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2683                                                 }
2684                                                 else if(r > 0)
2685                                                 {
2686                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2687                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2688                                                 }
2689                                         }
2690                                 }
2691                                 self.version_nagtime = 0;
2692                         }
2693
2694         // GOD MODE info
2695         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2696         {
2697                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2698                 self.max_armorvalue = 0;
2699         }
2700
2701 #ifdef TETRIS
2702         if (TetrisPreFrame())
2703                 return;
2704 #endif
2705
2706         MUTATOR_CALLHOOK(PlayerPreThink);
2707
2708         if(self.classname == "player") {
2709 //              if(self.netname == "Wazat")
2710 //                      bprint(self.classname, "\n");
2711
2712                 CheckRules_Player();
2713
2714                 PrintWelcomeMessage(self);
2715
2716                 if (intermission_running)
2717                 {
2718                         IntermissionThink ();   // otherwise a button could be missed between
2719                         return;                                 // the think tics
2720                 }
2721
2722                 if(self.teleport_time)
2723                 if(time > self.teleport_time)
2724                 {
2725                         self.teleport_time = 0;
2726                         self.effects = self.effects - (self.effects & EF_NODRAW);
2727                 }
2728
2729                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2730                         UpdateSelectedPlayer();
2731
2732                 //don't allow the player to turn around while game is paused!
2733                 if(timeoutStatus == 2) {
2734                         self.v_angle = self.lastV_angle;
2735                         self.angles = self.lastV_angle;
2736                         self.fixangle = TRUE;
2737                 }
2738
2739                 if(frametime)
2740                 {
2741                         if(self.health <= 0 && autocvar_g_deathglow)
2742                         {
2743                                 if(self.glowmod_x > 0)
2744                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2745                                 else
2746                                         self.glowmod_x = -1;
2747                                 if(self.glowmod_y > 0)
2748                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2749                                 else
2750                                         self.glowmod_y = -1;
2751                                 if(self.glowmod_z > 0)
2752                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2753                                 else
2754                                         self.glowmod_z = -1;
2755                         }
2756                         else
2757                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2758                         player_powerups();
2759                 }
2760
2761                 if (self.deadflag != DEAD_NO)
2762                 {
2763                         float button_pressed, force_respawn;
2764                         if(self.personal && g_race_qualifying)
2765                         {
2766                                 if(time > self.death_time)
2767                                 {
2768                                         self.death_time = time + 1; // only retry once a second
2769                                         respawn();
2770                                         self.impulse = 141;
2771                                 }
2772                         }
2773                         else
2774                         {
2775                                 if(frametime)
2776                                         player_anim();
2777                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2778                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2779                                 if (self.deadflag == DEAD_DYING)
2780                                 {
2781                                         if(force_respawn)
2782                                                 self.deadflag = DEAD_RESPAWNING;
2783                                         else if(!button_pressed)
2784                                                 self.deadflag = DEAD_DEAD;
2785                                 }
2786                                 else if (self.deadflag == DEAD_DEAD)
2787                                 {
2788                                         if(button_pressed)
2789                                                 self.deadflag = DEAD_RESPAWNABLE;
2790                                 }
2791                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2792                                 {
2793                                         if(!button_pressed)
2794                                                 self.deadflag = DEAD_RESPAWNING;
2795                                 }
2796                                 else if (self.deadflag == DEAD_RESPAWNING)
2797                                 {
2798                                         if(time > self.death_time)
2799                                         {
2800                                                 self.death_time = time + 1; // only retry once a second
2801                                                 respawn();
2802                                         }
2803                                 }
2804                                 ShowRespawnCountdown();
2805                         }
2806                         return;
2807                 }
2808
2809                 if(g_touchexplode)
2810                 if(time > self.touchexplode_time)
2811                 if(self.classname == "player")
2812                 if(self.deadflag == DEAD_NO)
2813                 if not(IS_INDEPENDENT_PLAYER(self))
2814                 FOR_EACH_PLAYER(other) if(self != other)
2815                 {
2816                         if(time > other.touchexplode_time)
2817                         if(other.deadflag == DEAD_NO)
2818                         if not(IS_INDEPENDENT_PLAYER(other))
2819                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2820                         {
2821                                 PlayerTouchExplode(self, other);
2822                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2823                         }
2824                 }
2825
2826                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2827                 {
2828                         vector dist;
2829
2830                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2831                         dist = self.prevorigin - self.origin;
2832                         dist_z = 0;
2833                         self.lms_traveled_distance += fabs(vlen(dist));
2834
2835                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2836                         {
2837                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2838                                 self.lms_traveled_distance = 0;
2839                         }
2840
2841                         if(time > self.lms_nextcheck)
2842                         {
2843                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2844                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2845                                 {
2846                                         centerprint(self, autocvar_g_lms_campcheck_message);
2847                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2848                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2849                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2850                                 }
2851                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2852                                 self.lms_traveled_distance = 0;
2853                         }
2854                 }
2855
2856                 self.prevorigin = self.origin;
2857
2858                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2859                 {
2860                         if (!self.crouch)
2861                         {
2862                                 self.crouch = TRUE;
2863                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2864                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2865                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2866                         }
2867                 }
2868                 else
2869                 {
2870                         if (self.crouch)
2871                         {
2872                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2873                                 if (!trace_startsolid)
2874                                 {
2875                                         self.crouch = FALSE;
2876                                         self.view_ofs = PL_VIEW_OFS;
2877                                         setsize (self, PL_MIN, PL_MAX);
2878                                 }
2879                         }
2880                 }
2881
2882                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2883                 {
2884                         if(self.bloodloss_timer < time)
2885                         {
2886                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2887                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2888                         }
2889                 }
2890
2891                 FixPlayermodel();
2892
2893                 GrapplingHookFrame();
2894
2895                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2896                 //if(frametime)
2897                 {
2898                         self.items &~= self.items_added;
2899
2900                         W_WeaponFrame();
2901
2902                         self.items_added = 0;
2903                         if(self.items & IT_JETPACK)
2904                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2905                                         self.items_added |= IT_FUEL;
2906
2907                         self.items |= self.items_added;
2908                 }
2909
2910                 player_regen();
2911
2912                 // rot nex charge to the charge limit
2913                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2914                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2915
2916                 if(frametime)
2917                         player_anim();
2918
2919                 if (g_minstagib)
2920                         minstagib_ammocheck();
2921
2922                 if(g_ctf)
2923                         ctf_setstatus();
2924
2925                 if(g_nexball)
2926                         nexball_setstatus();
2927
2928                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2929
2930                 //self.angles_y=self.v_angle_y + 90;   // temp
2931         } else if(gameover) {
2932                 if (intermission_running)
2933                         IntermissionThink ();   // otherwise a button could be missed between
2934                 return;
2935         } else if(self.classname == "observer") {
2936                 ObserverThink();
2937         } else if(self.classname == "spectator") {
2938                 SpectatorThink();
2939         }
2940
2941         if(!zoomstate_set)
2942                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_SNIPERRIFLE && autocvar_g_balance_sniperrifle_secondary == 0));
2943
2944         float oldspectatee_status;
2945         oldspectatee_status = self.spectatee_status;
2946         if(self.classname == "spectator")
2947                 self.spectatee_status = num_for_edict(self.enemy);
2948         else if(self.classname == "observer")
2949                 self.spectatee_status = num_for_edict(self);
2950         else
2951                 self.spectatee_status = 0;
2952         if(self.spectatee_status != oldspectatee_status)
2953         {
2954                 ClientData_Touch(self);
2955                 if(g_race || g_cts)
2956                         race_InitSpectator();
2957         }
2958
2959         if(self.teamkill_soundtime)
2960         if(time > self.teamkill_soundtime)
2961         {
2962                 self.teamkill_soundtime = 0;
2963
2964                 entity oldpusher, oldself;
2965
2966                 oldself = self; self = self.teamkill_soundsource;
2967                 oldpusher = self.pusher; self.pusher = oldself;
2968
2969                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2970
2971                 self.pusher = oldpusher;
2972                 self = oldself;
2973         }
2974
2975         if(self.taunt_soundtime)
2976         if(time > self.taunt_soundtime)
2977         {
2978                 self.taunt_soundtime = 0;
2979                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2980         }
2981
2982         target_voicescript_next(self);
2983
2984         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2985         if(!self.weapon)
2986                 self.clip_load = self.clip_size = 0;
2987 }
2988
2989 float isInvisibleString(string s)
2990 {
2991         float i, n, c;
2992         s = strdecolorize(s);
2993         for((i = 0), (n = strlen(s)); i < n; ++i)
2994         {
2995                 c = str2chr(s, i);
2996                 switch(c)
2997                 {
2998                         case 0:
2999                         case 32: // space
3000                                 break;
3001                         case 192: // charmap space
3002                                 if (!autocvar_utf8_enable)
3003                                         break;
3004                                 return FALSE;
3005                         case 160: // space in unicode fonts
3006                         case 0xE000 + 192: // utf8 charmap space
3007                                 if (autocvar_utf8_enable)
3008                                         break;
3009                         default:
3010                                 return FALSE;
3011                 }
3012         }
3013         return TRUE;
3014 }
3015
3016 /*
3017 =============
3018 PlayerPostThink
3019
3020 Called every frame for each client after the physics are run
3021 =============
3022 */
3023 .float idlekick_lasttimeleft;
3024 .entity showheadshotbbox;
3025 void showheadshotbbox_think()
3026 {
3027         if(self.owner.showheadshotbbox != self)
3028         {
3029                 remove(self);
3030                 return;
3031         }
3032         self.nextthink = time;
3033         setorigin(self, self.owner.origin);
3034         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3035 }
3036 void PlayerPostThink (void)
3037 {
3038         // Savage: Check for nameless players
3039         if (isInvisibleString(self.netname)) {
3040                 self.netname = "Player";
3041                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3042         }
3043
3044         if(sv_maxidle && frametime)
3045         {
3046                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3047                 float timeleft;
3048                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3049                 if(timeleft <= 0)
3050                 {
3051                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3052                         AnnounceTo(self, "terminated");
3053                         dropclient(self);
3054                         return;
3055                 }
3056                 else if(timeleft <= 10)
3057                 {
3058                         if(timeleft != self.idlekick_lasttimeleft)
3059                         {
3060                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3061                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3062                         }
3063                 }
3064                 else
3065                 {
3066                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3067                 }
3068                 self.idlekick_lasttimeleft = timeleft;
3069         }
3070
3071 #ifdef TETRIS
3072         if(self.impulse == 100)
3073                 ImpulseCommands();
3074         if (TetrisPostFrame())
3075                 return;
3076 #endif
3077
3078         CheatFrame();
3079
3080         if(self.classname == "player") {
3081                 CheckRules_Player();
3082                 UpdateChatBubble();
3083                 UpdateTeamBubble();
3084                 if (self.impulse)
3085                         ImpulseCommands();
3086                 if (intermission_running)
3087                         return;         // intermission or finale
3088                 GetPressedKeys();
3089         } else if (self.classname == "observer") {
3090                 //do nothing
3091         } else if (self.classname == "spectator") {
3092                 //do nothing
3093         }
3094
3095         /*
3096         float i;
3097         for(i = 0; i < 1000; ++i)
3098         {
3099                 vector end;
3100                 end = self.origin + '0 0 1024' + 512 * randomvec();
3101                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3102                 if(trace_fraction < 1)
3103                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3104                 {
3105                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3106                         break;
3107                 }
3108         }
3109         */
3110
3111         Arena_Warmup();
3112
3113         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3114
3115         if(self.waypointsprite_attachedforcarrier)
3116                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3117
3118         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3119         {
3120                 if(!self.showheadshotbbox)
3121                 {
3122                         self.showheadshotbbox = spawn();
3123                         self.showheadshotbbox.classname = "headshotbbox";
3124                         self.showheadshotbbox.owner = self;
3125                         self.showheadshotbbox.think = showheadshotbbox_think;
3126                         self.showheadshotbbox.nextthink = time;
3127                         self = self.showheadshotbbox;
3128                         self.think();
3129                         self = self.owner;
3130                 }
3131         }
3132         else
3133         {
3134                 if(self.showheadshotbbox)
3135                         remove(self.showheadshotbbox);
3136         }
3137
3138         playerdemo_write();
3139
3140         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3141         {
3142                 if(!self.stored_netname)
3143                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3144                 if(self.stored_netname != self.netname)
3145                 {
3146                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3147                         strunzone(self.stored_netname);
3148                         self.stored_netname = strzone(self.netname);
3149                 }
3150         }
3151
3152         /*
3153         if(g_race)
3154                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3155         */
3156 }