qcsrc/server/cheats.qc

   1 entity CopyBody(float keepvelocity);
   2
   3 #ifdef NOCHEATS
   4
   5 float CheatImpulse(float i) { return 0; }
   6 float CheatCommand(float argc) { return 0; }
   7 float CheatFrame() { return 0; }
   8 void CheatInit() { cheatcount_total = world.cheatcount; }
   9 void CheatShutdown() { }
  10 void CheatInitClient() { }
  11 void CheatShutdownClient() { }
  12 void Drag_MoveDrag(entity from, entity to) { }
  13
  14 #else
  15
  16 .float maycheat;
  17 float gamestart_sv_cheats;
  18
  19 #define CHIMPULSE_SPEEDRUN_INIT 30
  20 #define CHIMPULSE_GIVE_ALL 99
  21 #define CHIMPULSE_CLONE_MOVING 140
  22 #define CHIMPULSE_SPEEDRUN 141
  23 #define CHIMPULSE_CLONE_STANDING 142
  24 #define CHIMPULSE_TELEPORT 143
  25 #define CHIMPULSE_R00T 148
  26
  27 #define CHRAME_DRAG 8
  28
  29 void CheatInit()
  30 {
  31         gamestart_sv_cheats = autocvar_sv_cheats;
  32 }
  33
  34 void CheatShutdown()
  35 {
  36 }
  37
  38 void CheatInitClient()
  39 {
  40 }
  41
  42 void CheatShutdownClient()
  43 {
  44 }
  45
  46 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  47 {
  48         // dead people cannot cheat
  49         if(self.deadflag != DEAD_NO)
  50                 return 0;
  51         if(self.classname != "player")
  52                 return 0;
  53
  54         // sv_clones
  55         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  56                 if(self.lip < sv_clones)
  57                         return 1;
  58
  59         // haha
  60         if(self.maycheat)
  61                 return 1;
  62
  63         // sv_cheats
  64         if(gamestart_sv_cheats && autocvar_sv_cheats)
  65                 return 1;
  66
  67         // if we get here, player is not allowed to cheat. Log it.
  68         if(i)
  69                 bprint(sprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i));
  70         else if(argc)
  71                 bprint(sprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0)));
  72         else if(fr)
  73                 bprint(sprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr));
  74         else
  75                 bprint(sprintf("Player %s^7 tried to use an unknown cheat\n", self.netname));
  76
  77         return 0;
  78 }
  79
  80 #define BEGIN_CHEAT_FUNCTION() \
  81         float cheating, attempting; \
  82         cheating = 0; attempting = 0
  83 #define DID_CHEAT() \
  84         ++cheating
  85 #define ADD_CHEATS(e,n) \
  86         cheatcount_total += n; \
  87         e.cheatcount += n
  88 #define END_CHEAT_FUNCTION() \
  89         ADD_CHEATS(self,cheating); \
  90         return attempting
  91 #define IS_CHEAT(i,argc,fr) \
  92         if((++attempting, !CheatsAllowed(i,argc,fr))) \
  93                 break
  94
  95 float num_autoscreenshot;
  96 void info_autoscreenshot_findtarget()
  97 {
  98         entity e;
  99         e = find(world, targetname, self.target);
 100         if(!e)
 101         {
 102                 objerror("Missing target. FAIL!");
 103                 return;
 104         }
 105         vector a = vectoangles(e.origin - self.origin);
 106         a_x = -a_x; // don't ask
 107         self.angles_x = a_x;
 108         self.angles_y = a_y;
 109         // we leave Rick Roll alone
 110 }
 111 void spawnfunc_info_autoscreenshot()
 112 {
 113         if(++num_autoscreenshot > autocvar_g_max_info_autoscreenshot)
 114         {
 115                 objerror("Too many info_autoscreenshot entitites. FAIL!");
 116                 return;
 117         }
 118         if(self.target != "")
 119                 InitializeEntity(self, info_autoscreenshot_findtarget, INITPRIO_FINDTARGET);
 120         // this one just has to exist
 121 }
 122
 123 float CheatImpulse(float i)
 124 {
 125         BEGIN_CHEAT_FUNCTION();
 126         switch(i)
 127         {
 128                 entity e, e2;
 129                 vector org;
 130
 131                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
 132                         // shared with regular waypoint init, so this is not a cheat by itself
 133                         if(!self.personal)
 134                         {
 135                                 self.personal = spawn();
 136                                 self.personal.classname = "personal_wp";
 137                         }
 138                         self.personal.origin = self.origin;
 139                         self.personal.v_angle = self.v_angle;
 140                         self.personal.velocity = self.velocity;
 141                         self.personal.ammo_rockets = self.ammo_rockets;
 142                         self.personal.ammo_nails = self.ammo_nails;
 143                         self.personal.ammo_cells = self.ammo_cells;
 144                         self.personal.ammo_shells = self.ammo_shells;
 145                         self.personal.ammo_fuel = self.ammo_fuel;
 146                         self.personal.health = self.health;
 147                         self.personal.armorvalue = self.armorvalue;
 148                         self.personal.weapons = self.weapons;
 149                         self.personal.items = self.items;
 150                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 151                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 152                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 153                         self.personal.pauseregen_finished = self.pauseregen_finished;
 154                         self.personal.strength_finished = self.strength_finished;
 155                         self.personal.invincible_finished = self.invincible_finished;
 156                         self.personal.teleport_time = time;
 157                         break; // this part itself doesn't cheat, so let's not count this
 158                 case CHIMPULSE_CLONE_MOVING:
 159                         IS_CHEAT(i, 0, 0);
 160                         makevectors (self.v_angle);
 161                         e = CopyBody(1);
 162                         if(e.colormap <= maxclients && e.colormap > 0)
 163                                 e.colormap = 1024 + self.clientcolors;
 164                         e.velocity = e.velocity + v_forward * 300;
 165                         self.lip += 1;
 166                         DID_CHEAT();
 167                         break;
 168                 case CHIMPULSE_CLONE_STANDING:
 169                         IS_CHEAT(i, 0, 0);
 170                         e = CopyBody(0);
 171                         if(e.colormap <= maxclients && e.colormap > 0)
 172                                 e.colormap = 1024 + self.clientcolors;
 173                         self.lip += 1;
 174                         DID_CHEAT();
 175                         break;
 176                 case CHIMPULSE_GIVE_ALL:
 177                         IS_CHEAT(i, 0, 0);
 178                         CheatCommand(tokenize_console("give all"));
 179                         break; // already counted as cheat
 180                 case CHIMPULSE_SPEEDRUN:
 181                         IS_CHEAT(i, 0, 0);
 182                         if(self.personal)
 183                         {
 184                                 self.speedrunning = TRUE;
 185                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 186                                 if(trace_startsolid)
 187                                 {
 188                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 189                                 }
 190                                 else
 191                                 {
 192                                         // Abort speedrun, teleport back
 193                                         setorigin(self, self.personal.origin);
 194                                         self.oldvelocity = self.velocity = self.personal.velocity;
 195                                         self.angles = self.personal.v_angle;
 196                                         self.fixangle = TRUE;
 197                                         if(self.flagcarried)
 198                                         {
 199                                                 bprint("The ", self.flagcarried.netname, " was returned to base by its carrier\n");
 200                                                 ReturnFlag(self.flagcarried);
 201                                         }
 202                                 }
 203                                 if(g_ctf)
 204                                 {
 205                                         self.ammo_rockets = 999;
 206                                         self.ammo_nails = 999;
 207                                         self.ammo_cells = 999;
 208                                         self.ammo_shells = 999;
 209                                         self.ammo_fuel = 999;
 210                                         self.health = start_health;
 211                                         self.armorvalue = start_armorvalue;
 212                                         self.weapons |= weaponsInMap;
 213                                         self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 214                                         self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 215                                         self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 216                                         self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 217                                         self.strength_finished = 0;
 218                                         self.invincible_finished = 0;
 219                                 }
 220                                 else
 221                                 {
 222                                         self.ammo_rockets = self.personal.ammo_rockets;
 223                                         self.ammo_nails = self.personal.ammo_nails;
 224                                         self.ammo_cells = self.personal.ammo_cells;
 225                                         self.ammo_shells = self.personal.ammo_shells;
 226                                         self.ammo_fuel = self.personal.ammo_fuel;
 227                                         self.health = self.personal.health;
 228                                         self.armorvalue = self.personal.armorvalue;
 229                                         self.weapons = self.personal.weapons;
 230                                         self.items = self.personal.items;
 231                                         self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 232                                         self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 233                                         self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 234                                         self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 235                                         self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 236                                         self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 237                                 }
 238                                 DID_CHEAT();
 239                                 break;
 240                         }
 241                         if(self.deadflag != DEAD_NO)
 242                                 sprint(self, "UR DEAD AHAHAH))\n");
 243                         else
 244                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 245                         break;
 246                 case CHIMPULSE_TELEPORT:
 247                         IS_CHEAT(i, 0, 0);
 248                         if(self.movetype == MOVETYPE_NOCLIP)
 249                         {
 250                                 e = find(world, classname, "info_autoscreenshot");
 251                                 if(e)
 252                                 {
 253                                         sprint(self, "Emergency teleport used info_autoscreenshot location\n");
 254                                         setorigin(self, e.origin);
 255                                         self.angles = e.angles;
 256                                         remove(e);
 257                                         // should we? self.angles_x = -self.angles_x;
 258                                         self.fixangle = TRUE;
 259                                         self.velocity = '0 0 0';
 260                                         DID_CHEAT();
 261                                         break;
 262                                 }
 263                         }
 264                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats >= 2) ? 100000 : 100), 1024, 256))
 265                         {
 266                                 sprint(self, "Emergency teleport used random location\n");
 267                                 self.angles_x = -self.angles_x;
 268                                 self.fixangle = TRUE;
 269                                 self.velocity = '0 0 0';
 270                                 DID_CHEAT();
 271                                 break;
 272                         }
 273                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 274                         break;
 275                 case CHIMPULSE_R00T:
 276                         IS_CHEAT(i, 0, 0);
 277                         FOR_EACH_PLAYER(e)
 278                         {
 279                                 get_model_parameters(e.playermodel, e.skin);
 280                                 if(get_model_parameters_sex == "Female")
 281                                 {
 282                                         makevectors(e.angles);
 283                                         traceline(e.origin, e.origin + v_right * 256, MOVE_NORMAL, e);
 284                                 }
 285                                 else
 286                                 {
 287                                         org_x = random();
 288                                         org_y = random();
 289                                         org_z = 0;
 290                                         org = normalize(org);
 291                                         traceline(e.origin, e.origin + org * 256, MOVE_NORMAL, e); // random direction
 292                                 }
 293
 294                                 org = findbetterlocation(trace_endpos, 12);
 295
 296                                 e2 = spawn();
 297                                 setorigin(e2, org);
 298                                 pointparticles(particleeffectnum("rocket_explode"), org, '0 0 0', 1);
 299                                 sound(e2, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 300                                 RadiusDamage(e2, e, 1000, 0, 128, e, 500, DEATH_CHEAT, world);
 301                                 remove(e2);
 302                         }
 303                         print("404 Sportsmanship not found.\n");
 304                         DID_CHEAT();
 305                         break;
 306         }
 307
 308         END_CHEAT_FUNCTION();
 309 }
 310
 311 void DragBox_Think();
 312 float drag_lastcnt;
 313 float CheatCommand(float argc)
 314 {
 315         BEGIN_CHEAT_FUNCTION();
 316         string cmd;
 317         cmd = argv(0);
 318         switch(cmd)
 319         {
 320                 entity e;
 321                 float effectnum, f;
 322                 vector start, end;
 323                 entity oldself;
 324
 325                 case "pointparticles":
 326                         IS_CHEAT(0, argc, 0);
 327                         if(argc == 5)
 328                         {
 329                                 // arguments:
 330                                 //   effectname
 331                                 //   origin (0..1, on crosshair line)
 332                                 //   velocity
 333                                 //   howmany
 334                                 effectnum = particleeffectnum(argv(1));
 335                                 f = stof(argv(2));
 336                                 crosshair_trace(self);
 337                                 start = (1-f) * self.origin + f * trace_endpos;
 338                                 end = stov(argv(3));
 339                                 f = stof(argv(4));
 340                                 pointparticles(effectnum, start, end, f);
 341                                 DID_CHEAT();
 342                                 break;
 343                         }
 344                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 345                         break;
 346                 case "trailparticles":
 347                         IS_CHEAT(0, argc, 0);
 348                         if(argc == 2)
 349                         {
 350                                 // arguments:
 351                                 //   effectname
 352                                 effectnum = particleeffectnum(argv(1));
 353                                 W_SetupShot(self, FALSE, FALSE, "", CH_WEAPON_A, 0);
 354                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 355                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 356                                 DID_CHEAT();
 357                                 break;
 358                         }
 359                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 360                         break;
 361                 case "make":
 362                         IS_CHEAT(0, argc, 0);
 363                         if(argc == 3)
 364                         {
 365                                 // arguments:
 366                                 //   modelname mode
 367                                 f = stof(argv(2));
 368                                 W_SetupShot(self, FALSE, FALSE, "", CH_WEAPON_A, 0);
 369                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 370                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 371                                 {
 372                                         sprint(self, "cannot make stuff there (bad surface)\n");
 373                                 }
 374                                 else
 375                                 {
 376                                         e = spawn();
 377                                         e.model = strzone(argv(1));
 378                                         e.mdl = "rocket_explode";
 379                                         e.health = 1000;
 380                                         setorigin(e, trace_endpos);
 381                                         e.effects = EF_NOMODELFLAGS;
 382                                         if(f == 1)
 383                                         {
 384                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 385                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 386                                         }
 387                                         oldself = self;
 388                                         self = e;
 389                                         spawnfunc_func_breakable();
 390                                         self = oldself;
 391                                         // now, is it valid?
 392                                         if(f == 0)
 393                                         {
 394                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 395                                                 if(trace_startsolid)
 396                                                 {
 397                                                         remove(e);
 398                                                         sprint(self, "cannot make stuff there (no space)\n");
 399                                                 }
 400                                                 else
 401                                                         DID_CHEAT();
 402                                         }
 403                                         else
 404                                                 DID_CHEAT();
 405                                 }
 406                         }
 407                         else
 408                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 409                         break;
 410                 case "penalty":
 411                         IS_CHEAT(0, argc, 0);
 412                         if(argc == 3)
 413                         {
 414                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 415                                 DID_CHEAT();
 416                                 break;
 417                         }
 418                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 419                         break;
 420                 case "dragbox_spawn":
 421                         IS_CHEAT(0, argc, 0);
 422                         e = spawn();
 423                         e.classname = "dragbox_box";
 424                         e.think = DragBox_Think;
 425                         e.nextthink = time;
 426                         e.solid = -1; // black
 427                         setmodel(e, "null"); // network it
 428                         if(argc == 4)
 429                                 e.cnt = stof(argv(1));
 430                         else
 431                                 e.cnt = max(0, drag_lastcnt);
 432
 433                         e.aiment = spawn();
 434                         e.aiment.classname = "dragbox_corner_1";
 435                         e.aiment.owner = e;
 436                         setmodel(e.aiment, "models/marker.md3");
 437                         e.aiment.skin = 0;
 438                         setsize(e.aiment, '0 0 0', '0 0 0');
 439                         if(argc == 4)
 440                                 setorigin(e.aiment, stov(argv(2)));
 441                         else
 442                         {
 443                                 crosshair_trace(self);
 444                                 setorigin(e.aiment, trace_endpos);
 445                         }
 446
 447                         e.enemy = spawn();
 448                         e.enemy.classname = "dragbox_corner_2";
 449                         e.enemy.owner = e;
 450                         setmodel(e.enemy, "models/marker.md3");
 451                         e.enemy.skin = 1;
 452                         setsize(e.enemy, '0 0 0', '0 0 0');
 453                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 454                         end_x = (end_x > 0) * 2 - 1;
 455                         end_y = (end_y > 0) * 2 - 1;
 456                         end_z = (end_z > 0) * 2 - 1;
 457                         if(argc == 4)
 458                                 setorigin(e.enemy, stov(argv(3)));
 459                         else
 460                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 461
 462                         e.killindicator = spawn();
 463                         e.killindicator.classname = "drag_digit";
 464                         e.killindicator.owner = e;
 465                         setattachment(e.killindicator, e, "");
 466                         setorigin(e.killindicator, '0 0 -8');
 467                         e.killindicator.killindicator = spawn();
 468                         e.killindicator.killindicator.classname = "drag_digit";
 469                         e.killindicator.killindicator.owner = e;
 470                         setattachment(e.killindicator.killindicator, e, "");
 471                         setorigin(e.killindicator.killindicator, '0 0 8');
 472                         DID_CHEAT();
 473                         break;
 474                 case "dragpoint_spawn":
 475                         IS_CHEAT(0, argc, 0);
 476                         e = spawn();
 477                         e.classname = "dragpoint";
 478                         e.think = DragBox_Think;
 479                         e.nextthink = time;
 480                         e.solid = 0; // nothing special
 481                         setmodel(e, "models/marker.md3");
 482                         setsize(e, PL_MIN, PL_MAX);
 483                         e.skin = 2;
 484                         if(argc == 3)
 485                                 e.cnt = stof(argv(1));
 486                         else
 487                                 e.cnt = drag_lastcnt;
 488                         if(argc == 3)
 489                                 setorigin(e, stov(argv(2)));
 490                         else
 491                         {
 492                                 crosshair_trace(self);
 493                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 494                                 move_out_of_solid(e);
 495                         }
 496
 497                         e.killindicator = spawn();
 498                         e.killindicator.classname = "drag_digit";
 499                         e.killindicator.owner = e;
 500                         setattachment(e.killindicator, e, "");
 501                         setorigin(e.killindicator, '0 0 40');
 502                         e.killindicator.killindicator = spawn();
 503                         e.killindicator.killindicator.classname = "drag_digit";
 504                         e.killindicator.killindicator.owner = e;
 505                         setattachment(e.killindicator.killindicator, e, "");
 506                         setorigin(e.killindicator.killindicator, '0 0 56');
 507                         DID_CHEAT();
 508                         break;
 509                 case "drag_remove":
 510                         IS_CHEAT(0, argc, 0);
 511                         RandomSelection_Init();
 512                         crosshair_trace(self);
 513                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 514                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 515                         for(e = world; (e = find(e, classname, "dragpoint")); )
 516                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 517                         if(RandomSelection_chosen_ent)
 518                         {
 519                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 520                                 remove(RandomSelection_chosen_ent.killindicator);
 521                                 if(RandomSelection_chosen_ent.aiment)
 522                                         remove(RandomSelection_chosen_ent.aiment);
 523                                 if(RandomSelection_chosen_ent.enemy)
 524                                         remove(RandomSelection_chosen_ent.enemy);
 525                                 remove(RandomSelection_chosen_ent);
 526                         }
 527                         DID_CHEAT();
 528                         break;
 529                 case "drag_setcnt":
 530                         IS_CHEAT(0, argc, 0);
 531                         if(argc == 2)
 532                         {
 533                                 RandomSelection_Init();
 534                                 crosshair_trace(self);
 535                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 536                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 537                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 538                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 539                                 if(RandomSelection_chosen_ent)
 540                                 {
 541                                         if(substring(argv(1), 0, 1) == "*")
 542                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 543                                         else
 544                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 545                                 }
 546                                 DID_CHEAT();
 547                                 break;
 548                         }
 549                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 550                         break;
 551                 case "drag_save":
 552                         IS_CHEAT(0, argc, 0);
 553                         if(argc == 2)
 554                         {
 555                                 f = fopen(argv(1), FILE_WRITE);
 556                                 fputs(f, "cmd drag_clear\n");
 557                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 558                                 {
 559                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 560                                 }
 561                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 562                                 {
 563                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 564                                 }
 565                                 fclose(f);
 566                                 DID_CHEAT();
 567                                 break;
 568                         }
 569                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 570                         break;
 571                 case "drag_saveraceent":
 572                         IS_CHEAT(0, argc, 0);
 573                         if(argc == 2)
 574                         {
 575                                 f = fopen(argv(1), FILE_WRITE);
 576                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 577                                 {
 578                                         fputs(f, "{\n");
 579                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 580                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin_x), " ", ftos(e.absmin_y), " ", ftos(e.absmin_z), "\"\n"));
 581                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax_x - e.absmin_x), " ", ftos(e.absmax_y - e.absmin_y), " ", ftos(e.absmax_z - e.absmin_z), "\"\n"));
 582                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 583                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 584                                         fputs(f, "}\n");
 585                                 }
 586                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 587                                 {
 588                                         start = '0 0 0';
 589                                         effectnum = 0;
 590                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 591                                         {
 592                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 593                                                 {
 594                                                         start = start + oldself.origin;
 595                                                         ++effectnum;
 596                                                 }
 597                                         }
 598                                         start *= 1 / effectnum;
 599                                         fputs(f, "{\n");
 600                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 601                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 602                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin_x), " ", ftos(e.origin_y), " ", ftos(e.origin_z), "\"\n"));
 603                                         if(e.cnt == -2)
 604                                         {
 605                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 606                                                 fputs(f, "\"race_place\" \"0\"\n");
 607                                         }
 608                                         else if(e.cnt == -1)
 609                                         {
 610                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 611                                                 fputs(f, "\"race_place\" \"-1\"\n");
 612                                         }
 613                                         else
 614                                         {
 615                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 616                                                 if(e.cnt == 0)
 617                                                 {
 618                                                         // these need race_place
 619                                                         // counting...
 620                                                         effectnum = 1;
 621                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 622                                                         if(oldself.cnt == 0)
 623                                                         {
 624                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 625                                                                         ++effectnum;
 626                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 627                                                                         ++effectnum;
 628                                                         }
 629                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 630                                                 }
 631                                         }
 632                                         fputs(f, "}\n");
 633                                 }
 634                                 fclose(f);
 635                                 DID_CHEAT();
 636                                 break;
 637                         }
 638                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 639                         break;
 640                 case "drag_clear":
 641                         IS_CHEAT(0, argc, 0);
 642                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 643                                 remove(e);
 644                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 645                                 remove(e);
 646                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 647                                 remove(e);
 648                         for(e = world; (e = find(e, classname, "dragpoint")); )
 649                                 remove(e);
 650                         for(e = world; (e = find(e, classname, "drag_digit")); )
 651                                 remove(e);
 652                         DID_CHEAT();
 653                         break;
 654                 case "god":
 655                         IS_CHEAT(0, argc, 0);
 656                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 657                         if(self.flags & FL_GODMODE)
 658                         {
 659                                 sprint(self, "godmode ON\n");
 660                                 DID_CHEAT();
 661                         }
 662                         else
 663                                 sprint(self, "godmode OFF\n");
 664                         break;
 665                 case "notarget":
 666                         IS_CHEAT(0, argc, 0);
 667                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 668                         if(self.flags & FL_NOTARGET)
 669                         {
 670                                 sprint(self, "notarget ON\n");
 671                                 DID_CHEAT();
 672                         }
 673                         else
 674                                 sprint(self, "notarget OFF\n");
 675                         break;
 676                 case "noclip":
 677                         IS_CHEAT(0, argc, 0);
 678                         if(self.movetype != MOVETYPE_NOCLIP)
 679                         {
 680                                 self.movetype = MOVETYPE_NOCLIP;
 681                                 sprint(self, "noclip ON\n");
 682                                 DID_CHEAT();
 683                         }
 684                         else
 685                         {
 686                                 self.movetype = MOVETYPE_WALK;
 687                                 sprint(self, "noclip OFF\n");
 688                         }
 689                         break;
 690                 case "fly":
 691                         IS_CHEAT(0, argc, 0);
 692                         if(self.movetype != MOVETYPE_FLY)
 693                         {
 694                                 self.movetype = MOVETYPE_FLY;
 695                                 sprint(self, "flymode ON\n");
 696                                 DID_CHEAT();
 697                         }
 698                         else
 699                         {
 700                                 self.movetype = MOVETYPE_WALK;
 701                                 sprint(self, "flymode OFF\n");
 702                         }
 703                         break;
 704                 case "give":
 705                         IS_CHEAT(0, argc, 0);
 706                         if(GiveItems(self, 1, argc))
 707                                 DID_CHEAT();
 708                         break;
 709         }
 710
 711         END_CHEAT_FUNCTION();
 712 }
 713
 714 float Drag(entity e, float grab, float ischeat);
 715 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 716 void Drag_Finish(entity dragger);
 717 float Drag_IsDraggable(entity draggee);
 718 float Drag_MayChangeAngles(entity draggee);
 719 void Drag_MoveForward(entity dragger);
 720 void Drag_SetSpeed(entity dragger, float s);
 721 void Drag_MoveBackward(entity dragger);
 722 void Drag_Update(entity dragger);
 723 float Drag_CanDrag(entity dragger);
 724 float Drag_IsDragging(entity dragger);
 725 void Drag_MoveDrag(entity from, entity to);
 726 .entity dragentity;
 727
 728 float CheatFrame()
 729 {
 730         BEGIN_CHEAT_FUNCTION();
 731
 732         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 733         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 734         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 735         // grabbing itself no longer being accounted as cheating.
 736
 737         switch(0)
 738         {
 739                 default:
 740                         if(self.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 741                         {
 742                                 // use cheat dragging if cheats are enabled
 743                                 crosshair_trace_plusvisibletriggers(self);
 744                                 Drag(trace_ent, TRUE, TRUE);
 745                         }
 746                         else
 747                         {
 748                                 // drag is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 749                                 // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 750                                 // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 751                                 // it goes out of range while slinging it around.
 752
 753                                 float drag;
 754                                 crosshair_trace_plusvisibletriggers(self);
 755                                 if(vlen(self.origin - trace_ent.origin) <= autocvar_g_grab_range)
 756                                 {
 757                                         switch(trace_ent.grab)
 758                                         {
 759                                                 case 0: // can't grab
 760                                                         break;
 761                                                 case 1: // owner can grab
 762                                                         if(trace_ent.owner == self || trace_ent.realowner == self)
 763                                                                 drag = TRUE;
 764                                                         break;
 765                                                 case 2: // owner and team mates can grab
 766                                                         if(!IsDifferentTeam(trace_ent.owner, self) || !IsDifferentTeam(trace_ent.realowner, self) || trace_ent.team == self.team)
 767                                                                 drag = TRUE;
 768                                                         break;
 769                                                 case 3: // anyone can grab
 770                                                         drag = TRUE;
 771                                                         break;
 772                                                 default:
 773                                                         break;
 774                                         }
 775                                 }
 776                                 Drag(trace_ent, drag, FALSE); // execute dragging
 777                         }
 778                         break;
 779         }
 780
 781         END_CHEAT_FUNCTION();
 782 }
 783
 784
 785
 786
 787
 788 // ENTITY DRAGGING
 789
 790 float Drag(entity e, float pick, float ischeat)
 791 {
 792         BEGIN_CHEAT_FUNCTION();
 793
 794         // returns TRUE when an entity has been picked up
 795         // If pick is TRUE, the object can also be picked up if it's not being held already
 796         // If pick is FALSE, only keep dragging the object if it's already being held
 797
 798         switch(0)
 799         {
 800                 default:
 801                         if(Drag_IsDragging(self))
 802                         {
 803                                 if(self.BUTTON_DRAG)
 804                                 {
 805                                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 806                                         {
 807                                                 Drag_MoveForward(self);
 808                                                 self.impulse = 0;
 809                                         }
 810                                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 811                                         {
 812                                                 Drag_MoveBackward(self);
 813                                                 self.impulse = 0;
 814                                         }
 815                                         else if(self.impulse >= 1 && self.impulse <= 9)
 816                                         {
 817                                                 Drag_SetSpeed(self, self.impulse - 1);
 818                                         }
 819                                         else if(self.impulse == 14)
 820                                         {
 821                                                 Drag_SetSpeed(self, 9);
 822                                         }
 823
 824                                         if(frametime)
 825                                                 Drag_Update(self);
 826                                 }
 827                                 else
 828                                 {
 829                                         Drag_Finish(self);
 830                                 }
 831                         }
 832                         else
 833                         {
 834                                 if(Drag_CanDrag(self))
 835                                         if(self.BUTTON_DRAG && pick)
 836                                         {
 837                                                 if(e)
 838                                                         if(Drag_IsDraggable(e))
 839                                                         {
 840                                                                 if(ischeat)
 841                                                                         IS_CHEAT(0, 0, CHRAME_DRAG);
 842                                                                 if(e.draggedby)
 843                                                                         Drag_Finish(e.draggedby);
 844                                                                 if(e.tag_entity)
 845                                                                         detach_sameorigin(e);
 846                                                                 Drag_Begin(self, e, trace_endpos);
 847                                                                 if(ischeat)
 848                                                                         DID_CHEAT();
 849                                                                 return TRUE;
 850                                                         }
 851                                         }
 852                         }
 853                         break;
 854         }
 855         return FALSE;
 856 }
 857
 858 // on dragger:
 859 .float draggravity;
 860 .float dragspeed; // speed of mouse wheel action
 861 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 862 .vector draglocalvector; // local attachment vector of the dragentity
 863 .float draglocalangle;
 864 // on draggee:
 865 .entity draggedby;
 866 .float dragmovetype;
 867 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 868 {
 869         float tagscale;
 870
 871         draggee.dragmovetype = draggee.movetype;
 872         draggee.draggravity = draggee.gravity;
 873         draggee.movetype = MOVETYPE_WALK;
 874         draggee.gravity = 0.00001;
 875         draggee.flags &~= FL_ONGROUND;
 876         draggee.draggedby = dragger;
 877
 878         dragger.dragentity = draggee;
 879
 880         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 881         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
 882         touchpoint = touchpoint - gettaginfo(draggee, 0);
 883         tagscale = pow(vlen(v_forward), -2);
 884         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 885         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 886         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 887
 888         dragger.dragspeed = 64;
 889 }
 890
 891 void Drag_Finish(entity dragger)
 892 {
 893         entity draggee;
 894         draggee = dragger.dragentity;
 895         if(dragger)
 896                 dragger.dragentity = world;
 897         draggee.draggedby = world;
 898         draggee.movetype = draggee.dragmovetype;
 899         draggee.gravity = draggee.draggravity;
 900
 901         switch(draggee.movetype)
 902         {
 903                 case MOVETYPE_TOSS:
 904                 case MOVETYPE_WALK:
 905                 case MOVETYPE_STEP:
 906                 case MOVETYPE_FLYMISSILE:
 907                 case MOVETYPE_BOUNCE:
 908                 case MOVETYPE_BOUNCEMISSILE:
 909                 case MOVETYPE_PHYSICS:
 910                         break;
 911                 default:
 912                         draggee.velocity = '0 0 0';
 913                         break;
 914         }
 915
 916         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 917         {
 918                 draggee.velocity = '0 0 0';
 919                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 920         }
 921 }
 922
 923 float Drag_IsDraggable(entity draggee)
 924 {
 925         // TODO add more checks for bad stuff here
 926         if(draggee == world)
 927                 return FALSE;
 928         if(draggee.classname == "func_bobbing")
 929                 return FALSE;
 930         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 931                 return FALSE;
 932         if(draggee.classname == "plat")
 933                 return FALSE;
 934         if(draggee.classname == "func_button")
 935                 return FALSE;
 936 //      if(draggee.model == "")
 937 //              return FALSE;
 938         if(draggee.classname == "spectator")
 939                 return FALSE;
 940         if(draggee.classname == "observer")
 941                 return FALSE;
 942         if(draggee.classname == "exteriorweaponentity")
 943                 return FALSE;
 944         if(draggee.classname == "weaponentity")
 945                 return FALSE;
 946
 947         return TRUE;
 948 }
 949
 950 float Drag_MayChangeAngles(entity draggee)
 951 {
 952         // TODO add more checks for bad stuff here
 953         if(substring(draggee.model, 0, 1) == "*")
 954                 return FALSE;
 955         return TRUE;
 956 }
 957
 958 void Drag_MoveForward(entity dragger)
 959 {
 960         dragger.dragdistance += dragger.dragspeed;
 961 }
 962
 963 void Drag_SetSpeed(entity dragger, float s)
 964 {
 965         dragger.dragspeed = pow(2, s);
 966 }
 967
 968 void Drag_MoveBackward(entity dragger)
 969 {
 970         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 971 }
 972
 973 void Drag_Update(entity dragger)
 974 {
 975         vector curorigin, neworigin, goodvelocity;
 976         float f;
 977         entity draggee;
 978
 979         draggee = dragger.dragentity;
 980         draggee.flags &~= FL_ONGROUND;
 981
 982         curorigin = gettaginfo(draggee, 0);
 983         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
 984         makevectors(dragger.v_angle);
 985         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 986         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 987
 988         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
 989                 dragger.draglocalangle += 360;
 990         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
 991                 dragger.draglocalangle -= 360;
 992
 993         f = min(frametime * 10, 1);
 994         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
 995
 996         if(Drag_MayChangeAngles(draggee))
 997                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
 998
 999         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
1000
1001         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
1002 }
1003
1004 float Drag_CanDrag(entity dragger)
1005 {
1006         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
1007 }
1008
1009 float Drag_IsDragging(entity dragger)
1010 {
1011         if(!dragger.dragentity)
1012                 return FALSE;
1013         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
1014         {
1015                 dragger.dragentity = world;
1016                 return FALSE;
1017         }
1018         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
1019         {
1020                 Drag_Finish(dragger);
1021                 return FALSE;
1022         }
1023         return TRUE;
1024 }
1025
1026 void Drag_MoveDrag(entity from, entity to)
1027 {
1028         if(from.draggedby)
1029         {
1030                 to.draggedby = from.draggedby;
1031                 to.draggedby.dragentity = to;
1032                 from.draggedby = world;
1033         }
1034 }
1035
1036 void DragBox_Think()
1037 {
1038         if(self.aiment && self.enemy)
1039         {
1040                 self.origin_x = (self.aiment.origin_x + self.enemy.origin_x) * 0.5;
1041                 self.origin_y = (self.aiment.origin_y + self.enemy.origin_y) * 0.5;
1042                 self.origin_z = (self.aiment.origin_z + self.enemy.origin_z) * 0.5;
1043                 self.maxs_x = fabs(self.aiment.origin_x - self.enemy.origin_x) * 0.5;
1044                 self.maxs_y = fabs(self.aiment.origin_y - self.enemy.origin_y) * 0.5;
1045                 self.maxs_z = fabs(self.aiment.origin_z - self.enemy.origin_z) * 0.5;
1046                 self.mins = -1 * self.maxs;
1047                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
1048         }
1049
1050         if(self.cnt == -1) // actually race_place -1
1051         {
1052                 // show "10 10" for qualifying spawns
1053                 setmodel(self.killindicator, "models/sprites/10.spr32");
1054                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
1055         }
1056         else if(self.cnt == -2) // actually race_place 0
1057         {
1058                 // show "10 0" for loser spawns
1059                 setmodel(self.killindicator, "models/sprites/10.spr32");
1060                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
1061         }
1062         else
1063         {
1064                 setmodel(self.killindicator, strcat("models/sprites/", ftos(mod(self.cnt, 10)), ".spr32"));
1065                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
1066         }
1067
1068         self.nextthink = time;
1069 }
1070
1071 #endif