qcsrc/server/bot/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "../aim.qh"
   4 #include "../bot.qh"
   5 #include "../navigation.qh"
   6 #include "../scripting.qh"
   7 #include "../waypoints.qh"
   8
   9 #include <common/constants.qh>
  10 #include <common/items/all.qh>
  11
  12 #include <common/triggers/trigger/jumppads.qh>
  13
  14 #include <lib/warpzone/common.qh>
  15
  16 .float speed;
  17
  18 void havocbot_ai()
  19 {SELFPARAM();
  20         if(self.draggedby)
  21                 return;
  22
  23         if(bot_execute_commands())
  24                 return;
  25
  26         if (bot_strategytoken == self)
  27         if (!bot_strategytoken_taken)
  28         {
  29                 if(self.havocbot_blockhead)
  30                 {
  31                         self.havocbot_blockhead = false;
  32                 }
  33                 else
  34                 {
  35                         if (!self.jumppadcount)
  36                                 self.havocbot_role();
  37                 }
  38
  39                 // TODO: tracewalk() should take care of this job (better path finding under water)
  40                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  41                 if(self.deadflag != DEAD_NO)
  42                 if(self.goalcurrent==world)
  43                 if(self.waterlevel==WATERLEVEL_SWIMMING || (self.aistatus & AI_STATUS_OUT_WATER))
  44                 {
  45                         // Look for the closest waypoint out of water
  46                         entity newgoal, head;
  47                         float bestdistance, distance;
  48
  49                         newgoal = world;
  50                         bestdistance = 10000;
  51                         for (head = findchain(classname, "waypoint"); head; head = head.chain)
  52                         {
  53                                 distance = vlen(head.origin - self.origin);
  54                                 if(distance>10000)
  55                                         continue;
  56
  57                                 if(head.origin.z < self.origin.z)
  58                                         continue;
  59
  60                                 if(head.origin.z - self.origin.z - self.view_ofs.z > 100)
  61                                         continue;
  62
  63                                 if (pointcontents(head.origin + head.maxs + '0 0 1') != CONTENT_EMPTY)
  64                                         continue;
  65
  66                                 traceline(self.origin + self.view_ofs , head.origin, true, head);
  67
  68                                 if(trace_fraction<1)
  69                                         continue;
  70
  71                                 if(distance<bestdistance)
  72                                 {
  73                                         newgoal = head;
  74                                         bestdistance = distance;
  75                                 }
  76                         }
  77
  78                         if(newgoal)
  79                         {
  80                         //      te_wizspike(newgoal.origin);
  81                                 navigation_pushroute(newgoal);
  82                         }
  83                 }
  84
  85                 // token has been used this frame
  86                 bot_strategytoken_taken = true;
  87         }
  88
  89         if(self.deadflag != DEAD_NO)
  90                 return;
  91
  92         havocbot_chooseenemy();
  93         if (self.bot_chooseweapontime < time )
  94         {
  95                 self.bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
  96                 havocbot_chooseweapon();
  97         }
  98         havocbot_aim();
  99         lag_update();
 100         if (self.bot_aimtarg)
 101         {
 102                 self.aistatus |= AI_STATUS_ATTACKING;
 103                 self.aistatus &= ~AI_STATUS_ROAMING;
 104
 105                 if(self.weapons)
 106                 {
 107                         Weapon w = PS(self).m_weapon;
 108                         w.wr_aim(w);
 109                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(self))
 110                         {
 111                                 self.BUTTON_ATCK = false;
 112                                 self.BUTTON_ATCK2 = false;
 113                         }
 114                         else
 115                         {
 116                                 if(self.BUTTON_ATCK||self.BUTTON_ATCK2)
 117                                         self.lastfiredweapon = PS(self).m_weapon.m_id;
 118                         }
 119                 }
 120                 else
 121                 {
 122                         if(IS_PLAYER(self.bot_aimtarg))
 123                                 bot_aimdir(self.bot_aimtarg.origin + self.bot_aimtarg.view_ofs - self.origin - self.view_ofs , -1);
 124                 }
 125         }
 126         else if (self.goalcurrent)
 127         {
 128                 self.aistatus |= AI_STATUS_ROAMING;
 129                 self.aistatus &= ~AI_STATUS_ATTACKING;
 130
 131                 vector now,v,next;//,heading;
 132                 float aimdistance,skillblend,distanceblend,blend;
 133                 next = now = ( (self.goalcurrent.absmin + self.goalcurrent.absmax) * 0.5) - (self.origin + self.view_ofs);
 134                 aimdistance = vlen(now);
 135                 //heading = self.velocity;
 136                 //dprint(self.goalstack01.classname,etos(self.goalstack01),"\n");
 137                 if(
 138                         self.goalstack01 != self && self.goalstack01 != world && ((self.aistatus & AI_STATUS_RUNNING) == 0) &&
 139                         !(self.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 140                 )
 141                         next = ((self.goalstack01.absmin + self.goalstack01.absmax) * 0.5) - (self.origin + self.view_ofs);
 142
 143                 skillblend=bound(0,(skill+self.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 144                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 145                 blend = skillblend * (1-distanceblend);
 146                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 147                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 148                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 149                 v = now + blend * (next - now);
 150                 //dprint(etos(self), " ");
 151                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 152                 //v = now * (distanceblend) + next * (1-distanceblend);
 153                 if (self.waterlevel < WATERLEVEL_SWIMMING)
 154                         v.z = 0;
 155                 //dprint("walk at:", vtos(v), "\n");
 156                 //te_lightning2(world, self.origin, self.goalcurrent.origin);
 157                 bot_aimdir(v, -1);
 158         }
 159         havocbot_movetogoal();
 160
 161         // if the bot is not attacking, consider reloading weapons
 162         if (!(self.aistatus & AI_STATUS_ATTACKING))
 163         {
 164                 // we are currently holding a weapon that's not fully loaded, reload it
 165                 if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 166                 if(self.clip_load < self.clip_size)
 167                         self.impulse = 20; // "press" the reload button, not sure if this is done right
 168
 169                 // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 170                 // the code above executes next frame, starting the reloading then
 171                 if(skill >= 5) // bots can only look for unloaded weapons past this skill
 172                 if(self.clip_load >= 0) // only if we're not reloading a weapon already
 173                 {
 174                         FOREACH(Weapons, it != WEP_Null, LAMBDA(
 175                                 if((self.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (self.weapon_load[it.m_id] < it.reloading_ammo))
 176                                         PS(self).m_switchweapon = it;
 177                         ));
 178                 }
 179         }
 180 }
 181
 182 void havocbot_keyboard_movement(vector destorg)
 183 {SELFPARAM();
 184         vector keyboard;
 185         float blend, maxspeed;
 186         float sk;
 187
 188         sk = skill + self.bot_moveskill;
 189
 190         maxspeed = autocvar_sv_maxspeed;
 191
 192         if (time < self.havocbot_keyboardtime)
 193                 return;
 194
 195         self.havocbot_keyboardtime =
 196                 max(
 197                         self.havocbot_keyboardtime
 198                                 + 0.05/max(1, sk+self.havocbot_keyboardskill)
 199                                 + random()*0.025/max(0.00025, skill+self.havocbot_keyboardskill)
 200                 , time);
 201         keyboard = self.movement * (1.0 / maxspeed);
 202
 203         float trigger, trigger1;
 204         blend = bound(0,sk*0.1,1);
 205         trigger = autocvar_bot_ai_keyboard_threshold;
 206         trigger1 = 0 - trigger;
 207
 208         // categorize forward movement
 209         // at skill < 1.5 only forward
 210         // at skill < 2.5 only individual directions
 211         // at skill < 4.5 only individual directions, and forward diagonals
 212         // at skill >= 4.5, all cases allowed
 213         if (keyboard.x > trigger)
 214         {
 215                 keyboard.x = 1;
 216                 if (sk < 2.5)
 217                         keyboard.y = 0;
 218         }
 219         else if (keyboard.x < trigger1 && sk > 1.5)
 220         {
 221                 keyboard.x = -1;
 222                 if (sk < 4.5)
 223                         keyboard.y = 0;
 224         }
 225         else
 226         {
 227                 keyboard.x = 0;
 228                 if (sk < 1.5)
 229                         keyboard.y = 0;
 230         }
 231         if (sk < 4.5)
 232                 keyboard.z = 0;
 233
 234         if (keyboard.y > trigger)
 235                 keyboard.y = 1;
 236         else if (keyboard.y < trigger1)
 237                 keyboard.y = -1;
 238         else
 239                 keyboard.y = 0;
 240
 241         if (keyboard.z > trigger)
 242                 keyboard.z = 1;
 243         else if (keyboard.z < trigger1)
 244                 keyboard.z = -1;
 245         else
 246                 keyboard.z = 0;
 247
 248         self.havocbot_keyboard = keyboard * maxspeed;
 249         if (self.havocbot_ducktime>time) self.BUTTON_CROUCH=true;
 250
 251         keyboard = self.havocbot_keyboard;
 252         blend = bound(0,vlen(destorg-self.origin)/autocvar_bot_ai_keyboard_distance,1); // When getting close move with 360 degree
 253         //dprint("movement ", vtos(self.movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 254         self.movement = self.movement + (keyboard - self.movement) * blend;
 255 }
 256
 257 void havocbot_bunnyhop(vector dir)
 258 {SELFPARAM();
 259         float bunnyhopdistance;
 260         vector deviation;
 261         float maxspeed;
 262         vector gco, gno;
 263
 264         // Don't jump when attacking
 265         if(self.aistatus & AI_STATUS_ATTACKING)
 266                 return;
 267
 268         if(IS_PLAYER(self.goalcurrent))
 269                 return;
 270
 271         maxspeed = autocvar_sv_maxspeed;
 272
 273         if(self.aistatus & AI_STATUS_DANGER_AHEAD)
 274         {
 275                 self.aistatus &= ~AI_STATUS_RUNNING;
 276                 self.BUTTON_JUMP = false;
 277                 self.bot_canruntogoal = 0;
 278                 self.bot_timelastseengoal = 0;
 279                 return;
 280         }
 281
 282         if(self.waterlevel > WATERLEVEL_WETFEET)
 283         {
 284                 self.aistatus &= ~AI_STATUS_RUNNING;
 285                 return;
 286         }
 287
 288         if(self.bot_lastseengoal != self.goalcurrent && !(self.aistatus & AI_STATUS_RUNNING))
 289         {
 290                 self.bot_canruntogoal = 0;
 291                 self.bot_timelastseengoal = 0;
 292         }
 293
 294         gco = (self.goalcurrent.absmin + self.goalcurrent.absmax) * 0.5;
 295         bunnyhopdistance = vlen(self.origin - gco);
 296
 297         // Run only to visible goals
 298         if(IS_ONGROUND(self))
 299         if(self.speed==maxspeed)
 300         if(checkpvs(self.origin + self.view_ofs, self.goalcurrent))
 301         {
 302                         self.bot_lastseengoal = self.goalcurrent;
 303
 304                         // seen it before
 305                         if(self.bot_timelastseengoal)
 306                         {
 307                                 // for a period of time
 308                                 if(time - self.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 309                                 {
 310                                         float checkdistance;
 311                                         checkdistance = true;
 312
 313                                         // don't run if it is too close
 314                                         if(self.bot_canruntogoal==0)
 315                                         {
 316                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 317                                                         self.bot_canruntogoal = 1;
 318                                                 else
 319                                                         self.bot_canruntogoal = -1;
 320                                         }
 321
 322                                         if(self.bot_canruntogoal != 1)
 323                                                 return;
 324
 325                                         if(self.aistatus & AI_STATUS_ROAMING)
 326                                         if(self.goalcurrent.classname=="waypoint")
 327                                         if (!(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 328                                         if(fabs(gco.z - self.origin.z) < self.maxs.z - self.mins.z)
 329                                         if(self.goalstack01!=world)
 330                                         {
 331                                                 gno = (self.goalstack01.absmin + self.goalstack01.absmax) * 0.5;
 332                                                 deviation = vectoangles(gno - self.origin) - vectoangles(gco - self.origin);
 333                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 334                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 335
 336                                                 if(fabs(deviation.y) < 20)
 337                                                 if(bunnyhopdistance < vlen(self.origin - gno))
 338                                                 if(fabs(gno.z - gco.z) < self.maxs.z - self.mins.z)
 339                                                 {
 340                                                         if(vlen(gco - gno) > autocvar_bot_ai_bunnyhop_startdistance)
 341                                                         if(checkpvs(self.origin + self.view_ofs, self.goalstack01))
 342                                                         {
 343                                                                 checkdistance = false;
 344                                                         }
 345                                                 }
 346                                         }
 347
 348                                         if(checkdistance)
 349                                         {
 350                                                 self.aistatus &= ~AI_STATUS_RUNNING;
 351                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance)
 352                                                         self.BUTTON_JUMP = true;
 353                                         }
 354                                         else
 355                                         {
 356                                                 self.aistatus |= AI_STATUS_RUNNING;
 357                                                 self.BUTTON_JUMP = true;
 358                                         }
 359                                 }
 360                         }
 361                         else
 362                         {
 363                                 self.bot_timelastseengoal = time;
 364                         }
 365         }
 366         else
 367         {
 368                 self.bot_timelastseengoal = 0;
 369         }
 370
 371 #if 0
 372         // Release jump button
 373         if(!cvar("sv_pogostick"))
 374         if((IS_ONGROUND(self)) == 0)
 375         {
 376                 if(self.velocity.z < 0 || vlen(self.velocity)<maxspeed)
 377                         self.BUTTON_JUMP = false;
 378
 379                 // Strafe
 380                 if(self.aistatus & AI_STATUS_RUNNING)
 381                 if(vlen(self.velocity)>maxspeed)
 382                 {
 383                         deviation = vectoangles(dir) - vectoangles(self.velocity);
 384                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 385                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 386
 387                         if(fabs(deviation.y)>10)
 388                                 self.movement_x = 0;
 389
 390                         if(deviation.y>10)
 391                                 self.movement_y = maxspeed * -1;
 392                         else if(deviation.y<10)
 393                                 self.movement_y = maxspeed;
 394
 395                 }
 396         }
 397 #endif
 398 }
 399
 400 void havocbot_movetogoal()
 401 {SELFPARAM();
 402         vector destorg;
 403         vector diff;
 404         vector dir;
 405         vector flatdir;
 406         vector m1;
 407         vector m2;
 408         vector evadeobstacle;
 409         vector evadelava;
 410         float s;
 411         float maxspeed;
 412         vector gco;
 413         //float dist;
 414         vector dodge;
 415         //if (self.goalentity)
 416         //      te_lightning2(self, self.origin, (self.goalentity.absmin + self.goalentity.absmax) * 0.5);
 417         self.movement = '0 0 0';
 418         maxspeed = autocvar_sv_maxspeed;
 419
 420         // Jetpack navigation
 421         if(self.goalcurrent)
 422         if(self.navigation_jetpack_goal)
 423         if(self.goalcurrent==self.navigation_jetpack_goal)
 424         if(self.ammo_fuel)
 425         {
 426                 if(autocvar_bot_debug_goalstack)
 427                 {
 428                         debuggoalstack();
 429                         te_wizspike(self.navigation_jetpack_point);
 430                 }
 431
 432                 // Take off
 433                 if (!(self.aistatus & AI_STATUS_JETPACK_FLYING))
 434                 {
 435                         // Brake almost completely so it can get a good direction
 436                         if(vlen(self.velocity)>10)
 437                                 return;
 438                         self.aistatus |= AI_STATUS_JETPACK_FLYING;
 439                 }
 440
 441                 makevectors(self.v_angle.y * '0 1 0');
 442                 dir = normalize(self.navigation_jetpack_point - self.origin);
 443
 444                 // Landing
 445                 if(self.aistatus & AI_STATUS_JETPACK_LANDING)
 446                 {
 447                         // Calculate brake distance in xy
 448                         float db, v, d;
 449                         vector dxy;
 450
 451                         dxy = self.origin - ( ( self.goalcurrent.absmin + self.goalcurrent.absmax ) * 0.5 ); dxy.z = 0;
 452                         d = vlen(dxy);
 453                         v = vlen(self.velocity -  self.velocity.z * '0 0 1');
 454                         db = (pow(v,2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 455                 //      dprint("distance ", ftos(ceil(d)), " velocity ", ftos(ceil(v)), " brake at ", ftos(ceil(db)), "\n");
 456                         if(d < db || d < 500)
 457                         {
 458                                 // Brake
 459                                 if(fabs(self.velocity.x)>maxspeed*0.3)
 460                                 {
 461                                         self.movement_x = dir * v_forward * -maxspeed;
 462                                         return;
 463                                 }
 464                                 // Switch to normal mode
 465                                 self.navigation_jetpack_goal = world;
 466                                 self.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 467                                 self.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 468                                 return;
 469                         }
 470                 }
 471                 else if(checkpvs(self.origin,self.goalcurrent))
 472                 {
 473                         // If I can see the goal switch to landing code
 474                         self.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 475                         self.aistatus |= AI_STATUS_JETPACK_LANDING;
 476                         return;
 477                 }
 478
 479                 // Flying
 480                 self.BUTTON_HOOK = true;
 481                 if(self.navigation_jetpack_point.z - STAT(PL_MAX, NULL).z + STAT(PL_MIN, NULL).z < self.origin.z)
 482                 {
 483                         self.movement_x = dir * v_forward * maxspeed;
 484                         self.movement_y = dir * v_right * maxspeed;
 485                 }
 486                 return;
 487         }
 488
 489         // Handling of jump pads
 490         if(self.jumppadcount)
 491         {
 492                 // If got stuck on the jump pad try to reach the farthest visible waypoint
 493                 if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
 494                 {
 495                         if(fabs(self.velocity.z)<50)
 496                         {
 497                                 entity head, newgoal = world;
 498                                 float distance, bestdistance = 0;
 499
 500                                 for (head = findchain(classname, "waypoint"); head; head = head.chain)
 501                                 {
 502
 503                                         distance = vlen(head.origin - self.origin);
 504                                         if(distance>1000)
 505                                                 continue;
 506
 507                                         traceline(self.origin + self.view_ofs , ( ( head.absmin + head.absmax ) * 0.5 ), true, world);
 508
 509                                         if(trace_fraction<1)
 510                                                 continue;
 511
 512                                         if(distance>bestdistance)
 513                                         {
 514                                                 newgoal = head;
 515                                                 bestdistance = distance;
 516                                         }
 517                                 }
 518
 519                                 if(newgoal)
 520                                 {
 521                                         self.ignoregoal = self.goalcurrent;
 522                                         self.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 523                                         navigation_clearroute();
 524                                         navigation_routetogoal(newgoal, self.origin);
 525                                         self.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 526                                 }
 527                         }
 528                         else
 529                                 return;
 530                 }
 531                 else
 532                 {
 533                         if(self.velocity.z>0)
 534                         {
 535                                 float threshold, sxy;
 536                                 vector velxy = self.velocity; velxy_z = 0;
 537                                 sxy = vlen(velxy);
 538                                 threshold = maxspeed * 0.2;
 539                                 if(sxy < threshold)
 540                                 {
 541                                         LOG_TRACE("Warning: ", self.netname, " got stuck on a jumppad (velocity in xy is ", ftos(sxy), "), trying to get out of it now\n");
 542                                         self.aistatus |= AI_STATUS_OUT_JUMPPAD;
 543                                 }
 544                                 return;
 545                         }
 546
 547                         // Don't chase players while using a jump pad
 548                         if(IS_PLAYER(self.goalcurrent) || IS_PLAYER(self.goalstack01))
 549                                 return;
 550                 }
 551         }
 552         else if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
 553                 self.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 554
 555         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 556         if(skill>6)
 557         if (!(IS_ONGROUND(self)))
 558         {
 559                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 -65536', MOVE_NOMONSTERS, self);
 560                 if(tracebox_hits_trigger_hurt(self.origin, self.mins, self.maxs, trace_endpos ))
 561                 if(self.items & IT_JETPACK)
 562                 {
 563                         tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 65536', MOVE_NOMONSTERS, self);
 564                         if(tracebox_hits_trigger_hurt(self.origin, self.mins, self.maxs, trace_endpos + '0 0 1' ))
 565                         {
 566                                 if(self.velocity.z<0)
 567                                 {
 568                                         self.BUTTON_HOOK = true;
 569                                 }
 570                         }
 571                         else
 572                                 self.BUTTON_HOOK = true;
 573
 574                         // If there is no goal try to move forward
 575
 576                         if(self.goalcurrent==world)
 577                                 dir = v_forward;
 578                         else
 579                                 dir = normalize(( ( self.goalcurrent.absmin + self.goalcurrent.absmax ) * 0.5 ) - self.origin);
 580
 581                         vector xyvelocity = self.velocity; xyvelocity_z = 0;
 582                         float xyspeed = xyvelocity * dir;
 583
 584                         if(xyspeed < (maxspeed / 2))
 585                         {
 586                                 makevectors(self.v_angle.y * '0 1 0');
 587                                 tracebox(self.origin, self.mins, self.maxs, self.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, self);
 588                                 if(trace_fraction==1)
 589                                 {
 590                                         self.movement_x = dir * v_forward * maxspeed;
 591                                         self.movement_y = dir * v_right * maxspeed;
 592                                         if (skill < 10)
 593                                                 havocbot_keyboard_movement(self.origin + dir * 100);
 594                                 }
 595                         }
 596
 597                         self.havocbot_blockhead = true;
 598
 599                         return;
 600                 }
 601                 else if(self.health>WEP_CVAR(devastator, damage)*0.5)
 602                 {
 603                         if(self.velocity.z < 0)
 604                         if(client_hasweapon(self, WEP_DEVASTATOR, true, false))
 605                         {
 606                                 self.movement_x = maxspeed;
 607
 608                                 if(self.rocketjumptime)
 609                                 {
 610                                         if(time > self.rocketjumptime)
 611                                         {
 612                                                 self.BUTTON_ATCK2 = true;
 613                                                 self.rocketjumptime = 0;
 614                                         }
 615                                         return;
 616                                 }
 617
 618                                 PS(self).m_switchweapon = WEP_DEVASTATOR;
 619                                 self.v_angle_x = 90;
 620                                 self.BUTTON_ATCK = true;
 621                                 self.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 622                                 return;
 623                         }
 624                 }
 625                 else
 626                 {
 627                         // If there is no goal try to move forward
 628                         if(self.goalcurrent==world)
 629                                 self.movement_x = maxspeed;
 630                 }
 631         }
 632
 633         // If we are under water with no goals, swim up
 634         if(self.waterlevel)
 635         if(self.goalcurrent==world)
 636         {
 637                 dir = '0 0 0';
 638                 if(self.waterlevel>WATERLEVEL_SWIMMING)
 639                         dir.z = 1;
 640                 else if(self.velocity.z >= 0 && !(self.waterlevel == WATERLEVEL_WETFEET && self.watertype == CONTENT_WATER))
 641                         self.BUTTON_JUMP = true;
 642                 else
 643                         self.BUTTON_JUMP = false;
 644                 makevectors(self.v_angle.y * '0 1 0');
 645                 self.movement_x = dir * v_forward * maxspeed;
 646                 self.movement_y = dir * v_right * maxspeed;
 647                 self.movement_z = dir * v_up * maxspeed;
 648         }
 649
 650         // if there is nowhere to go, exit
 651         if (self.goalcurrent == world)
 652                 return;
 653
 654         if (self.goalcurrent)
 655                 navigation_poptouchedgoals();
 656
 657         // if ran out of goals try to use an alternative goal or get a new strategy asap
 658         if(self.goalcurrent == world)
 659         {
 660                 self.bot_strategytime = 0;
 661                 return;
 662         }
 663
 664
 665         if(autocvar_bot_debug_goalstack)
 666                 debuggoalstack();
 667
 668         m1 = self.goalcurrent.origin + self.goalcurrent.mins;
 669         m2 = self.goalcurrent.origin + self.goalcurrent.maxs;
 670         destorg = self.origin;
 671         destorg.x = bound(m1_x, destorg.x, m2_x);
 672         destorg.y = bound(m1_y, destorg.y, m2_y);
 673         destorg.z = bound(m1_z, destorg.z, m2_z);
 674         diff = destorg - self.origin;
 675         //dist = vlen(diff);
 676         dir = normalize(diff);
 677         flatdir = diff;flatdir.z = 0;
 678         flatdir = normalize(flatdir);
 679         gco = (self.goalcurrent.absmin + self.goalcurrent.absmax) * 0.5;
 680
 681         //if (self.bot_dodgevector_time < time)
 682         {
 683         //      self.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 684         //      self.bot_dodgevector_jumpbutton = 1;
 685                 evadeobstacle = '0 0 0';
 686                 evadelava = '0 0 0';
 687
 688                 if (self.waterlevel)
 689                 {
 690                         if(self.waterlevel>WATERLEVEL_SWIMMING)
 691                         {
 692                         //      flatdir_z = 1;
 693                                 self.aistatus |= AI_STATUS_OUT_WATER;
 694                         }
 695                         else
 696                         {
 697                                 if(self.velocity.z >= 0 && !(self.watertype == CONTENT_WATER && gco.z < self.origin.z) &&
 698                                         ( !(self.waterlevel == WATERLEVEL_WETFEET && self.watertype == CONTENT_WATER) || self.aistatus & AI_STATUS_OUT_WATER))
 699                                         self.BUTTON_JUMP = true;
 700                                 else
 701                                         self.BUTTON_JUMP = false;
 702                         }
 703                         dir = normalize(flatdir);
 704                         makevectors(self.v_angle.y * '0 1 0');
 705                 }
 706                 else
 707                 {
 708                         if(self.aistatus & AI_STATUS_OUT_WATER)
 709                                 self.aistatus &= ~AI_STATUS_OUT_WATER;
 710
 711                         // jump if going toward an obstacle that doesn't look like stairs we
 712                         // can walk up directly
 713                         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.2, false, self);
 714                         if (trace_fraction < 1)
 715                         if (trace_plane_normal.z < 0.7)
 716                         {
 717                                 s = trace_fraction;
 718                                 tracebox(self.origin + stepheightvec, self.mins, self.maxs, self.origin + self.velocity * 0.2 + stepheightvec, false, self);
 719                                 if (trace_fraction < s + 0.01)
 720                                 if (trace_plane_normal.z < 0.7)
 721                                 {
 722                                         s = trace_fraction;
 723                                         tracebox(self.origin + jumpstepheightvec, self.mins, self.maxs, self.origin + self.velocity * 0.2 + jumpstepheightvec, false, self);
 724                                         if (trace_fraction > s)
 725                                                 self.BUTTON_JUMP = 1;
 726                                 }
 727                         }
 728
 729                         // avoiding dangers and obstacles
 730                         vector dst_ahead, dst_down;
 731                         makevectors(self.v_angle.y * '0 1 0');
 732                         dst_ahead = self.origin + self.view_ofs + (self.velocity * 0.4) + (v_forward * 32 * 3);
 733                         dst_down = dst_ahead - '0 0 1500';
 734
 735                         // Look ahead
 736                         traceline(self.origin + self.view_ofs, dst_ahead, true, world);
 737
 738                         // Check head-banging against walls
 739                         if(vlen(self.origin + self.view_ofs - trace_endpos) < 25 && !(self.aistatus & AI_STATUS_OUT_WATER))
 740                         {
 741                                 self.BUTTON_JUMP = true;
 742                                 if(self.facingwalltime && time > self.facingwalltime)
 743                                 {
 744                                         self.ignoregoal = self.goalcurrent;
 745                                         self.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 746                                         self.bot_strategytime = 0;
 747                                         return;
 748                                 }
 749                                 else
 750                                 {
 751                                         self.facingwalltime = time + 0.05;
 752                                 }
 753                         }
 754                         else
 755                         {
 756                                 self.facingwalltime = 0;
 757
 758                                 if(self.ignoregoal != world && time > self.ignoregoaltime)
 759                                 {
 760                                         self.ignoregoal = world;
 761                                         self.ignoregoaltime = 0;
 762                                 }
 763                         }
 764
 765                         // Check for water/slime/lava and dangerous edges
 766                         // (only when the bot is on the ground or jumping intentionally)
 767                         self.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 768
 769                         if(trace_fraction == 1 && self.jumppadcount == 0 && !self.goalcurrent.wphardwired )
 770                         if((IS_ONGROUND(self)) || (self.aistatus & AI_STATUS_RUNNING) || self.BUTTON_JUMP == true)
 771                         {
 772                                 // Look downwards
 773                                 traceline(dst_ahead , dst_down, true, world);
 774                         //      te_lightning2(world, self.origin, dst_ahead);   // Draw "ahead" look
 775                         //      te_lightning2(world, dst_ahead, dst_down);              // Draw "downwards" look
 776                                 if(trace_endpos.z < self.origin.z + self.mins.z)
 777                                 {
 778                                         s = pointcontents(trace_endpos + '0 0 1');
 779                                         if (s != CONTENT_SOLID)
 780                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 781                                                 evadelava = normalize(self.velocity) * -1;
 782                                         else if (s == CONTENT_SKY)
 783                                                 evadeobstacle = normalize(self.velocity) * -1;
 784                                         else if (!boxesoverlap(dst_ahead - self.view_ofs + self.mins, dst_ahead - self.view_ofs + self.maxs,
 785                                                                 self.goalcurrent.absmin, self.goalcurrent.absmax))
 786                                         {
 787                                                 // if ain't a safe goal with "holes" (like the jumpad on soylent)
 788                                                 // and there is a trigger_hurt below
 789                                                 if(tracebox_hits_trigger_hurt(dst_ahead, self.mins, self.maxs, trace_endpos))
 790                                                 {
 791                                                         // Remove dangerous dynamic goals from stack
 792                                                         LOG_TRACE("bot ", self.netname, " avoided the goal ", self.goalcurrent.classname, " ", etos(self.goalcurrent), " because it led to a dangerous path; goal stack cleared\n");
 793                                                         navigation_clearroute();
 794                                                         return;
 795                                                 }
 796                                         }
 797                                 }
 798                         }
 799
 800                         dir = flatdir;
 801                         evadeobstacle.z = 0;
 802                         evadelava.z = 0;
 803                         makevectors(self.v_angle.y * '0 1 0');
 804
 805                         if(evadeobstacle!='0 0 0'||evadelava!='0 0 0')
 806                                 self.aistatus |= AI_STATUS_DANGER_AHEAD;
 807                 }
 808
 809                 dodge = havocbot_dodge();
 810                 dodge = dodge * bound(0,0.5+(skill+self.bot_dodgeskill)*0.1,1);
 811                 evadelava = evadelava * bound(1,3-(skill+self.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 812                 traceline(self.origin, ( ( self.enemy.absmin + self.enemy.absmax ) * 0.5 ), true, world);
 813                 if(IS_PLAYER(trace_ent))
 814                         dir = dir * bound(0,(skill+self.bot_dodgeskill)/7,1);
 815
 816                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 817         //      self.bot_dodgevector = dir;
 818         //      self.bot_dodgevector_jumpbutton = self.BUTTON_JUMP;
 819         }
 820
 821         if(time < self.ladder_time)
 822         {
 823                 if(self.goalcurrent.origin.z + self.goalcurrent.mins.z > self.origin.z + self.mins.z)
 824                 {
 825                         if(self.origin.z + self.mins.z  < self.ladder_entity.origin.z + self.ladder_entity.maxs.z)
 826                                 dir.z = 1;
 827                 }
 828                 else
 829                 {
 830                         if(self.origin.z + self.mins.z  > self.ladder_entity.origin.z + self.ladder_entity.mins.z)
 831                                 dir.z = -1;
 832                 }
 833         }
 834
 835         //dir = self.bot_dodgevector;
 836         //if (self.bot_dodgevector_jumpbutton)
 837         //      self.BUTTON_JUMP = 1;
 838         self.movement_x = dir * v_forward * maxspeed;
 839         self.movement_y = dir * v_right * maxspeed;
 840         self.movement_z = dir * v_up * maxspeed;
 841
 842         // Emulate keyboard interface
 843         if (skill < 10)
 844                 havocbot_keyboard_movement(destorg);
 845
 846         // Bunnyhop!
 847 //      if(self.aistatus & AI_STATUS_ROAMING)
 848         if(self.goalcurrent)
 849         if(skill+self.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
 850                 havocbot_bunnyhop(dir);
 851
 852         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(self))) self.BUTTON_JUMP=1;
 853         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-self.bot_dodgeskill)*0.1,1)) self.BUTTON_JUMP=true;
 854         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-self.bot_dodgeskill)*0.1,1)) self.havocbot_ducktime=time+0.3/bound(0.1,skill+self.bot_dodgeskill,10);
 855 }
 856
 857 void havocbot_chooseenemy()
 858 {SELFPARAM();
 859         entity head, best, head2;
 860         float rating, bestrating, hf;
 861         vector eye, v;
 862         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(self))
 863         {
 864                 self.enemy = world;
 865                 return;
 866         }
 867         if (self.enemy)
 868         {
 869                 if (!bot_shouldattack(self.enemy))
 870                 {
 871                         // enemy died or something, find a new target
 872                         self.enemy = world;
 873                         self.havocbot_chooseenemy_finished = time;
 874                 }
 875                 else if (self.havocbot_stickenemy)
 876                 {
 877                         // tracking last chosen enemy
 878                         // if enemy is visible
 879                         // and not really really far away
 880                         // and we're not severely injured
 881                         // then keep tracking for a half second into the future
 882                         traceline(self.origin+self.view_ofs, ( self.enemy.absmin + self.enemy.absmax ) * 0.5,false,world);
 883                         if (trace_ent == self.enemy || trace_fraction == 1)
 884                         if (vlen((( self.enemy.absmin + self.enemy.absmax ) * 0.5) - self.origin) < 1000)
 885                         if (self.health > 30)
 886                         {
 887                                 // remain tracking him for a shot while (case he went after a small corner or pilar
 888                                 self.havocbot_chooseenemy_finished = time + 0.5;
 889                                 return;
 890                         }
 891                         // enemy isn't visible, or is far away, or we're injured severely
 892                         // so stop preferring this enemy
 893                         // (it will still take a half second until a new one is chosen)
 894                         self.havocbot_stickenemy = 0;
 895                 }
 896         }
 897         if (time < self.havocbot_chooseenemy_finished)
 898                 return;
 899         self.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
 900         eye = self.origin + self.view_ofs;
 901         best = world;
 902         bestrating = 100000000;
 903         head = head2 = findchainfloat(bot_attack, true);
 904
 905         // Backup hit flags
 906         hf = self.dphitcontentsmask;
 907
 908         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
 909
 910         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 911
 912         bool scan_transparent = false;
 913         bool scan_secondary_targets = false;
 914         bool have_secondary_targets = false;
 915         while(true)
 916         {
 917                 scan_secondary_targets = false;
 918                 :scan_targets
 919                 for( ; head; head = head.chain)
 920                 {
 921                         if(!scan_secondary_targets)
 922                         {
 923                                 if(head.classname == "misc_breakablemodel")
 924                                 {
 925                                         have_secondary_targets = true;
 926                                         continue;
 927                                 }
 928                         }
 929                         else
 930                         {
 931                                 if(head.classname != "misc_breakablemodel")
 932                                         continue;
 933                         }
 934
 935                         v = (head.absmin + head.absmax) * 0.5;
 936                         rating = vlen(v - eye);
 937                         if (rating<autocvar_bot_ai_enemydetectionradius)
 938                         if (bestrating > rating)
 939                         if (bot_shouldattack(head))
 940                         {
 941                                 traceline(eye, v, true, self);
 942                                 if (trace_ent == head || trace_fraction >= 1)
 943                                 {
 944                                         best = head;
 945                                         bestrating = rating;
 946                                 }
 947                         }
 948                 }
 949
 950                 if(!best && have_secondary_targets && !scan_secondary_targets)
 951                 {
 952                         scan_secondary_targets = true;
 953                         // restart the loop
 954                         head = head2;
 955                         bestrating = 100000000;
 956                         goto scan_targets;
 957                 }
 958
 959                 // I want to do a second scan if no enemy was found or I don't have weapons
 960                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
 961                 if(best || self.weapons) // || self.weapon == WEP_RIFLE.m_id
 962                         break;
 963                 if(scan_transparent)
 964                         break;
 965
 966                 // Set flags to see through transparent objects
 967                 self.dphitcontentsmask |= DPCONTENTS_OPAQUE;
 968
 969                 head = head2;
 970                 scan_transparent = true;
 971         }
 972
 973         // Restore hit flags
 974         self.dphitcontentsmask = hf;
 975
 976         self.enemy = best;
 977         self.havocbot_stickenemy = true;
 978         if(best && best.classname == "misc_breakablemodel")
 979                 self.havocbot_stickenemy = false;
 980 }
 981
 982 float havocbot_chooseweapon_checkreload(int new_weapon)
 983 {SELFPARAM();
 984         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
 985         // so skip this for them, or they'll never get to reload their weapons at all.
 986         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
 987         if(skill < 5)
 988                 return false;
 989
 990         // if this weapon is scheduled for reloading, don't switch to it during combat
 991         if (self.weapon_load[new_weapon] < 0)
 992         {
 993                 bool other_weapon_available = false;
 994                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 995                         if(it.wr_checkammo1(it) + it.wr_checkammo2(it))
 996                                 other_weapon_available = true;
 997                 ));
 998                 if(other_weapon_available)
 999                         return true;
1000         }
1001
1002         return false;
1003 }
1004
1005 void havocbot_chooseweapon()
1006 {SELFPARAM();
1007         int i;
1008
1009         // ;)
1010         if(g_weaponarena_weapons == WEPSET(TUBA))
1011         {
1012                 PS(self).m_switchweapon = WEP_TUBA;
1013                 return;
1014         }
1015
1016         // TODO: clean this up by moving it to weapon code
1017         if(self.enemy==world)
1018         {
1019                 // If no weapon was chosen get the first available weapon
1020                 if(PS(self).m_weapon==WEP_Null)
1021                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1022                         if(client_hasweapon(self, it, true, false))
1023                         {
1024                                 PS(self).m_switchweapon = it;
1025                                 return;
1026                         }
1027                 ));
1028                 return;
1029         }
1030
1031         // Do not change weapon during the next second after a combo
1032         float f = time - self.lastcombotime;
1033         if(f < 1)
1034                 return;
1035
1036         float w;
1037         float distance; distance=bound(10,vlen(self.origin-self.enemy.origin)-200,10000);
1038
1039         // Should it do a weapon combo?
1040         float af, ct, combo_time, combo;
1041
1042         af = ATTACK_FINISHED(self, 0);
1043         ct = autocvar_bot_ai_weapon_combo_threshold;
1044
1045         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1046         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1047         combo_time = time + ct + (ct * ((-0.3*(skill+self.bot_weaponskill))+3));
1048
1049         combo = false;
1050
1051         if(autocvar_bot_ai_weapon_combo)
1052         if(PS(self).m_weapon.m_id == self.lastfiredweapon)
1053         if(af > combo_time)
1054         {
1055                 combo = true;
1056                 self.lastcombotime = time;
1057         }
1058
1059         distance *= pow(2, self.bot_rangepreference);
1060
1061         // Custom weapon list based on distance to the enemy
1062         if(bot_custom_weapon){
1063
1064                 // Choose weapons for far distance
1065                 if ( distance > bot_distance_far ) {
1066                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1067                                 w = bot_weapons_far[i];
1068                                 if ( client_hasweapon(self, Weapons_from(w), true, false) )
1069                                 {
1070                                         if ((PS(self).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(w))
1071                                                 continue;
1072                                         PS(self).m_switchweapon = Weapons_from(w);
1073                                         return;
1074                                 }
1075                         }
1076                 }
1077
1078                 // Choose weapons for mid distance
1079                 if ( distance > bot_distance_close) {
1080                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1081                                 w = bot_weapons_mid[i];
1082                                 if ( client_hasweapon(self, Weapons_from(w), true, false) )
1083                                 {
1084                                         if ((PS(self).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(w))
1085                                                 continue;
1086                                         PS(self).m_switchweapon = Weapons_from(w);
1087                                         return;
1088                                 }
1089                         }
1090                 }
1091
1092                 // Choose weapons for close distance
1093                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1094                         w = bot_weapons_close[i];
1095                         if ( client_hasweapon(self, Weapons_from(w), true, false) )
1096                         {
1097                                 if ((PS(self).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(w))
1098                                         continue;
1099                                 PS(self).m_switchweapon = Weapons_from(w);
1100                                 return;
1101                         }
1102                 }
1103         }
1104 }
1105
1106 void havocbot_aim()
1107 {SELFPARAM();
1108         vector selfvel, enemyvel;
1109 //      if(self.flags & FL_INWATER)
1110 //              return;
1111         if (time < self.nextaim)
1112                 return;
1113         self.nextaim = time + 0.1;
1114         selfvel = self.velocity;
1115         if (!self.waterlevel)
1116                 selfvel.z = 0;
1117         if (self.enemy)
1118         {
1119                 enemyvel = self.enemy.velocity;
1120                 if (!self.enemy.waterlevel)
1121                         enemyvel.z = 0;
1122                 lag_additem(time + self.ping, 0, 0, self.enemy, self.origin, selfvel, (self.enemy.absmin + self.enemy.absmax) * 0.5, enemyvel);
1123         }
1124         else
1125                 lag_additem(time + self.ping, 0, 0, world, self.origin, selfvel, ( self.goalcurrent.absmin + self.goalcurrent.absmax ) * 0.5, '0 0 0');
1126 }
1127
1128 float havocbot_moveto_refresh_route()
1129 {SELFPARAM();
1130         // Refresh path to goal if necessary
1131         entity wp;
1132         wp = self.havocbot_personal_waypoint;
1133         navigation_goalrating_start();
1134         navigation_routerating(wp, 10000, 10000);
1135         navigation_goalrating_end();
1136         return self.navigation_hasgoals;
1137 }
1138
1139 float havocbot_moveto(vector pos)
1140 {SELFPARAM();
1141         entity wp;
1142
1143         if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1144         {
1145                 // Step 4: Move to waypoint
1146                 if(self.havocbot_personal_waypoint==world)
1147                 {
1148                         LOG_TRACE("Error: ", self.netname, " trying to walk to a non existent personal waypoint\n");
1149                         self.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1150                         return CMD_STATUS_ERROR;
1151                 }
1152
1153                 if (!bot_strategytoken_taken)
1154                 if(self.havocbot_personal_waypoint_searchtime<time)
1155                 {
1156                         bot_strategytoken_taken = true;
1157                         if(havocbot_moveto_refresh_route())
1158                         {
1159                                 LOG_TRACE(self.netname, " walking to its personal waypoint (after ", ftos(self.havocbot_personal_waypoint_failcounter), " failed attempts)\n");
1160                                 self.havocbot_personal_waypoint_searchtime = time + 10;
1161                                 self.havocbot_personal_waypoint_failcounter = 0;
1162                         }
1163                         else
1164                         {
1165                                 self.havocbot_personal_waypoint_failcounter += 1;
1166                                 self.havocbot_personal_waypoint_searchtime = time + 2;
1167                                 if(self.havocbot_personal_waypoint_failcounter >= 30)
1168                                 {
1169                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(self.havocbot_personal_waypoint.origin),"\n");
1170                                         self.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1171                                         remove(self.havocbot_personal_waypoint);
1172                                         return CMD_STATUS_ERROR;
1173                                 }
1174                                 else
1175                                         LOG_TRACE(self.netname, " can't walk to its personal waypoint (after ", ftos(self.havocbot_personal_waypoint_failcounter), " failed attempts), trying later\n");
1176                         }
1177                 }
1178
1179                 if(autocvar_bot_debug_goalstack)
1180                         debuggoalstack();
1181
1182                 // Heading
1183                 vector dir = ( ( self.goalcurrent.absmin + self.goalcurrent.absmax ) * 0.5 ) - (self.origin + self.view_ofs);
1184                 dir.z = 0;
1185                 bot_aimdir(dir, -1);
1186
1187                 // Go!
1188                 havocbot_movetogoal();
1189
1190                 if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1191                 {
1192                         // Step 5: Waypoint reached
1193                         LOG_TRACE(self.netname, "'s personal waypoint reached\n");
1194                         remove(self.havocbot_personal_waypoint);
1195                         self.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1196                         return CMD_STATUS_FINISHED;
1197                 }
1198
1199                 return CMD_STATUS_EXECUTING;
1200         }
1201
1202         // Step 2: Linking waypoint
1203         if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1204         {
1205                 // Wait until it is linked
1206                 if(!self.havocbot_personal_waypoint.wplinked)
1207                 {
1208                         LOG_TRACE(self.netname, " waiting for personal waypoint to be linked\n");
1209                         return CMD_STATUS_EXECUTING;
1210                 }
1211
1212                 self.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1213                 self.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1214                 self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1215
1216                 // Step 3: Route to waypoint
1217                 LOG_TRACE(self.netname, " walking to its personal waypoint\n");
1218
1219                 return CMD_STATUS_EXECUTING;
1220         }
1221
1222         // Step 1: Spawning waypoint
1223         wp = waypoint_spawnpersonal(pos);
1224         if(wp==world)
1225         {
1226                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos),"\n");
1227                 return CMD_STATUS_ERROR;
1228         }
1229
1230         self.havocbot_personal_waypoint = wp;
1231         self.havocbot_personal_waypoint_failcounter = 0;
1232         self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1233
1234         // if pos is inside a teleport, then let's mark it as teleport waypoint
1235         entity head;
1236         for(head = world; (head = find(head, classname, "trigger_teleport")); )
1237         {
1238                 if(WarpZoneLib_BoxTouchesBrush(pos, pos, head, world))
1239                 {
1240                         wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1241                         self.lastteleporttime = 0;
1242                 }
1243         }
1244
1245 /*
1246         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1247                 print("routing to a teleporter\n");
1248         else
1249                 print("routing to a non-teleporter\n");
1250 */
1251
1252         return CMD_STATUS_EXECUTING;
1253 }
1254
1255 float havocbot_resetgoal()
1256 {
1257         navigation_clearroute();
1258         return CMD_STATUS_FINISHED;
1259 }
1260
1261 void havocbot_setupbot()
1262 {SELFPARAM();
1263         self.bot_ai = havocbot_ai;
1264         self.cmd_moveto = havocbot_moveto;
1265         self.cmd_resetgoal = havocbot_resetgoal;
1266
1267         havocbot_chooserole();
1268 }
1269
1270 vector havocbot_dodge()
1271 {SELFPARAM();
1272         // LordHavoc: disabled because this is too expensive
1273         return '0 0 0';
1274 #if 0
1275         entity head;
1276         vector dodge, v, n;
1277         float danger, bestdanger, vl, d;
1278         dodge = '0 0 0';
1279         bestdanger = -20;
1280         // check for dangerous objects near bot or approaching bot
1281         head = findchainfloat(bot_dodge, true);
1282         while(head)
1283         {
1284                 if (head.owner != self)
1285                 {
1286                         vl = vlen(head.velocity);
1287                         if (vl > autocvar_sv_maxspeed * 0.3)
1288                         {
1289                                 n = normalize(head.velocity);
1290                                 v = self.origin - head.origin;
1291                                 d = v * n;
1292                                 if (d > (0 - head.bot_dodgerating))
1293                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1294                                 {
1295                                         // calculate direction and distance from the flight path, by removing the forward axis
1296                                         v = v - (n * (v * n));
1297                                         danger = head.bot_dodgerating - vlen(v);
1298                                         if (bestdanger < danger)
1299                                         {
1300                                                 bestdanger = danger;
1301                                                 // dodge to the side of the object
1302                                                 dodge = normalize(v);
1303                                         }
1304                                 }
1305                         }
1306                         else
1307                         {
1308                                 danger = head.bot_dodgerating - vlen(head.origin - self.origin);
1309                                 if (bestdanger < danger)
1310                                 {
1311                                         bestdanger = danger;
1312                                         dodge = normalize(self.origin - head.origin);
1313                                 }
1314                         }
1315                 }
1316                 head = head.chain;
1317         }
1318         return dodge;
1319 #endif
1320 }