qcsrc/server/cheats.qc

   1 void CopyBody(float keepvelocity);
   2
   3 #ifdef NOCHEATS
   4
   5 float CheatImpulse(float i) { return 0; }
   6 float CheatCommand(float argc) { return 0; }
   7 float CheatFrame() { return 0; }
   8 void CheatInit() { cheatcount_total = world.cheatcount; }
   9 void CheatShutdown() { }
  10 void CheatInitClient() { }
  11 void CheatShutdownClient() { }
  12 void Drag_MoveDrag(entity from, entity to) { }
  13
  14 #else
  15
  16 .float maycheat;
  17 float gamestart_sv_cheats;
  18
  19 #define CHIMPULSE_SPEEDRUN_INIT 30
  20 #define CHIMPULSE_GIVE_ALL 99
  21 #define CHIMPULSE_CLONE_MOVING 140
  22 #define CHIMPULSE_SPEEDRUN 141
  23 #define CHIMPULSE_CLONE_STANDING 142
  24 #define CHIMPULSE_TELEPORT 143
  25 #define CHIMPULSE_R00T 148
  26
  27 #define CHRAME_DRAG 8
  28
  29 void CheatInit()
  30 {
  31         gamestart_sv_cheats = autocvar_sv_cheats;
  32 }
  33
  34 void CheatShutdown()
  35 {
  36 }
  37
  38 void CheatInitClient()
  39 {
  40 }
  41
  42 void CheatShutdownClient()
  43 {
  44 }
  45
  46 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  47 {
  48         // dead people cannot cheat
  49         if(self.deadflag != DEAD_NO)
  50                 return 0;
  51         if(self.classname != "player")
  52                 return 0;
  53
  54         // sv_clones
  55         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  56                 if(self.lip < sv_clones)
  57                         return 1;
  58
  59         // haha
  60         if(self.maycheat)
  61                 return 1;
  62
  63         // sv_cheats
  64         if(gamestart_sv_cheats && autocvar_sv_cheats)
  65                 return 1;
  66
  67         // if we get here, player is not allowed to cheat. Log it.
  68         if(i)
  69                 bprint(sprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i));
  70         else if(argc)
  71                 bprint(sprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0)));
  72         else if(fr)
  73                 bprint(sprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr));
  74         else
  75                 bprint(sprintf("Player %s^7 tried to use an unknown cheat\n", self.netname));
  76
  77         return 0;
  78 }
  79
  80 #define BEGIN_CHEAT_FUNCTION() \
  81         float cheating, attempting; \
  82         cheating = 0; attempting = 0
  83 #define DID_CHEAT() \
  84         ++cheating
  85 #define ADD_CHEATS(e,n) \
  86         cheatcount_total += n; \
  87         e.cheatcount += n
  88 #define END_CHEAT_FUNCTION() \
  89         ADD_CHEATS(self,cheating); \
  90         return attempting
  91 #define IS_CHEAT(i,argc,fr) \
  92         if((++attempting, !CheatsAllowed(i,argc,fr))) \
  93                 break
  94
  95 void spawnfunc_info_autoscreenshot()
  96 {
  97         // empty spawnfunc just so this entity can exist
  98 }
  99
 100 float CheatImpulse(float i)
 101 {
 102         BEGIN_CHEAT_FUNCTION();
 103         switch(i)
 104         {
 105                 entity e, e2;
 106                 vector org;
 107
 108                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
 109                         // shared with regular waypoint init, so this is not a cheat by itself
 110                         if(!self.personal)
 111                         {
 112                                 self.personal = spawn();
 113                                 self.personal.classname = "personal_wp";
 114                         }
 115                         self.personal.origin = self.origin;
 116                         self.personal.v_angle = self.v_angle;
 117                         self.personal.velocity = self.velocity;
 118                         self.personal.ammo_rockets = self.ammo_rockets;
 119                         self.personal.ammo_nails = self.ammo_nails;
 120                         self.personal.ammo_cells = self.ammo_cells;
 121                         self.personal.ammo_shells = self.ammo_shells;
 122                         self.personal.ammo_fuel = self.ammo_fuel;
 123                         self.personal.health = self.health;
 124                         self.personal.armorvalue = self.armorvalue;
 125                         self.personal.weapons = self.weapons;
 126                         self.personal.items = self.items;
 127                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 128                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 129                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 130                         self.personal.pauseregen_finished = self.pauseregen_finished;
 131                         self.personal.strength_finished = self.strength_finished;
 132                         self.personal.invincible_finished = self.invincible_finished;
 133                         self.personal.teleport_time = time;
 134                         break; // this part itself doesn't cheat, so let's not count this
 135                 case CHIMPULSE_CLONE_MOVING:
 136                         IS_CHEAT(i, 0, 0);
 137                         makevectors (self.v_angle);
 138                         self.velocity = self.velocity + v_forward * 300;
 139                         CopyBody(1);
 140                         self.lip += 1;
 141                         self.velocity = self.velocity - v_forward * 300;
 142                         DID_CHEAT();
 143                         break;
 144                 case CHIMPULSE_CLONE_STANDING:
 145                         IS_CHEAT(i, 0, 0);
 146                         CopyBody(0);
 147                         self.lip += 1;
 148                         DID_CHEAT();
 149                         break;
 150                 case CHIMPULSE_GIVE_ALL:
 151                         IS_CHEAT(i, 0, 0);
 152                         CheatCommand(tokenize_console("give all"));
 153                         break; // already counted as cheat
 154                 case CHIMPULSE_SPEEDRUN:
 155                         IS_CHEAT(i, 0, 0);
 156                         if(self.personal)
 157                         {
 158                                 self.speedrunning = TRUE;
 159                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 160                                 if(trace_startsolid)
 161                                 {
 162                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 163                                 }
 164                                 else
 165                                 {
 166                                         // Abort speedrun, teleport back
 167                                         setorigin(self, self.personal.origin);
 168                                         self.oldvelocity = self.velocity = self.personal.velocity;
 169                                         self.angles = self.personal.v_angle;
 170                                         self.fixangle = TRUE;
 171                                         if(self.flagcarried)
 172                                         {
 173                                                 bprint("The ", self.flagcarried.netname, " was returned to base by its carrier\n");
 174                                                 ReturnFlag(self.flagcarried);
 175                                         }
 176                                 }
 177                                 if(g_ctf)
 178                                 {
 179                                         self.ammo_rockets = 999;
 180                                         self.ammo_nails = 999;
 181                                         self.ammo_cells = 999;
 182                                         self.ammo_shells = 999;
 183                                         self.ammo_fuel = 999;
 184                                         self.health = start_health;
 185                                         self.armorvalue = start_armorvalue;
 186                                         self.weapons |= weaponsInMap;
 187                                         self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 188                                         self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 189                                         self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 190                                         self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 191                                         self.strength_finished = 0;
 192                                         self.invincible_finished = 0;
 193                                 }
 194                                 else
 195                                 {
 196                                         self.ammo_rockets = self.personal.ammo_rockets;
 197                                         self.ammo_nails = self.personal.ammo_nails;
 198                                         self.ammo_cells = self.personal.ammo_cells;
 199                                         self.ammo_shells = self.personal.ammo_shells;
 200                                         self.ammo_fuel = self.personal.ammo_fuel;
 201                                         self.health = self.personal.health;
 202                                         self.armorvalue = self.personal.armorvalue;
 203                                         self.weapons = self.personal.weapons;
 204                                         self.items = self.personal.items;
 205                                         self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 206                                         self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 207                                         self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 208                                         self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 209                                         self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 210                                         self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 211                                 }
 212                                 DID_CHEAT();
 213                                 break;
 214                         }
 215                         if(self.deadflag != DEAD_NO)
 216                                 sprint(self, "UR DEAD AHAHAH))\n");
 217                         else
 218                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 219                         break;
 220                 case CHIMPULSE_TELEPORT:
 221                         IS_CHEAT(i, 0, 0);
 222                         if(self.movetype == MOVETYPE_NOCLIP)
 223                         {
 224                                 e = find(world, classname, "info_autoscreenshot");
 225                                 if(e)
 226                                 {
 227                                         sprint(self, "Emergency teleport uses info_autoscreenshot location\n");
 228                                         setorigin(self, e.origin);
 229                                         self.angles = e.angles;
 230                                         remove(e);
 231                                         // should we? self.angles_x = -self.angles_x;
 232                                         self.fixangle = TRUE;
 233                                         self.velocity = '0 0 0';
 234                                         DID_CHEAT();
 235                                         break;
 236                                 }
 237                         }
 238                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats >= 2) ? 100000 : 100), 1024, 256))
 239                         {
 240                                 self.angles_x = -self.angles_x;
 241                                 self.fixangle = TRUE;
 242                                 self.velocity = '0 0 0';
 243                                 DID_CHEAT();
 244                                 break;
 245                         }
 246                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 247                         break;
 248                 case CHIMPULSE_R00T:
 249                         IS_CHEAT(i, 0, 0);
 250                         FOR_EACH_PLAYER(e)
 251                         {
 252                                 get_model_parameters(e.playermodel, e.skin);
 253                                 if(get_model_parameters_sex == "Female")
 254                                 {
 255                                         makevectors(e.angles);
 256                                         traceline(e.origin, e.origin + v_right * 256, MOVE_NORMAL, e);
 257                                 }
 258                                 else
 259                                 {
 260                                         org_x = random();
 261                                         org_y = random();
 262                                         org_z = 0;
 263                                         org = normalize(org);
 264                                         traceline(e.origin, e.origin + org * 256, MOVE_NORMAL, e); // random direction
 265                                 }
 266
 267                                 org = findbetterlocation(trace_endpos, 12);
 268
 269                                 e2 = spawn();
 270                                 setorigin(e2, org);
 271                                 pointparticles(particleeffectnum("rocket_explode"), org, '0 0 0', 1);
 272                                 sound(e2, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 273                                 RadiusDamage(e2, e, 1000, 0, 128, e, 500, DEATH_CHEAT, world);
 274                                 remove(e2);
 275                         }
 276                         print("404 Sportsmanship not found.\n");
 277                         DID_CHEAT();
 278                         break;
 279         }
 280
 281         END_CHEAT_FUNCTION();
 282 }
 283
 284 void DragBox_Think();
 285 float drag_lastcnt;
 286 float CheatCommand(float argc)
 287 {
 288         BEGIN_CHEAT_FUNCTION();
 289         string cmd;
 290         cmd = argv(0);
 291         switch(cmd)
 292         {
 293                 entity e;
 294                 float effectnum, f;
 295                 vector start, end;
 296                 entity oldself;
 297
 298                 case "pointparticles":
 299                         IS_CHEAT(0, argc, 0);
 300                         if(argc == 5)
 301                         {
 302                                 // arguments:
 303                                 //   effectname
 304                                 //   origin (0..1, on crosshair line)
 305                                 //   velocity
 306                                 //   howmany
 307                                 effectnum = particleeffectnum(argv(1));
 308                                 f = stof(argv(2));
 309                                 crosshair_trace(self);
 310                                 start = (1-f) * self.origin + f * trace_endpos;
 311                                 end = stov(argv(3));
 312                                 f = stof(argv(4));
 313                                 pointparticles(effectnum, start, end, f);
 314                                 DID_CHEAT();
 315                                 break;
 316                         }
 317                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 318                         break;
 319                 case "trailparticles":
 320                         IS_CHEAT(0, argc, 0);
 321                         if(argc == 2)
 322                         {
 323                                 // arguments:
 324                                 //   effectname
 325                                 effectnum = particleeffectnum(argv(1));
 326                                 W_SetupShot(self, FALSE, FALSE, "", CH_WEAPON_A, 0);
 327                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 328                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 329                                 DID_CHEAT();
 330                                 break;
 331                         }
 332                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 333                         break;
 334                 case "make":
 335                         IS_CHEAT(0, argc, 0);
 336                         if(argc == 3)
 337                         {
 338                                 // arguments:
 339                                 //   modelname mode
 340                                 f = stof(argv(2));
 341                                 W_SetupShot(self, FALSE, FALSE, "", CH_WEAPON_A, 0);
 342                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 343                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 344                                 {
 345                                         sprint(self, "cannot make stuff there (bad surface)\n");
 346                                 }
 347                                 else
 348                                 {
 349                                         e = spawn();
 350                                         e.model = strzone(argv(1));
 351                                         e.mdl = "rocket_explode";
 352                                         e.health = 1000;
 353                                         setorigin(e, trace_endpos);
 354                                         e.effects = EF_NOMODELFLAGS;
 355                                         if(f == 1)
 356                                         {
 357                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 358                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 359                                         }
 360                                         oldself = self;
 361                                         self = e;
 362                                         spawnfunc_func_breakable();
 363                                         self = oldself;
 364                                         // now, is it valid?
 365                                         if(f == 0)
 366                                         {
 367                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 368                                                 if(trace_startsolid)
 369                                                 {
 370                                                         remove(e);
 371                                                         sprint(self, "cannot make stuff there (no space)\n");
 372                                                 }
 373                                                 else
 374                                                         DID_CHEAT();
 375                                         }
 376                                         else
 377                                                 DID_CHEAT();
 378                                 }
 379                         }
 380                         else
 381                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 382                         break;
 383                 case "penalty":
 384                         IS_CHEAT(0, argc, 0);
 385                         if(argc == 3)
 386                         {
 387                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 388                                 DID_CHEAT();
 389                                 break;
 390                         }
 391                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 392                         break;
 393                 case "dragbox_spawn":
 394                         IS_CHEAT(0, argc, 0);
 395                         e = spawn();
 396                         e.classname = "dragbox_box";
 397                         e.think = DragBox_Think;
 398                         e.nextthink = time;
 399                         e.solid = -1; // black
 400                         setmodel(e, "null"); // network it
 401                         if(argc == 4)
 402                                 e.cnt = stof(argv(1));
 403                         else
 404                                 e.cnt = max(0, drag_lastcnt);
 405
 406                         e.aiment = spawn();
 407                         e.aiment.classname = "dragbox_corner_1";
 408                         e.aiment.owner = e;
 409                         setmodel(e.aiment, "models/marker.md3");
 410                         e.aiment.skin = 0;
 411                         setsize(e.aiment, '0 0 0', '0 0 0');
 412                         if(argc == 4)
 413                                 setorigin(e.aiment, stov(argv(2)));
 414                         else
 415                         {
 416                                 crosshair_trace(self);
 417                                 setorigin(e.aiment, trace_endpos);
 418                         }
 419
 420                         e.enemy = spawn();
 421                         e.enemy.classname = "dragbox_corner_2";
 422                         e.enemy.owner = e;
 423                         setmodel(e.enemy, "models/marker.md3");
 424                         e.enemy.skin = 1;
 425                         setsize(e.enemy, '0 0 0', '0 0 0');
 426                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 427                         end_x = (end_x > 0) * 2 - 1;
 428                         end_y = (end_y > 0) * 2 - 1;
 429                         end_z = (end_z > 0) * 2 - 1;
 430                         if(argc == 4)
 431                                 setorigin(e.enemy, stov(argv(3)));
 432                         else
 433                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 434
 435                         e.killindicator = spawn();
 436                         e.killindicator.classname = "drag_digit";
 437                         e.killindicator.owner = e;
 438                         setattachment(e.killindicator, e, "");
 439                         setorigin(e.killindicator, '0 0 -8');
 440                         e.killindicator.killindicator = spawn();
 441                         e.killindicator.killindicator.classname = "drag_digit";
 442                         e.killindicator.killindicator.owner = e;
 443                         setattachment(e.killindicator.killindicator, e, "");
 444                         setorigin(e.killindicator.killindicator, '0 0 8');
 445                         DID_CHEAT();
 446                         break;
 447                 case "dragpoint_spawn":
 448                         IS_CHEAT(0, argc, 0);
 449                         e = spawn();
 450                         e.classname = "dragpoint";
 451                         e.think = DragBox_Think;
 452                         e.nextthink = time;
 453                         e.solid = 0; // nothing special
 454                         setmodel(e, "models/marker.md3");
 455                         setsize(e, PL_MIN, PL_MAX);
 456                         e.skin = 2;
 457                         if(argc == 3)
 458                                 e.cnt = stof(argv(1));
 459                         else
 460                                 e.cnt = drag_lastcnt;
 461                         if(argc == 3)
 462                                 setorigin(e, stov(argv(2)));
 463                         else
 464                         {
 465                                 crosshair_trace(self);
 466                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 467                                 move_out_of_solid(e);
 468                         }
 469
 470                         e.killindicator = spawn();
 471                         e.killindicator.classname = "drag_digit";
 472                         e.killindicator.owner = e;
 473                         setattachment(e.killindicator, e, "");
 474                         setorigin(e.killindicator, '0 0 40');
 475                         e.killindicator.killindicator = spawn();
 476                         e.killindicator.killindicator.classname = "drag_digit";
 477                         e.killindicator.killindicator.owner = e;
 478                         setattachment(e.killindicator.killindicator, e, "");
 479                         setorigin(e.killindicator.killindicator, '0 0 56');
 480                         DID_CHEAT();
 481                         break;
 482                 case "drag_remove":
 483                         IS_CHEAT(0, argc, 0);
 484                         RandomSelection_Init();
 485                         crosshair_trace(self);
 486                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 487                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 488                         for(e = world; (e = find(e, classname, "dragpoint")); )
 489                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 490                         if(RandomSelection_chosen_ent)
 491                         {
 492                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 493                                 remove(RandomSelection_chosen_ent.killindicator);
 494                                 if(RandomSelection_chosen_ent.aiment)
 495                                         remove(RandomSelection_chosen_ent.aiment);
 496                                 if(RandomSelection_chosen_ent.enemy)
 497                                         remove(RandomSelection_chosen_ent.enemy);
 498                                 remove(RandomSelection_chosen_ent);
 499                         }
 500                         DID_CHEAT();
 501                         break;
 502                 case "drag_setcnt":
 503                         IS_CHEAT(0, argc, 0);
 504                         if(argc == 2)
 505                         {
 506                                 RandomSelection_Init();
 507                                 crosshair_trace(self);
 508                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 509                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 510                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 511                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 512                                 if(RandomSelection_chosen_ent)
 513                                 {
 514                                         if(substring(argv(1), 0, 1) == "*")
 515                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 516                                         else
 517                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 518                                 }
 519                                 DID_CHEAT();
 520                                 break;
 521                         }
 522                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 523                         break;
 524                 case "drag_save":
 525                         IS_CHEAT(0, argc, 0);
 526                         if(argc == 2)
 527                         {
 528                                 f = fopen(argv(1), FILE_WRITE);
 529                                 fputs(f, "cmd drag_clear\n");
 530                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 531                                 {
 532                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 533                                 }
 534                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 535                                 {
 536                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 537                                 }
 538                                 fclose(f);
 539                                 DID_CHEAT();
 540                                 break;
 541                         }
 542                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 543                         break;
 544                 case "drag_saveraceent":
 545                         IS_CHEAT(0, argc, 0);
 546                         if(argc == 2)
 547                         {
 548                                 f = fopen(argv(1), FILE_WRITE);
 549                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 550                                 {
 551                                         fputs(f, "{\n");
 552                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 553                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin_x), " ", ftos(e.absmin_y), " ", ftos(e.absmin_z), "\"\n"));
 554                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax_x - e.absmin_x), " ", ftos(e.absmax_y - e.absmin_y), " ", ftos(e.absmax_z - e.absmin_z), "\"\n"));
 555                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 556                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 557                                         fputs(f, "}\n");
 558                                 }
 559                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 560                                 {
 561                                         start = '0 0 0';
 562                                         effectnum = 0;
 563                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 564                                         {
 565                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 566                                                 {
 567                                                         start = start + oldself.origin;
 568                                                         ++effectnum;
 569                                                 }
 570                                         }
 571                                         start *= 1 / effectnum;
 572                                         fputs(f, "{\n");
 573                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 574                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 575                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin_x), " ", ftos(e.origin_y), " ", ftos(e.origin_z), "\"\n"));
 576                                         if(e.cnt == -2)
 577                                         {
 578                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 579                                                 fputs(f, "\"race_place\" \"0\"\n");
 580                                         }
 581                                         else if(e.cnt == -1)
 582                                         {
 583                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 584                                                 fputs(f, "\"race_place\" \"-1\"\n");
 585                                         }
 586                                         else
 587                                         {
 588                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 589                                                 if(e.cnt == 0)
 590                                                 {
 591                                                         // these need race_place
 592                                                         // counting...
 593                                                         effectnum = 1;
 594                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 595                                                         if(oldself.cnt == 0)
 596                                                         {
 597                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 598                                                                         ++effectnum;
 599                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 600                                                                         ++effectnum;
 601                                                         }
 602                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 603                                                 }
 604                                         }
 605                                         fputs(f, "}\n");
 606                                 }
 607                                 fclose(f);
 608                                 DID_CHEAT();
 609                                 break;
 610                         }
 611                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 612                         break;
 613                 case "drag_clear":
 614                         IS_CHEAT(0, argc, 0);
 615                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 616                                 remove(e);
 617                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 618                                 remove(e);
 619                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 620                                 remove(e);
 621                         for(e = world; (e = find(e, classname, "dragpoint")); )
 622                                 remove(e);
 623                         for(e = world; (e = find(e, classname, "drag_digit")); )
 624                                 remove(e);
 625                         DID_CHEAT();
 626                         break;
 627                 case "god":
 628                         IS_CHEAT(0, argc, 0);
 629                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 630                         if(self.flags & FL_GODMODE)
 631                         {
 632                                 sprint(self, "godmode ON\n");
 633                                 DID_CHEAT();
 634                         }
 635                         else
 636                                 sprint(self, "godmode OFF\n");
 637                         break;
 638                 case "notarget":
 639                         IS_CHEAT(0, argc, 0);
 640                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 641                         if(self.flags & FL_NOTARGET)
 642                         {
 643                                 sprint(self, "notarget ON\n");
 644                                 DID_CHEAT();
 645                         }
 646                         else
 647                                 sprint(self, "notarget OFF\n");
 648                         break;
 649                 case "noclip":
 650                         IS_CHEAT(0, argc, 0);
 651                         if(self.movetype != MOVETYPE_NOCLIP)
 652                         {
 653                                 self.movetype = MOVETYPE_NOCLIP;
 654                                 sprint(self, "noclip ON\n");
 655                                 DID_CHEAT();
 656                         }
 657                         else
 658                         {
 659                                 self.movetype = MOVETYPE_WALK;
 660                                 sprint(self, "noclip OFF\n");
 661                         }
 662                         break;
 663                 case "fly":
 664                         IS_CHEAT(0, argc, 0);
 665                         if(self.movetype != MOVETYPE_FLY)
 666                         {
 667                                 self.movetype = MOVETYPE_FLY;
 668                                 sprint(self, "flymode ON\n");
 669                                 DID_CHEAT();
 670                         }
 671                         else
 672                         {
 673                                 self.movetype = MOVETYPE_WALK;
 674                                 sprint(self, "flymode OFF\n");
 675                         }
 676                         break;
 677                 case "give":
 678                         IS_CHEAT(0, argc, 0);
 679                         if(GiveItems(self, 1, argc))
 680                                 DID_CHEAT();
 681                         break;
 682         }
 683
 684         END_CHEAT_FUNCTION();
 685 }
 686
 687 float Drag(entity e, float grab, float ischeat);
 688 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 689 void Drag_Finish(entity dragger);
 690 float Drag_IsDraggable(entity draggee);
 691 float Drag_MayChangeAngles(entity draggee);
 692 void Drag_MoveForward(entity dragger);
 693 void Drag_SetSpeed(entity dragger, float s);
 694 void Drag_MoveBackward(entity dragger);
 695 void Drag_Update(entity dragger);
 696 float Drag_CanDrag(entity dragger);
 697 float Drag_IsDragging(entity dragger);
 698 void Drag_MoveDrag(entity from, entity to);
 699 .entity dragentity;
 700
 701 float CheatFrame()
 702 {
 703         BEGIN_CHEAT_FUNCTION();
 704
 705         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 706         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 707         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 708         // grabbing itself no longer being accounted as cheating.
 709
 710         switch(0)
 711         {
 712                 default:
 713                         if(self.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 714                         {
 715                                 // use cheat dragging if cheats are enabled
 716                                 crosshair_trace_plusvisibletriggers(self);
 717                                 Drag(trace_ent, TRUE, TRUE);
 718                         }
 719                         else
 720                         {
 721                                 // drag is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 722                                 // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 723                                 // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 724                                 // it goes out of range while slinging it around.
 725
 726                                 float drag;
 727                                 crosshair_trace_plusvisibletriggers(self);
 728                                 if(vlen(self.origin - trace_ent.origin) <= autocvar_g_grab_range)
 729                                 {
 730                                         switch(trace_ent.grab)
 731                                         {
 732                                                 case 0: // can't grab
 733                                                         break;
 734                                                 case 1: // owner can grab
 735                                                         if(trace_ent.owner == self || trace_ent.realowner == self)
 736                                                                 drag = TRUE;
 737                                                         break;
 738                                                 case 2: // owner and team mates can grab
 739                                                         if(!IsDifferentTeam(trace_ent.owner, self) || !IsDifferentTeam(trace_ent.realowner, self) || trace_ent.team == self.team)
 740                                                                 drag = TRUE;
 741                                                         break;
 742                                                 case 3: // anyone can grab
 743                                                         drag = TRUE;
 744                                                         break;
 745                                                 default:
 746                                                         break;
 747                                         }
 748                                 }
 749                                 Drag(trace_ent, drag, FALSE); // execute dragging
 750                         }
 751                         break;
 752         }
 753
 754         END_CHEAT_FUNCTION();
 755 }
 756
 757
 758
 759
 760
 761 // ENTITY DRAGGING
 762
 763 float Drag(entity e, float pick, float ischeat)
 764 {
 765         BEGIN_CHEAT_FUNCTION();
 766
 767         // returns TRUE when an entity has been picked up
 768         // If pick is TRUE, the object can also be picked up if it's not being held already
 769         // If pick is FALSE, only keep dragging the object if it's already being held
 770
 771         switch(0)
 772         {
 773                 default:
 774                         if(Drag_IsDragging(self))
 775                         {
 776                                 if(self.BUTTON_DRAG)
 777                                 {
 778                                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 779                                         {
 780                                                 Drag_MoveForward(self);
 781                                                 self.impulse = 0;
 782                                         }
 783                                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 784                                         {
 785                                                 Drag_MoveBackward(self);
 786                                                 self.impulse = 0;
 787                                         }
 788                                         else if(self.impulse >= 1 && self.impulse <= 9)
 789                                         {
 790                                                 Drag_SetSpeed(self, self.impulse - 1);
 791                                         }
 792                                         else if(self.impulse == 14)
 793                                         {
 794                                                 Drag_SetSpeed(self, 9);
 795                                         }
 796
 797                                         if(frametime)
 798                                                 Drag_Update(self);
 799                                 }
 800                                 else
 801                                 {
 802                                         Drag_Finish(self);
 803                                 }
 804                         }
 805                         else
 806                         {
 807                                 if(Drag_CanDrag(self))
 808                                         if(self.BUTTON_DRAG && pick)
 809                                         {
 810                                                 if(e)
 811                                                         if(Drag_IsDraggable(e))
 812                                                         {
 813                                                                 if(ischeat)
 814                                                                         IS_CHEAT(0, 0, CHRAME_DRAG);
 815                                                                 if(e.draggedby)
 816                                                                         Drag_Finish(e.draggedby);
 817                                                                 if(e.tag_entity)
 818                                                                         detach_sameorigin(e);
 819                                                                 Drag_Begin(self, e, trace_endpos);
 820                                                                 if(ischeat)
 821                                                                         DID_CHEAT();
 822                                                                 return TRUE;
 823                                                         }
 824                                         }
 825                         }
 826                         break;
 827         }
 828         return FALSE;
 829 }
 830
 831 // on dragger:
 832 .float draggravity;
 833 .float dragspeed; // speed of mouse wheel action
 834 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 835 .vector draglocalvector; // local attachment vector of the dragentity
 836 .float draglocalangle;
 837 // on draggee:
 838 .entity draggedby;
 839 .float dragmovetype;
 840 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 841 {
 842         float tagscale;
 843
 844         draggee.dragmovetype = draggee.movetype;
 845         draggee.draggravity = draggee.gravity;
 846         draggee.movetype = MOVETYPE_WALK;
 847         draggee.gravity = 0.00001;
 848         draggee.flags &~= FL_ONGROUND;
 849         draggee.draggedby = dragger;
 850
 851         dragger.dragentity = draggee;
 852
 853         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 854         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
 855         touchpoint = touchpoint - gettaginfo(draggee, 0);
 856         tagscale = pow(vlen(v_forward), -2);
 857         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 858         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 859         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 860
 861         dragger.dragspeed = 64;
 862 }
 863
 864 void Drag_Finish(entity dragger)
 865 {
 866         entity draggee;
 867         draggee = dragger.dragentity;
 868         if(dragger)
 869                 dragger.dragentity = world;
 870         draggee.draggedby = world;
 871         draggee.movetype = draggee.dragmovetype;
 872         draggee.gravity = draggee.draggravity;
 873
 874         switch(draggee.movetype)
 875         {
 876                 case MOVETYPE_TOSS:
 877                 case MOVETYPE_WALK:
 878                 case MOVETYPE_STEP:
 879                 case MOVETYPE_FLYMISSILE:
 880                 case MOVETYPE_BOUNCE:
 881                 case MOVETYPE_BOUNCEMISSILE:
 882                 case MOVETYPE_PHYSICS:
 883                         break;
 884                 default:
 885                         draggee.velocity = '0 0 0';
 886                         break;
 887         }
 888
 889         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 890         {
 891                 draggee.velocity = '0 0 0';
 892                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 893         }
 894 }
 895
 896 float Drag_IsDraggable(entity draggee)
 897 {
 898         // TODO add more checks for bad stuff here
 899         if(draggee == world)
 900                 return FALSE;
 901         if(draggee.classname == "func_bobbing")
 902                 return FALSE;
 903         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 904                 return FALSE;
 905         if(draggee.classname == "plat")
 906                 return FALSE;
 907         if(draggee.classname == "func_button")
 908                 return FALSE;
 909 //      if(draggee.model == "")
 910 //              return FALSE;
 911         if(draggee.classname == "spectator")
 912                 return FALSE;
 913         if(draggee.classname == "observer")
 914                 return FALSE;
 915         if(draggee.classname == "exteriorweaponentity")
 916                 return FALSE;
 917         if(draggee.classname == "weaponentity")
 918                 return FALSE;
 919
 920         return TRUE;
 921 }
 922
 923 float Drag_MayChangeAngles(entity draggee)
 924 {
 925         // TODO add more checks for bad stuff here
 926         if(substring(draggee.model, 0, 1) == "*")
 927                 return FALSE;
 928         return TRUE;
 929 }
 930
 931 void Drag_MoveForward(entity dragger)
 932 {
 933         dragger.dragdistance += dragger.dragspeed;
 934 }
 935
 936 void Drag_SetSpeed(entity dragger, float s)
 937 {
 938         dragger.dragspeed = pow(2, s);
 939 }
 940
 941 void Drag_MoveBackward(entity dragger)
 942 {
 943         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 944 }
 945
 946 void Drag_Update(entity dragger)
 947 {
 948         vector curorigin, neworigin, goodvelocity;
 949         float f;
 950         entity draggee;
 951
 952         draggee = dragger.dragentity;
 953         draggee.flags &~= FL_ONGROUND;
 954
 955         curorigin = gettaginfo(draggee, 0);
 956         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
 957         makevectors(dragger.v_angle);
 958         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 959         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 960
 961         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
 962                 dragger.draglocalangle += 360;
 963         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
 964                 dragger.draglocalangle -= 360;
 965
 966         f = min(frametime * 10, 1);
 967         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
 968
 969         if(Drag_MayChangeAngles(draggee))
 970                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
 971
 972         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
 973
 974         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
 975 }
 976
 977 float Drag_CanDrag(entity dragger)
 978 {
 979         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
 980 }
 981
 982 float Drag_IsDragging(entity dragger)
 983 {
 984         if(!dragger.dragentity)
 985                 return FALSE;
 986         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
 987         {
 988                 dragger.dragentity = world;
 989                 return FALSE;
 990         }
 991         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
 992         {
 993                 Drag_Finish(dragger);
 994                 return FALSE;
 995         }
 996         return TRUE;
 997 }
 998
 999 void Drag_MoveDrag(entity from, entity to)
1000 {
1001         if(from.draggedby)
1002         {
1003                 to.draggedby = from.draggedby;
1004                 to.draggedby.dragentity = to;
1005                 from.draggedby = world;
1006         }
1007 }
1008
1009 void DragBox_Think()
1010 {
1011         if(self.aiment && self.enemy)
1012         {
1013                 self.origin_x = (self.aiment.origin_x + self.enemy.origin_x) * 0.5;
1014                 self.origin_y = (self.aiment.origin_y + self.enemy.origin_y) * 0.5;
1015                 self.origin_z = (self.aiment.origin_z + self.enemy.origin_z) * 0.5;
1016                 self.maxs_x = fabs(self.aiment.origin_x - self.enemy.origin_x) * 0.5;
1017                 self.maxs_y = fabs(self.aiment.origin_y - self.enemy.origin_y) * 0.5;
1018                 self.maxs_z = fabs(self.aiment.origin_z - self.enemy.origin_z) * 0.5;
1019                 self.mins = -1 * self.maxs;
1020                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
1021         }
1022
1023         if(self.cnt == -1) // actually race_place -1
1024         {
1025                 // show "10 10" for qualifying spawns
1026                 setmodel(self.killindicator, "models/sprites/10.spr32");
1027                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
1028         }
1029         else if(self.cnt == -2) // actually race_place 0
1030         {
1031                 // show "10 0" for loser spawns
1032                 setmodel(self.killindicator, "models/sprites/10.spr32");
1033                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
1034         }
1035         else
1036         {
1037                 setmodel(self.killindicator, strcat("models/sprites/", ftos(mod(self.cnt, 10)), ".spr32"));
1038                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
1039         }
1040
1041         self.nextthink = time;
1042 }
1043
1044 #endif