qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <common/animdecide.qh>
   4 #include <common/constants.qh>
   5 #include <common/debug.qh>
   6 #include <common/gamemodes/_mod.qh>
   7 #include <common/mapobjects/trigger/jumppads.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/physics/player.qh>
  10 #include <common/state.qh>
  11 #include <common/stats.qh>
  12 #include <common/weapons/_all.qh>
  13 #include <lib/warpzone/common.qh>
  14 #include <lib/warpzone/util_server.qh>
  15 #include <server/antilag.qh>
  16 #include <server/bot/default/bot.qh>
  17 #include <server/bot/default/cvars.qh>
  18 #include <server/bot/default/navigation.qh>
  19 #include <server/items/items.qh>
  20 #include <server/spawnpoints.qh>
  21 #include <server/weapons/tracing.qh>
  22
  23 STATIC_INIT(waypoints)
  24 {
  25         waypointeditor_enabled = autocvar_g_waypointeditor;
  26 }
  27 .entity spawnpointmodel;
  28 void waypoint_unreachable(entity pl)
  29 {
  30         IL_EACH(g_waypoints, true,
  31         {
  32                 it.colormod = '0.5 0.5 0.5';
  33                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  34         });
  35
  36         entity e2 = navigation_findnearestwaypoint(pl, false);
  37         if(!e2)
  38         {
  39                 LOG_INFO("Can't find any waypoint nearby\n");
  40                 return;
  41         }
  42
  43         navigation_markroutes(pl, e2);
  44
  45         int j = 0;
  46         int m = 0;
  47         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  48         {
  49                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  50                 it.colormod_z = 8;
  51                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  52                 j++;
  53                 m++;
  54         });
  55         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  56         navigation_markroutes_inverted(e2);
  57
  58         j = 0;
  59         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  60         {
  61                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  62                 it.colormod_x = 8;
  63                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  64                         m++;
  65                 it.effects |= EF_NODEPTHTEST | EF_RED;
  66                 j++;
  67         });
  68         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  69         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  70
  71         j = 0;
  72         IL_EACH(g_spawnpoints, true,
  73         {
  74                 if (navigation_findnearestwaypoint(it, false))
  75                 {
  76                         if(it.spawnpointmodel)
  77                         {
  78                                 delete(it.spawnpointmodel);
  79                                 it.spawnpointmodel = NULL;
  80                         }
  81                 }
  82                 else
  83                 {
  84                         if(!it.spawnpointmodel)
  85                         {
  86                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  87                                 entity e = new(spawnpointmodel);
  88                                 vector org = trace_endpos + eZ;
  89                                 setorigin(e, org);
  90                                 e.solid = SOLID_TRIGGER;
  91                                 it.spawnpointmodel = e;
  92                         }
  93                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  94                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  95                         _setmodel(it.spawnpointmodel, pl.model);
  96                         it.spawnpointmodel.frame = ANIM_idle.m_id;
  97                         it.spawnpointmodel.skin = pl.skin;
  98                         it.spawnpointmodel.colormap = 1024 + 68;
  99                         it.spawnpointmodel.glowmod = '1 0 0';
 100                         it.spawnpointmodel.angles = it.angles;
 101                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
 102                         j++;
 103                 }
 104         });
 105         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 106
 107         j = 0;
 108         IL_EACH(g_items, true,
 109         {
 110                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 111                 it.colormod = '0.5 0.5 0.5';
 112         });
 113         IL_EACH(g_items, true,
 114         {
 115                 if (navigation_findnearestwaypoint(it, false))
 116                         continue;
 117                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 118                 it.effects |= EF_NODEPTHTEST | EF_RED;
 119                 it.colormod_x = 8;
 120                 j++;
 121         });
 122         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 123
 124         j = 0;
 125         IL_EACH(g_items, true,
 126         {
 127                 if (navigation_findnearestwaypoint(it, true))
 128                         continue;
 129                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 130                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 131                 it.colormod_z = 8;
 132                 j++;
 133         });
 134         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 135 }
 136
 137 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 138 {
 139         vector v1 = stov(argv(arg_idx++));
 140         vector v2 = stov(argv(arg_idx++));
 141         vector mid = (v1 + v2) / 2;
 142
 143         float diffy = (v2.y - v1.y);
 144         float diffx = (v2.x - v1.x);
 145         if (v1.y == v2.y)
 146                 diffy = 0.000001;
 147         if (v1.x == v2.x)
 148                 diffx = 0.000001;
 149         float m = - diffx / diffy;
 150         float q = - m * mid.x + mid.y;
 151         if (fabs(m) <= 0.000001) m = 0;
 152         if (fabs(q) <= 0.000001) q = 0;
 153
 154         string axis_str =  strcat(ftos(m), " ", ftos(q));
 155         if (save)
 156                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 157         axis_str = strcat("\"", axis_str, "\"");
 158         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 159         if (save)
 160                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 161         if (save)
 162         {
 163                 cvar_set("g_waypointeditor_symmetrical", "-2");
 164                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 165                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 166         }
 167 }
 168
 169 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 170 {
 171         vector org = '0 0 0';
 172         int ctf_flags = 0;
 173         for (int i = 0; i < 6; i++)
 174         {
 175                 if (argv(arg_idx + i) != "")
 176                         ctf_flags++;
 177         }
 178         if (ctf_flags < 2)
 179         {
 180                 ctf_flags = 0;
 181                 org = vec2(havocbot_middlepoint);
 182                 if (argv(arg_idx) != "")
 183                         sprint(caller, "WARNING: Ignoring single input point\n");
 184                 if (havocbot_middlepoint_radius == 0)
 185                 {
 186                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 187                         return;
 188                 }
 189         }
 190         else
 191         {
 192                 vector v1, v2, v3, v4, v5, v6;
 193                 for (int i = 1; i <= ctf_flags; i++)
 194                 {
 195                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 196                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 197                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 198                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 199                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 200                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 201                 }
 202         }
 203
 204         if (fabs(org.x) <= 0.000001) org.x = 0;
 205         if (fabs(org.y) <= 0.000001) org.y = 0;
 206         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 207         if (save)
 208         {
 209                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 210                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 211         }
 212         org_str = strcat("\"", org_str, "\"");
 213
 214         if (ctf_flags < 2)
 215                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 216         else
 217                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 218         if (save)
 219                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 220
 221         if (ctf_flags < 2)
 222                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 223         else
 224                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 225         if (save)
 226                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 227
 228         if (save)
 229         {
 230                 if (ctf_flags < 2)
 231                         cvar_set("g_waypointeditor_symmetrical", "0");
 232                 else
 233                         cvar_set("g_waypointeditor_symmetrical", "-1");
 234                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 235                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 236         }
 237 }
 238
 239 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 240 {
 241         vector new_org = org;
 242         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 243         {
 244                 vector map_center = havocbot_middlepoint;
 245                 if (autocvar_g_waypointeditor_symmetrical == -1)
 246                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 247
 248                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 249         }
 250         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 251         {
 252                 float m = havocbot_symmetry_axis_m;
 253                 float q = havocbot_symmetry_axis_q;
 254                 if (autocvar_g_waypointeditor_symmetrical == -2)
 255                 {
 256                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 257                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 258                 }
 259
 260                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 261                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 262         }
 263         new_org.z = org.z;
 264         return new_org;
 265 }
 266
 267 void crosshair_trace_waypoints(entity pl);
 268 void waypoint_lock(entity pl)
 269 {
 270         crosshair_trace_waypoints(pl);
 271         pl.wp_locked = trace_ent;
 272 }
 273
 274 bool waypoint_has_hardwiredlinks(entity wp)
 275 {
 276         if (!wp)
 277                 return false;
 278         return (wp.wphw00 != NULL);
 279 }
 280
 281 bool waypoint_is_hardwiredlink(entity wp_from, entity wp_to)
 282 {
 283         if (!(wp_from && wp_to))
 284                 return false;
 285
 286         if (!wp_from.wphw00) return false; else if (wp_from.wphw00 == wp_to) return true;
 287         if (!wp_from.wphw01) return false; else if (wp_from.wphw01 == wp_to) return true;
 288         if (!wp_from.wphw02) return false; else if (wp_from.wphw02 == wp_to) return true;
 289         if (!wp_from.wphw03) return false; else if (wp_from.wphw03 == wp_to) return true;
 290         if (!wp_from.wphw04) return false; else if (wp_from.wphw04 == wp_to) return true;
 291         if (!wp_from.wphw05) return false; else if (wp_from.wphw05 == wp_to) return true;
 292         if (!wp_from.wphw06) return false; else if (wp_from.wphw06 == wp_to) return true;
 293         if (!wp_from.wphw07) return false; else if (wp_from.wphw07 == wp_to) return true;
 294
 295         return false;
 296 }
 297
 298 void waypoint_setupmodel(entity wp);
 299 void waypoint_mark_hardwiredlink(entity wp_from, entity wp_to)
 300 {
 301         if (!(wp_from && wp_to))
 302                 return;
 303
 304         if (!wp_from.wphw00 || wp_from.wphw00 == wp_to) { wp_from.wphw00 = wp_to; waypoint_setupmodel(wp_from); return; }
 305         if (!wp_from.wphw01 || wp_from.wphw01 == wp_to) { wp_from.wphw01 = wp_to; return; }
 306         if (!wp_from.wphw02 || wp_from.wphw02 == wp_to) { wp_from.wphw02 = wp_to; return; }
 307         if (!wp_from.wphw03 || wp_from.wphw03 == wp_to) { wp_from.wphw03 = wp_to; return; }
 308         if (!wp_from.wphw04 || wp_from.wphw04 == wp_to) { wp_from.wphw04 = wp_to; return; }
 309         if (!wp_from.wphw05 || wp_from.wphw05 == wp_to) { wp_from.wphw05 = wp_to; return; }
 310         if (!wp_from.wphw06 || wp_from.wphw06 == wp_to) { wp_from.wphw06 = wp_to; return; }
 311         if (!wp_from.wphw07 || wp_from.wphw07 == wp_to) { wp_from.wphw07 = wp_to; return; }
 312
 313         return;
 314 }
 315
 316 void waypoint_unmark_hardwiredlink(entity wp_from, entity wp_to)
 317 {
 318         if (!(wp_from && wp_to))
 319                 return;
 320
 321         int removed = -1;
 322         if (removed < 0 && wp_from.wphw00 == wp_to) removed = 0;
 323         if (removed < 0 && wp_from.wphw01 == wp_to) removed = 1;
 324         if (removed < 0 && wp_from.wphw02 == wp_to) removed = 2;
 325         if (removed < 0 && wp_from.wphw03 == wp_to) removed = 3;
 326         if (removed < 0 && wp_from.wphw04 == wp_to) removed = 4;
 327         if (removed < 0 && wp_from.wphw05 == wp_to) removed = 5;
 328         if (removed < 0 && wp_from.wphw06 == wp_to) removed = 6;
 329         if (removed < 0 && wp_from.wphw07 == wp_to) removed = 7;
 330
 331         if (removed >= 0)
 332         {
 333                 if (removed <= 0) wp_from.wphw00 = wp_from.wphw01;
 334                 if (removed <= 1) wp_from.wphw01 = wp_from.wphw02;
 335                 if (removed <= 2) wp_from.wphw02 = wp_from.wphw03;
 336                 if (removed <= 3) wp_from.wphw03 = wp_from.wphw04;
 337                 if (removed <= 4) wp_from.wphw04 = wp_from.wphw05;
 338                 if (removed <= 5) wp_from.wphw05 = wp_from.wphw06;
 339                 if (removed <= 6) wp_from.wphw06 = wp_from.wphw07;
 340                 if (removed <= 7) wp_from.wphw07 = NULL;
 341                 if (!wp_from.wphw00)
 342                         waypoint_setupmodel(wp_from);
 343         }
 344
 345         return;
 346 }
 347
 348 void waypoint_restore_hardwiredlinks(entity wp)
 349 {
 350         if (wp.wphw00) waypoint_addlink(wp, wp.wphw00);
 351         if (wp.wphw01) waypoint_addlink(wp, wp.wphw01);
 352         if (wp.wphw02) waypoint_addlink(wp, wp.wphw02);
 353         if (wp.wphw03) waypoint_addlink(wp, wp.wphw03);
 354         if (wp.wphw04) waypoint_addlink(wp, wp.wphw04);
 355         if (wp.wphw05) waypoint_addlink(wp, wp.wphw05);
 356         if (wp.wphw06) waypoint_addlink(wp, wp.wphw06);
 357         if (wp.wphw07) waypoint_addlink(wp, wp.wphw07);
 358 }
 359
 360 void waypoint_setupmodel(entity wp)
 361 {
 362         if (waypointeditor_enabled)
 363         {
 364                 // TODO: add some sort of visible box in edit mode for box waypoints
 365                 vector m1 = wp.mins;
 366                 vector m2 = wp.maxs;
 367                 setmodel(wp, MDL_WAYPOINT);
 368                 setsize(wp, m1, m2);
 369                 wp.effects = EF_LOWPRECISION;
 370                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 371                         wp.colormod = '1 0 0'; // red
 372                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 373                         wp.colormod = '1 1 0'; // yellow
 374                 else if (wp.wpflags & WAYPOINTFLAG_SUPPORT)
 375                         wp.colormod = '0 1 0'; // green
 376                 else if (wp.wpflags & WAYPOINTFLAG_CUSTOM_JP)
 377                         wp.colormod = '1 0.5 0'; // orange
 378                 else if (wp.wpflags & WAYPOINTFLAG_TELEPORT)
 379                         wp.colormod = '1 0.5 0'; // orange
 380                 else if (wp.wpflags & WAYPOINTFLAG_LADDER)
 381                         wp.colormod = '1 0.5 0'; // orange
 382                 else if (wp.wpflags & WAYPOINTFLAG_JUMP)
 383                         wp.colormod = '1 0.5 0'; // orange
 384                 else if (wp.wpflags & WAYPOINTFLAG_CROUCH)
 385                         wp.colormod = '0 1 1'; // cyan
 386                 else if (waypoint_has_hardwiredlinks(wp))
 387                         wp.colormod = '0.5 0 1'; // purple
 388                 else
 389                         wp.colormod = '1 1 1';
 390         }
 391         else
 392                 wp.model = "";
 393 }
 394
 395 string waypoint_get_type_name(entity wp)
 396 {
 397         if (wp.wpflags & WAYPOINTFLAG_ITEM) return "^1Item waypoint";
 398         else if (wp.wpflags & WAYPOINTFLAG_CROUCH) return "^5Crouch waypoint";
 399         else if (wp.wpflags & WAYPOINTFLAG_JUMP) return "^xf80Jump waypoint";
 400         else if (wp.wpflags & WAYPOINTFLAG_SUPPORT) return "^2Support waypoint";
 401         else if (waypoint_has_hardwiredlinks(wp)) return "^x80fHardwired waypoint";
 402         else if (wp.wpflags & WAYPOINTFLAG_LADDER) return "^3Ladder waypoint";
 403         else if (wp.wpflags & WAYPOINTFLAG_TELEPORT)
 404         {
 405                 if (!wp.wpisbox) return "^3Warpzone waypoint";
 406                 else if (wp.wpflags & WAYPOINTFLAG_CUSTOM_JP) return "^3Custom jumppad waypoint";
 407                 else
 408                 {
 409                         IL_EACH(g_jumppads, boxesoverlap(wp.absmin, wp.absmax, it.absmin, it.absmax),
 410                                 { return "^3Jumppad waypoint"; });
 411                         return "^3Teleport waypoint";
 412                 }
 413         }
 414
 415         return "^7Waypoint";
 416 }
 417
 418 entity waypoint_get(vector m1, vector m2)
 419 {
 420         if (m1 == m2)
 421         {
 422                 m1 -= '8 8 8';
 423                 m2 += '8 8 8';
 424         }
 425         IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax), { return it; });
 426
 427         return NULL;
 428 }
 429
 430 .float createdtime;
 431 entity waypoint_spawn(vector m1, vector m2, float f)
 432 {
 433         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 434         {
 435                 entity wp_found = waypoint_get(m1, m2);
 436                 if (wp_found)
 437                         return wp_found;
 438         }
 439         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 440         // otherwise links loaded from file would be applied only to the first destination
 441         // waypoint since link format doesn't specify waypoint entities but just positions
 442         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WPFLAGMASK_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 443         {
 444                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 445                 {
 446                         return it;
 447                 });
 448         }
 449
 450         entity w = new(waypoint);
 451         IL_PUSH(g_waypoints, w);
 452         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 453         w.wpflags = f;
 454         w.solid = SOLID_TRIGGER;
 455         w.createdtime = time;
 456         w.origin = (m1 + m2) * 0.5;
 457         if (waypointeditor_enabled)
 458                 setorigin(w, w.origin);
 459         else // don't link into the world, only bots are aware of waypoints
 460                 make_pure(w);
 461         setsize(w, m1 - w.origin, m2 - w.origin);
 462         if (w.size)
 463                 w.wpisbox = true;
 464
 465         if(!w.wpisbox)
 466         {
 467                 if (f & WAYPOINTFLAG_CROUCH)
 468                         setsize(w, PL_CROUCH_MIN_CONST - '1 1 0', PL_CROUCH_MAX_CONST + '1 1 0');
 469                 else
 470                         setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 471                 if(!move_out_of_solid(w))
 472                 {
 473                         if(!(f & WAYPOINTFLAG_GENERATED))
 474                         {
 475                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 476                                 delete(w);
 477                                 return NULL;
 478                         }
 479                         else
 480                         {
 481                                 if(autocvar_developer > 0)
 482                                 {
 483                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 484                                         backtrace("Waypoint stuck");
 485                                 }
 486                         }
 487                 }
 488                 setsize(w, '0 0 0', '0 0 0');
 489         }
 490
 491         waypoint_clearlinks(w);
 492         //waypoint_schedulerelink(w);
 493
 494         waypoint_setupmodel(w);
 495
 496         return w;
 497 }
 498
 499 float trigger_push_get_push_time(entity this, vector endpos);
 500 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 501 {
 502         entity jp = NULL;
 503         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 504         {
 505                 jp = it;
 506                 break;
 507         });
 508         if (!jp)
 509                 return;
 510
 511         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 512         wp_from.wp00 = wp_to;
 513         wp_from.wp00mincost = cost;
 514         jp.nearestwaypoint = wp_from;
 515         jp.nearestwaypointtimeout = -1;
 516 }
 517
 518 bool start_wp_is_spawned;
 519 vector start_wp_origin;
 520 bool start_wp_is_hardwired;
 521 bool start_wp_is_support;
 522
 523 void waypoint_clear_start_wp_globals(entity pl, bool warn)
 524 {
 525         start_wp_is_spawned = false;
 526         start_wp_origin = '0 0 0';
 527         pl.wp_locked = NULL;
 528         start_wp_is_hardwired = false;
 529         start_wp_is_support = false;
 530         if (warn)
 531                 LOG_INFO("^xf80Start waypoint has been cleared.\n");
 532 }
 533
 534 void waypoint_start_hardwiredlink(entity pl, bool at_crosshair)
 535 {
 536         entity wp = pl.nearestwaypoint;
 537         if (at_crosshair)
 538         {
 539                 crosshair_trace_waypoints(pl);
 540                 wp = trace_ent;
 541         }
 542         string err = "";
 543         if (start_wp_is_spawned && !start_wp_is_hardwired)
 544                 err = "can't hardwire while in the process of creating a special link";
 545         else if (!wp)
 546         {
 547                 if (at_crosshair)
 548                         err = "couldn't find any waypoint at crosshair";
 549                 else
 550                         err = "couldn't find any waypoint nearby";
 551         }
 552         else if (wp.wpflags & WPFLAGMASK_NORELINK)
 553                 err = "can't hardwire a waypoint with special links";
 554
 555         if (err == "")
 556         {
 557                 start_wp_is_hardwired = true;
 558                 start_wp_is_spawned = true;
 559                 start_wp_origin = wp.origin;
 560                 pl.wp_locked = wp;
 561                 LOG_INFOF("^x80fWaypoint %s marked as hardwired link origin.\n", vtos(wp.origin));
 562         }
 563         else
 564         {
 565                 start_wp_is_hardwired = false;
 566                 LOG_INFO("Error: ", err, "\n");
 567         }
 568 }
 569
 570 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair, bool is_jump_wp, bool is_crouch_wp, bool is_support_wp)
 571 {
 572         if (WAYPOINT_VERSION < waypoint_version_loaded)
 573         {
 574                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 575                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 576                 return;
 577         }
 578
 579         entity e = NULL, jp = NULL;
 580         vector org = pl.origin;
 581         if (at_crosshair)
 582         {
 583                 crosshair_trace_waypoints(pl);
 584                 org = trace_endpos;
 585                 if (!trace_ent)
 586                         org.z -= PL_MIN_CONST.z;
 587                 if (!(start_wp_is_hardwired || start_wp_is_support))
 588                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 589                         {
 590                                 jp = it;
 591                                 break;
 592                         });
 593                 if (!jp && !start_wp_is_spawned && trace_ent)
 594                 {
 595                         if (trace_ent.wpflags & (WAYPOINTFLAG_JUMP))
 596                                 is_jump_wp = true;
 597                         else if (trace_ent.wpflags & (WAYPOINTFLAG_SUPPORT))
 598                                 is_support_wp = true;
 599                 }
 600         }
 601         if (jp || is_jump_wp || is_support_wp)
 602         {
 603                 if (start_wp_is_spawned)
 604                         start_wp_is_spawned = false;
 605                 LOG_INFO("^xf80Spawning start waypoint...\n");
 606         }
 607         int ctf_flags = havocbot_symmetry_origin_order;
 608         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 609                    || (autocvar_g_waypointeditor_symmetrical < 0));
 610         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 611                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 612         if (sym && ctf_flags < 2)
 613                 ctf_flags = 2;
 614         int wp_num = ctf_flags;
 615
 616         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair && !is_jump_wp && !is_support_wp)
 617         {
 618                 // snap waypoint to item's origin if close enough
 619                 IL_EACH(g_items, true,
 620                 {
 621                         vector item_org = (it.absmin + it.absmax) * 0.5;
 622                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 623                         if (vlen(item_org - org) < 20)
 624                         {
 625                                 org = item_org;
 626                                 break;
 627                         }
 628                 });
 629         }
 630
 631         vector start_org = '0 0 0';
 632         if (start_wp_is_spawned)
 633         {
 634                 if (!start_wp_is_hardwired)
 635                         LOG_INFO("^xf80Spawning destination waypoint...\n");
 636                 start_org = start_wp_origin;
 637         }
 638
 639         // save org as it can be modified spawning symmetrycal waypoints
 640         vector initial_origin = '0 0 0';
 641         bool initial_origin_is_set = false;
 642
 643         LABEL(add_wp);
 644
 645         if (jp)
 646         {
 647                 e = NULL;
 648                 IL_EACH(g_waypoints, (it.wpflags & WPFLAGMASK_NORELINK)
 649                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 650                 {
 651                         e = it; break;
 652                 });
 653                 if (!e)
 654                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT);
 655                 if (!pl.wp_locked)
 656                         pl.wp_locked = e;
 657         }
 658         else if (is_jump_wp || is_support_wp)
 659         {
 660                 int type_flag = (is_jump_wp) ? WAYPOINTFLAG_JUMP : WAYPOINTFLAG_SUPPORT;
 661
 662                 entity wp_found = waypoint_get(org, org);
 663                 if (wp_found && !(wp_found.wpflags & type_flag))
 664                 {
 665                         LOG_INFOF("Error: can't spawn a %s waypoint over an existent waypoint of a different type\n", (is_jump_wp) ? "Jump" : "Support");
 666                         return;
 667                 }
 668                 e = waypoint_spawn(org, org, type_flag);
 669                 if (!pl.wp_locked)
 670                         pl.wp_locked = e;
 671         }
 672         else
 673                 e = waypoint_spawn(org, org, (is_crouch_wp) ? WAYPOINTFLAG_CROUCH : 0);
 674         if(!e)
 675         {
 676                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 677                 if (start_wp_is_spawned)
 678                         waypoint_clear_start_wp_globals(pl, true);
 679                 return;
 680         }
 681
 682         if (!initial_origin_is_set)
 683         {
 684                 initial_origin = e.origin;
 685                 initial_origin_is_set = true;
 686         }
 687
 688         entity start_wp = NULL;
 689         if (start_wp_is_spawned)
 690         {
 691                 IL_EACH(g_waypoints, (start_wp_is_hardwired || (it.wpflags & WPFLAGMASK_NORELINK))
 692                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 693                 {
 694                         start_wp = it; break;
 695                 });
 696                 if(!start_wp)
 697                 {
 698                         // should not happen
 699                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 700                         waypoint_clear_start_wp_globals(pl, true);
 701                         return;
 702                 }
 703                 if (start_wp_is_hardwired)
 704                 {
 705                         if (waypoint_is_hardwiredlink(start_wp, e))
 706                         {
 707                                 waypoint_unmark_hardwiredlink(start_wp, e);
 708                                 waypoint_removelink(start_wp, e);
 709                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 710                                 LOG_INFOF("^x80fRemoved hardwired link %s.\n", s);
 711                         }
 712                         else
 713                         {
 714                                 if (e.createdtime == time)
 715                                 {
 716                                         LOG_INFO("Error: hardwired links can be created only between 2 existing (and unconnected) waypoints.\n");
 717                                         waypoint_remove(e);
 718                                         waypoint_clear_start_wp_globals(pl, true);
 719                                         waypoint_spawn_fromeditor(pl, at_crosshair, is_jump_wp, is_crouch_wp, is_support_wp);
 720                                         return;
 721                                 }
 722                                 if (start_wp == e)
 723                                 {
 724                                         LOG_INFO("Error: start and destination waypoints coincide.\n");
 725                                         waypoint_clear_start_wp_globals(pl, true);
 726                                         return;
 727                                 }
 728                                 if (waypoint_islinked(start_wp, e))
 729                                 {
 730                                         LOG_INFO("Error: waypoints are already linked.\n");
 731                                         waypoint_clear_start_wp_globals(pl, true);
 732                                         return;
 733                                 }
 734                                 waypoint_addlink(start_wp, e);
 735                                 waypoint_mark_hardwiredlink(start_wp, e);
 736                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 737                                 LOG_INFOF("^x80fAdded hardwired link %s.\n", s);
 738                         }
 739                 }
 740                 else
 741                 {
 742                         if (start_wp_is_support)
 743                         {
 744                                 if (e.SUPPORT_WP)
 745                                 {
 746                                         LOG_INFOF("Waypoint %v has already a support waypoint, delete it first.\n", e.origin);
 747                                         waypoint_clear_start_wp_globals(pl, true);
 748                                         return;
 749                                 }
 750                                 // clear all links to e
 751                                 IL_EACH(g_waypoints, it != e,
 752                                 {
 753                                         if (waypoint_islinked(it, e) && !waypoint_is_hardwiredlink(it, e))
 754                                                 waypoint_removelink(it, e);
 755                                 });
 756                         }
 757                         waypoint_addlink(start_wp, e);
 758                 }
 759         }
 760
 761         if (!(jp || is_jump_wp || is_support_wp || start_wp_is_hardwired))
 762                 waypoint_schedulerelink(e);
 763
 764         string wp_type_str = waypoint_get_type_name(e);
 765
 766         bprint(strcat(wp_type_str, "^7 spawned at ", vtos(e.origin), "\n"));
 767
 768         if (start_wp_is_spawned)
 769         {
 770                 pl.wp_locked = NULL;
 771                 if (!start_wp_is_hardwired)
 772                         waypoint_schedulerelink(start_wp);
 773                 if (start_wp.wpflags & WAYPOINTFLAG_TELEPORT)
 774                 {
 775                         if (start_wp.wp00_original == start_wp.wp00)
 776                                 start_wp.wpflags &= ~WAYPOINTFLAG_CUSTOM_JP;
 777                         else
 778                                 start_wp.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
 779                 }
 780         }
 781
 782         if (sym)
 783         {
 784                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 785                 if (jp)
 786                 {
 787                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 788                         {
 789                                 jp = it; break;
 790                         });
 791                 }
 792                 if (start_wp_is_spawned)
 793                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 794                 if (vdist(org - pl.origin, >, 32))
 795                 {
 796                         if(wp_num > 2)
 797                                 wp_num--;
 798                         else
 799                                 sym = false;
 800                         goto add_wp;
 801                 }
 802         }
 803         if (jp || is_jump_wp || is_support_wp)
 804         {
 805                 if (!start_wp_is_spawned)
 806                 {
 807                         // we've just created a custom jumppad waypoint
 808                         // the next one created by the user will be the destination waypoint
 809                         start_wp_is_spawned = true;
 810                         start_wp_origin = initial_origin;
 811                         if (is_support_wp)
 812                                 start_wp_is_support = true;
 813                 }
 814         }
 815         else if (start_wp_is_spawned)
 816         {
 817                 waypoint_clear_start_wp_globals(pl, false);
 818         }
 819 }
 820
 821 void waypoint_remove(entity wp)
 822 {
 823         IL_EACH(g_waypoints, it != wp,
 824         {
 825                 if (it.SUPPORT_WP == wp)
 826                 {
 827                         it.SUPPORT_WP = NULL;
 828                         waypoint_schedulerelink(it); // restore incoming links
 829                 }
 830                 if (waypoint_islinked(it, wp))
 831                 {
 832                         if (waypoint_is_hardwiredlink(it, wp))
 833                                 waypoint_unmark_hardwiredlink(it, wp);
 834                         waypoint_removelink(it, wp);
 835                 }
 836         });
 837         delete(wp);
 838 }
 839
 840 void waypoint_remove_fromeditor(entity pl)
 841 {
 842         if (WAYPOINT_VERSION < waypoint_version_loaded)
 843         {
 844                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 845                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 846                 return;
 847         }
 848
 849         entity e = navigation_findnearestwaypoint(pl, false);
 850
 851         int ctf_flags = havocbot_symmetry_origin_order;
 852         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 853                    || (autocvar_g_waypointeditor_symmetrical < 0));
 854         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 855                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 856         if (sym && ctf_flags < 2)
 857                 ctf_flags = 2;
 858         int wp_num = ctf_flags;
 859
 860         LABEL(remove_wp);
 861         if (!e) return;
 862
 863         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 864         {
 865                 if (start_wp_is_spawned)
 866                         waypoint_clear_start_wp_globals(pl, true);
 867                 return;
 868         }
 869
 870         if (waypoint_has_hardwiredlinks(e))
 871         {
 872                 LOG_INFO("Can't remove a waypoint with hardwired links, remove links with \"wpeditor hardwire\" first\n");
 873                 return;
 874         }
 875
 876         entity wp_sym = NULL;
 877         if (sym)
 878         {
 879                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 880                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 881                         if(vdist(org - it.origin, <, 3))
 882                         {
 883                                 wp_sym = it;
 884                                 break;
 885                         }
 886                 });
 887         }
 888
 889         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 890         te_explosion(e.origin);
 891         waypoint_remove(e);
 892
 893         if (sym && wp_sym)
 894         {
 895                 e = wp_sym;
 896                 if(wp_num > 2)
 897                         wp_num--;
 898                 else
 899                         sym = false;
 900                 goto remove_wp;
 901         }
 902
 903         if (start_wp_is_spawned)
 904                 waypoint_clear_start_wp_globals(pl, true);
 905 }
 906
 907 void waypoint_removelink(entity from, entity to)
 908 {
 909         if (from == to || ((from.wpflags & WPFLAGMASK_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT))))
 910                 return;
 911
 912         entity fromwp31_prev = from.wp31;
 913
 914         switch (waypoint_getlinknum(from, to))
 915         {
 916                 // fallthrough all the way
 917                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 918                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 919                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 920                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 921                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 922                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 923                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 924                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 925                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 926                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 927                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 928                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 929                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 930                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 931                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 932                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 933                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 934                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 935                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 936                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 937                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 938                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 939                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 940                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 941                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 942                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 943                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 944                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 945                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 946                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 947                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 948                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 949         }
 950
 951         if (fromwp31_prev && !from.wp31)
 952                 waypoint_schedulerelink(from);
 953 }
 954
 955 int waypoint_getlinknum(entity from, entity to)
 956 {
 957         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 958         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 959         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 960         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 961         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 962         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 963         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 964         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 965         return -1;
 966 }
 967
 968 bool waypoint_islinked(entity from, entity to)
 969 {
 970         return (waypoint_getlinknum(from, to) >= 0);
 971 }
 972
 973 void waypoint_updatecost_foralllinks()
 974 {
 975         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 976         {
 977                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 978                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 979                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 980                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 981                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 982                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 983                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 984                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 985                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 986                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 987                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 988                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 989                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 990                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 991                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 992                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 993                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 994                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 995                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 996                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 997                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 998                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 999                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
1000                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
1001                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
1002                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
1003                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
1004                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
1005                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
1006                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
1007                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
1008                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
1009         });
1010 }
1011
1012 float waypoint_getlinearcost(float dist)
1013 {
1014         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
1015                 return dist / (autocvar_sv_maxspeed * 1.25);
1016         return dist / autocvar_sv_maxspeed;
1017 }
1018
1019 float waypoint_getlinearcost_underwater(float dist)
1020 {
1021         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
1022         return dist / (autocvar_sv_maxspeed * 0.7);
1023 }
1024
1025 float waypoint_getlinearcost_crouched(float dist)
1026 {
1027         return dist / (autocvar_sv_maxspeed * 0.5);
1028 }
1029
1030 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
1031 {
1032         bool submerged_from = navigation_check_submerged_state(from_ent, from);
1033         bool submerged_to = navigation_check_submerged_state(to_ent, to);
1034
1035         if (submerged_from && submerged_to)
1036                 return waypoint_getlinearcost_underwater(vlen(to - from));
1037
1038         if ((from_ent.wpflags & WAYPOINTFLAG_CROUCH) && (to_ent.wpflags & WAYPOINTFLAG_CROUCH))
1039                 return waypoint_getlinearcost_crouched(vlen(to - from));
1040
1041         float c = waypoint_getlinearcost(vlen(to - from));
1042
1043         float height = from.z - to.z;
1044         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
1045         {
1046                 float height_cost; // fall cost
1047                 if (from_ent.wpflags & WAYPOINTFLAG_JUMP)
1048                         height_cost = jumpheight_time + sqrt((height + jumpheight_vec.z) / (autocvar_sv_gravity / 2));
1049                 else
1050                         height_cost = sqrt(height / (autocvar_sv_gravity / 2));
1051                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
1052                 if(height_cost > c)
1053                         c = height_cost;
1054         }
1055
1056         // consider half path underwater
1057         if (submerged_from || submerged_to)
1058                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
1059
1060         // consider half path crouched
1061         if ((from_ent.wpflags & WAYPOINTFLAG_CROUCH) || (to_ent.wpflags & WAYPOINTFLAG_CROUCH))
1062                 return (c + waypoint_getlinearcost_crouched(vlen(to - from))) / 2;
1063
1064         return c;
1065 }
1066
1067 float waypoint_getlinkcost(entity from, entity to)
1068 {
1069         vector v1 = from.origin;
1070         vector v2 = to.origin;
1071         if (from.wpisbox)
1072         {
1073                 vector m1 = from.absmin, m2 = from.absmax;
1074                 v1.x = bound(m1.x, v2.x, m2.x);
1075                 v1.y = bound(m1.y, v2.y, m2.y);
1076                 v1.z = bound(m1.z, v2.z, m2.z);
1077         }
1078         if (to.wpisbox)
1079         {
1080                 vector m1 = to.absmin, m2 = to.absmax;
1081                 v2.x = bound(m1.x, v1.x, m2.x);
1082                 v2.y = bound(m1.y, v1.y, m2.y);
1083                 v2.z = bound(m1.z, v1.z, m2.z);
1084         }
1085         return waypoint_gettravelcost(v1, v2, from, to);
1086 }
1087
1088 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
1089 // if c == -1 automatically determine cost of the link
1090 void waypoint_addlink_customcost(entity from, entity to, float c)
1091 {
1092         if (from == to || waypoint_islinked(from, to))
1093                 return;
1094         if (c == -1 && (from.wpflags & WPFLAGMASK_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)))
1095                 return;
1096
1097         if(c == -1)
1098                 c = waypoint_getlinkcost(from, to);
1099
1100         if (from.wp31mincost < c) return;
1101         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
1102         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
1103         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
1104         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
1105         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
1106         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
1107         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
1108         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
1109         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
1110         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
1111         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
1112         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
1113         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
1114         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
1115         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
1116         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
1117         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
1118         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
1119         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
1120         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
1121         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
1122         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
1123         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
1124         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
1125         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
1126         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
1127         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
1128         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
1129         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
1130         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
1131         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
1132         from.wp00 = to;from.wp00mincost = c;return;
1133 }
1134
1135 void waypoint_addlink(entity from, entity to)
1136 {
1137         if ((from.wpflags & WPFLAGMASK_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)))
1138                 waypoint_addlink_for_custom_jumppad(from, to);
1139         else
1140                 waypoint_addlink_customcost(from, to, -1);
1141
1142         if (from.wpflags & WAYPOINTFLAG_SUPPORT)
1143                 to.SUPPORT_WP = from;
1144 }
1145
1146 // relink this spawnfunc_waypoint
1147 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
1148 // (SLOW!)
1149 void waypoint_think(entity this)
1150 {
1151         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
1152         float sv2_height = 0, ev2_height = 0;
1153
1154         bot_calculate_stepheightvec();
1155
1156         int dphitcontentsmask_save = this.dphitcontentsmask;
1157         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1158
1159         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
1160
1161         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
1162         IL_EACH(g_waypoints, this != it,
1163         {
1164                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
1165                 {
1166                         if (!(this.wpflags & WPFLAGMASK_NORELINK))
1167                                 waypoint_addlink(this, it);
1168                         if (!(it.wpflags & WPFLAGMASK_NORELINK))
1169                                 waypoint_addlink(it, this);
1170                 }
1171                 else
1172                 {
1173                         ++relink_total;
1174                         if(!checkpvs(this.origin, it))
1175                         {
1176                                 ++relink_pvsculled;
1177                                 continue;
1178                         }
1179
1180                         sv = set_tracewalk_dest_2(this, it.origin);
1181                         sv2 = tracewalk_dest;
1182                         sv2_height = tracewalk_dest_height;
1183                         ev = set_tracewalk_dest_2(it, this.origin);
1184                         ev2 = tracewalk_dest;
1185                         ev2_height = tracewalk_dest_height;
1186
1187                         dv = ev - sv;
1188                         dv.z = 0;
1189                         int maxdist = 1050;
1190                         vector m1 = PL_MIN_CONST;
1191                         vector m2 = PL_MAX_CONST;
1192
1193                         if ((this.wpflags & WAYPOINTFLAG_CROUCH) || (it.wpflags & WAYPOINTFLAG_CROUCH))
1194                         {
1195                                 m1 = PL_CROUCH_MIN_CONST;
1196                                 m2 = PL_CROUCH_MAX_CONST;
1197                                 // links from crouch wp to normal wp (and viceversa) are very short to avoid creating many links
1198                                 // that would be wasted due to rough travel cost calculation (the longer link is, the higher cost is)
1199                                 // links from crouch wp to crouch wp can be as long as normal links
1200                                 if (!((this.wpflags & WAYPOINTFLAG_CROUCH) && (it.wpflags & WAYPOINTFLAG_CROUCH)))
1201                                         maxdist = 100;
1202                         }
1203
1204                         if (vdist(dv, >=, maxdist)) // max search distance in XY
1205                         {
1206                                 ++relink_lengthculled;
1207                                 continue;
1208                         }
1209
1210                         navigation_testtracewalk = 0;
1211
1212                         //traceline(this.origin, it.origin, false, NULL);
1213                         //if (trace_fraction == 1)
1214                         if (this.wpisbox || (this.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)) // forbid outgoing links
1215                                 || it.SUPPORT_WP) // forbid incoming links
1216                         {
1217                                 relink_walkculled += 0.5;
1218                         }
1219                         else
1220                         {
1221                                 if (tracewalk(this, sv, m1, m2, ev2, ev2_height, MOVE_NOMONSTERS))
1222                                         waypoint_addlink(this, it);
1223                                 else
1224                                         relink_walkculled += 0.5;
1225                         }
1226
1227                         // reverse direction
1228                         if (it.wpisbox || (it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)) // forbid incoming links
1229                                 || this.SUPPORT_WP) // forbid outgoing links
1230                         {
1231                                 relink_walkculled += 0.5;
1232                         }
1233                         else
1234                         {
1235                                 if (tracewalk(this, ev, m1, m2, sv2, sv2_height, MOVE_NOMONSTERS))
1236                                         waypoint_addlink(it, this);
1237                                 else
1238                                         relink_walkculled += 0.5;
1239                         }
1240                 }
1241         });
1242
1243         // waypoint_clearlinks preserves references to old hardwired links (.wphwXX links)
1244         // so they can be restored here when a wp is spawned over an existing one
1245         waypoint_restore_hardwiredlinks(this);
1246
1247         navigation_testtracewalk = 0;
1248         this.wplinked = true;
1249         this.dphitcontentsmask = dphitcontentsmask_save;
1250
1251         setthink(this, func_null);
1252         this.nextthink = 0;
1253 }
1254
1255 void waypoint_clearlinks(entity wp)
1256 {
1257         // clear links to other waypoints
1258         float f = 10000000;
1259         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
1260         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
1261         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
1262         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
1263
1264         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
1265         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
1266         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
1267         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
1268
1269         // don't remove references to hardwired links (.wphwXX fields)
1270
1271         wp.wplinked = false;
1272 }
1273
1274 // tell a spawnfunc_waypoint to relink
1275 void waypoint_schedulerelink(entity wp)
1276 {
1277         if (wp == NULL)
1278                 return;
1279
1280         waypoint_setupmodel(wp);
1281         wp.wpisbox = vdist(wp.size, >, 0);
1282         wp.enemy = NULL;
1283         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
1284                 wp.owner = NULL;
1285         if (!(wp.wpflags & WPFLAGMASK_NORELINK))
1286                 waypoint_clearlinks(wp);
1287         // schedule an actual relink on next frame
1288         setthink(wp, waypoint_think);
1289         wp.nextthink = time;
1290         wp.effects = EF_LOWPRECISION;
1291 }
1292
1293 // spawnfunc_waypoint map entity
1294 spawnfunc(waypoint)
1295 {
1296         IL_PUSH(g_waypoints, this);
1297
1298         if (waypointeditor_enabled)
1299                 setorigin(this, this.origin);
1300         else
1301                 make_pure(this);
1302         // schedule a relink after other waypoints have had a chance to spawn
1303         waypoint_clearlinks(this);
1304         //waypoint_schedulerelink(this);
1305 }
1306
1307 // tell all waypoints to relink
1308 // actually this is useful only to update relink_* stats
1309 void waypoint_schedulerelinkall()
1310 {
1311         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
1312         IL_EACH(g_waypoints, true,
1313         {
1314                 waypoint_schedulerelink(it);
1315         });
1316         waypoint_load_hardwiredlinks();
1317 }
1318
1319 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
1320
1321 // Load waypoint links from file
1322 bool waypoint_load_links()
1323 {
1324         string s;
1325         float file, tokens, c = 0, found;
1326         entity wp_from = NULL, wp_to;
1327         vector wp_to_pos, wp_from_pos;
1328
1329         string gt_ext = GET_GAMETYPE_EXTENSION();
1330
1331         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1332         file = fopen(filename, FILE_READ);
1333
1334         if (gt_ext != "" && file < 0)
1335         {
1336                 // if race waypoint file doesn't exist load the default one
1337                 filename = sprintf("maps/%s.waypoints.cache", mapname);
1338                 file = fopen(filename, FILE_READ);
1339         }
1340
1341         if (file < 0)
1342         {
1343                 LOG_TRACE("waypoint links load from ", filename, " failed");
1344                 waypoint_schedulerelinkall();
1345                 return false;
1346         }
1347
1348         bool parse_comments = true;
1349         float ver = 0;
1350         string links_time = string_null;
1351
1352         while ((s = fgets(file)))
1353         {
1354                 if(parse_comments)
1355                 {
1356                         if(substring(s, 0, 2) == "//")
1357                         {
1358                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1359                                         ver = stof(substring(s, 19, -1));
1360                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1361                                         links_time = substring(s, 16, -1);
1362                                 continue;
1363                         }
1364                         else
1365                         {
1366                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
1367                                 {
1368                                         if (links_time != waypoint_time)
1369                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
1370                                         else
1371                                                 LOG_TRACE("waypoint links for this map are outdated.");
1372                                         if (g_assault)
1373                                         {
1374                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
1375                                         }
1376                                         else
1377                                         {
1378                                                 LOG_TRACE("automatically updating...");
1379                                                 waypoint_schedulerelinkall();
1380                                                 fclose(file);
1381                                                 return false;
1382                                         }
1383                                 }
1384                                 parse_comments = false;
1385                         }
1386                 }
1387
1388                 tokens = tokenizebyseparator(s, "*");
1389
1390                 if (tokens!=2)
1391                 {
1392                         // bad file format
1393                         fclose(file);
1394                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1395                         return false;
1396                 }
1397
1398                 wp_from_pos     = stov(argv(0));
1399                 wp_to_pos       = stov(argv(1));
1400
1401                 // Search "from" waypoint
1402                 if(!wp_from || wp_from.origin!=wp_from_pos)
1403                 {
1404                         wp_from = findradius(wp_from_pos, 1);
1405                         found = false;
1406                         while(wp_from)
1407                         {
1408                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1409                                 if(wp_from.classname == "waypoint")
1410                                 {
1411                                         found = true;
1412                                         break;
1413                                 }
1414                                 wp_from = wp_from.chain;
1415                         }
1416
1417                         if(!found)
1418                         {
1419                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1420                                 continue;
1421                         }
1422                 }
1423
1424                 // Search "to" waypoint
1425                 wp_to = findradius(wp_to_pos, 1);
1426                 found = false;
1427                 while(wp_to)
1428                 {
1429                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1430                         if(wp_to.classname == "waypoint")
1431                         {
1432                                 found = true;
1433                                 break;
1434                         }
1435                         wp_to = wp_to.chain;
1436                 }
1437
1438                 if(!found)
1439                 {
1440                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1441                         continue;
1442                 }
1443
1444                 ++c;
1445                 waypoint_addlink(wp_from, wp_to);
1446                 if (wp_from.wp00_original && wp_from.wp00_original != wp_from.wp00)
1447                         wp_from.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
1448         }
1449
1450         fclose(file);
1451
1452         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1453
1454         bool scheduled = false;
1455         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1456         {
1457                 if (!it.wp00)
1458                 {
1459                         waypoint_schedulerelink(it);
1460                         scheduled = true;
1461                 }
1462         });
1463         if (scheduled)
1464                 return false;
1465
1466         botframe_cachedwaypointlinks = true;
1467         return true;
1468 }
1469
1470 void waypoint_load_hardwiredlinks()
1471 {
1472         string s;
1473         float file, tokens, c = 0, found;
1474         entity wp_from = NULL, wp_to;
1475         vector wp_to_pos, wp_from_pos;
1476
1477         string gt_ext = GET_GAMETYPE_EXTENSION();
1478
1479         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1480         file = fopen(filename, FILE_READ);
1481
1482         if (gt_ext != "" && file < 0)
1483         {
1484                 // if race waypoint file doesn't exist load the default one
1485                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1486                 file = fopen(filename, FILE_READ);
1487         }
1488
1489         botframe_loadedforcedlinks = true;
1490
1491         if (file < 0)
1492         {
1493                 LOG_TRACE("waypoint links load from ", filename, " failed");
1494                 return;
1495         }
1496
1497         bool is_special = false;
1498         while ((s = fgets(file)))
1499         {
1500                 if(substring(s, 0, 2)=="//")
1501                         continue;
1502
1503                 if(substring(s, 0, 1)=="#")
1504                         continue;
1505
1506                 // special links start with *, so old xonotic versions don't load them
1507                 is_special = false;
1508                 if (substring(s, 0, 1) == "*")
1509                 {
1510                         is_special = true;
1511                         s = substring(s, 1, -1);
1512                 }
1513
1514                 tokens = tokenizebyseparator(s, "*");
1515
1516                 if (tokens!=2)
1517                         continue;
1518
1519                 wp_from_pos     = stov(argv(0));
1520                 wp_to_pos       = stov(argv(1));
1521
1522                 // Search "from" waypoint
1523                 if(!wp_from || wp_from.origin!=wp_from_pos)
1524                 {
1525                         wp_from = findradius(wp_from_pos, 5);
1526                         found = false;
1527                         while(wp_from)
1528                         {
1529                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1530                                 if(wp_from.classname == "waypoint")
1531                                 {
1532                                         found = true;
1533                                         break;
1534                                 }
1535                                 wp_from = wp_from.chain;
1536                         }
1537
1538                         if(!found)
1539                         {
1540                                 s = strcat(((is_special) ? "special link " : "hardwired link "), s);
1541                                 LOG_INFO("NOTICE: Can not find origin waypoint of the ", s, ". Path skipped");
1542                                 continue;
1543                         }
1544                 }
1545
1546                 // Search "to" waypoint
1547                 wp_to = findradius(wp_to_pos, 5);
1548                 found = false;
1549                 while(wp_to)
1550                 {
1551                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1552                         if(wp_to.classname == "waypoint")
1553                         {
1554                                 found = true;
1555                                 break;
1556                         }
1557                         wp_to = wp_to.chain;
1558                 }
1559
1560                 if(!found)
1561                 {
1562                         s = strcat(((is_special) ? "special link " : "hardwired link "), s);
1563                         LOG_INFO("NOTICE: Can not find destination waypoint of the ", s, ". Path skipped");
1564                         continue;
1565                 }
1566
1567                 ++c;
1568
1569                 if (!is_special)
1570                 {
1571                         waypoint_addlink(wp_from, wp_to);
1572                         waypoint_mark_hardwiredlink(wp_from, wp_to);
1573                 } else if (wp_from.wpflags & WPFLAGMASK_NORELINK
1574                         && ((wp_from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT))
1575                                 || (wp_from.wpisbox && wp_from.wpflags & WAYPOINTFLAG_TELEPORT)))
1576                 {
1577                         waypoint_addlink(wp_from, wp_to);
1578                 }
1579         }
1580
1581         fclose(file);
1582
1583         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1584 }
1585
1586 float waypoint_get_assigned_link_cost(entity w, float i)
1587 {
1588         switch(i)
1589         {
1590                 case  0: return w.wp00mincost;
1591                 case  1: return w.wp01mincost;
1592                 case  2: return w.wp02mincost;
1593                 case  3: return w.wp03mincost;
1594                 case  4: return w.wp04mincost;
1595                 case  5: return w.wp05mincost;
1596                 case  6: return w.wp06mincost;
1597                 case  7: return w.wp07mincost;
1598                 case  8: return w.wp08mincost;
1599                 case  9: return w.wp09mincost;
1600                 case 10: return w.wp10mincost;
1601                 case 11: return w.wp11mincost;
1602                 case 12: return w.wp12mincost;
1603                 case 13: return w.wp13mincost;
1604                 case 14: return w.wp14mincost;
1605                 case 15: return w.wp15mincost;
1606                 case 16: return w.wp16mincost;
1607                 case 17: return w.wp17mincost;
1608                 case 18: return w.wp18mincost;
1609                 case 19: return w.wp19mincost;
1610                 case 20: return w.wp20mincost;
1611                 case 21: return w.wp21mincost;
1612                 case 22: return w.wp22mincost;
1613                 case 23: return w.wp23mincost;
1614                 case 24: return w.wp24mincost;
1615                 case 25: return w.wp25mincost;
1616                 case 26: return w.wp26mincost;
1617                 case 27: return w.wp27mincost;
1618                 case 28: return w.wp28mincost;
1619                 case 29: return w.wp29mincost;
1620                 case 30: return w.wp30mincost;
1621                 case 31: return w.wp31mincost;
1622                 default: return -1;
1623         }
1624 }
1625
1626 entity waypoint_get_link(entity w, float i)
1627 {
1628         switch(i)
1629         {
1630                 case  0:return w.wp00;
1631                 case  1:return w.wp01;
1632                 case  2:return w.wp02;
1633                 case  3:return w.wp03;
1634                 case  4:return w.wp04;
1635                 case  5:return w.wp05;
1636                 case  6:return w.wp06;
1637                 case  7:return w.wp07;
1638                 case  8:return w.wp08;
1639                 case  9:return w.wp09;
1640                 case 10:return w.wp10;
1641                 case 11:return w.wp11;
1642                 case 12:return w.wp12;
1643                 case 13:return w.wp13;
1644                 case 14:return w.wp14;
1645                 case 15:return w.wp15;
1646                 case 16:return w.wp16;
1647                 case 17:return w.wp17;
1648                 case 18:return w.wp18;
1649                 case 19:return w.wp19;
1650                 case 20:return w.wp20;
1651                 case 21:return w.wp21;
1652                 case 22:return w.wp22;
1653                 case 23:return w.wp23;
1654                 case 24:return w.wp24;
1655                 case 25:return w.wp25;
1656                 case 26:return w.wp26;
1657                 case 27:return w.wp27;
1658                 case 28:return w.wp28;
1659                 case 29:return w.wp29;
1660                 case 30:return w.wp30;
1661                 case 31:return w.wp31;
1662                 default:return NULL;
1663         }
1664 }
1665
1666 // Save all hardwired waypoint links to a file
1667 void waypoint_save_hardwiredlinks()
1668 {
1669         string gt_ext = GET_GAMETYPE_EXTENSION();
1670
1671         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1672         int file = fopen(filename, FILE_WRITE);
1673         if (file < 0)
1674         {
1675                 LOG_TRACE("waypoint hardwired links ", filename, " creation failed");
1676                 return;
1677         }
1678
1679         // write hardwired links to file
1680         int count = 0;
1681         fputs(file, "// HARDWIRED LINKS\n");
1682         IL_EACH(g_waypoints, waypoint_has_hardwiredlinks(it),
1683         {
1684                 for (int j = 0; j < 32; ++j)
1685                 {
1686                         entity link = waypoint_get_link(it, j);
1687                         if (waypoint_is_hardwiredlink(it, link))
1688                         {
1689                                 // NOTE: vtos rounds vector components to 1 decimal place
1690                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1691                                 fputs(file, s);
1692                                 ++count;
1693                         }
1694                 }
1695         });
1696
1697         // write special links to file
1698         int count2 = 0;
1699         fputs(file, "\n// SPECIAL LINKS\n");
1700         IL_EACH(g_waypoints, it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP),
1701         {
1702                 for (int j = 0; j < 32; ++j)
1703                 {
1704                         entity link = waypoint_get_link(it, j);
1705                         if (link)
1706                         {
1707                                 // NOTE: vtos rounds vector components to 1 decimal place
1708                                 string s = strcat("*", vtos(it.origin), "*", vtos(link.origin), "\n");
1709                                 fputs(file, s);
1710                                 ++count2;
1711                         }
1712                 }
1713         });
1714
1715         fclose(file);
1716
1717         LOG_INFOF("saved %d hardwired links and %d special links to %s", count, count2, filename);
1718 }
1719
1720 // Save all waypoint links to a file
1721 void waypoint_save_links()
1722 {
1723         string gt_ext = GET_GAMETYPE_EXTENSION();
1724
1725         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1726         int file = fopen(filename, FILE_WRITE);
1727         if (file < 0)
1728         {
1729                 LOG_INFOF("waypoint link save to %s failed", filename);
1730                 return;
1731         }
1732
1733         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1734         if (waypoint_time != "")
1735                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1736
1737         int c = 0;
1738         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP)),
1739         {
1740                 for(int j = 0; j < 32; ++j)
1741                 {
1742                         entity link = waypoint_get_link(it, j);
1743                         if (link && !waypoint_is_hardwiredlink(it, link))
1744                         {
1745                                 // NOTE: vtos rounds vector components to 1 decimal place
1746                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1747                                 fputs(file, s);
1748                                 ++c;
1749                         }
1750                 }
1751         });
1752         fclose(file);
1753
1754         botframe_cachedwaypointlinks = true;
1755
1756         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1757 }
1758
1759 // save waypoints to gamedir/data/maps/mapname.waypoints
1760 void waypoint_saveall()
1761 {
1762         if (WAYPOINT_VERSION < waypoint_version_loaded)
1763         {
1764                 LOG_INFOF("^1Overwriting waypoints with a higher version number (%f) is not allowed.\n"
1765                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1766                 return;
1767         }
1768         string gt_ext = GET_GAMETYPE_EXTENSION();
1769
1770         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1771         int file = fopen(filename, FILE_WRITE);
1772         if (file < 0)
1773         {
1774                 waypoint_save_links(); // save anyway?
1775                 botframe_loadedforcedlinks = false;
1776
1777                 LOG_INFOF("waypoint links: save to %s failed", filename);
1778                 return;
1779         }
1780
1781         float sym = autocvar_g_waypointeditor_symmetrical;
1782         string sym_str = ftos(sym);
1783         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1784         {
1785                 if (sym == 1)
1786                 {
1787                         sym_str = cons(sym_str, "-");
1788                         sym_str = cons(sym_str, "-");
1789                 }
1790                 else
1791                 {
1792                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1793                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1794                 }
1795                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1796                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1797         }
1798         else if (autocvar_g_waypointeditor_symmetrical == -2)
1799         {
1800                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1801                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1802         }
1803
1804         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1805         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1806         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1807         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1808
1809         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1810         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1811         //fputs(file, strcat("//", "\n"));
1812         //fputs(file, strcat("//", "\n"));
1813         //fputs(file, strcat("//", "\n"));
1814
1815         int c = 0;
1816         IL_EACH(g_waypoints, true,
1817         {
1818                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1819                         continue;
1820
1821                 string s;
1822                 // NOTE: vtos rounds vector components to 1 decimal place
1823                 s = strcat(vtos(it.origin + it.mins), "\n");
1824                 s = strcat(s, vtos(it.origin + it.maxs));
1825                 s = strcat(s, "\n");
1826                 s = strcat(s, ftos(it.wpflags));
1827                 s = strcat(s, "\n");
1828                 fputs(file, s);
1829                 c++;
1830         });
1831         fclose(file);
1832         waypoint_save_links();
1833         waypoint_save_hardwiredlinks();
1834
1835         botframe_loadedforcedlinks = false;
1836
1837         waypoint_version_loaded = WAYPOINT_VERSION;
1838         LOG_INFOF("saved %d waypoints to %s", c, filename);
1839 }
1840
1841 // load waypoints from file
1842 float waypoint_loadall()
1843 {
1844         string s;
1845         int file, cwp, cwb, fl;
1846         vector m1, m2;
1847         cwp = 0;
1848         cwb = 0;
1849
1850         string gt_ext = GET_GAMETYPE_EXTENSION();
1851
1852         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1853         file = fopen(filename, FILE_READ);
1854
1855         if (gt_ext != "" && file < 0)
1856         {
1857                 // if race waypoint file doesn't exist load the default one
1858                 filename = sprintf("maps/%s.waypoints", mapname);
1859                 file = fopen(filename, FILE_READ);
1860         }
1861
1862         if (file < 0)
1863         {
1864                 LOG_TRACE("waypoint load from ", filename, " failed");
1865                 return 0;
1866         }
1867
1868         bool parse_comments = true;
1869         float ver = 0;
1870         float sym = 0;
1871         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1872
1873         while ((s = fgets(file)))
1874         {
1875                 if(parse_comments)
1876                 {
1877                         if(substring(s, 0, 2) == "//")
1878                         {
1879                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1880                                         ver = stof(substring(s, 19, -1));
1881                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1882                                 {
1883                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1884                                         if (tokens) { sym = stof(argv(0)); }
1885                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1886                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1887                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1888                                 }
1889                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1890                                         strcpy(waypoint_time, substring(s, 16, -1));
1891                                 continue;
1892                         }
1893                         else
1894                         {
1895                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1896                                 {
1897                                         LOG_TRACE("waypoints for this map are outdated");
1898                                         LOG_TRACE("please update them in the editor");
1899                                 }
1900                                 parse_comments = false;
1901                         }
1902                 }
1903                 m1 = stov(s);
1904                 s = fgets(file);
1905                 if (!s)
1906                         break;
1907                 m2 = stov(s);
1908                 s = fgets(file);
1909                 if (!s)
1910                         break;
1911                 fl = stof(s);
1912                 fl &= ~WAYPOINTFLAG_NORELINK__DEPRECATED;
1913                 waypoint_spawn(m1, m2, fl);
1914                 if (m1 == m2)
1915                         cwp = cwp + 1;
1916                 else
1917                         cwb = cwb + 1;
1918         }
1919         fclose(file);
1920         waypoint_version_loaded = ver;
1921         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1922
1923         if (waypointeditor_enabled && autocvar_g_waypointeditor_symmetrical_allowload)
1924         {
1925                 string sym_str = "";
1926                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1927                 if (sym == 1 && sym_param3 < 2)
1928                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1929                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1930                 {
1931                         string params;
1932                         if (sym == 1)
1933                                 params = cons("-", "-");
1934                         else
1935                         {
1936                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1937                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1938                         }
1939                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1940                         sym_str = strcat(ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1941                 }
1942                 else if (sym == -2)
1943                 {
1944                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1945                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1946                         sym_str = strcat(ftos(sym), " with axis ", params);
1947                 }
1948                 else
1949                         sym_str = ftos(sym);
1950                 if (sym_str != "")
1951                         LOG_INFO("Waypoint editor: loaded symmetry ", sym_str);
1952                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1953         }
1954
1955         if (WAYPOINT_VERSION < waypoint_version_loaded)
1956                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
1957                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1958
1959         return cwp + cwb;
1960 }
1961
1962 #define waypoint_fixorigin(position, tracetest_ent) \
1963         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1964
1965 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1966 {
1967         vector endpos = position + down_dir * 3000;
1968         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1969         if(trace_startsolid)
1970                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1971         if(trace_startsolid)
1972                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1973         if(trace_fraction < 1)
1974                 position = trace_endpos;
1975         return position;
1976 }
1977
1978 void waypoint_spawnforitem_force(entity e, vector org)
1979 {
1980         // Fix the waypoint altitude if necessary
1981         org = waypoint_fixorigin(org, NULL);
1982
1983         // don't spawn an item spawnfunc_waypoint if it already exists
1984         IL_EACH(g_waypoints, true,
1985         {
1986                 if(it.wpisbox)
1987                 {
1988                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1989                         {
1990                                 e.nearestwaypoint = it;
1991                                 return;
1992                         }
1993                 }
1994                 else
1995                 {
1996                         if(vdist(it.origin - org, <, 16))
1997                         {
1998                                 e.nearestwaypoint = it;
1999                                 return;
2000                         }
2001                 }
2002         });
2003
2004         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
2005 }
2006
2007 void waypoint_spawnforitem(entity e)
2008 {
2009         if(!bot_waypoints_for_items)
2010                 return;
2011
2012         waypoint_spawnforitem_force(e, e.origin);
2013 }
2014
2015 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
2016 {
2017         entity w;
2018         entity dw;
2019         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag);
2020         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
2021         // one way link to the destination
2022         w.wp00_original = dw;
2023         w.wp00 = dw;
2024         w.wp00mincost = timetaken; // this is just for jump pads
2025         // the teleporter's nearest spawnfunc_waypoint is this one
2026         // (teleporters are not goals, so this is probably useless)
2027         e.nearestwaypoint = w;
2028         e.nearestwaypointtimeout = -1;
2029 }
2030
2031 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
2032 {
2033         float src_angle = e.warpzone_angles.x;
2034         while (src_angle < -180) src_angle += 360;
2035         while (src_angle > 180) src_angle -= 360;
2036
2037         float dest_angle = e.enemy.warpzone_angles.x;
2038         while (dest_angle < -180) dest_angle += 360;
2039         while (dest_angle > 180) dest_angle -= 360;
2040
2041         // no waypoints for warpzones pointing upwards, they can't be used by the bots
2042         if (src_angle == -90 || dest_angle == -90)
2043                 return;
2044
2045         makevectors(e.warpzone_angles);
2046         vector src = (e.absmin + e.absmax) * 0.5;
2047         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
2048         vector down_dir_src = -v_up;
2049
2050         makevectors(e.enemy.warpzone_angles);
2051         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
2052         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
2053         vector down_dir_dest = -v_up;
2054
2055         int extra_flag = 0;
2056         // don't snap to the ground waypoints for source warpzones pointing downwards
2057         if (src_angle != 90)
2058         {
2059                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
2060                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
2061                 // oblique warpzones need a jump otherwise bots gets stuck
2062                 if (src_angle != 0)
2063                         extra_flag = WAYPOINTFLAG_JUMP;
2064         }
2065
2066         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
2067 }
2068
2069 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
2070 {
2071         destination = waypoint_fixorigin(destination, tracetest_ent);
2072         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
2073 }
2074
2075 entity waypoint_spawnpersonal(entity this, vector position)
2076 {
2077         entity w;
2078
2079         // drop the waypoint to a proper location:
2080         //   first move it up by a player height
2081         //   then move it down to hit the floor with player bbox size
2082         position = waypoint_fixorigin(position, this);
2083
2084         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
2085         w.nearestwaypoint = NULL;
2086         w.nearestwaypointtimeout = 0;
2087         w.owner = this;
2088
2089         waypoint_schedulerelink(w);
2090
2091         return w;
2092 }
2093
2094 void waypoint_showlink(entity wp1, entity wp2, int display_type)
2095 {
2096         if (!(wp1 && wp2))
2097                 return;
2098
2099         if (waypoint_is_hardwiredlink(wp1, wp2) || (wp1.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP)))
2100                 te_beam(NULL, wp1.origin, wp2.origin);
2101         else if (display_type == 1)
2102                 te_lightning2(NULL, wp1.origin, wp2.origin);
2103 }
2104
2105 void waypoint_showlinks_to(entity wp, int display_type)
2106 {
2107         IL_EACH(g_waypoints, it != wp,
2108         {
2109                 if (waypoint_islinked(it, wp))
2110                         waypoint_showlink(it, wp, display_type);
2111         });
2112 }
2113
2114 void waypoint_showlinks_from(entity wp, int display_type)
2115 {
2116         waypoint_showlink(wp, wp.wp00, display_type); waypoint_showlink(wp, wp.wp16, display_type);
2117         waypoint_showlink(wp, wp.wp01, display_type); waypoint_showlink(wp, wp.wp17, display_type);
2118         waypoint_showlink(wp, wp.wp02, display_type); waypoint_showlink(wp, wp.wp18, display_type);
2119         waypoint_showlink(wp, wp.wp03, display_type); waypoint_showlink(wp, wp.wp19, display_type);
2120         waypoint_showlink(wp, wp.wp04, display_type); waypoint_showlink(wp, wp.wp20, display_type);
2121         waypoint_showlink(wp, wp.wp05, display_type); waypoint_showlink(wp, wp.wp21, display_type);
2122         waypoint_showlink(wp, wp.wp06, display_type); waypoint_showlink(wp, wp.wp22, display_type);
2123         waypoint_showlink(wp, wp.wp07, display_type); waypoint_showlink(wp, wp.wp23, display_type);
2124         waypoint_showlink(wp, wp.wp08, display_type); waypoint_showlink(wp, wp.wp24, display_type);
2125         waypoint_showlink(wp, wp.wp09, display_type); waypoint_showlink(wp, wp.wp25, display_type);
2126         waypoint_showlink(wp, wp.wp10, display_type); waypoint_showlink(wp, wp.wp26, display_type);
2127         waypoint_showlink(wp, wp.wp11, display_type); waypoint_showlink(wp, wp.wp27, display_type);
2128         waypoint_showlink(wp, wp.wp12, display_type); waypoint_showlink(wp, wp.wp28, display_type);
2129         waypoint_showlink(wp, wp.wp13, display_type); waypoint_showlink(wp, wp.wp29, display_type);
2130         waypoint_showlink(wp, wp.wp14, display_type); waypoint_showlink(wp, wp.wp30, display_type);
2131         waypoint_showlink(wp, wp.wp15, display_type); waypoint_showlink(wp, wp.wp31, display_type);
2132 }
2133
2134 void crosshair_trace_waypoints(entity pl)
2135 {
2136         IL_EACH(g_waypoints, true, {
2137                 it.solid = SOLID_BSP;
2138                 if (!it.wpisbox)
2139                         setsize(it, '-16 -16 -16', '16 16 16');
2140         });
2141
2142         WarpZone_crosshair_trace(pl);
2143
2144         IL_EACH(g_waypoints, true, {
2145                 it.solid = SOLID_TRIGGER;
2146                 if (!it.wpisbox)
2147                         setsize(it, '0 0 0', '0 0 0');
2148         });
2149
2150         if (trace_ent.classname != "waypoint")
2151                 trace_ent = NULL;
2152         else if (!trace_ent.wpisbox)
2153                 trace_endpos = trace_ent.origin;
2154 }
2155
2156 void botframe_showwaypointlinks()
2157 {
2158         if (time < botframe_waypointeditorlightningtime)
2159                 return;
2160         botframe_waypointeditorlightningtime = time + 0.5;
2161         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
2162         {
2163                 int display_type = 0;
2164                 if (wasfreed(it.wp_aimed))
2165                         it.wp_aimed = NULL;
2166                 if (wasfreed(it.wp_locked))
2167                         it.wp_locked = NULL;
2168                 entity head = it.wp_locked;
2169                 if (!head)
2170                         head = navigation_findnearestwaypoint(it, false);
2171                 it.nearestwaypoint = head; // mainly useful for debug
2172                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
2173                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
2174                         display_type = 1; // default
2175                 else if(waypoint_has_hardwiredlinks(head))
2176                         display_type = 2; // only hardwired
2177
2178                 if (display_type)
2179                 {
2180                         //navigation_testtracewalk = true;
2181                         //print("currently selected WP is ", etos(head), "\n");
2182                         //navigation_testtracewalk = false;
2183                         if (head)
2184                         {
2185                                 te_lightning2(NULL, head.origin, it.origin);
2186                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
2187                                         waypoint_showlinks_to(head, display_type);
2188                                 else
2189                                         waypoint_showlinks_from(head, display_type);
2190                         }
2191                 }
2192                 string str;
2193                 entity wp = NULL;
2194                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
2195                 {
2196                         crosshair_trace_waypoints(it);
2197                         if (trace_ent)
2198                         {
2199                                 wp = trace_ent;
2200                                 if (wp != it.wp_aimed)
2201                                 {
2202                                         string wp_type_str = waypoint_get_type_name(wp);
2203                                         str = sprintf("\necho Entity %d: %s^7, flags: %d, origin: %s\n", etof(wp), wp_type_str, wp.wpflags, vtos(wp.origin));
2204                                         if (wp.wpisbox)
2205                                                 str = strcat(str, sprintf("echo \" absmin: %s, absmax: %s\"\n", vtos(wp.absmin), vtos(wp.absmax)));
2206                                         stuffcmd(it, str);
2207                                         str = sprintf("Entity %d: %s^7\nflags: %d\norigin: %s", etof(wp), wp_type_str, wp.wpflags, vtos(wp.origin));
2208                                         if (wp.wpisbox)
2209                                                 str = strcat(str, sprintf(" \nabsmin: %s\nabsmax: %s", vtos(wp.absmin), vtos(wp.absmax)));
2210                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
2211                                 }
2212                         }
2213                 }
2214                 if (it.wp_aimed != wp)
2215                         it.wp_aimed = wp;
2216         });
2217 }
2218
2219 float botframe_autowaypoints_fixdown(vector v)
2220 {
2221         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
2222         if(trace_fraction >= 1)
2223                 return 0;
2224         return 1;
2225 }
2226
2227 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
2228 {
2229         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
2230         {
2231                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
2232                 return 0;
2233         });
2234
2235         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
2236         return 1;
2237 }
2238
2239 // return value:
2240 //    1 = WP created
2241 //    0 = no action needed
2242 //   -1 = temp fail, try from world too
2243 //   -2 = permanent fail, do not retry
2244 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
2245 {
2246         // make it possible to go from p to wp, if we can
2247         // if wp is NULL, nearest is chosen
2248
2249         entity w;
2250         vector porg;
2251         float t, tmin, tmax;
2252         vector o;
2253         vector save;
2254
2255         if(!botframe_autowaypoints_fixdown(p.origin))
2256                 return -2;
2257         porg = trace_endpos;
2258
2259         if(wp)
2260         {
2261                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
2262
2263                 // if wp -> porg, then OK
2264                 float maxdist;
2265                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
2266                 {
2267                         // we may find a better one
2268                         maxdist = vlen(wp.origin - porg);
2269                 }
2270                 else
2271                 {
2272                         // accept any "good"
2273                         maxdist = 2100;
2274                 }
2275
2276                 float bestdist = maxdist;
2277                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WPFLAGMASK_NORELINK),
2278                 {
2279                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
2280                         if(d < bestdist)
2281                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
2282                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
2283                         {
2284                                 bestdist = d;
2285                                 p.(fld) = it;
2286                         }
2287                 });
2288                 if(bestdist < maxdist)
2289                 {
2290                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
2291                         return 0;
2292                 }
2293
2294                 if(bestdist < 2100)
2295                 {
2296                         // we know maxdist < 2100
2297                         // so wp -> porg is still valid
2298                         // all is good
2299                         p.(fld) = wp;
2300                         return 0;
2301                 }
2302
2303                 // otherwise, no existing WP can fix our issues
2304         }
2305         else
2306         {
2307                 save = p.origin;
2308                 setorigin(p, porg);
2309                 w = navigation_findnearestwaypoint(p, walkfromwp);
2310                 setorigin(p, save);
2311                 if(w)
2312                 {
2313                         p.(fld) = w;
2314                         return 0;
2315                 }
2316         }
2317
2318         tmin = 0;
2319         tmax = 1;
2320         for (;;)
2321         {
2322                 if(tmax - tmin < 0.001)
2323                 {
2324                         // did not get a good candidate
2325                         return -1;
2326                 }
2327
2328                 t = (tmin + tmax) * 0.5;
2329                 o = antilag_takebackorigin(p, CS(p), time - t);
2330                 if(!botframe_autowaypoints_fixdown(o))
2331                         return -2;
2332                 o = trace_endpos;
2333
2334                 if(wp)
2335                 {
2336                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
2337                         {
2338                                 // we cannot walk from wp.origin to o
2339                                 // get closer to tmax
2340                                 tmin = t;
2341                                 continue;
2342                         }
2343                 }
2344                 else
2345                 {
2346                         save = p.origin;
2347                         setorigin(p, o);
2348                         w = navigation_findnearestwaypoint(p, walkfromwp);
2349                         setorigin(p, save);
2350                         if(!w)
2351                         {
2352                                 // we cannot walk from any WP to o
2353                                 // get closer to tmax
2354                                 tmin = t;
2355                                 continue;
2356                         }
2357                 }
2358
2359                 // if we get here, o is valid regarding waypoints
2360                 // check if o is connected right to the player
2361                 // we break if it succeeds, as that means o is a good waypoint location
2362                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
2363                         break;
2364
2365                 // o is no good, we need to get closer to the player
2366                 tmax = t;
2367         }
2368
2369         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
2370         botframe_autowaypoints_createwp(o, p, fld, 0);
2371         return 1;
2372 }
2373
2374 // automatically create missing waypoints
2375 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
2376 {
2377         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
2378         if(r != -1)
2379                 return;
2380         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
2381         if(r != -1)
2382                 return;
2383
2384         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
2385         if(!botframe_autowaypoints_fixdown(p.origin))
2386                 return; // shouldn't happen, caught above
2387         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
2388 }
2389
2390 void botframe_deleteuselesswaypoints()
2391 {
2392         IL_EACH(g_items, it.bot_pickup,
2393         {
2394                 // NOTE: this protects waypoints if they're the ONLY nearest
2395                 // waypoint. That's the intention.
2396                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
2397                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
2398         });
2399         IL_EACH(g_waypoints, true,
2400         {
2401                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
2402                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
2403                 // WP is useful if:
2404                 if (it.wpflags & WAYPOINTFLAG_ITEM)
2405                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2406                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
2407                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2408                 if (it.wpflags & WAYPOINTFLAG_LADDER)
2409                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2410                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
2411                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2412                 // b) WP is closest WP for an item/spawnpoint/other entity
2413                 //    This has been done above by protecting these WPs.
2414         });
2415         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
2416         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
2417         {
2418                 for (int m = 0; m < 32; ++m)
2419                 {
2420                         entity w = waypoint_get_link(it, m);
2421                         if (!w)
2422                                 break;
2423                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
2424                                 continue;
2425                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
2426                                 continue;
2427                         for (int j = 0; j < 32; ++j)
2428                         {
2429                                 entity w2 = waypoint_get_link(w, j);
2430                                 if (!w2)
2431                                         break;
2432                                 if (it == w2)
2433                                         continue;
2434                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
2435                                         continue;
2436                                 // If we got here, it != w2 exist with it -> w
2437                                 // and w -> w2. That means the waypoint is not
2438                                 // a dead end.
2439                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
2440                                 for (int k = 0; k < 32; ++k)
2441                                 {
2442                                         if (waypoint_get_link(it, k) == w2)
2443                                                 continue;
2444                                         // IF WE GET HERE, w is proven useful
2445                                         // to get from it to w2!
2446                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
2447                                         goto next;
2448                                 }
2449                         }
2450 LABEL(next)
2451                 }
2452         });
2453         // d) The waypoint is a dead end. Dead end waypoints must be kept as
2454         //     they are needed to complete routes while autowaypointing.
2455
2456         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
2457         {
2458                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
2459                 te_explosion(it.origin);
2460                 waypoint_remove(it);
2461                 break;
2462         });
2463
2464         IL_EACH(g_waypoints, true,
2465         {
2466                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
2467         });
2468 }
2469
2470 //.entity botframe_autowaypoints_lastwp0;
2471 .entity botframe_autowaypoints_lastwp1;
2472 void botframe_autowaypoints()
2473 {
2474         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
2475                 // going back is broken, so only fix waypoints to walk TO the player
2476                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
2477                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
2478                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
2479         });
2480
2481         if (autocvar_g_waypointeditor_auto >= 2) {
2482                 botframe_deleteuselesswaypoints();
2483         }
2484 }
2485