qcsrc/server/campaign.qc

   1 #include "campaign.qh"
   2
   3 #include "defs.qh"
   4
   5 #include "cheats.qh"
   6 #include "miscfunctions.qh"
   7 #include "g_world.qh"
   8
   9 #include "../common/campaign_common.qh"
  10
  11 // campaign cvars:
  12 //   _campaign_index: index of CURRENT map
  13 //   _campaign_name: name of the current campaign
  14 //   g_campaign(name) _index: index of current LAST map (saved)
  15 //   g_campaign_skill: bot skill offset
  16
  17 float campaign_level;
  18 float campaign_won;
  19 string campaign_index_var;
  20 // float checkrules_equality;
  21
  22 float CampaignBailout(string s)
  23 {
  24         cvar = cvar_normal;
  25         cvar_string = cvar_string_normal;
  26         cvar_set = cvar_set_normal;
  27         cvar_set("g_campaign", "0");
  28         LOG_INFO("^4campaign initialization failed: ", s);
  29         if (autocvar__campaign_testrun) {
  30                 error("CAMPAIGN FAIL AHAHAHAHAHAHAHAHAH))");
  31         }
  32         return 1;
  33 }
  34
  35 string cvar_campaignwrapper_list; // string of format ; var value; var value; var value;
  36 string cvar_string_campaignwrapper(string theCvar)
  37 {
  38         float p, q;
  39         p = strstrofs(cvar_campaignwrapper_list, strcat("; ", theCvar, " "), 0);
  40         if (p < 0) {
  41                 return cvar_defstring(theCvar);
  42         }
  43         p += strlen(theCvar) + 3;
  44         q = strstrofs(cvar_campaignwrapper_list, ";", p);
  45         if (q < 0) {
  46                 return cvar_defstring(theCvar);
  47         }
  48         return substring(cvar_campaignwrapper_list, p, q - p);
  49 }
  50 float cvar_campaignwrapper(string theCvar)
  51 {
  52         return stof(cvar_string_campaignwrapper(theCvar));
  53 }
  54 void cvar_set_campaignwrapper(string theCvar, string theValue)
  55 {
  56         if (cvar_string_campaignwrapper(theCvar) == theValue) {
  57                 return;
  58         }
  59         string s;
  60         s = cvar_campaignwrapper_list;
  61         cvar_campaignwrapper_list = strzone(strcat("; ", theCvar, " ", theValue, s));
  62         strunzone(s);
  63         // print(cvar_campaignwrapper_list, "\n");
  64 }
  65
  66 float Campaign_Invalid()
  67 {
  68         string thismapname, wantedmapname;
  69         thismapname = GetMapname();
  70         wantedmapname = campaign_gametype[0];
  71         if (MapInfo_CurrentGametype() != MapInfo_Type_FromString(wantedmapname)) {
  72                 return CampaignBailout("wrong game type!");
  73         }
  74         wantedmapname = campaign_mapname[0];
  75         if (wantedmapname != thismapname) {
  76                 return CampaignBailout(strcat("wrong map: ", wantedmapname, " != ", thismapname));
  77         }
  78         return 0;
  79 }
  80
  81 void CampaignPreInit()
  82 {
  83         float baseskill;
  84         string title;
  85         campaign_level = autocvar__campaign_index;
  86         campaign_name = strzone(autocvar__campaign_name);
  87         campaign_index_var = strzone(strcat("g_campaign", campaign_name, "_index"));
  88         CampaignFile_Load(campaign_level, 2);
  89
  90         if (campaign_entries < 1) {
  91                 CampaignBailout("unknown map");
  92                 return;
  93         }
  94
  95         if (autocvar_sv_cheats) {
  96                 MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0]));
  97                 CampaignFile_Unload();
  98                 CampaignBailout("JOLLY CHEATS AHAHAHAHAHAHAH))");
  99                 return;
 100         }
 101
 102         baseskill = autocvar_g_campaign_skill;
 103         baseskill = baseskill + campaign_botskill[0];
 104         if (baseskill < 0) {
 105                 baseskill = 0;
 106         }
 107
 108         cvar_set("sv_public", "0");
 109         cvar_set("pausable", "1");
 110
 111         cvar_campaignwrapper_list = strzone(strcat("; ", campaign_mutators[0], "; "));
 112
 113         cvar = cvar_campaignwrapper;
 114         cvar_string = cvar_string_campaignwrapper;
 115         cvar_set = cvar_set_campaignwrapper;
 116
 117         cvar_set("g_campaign", "1");
 118         cvar_set("g_dm", "0");
 119         cvar_set("skill", ftos(baseskill));
 120         cvar_set("bot_number", ftos(campaign_bots[0]));
 121         MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0]));
 122
 123         // copy sv_gravity cvar, as the engine needs it too (sorry, this will mess
 124         // with the menu a little still...)
 125         cvar_set_normal("sv_gravity", ftos(autocvar_sv_gravity));
 126
 127         if (Campaign_Invalid()) {
 128                 return;
 129         }
 130
 131         title = campaign_shortdesc[0];
 132         title = strzone(strcat("Level ", ftos(campaign_level + 1), ": ", title));
 133         campaign_message = strzone(strcat(title, "\n^3\n", campaign_longdesc[0], "\n\n^1press jump to enter the game"));
 134         strunzone(title);
 135 }
 136
 137 void CampaignPostInit()
 138 {
 139         // now some sanity checks
 140         if (Campaign_Invalid()) {
 141                 return;
 142         }
 143         if (autocvar__campaign_testrun) {
 144                 cvar_set("fraglimit", "0");
 145                 cvar_set("timelimit", "0.01");
 146                 cvar_set_normal("fraglimit", "0");
 147                 cvar_set_normal("timelimit", "0.01");
 148         } else {
 149                 cvar_set("fraglimit", ftos(campaign_fraglimit[0]));
 150                 cvar_set("timelimit", ftos(campaign_timelimit[0]));
 151                 cvar_set_normal("fraglimit", ftos(campaign_fraglimit[0]));
 152                 cvar_set_normal("timelimit", ftos(campaign_timelimit[0]));
 153         }
 154 }
 155
 156 void CampaignSaveCvar(string cvarname, float value)
 157 {
 158         float fh;
 159         float len;
 160         string contents;
 161         string l;
 162
 163         registercvar(cvarname, ftos(value));
 164         cvar_set_normal(cvarname, ftos(value));
 165         // note: cvarname must be remembered
 166
 167         fh = fopen("campaign.cfg", FILE_READ);
 168         contents = "";
 169         if (fh >= 0) {
 170                 while ((l = fgets(fh))) {
 171                         len = tokenize_console(l);
 172                         if (len != 3) {
 173                                 continue;
 174                         }
 175                         if (argv(0) != "set") {
 176                                 continue;
 177                         }
 178                         if (argv(1) == cvarname) {
 179                                 continue;
 180                         }
 181                         contents = strcat(contents, "set ", argv(1), " ", argv(2), "\n");
 182                 }
 183                 fclose(fh);
 184         }
 185         contents = strcat(contents, "set ", cvarname,  " ", ftos(value), "\n");
 186         fh = fopen("campaign.cfg", FILE_WRITE);
 187         if (fh >= 0) {
 188                 fputs(fh, contents);
 189         } else {
 190                 error("Cannot write to campaign file");
 191         }
 192 }
 193
 194 void CampaignPreIntermission()
 195 {
 196         int won = 0;
 197         int lost = 0;
 198         string savevar;
 199
 200         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 201                 if (it.winning) {
 202                         won += 1;
 203                 } else {
 204                         lost += 1;
 205                 }
 206         });
 207
 208         if (autocvar__campaign_testrun) {
 209                 campaign_won = 1;
 210                 bprint("Campaign test run, advancing level.\n");
 211         } else if (won == 1 && lost == 0 && checkrules_equality == 0) {
 212                 if (autocvar_timelimit != 0 && autocvar_fraglimit != 0 && time > autocvar_timelimit * 60) { // checks if the timelimit has expired.
 213                         campaign_won = 0;
 214                         bprint("Time's up! The current level has been LOST.\n");
 215                         // sound!
 216                 } else {
 217                         campaign_won = 1;
 218                         bprint("The current level has been WON.\n");
 219                         // sound!
 220                 }
 221         } else if (autocvar_timelimit != 0 && time > autocvar_timelimit * 60) {
 222                 campaign_won = 0;
 223                 bprint("Time's up! The current level has been LOST.\n");
 224                 // sound!
 225         } else {
 226                 campaign_won = 0;
 227                 bprint("The current level has been LOST.\n");
 228                 // sound!
 229         }
 230
 231         if (campaign_won && cheatcount_total == 0 && !autocvar__campaign_testrun) {
 232                 if (campaign_level == cvar_normal(campaign_index_var)) {
 233                         if (campaign_entries < 2) {
 234                                 // I have won
 235                                 savevar = strcat("g_campaign", campaign_name, "_won");
 236                                 CampaignSaveCvar(savevar, 1);
 237                                 // advance level (for menu to show it right)
 238                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 239                         } else {
 240                                 // advance level
 241                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 242                         }
 243                 }
 244         }
 245 }
 246
 247 void CampaignPostIntermission()
 248 {
 249         // NOTE: campaign_won is 0 or 1, that is, points to the next level
 250
 251         if (campaign_won && campaign_entries < 2) {
 252                 // last map won!
 253                 LOG_DEBUG("^2test run: campaign looks GOOD");
 254                 localcmd("togglemenu 1\n");
 255                 CampaignFile_Unload();
 256                 return;
 257         }
 258
 259         CampaignSetup(campaign_won);
 260         CampaignFile_Unload();
 261         strunzone(campaign_message);
 262         strunzone(campaign_index_var);
 263         strunzone(campaign_name);
 264         campaign_name = "";
 265 }
 266
 267
 268 void CampaignLevelWarp(float n)
 269 {
 270         if (n < 0) {
 271                 n = campaign_level + 1;
 272         }
 273         CampaignFile_Unload();
 274         CampaignFile_Load(n, 1);
 275         if (campaign_entries) {
 276                 CampaignSetup(0);
 277         } else {
 278                 error("Sorry, cheater. You are NOT WELCOME.");
 279         }
 280         CampaignFile_Unload();
 281 }