qcsrc/server/bot/waypoints.qc

   1 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
   2 // them back to it as well
   3 // (suitable for spawnfunc_waypoint editor)
   4 entity waypoint_spawn(vector m1, vector m2, float f)
   5 {
   6         entity w;
   7         w = find(world, classname, "waypoint");
   8
   9         if not(f & WAYPOINTFLAG_PERSONAL)
  10         while (w)
  11         {
  12                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
  13                 if (boxesoverlap(m1, m2, w.absmin, w.absmax))
  14                         return w;
  15                 w = find(w, classname, "waypoint");
  16         }
  17
  18         w = spawn();
  19         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
  20         w.classname = "waypoint";
  21         w.wpflags = f;
  22         setorigin(w, (m1 + m2) * 0.5);
  23         setsize(w, m1 - w.origin, m2 - w.origin);
  24         if (vlen(w.size) > 0)
  25                 w.wpisbox = TRUE;
  26
  27         if(!w.wpisbox)
  28         {
  29                 setsize(w, PL_MIN - '1 1 0', PL_MAX + '1 1 0');
  30                 if(!move_out_of_solid(w))
  31                 {
  32                         if(!(f & WAYPOINTFLAG_GENERATED))
  33                         {
  34                                 dprint("Killed a waypoint that was stuck in solid at ", vtos(w.origin), "\n");
  35                                 remove(w);
  36                                 return world;
  37                         }
  38                         else
  39                         {
  40                                 if(autocvar_developer)
  41                                 {
  42                                         print("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
  43                                         backtrace("Waypoint stuck");
  44                                 }
  45                         }
  46                 }
  47                 setsize(w, '0 0 0', '0 0 0');
  48         }
  49
  50         waypoint_clearlinks(w);
  51         //waypoint_schedulerelink(w);
  52
  53         if (autocvar_g_waypointeditor)
  54         {
  55                 m1 = w.mins;
  56                 m2 = w.maxs;
  57                 setmodel(w, "models/runematch/rune.mdl"); w.effects = EF_LOWPRECISION;
  58                 setsize(w, m1, m2);
  59                 if (w.wpflags & WAYPOINTFLAG_ITEM)
  60                         w.colormod = '1 0 0';
  61                 else if (w.wpflags & WAYPOINTFLAG_GENERATED)
  62                         w.colormod = '1 1 0';
  63                 else
  64                         w.colormod = '1 1 1';
  65         }
  66         else
  67                 w.model = "";
  68
  69         return w;
  70 }
  71
  72 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
  73 void waypoint_addlink(entity from, entity to)
  74 {
  75         float c;
  76
  77         if (from == to)
  78                 return;
  79         if (from.wpflags & WAYPOINTFLAG_NORELINK)
  80                 return;
  81
  82         if (from.wp00 == to) return;if (from.wp01 == to) return;if (from.wp02 == to) return;if (from.wp03 == to) return;
  83         if (from.wp04 == to) return;if (from.wp05 == to) return;if (from.wp06 == to) return;if (from.wp07 == to) return;
  84         if (from.wp08 == to) return;if (from.wp09 == to) return;if (from.wp10 == to) return;if (from.wp11 == to) return;
  85         if (from.wp12 == to) return;if (from.wp13 == to) return;if (from.wp14 == to) return;if (from.wp15 == to) return;
  86         if (from.wp16 == to) return;if (from.wp17 == to) return;if (from.wp18 == to) return;if (from.wp19 == to) return;
  87         if (from.wp20 == to) return;if (from.wp21 == to) return;if (from.wp22 == to) return;if (from.wp23 == to) return;
  88         if (from.wp24 == to) return;if (from.wp25 == to) return;if (from.wp26 == to) return;if (from.wp27 == to) return;
  89         if (from.wp28 == to) return;if (from.wp29 == to) return;if (from.wp30 == to) return;if (from.wp31 == to) return;
  90
  91         if (to.wpisbox || from.wpisbox)
  92         {
  93                 // if either is a box we have to find the nearest points on them to
  94                 // calculate the distance properly
  95                 vector v1, v2, m1, m2;
  96                 v1 = from.origin;
  97                 m1 = to.absmin;
  98                 m2 = to.absmax;
  99                 v1_x = bound(m1_x, v1_x, m2_x);
 100                 v1_y = bound(m1_y, v1_y, m2_y);
 101                 v1_z = bound(m1_z, v1_z, m2_z);
 102                 v2 = to.origin;
 103                 m1 = from.absmin;
 104                 m2 = from.absmax;
 105                 v2_x = bound(m1_x, v2_x, m2_x);
 106                 v2_y = bound(m1_y, v2_y, m2_y);
 107                 v2_z = bound(m1_z, v2_z, m2_z);
 108                 v2 = to.origin;
 109                 c = vlen(v2 - v1);
 110         }
 111         else
 112                 c = vlen(to.origin - from.origin);
 113
 114         if (from.wp31mincost < c) return;
 115         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 116         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 117         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 118         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 119         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 120         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 121         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 122         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 123         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 124         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 125         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 126         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 127         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 128         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 129         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 130         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 131         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 132         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 133         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 134         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 135         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 136         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 137         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 138         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 139         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 140         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 141         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 142         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 143         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 144         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 145         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 146         from.wp00 = to;from.wp00mincost = c;return;
 147 }
 148
 149 // relink this spawnfunc_waypoint
 150 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 151 // (SLOW!)
 152 void waypoint_think()
 153 {
 154         entity e;
 155         vector sv, sm1, sm2, ev, em1, em2, dv;
 156
 157         bot_calculate_stepheightvec();
 158
 159         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 160
 161         //dprint("waypoint_think wpisbox = ", ftos(self.wpisbox), "\n");
 162         sm1 = self.origin + self.mins;
 163         sm2 = self.origin + self.maxs;
 164         for(e = world; (e = find(e, classname, "waypoint")); )
 165         {
 166                 if (boxesoverlap(self.absmin, self.absmax, e.absmin, e.absmax))
 167                 {
 168                         waypoint_addlink(self, e);
 169                         waypoint_addlink(e, self);
 170                 }
 171                 else
 172                 {
 173                         ++relink_total;
 174                         if(!checkpvs(self.origin, e))
 175                         {
 176                                 ++relink_pvsculled;
 177                                 continue;
 178                         }
 179                         sv = e.origin;
 180                         sv_x = bound(sm1_x, sv_x, sm2_x);
 181                         sv_y = bound(sm1_y, sv_y, sm2_y);
 182                         sv_z = bound(sm1_z, sv_z, sm2_z);
 183                         ev = self.origin;
 184                         em1 = e.origin + e.mins;
 185                         em2 = e.origin + e.maxs;
 186                         ev_x = bound(em1_x, ev_x, em2_x);
 187                         ev_y = bound(em1_y, ev_y, em2_y);
 188                         ev_z = bound(em1_z, ev_z, em2_z);
 189                         dv = ev - sv;
 190                         dv_z = 0;
 191                         if (vlen(dv) >= 1050) // max search distance in XY
 192                         {
 193                                 ++relink_lengthculled;
 194                                 continue;
 195                         }
 196                         navigation_testtracewalk = 0;
 197                         if (!self.wpisbox)
 198                         {
 199                                 tracebox(sv - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, sv, FALSE, self);
 200                                 if (!trace_startsolid)
 201                                 {
 202                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 203                                         sv = trace_endpos + '0 0 1';
 204                                 }
 205                         }
 206                         if (!e.wpisbox)
 207                         {
 208                                 tracebox(ev - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, ev, FALSE, e);
 209                                 if (!trace_startsolid)
 210                                 {
 211                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 212                                         ev = trace_endpos + '0 0 1';
 213                                 }
 214                         }
 215                         //traceline(self.origin, e.origin, FALSE, world);
 216                         //if (trace_fraction == 1)
 217                         if (!self.wpisbox && tracewalk(self, sv, PL_MIN, PL_MAX, ev, MOVE_NOMONSTERS))
 218                                 waypoint_addlink(self, e);
 219                         else
 220                                 relink_walkculled += 0.5;
 221                         if (!e.wpisbox && tracewalk(e, ev, PL_MIN, PL_MAX, sv, MOVE_NOMONSTERS))
 222                                 waypoint_addlink(e, self);
 223                         else
 224                                 relink_walkculled += 0.5;
 225                 }
 226         }
 227         navigation_testtracewalk = 0;
 228         self.wplinked = TRUE;
 229 }
 230
 231 void waypoint_clearlinks(entity wp)
 232 {
 233         // clear links to other waypoints
 234         float f;
 235         f = 10000000;
 236         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = world;
 237         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = world;
 238         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = world;
 239         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = world;
 240
 241         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 242         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 243         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 244         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 245
 246         wp.wplinked = FALSE;
 247 }
 248
 249 // tell a spawnfunc_waypoint to relink
 250 void waypoint_schedulerelink(entity wp)
 251 {
 252         if (wp == world)
 253                 return;
 254         // TODO: add some sort of visible box in edit mode for box waypoints
 255         if (autocvar_g_waypointeditor)
 256         {
 257                 vector m1, m2;
 258                 m1 = wp.mins;
 259                 m2 = wp.maxs;
 260                 setmodel(wp, "models/runematch/rune.mdl"); wp.effects = EF_LOWPRECISION;
 261                 setsize(wp, m1, m2);
 262                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 263                         wp.colormod = '1 0 0';
 264                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 265                         wp.colormod = '1 1 0';
 266                 else
 267                         wp.colormod = '1 1 1';
 268         }
 269         else
 270                 wp.model = "";
 271         wp.wpisbox = vlen(wp.size) > 0;
 272         wp.enemy = world;
 273         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 274                 wp.owner = world;
 275         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 276                 waypoint_clearlinks(wp);
 277         // schedule an actual relink on next frame
 278         wp.think = waypoint_think;
 279         wp.nextthink = time;
 280         wp.effects = EF_LOWPRECISION;
 281 }
 282
 283 // spawnfunc_waypoint map entity
 284 void spawnfunc_waypoint()
 285 {
 286         setorigin(self, self.origin);
 287         // schedule a relink after other waypoints have had a chance to spawn
 288         waypoint_clearlinks(self);
 289         //waypoint_schedulerelink(self);
 290 }
 291
 292 // remove a spawnfunc_waypoint, and schedule all neighbors to relink
 293 void waypoint_remove(entity e)
 294 {
 295         // tell all linked waypoints that they need to relink
 296         waypoint_schedulerelink(e.wp00);
 297         waypoint_schedulerelink(e.wp01);
 298         waypoint_schedulerelink(e.wp02);
 299         waypoint_schedulerelink(e.wp03);
 300         waypoint_schedulerelink(e.wp04);
 301         waypoint_schedulerelink(e.wp05);
 302         waypoint_schedulerelink(e.wp06);
 303         waypoint_schedulerelink(e.wp07);
 304         waypoint_schedulerelink(e.wp08);
 305         waypoint_schedulerelink(e.wp09);
 306         waypoint_schedulerelink(e.wp10);
 307         waypoint_schedulerelink(e.wp11);
 308         waypoint_schedulerelink(e.wp12);
 309         waypoint_schedulerelink(e.wp13);
 310         waypoint_schedulerelink(e.wp14);
 311         waypoint_schedulerelink(e.wp15);
 312         waypoint_schedulerelink(e.wp16);
 313         waypoint_schedulerelink(e.wp17);
 314         waypoint_schedulerelink(e.wp18);
 315         waypoint_schedulerelink(e.wp19);
 316         waypoint_schedulerelink(e.wp20);
 317         waypoint_schedulerelink(e.wp21);
 318         waypoint_schedulerelink(e.wp22);
 319         waypoint_schedulerelink(e.wp23);
 320         waypoint_schedulerelink(e.wp24);
 321         waypoint_schedulerelink(e.wp25);
 322         waypoint_schedulerelink(e.wp26);
 323         waypoint_schedulerelink(e.wp27);
 324         waypoint_schedulerelink(e.wp28);
 325         waypoint_schedulerelink(e.wp29);
 326         waypoint_schedulerelink(e.wp30);
 327         waypoint_schedulerelink(e.wp31);
 328         // and now remove the spawnfunc_waypoint
 329         remove(e);
 330 }
 331
 332 // empties the map of waypoints
 333 void waypoint_removeall()
 334 {
 335         entity head, next;
 336         head = findchain(classname, "waypoint");
 337         while (head)
 338         {
 339                 next = head.chain;
 340                 remove(head);
 341                 head = next;
 342         }
 343 }
 344
 345 // tell all waypoints to relink
 346 // (is this useful at all?)
 347 void waypoint_schedulerelinkall()
 348 {
 349         entity head;
 350         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 351         head = findchain(classname, "waypoint");
 352         while (head)
 353         {
 354                 waypoint_schedulerelink(head);
 355                 head = head.chain;
 356         }
 357 }
 358
 359 // Load waypoint links from file
 360 float waypoint_load_links()
 361 {
 362         string filename, s;
 363         float file, tokens, c = 0, found;
 364         entity wp_from = world, wp_to;
 365         vector wp_to_pos, wp_from_pos;
 366         filename = strcat("maps/", mapname);
 367         filename = strcat(filename, ".waypoints.cache");
 368         file = fopen(filename, FILE_READ);
 369
 370         if (file < 0)
 371         {
 372                 dprint("waypoint links load from ");
 373                 dprint(filename);
 374                 dprint(" failed\n");
 375                 return FALSE;
 376         }
 377
 378         while (1)
 379         {
 380                 s = fgets(file);
 381                 if (!s)
 382                         break;
 383
 384                 tokens = tokenizebyseparator(s, "*");
 385
 386                 if (tokens!=2)
 387                 {
 388                         // bad file format
 389                         fclose(file);
 390                         return FALSE;
 391                 }
 392
 393                 wp_from_pos     = stov(argv(0));
 394                 wp_to_pos       = stov(argv(1));
 395
 396                 // Search "from" waypoint
 397                 if(wp_from && wp_from.origin!=wp_from_pos)
 398                 {
 399                         wp_from = findradius(wp_from_pos, 1);
 400                         found = FALSE;
 401                         while(wp_from)
 402                         {
 403                                 if(vlen(wp_from.origin-wp_from_pos)<1)
 404                                 if(wp_from.classname == "waypoint")
 405                                 {
 406                                         found = TRUE;
 407                                         break;
 408                                 }
 409                                 wp_from = wp_from.chain;
 410                         }
 411
 412                         if(!found)
 413                         {
 414                                 dprint("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from.origin),"\n");
 415                                 continue;
 416                         }
 417
 418                 }
 419
 420                 // Search "to" waypoint
 421                 wp_to = findradius(wp_to_pos, 1);
 422                 found = FALSE;
 423                 while(wp_to)
 424                 {
 425                         if(vlen(wp_to.origin-wp_to_pos)<1)
 426                         if(wp_to.classname == "waypoint")
 427                         {
 428                                 found = TRUE;
 429                                 break;
 430                         }
 431                         wp_to = wp_to.chain;
 432                 }
 433
 434                 if(!found)
 435                 {
 436                         dprint("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to.origin),"\n");
 437                         continue;
 438                 }
 439
 440                 ++c;
 441                 waypoint_addlink(wp_from, wp_to);
 442         }
 443
 444         fclose(file);
 445
 446         dprint("loaded ");
 447         dprint(ftos(c));
 448         dprint(" waypoint links from maps/");
 449         dprint(mapname);
 450         dprint(".waypoints.cache\n");
 451
 452         botframe_cachedwaypointlinks = TRUE;
 453         return TRUE;
 454 }
 455
 456 void waypoint_load_links_hardwired()
 457 {
 458         string filename, s;
 459         float file, tokens, c = 0, found;
 460         entity wp_from = world, wp_to;
 461         vector wp_to_pos, wp_from_pos;
 462         filename = strcat("maps/", mapname);
 463         filename = strcat(filename, ".waypoints.hardwired");
 464         file = fopen(filename, FILE_READ);
 465
 466         botframe_loadedforcedlinks = TRUE;
 467
 468         if (file < 0)
 469         {
 470                 dprint("waypoint links load from ");
 471                 dprint(filename);
 472                 dprint(" failed\n");
 473                 return;
 474         }
 475
 476         for (;;)
 477         {
 478                 s = fgets(file);
 479                 if (!s)
 480                         break;
 481
 482                 if(substring(s, 0, 2)=="//")
 483                         continue;
 484
 485                 if(substring(s, 0, 1)=="#")
 486                         continue;
 487
 488                 tokens = tokenizebyseparator(s, "*");
 489
 490                 if (tokens!=2)
 491                         continue;
 492
 493                 wp_from_pos     = stov(argv(0));
 494                 wp_to_pos       = stov(argv(1));
 495
 496                 // Search "from" waypoint
 497                 if(wp_from && wp_from.origin!=wp_from_pos)
 498                 {
 499                         wp_from = findradius(wp_from_pos, 5);
 500                         found = FALSE;
 501                         while(wp_from)
 502                         {
 503                                 if(vlen(wp_from.origin-wp_from_pos)<5)
 504                                 if(wp_from.classname == "waypoint")
 505                                 {
 506                                         found = TRUE;
 507                                         break;
 508                                 }
 509                                 wp_from = wp_from.chain;
 510                         }
 511
 512                         if(!found)
 513                         {
 514                                 print(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 515                                 continue;
 516                         }
 517                 }
 518
 519                 // Search "to" waypoint
 520                 wp_to = findradius(wp_to_pos, 5);
 521                 found = FALSE;
 522                 while(wp_to)
 523                 {
 524                         if(vlen(wp_to.origin-wp_to_pos)<5)
 525                         if(wp_to.classname == "waypoint")
 526                         {
 527                                 found = TRUE;
 528                                 break;
 529                         }
 530                         wp_to = wp_to.chain;
 531                 }
 532
 533                 if(!found)
 534                 {
 535                         print(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 536                         continue;
 537                 }
 538
 539                 ++c;
 540                 waypoint_addlink(wp_from, wp_to);
 541                 wp_from.wphardwired = TRUE;
 542                 wp_to.wphardwired = TRUE;
 543         }
 544
 545         fclose(file);
 546
 547         dprint("loaded ");
 548         dprint(ftos(c));
 549         dprint(" waypoint links from maps/");
 550         dprint(mapname);
 551         dprint(".waypoints.hardwired\n");
 552 }
 553
 554 // Save all waypoint links to a file
 555 void waypoint_save_links()
 556 {
 557         string filename, s;
 558         float file, c, i;
 559         entity w, link;
 560         filename = strcat("maps/", mapname);
 561         filename = strcat(filename, ".waypoints.cache");
 562         file = fopen(filename, FILE_WRITE);
 563         if (file < 0)
 564         {
 565                 print("waypoint links save to ");
 566                 print(filename);
 567                 print(" failed\n");
 568         }
 569         c = 0;
 570         w = findchain(classname, "waypoint");
 571         while (w)
 572         {
 573                 for(i=0;i<32;++i)
 574                 {
 575                         // :S
 576                         link = world;
 577                         switch(i)
 578                         {
 579                                 //      for i in $(seq -w 0 31); do echo "case $i:link = w.wp$i; break;"; done;
 580                                 case  0:link = w.wp00; break;
 581                                 case  1:link = w.wp01; break;
 582                                 case  2:link = w.wp02; break;
 583                                 case  3:link = w.wp03; break;
 584                                 case  4:link = w.wp04; break;
 585                                 case  5:link = w.wp05; break;
 586                                 case  6:link = w.wp06; break;
 587                                 case  7:link = w.wp07; break;
 588                                 case  8:link = w.wp08; break;
 589                                 case  9:link = w.wp09; break;
 590                                 case 10:link = w.wp10; break;
 591                                 case 11:link = w.wp11; break;
 592                                 case 12:link = w.wp12; break;
 593                                 case 13:link = w.wp13; break;
 594                                 case 14:link = w.wp14; break;
 595                                 case 15:link = w.wp15; break;
 596                                 case 16:link = w.wp16; break;
 597                                 case 17:link = w.wp17; break;
 598                                 case 18:link = w.wp18; break;
 599                                 case 19:link = w.wp19; break;
 600                                 case 20:link = w.wp20; break;
 601                                 case 21:link = w.wp21; break;
 602                                 case 22:link = w.wp22; break;
 603                                 case 23:link = w.wp23; break;
 604                                 case 24:link = w.wp24; break;
 605                                 case 25:link = w.wp25; break;
 606                                 case 26:link = w.wp26; break;
 607                                 case 27:link = w.wp27; break;
 608                                 case 28:link = w.wp28; break;
 609                                 case 29:link = w.wp29; break;
 610                                 case 30:link = w.wp30; break;
 611                                 case 31:link = w.wp31; break;
 612                         }
 613
 614                         if(link==world)
 615                                 continue;
 616
 617                         s = strcat(vtos(w.origin), "*", vtos(link.origin), "\n");
 618                         fputs(file, s);
 619                         ++c;
 620                 }
 621                 w = w.chain;
 622         }
 623         fclose(file);
 624         botframe_cachedwaypointlinks = TRUE;
 625
 626         print("saved ");
 627         print(ftos(c));
 628         print(" waypoints links to maps/");
 629         print(mapname);
 630         print(".waypoints.cache\n");
 631 }
 632
 633 // save waypoints to gamedir/data/maps/mapname.waypoints
 634 void waypoint_saveall()
 635 {
 636         string filename, s;
 637         float file, c;
 638         entity w;
 639         filename = strcat("maps/", mapname);
 640         filename = strcat(filename, ".waypoints");
 641         file = fopen(filename, FILE_WRITE);
 642         if (file >= 0)
 643         {
 644                 c = 0;
 645                 w = findchain(classname, "waypoint");
 646                 while (w)
 647                 {
 648                         if (!(w.wpflags & WAYPOINTFLAG_GENERATED))
 649                         {
 650                                 s = strcat(vtos(w.origin + w.mins), "\n");
 651                                 s = strcat(s, vtos(w.origin + w.maxs));
 652                                 s = strcat(s, "\n");
 653                                 s = strcat(s, ftos(w.wpflags));
 654                                 s = strcat(s, "\n");
 655                                 fputs(file, s);
 656                                 c = c + 1;
 657                         }
 658                         w = w.chain;
 659                 }
 660                 fclose(file);
 661                 bprint("saved ");
 662                 bprint(ftos(c));
 663                 bprint(" waypoints to maps/");
 664                 bprint(mapname);
 665                 bprint(".waypoints\n");
 666         }
 667         else
 668         {
 669                 bprint("waypoint save to ");
 670                 bprint(filename);
 671                 bprint(" failed\n");
 672         }
 673         waypoint_save_links();
 674         botframe_loadedforcedlinks = FALSE;
 675 }
 676
 677 // load waypoints from file
 678 float waypoint_loadall()
 679 {
 680         string filename, s;
 681         float file, cwp, cwb, fl;
 682         vector m1, m2;
 683         cwp = 0;
 684         cwb = 0;
 685         filename = strcat("maps/", mapname);
 686         filename = strcat(filename, ".waypoints");
 687         file = fopen(filename, FILE_READ);
 688         if (file >= 0)
 689         {
 690                 while (1)
 691                 {
 692                         s = fgets(file);
 693                         if (!s)
 694                                 break;
 695                         m1 = stov(s);
 696                         s = fgets(file);
 697                         if (!s)
 698                                 break;
 699                         m2 = stov(s);
 700                         s = fgets(file);
 701                         if (!s)
 702                                 break;
 703                         fl = stof(s);
 704                         waypoint_spawn(m1, m2, fl);
 705                         if (m1 == m2)
 706                                 cwp = cwp + 1;
 707                         else
 708                                 cwb = cwb + 1;
 709                 }
 710                 fclose(file);
 711                 dprint("loaded ");
 712                 dprint(ftos(cwp));
 713                 dprint(" waypoints and ");
 714                 dprint(ftos(cwb));
 715                 dprint(" wayboxes from maps/");
 716                 dprint(mapname);
 717                 dprint(".waypoints\n");
 718         }
 719         else
 720         {
 721                 dprint("waypoint load from ");
 722                 dprint(filename);
 723                 dprint(" failed\n");
 724         }
 725         return cwp + cwb;
 726 }
 727
 728 vector waypoint_fixorigin(vector position)
 729 {
 730         tracebox(position + '0 0 1' * (1 - PL_MIN_z), PL_MIN, PL_MAX, position + '0 0 -512', MOVE_NOMONSTERS, world);
 731         if(trace_fraction < 1)
 732                 position = trace_endpos;
 733         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, world);
 734         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
 735         return position;
 736 }
 737
 738 void waypoint_spawnforitem_force(entity e, vector org)
 739 {
 740         entity w;
 741
 742         // Fix the waypoint altitude if necessary
 743         org = waypoint_fixorigin(org);
 744
 745         // don't spawn an item spawnfunc_waypoint if it already exists
 746         w = findchain(classname, "waypoint");
 747         while (w)
 748         {
 749                 if (w.wpisbox)
 750                 {
 751                         if (boxesoverlap(org, org, w.absmin, w.absmax))
 752                         {
 753                                 e.nearestwaypoint = w;
 754                                 return;
 755                         }
 756                 }
 757                 else
 758                 {
 759                         if (vlen(w.origin - org) < 16)
 760                         {
 761                                 e.nearestwaypoint = w;
 762                                 return;
 763                         }
 764                 }
 765                 w = w.chain;
 766         }
 767         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 768 }
 769
 770 void waypoint_spawnforitem(entity e)
 771 {
 772         if(!bot_waypoints_for_items)
 773                 return;
 774
 775         waypoint_spawnforitem_force(e, e.origin);
 776 }
 777
 778 void waypoint_spawnforteleporter_boxes(entity e, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
 779 {
 780         entity w;
 781         entity dw;
 782         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 783         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
 784         // one way link to the destination
 785         w.wp00 = dw;
 786         w.wp00mincost = timetaken; // this is just for jump pads
 787         // the teleporter's nearest spawnfunc_waypoint is this one
 788         // (teleporters are not goals, so this is probably useless)
 789         e.nearestwaypoint = w;
 790         e.nearestwaypointtimeout = time + 1000000000;
 791 }
 792
 793 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
 794 {
 795         org = waypoint_fixorigin(org);
 796         destination = waypoint_fixorigin(destination);
 797         waypoint_spawnforteleporter_boxes(e, org, org, destination, destination, timetaken);
 798 }
 799
 800 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
 801 {
 802         destination = waypoint_fixorigin(destination);
 803         waypoint_spawnforteleporter_boxes(e, e.absmin, e.absmax, destination, destination, timetaken);
 804 }
 805
 806 entity waypoint_spawnpersonal(vector position)
 807 {
 808         entity w;
 809
 810         // drop the waypoint to a proper location:
 811         //   first move it up by a player height
 812         //   then move it down to hit the floor with player bbox size
 813         position = waypoint_fixorigin(position);
 814
 815         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
 816         w.nearestwaypoint = world;
 817         w.nearestwaypointtimeout = 0;
 818         w.owner = self;
 819
 820         waypoint_schedulerelink(w);
 821
 822         return w;
 823 }
 824
 825 void botframe_showwaypointlinks()
 826 {
 827         entity player, head, w;
 828         if (time < botframe_waypointeditorlightningtime)
 829                 return;
 830         botframe_waypointeditorlightningtime = time + 0.5;
 831         player = find(world, classname, "player");
 832         while (player)
 833         {
 834                 if (!player.isbot)
 835                 if (player.flags & FL_ONGROUND || player.waterlevel > WATERLEVEL_NONE)
 836                 {
 837                         //navigation_testtracewalk = TRUE;
 838                         head = navigation_findnearestwaypoint(player, FALSE);
 839                 //      print("currently selected WP is ", etos(head), "\n");
 840                         //navigation_testtracewalk = FALSE;
 841                         if (head)
 842                         {
 843                                 w = head     ;if (w) te_lightning2(world, w.origin, player.origin);
 844                                 w = head.wp00;if (w) te_lightning2(world, w.origin, head.origin);
 845                                 w = head.wp01;if (w) te_lightning2(world, w.origin, head.origin);
 846                                 w = head.wp02;if (w) te_lightning2(world, w.origin, head.origin);
 847                                 w = head.wp03;if (w) te_lightning2(world, w.origin, head.origin);
 848                                 w = head.wp04;if (w) te_lightning2(world, w.origin, head.origin);
 849                                 w = head.wp05;if (w) te_lightning2(world, w.origin, head.origin);
 850                                 w = head.wp06;if (w) te_lightning2(world, w.origin, head.origin);
 851                                 w = head.wp07;if (w) te_lightning2(world, w.origin, head.origin);
 852                                 w = head.wp08;if (w) te_lightning2(world, w.origin, head.origin);
 853                                 w = head.wp09;if (w) te_lightning2(world, w.origin, head.origin);
 854                                 w = head.wp10;if (w) te_lightning2(world, w.origin, head.origin);
 855                                 w = head.wp11;if (w) te_lightning2(world, w.origin, head.origin);
 856                                 w = head.wp12;if (w) te_lightning2(world, w.origin, head.origin);
 857                                 w = head.wp13;if (w) te_lightning2(world, w.origin, head.origin);
 858                                 w = head.wp14;if (w) te_lightning2(world, w.origin, head.origin);
 859                                 w = head.wp15;if (w) te_lightning2(world, w.origin, head.origin);
 860                                 w = head.wp16;if (w) te_lightning2(world, w.origin, head.origin);
 861                                 w = head.wp17;if (w) te_lightning2(world, w.origin, head.origin);
 862                                 w = head.wp18;if (w) te_lightning2(world, w.origin, head.origin);
 863                                 w = head.wp19;if (w) te_lightning2(world, w.origin, head.origin);
 864                                 w = head.wp20;if (w) te_lightning2(world, w.origin, head.origin);
 865                                 w = head.wp21;if (w) te_lightning2(world, w.origin, head.origin);
 866                                 w = head.wp22;if (w) te_lightning2(world, w.origin, head.origin);
 867                                 w = head.wp23;if (w) te_lightning2(world, w.origin, head.origin);
 868                                 w = head.wp24;if (w) te_lightning2(world, w.origin, head.origin);
 869                                 w = head.wp25;if (w) te_lightning2(world, w.origin, head.origin);
 870                                 w = head.wp26;if (w) te_lightning2(world, w.origin, head.origin);
 871                                 w = head.wp27;if (w) te_lightning2(world, w.origin, head.origin);
 872                                 w = head.wp28;if (w) te_lightning2(world, w.origin, head.origin);
 873                                 w = head.wp29;if (w) te_lightning2(world, w.origin, head.origin);
 874                                 w = head.wp30;if (w) te_lightning2(world, w.origin, head.origin);
 875                                 w = head.wp31;if (w) te_lightning2(world, w.origin, head.origin);
 876                         }
 877                 }
 878                 player = find(player, classname, "player");
 879         }
 880 }
 881
 882 float botframe_autowaypoints_fixdown(vector v)
 883 {
 884         tracebox(v, PL_MIN, PL_MAX, v + '0 0 -64', MOVE_NOMONSTERS, world);
 885         if(trace_fraction >= 1)
 886                 return 0;
 887         return 1;
 888 }
 889
 890 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld)
 891 {
 892         entity w;
 893
 894         w = find(world, classname, "waypoint");
 895         while (w)
 896         {
 897                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
 898                 if (boxesoverlap(v - '32 32 32', v + '32 32 32', w.absmin, w.absmax))
 899                 //if (boxesoverlap(v - '4 4 4', v + '4 4 4', w.absmin, w.absmax))
 900                         return 0;
 901                 w = find(w, classname, "waypoint");
 902         }
 903
 904         waypoint_schedulerelink(p.fld = waypoint_spawn(v, v, 0));
 905         return 1;
 906 }
 907
 908 // return value:
 909 //    1 = WP created
 910 //    0 = no action needed
 911 //   -1 = temp fail, try from world too
 912 //   -2 = permanent fail, do not retry
 913 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
 914 {
 915         // make it possible to go from p to wp, if we can
 916         // if wp is world, nearest is chosen
 917
 918         entity w;
 919         vector porg;
 920         float t, tmin, tmax;
 921         vector o;
 922         vector save;
 923
 924         if(!botframe_autowaypoints_fixdown(p.origin))
 925                 return -2;
 926         porg = trace_endpos;
 927
 928         if(wp)
 929         {
 930                 // if any WP w fulfills wp -> w -> porg, then switch from wp to w
 931
 932                 // if wp -> porg, then OK
 933                 float maxdist;
 934                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
 935                 {
 936                         // we may find a better one
 937                         maxdist = vlen(wp.origin - porg);
 938                 }
 939                 else
 940                 {
 941                         // accept any "good"
 942                         maxdist = 2100;
 943                 }
 944
 945                 float bestdist;
 946                 bestdist = maxdist;
 947                 w = find(world, classname, "waypoint");
 948                 while (w)
 949                 {
 950                         if(w != wp && !(w.wpflags & WAYPOINTFLAG_NORELINK))
 951                         {
 952                                 float d;
 953                                 d = vlen(wp.origin - w.origin) + vlen(w.origin - porg);
 954                                 if(d < bestdist)
 955                                         if(navigation_waypoint_will_link(wp.origin, w.origin, p, walkfromwp, 1050))
 956                                                 if(navigation_waypoint_will_link(w.origin, porg, p, walkfromwp, 1050))
 957                                                 {
 958                                                         bestdist = d;
 959                                                         p.fld = w;
 960                                                 }
 961                         }
 962                         w = find(w, classname, "waypoint");
 963                 }
 964                 if(bestdist < maxdist)
 965                 {
 966                         print("update chain to new nearest WP ", etos(p.fld), "\n");
 967                         return 0;
 968                 }
 969
 970                 if(bestdist < 2100)
 971                 {
 972                         // we know maxdist < 2100
 973                         // so wp -> porg is still valid
 974                         // all is good
 975                         p.fld = wp;
 976                         return 0;
 977                 }
 978
 979                 // otherwise, no existing WP can fix our issues
 980         }
 981         else
 982         {
 983                 save = p.origin;
 984                 setorigin(p, porg);
 985                 w = navigation_findnearestwaypoint(p, walkfromwp);
 986                 setorigin(p, save);
 987                 if(w)
 988                 {
 989                         p.fld = w;
 990                         return 0;
 991                 }
 992         }
 993
 994         tmin = 0;
 995         tmax = 1;
 996         for(;;)
 997         {
 998                 if(tmax - tmin < 0.001)
 999                 {
1000                         // did not get a good candidate
1001                         return -1;
1002                 }
1003
1004                 t = (tmin + tmax) * 0.5;
1005                 o = antilag_takebackorigin(p, time - t);
1006                 if(!botframe_autowaypoints_fixdown(o))
1007                         return -1;
1008                 o = trace_endpos;
1009
1010                 if(wp)
1011                 {
1012                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
1013                         {
1014                                 // we cannot walk from wp.origin to o
1015                                 // get closer to tmax
1016                                 tmin = t;
1017                                 continue;
1018                         }
1019                 }
1020                 else
1021                 {
1022                         save = p.origin;
1023                         setorigin(p, o);
1024                         w = navigation_findnearestwaypoint(p, walkfromwp);
1025                         setorigin(p, save);
1026                         if(!w)
1027                         {
1028                                 // we cannot walk from any WP to o
1029                                 // get closer to tmax
1030                                 tmin = t;
1031                                 continue;
1032                         }
1033                 }
1034
1035                 // if we get here, o is valid regarding waypoints
1036                 // check if o is connected right to the player
1037                 // we break if it succeeds, as that means o is a good waypoint location
1038                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
1039                         break;
1040
1041                 // o is no good, we need to get closer to the player
1042                 tmax = t;
1043         }
1044
1045         print("spawning a waypoint for connecting to ", etos(wp), "\n");
1046         botframe_autowaypoints_createwp(o, p, fld);
1047         return 1;
1048 }
1049
1050 // automatically create missing waypoints
1051 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1052 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1053 {
1054         float r;
1055         r = botframe_autowaypoints_fix_from(p, walkfromwp, p.fld, fld);
1056         if(r != -1)
1057                 return;
1058         r = botframe_autowaypoints_fix_from(p, walkfromwp, world, fld);
1059         if(r != -1)
1060                 return;
1061
1062         print("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1063         if(!botframe_autowaypoints_fixdown(p.origin))
1064                 return; // shouldn't happen, caught above
1065         botframe_autowaypoints_createwp(trace_endpos, p, fld);
1066 }
1067
1068 void botframe_autowaypoints()
1069 {
1070         entity p;
1071         FOR_EACH_REALPLAYER(p)
1072         {
1073                 if(p.deadflag)
1074                         continue;
1075                 // going back is broken, so only fix waypoints to walk TO the player
1076                 //botframe_autowaypoints_fix(p, FALSE, botframe_autowaypoints_lastwp0);
1077                 botframe_autowaypoints_fix(p, TRUE, botframe_autowaypoints_lastwp1);
1078                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1079         }
1080 }
1081