qcsrc/server/cheats.qc

   1 void CopyBody(float keepvelocity);
   2
   3 #ifdef NOCHEATS
   4
   5 float CheatImpulse(float i) { return 0; }
   6 float CheatCommand(float argc) { return 0; }
   7 float CheatFrame() { return 0; }
   8 void CheatInit() { cheatcount_total = world.cheatcount; }
   9 void CheatShutdown() { }
  10 void CheatInitClient() { }
  11 void CheatShutdownClient() { }
  12 void Drag_MoveDrag(entity from, entity to) { }
  13
  14 #else
  15
  16 .float maycheat;
  17 float gamestart_sv_cheats;
  18
  19 #define CHIMPULSE_SPEEDRUN_INIT 30
  20 #define CHIMPULSE_GIVE_ALL 99
  21 #define CHIMPULSE_CLONE_MOVING 140
  22 #define CHIMPULSE_SPEEDRUN 141
  23 #define CHIMPULSE_CLONE_STANDING 142
  24 #define CHIMPULSE_TELEPORT 143
  25 #define CHIMPULSE_R00T 148
  26
  27 #define CHRAME_DRAG 8
  28
  29 void CheatInit()
  30 {
  31         gamestart_sv_cheats = autocvar_sv_cheats;
  32 }
  33
  34 void CheatShutdown()
  35 {
  36 }
  37
  38 void CheatInitClient()
  39 {
  40 }
  41
  42 void CheatShutdownClient()
  43 {
  44 }
  45
  46 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  47 {
  48         // dead people cannot cheat
  49         if(self.deadflag != DEAD_NO)
  50                 return 0;
  51         if(self.classname != "player")
  52                 return 0;
  53
  54         // sv_clones
  55         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  56                 if(self.lip < sv_clones)
  57                         return 1;
  58
  59         // haha
  60         if(self.maycheat)
  61                 return 1;
  62
  63         // sv_cheats
  64         if(gamestart_sv_cheats && autocvar_sv_cheats)
  65                 return 1;
  66
  67         // if we get here, player is not allowed to cheat. Log it.
  68         if(i)
  69                 bprint(sprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i));
  70         else if(argc)
  71                 bprint(sprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0)));
  72         else if(fr)
  73                 bprint(sprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr));
  74         else
  75                 bprint(sprintf("Player %s^7 tried to use an unknown cheat\n", self.netname));
  76
  77         return 0;
  78 }
  79
  80 #define BEGIN_CHEAT_FUNCTION() \
  81         float cheating, attempting; \
  82         cheating = 0; attempting = 0
  83 #define DID_CHEAT() \
  84         ++cheating
  85 #define ADD_CHEATS(e,n) \
  86         cheatcount_total += n; \
  87         e.cheatcount += n
  88 #define END_CHEAT_FUNCTION() \
  89         ADD_CHEATS(self,cheating); \
  90         return attempting
  91 #define IS_CHEAT(i,argc,fr) \
  92         if((++attempting, !CheatsAllowed(i,argc,fr))) \
  93                 break
  94
  95 void spawnfunc_info_autoscreenshot()
  96 {
  97         // empty spawnfunc just so this entity can exist
  98 }
  99
 100 float CheatImpulse(float i)
 101 {
 102         BEGIN_CHEAT_FUNCTION();
 103         switch(i)
 104         {
 105                 entity e, e2;
 106                 vector org;
 107
 108                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
 109                         // shared with regular waypoint init, so this is not a cheat by itself
 110                         if(!self.personal)
 111                         {
 112                                 self.personal = spawn();
 113                                 self.personal.classname = "personal_wp";
 114                         }
 115                         self.personal.origin = self.origin;
 116                         self.personal.v_angle = self.v_angle;
 117                         self.personal.velocity = self.velocity;
 118                         self.personal.ammo_rockets = self.ammo_rockets;
 119                         self.personal.ammo_nails = self.ammo_nails;
 120                         self.personal.ammo_cells = self.ammo_cells;
 121                         self.personal.ammo_shells = self.ammo_shells;
 122                         self.personal.ammo_fuel = self.ammo_fuel;
 123                         self.personal.health = self.health;
 124                         self.personal.armorvalue = self.armorvalue;
 125                         self.personal.weapons = self.weapons;
 126                         self.personal.items = self.items;
 127                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 128                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 129                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 130                         self.personal.pauseregen_finished = self.pauseregen_finished;
 131                         self.personal.strength_finished = self.strength_finished;
 132                         self.personal.invincible_finished = self.invincible_finished;
 133                         self.personal.teleport_time = time;
 134                         break; // this part itself doesn't cheat, so let's not count this
 135                 case CHIMPULSE_CLONE_MOVING:
 136                         IS_CHEAT(i, 0, 0);
 137                         makevectors (self.v_angle);
 138                         self.velocity = self.velocity + v_forward * 300;
 139                         CopyBody(1);
 140                         self.lip += 1;
 141                         self.velocity = self.velocity - v_forward * 300;
 142                         DID_CHEAT();
 143                         break;
 144                 case CHIMPULSE_CLONE_STANDING:
 145                         IS_CHEAT(i, 0, 0);
 146                         CopyBody(0);
 147                         self.lip += 1;
 148                         DID_CHEAT();
 149                         break;
 150                 case CHIMPULSE_GIVE_ALL:
 151                         IS_CHEAT(i, 0, 0);
 152                         CheatCommand(tokenize_console("give all"));
 153                         break; // already counted as cheat
 154                 case CHIMPULSE_SPEEDRUN:
 155                         IS_CHEAT(i, 0, 0);
 156                         if(self.personal)
 157                         {
 158                                 self.speedrunning = TRUE;
 159                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 160                                 if(trace_startsolid)
 161                                 {
 162                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 163                                 }
 164                                 else
 165                                 {
 166                                         // Abort speedrun, teleport back
 167                                         setorigin(self, self.personal.origin);
 168                                         self.oldvelocity = self.velocity = self.personal.velocity;
 169                                         self.angles = self.personal.v_angle;
 170                                         self.fixangle = TRUE;
 171                                         if(self.flagcarried)
 172                                         {
 173                                                 bprint("The ", self.flagcarried.netname, " was returned to base by its carrier\n");
 174                                                 ReturnFlag(self.flagcarried);
 175                                         }
 176                                 }
 177                                 if(g_ctf)
 178                                 {
 179                                         self.ammo_rockets = 999;
 180                                         self.ammo_nails = 999;
 181                                         self.ammo_cells = 999;
 182                                         self.ammo_shells = 999;
 183                                         self.ammo_fuel = 999;
 184                                         self.health = start_health;
 185                                         self.armorvalue = start_armorvalue;
 186                                         self.weapons |= weaponsInMap;
 187                                         self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 188                                         self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 189                                         self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 190                                         self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 191                                         self.strength_finished = 0;
 192                                         self.invincible_finished = 0;
 193                                 }
 194                                 else
 195                                 {
 196                                         self.ammo_rockets = self.personal.ammo_rockets;
 197                                         self.ammo_nails = self.personal.ammo_nails;
 198                                         self.ammo_cells = self.personal.ammo_cells;
 199                                         self.ammo_shells = self.personal.ammo_shells;
 200                                         self.ammo_fuel = self.personal.ammo_fuel;
 201                                         self.health = self.personal.health;
 202                                         self.armorvalue = self.personal.armorvalue;
 203                                         self.weapons = self.personal.weapons;
 204                                         self.items = self.personal.items;
 205                                         self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 206                                         self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 207                                         self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 208                                         self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 209                                         self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 210                                         self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 211                                 }
 212                                 DID_CHEAT();
 213                                 break;
 214                         }
 215                         if(self.deadflag != DEAD_NO)
 216                                 sprint(self, "UR DEAD AHAHAH))\n");
 217                         else
 218                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 219                         break;
 220                 case CHIMPULSE_TELEPORT:
 221                         IS_CHEAT(i, 0, 0);
 222                         if(self.movetype == MOVETYPE_NOCLIP)
 223                         {
 224                                 e = find(world, classname, "info_autoscreenshot");
 225                                 if(e)
 226                                 {
 227                                         sprint(self, "Emergency teleport used info_autoscreenshot location\n");
 228                                         setorigin(self, e.origin);
 229                                         self.angles = e.angles;
 230                                         remove(e);
 231                                         // should we? self.angles_x = -self.angles_x;
 232                                         self.fixangle = TRUE;
 233                                         self.velocity = '0 0 0';
 234                                         DID_CHEAT();
 235                                         break;
 236                                 }
 237                         }
 238                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats >= 2) ? 100000 : 100), 1024, 256))
 239                         {
 240                                 sprint(self, "Emergency teleport used random location\n");
 241                                 self.angles_x = -self.angles_x;
 242                                 self.fixangle = TRUE;
 243                                 self.velocity = '0 0 0';
 244                                 DID_CHEAT();
 245                                 break;
 246                         }
 247                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 248                         break;
 249                 case CHIMPULSE_R00T:
 250                         IS_CHEAT(i, 0, 0);
 251                         FOR_EACH_PLAYER(e)
 252                         {
 253                                 get_model_parameters(e.playermodel, e.skin);
 254                                 if(get_model_parameters_sex == "Female")
 255                                 {
 256                                         makevectors(e.angles);
 257                                         traceline(e.origin, e.origin + v_right * 256, MOVE_NORMAL, e);
 258                                 }
 259                                 else
 260                                 {
 261                                         org_x = random();
 262                                         org_y = random();
 263                                         org_z = 0;
 264                                         org = normalize(org);
 265                                         traceline(e.origin, e.origin + org * 256, MOVE_NORMAL, e); // random direction
 266                                 }
 267
 268                                 org = findbetterlocation(trace_endpos, 12);
 269
 270                                 e2 = spawn();
 271                                 setorigin(e2, org);
 272                                 pointparticles(particleeffectnum("rocket_explode"), org, '0 0 0', 1);
 273                                 sound(e2, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 274                                 RadiusDamage(e2, e, 1000, 0, 128, e, 500, DEATH_CHEAT, world);
 275                                 remove(e2);
 276                         }
 277                         print("404 Sportsmanship not found.\n");
 278                         DID_CHEAT();
 279                         break;
 280         }
 281
 282         END_CHEAT_FUNCTION();
 283 }
 284
 285 void DragBox_Think();
 286 float drag_lastcnt;
 287 float CheatCommand(float argc)
 288 {
 289         BEGIN_CHEAT_FUNCTION();
 290         string cmd;
 291         cmd = argv(0);
 292         switch(cmd)
 293         {
 294                 entity e;
 295                 float effectnum, f;
 296                 vector start, end;
 297                 entity oldself;
 298
 299                 case "pointparticles":
 300                         IS_CHEAT(0, argc, 0);
 301                         if(argc == 5)
 302                         {
 303                                 // arguments:
 304                                 //   effectname
 305                                 //   origin (0..1, on crosshair line)
 306                                 //   velocity
 307                                 //   howmany
 308                                 effectnum = particleeffectnum(argv(1));
 309                                 f = stof(argv(2));
 310                                 crosshair_trace(self);
 311                                 start = (1-f) * self.origin + f * trace_endpos;
 312                                 end = stov(argv(3));
 313                                 f = stof(argv(4));
 314                                 pointparticles(effectnum, start, end, f);
 315                                 DID_CHEAT();
 316                                 break;
 317                         }
 318                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 319                         break;
 320                 case "trailparticles":
 321                         IS_CHEAT(0, argc, 0);
 322                         if(argc == 2)
 323                         {
 324                                 // arguments:
 325                                 //   effectname
 326                                 effectnum = particleeffectnum(argv(1));
 327                                 W_SetupShot(self, FALSE, FALSE, "", CH_WEAPON_A, 0);
 328                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 329                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 330                                 DID_CHEAT();
 331                                 break;
 332                         }
 333                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 334                         break;
 335                 case "make":
 336                         IS_CHEAT(0, argc, 0);
 337                         if(argc == 3)
 338                         {
 339                                 // arguments:
 340                                 //   modelname mode
 341                                 f = stof(argv(2));
 342                                 W_SetupShot(self, FALSE, FALSE, "", CH_WEAPON_A, 0);
 343                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 344                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 345                                 {
 346                                         sprint(self, "cannot make stuff there (bad surface)\n");
 347                                 }
 348                                 else
 349                                 {
 350                                         e = spawn();
 351                                         e.model = strzone(argv(1));
 352                                         e.mdl = "rocket_explode";
 353                                         e.health = 1000;
 354                                         setorigin(e, trace_endpos);
 355                                         e.effects = EF_NOMODELFLAGS;
 356                                         if(f == 1)
 357                                         {
 358                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 359                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 360                                         }
 361                                         oldself = self;
 362                                         self = e;
 363                                         spawnfunc_func_breakable();
 364                                         self = oldself;
 365                                         // now, is it valid?
 366                                         if(f == 0)
 367                                         {
 368                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 369                                                 if(trace_startsolid)
 370                                                 {
 371                                                         remove(e);
 372                                                         sprint(self, "cannot make stuff there (no space)\n");
 373                                                 }
 374                                                 else
 375                                                         DID_CHEAT();
 376                                         }
 377                                         else
 378                                                 DID_CHEAT();
 379                                 }
 380                         }
 381                         else
 382                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 383                         break;
 384                 case "penalty":
 385                         IS_CHEAT(0, argc, 0);
 386                         if(argc == 3)
 387                         {
 388                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 389                                 DID_CHEAT();
 390                                 break;
 391                         }
 392                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 393                         break;
 394                 case "dragbox_spawn":
 395                         IS_CHEAT(0, argc, 0);
 396                         e = spawn();
 397                         e.classname = "dragbox_box";
 398                         e.think = DragBox_Think;
 399                         e.nextthink = time;
 400                         e.solid = -1; // black
 401                         setmodel(e, "null"); // network it
 402                         if(argc == 4)
 403                                 e.cnt = stof(argv(1));
 404                         else
 405                                 e.cnt = max(0, drag_lastcnt);
 406
 407                         e.aiment = spawn();
 408                         e.aiment.classname = "dragbox_corner_1";
 409                         e.aiment.owner = e;
 410                         setmodel(e.aiment, "models/marker.md3");
 411                         e.aiment.skin = 0;
 412                         setsize(e.aiment, '0 0 0', '0 0 0');
 413                         if(argc == 4)
 414                                 setorigin(e.aiment, stov(argv(2)));
 415                         else
 416                         {
 417                                 crosshair_trace(self);
 418                                 setorigin(e.aiment, trace_endpos);
 419                         }
 420
 421                         e.enemy = spawn();
 422                         e.enemy.classname = "dragbox_corner_2";
 423                         e.enemy.owner = e;
 424                         setmodel(e.enemy, "models/marker.md3");
 425                         e.enemy.skin = 1;
 426                         setsize(e.enemy, '0 0 0', '0 0 0');
 427                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 428                         end_x = (end_x > 0) * 2 - 1;
 429                         end_y = (end_y > 0) * 2 - 1;
 430                         end_z = (end_z > 0) * 2 - 1;
 431                         if(argc == 4)
 432                                 setorigin(e.enemy, stov(argv(3)));
 433                         else
 434                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 435
 436                         e.killindicator = spawn();
 437                         e.killindicator.classname = "drag_digit";
 438                         e.killindicator.owner = e;
 439                         setattachment(e.killindicator, e, "");
 440                         setorigin(e.killindicator, '0 0 -8');
 441                         e.killindicator.killindicator = spawn();
 442                         e.killindicator.killindicator.classname = "drag_digit";
 443                         e.killindicator.killindicator.owner = e;
 444                         setattachment(e.killindicator.killindicator, e, "");
 445                         setorigin(e.killindicator.killindicator, '0 0 8');
 446                         DID_CHEAT();
 447                         break;
 448                 case "dragpoint_spawn":
 449                         IS_CHEAT(0, argc, 0);
 450                         e = spawn();
 451                         e.classname = "dragpoint";
 452                         e.think = DragBox_Think;
 453                         e.nextthink = time;
 454                         e.solid = 0; // nothing special
 455                         setmodel(e, "models/marker.md3");
 456                         setsize(e, PL_MIN, PL_MAX);
 457                         e.skin = 2;
 458                         if(argc == 3)
 459                                 e.cnt = stof(argv(1));
 460                         else
 461                                 e.cnt = drag_lastcnt;
 462                         if(argc == 3)
 463                                 setorigin(e, stov(argv(2)));
 464                         else
 465                         {
 466                                 crosshair_trace(self);
 467                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 468                                 move_out_of_solid(e);
 469                         }
 470
 471                         e.killindicator = spawn();
 472                         e.killindicator.classname = "drag_digit";
 473                         e.killindicator.owner = e;
 474                         setattachment(e.killindicator, e, "");
 475                         setorigin(e.killindicator, '0 0 40');
 476                         e.killindicator.killindicator = spawn();
 477                         e.killindicator.killindicator.classname = "drag_digit";
 478                         e.killindicator.killindicator.owner = e;
 479                         setattachment(e.killindicator.killindicator, e, "");
 480                         setorigin(e.killindicator.killindicator, '0 0 56');
 481                         DID_CHEAT();
 482                         break;
 483                 case "drag_remove":
 484                         IS_CHEAT(0, argc, 0);
 485                         RandomSelection_Init();
 486                         crosshair_trace(self);
 487                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 488                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 489                         for(e = world; (e = find(e, classname, "dragpoint")); )
 490                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 491                         if(RandomSelection_chosen_ent)
 492                         {
 493                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 494                                 remove(RandomSelection_chosen_ent.killindicator);
 495                                 if(RandomSelection_chosen_ent.aiment)
 496                                         remove(RandomSelection_chosen_ent.aiment);
 497                                 if(RandomSelection_chosen_ent.enemy)
 498                                         remove(RandomSelection_chosen_ent.enemy);
 499                                 remove(RandomSelection_chosen_ent);
 500                         }
 501                         DID_CHEAT();
 502                         break;
 503                 case "drag_setcnt":
 504                         IS_CHEAT(0, argc, 0);
 505                         if(argc == 2)
 506                         {
 507                                 RandomSelection_Init();
 508                                 crosshair_trace(self);
 509                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 510                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 511                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 512                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 513                                 if(RandomSelection_chosen_ent)
 514                                 {
 515                                         if(substring(argv(1), 0, 1) == "*")
 516                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 517                                         else
 518                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 519                                 }
 520                                 DID_CHEAT();
 521                                 break;
 522                         }
 523                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 524                         break;
 525                 case "drag_save":
 526                         IS_CHEAT(0, argc, 0);
 527                         if(argc == 2)
 528                         {
 529                                 f = fopen(argv(1), FILE_WRITE);
 530                                 fputs(f, "cmd drag_clear\n");
 531                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 532                                 {
 533                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 534                                 }
 535                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 536                                 {
 537                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 538                                 }
 539                                 fclose(f);
 540                                 DID_CHEAT();
 541                                 break;
 542                         }
 543                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 544                         break;
 545                 case "drag_saveraceent":
 546                         IS_CHEAT(0, argc, 0);
 547                         if(argc == 2)
 548                         {
 549                                 f = fopen(argv(1), FILE_WRITE);
 550                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 551                                 {
 552                                         fputs(f, "{\n");
 553                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 554                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin_x), " ", ftos(e.absmin_y), " ", ftos(e.absmin_z), "\"\n"));
 555                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax_x - e.absmin_x), " ", ftos(e.absmax_y - e.absmin_y), " ", ftos(e.absmax_z - e.absmin_z), "\"\n"));
 556                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 557                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 558                                         fputs(f, "}\n");
 559                                 }
 560                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 561                                 {
 562                                         start = '0 0 0';
 563                                         effectnum = 0;
 564                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 565                                         {
 566                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 567                                                 {
 568                                                         start = start + oldself.origin;
 569                                                         ++effectnum;
 570                                                 }
 571                                         }
 572                                         start *= 1 / effectnum;
 573                                         fputs(f, "{\n");
 574                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 575                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 576                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin_x), " ", ftos(e.origin_y), " ", ftos(e.origin_z), "\"\n"));
 577                                         if(e.cnt == -2)
 578                                         {
 579                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 580                                                 fputs(f, "\"race_place\" \"0\"\n");
 581                                         }
 582                                         else if(e.cnt == -1)
 583                                         {
 584                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 585                                                 fputs(f, "\"race_place\" \"-1\"\n");
 586                                         }
 587                                         else
 588                                         {
 589                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 590                                                 if(e.cnt == 0)
 591                                                 {
 592                                                         // these need race_place
 593                                                         // counting...
 594                                                         effectnum = 1;
 595                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 596                                                         if(oldself.cnt == 0)
 597                                                         {
 598                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 599                                                                         ++effectnum;
 600                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 601                                                                         ++effectnum;
 602                                                         }
 603                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 604                                                 }
 605                                         }
 606                                         fputs(f, "}\n");
 607                                 }
 608                                 fclose(f);
 609                                 DID_CHEAT();
 610                                 break;
 611                         }
 612                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 613                         break;
 614                 case "drag_clear":
 615                         IS_CHEAT(0, argc, 0);
 616                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 617                                 remove(e);
 618                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 619                                 remove(e);
 620                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 621                                 remove(e);
 622                         for(e = world; (e = find(e, classname, "dragpoint")); )
 623                                 remove(e);
 624                         for(e = world; (e = find(e, classname, "drag_digit")); )
 625                                 remove(e);
 626                         DID_CHEAT();
 627                         break;
 628                 case "god":
 629                         IS_CHEAT(0, argc, 0);
 630                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 631                         if(self.flags & FL_GODMODE)
 632                         {
 633                                 sprint(self, "godmode ON\n");
 634                                 DID_CHEAT();
 635                         }
 636                         else
 637                                 sprint(self, "godmode OFF\n");
 638                         break;
 639                 case "notarget":
 640                         IS_CHEAT(0, argc, 0);
 641                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 642                         if(self.flags & FL_NOTARGET)
 643                         {
 644                                 sprint(self, "notarget ON\n");
 645                                 DID_CHEAT();
 646                         }
 647                         else
 648                                 sprint(self, "notarget OFF\n");
 649                         break;
 650                 case "noclip":
 651                         IS_CHEAT(0, argc, 0);
 652                         if(self.movetype != MOVETYPE_NOCLIP)
 653                         {
 654                                 self.movetype = MOVETYPE_NOCLIP;
 655                                 sprint(self, "noclip ON\n");
 656                                 DID_CHEAT();
 657                         }
 658                         else
 659                         {
 660                                 self.movetype = MOVETYPE_WALK;
 661                                 sprint(self, "noclip OFF\n");
 662                         }
 663                         break;
 664                 case "fly":
 665                         IS_CHEAT(0, argc, 0);
 666                         if(self.movetype != MOVETYPE_FLY)
 667                         {
 668                                 self.movetype = MOVETYPE_FLY;
 669                                 sprint(self, "flymode ON\n");
 670                                 DID_CHEAT();
 671                         }
 672                         else
 673                         {
 674                                 self.movetype = MOVETYPE_WALK;
 675                                 sprint(self, "flymode OFF\n");
 676                         }
 677                         break;
 678                 case "give":
 679                         IS_CHEAT(0, argc, 0);
 680                         if(GiveItems(self, 1, argc))
 681                                 DID_CHEAT();
 682                         break;
 683         }
 684
 685         END_CHEAT_FUNCTION();
 686 }
 687
 688 float Drag(entity e, float grab, float ischeat);
 689 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 690 void Drag_Finish(entity dragger);
 691 float Drag_IsDraggable(entity draggee);
 692 float Drag_MayChangeAngles(entity draggee);
 693 void Drag_MoveForward(entity dragger);
 694 void Drag_SetSpeed(entity dragger, float s);
 695 void Drag_MoveBackward(entity dragger);
 696 void Drag_Update(entity dragger);
 697 float Drag_CanDrag(entity dragger);
 698 float Drag_IsDragging(entity dragger);
 699 void Drag_MoveDrag(entity from, entity to);
 700 .entity dragentity;
 701
 702 float CheatFrame()
 703 {
 704         BEGIN_CHEAT_FUNCTION();
 705
 706         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 707         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 708         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 709         // grabbing itself no longer being accounted as cheating.
 710
 711         switch(0)
 712         {
 713                 default:
 714                         if(self.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 715                         {
 716                                 // use cheat dragging if cheats are enabled
 717                                 crosshair_trace_plusvisibletriggers(self);
 718                                 Drag(trace_ent, TRUE, TRUE);
 719                         }
 720                         else
 721                         {
 722                                 // drag is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 723                                 // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 724                                 // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 725                                 // it goes out of range while slinging it around.
 726
 727                                 float drag;
 728                                 crosshair_trace_plusvisibletriggers(self);
 729                                 if(vlen(self.origin - trace_ent.origin) <= autocvar_g_grab_range)
 730                                 {
 731                                         switch(trace_ent.grab)
 732                                         {
 733                                                 case 0: // can't grab
 734                                                         break;
 735                                                 case 1: // owner can grab
 736                                                         if(trace_ent.owner == self || trace_ent.realowner == self)
 737                                                                 drag = TRUE;
 738                                                         break;
 739                                                 case 2: // owner and team mates can grab
 740                                                         if(!IsDifferentTeam(trace_ent.owner, self) || !IsDifferentTeam(trace_ent.realowner, self) || trace_ent.team == self.team)
 741                                                                 drag = TRUE;
 742                                                         break;
 743                                                 case 3: // anyone can grab
 744                                                         drag = TRUE;
 745                                                         break;
 746                                                 default:
 747                                                         break;
 748                                         }
 749                                 }
 750                                 Drag(trace_ent, drag, FALSE); // execute dragging
 751                         }
 752                         break;
 753         }
 754
 755         END_CHEAT_FUNCTION();
 756 }
 757
 758
 759
 760
 761
 762 // ENTITY DRAGGING
 763
 764 float Drag(entity e, float pick, float ischeat)
 765 {
 766         BEGIN_CHEAT_FUNCTION();
 767
 768         // returns TRUE when an entity has been picked up
 769         // If pick is TRUE, the object can also be picked up if it's not being held already
 770         // If pick is FALSE, only keep dragging the object if it's already being held
 771
 772         switch(0)
 773         {
 774                 default:
 775                         if(Drag_IsDragging(self))
 776                         {
 777                                 if(self.BUTTON_DRAG)
 778                                 {
 779                                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 780                                         {
 781                                                 Drag_MoveForward(self);
 782                                                 self.impulse = 0;
 783                                         }
 784                                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 785                                         {
 786                                                 Drag_MoveBackward(self);
 787                                                 self.impulse = 0;
 788                                         }
 789                                         else if(self.impulse >= 1 && self.impulse <= 9)
 790                                         {
 791                                                 Drag_SetSpeed(self, self.impulse - 1);
 792                                         }
 793                                         else if(self.impulse == 14)
 794                                         {
 795                                                 Drag_SetSpeed(self, 9);
 796                                         }
 797
 798                                         if(frametime)
 799                                                 Drag_Update(self);
 800                                 }
 801                                 else
 802                                 {
 803                                         Drag_Finish(self);
 804                                 }
 805                         }
 806                         else
 807                         {
 808                                 if(Drag_CanDrag(self))
 809                                         if(self.BUTTON_DRAG && pick)
 810                                         {
 811                                                 if(e)
 812                                                         if(Drag_IsDraggable(e))
 813                                                         {
 814                                                                 if(ischeat)
 815                                                                         IS_CHEAT(0, 0, CHRAME_DRAG);
 816                                                                 if(e.draggedby)
 817                                                                         Drag_Finish(e.draggedby);
 818                                                                 if(e.tag_entity)
 819                                                                         detach_sameorigin(e);
 820                                                                 Drag_Begin(self, e, trace_endpos);
 821                                                                 if(ischeat)
 822                                                                         DID_CHEAT();
 823                                                                 return TRUE;
 824                                                         }
 825                                         }
 826                         }
 827                         break;
 828         }
 829         return FALSE;
 830 }
 831
 832 // on dragger:
 833 .float draggravity;
 834 .float dragspeed; // speed of mouse wheel action
 835 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 836 .vector draglocalvector; // local attachment vector of the dragentity
 837 .float draglocalangle;
 838 // on draggee:
 839 .entity draggedby;
 840 .float dragmovetype;
 841 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 842 {
 843         float tagscale;
 844
 845         draggee.dragmovetype = draggee.movetype;
 846         draggee.draggravity = draggee.gravity;
 847         draggee.movetype = MOVETYPE_WALK;
 848         draggee.gravity = 0.00001;
 849         draggee.flags &~= FL_ONGROUND;
 850         draggee.draggedby = dragger;
 851
 852         dragger.dragentity = draggee;
 853
 854         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 855         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
 856         touchpoint = touchpoint - gettaginfo(draggee, 0);
 857         tagscale = pow(vlen(v_forward), -2);
 858         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 859         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 860         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 861
 862         dragger.dragspeed = 64;
 863 }
 864
 865 void Drag_Finish(entity dragger)
 866 {
 867         entity draggee;
 868         draggee = dragger.dragentity;
 869         if(dragger)
 870                 dragger.dragentity = world;
 871         draggee.draggedby = world;
 872         draggee.movetype = draggee.dragmovetype;
 873         draggee.gravity = draggee.draggravity;
 874
 875         switch(draggee.movetype)
 876         {
 877                 case MOVETYPE_TOSS:
 878                 case MOVETYPE_WALK:
 879                 case MOVETYPE_STEP:
 880                 case MOVETYPE_FLYMISSILE:
 881                 case MOVETYPE_BOUNCE:
 882                 case MOVETYPE_BOUNCEMISSILE:
 883                 case MOVETYPE_PHYSICS:
 884                         break;
 885                 default:
 886                         draggee.velocity = '0 0 0';
 887                         break;
 888         }
 889
 890         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 891         {
 892                 draggee.velocity = '0 0 0';
 893                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 894         }
 895 }
 896
 897 float Drag_IsDraggable(entity draggee)
 898 {
 899         // TODO add more checks for bad stuff here
 900         if(draggee == world)
 901                 return FALSE;
 902         if(draggee.classname == "func_bobbing")
 903                 return FALSE;
 904         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 905                 return FALSE;
 906         if(draggee.classname == "plat")
 907                 return FALSE;
 908         if(draggee.classname == "func_button")
 909                 return FALSE;
 910 //      if(draggee.model == "")
 911 //              return FALSE;
 912         if(draggee.classname == "spectator")
 913                 return FALSE;
 914         if(draggee.classname == "observer")
 915                 return FALSE;
 916         if(draggee.classname == "exteriorweaponentity")
 917                 return FALSE;
 918         if(draggee.classname == "weaponentity")
 919                 return FALSE;
 920
 921         return TRUE;
 922 }
 923
 924 float Drag_MayChangeAngles(entity draggee)
 925 {
 926         // TODO add more checks for bad stuff here
 927         if(substring(draggee.model, 0, 1) == "*")
 928                 return FALSE;
 929         return TRUE;
 930 }
 931
 932 void Drag_MoveForward(entity dragger)
 933 {
 934         dragger.dragdistance += dragger.dragspeed;
 935 }
 936
 937 void Drag_SetSpeed(entity dragger, float s)
 938 {
 939         dragger.dragspeed = pow(2, s);
 940 }
 941
 942 void Drag_MoveBackward(entity dragger)
 943 {
 944         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 945 }
 946
 947 void Drag_Update(entity dragger)
 948 {
 949         vector curorigin, neworigin, goodvelocity;
 950         float f;
 951         entity draggee;
 952
 953         draggee = dragger.dragentity;
 954         draggee.flags &~= FL_ONGROUND;
 955
 956         curorigin = gettaginfo(draggee, 0);
 957         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
 958         makevectors(dragger.v_angle);
 959         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 960         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 961
 962         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
 963                 dragger.draglocalangle += 360;
 964         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
 965                 dragger.draglocalangle -= 360;
 966
 967         f = min(frametime * 10, 1);
 968         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
 969
 970         if(Drag_MayChangeAngles(draggee))
 971                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
 972
 973         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
 974
 975         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
 976 }
 977
 978 float Drag_CanDrag(entity dragger)
 979 {
 980         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
 981 }
 982
 983 float Drag_IsDragging(entity dragger)
 984 {
 985         if(!dragger.dragentity)
 986                 return FALSE;
 987         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
 988         {
 989                 dragger.dragentity = world;
 990                 return FALSE;
 991         }
 992         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
 993         {
 994                 Drag_Finish(dragger);
 995                 return FALSE;
 996         }
 997         return TRUE;
 998 }
 999
1000 void Drag_MoveDrag(entity from, entity to)
1001 {
1002         if(from.draggedby)
1003         {
1004                 to.draggedby = from.draggedby;
1005                 to.draggedby.dragentity = to;
1006                 from.draggedby = world;
1007         }
1008 }
1009
1010 void DragBox_Think()
1011 {
1012         if(self.aiment && self.enemy)
1013         {
1014                 self.origin_x = (self.aiment.origin_x + self.enemy.origin_x) * 0.5;
1015                 self.origin_y = (self.aiment.origin_y + self.enemy.origin_y) * 0.5;
1016                 self.origin_z = (self.aiment.origin_z + self.enemy.origin_z) * 0.5;
1017                 self.maxs_x = fabs(self.aiment.origin_x - self.enemy.origin_x) * 0.5;
1018                 self.maxs_y = fabs(self.aiment.origin_y - self.enemy.origin_y) * 0.5;
1019                 self.maxs_z = fabs(self.aiment.origin_z - self.enemy.origin_z) * 0.5;
1020                 self.mins = -1 * self.maxs;
1021                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
1022         }
1023
1024         if(self.cnt == -1) // actually race_place -1
1025         {
1026                 // show "10 10" for qualifying spawns
1027                 setmodel(self.killindicator, "models/sprites/10.spr32");
1028                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
1029         }
1030         else if(self.cnt == -2) // actually race_place 0
1031         {
1032                 // show "10 0" for loser spawns
1033                 setmodel(self.killindicator, "models/sprites/10.spr32");
1034                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
1035         }
1036         else
1037         {
1038                 setmodel(self.killindicator, strcat("models/sprites/", ftos(mod(self.cnt, 10)), ".spr32"));
1039                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
1040         }
1041
1042         self.nextthink = time;
1043 }
1044
1045 #endif