qcsrc/server/bot/default/navigation.qc

   1 #include "navigation.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "waypoints.qh"
   9
  10 #include <common/t_items.qh>
  11
  12 #include <common/items/_mod.qh>
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/triggers/trigger/jumppads.qh>
  17
  18 .float speed;
  19
  20 void navigation_goalrating_timeout_set(entity this)
  21 {
  22         if(IS_MOVABLE(this.goalentity))
  23                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval_movingtarget;
  24         else
  25                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
  26 }
  27
  28 void navigation_goalrating_timeout_force(entity this)
  29 {
  30         this.bot_strategytime = 0;
  31 }
  32
  33 bool navigation_goalrating_timeout(entity this)
  34 {
  35         return this.bot_strategytime < time;
  36 }
  37
  38 void navigation_dynamicgoal_init(entity this, bool initially_static)
  39 {
  40         this.navigation_dynamicgoal = true;
  41         this.bot_basewaypoint = this.nearestwaypoint;
  42         if(initially_static)
  43                 this.nearestwaypointtimeout = -1;
  44         else
  45                 this.nearestwaypointtimeout = time;
  46 }
  47
  48 void navigation_dynamicgoal_set(entity this)
  49 {
  50         this.nearestwaypointtimeout = time;
  51 }
  52
  53 void navigation_dynamicgoal_unset(entity this)
  54 {
  55         if(this.bot_basewaypoint)
  56                 this.nearestwaypoint = this.bot_basewaypoint;
  57         this.nearestwaypointtimeout = -1;
  58 }
  59
  60 bool navigation_check_submerged_state(entity ent, vector pos)
  61 {
  62         bool submerged;
  63         if(IS_PLAYER(ent))
  64                 submerged = (ent.waterlevel == WATERLEVEL_SUBMERGED);
  65         else if(ent.nav_submerged_state != SUBMERGED_UNDEFINED)
  66                 submerged = (ent.nav_submerged_state == SUBMERGED_YES);
  67         else
  68         {
  69                 submerged = SUBMERGED(pos);
  70                 // NOTE: SUBMERGED check of box waypoint origin may fail even if origin
  71                 //  is actually submerged because often they are inside some solid.
  72                 //  That's why submerged state is saved now that we know current pos is
  73                 //  not stuck in solid (previous tracewalk call to this pos was successfully)
  74                 if(!ent.navigation_dynamicgoal)
  75                         ent.nav_submerged_state = (submerged) ? SUBMERGED_YES : SUBMERGED_NO;
  76         }
  77         return submerged;
  78 }
  79
  80 bool navigation_checkladders(entity e, vector org, vector m1, vector m2, vector end, vector end2, int movemode)
  81 {
  82         IL_EACH(g_ladders, it.classname == "func_ladder",
  83         {
  84                 if(it.bot_pickup)
  85                 if(boxesoverlap(org + m1 + '-1 -1 -1', org + m2 + '1 1 1', it.absmin, it.absmax))
  86                 if(boxesoverlap(end, end2, it.absmin + vec2(m1) + '-1 -1 0', it.absmax + vec2(m2) + '1 1 0'))
  87                 {
  88                         vector top = org;
  89                         top.z = it.absmax.z + (PL_MAX_CONST.z - PL_MIN_CONST.z);
  90                         tracebox(org, m1, m2, top, movemode, e);
  91                         if(trace_fraction == 1)
  92                                 return true;
  93                 }
  94         });
  95         return false;
  96 }
  97
  98 vector resurface_limited(vector org, float lim, vector m1)
  99 {
 100         if (WETFEET(org + eZ * (lim - org.z)))
 101                 org.z = lim;
 102         else
 103         {
 104                 float RES_min_h = org.z;
 105                 float RES_max_h = lim;
 106                 do {
 107                         org.z = 0.5 * (RES_min_h + RES_max_h);
 108                         if(WETFEET(org))
 109                                 RES_min_h = org.z;
 110                         else
 111                                 RES_max_h = org.z;
 112                 } while (RES_max_h - RES_min_h >= 1);
 113                 org.z = RES_min_h;
 114         }
 115         return org;
 116 }
 117 #define RESURFACE_LIMITED(org, lim) org = resurface_limited(org, lim, m1)
 118
 119 #define NAV_WALK 0
 120 #define NAV_SWIM_ONWATER 1
 121 #define NAV_SWIM_UNDERWATER 2
 122
 123 // rough simulation of walking from one point to another to test if a path
 124 // can be traveled, used for waypoint linking and havocbot
 125 // if end_height is > 0 destination is any point in the vertical segment [end, end + end_height * eZ]
 126 bool tracewalk(entity e, vector start, vector m1, vector m2, vector end, float end_height, float movemode)
 127 {
 128         if(autocvar_bot_debug_tracewalk)
 129         {
 130                 debugresetnodes();
 131                 debugnode(e, start);
 132         }
 133
 134         vector org = start;
 135         vector flatdir = end - start;
 136         flatdir.z = 0;
 137         float flatdist = vlen(flatdir);
 138         flatdir = normalize(flatdir);
 139         float stepdist = 32;
 140         bool ignorehazards = false;
 141         int nav_action;
 142
 143         // Analyze starting point
 144         traceline(start, start, MOVE_NORMAL, e);
 145         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
 146                 ignorehazards = true;
 147
 148         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
 149         if (trace_startsolid)
 150         {
 151                 // Bad start
 152                 if(autocvar_bot_debug_tracewalk)
 153                         debugnodestatus(start, DEBUG_NODE_FAIL);
 154
 155                 //print("tracewalk: ", vtos(start), " is a bad start\n");
 156                 return false;
 157         }
 158
 159         vector end2 = end;
 160         if(end_height)
 161                 end2.z += end_height;
 162
 163         vector fixed_end = end;
 164         vector move;
 165
 166         if (flatdist > 0 && WETFEET(org))
 167         {
 168                 if (SUBMERGED(org))
 169                         nav_action = NAV_SWIM_UNDERWATER;
 170                 else
 171                 {
 172                         // tracebox down by player's height
 173                         // useful to know if water level is so low that bot can still walk
 174                         tracebox(org, m1, m2, org - eZ * (m2.z - m1.z), movemode, e);
 175                         if (SUBMERGED(trace_endpos))
 176                         {
 177                                 org = trace_endpos;
 178                                 nav_action = NAV_SWIM_UNDERWATER;
 179                         }
 180                         else
 181                                 nav_action = NAV_WALK;
 182                 }
 183         }
 184         else
 185                 nav_action =  NAV_WALK;
 186
 187         // Movement loop
 188         while (true)
 189         {
 190                 if (flatdist <= 0)
 191                 {
 192                         bool success = true;
 193                         if (org.z > end2.z + 1)
 194                         {
 195                                 tracebox(org, m1, m2, end2, movemode, e);
 196                                 org = trace_endpos;
 197                                 if (org.z > end2.z + 1)
 198                                         success = false;
 199                         }
 200                         else if (org.z < end.z - 1)
 201                         {
 202                                 tracebox(org, m1, m2, org - jumpheight_vec, movemode, e);
 203                                 if (SUBMERGED(trace_endpos))
 204                                 {
 205                                         vector v = trace_endpos;
 206                                         tracebox(v, m1, m2, end, movemode, e);
 207                                         if(trace_endpos.z >= end.z - 1)
 208                                         {
 209                                                 RESURFACE_LIMITED(v, trace_endpos.z);
 210                                                 trace_endpos = v;
 211                                         }
 212                                 }
 213                                 else if (trace_endpos.z > org.z - jumpheight_vec.z)
 214                                         tracebox(trace_endpos, m1, m2, trace_endpos + jumpheight_vec, movemode, e);
 215                                 org = trace_endpos;
 216                                 if (org.z < end.z - 1)
 217                                         success = false;
 218                         }
 219
 220                         if (success)
 221                         {
 222                                 // Succeeded
 223                                 if(autocvar_bot_debug_tracewalk)
 224                                 {
 225                                         debugnode(e, org);
 226                                         debugnodestatus(org, DEBUG_NODE_SUCCESS);
 227                                 }
 228
 229                                 //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 230                                 return true;
 231                         }
 232                 }
 233
 234                 if(autocvar_bot_debug_tracewalk)
 235                         debugnode(e, org);
 236
 237                 if (flatdist <= 0)
 238                         break;
 239
 240                 if (stepdist > flatdist)
 241                         stepdist = flatdist;
 242                 if(nav_action == NAV_SWIM_UNDERWATER || (nav_action == NAV_SWIM_ONWATER && org.z > end2.z))
 243                 {
 244                         // can't use movement direction here to calculate move because of
 245                         // precision errors especially when direction has a high enough z value
 246                         //water_dir = normalize(water_end - org);
 247                         //move = org + water_dir * stepdist;
 248                         fixed_end.z = bound(end.z, org.z, end2.z);
 249                         if (stepdist == flatdist) {
 250                                 move = fixed_end;
 251                                 flatdist = 0;
 252                         } else {
 253                                 move = org + (fixed_end - org) * (stepdist / flatdist);
 254                                 flatdist = vlen(vec2(fixed_end - move));
 255                         }
 256                 }
 257                 else // horiz. direction
 258                 {
 259                         flatdist -= stepdist;
 260                         move = org + flatdir * stepdist;
 261                 }
 262
 263                 if(nav_action == NAV_SWIM_ONWATER)
 264                 {
 265                         tracebox(org, m1, m2, move, movemode, e); // swim
 266
 267                         // hit something
 268                         if (trace_fraction < 1)
 269                         {
 270                                 // stepswim
 271                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 272
 273                                 if (trace_fraction < 1 || trace_startsolid) // can't jump obstacle out of water
 274                                 {
 275                                         org = trace_endpos;
 276                                         if(navigation_checkladders(e, org, m1, m2, end, end2, movemode))
 277                                         {
 278                                                 if(autocvar_bot_debug_tracewalk)
 279                                                 {
 280                                                         debugnode(e, org);
 281                                                         debugnodestatus(org, DEBUG_NODE_SUCCESS);
 282                                                 }
 283
 284                                                 //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 285                                                 return true;
 286                                         }
 287
 288                                         if(autocvar_bot_debug_tracewalk)
 289                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 290
 291                                         return false;
 292                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 293                                 }
 294
 295                                 //succesful stepswim
 296
 297                                 if (flatdist <= 0)
 298                                 {
 299                                         org = trace_endpos;
 300                                         continue;
 301                                 }
 302
 303                                 if (org.z <= move.z) // going horiz.
 304                                 {
 305                                         tracebox(trace_endpos, m1, m2, move, movemode, e);
 306                                         org = trace_endpos;
 307                                         nav_action = NAV_WALK;
 308                                         continue;
 309                                 }
 310                         }
 311
 312                         if (org.z <= move.z) // going horiz.
 313                         {
 314                                 org = trace_endpos;
 315                                 nav_action = NAV_SWIM_ONWATER;
 316                         }
 317                         else // going down
 318                         {
 319                                 org = trace_endpos;
 320                                 if (SUBMERGED(org))
 321                                         nav_action = NAV_SWIM_UNDERWATER;
 322                                 else
 323                                         nav_action = NAV_SWIM_ONWATER;
 324                         }
 325                 }
 326                 else if(nav_action == NAV_SWIM_UNDERWATER)
 327                 {
 328                         if (move.z >= org.z) // swimming upwards or horiz.
 329                         {
 330                                 tracebox(org, m1, m2, move, movemode, e); // swim
 331
 332                                 bool stepswum = false;
 333
 334                                 // hit something
 335                                 if (trace_fraction < 1)
 336                                 {
 337                                         // stepswim
 338                                         vector stepswim_move = move + stepheightvec;
 339                                         if (flatdist > 0 && stepswim_move.z > end2.z + stepheightvec.z) // don't allow stepswim to go higher than destination
 340                                                 stepswim_move.z = end2.z;
 341
 342                                         tracebox(org + stepheightvec, m1, m2, stepswim_move, movemode, e);
 343
 344                                         // hit something
 345                                         if (trace_startsolid)
 346                                         {
 347                                                 if(autocvar_bot_debug_tracewalk)
 348                                                         debugnodestatus(org, DEBUG_NODE_FAIL);
 349
 350                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 351                                                 return false;
 352                                         }
 353
 354                                         if (trace_fraction < 1)
 355                                         {
 356                                                 float org_z_prev = org.z;
 357                                                 RESURFACE_LIMITED(org, end2.z);
 358                                                 if(org.z == org_z_prev)
 359                                                 {
 360                                                         if(autocvar_bot_debug_tracewalk)
 361                                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 362
 363                                                         //print("tracewalk: ", vtos(start), " can't reach ", vtos(end), "\n");
 364                                                         return false;
 365                                                 }
 366                                                 if(SUBMERGED(org))
 367                                                         nav_action = NAV_SWIM_UNDERWATER;
 368                                                 else
 369                                                         nav_action = NAV_SWIM_ONWATER;
 370
 371                                                 // we didn't advance horiz. in this step, flatdist decrease should be reverted
 372                                                 // but we can't do it properly right now... apply this workaround instead
 373                                                 if (flatdist <= 0)
 374                                                         flatdist = 1;
 375
 376                                                 continue;
 377                                         }
 378
 379                                         //succesful stepswim
 380
 381                                         if (flatdist <= 0)
 382                                         {
 383                                                 org = trace_endpos;
 384                                                 continue;
 385                                         }
 386
 387                                         stepswum = true;
 388                                 }
 389
 390                                 if (!WETFEET(trace_endpos))
 391                                 {
 392                                         tracebox(trace_endpos, m1, m2, trace_endpos - eZ * (stepdist + (m2.z - m1.z)), movemode, e);
 393                                         // if stepswum we'll land on the obstacle, avoid the SUBMERGED check
 394                                         if (!stepswum && SUBMERGED(trace_endpos))
 395                                         {
 396                                                 RESURFACE_LIMITED(trace_endpos, end2.z);
 397                                                 org = trace_endpos;
 398                                                 nav_action = NAV_SWIM_ONWATER;
 399                                                 continue;
 400                                         }
 401
 402                                         // not submerged
 403                                         org = trace_endpos;
 404                                         nav_action = NAV_WALK;
 405                                         continue;
 406                                 }
 407
 408                                 // wetfeet
 409                                 org = trace_endpos;
 410                                 nav_action = NAV_SWIM_UNDERWATER;
 411                                 continue;
 412                         }
 413                         else //if (move.z < org.z) // swimming downwards
 414                         {
 415                                 tracebox(org, m1, m2, move, movemode, e); // swim
 416
 417                                 // hit something
 418                                 if (trace_fraction < 1)
 419                                 {
 420                                         // stepswim
 421                                         tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 422
 423                                         // hit something
 424                                         if (trace_fraction < 1 || trace_startsolid) // can't jump obstacle out of water
 425                                         {
 426                                                 if(autocvar_bot_debug_tracewalk)
 427                                                         debugnodestatus(move, DEBUG_NODE_FAIL);
 428
 429                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 430                                                 return false;
 431                                         }
 432
 433                                         //succesful stepswim
 434
 435                                         if (flatdist <= 0)
 436                                         {
 437                                                 org = trace_endpos;
 438                                                 continue;
 439                                         }
 440
 441                                         if (trace_endpos.z > org.z && !SUBMERGED(trace_endpos))
 442                                         {
 443                                                 // stepswim caused upwards direction
 444                                                 tracebox(trace_endpos, m1, m2, trace_endpos - stepheightvec, movemode, e);
 445                                                 if (!SUBMERGED(trace_endpos))
 446                                                 {
 447                                                         org = trace_endpos;
 448                                                         nav_action = NAV_WALK;
 449                                                         continue;
 450                                                 }
 451                                         }
 452                                 }
 453
 454                                 org = trace_endpos;
 455                                 nav_action = NAV_SWIM_UNDERWATER;
 456                                 continue;
 457                         }
 458                 }
 459                 else if(nav_action == NAV_WALK)
 460                 {
 461                         // walk
 462                         tracebox(org, m1, m2, move, movemode, e);
 463
 464                         if(autocvar_bot_debug_tracewalk)
 465                                 debugnode(e, trace_endpos);
 466
 467                         // hit something
 468                         if (trace_fraction < 1)
 469                         {
 470                                 // check if we can walk over this obstacle, possibly by jumpstepping
 471                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 472                                 if (trace_fraction < 1 || trace_startsolid)
 473                                 {
 474                                         if (trace_startsolid) // hit ceiling above org
 475                                         {
 476                                                 // reduce stepwalk height
 477                                                 tracebox(org, m1, m2, org + stepheightvec, movemode, e);
 478                                                 tracebox(trace_endpos, m1, m2, move + eZ * (trace_endpos.z - move.z), movemode, e);
 479                                         }
 480                                         else //if (trace_fraction < 1)
 481                                         {
 482                                                 tracebox(org + jumpstepheightvec, m1, m2, move + jumpstepheightvec, movemode, e);
 483                                                 if (trace_startsolid) // hit ceiling above org
 484                                                 {
 485                                                         // reduce jumpstepwalk height
 486                                                         tracebox(org, m1, m2, org + jumpstepheightvec, movemode, e);
 487                                                         tracebox(trace_endpos, m1, m2, move + eZ * (trace_endpos.z - move.z), movemode, e);
 488                                                 }
 489                                         }
 490
 491                                         if (trace_fraction < 1)
 492                                         {
 493                                                 vector v = trace_endpos;
 494                                                 v.z = org.z + jumpheight_vec.z;
 495                                                 if(navigation_checkladders(e, v, m1, m2, end, end2, movemode))
 496                                                 {
 497                                                         if(autocvar_bot_debug_tracewalk)
 498                                                         {
 499                                                                 debugnode(e, v);
 500                                                                 debugnodestatus(v, DEBUG_NODE_SUCCESS);
 501                                                         }
 502
 503                                                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 504                                                         return true;
 505                                                 }
 506
 507                                                 if(autocvar_bot_debug_tracewalk)
 508                                                         debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 509
 510                                                 traceline( org, move, movemode, e);
 511
 512                                                 if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 513                                                 {
 514                                                         vector nextmove;
 515                                                         move = trace_endpos;
 516                                                         while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 517                                                         {
 518                                                                 nextmove = move + (flatdir * stepdist);
 519                                                                 traceline( move, nextmove, movemode, e);
 520                                                                 move = nextmove;
 521                                                         }
 522                                                         flatdist = vlen(vec2(end - move));
 523                                                 }
 524                                                 else
 525                                                 {
 526                                                         if(autocvar_bot_debug_tracewalk)
 527                                                                 debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 528
 529                                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 530                                                         //te_explosion(trace_endpos);
 531                                                         //print(ftos(e.dphitcontentsmask), "\n");
 532                                                         return false; // failed
 533                                                 }
 534                                         }
 535                                         else
 536                                                 move = trace_endpos;
 537                                 }
 538                                 else
 539                                         move = trace_endpos;
 540                         }
 541                         else
 542                                 move = trace_endpos;
 543
 544                         // trace down from stepheight as far as possible and move there,
 545                         // if this starts in solid we try again without the stepup, and
 546                         // if that also fails we assume it is a wall
 547                         // (this is the same logic as the Quake walkmove function used)
 548                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 549
 550                         org = trace_endpos;
 551
 552                         if (!ignorehazards)
 553                         {
 554                                 if (IN_LAVA(org))
 555                                 {
 556                                         if(autocvar_bot_debug_tracewalk)
 557                                         {
 558                                                 debugnode(e, trace_endpos);
 559                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 560                                         }
 561
 562                                         //print("tracewalk: ", vtos(start), " hits a hazard when trying to reach ", vtos(end), "\n");
 563                                         return false;
 564                                 }
 565                         }
 566
 567                         if (flatdist <= 0)
 568                         {
 569                                 if(move.z >= end2.z && org.z < end2.z)
 570                                         org.z = end2.z;
 571                                 continue;
 572                         }
 573
 574                         if(org.z > move.z - 1 || !SUBMERGED(org))
 575                         {
 576                                 nav_action = NAV_WALK;
 577                                 continue;
 578                         }
 579
 580                         // ended up submerged while walking
 581                         if(autocvar_bot_debug_tracewalk)
 582                                 debugnode(e, org);
 583
 584                         RESURFACE_LIMITED(org, move.z);
 585                         nav_action = NAV_SWIM_ONWATER;
 586                         continue;
 587                 }
 588         }
 589
 590         //print("tracewalk: ", vtos(start), " did not arrive at ", vtos(end), " but at ", vtos(org), "\n");
 591
 592         // moved but didn't arrive at the intended destination
 593         if(autocvar_bot_debug_tracewalk)
 594                 debugnodestatus(org, DEBUG_NODE_FAIL);
 595
 596         return false;
 597 }
 598
 599 /////////////////////////////////////////////////////////////////////////////
 600 // goal stack
 601 /////////////////////////////////////////////////////////////////////////////
 602
 603 // completely empty the goal stack, used when deciding where to go
 604 void navigation_clearroute(entity this)
 605 {
 606         this.goalcurrent_prev = this.goalcurrent;
 607         this.goalcurrent_distance = 10000000;
 608         this.goalcurrent_distance_time = 0;
 609         //print("bot ", etos(this), " clear\n");
 610         this.goalentity = NULL;
 611         this.goalcurrent = NULL;
 612         this.goalstack01 = NULL;
 613         this.goalstack02 = NULL;
 614         this.goalstack03 = NULL;
 615         this.goalstack04 = NULL;
 616         this.goalstack05 = NULL;
 617         this.goalstack06 = NULL;
 618         this.goalstack07 = NULL;
 619         this.goalstack08 = NULL;
 620         this.goalstack09 = NULL;
 621         this.goalstack10 = NULL;
 622         this.goalstack11 = NULL;
 623         this.goalstack12 = NULL;
 624         this.goalstack13 = NULL;
 625         this.goalstack14 = NULL;
 626         this.goalstack15 = NULL;
 627         this.goalstack16 = NULL;
 628         this.goalstack17 = NULL;
 629         this.goalstack18 = NULL;
 630         this.goalstack19 = NULL;
 631         this.goalstack20 = NULL;
 632         this.goalstack21 = NULL;
 633         this.goalstack22 = NULL;
 634         this.goalstack23 = NULL;
 635         this.goalstack24 = NULL;
 636         this.goalstack25 = NULL;
 637         this.goalstack26 = NULL;
 638         this.goalstack27 = NULL;
 639         this.goalstack28 = NULL;
 640         this.goalstack29 = NULL;
 641         this.goalstack30 = NULL;
 642         this.goalstack31 = NULL;
 643 }
 644
 645 // add a new goal at the beginning of the stack
 646 // (in other words: add a new prerequisite before going to the later goals)
 647 // NOTE: when a waypoint is added, the WP gets pushed first, then the
 648 // next-closest WP on the shortest path to the WP
 649 // That means, if the stack overflows, the bot will know how to do the FIRST 32
 650 // steps to the goal, and then recalculate the path.
 651 void navigation_pushroute(entity this, entity e)
 652 {
 653         this.goalcurrent_prev = this.goalcurrent;
 654         this.goalcurrent_distance = 10000000;
 655         this.goalcurrent_distance_time = 0;
 656         //print("bot ", etos(this), " push ", etos(e), "\n");
 657         if(this.goalstack31 == this.goalentity)
 658                 this.goalentity = NULL;
 659         this.goalstack31 = this.goalstack30;
 660         this.goalstack30 = this.goalstack29;
 661         this.goalstack29 = this.goalstack28;
 662         this.goalstack28 = this.goalstack27;
 663         this.goalstack27 = this.goalstack26;
 664         this.goalstack26 = this.goalstack25;
 665         this.goalstack25 = this.goalstack24;
 666         this.goalstack24 = this.goalstack23;
 667         this.goalstack23 = this.goalstack22;
 668         this.goalstack22 = this.goalstack21;
 669         this.goalstack21 = this.goalstack20;
 670         this.goalstack20 = this.goalstack19;
 671         this.goalstack19 = this.goalstack18;
 672         this.goalstack18 = this.goalstack17;
 673         this.goalstack17 = this.goalstack16;
 674         this.goalstack16 = this.goalstack15;
 675         this.goalstack15 = this.goalstack14;
 676         this.goalstack14 = this.goalstack13;
 677         this.goalstack13 = this.goalstack12;
 678         this.goalstack12 = this.goalstack11;
 679         this.goalstack11 = this.goalstack10;
 680         this.goalstack10 = this.goalstack09;
 681         this.goalstack09 = this.goalstack08;
 682         this.goalstack08 = this.goalstack07;
 683         this.goalstack07 = this.goalstack06;
 684         this.goalstack06 = this.goalstack05;
 685         this.goalstack05 = this.goalstack04;
 686         this.goalstack04 = this.goalstack03;
 687         this.goalstack03 = this.goalstack02;
 688         this.goalstack02 = this.goalstack01;
 689         this.goalstack01 = this.goalcurrent;
 690         this.goalcurrent = e;
 691 }
 692
 693 // remove first goal from stack
 694 // (in other words: remove a prerequisite for reaching the later goals)
 695 // (used when a spawnfunc_waypoint is reached)
 696 void navigation_poproute(entity this)
 697 {
 698         this.goalcurrent_prev = this.goalcurrent;
 699         this.goalcurrent_distance = 10000000;
 700         this.goalcurrent_distance_time = 0;
 701         //print("bot ", etos(this), " pop\n");
 702         if(this.goalcurrent == this.goalentity)
 703                 this.goalentity = NULL;
 704         this.goalcurrent = this.goalstack01;
 705         this.goalstack01 = this.goalstack02;
 706         this.goalstack02 = this.goalstack03;
 707         this.goalstack03 = this.goalstack04;
 708         this.goalstack04 = this.goalstack05;
 709         this.goalstack05 = this.goalstack06;
 710         this.goalstack06 = this.goalstack07;
 711         this.goalstack07 = this.goalstack08;
 712         this.goalstack08 = this.goalstack09;
 713         this.goalstack09 = this.goalstack10;
 714         this.goalstack10 = this.goalstack11;
 715         this.goalstack11 = this.goalstack12;
 716         this.goalstack12 = this.goalstack13;
 717         this.goalstack13 = this.goalstack14;
 718         this.goalstack14 = this.goalstack15;
 719         this.goalstack15 = this.goalstack16;
 720         this.goalstack16 = this.goalstack17;
 721         this.goalstack17 = this.goalstack18;
 722         this.goalstack18 = this.goalstack19;
 723         this.goalstack19 = this.goalstack20;
 724         this.goalstack20 = this.goalstack21;
 725         this.goalstack21 = this.goalstack22;
 726         this.goalstack22 = this.goalstack23;
 727         this.goalstack23 = this.goalstack24;
 728         this.goalstack24 = this.goalstack25;
 729         this.goalstack25 = this.goalstack26;
 730         this.goalstack26 = this.goalstack27;
 731         this.goalstack27 = this.goalstack28;
 732         this.goalstack28 = this.goalstack29;
 733         this.goalstack29 = this.goalstack30;
 734         this.goalstack30 = this.goalstack31;
 735         this.goalstack31 = NULL;
 736 }
 737
 738 // walking to wp (walkfromwp == false) v2 and v2_height will be used as
 739 // waypoint destination coordinates instead of v (only useful for box waypoints)
 740 // for normal waypoints v2 == v and v2_height == 0
 741 float navigation_waypoint_will_link(vector v, vector org, entity ent, vector v2, float v2_height, vector o2, float o2_height, float walkfromwp, float bestdist)
 742 {
 743         if (vdist(v - org, <, bestdist))
 744         {
 745                 traceline(v, org, true, ent);
 746                 if (trace_fraction == 1)
 747                 {
 748                         if (walkfromwp)
 749                         {
 750                                 if (tracewalk(ent, v, PL_MIN_CONST, PL_MAX_CONST, v2, v2_height, bot_navigation_movemode))
 751                                         return true;
 752                         }
 753                         else
 754                         {
 755                                 if (tracewalk(ent, org, PL_MIN_CONST, PL_MAX_CONST, o2, o2_height, bot_navigation_movemode))
 756                                         return true;
 757                         }
 758                 }
 759         }
 760         return false;
 761 }
 762
 763 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
 764 entity navigation_findnearestwaypoint_withdist_except(entity ent, float walkfromwp, float bestdist, entity except)
 765 {
 766         if(ent.tag_entity)
 767                 ent = ent.tag_entity;
 768
 769         vector pm1 = ent.origin + ent.mins;
 770         vector pm2 = ent.origin + ent.maxs;
 771
 772         // do two scans, because box test is cheaper
 773         IL_EACH(g_waypoints, it != ent && it != except,
 774         {
 775                 if(boxesoverlap(pm1, pm2, it.absmin, it.absmax))
 776                 {
 777                         if(!autocvar_g_waypointeditor && walkfromwp && !ent.navigation_dynamicgoal)
 778                         {
 779                                 waypoint_clearlinks(ent); // initialize wpXXmincost fields
 780                                 navigation_item_addlink(it, ent);
 781                         }
 782                         return it;
 783                 }
 784         });
 785
 786         vector org = ent.origin;
 787         if (navigation_testtracewalk)
 788                 te_plasmaburn(org);
 789
 790         entity best = NULL;
 791         vector v = '0 0 0', v2 = '0 0 0';
 792         float v2_height = 0;
 793
 794         if(ent.size && !IS_PLAYER(ent))
 795         {
 796                 org += 0.5 * (ent.mins + ent.maxs);
 797                 org.z = ent.origin.z + ent.mins.z - PL_MIN_CONST.z; // player height
 798         }
 799
 800         if(!autocvar_g_waypointeditor && walkfromwp && !ent.navigation_dynamicgoal)
 801         {
 802                 waypoint_clearlinks(ent); // initialize wpXXmincost fields
 803                 IL_EACH(g_waypoints, it != ent,
 804                 {
 805                         if(walkfromwp && (it.wpflags & WAYPOINTFLAG_NORELINK))
 806                                 continue;
 807
 808                         SET_TRACEWALK_DESTCOORDS(it, org, v2, v2_height);
 809                         if(vdist(v2 - org, <, 1050))
 810                         if(tracewalk(ent, org, PL_MIN_CONST, PL_MAX_CONST, v2, v2_height, bot_navigation_movemode))
 811                                 navigation_item_addlink(it, ent);
 812                 });
 813         }
 814
 815         // box check failed, try walk
 816         IL_EACH(g_waypoints, it != ent,
 817         {
 818                 if(walkfromwp && (it.wpflags & WAYPOINTFLAG_NORELINK))
 819                         continue;
 820                 v = it.origin;
 821                 if(walkfromwp)
 822                         SET_TRACEWALK_DESTCOORDS(ent, v, v2, v2_height);
 823                 else
 824                         SET_TRACEWALK_DESTCOORDS(it, org, v2, v2_height);
 825                 if(navigation_waypoint_will_link(v, org, ent, v2, v2_height, v2, v2_height, walkfromwp, bestdist))
 826                 {
 827                         bestdist = vlen(v - org);
 828                         best = it;
 829                 }
 830         });
 831         return best;
 832 }
 833 entity navigation_findnearestwaypoint(entity ent, float walkfromwp)
 834 {
 835         entity wp = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, NULL);
 836         if (autocvar_g_waypointeditor_auto)
 837         {
 838                 entity wp2 = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, wp);
 839                 if (wp && !wp2)
 840                         wp.wpflags |= WAYPOINTFLAG_PROTECTED;
 841         }
 842         return wp;
 843 }
 844
 845 // finds the waypoints near the bot initiating a navigation query
 846 float navigation_markroutes_nearestwaypoints(entity this, float maxdist)
 847 {
 848         vector v = '0 0 0';
 849         //navigation_testtracewalk = true;
 850         int c = 0;
 851         float v_height = 0;
 852         IL_EACH(g_waypoints, !it.wpconsidered,
 853         {
 854                 SET_TRACEWALK_DESTCOORDS(it, this.origin, v, v_height);
 855
 856                 vector diff = v - this.origin;
 857                 diff.z = max(0, diff.z);
 858                 if(vdist(diff, <, maxdist))
 859                 {
 860                         it.wpconsidered = true;
 861                         if (tracewalk(this, this.origin, this.mins, this.maxs, v, v_height, bot_navigation_movemode))
 862                         {
 863                                 it.wpnearestpoint = v;
 864                                 it.wpcost = waypoint_gettravelcost(this.origin, v, this, it) + it.dmg;
 865                                 it.wpfire = 1;
 866                                 it.enemy = NULL;
 867                                 c = c + 1;
 868                         }
 869                 }
 870         });
 871         //navigation_testtracewalk = false;
 872         return c;
 873 }
 874
 875 // updates a path link if a spawnfunc_waypoint link is better than the current one
 876 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost, vector p)
 877 {
 878         vector m1, m2;
 879         vector v;
 880         if (wp.wpisbox)
 881         {
 882                 m1 = wp.origin + wp.mins;
 883                 m2 = wp.origin + wp.maxs;
 884                 v.x = bound(m1_x, p.x, m2_x);
 885                 v.y = bound(m1_y, p.y, m2_y);
 886                 v.z = bound(m1_z, p.z, m2_z);
 887         }
 888         else
 889                 v = wp.origin;
 890         if (w.wpflags & WAYPOINTFLAG_TELEPORT)
 891                 cost += w.wp00mincost; // assuming teleport has exactly one destination
 892         else
 893                 cost += waypoint_gettravelcost(p, v, w, wp);
 894         if (wp.wpcost > cost)
 895         {
 896                 wp.wpcost = cost;
 897                 wp.enemy = w;
 898                 wp.wpfire = 1;
 899                 wp.wpnearestpoint = v;
 900         }
 901 }
 902
 903 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
 904 void navigation_markroutes(entity this, entity fixed_source_waypoint)
 905 {
 906         float cost, cost2;
 907         vector p;
 908
 909         IL_EACH(g_waypoints, true,
 910         {
 911                 it.wpconsidered = false;
 912                 it.wpnearestpoint = '0 0 0';
 913                 it.wpcost = 10000000;
 914                 it.wpfire = 0;
 915                 it.enemy = NULL;
 916         });
 917
 918         if(fixed_source_waypoint)
 919         {
 920                 fixed_source_waypoint.wpconsidered = true;
 921                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 922                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg;
 923                 fixed_source_waypoint.wpfire = 1;
 924                 fixed_source_waypoint.enemy = NULL;
 925         }
 926         else
 927         {
 928                 // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
 929                 // as this search is expensive we will use lower values if the bot is on the air
 930                 float increment, maxdistance;
 931                 if(IS_ONGROUND(this))
 932                 {
 933                         increment = 750;
 934                         maxdistance = 50000;
 935                 }
 936                 else
 937                 {
 938                         increment = 500;
 939                         maxdistance = 1500;
 940                 }
 941
 942                 for(int j = increment; !navigation_markroutes_nearestwaypoints(this, j) && j < maxdistance; j += increment);
 943         }
 944
 945         bool searching = true;
 946         while (searching)
 947         {
 948                 searching = false;
 949                 IL_EACH(g_waypoints, it.wpfire,
 950                 {
 951                         searching = true;
 952                         it.wpfire = 0;
 953                         cost = it.wpcost;
 954                         p = it.wpnearestpoint;
 955                         entity wp;
 956                         wp = it.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp00mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 957                         wp = it.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp01mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 958                         wp = it.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp02mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 959                         wp = it.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp03mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 960                         wp = it.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp04mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 961                         wp = it.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp05mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 962                         wp = it.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp06mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 963                         wp = it.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp07mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 964                         wp = it.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp08mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 965                         wp = it.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp09mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 966                         wp = it.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp10mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 967                         wp = it.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp11mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 968                         wp = it.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp12mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 969                         wp = it.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp13mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 970                         wp = it.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp14mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 971                         wp = it.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp15mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 972                         wp = it.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp16mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 973                         wp = it.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp17mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 974                         wp = it.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp18mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 975                         wp = it.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp19mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 976                         wp = it.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp20mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 977                         wp = it.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp21mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 978                         wp = it.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp22mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 979                         wp = it.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp23mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 980                         wp = it.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp24mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 981                         wp = it.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp25mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 982                         wp = it.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp26mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 983                         wp = it.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp27mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 984                         wp = it.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp28mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 985                         wp = it.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp29mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 986                         wp = it.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp30mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 987                         wp = it.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp31mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 988                         }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
 989                 });
 990         }
 991 }
 992
 993 // queries the entire spawnfunc_waypoint network for pathes leading to the bot
 994 void navigation_markroutes_inverted(entity fixed_source_waypoint)
 995 {
 996         float cost, cost2;
 997         vector p;
 998         IL_EACH(g_waypoints, true,
 999         {
1000                 it.wpconsidered = false;
1001                 it.wpnearestpoint = '0 0 0';
1002                 it.wpcost = 10000000;
1003                 it.wpfire = 0;
1004                 it.enemy = NULL;
1005         });
1006
1007         if(fixed_source_waypoint)
1008         {
1009                 fixed_source_waypoint.wpconsidered = true;
1010                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
1011                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg; // the cost to get from X to fixed_source_waypoint
1012                 fixed_source_waypoint.wpfire = 1;
1013                 fixed_source_waypoint.enemy = NULL;
1014         }
1015         else
1016         {
1017                 error("need to start with a waypoint\n");
1018         }
1019
1020         bool searching = true;
1021         while (searching)
1022         {
1023                 searching = false;
1024                 IL_EACH(g_waypoints, it.wpfire,
1025                 {
1026                         searching = true;
1027                         it.wpfire = 0;
1028                         cost = it.wpcost; // cost to walk from it to home
1029                         p = it.wpnearestpoint;
1030                         entity wp = it;
1031                         IL_EACH(g_waypoints, it != wp,
1032                         {
1033                                 if(!waypoint_islinked(it, wp))
1034                                         continue;
1035                                 cost2 = cost + it.dmg;
1036                                 navigation_markroutes_checkwaypoint(wp, it, cost2, p);
1037                         });
1038                 });
1039         }
1040 }
1041
1042 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
1043 void navigation_routerating(entity this, entity e, float f, float rangebias)
1044 {
1045         if (!e)
1046                 return;
1047
1048         if(e.blacklisted)
1049                 return;
1050
1051         rangebias = waypoint_getlinearcost(rangebias);
1052         f = waypoint_getlinearcost(f);
1053
1054         if (IS_PLAYER(e))
1055         {
1056                 bool rate_wps = false;
1057                 if((e.flags & FL_INWATER) || (e.flags & FL_PARTIALGROUND))
1058                         rate_wps = true;
1059
1060                 if(!IS_ONGROUND(e))
1061                 {
1062                         traceline(e.origin, e.origin + '0 0 -1500', true, NULL);
1063                         int t = pointcontents(trace_endpos + '0 0 1');
1064                         if(t != CONTENT_SOLID )
1065                         {
1066                                 if(t == CONTENT_WATER || t == CONTENT_SLIME || t == CONTENT_LAVA)
1067                                         rate_wps = true;
1068                                 else if(tracebox_hits_trigger_hurt(e.origin, e.mins, e.maxs, trace_endpos))
1069                                         return;
1070                         }
1071                 }
1072
1073                 if(rate_wps)
1074                 {
1075                         entity theEnemy = e;
1076                         entity best_wp = NULL;
1077                         float best_dist = 10000;
1078                         IL_EACH(g_waypoints, vdist(it.origin - theEnemy.origin, <, 500)
1079                                 && vdist(it.origin - this.origin, >, 100)
1080                                 && !(it.wpflags & WAYPOINTFLAG_TELEPORT),
1081                         {
1082                                 float dist = vlen(it.origin - theEnemy.origin);
1083                                 if (dist < best_dist)
1084                                 {
1085                                         best_wp = it;
1086                                         best_dist = dist;
1087                                 }
1088                         });
1089                         if (!best_wp)
1090                                 return;
1091                         e = best_wp;
1092                 }
1093         }
1094
1095         vector goal_org = (e.absmin + e.absmax) * 0.5;
1096
1097         //print("routerating ", etos(e), " = ", ftos(f), " - ", ftos(rangebias), "\n");
1098
1099         // Evaluate path using jetpack
1100         if(g_jetpack)
1101         if(this.items & IT_JETPACK)
1102         if(autocvar_bot_ai_navigation_jetpack)
1103         if(vdist(this.origin - goal_org, >, autocvar_bot_ai_navigation_jetpack_mindistance))
1104         {
1105                 vector pointa, pointb;
1106
1107                 LOG_DEBUG("jetpack ai: evaluating path for ", e.classname);
1108
1109                 // Point A
1110                 traceline(this.origin, this.origin + '0 0 65535', MOVE_NORMAL, this);
1111                 pointa = trace_endpos - '0 0 1';
1112
1113                 // Point B
1114                 traceline(goal_org, goal_org + '0 0 65535', MOVE_NORMAL, e);
1115                 pointb = trace_endpos - '0 0 1';
1116
1117                 // Can I see these two points from the sky?
1118                 traceline(pointa, pointb, MOVE_NORMAL, this);
1119
1120                 if(trace_fraction==1)
1121                 {
1122                         LOG_DEBUG("jetpack ai: can bridge these two points");
1123
1124                         // Lower the altitude of these points as much as possible
1125                         float zdistance, xydistance, cost, t, fuel;
1126                         vector down, npa, npb;
1127
1128                         down = '0 0 -1' * (STAT(PL_MAX, this).z - STAT(PL_MIN, this).z) * 10;
1129
1130                         do{
1131                                 npa = pointa + down;
1132                                 npb = pointb + down;
1133
1134                                 if(npa.z<=this.absmax.z)
1135                                         break;
1136
1137                                 if(npb.z<=e.absmax.z)
1138                                         break;
1139
1140                                 traceline(npa, npb, MOVE_NORMAL, this);
1141                                 if(trace_fraction==1)
1142                                 {
1143                                         pointa = npa;
1144                                         pointb = npb;
1145                                 }
1146                         }
1147                         while(trace_fraction == 1);
1148
1149
1150                         // Rough estimation of fuel consumption
1151                         // (ignores acceleration and current xyz velocity)
1152                         xydistance = vlen(pointa - pointb);
1153                         zdistance = fabs(pointa.z - this.origin.z);
1154
1155                         t = zdistance / autocvar_g_jetpack_maxspeed_up;
1156                         t += xydistance / autocvar_g_jetpack_maxspeed_side;
1157                         fuel = t * autocvar_g_jetpack_fuel * 0.8;
1158
1159                         LOG_DEBUG("jetpack ai: required fuel ", ftos(fuel), " this.ammo_fuel ", ftos(this.ammo_fuel));
1160
1161                         // enough fuel ?
1162                         if(this.ammo_fuel>fuel)
1163                         {
1164                                 // Estimate cost
1165                                 // (as onground costs calculation is mostly based on distances, here we do the same establishing some relationship
1166                                 //  - between air and ground speeds)
1167
1168                                 cost = xydistance / (autocvar_g_jetpack_maxspeed_side/autocvar_sv_maxspeed);
1169                                 cost += zdistance / (autocvar_g_jetpack_maxspeed_up/autocvar_sv_maxspeed);
1170                                 cost *= 1.5;
1171
1172                                 // Compare against other goals
1173                                 f = f * rangebias / (rangebias + cost);
1174
1175                                 if (navigation_bestrating < f)
1176                                 {
1177                                         LOG_DEBUG("jetpack path: added goal ", e.classname, " (with rating ", ftos(f), ")");
1178                                         navigation_bestrating = f;
1179                                         navigation_bestgoal = e;
1180                                         this.navigation_jetpack_goal = e;
1181                                         this.navigation_jetpack_point = pointb;
1182                                 }
1183                                 return;
1184                         }
1185                 }
1186         }
1187
1188         entity nwp;
1189         //te_wizspike(e.origin);
1190         //bprint(etos(e));
1191         //bprint("\n");
1192         // update the cached spawnfunc_waypoint link on a dynamic item entity
1193         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
1194         {
1195                 nwp = e;
1196         }
1197         else
1198         {
1199                 if(autocvar_g_waypointeditor && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
1200                         e.nearestwaypoint = NULL;
1201
1202                 if ((!e.nearestwaypoint || e.navigation_dynamicgoal)
1203                         && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
1204                 {
1205                         nwp = navigation_findnearestwaypoint(e, true);
1206                         if(nwp)
1207                         {
1208                                 e.nearestwaypoint = nwp;
1209
1210                                 vector m1 = nwp.absmin, m2 = nwp.absmax;
1211                                 m1.x = nwp.origin.x; m1.y = nwp.origin.y;
1212                                 m2.x = nwp.origin.x; m2.y = nwp.origin.y;
1213                                 vector ve = (e.absmin - e.absmax) * 0.5;
1214                                 ve.x = bound(m1.x, ve.x, m2.x);
1215                                 ve.y = bound(m1.y, ve.y, m2.y);
1216                                 ve.z = bound(m1.z, ve.z, m2.z);
1217
1218                                 m1 = e.absmin; m2 = e.absmax;
1219                                 m1.x = e.origin.x; m1.y = e.origin.y;
1220                                 m2.x = e.origin.x; m2.y = e.origin.y;
1221                                 vector vnwp = nwp.origin;
1222                                 vnwp.x = bound(m1.x, vnwp.x, m2.x);
1223                                 vnwp.y = bound(m1.y, vnwp.y, m2.y);
1224                                 vnwp.z = bound(m1.z, vnwp.z, m2.z);
1225                                 e.nearestwaypoint_dist = vlen(ve - vnwp);
1226                         }
1227                         else
1228                         {
1229                                 LOG_DEBUG("FAILED to find a nearest waypoint to '", e.classname, "' #", etos(e));
1230
1231                                 if(!e.navigation_dynamicgoal)
1232                                         e.blacklisted = true;
1233
1234                                 if(e.blacklisted)
1235                                 {
1236                                         LOG_DEBUG("The entity '", e.classname, "' is going to be excluded from path finding during this match");
1237                                         return;
1238                                 }
1239                         }
1240
1241                         if(e.navigation_dynamicgoal)
1242                                 e.nearestwaypointtimeout = time + 2;
1243                         else if(autocvar_g_waypointeditor)
1244                                 e.nearestwaypointtimeout = time + 3 + random() * 2;
1245                 }
1246                 nwp = e.nearestwaypoint;
1247         }
1248
1249         LOG_DEBUG("-- checking ", e.classname, " (with cost ", ftos(nwp.wpcost), ")");
1250         if (nwp)
1251         if (nwp.wpcost < 10000000)
1252         {
1253                 //te_wizspike(nwp.wpnearestpoint);
1254                 float cost = nwp.wpcost + waypoint_gettravelcost(nwp.wpnearestpoint, goal_org, nwp, e);
1255                 LOG_DEBUG(e.classname, " ", ftos(f), "/(1+", ftos(cost), "/", ftos(rangebias), ") = ");
1256                 f = f * rangebias / (rangebias + cost);
1257                 LOG_DEBUG("considering ", e.classname, " (with rating ", ftos(f), ")");
1258                 if (navigation_bestrating < f)
1259                 {
1260                         LOG_DEBUG("ground path: added goal ", e.classname, " (with rating ", ftos(f), ")");
1261                         navigation_bestrating = f;
1262                         navigation_bestgoal = e;
1263                 }
1264         }
1265 }
1266
1267 // adds an item to the the goal stack with the path to a given item
1268 bool navigation_routetogoal(entity this, entity e, vector startposition)
1269 {
1270         // if there is no goal, just exit
1271         if (!e)
1272                 return false;
1273
1274         entity teleport_goal = NULL;
1275
1276         this.goalentity = e;
1277
1278         if(e.wpflags & WAYPOINTFLAG_TELEPORT)
1279         {
1280                 // force teleport destination as route destination
1281                 teleport_goal = e;
1282                 navigation_pushroute(this, e.wp00);
1283                 this.goalentity = e.wp00;
1284         }
1285
1286         // put the entity on the goal stack
1287         //print("routetogoal ", etos(e), "\n");
1288         navigation_pushroute(this, e);
1289
1290         if(teleport_goal)
1291                 e = this.goalentity;
1292
1293         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
1294         {
1295                 this.wp_goal_prev1 = this.wp_goal_prev0;
1296                 this.wp_goal_prev0 = e;
1297         }
1298
1299         if(g_jetpack)
1300         if(e==this.navigation_jetpack_goal)
1301                 return true;
1302
1303         // if it can reach the goal there is nothing more to do
1304         vector dest = '0 0 0';
1305         float dest_height = 0;
1306         SET_TRACEWALK_DESTCOORDS(e, startposition, dest, dest_height);
1307         if (tracewalk(this, startposition, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1308                 return true;
1309
1310         entity nearest_wp = NULL;
1311         // see if there are waypoints describing a path to the item
1312         if(e.classname != "waypoint" || (e.wpflags & WAYPOINTFLAG_PERSONAL))
1313         {
1314                 e = e.nearestwaypoint;
1315                 nearest_wp = e;
1316         }
1317         else if(teleport_goal)
1318                 e = teleport_goal;
1319         else
1320                 e = e.enemy; // we already have added it, so...
1321
1322         if(e == NULL)
1323                 return false;
1324
1325         if(nearest_wp && nearest_wp.enemy)
1326         {
1327                 // often path can be optimized by not adding the nearest waypoint
1328                 if (this.goalentity.nearestwaypoint_dist < 8)
1329                         e = nearest_wp.enemy;
1330                 else
1331                 {
1332                         if (this.goalentity.navigation_dynamicgoal || autocvar_g_waypointeditor)
1333                         {
1334                                 SET_TRACEWALK_DESTCOORDS(this.goalentity, nearest_wp.enemy.origin, dest, dest_height);
1335                                 if(vdist(dest - nearest_wp.enemy.origin, <, 1050))
1336                                 if(tracewalk(this, nearest_wp.enemy.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1337                                         e = nearest_wp.enemy;
1338                         }
1339                         else if(navigation_item_islinked(nearest_wp.enemy, this.goalentity))
1340                                 e = nearest_wp.enemy;
1341                 }
1342         }
1343
1344         for (;;)
1345         {
1346                 // add the spawnfunc_waypoint to the path
1347                 navigation_pushroute(this, e);
1348                 e = e.enemy;
1349
1350                 if(e==NULL)
1351                         break;
1352         }
1353
1354         return false;
1355 }
1356
1357 // removes any currently touching waypoints from the goal stack
1358 // (this is how bots detect if they reached a goal)
1359 int navigation_poptouchedgoals(entity this)
1360 {
1361         int removed_goals = 0;
1362         if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1363         {
1364                 // make sure jumppad is really hit, don't rely on distance based checks
1365                 // as they may report a touch even if it didn't really happen
1366                 if(this.lastteleporttime > 0
1367                         && time - this.lastteleporttime < ((this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL) ? 2 : 0.15))
1368                 {
1369                         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1370                         if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1371                         {
1372                                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1373                                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1374                         }
1375                         navigation_poproute(this);
1376                         ++removed_goals;
1377                 }
1378                 else
1379                         return removed_goals;
1380         }
1381
1382         // If for some reason the bot is closer to the next goal, pop the current one
1383         if(this.goalstack01 && !wasfreed(this.goalstack01))
1384         if(vlen2(this.goalcurrent.origin - this.origin) > vlen2(this.goalstack01.origin - this.origin))
1385         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
1386         {
1387                 vector dest = '0 0 0';
1388                 float dest_height = 0;
1389                 SET_TRACEWALK_DESTCOORDS(this.goalstack01, this.origin, dest, dest_height);
1390                 if(tracewalk(this, this.origin, this.mins, this.maxs, dest, dest_height, bot_navigation_movemode))
1391                 {
1392                         LOG_DEBUG("path optimized for ", this.netname, ", removed a goal from the queue");
1393                         navigation_poproute(this);
1394                         ++removed_goals;
1395                         if(this.goalcurrent && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1396                                 return removed_goals;
1397                         // TODO this may also be a nice idea to do "early" (e.g. by
1398                         // manipulating the vlen() comparisons) to shorten paths in
1399                         // general - this would make bots walk more "on rails" than
1400                         // "zigzagging" which they currently do with sufficiently
1401                         // random-like waypoints, and thus can make a nice bot
1402                         // personality property
1403                 }
1404         }
1405
1406         // Loose goal touching check when running
1407         if(this.aistatus & AI_STATUS_RUNNING)
1408         if(this.goalcurrent.classname=="waypoint")
1409         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
1410         {
1411                 if(vdist(this.origin - this.goalcurrent.origin, <, 150))
1412                 {
1413                         traceline(this.origin + this.view_ofs , this.goalcurrent.origin, true, NULL);
1414                         if(trace_fraction==1)
1415                         {
1416                                 // Detect personal waypoints
1417                                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1418                                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1419                                 {
1420                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1421                                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1422                                 }
1423
1424                                 navigation_poproute(this);
1425                                 ++removed_goals;
1426                                 if(this.goalcurrent && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1427                                         return removed_goals;
1428                         }
1429                 }
1430         }
1431
1432         while (this.goalcurrent && !IS_PLAYER(this.goalcurrent))
1433         {
1434                 vector gc_min = this.goalcurrent.absmin;
1435                 vector gc_max = this.goalcurrent.absmax;
1436                 if(this.goalcurrent.classname == "waypoint" && !this.goalcurrent.wpisbox)
1437                 {
1438                         gc_min = this.goalcurrent.origin - '1 1 1' * 12;
1439                         gc_max = this.goalcurrent.origin + '1 1 1' * 12;
1440                 }
1441                 if(!boxesoverlap(this.absmin, this.absmax, gc_min, gc_max))
1442                         break;
1443
1444                 // Detect personal waypoints
1445                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1446                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1447                 {
1448                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1449                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1450                 }
1451
1452                 navigation_poproute(this);
1453                 ++removed_goals;
1454                 if(this.goalcurrent && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1455                         return removed_goals;
1456         }
1457         return removed_goals;
1458 }
1459
1460 entity navigation_get_really_close_waypoint(entity this)
1461 {
1462         entity wp = this.goalcurrent;
1463         if(!wp || vdist(wp.origin - this.origin, >, 50))
1464                 wp = this.goalcurrent_prev;
1465         if(!wp)
1466                 return NULL;
1467         if(wp.classname != "waypoint")
1468         {
1469                 wp = wp.nearestwaypoint;
1470                 if(!wp)
1471                         return NULL;
1472         }
1473         if(vdist(wp.origin - this.origin, >, 50))
1474         {
1475                 IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
1476                 {
1477                         if(vdist(it.origin - this.origin, <, 50))
1478                         {
1479                                 wp = it;
1480                                 break;
1481                         }
1482                 });
1483         }
1484         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1485                 return NULL;
1486
1487         vector dest = '0 0 0';
1488         float dest_height = 0;
1489         SET_TRACEWALK_DESTCOORDS(wp, this.origin, dest, dest_height);
1490         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1491                 return NULL;
1492         return wp;
1493 }
1494
1495 // begin a goal selection session (queries spawnfunc_waypoint network)
1496 void navigation_goalrating_start(entity this)
1497 {
1498         if(this.aistatus & AI_STATUS_STUCK)
1499                 return;
1500
1501         this.navigation_jetpack_goal = NULL;
1502         navigation_bestrating = -1;
1503         entity wp = navigation_get_really_close_waypoint(this);
1504         navigation_clearroute(this);
1505         navigation_bestgoal = NULL;
1506         navigation_markroutes(this, wp);
1507 }
1508
1509 // ends a goal selection session (updates goal stack to the best goal)
1510 void navigation_goalrating_end(entity this)
1511 {
1512         if(this.aistatus & AI_STATUS_STUCK)
1513                 return;
1514
1515         navigation_routetogoal(this, navigation_bestgoal, this.origin);
1516         LOG_DEBUG("best goal ", this.goalcurrent.classname);
1517
1518         // If the bot got stuck then try to reach the farthest waypoint
1519         if (!this.goalentity && autocvar_bot_wander_enable)
1520         {
1521                 if (!(this.aistatus & AI_STATUS_STUCK))
1522                 {
1523                         LOG_DEBUG(this.netname, " cannot walk to any goal");
1524                         this.aistatus |= AI_STATUS_STUCK;
1525                 }
1526         }
1527 }
1528
1529 void botframe_updatedangerousobjects(float maxupdate)
1530 {
1531         vector m1, m2, v, o;
1532         float c, d, danger;
1533         c = 0;
1534         entity wp_cur;
1535         IL_EACH(g_waypoints, true,
1536         {
1537                 danger = 0;
1538                 m1 = it.absmin;
1539                 m2 = it.absmax;
1540                 wp_cur = it;
1541                 IL_EACH(g_bot_dodge, it.bot_dodge,
1542                 {
1543                         v = it.origin;
1544                         v.x = bound(m1_x, v.x, m2_x);
1545                         v.y = bound(m1_y, v.y, m2_y);
1546                         v.z = bound(m1_z, v.z, m2_z);
1547                         o = (it.absmin + it.absmax) * 0.5;
1548                         d = waypoint_getlinearcost(it.bot_dodgerating) - waypoint_gettravelcost(o, v, it, wp_cur);
1549                         if (d > 0)
1550                         {
1551                                 traceline(o, v, true, NULL);
1552                                 if (trace_fraction == 1)
1553                                         danger = danger + d;
1554                         }
1555                 });
1556                 it.dmg = danger;
1557                 c = c + 1;
1558                 if (c >= maxupdate)
1559                         break;
1560         });
1561 }
1562
1563 void navigation_unstuck(entity this)
1564 {
1565         float search_radius = 1000;
1566
1567         if (!autocvar_bot_wander_enable)
1568                 return;
1569
1570         if (!bot_waypoint_queue_owner)
1571         {
1572                 LOG_DEBUG(this.netname, " stuck, taking over the waypoints queue");
1573                 bot_waypoint_queue_owner = this;
1574                 bot_waypoint_queue_bestgoal = NULL;
1575                 bot_waypoint_queue_bestgoalrating = 0;
1576         }
1577
1578         if(bot_waypoint_queue_owner!=this)
1579                 return;
1580
1581         if (bot_waypoint_queue_goal)
1582         {
1583                 // evaluate the next goal on the queue
1584                 float d = vlen2(this.origin - bot_waypoint_queue_goal.origin);
1585                 LOG_DEBUG(this.netname, " evaluating ", bot_waypoint_queue_goal.classname, " with distance ", ftos(d));
1586                 vector dest = '0 0 0';
1587                 float dest_height = 0;
1588                 SET_TRACEWALK_DESTCOORDS(bot_waypoint_queue_goal, this.origin, dest, dest_height);
1589                 if(tracewalk(bot_waypoint_queue_goal, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1590                 {
1591                         if( d > bot_waypoint_queue_bestgoalrating)
1592                         {
1593                                 bot_waypoint_queue_bestgoalrating = d;
1594                                 bot_waypoint_queue_bestgoal = bot_waypoint_queue_goal;
1595                         }
1596                 }
1597                 bot_waypoint_queue_goal = bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal;
1598
1599                 if (!bot_waypoint_queue_goal)
1600                 {
1601                         if (bot_waypoint_queue_bestgoal)
1602                         {
1603                                 LOG_DEBUG(this.netname, " stuck, reachable waypoint found, heading to it");
1604                                 navigation_routetogoal(this, bot_waypoint_queue_bestgoal, this.origin);
1605                                 navigation_goalrating_timeout_set(this);
1606                                 this.aistatus &= ~AI_STATUS_STUCK;
1607                         }
1608                         else
1609                         {
1610                                 LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1611                         }
1612
1613                         bot_waypoint_queue_owner = NULL;
1614                 }
1615         }
1616         else
1617         {
1618                 if(bot_strategytoken!=this)
1619                         return;
1620
1621                 // build a new queue
1622                 LOG_DEBUG(this.netname, " stuck, scanning reachable waypoints within ", ftos(search_radius)," qu");
1623
1624                 entity first = NULL;
1625
1626                 FOREACH_ENTITY_RADIUS(this.origin, search_radius, it.classname == "waypoint" && !(it.wpflags & WAYPOINTFLAG_GENERATED),
1627                 {
1628                         if(bot_waypoint_queue_goal)
1629                                 bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = it;
1630                         else
1631                                 first = it;
1632
1633                         bot_waypoint_queue_goal = it;
1634                         bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = NULL;
1635                 });
1636
1637                 if (first)
1638                         bot_waypoint_queue_goal = first;
1639                 else
1640                 {
1641                         LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1642                         bot_waypoint_queue_owner = NULL;
1643                 }
1644         }
1645 }
1646
1647 // Support for debugging tracewalk visually
1648
1649 void debugresetnodes()
1650 {
1651         debuglastnode = '0 0 0';
1652 }
1653
1654 void debugnode(entity this, vector node)
1655 {
1656         if (!IS_PLAYER(this))
1657                 return;
1658
1659         if(debuglastnode=='0 0 0')
1660         {
1661                 debuglastnode = node;
1662                 return;
1663         }
1664
1665         te_lightning2(NULL, node, debuglastnode);
1666         debuglastnode = node;
1667 }
1668
1669 void debugnodestatus(vector position, float status)
1670 {
1671         vector c;
1672
1673         switch (status)
1674         {
1675                 case DEBUG_NODE_SUCCESS:
1676                         c = '0 15 0';
1677                         break;
1678                 case DEBUG_NODE_WARNING:
1679                         c = '15 15 0';
1680                         break;
1681                 case DEBUG_NODE_FAIL:
1682                         c = '15 0 0';
1683                         break;
1684                 default:
1685                         c = '15 15 15';
1686         }
1687
1688         te_customflash(position, 40,  2, c);
1689 }
1690
1691 // Support for debugging the goal stack visually
1692
1693 .float goalcounter;
1694 .vector lastposition;
1695
1696 // Debug the goal stack visually
1697 void debuggoalstack(entity this)
1698 {
1699         entity goal;
1700         vector org, go;
1701
1702         if(this.goalcounter==0)goal=this.goalcurrent;
1703         else if(this.goalcounter==1)goal=this.goalstack01;
1704         else if(this.goalcounter==2)goal=this.goalstack02;
1705         else if(this.goalcounter==3)goal=this.goalstack03;
1706         else if(this.goalcounter==4)goal=this.goalstack04;
1707         else if(this.goalcounter==5)goal=this.goalstack05;
1708         else if(this.goalcounter==6)goal=this.goalstack06;
1709         else if(this.goalcounter==7)goal=this.goalstack07;
1710         else if(this.goalcounter==8)goal=this.goalstack08;
1711         else if(this.goalcounter==9)goal=this.goalstack09;
1712         else if(this.goalcounter==10)goal=this.goalstack10;
1713         else if(this.goalcounter==11)goal=this.goalstack11;
1714         else if(this.goalcounter==12)goal=this.goalstack12;
1715         else if(this.goalcounter==13)goal=this.goalstack13;
1716         else if(this.goalcounter==14)goal=this.goalstack14;
1717         else if(this.goalcounter==15)goal=this.goalstack15;
1718         else if(this.goalcounter==16)goal=this.goalstack16;
1719         else if(this.goalcounter==17)goal=this.goalstack17;
1720         else if(this.goalcounter==18)goal=this.goalstack18;
1721         else if(this.goalcounter==19)goal=this.goalstack19;
1722         else if(this.goalcounter==20)goal=this.goalstack20;
1723         else if(this.goalcounter==21)goal=this.goalstack21;
1724         else if(this.goalcounter==22)goal=this.goalstack22;
1725         else if(this.goalcounter==23)goal=this.goalstack23;
1726         else if(this.goalcounter==24)goal=this.goalstack24;
1727         else if(this.goalcounter==25)goal=this.goalstack25;
1728         else if(this.goalcounter==26)goal=this.goalstack26;
1729         else if(this.goalcounter==27)goal=this.goalstack27;
1730         else if(this.goalcounter==28)goal=this.goalstack28;
1731         else if(this.goalcounter==29)goal=this.goalstack29;
1732         else if(this.goalcounter==30)goal=this.goalstack30;
1733         else if(this.goalcounter==31)goal=this.goalstack31;
1734         else goal=NULL;
1735
1736         if(goal==NULL)
1737         {
1738                 this.goalcounter = 0;
1739                 this.lastposition='0 0 0';
1740                 return;
1741         }
1742
1743         if(this.lastposition=='0 0 0')
1744                 org = this.origin;
1745         else
1746                 org = this.lastposition;
1747
1748
1749         go = ( goal.absmin + goal.absmax ) * 0.5;
1750         te_lightning2(NULL, org, go);
1751         this.lastposition = go;
1752
1753         this.goalcounter++;
1754 }