qcsrc/server/bot/default/navigation.qc

   1 #include "navigation.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "waypoints.qh"
   7
   8 #include <common/t_items.qh>
   9
  10 #include <common/items/_mod.qh>
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/triggers/trigger/jumppads.qh>
  15
  16 .float speed;
  17
  18 void navigation_dynamicgoal_init(entity this, bool initially_static)
  19 {
  20         this.navigation_dynamicgoal = true;
  21         this.bot_basewaypoint = this.nearestwaypoint;
  22         if(initially_static)
  23                 this.nearestwaypointtimeout = -1;
  24         else
  25                 this.nearestwaypointtimeout = time;
  26 }
  27
  28 void navigation_dynamicgoal_set(entity this)
  29 {
  30         this.nearestwaypointtimeout = time;
  31 }
  32
  33 void navigation_dynamicgoal_unset(entity this)
  34 {
  35         if(this.bot_basewaypoint)
  36                 this.nearestwaypoint = this.bot_basewaypoint;
  37         this.nearestwaypointtimeout = -1;
  38 }
  39
  40 bool navigation_checkladders(entity e, vector org, vector m1, vector m2, vector end, vector end2, int movemode)
  41 {
  42         IL_EACH(g_ladders, it.classname == "func_ladder",
  43         {
  44                 if(it.bot_pickup)
  45                 if(boxesoverlap(org + m1 + '-1 -1 -1', org + m2 + '1 1 1', it.absmin, it.absmax))
  46                 if(boxesoverlap(end, end2, it.absmin + (m1 - eZ * m1.z - '1 1 0'), it.absmax + (m2 - eZ * m2.z + '1 1 0')))
  47                 {
  48                         vector top = org;
  49                         top.z = it.absmax.z + (PL_MAX_CONST.z - PL_MIN_CONST.z);
  50                         tracebox(org, m1, m2, top, movemode, e);
  51                         if(trace_fraction == 1)
  52                                 return true;
  53                 }
  54         });
  55         return false;
  56 }
  57
  58 #define IN_WATER(pos) (cont = pointcontents(pos), (cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME))
  59 #define SUBMERGED(pos) IN_WATER(pos + autocvar_sv_player_viewoffset)
  60 #define WATERFEET(pos) IN_WATER(pos + eZ * (m1.z + 1))
  61
  62 #define RESURFACE(org) MACRO_BEGIN { \
  63         while(org.z + 4 < end2.z) { \
  64                 if(!WATERFEET(org + eZ * 4)) \
  65                         break; \
  66                 org.z += 4; \
  67         } \
  68 } MACRO_END
  69 // rough simulation of walking from one point to another to test if a path
  70 // can be traveled, used for waypoint linking and havocbot
  71 // if end_height is > 0 destination is any point in the vertical segment [end, end + end_height * eZ]
  72 bool tracewalk(entity e, vector start, vector m1, vector m2, vector end, float end_height, float movemode)
  73 {
  74         if(autocvar_bot_debug_tracewalk)
  75         {
  76                 debugresetnodes();
  77                 debugnode(e, start);
  78         }
  79
  80         vector org = start;
  81         vector dir = end - start;
  82         dir.z = 0;
  83         float dist = vlen(dir);
  84         dir = normalize(dir);
  85         float stepdist = 32;
  86         bool ignorehazards = false;
  87         bool swimming = false;
  88         bool swimming_outwater = false;
  89         int cont;
  90
  91         // Analyze starting point
  92         traceline(start, start, MOVE_NORMAL, e);
  93         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  94                 ignorehazards = true;
  95         else
  96         {
  97                 traceline( start, start + '0 0 -65536', MOVE_NORMAL, e);
  98                 if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  99                         ignorehazards = true;
 100         }
 101         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
 102         if (trace_startsolid)
 103         {
 104                 // Bad start
 105                 if(autocvar_bot_debug_tracewalk)
 106                         debugnodestatus(start, DEBUG_NODE_FAIL);
 107
 108                 //print("tracewalk: ", vtos(start), " is a bad start\n");
 109                 return false;
 110         }
 111
 112         vector end2 = end;
 113         if(end_height)
 114                 end2.z += end_height;
 115         // Movement loop
 116         for (;;)
 117         {
 118                 if (boxesoverlap(end, end2, org + '-1 -1 -1', org + '1 1 1'))
 119                 {
 120                         // Succeeded
 121                         if(autocvar_bot_debug_tracewalk)
 122                                 debugnodestatus(org, DEBUG_NODE_SUCCESS);
 123
 124                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 125                         return true;
 126                 }
 127                 if(autocvar_bot_debug_tracewalk)
 128                         debugnode(e, org);
 129
 130                 if (dist <= 0)
 131                         break;
 132
 133                 traceline(org, org, MOVE_NORMAL, e);
 134
 135                 if (!ignorehazards)
 136                 {
 137                         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
 138                         {
 139                                 // hazards blocking path
 140                                 if(autocvar_bot_debug_tracewalk)
 141                                         debugnodestatus(org, DEBUG_NODE_FAIL);
 142
 143                                 //print("tracewalk: ", vtos(start), " hits a hazard when trying to reach ", vtos(end), "\n");
 144                                 return false;
 145                         }
 146                 }
 147                 if ((trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK) || swimming)
 148                 {
 149                         vector water_end = end;
 150                         water_end.z = bound(end.z, org.z, end2.z);
 151                         vector water_dir;
 152                         if(swimming_outwater)
 153                         {
 154                                 water_dir = dir;
 155                                 if (stepdist > dist)
 156                                         stepdist = dist;
 157                                 dist -= stepdist;
 158                         }
 159                         else
 160                         {
 161                                 water_dir = normalize(water_end - org);
 162                                 vector ang = vectoangles(water_dir);
 163                                 float c = cos(ang.x * DEG2RAD);
 164                                 if (stepdist * c > dist)
 165                                         stepdist = dist / c;
 166                                 dist -= stepdist * c;
 167                         }
 168                         vector move = org + water_dir * stepdist;
 169
 170                         tracebox(org, m1, m2, move, movemode, e);
 171                         if (trace_fraction < 1) // cant swim in the current direction
 172                         {
 173                                 if(dist <= 0)
 174                                         tracebox(org + stepheightvec, m1, m2, move, movemode, e);
 175                                 else
 176                                         tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 177                                 if (trace_startsolid)
 178                                 {
 179                                         if(autocvar_bot_debug_tracewalk)
 180                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 181
 182                                         return false;
 183                                         //print("tracewalk: ", vtos(start), " failed under water\n");
 184                                 }
 185
 186                                 if (trace_fraction < 1) // cant step-swim in the current direction
 187                                 {
 188                                         if(autocvar_bot_debug_tracewalk)
 189                                                 debugnodestatus(org, DEBUG_NODE_WARNING);
 190
 191                                         if(WATERFEET(org))
 192                                         {
 193                                                 RESURFACE(org);
 194                                                 if(autocvar_bot_debug_tracewalk)
 195                                                         debugnode(e, org);
 196
 197                                                 //water_dir = dir;
 198                                                 move = org + dir * stepdist;
 199
 200                                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 201                                         }
 202
 203                                         if (trace_fraction < 1 || trace_startsolid) // can't jump obstacle out of water
 204                                         {
 205                                                 vector v = trace_endpos - stepheightvec + jumpheight_vec;
 206                                                 if(navigation_checkladders(e, v, m1, m2, end, end2, movemode))
 207                                                 {
 208                                                         if(autocvar_bot_debug_tracewalk)
 209                                                         {
 210                                                                 debugnode(e, v);
 211                                                                 debugnodestatus(v, DEBUG_NODE_SUCCESS);
 212                                                         }
 213
 214                                                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 215                                                         return true;
 216                                                 }
 217
 218                                                 if(autocvar_bot_debug_tracewalk)
 219                                                         debugnodestatus(org, DEBUG_NODE_FAIL);
 220
 221                                                 return false;
 222                                                 //print("tracewalk: ", vtos(start), " failed under water\n");
 223                                         }
 224
 225                                         // successfully jumped obstacle up out of water
 226                                         move = trace_endpos;
 227                                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 228                                         if(trace_endpos != move)
 229                                         if(autocvar_bot_debug_tracewalk)
 230                                                 debugnode(e, move);
 231                                         org = trace_endpos;
 232
 233                                         swimming = false;
 234                                         swimming_outwater = false;
 235
 236                                         continue;
 237                                 }
 238                         }
 239
 240                         float height = trace_endpos.z - org.z;
 241
 242                         // successfully advanced by swimming or step-swimming
 243                         org = trace_endpos;
 244
 245                         if(height > 0 && (swimming || !SUBMERGED(org)))
 246                         {
 247                                 swimming = true;
 248                                 if(!swimming_outwater && !WATERFEET(org))
 249                                 {
 250                                         // put it back in the water if it gets out of water
 251                                         do {
 252                                                 org.z -= 4;
 253                                                 if(WATERFEET(org))
 254                                                         break;
 255                                         } while(org.z > height);
 256                                         swimming_outwater = true;
 257                                 }
 258                         }
 259                 }
 260                 else // if (!((trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK) || swimming))
 261                 {
 262                         if (stepdist > dist)
 263                                 stepdist = dist;
 264                         dist -= stepdist;
 265
 266                         vector move = org + dir * stepdist;
 267                         tracebox(org, m1, m2, move, movemode, e);
 268
 269                         if(autocvar_bot_debug_tracewalk)
 270                                 debugnode(e, trace_endpos);
 271
 272                         // hit something
 273                         if (trace_fraction < 1)
 274                         {
 275                                 // check if we can walk over this obstacle, possibly by jumpstepping
 276                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 277                                 if (trace_fraction < 1 || trace_startsolid)
 278                                 {
 279                                         tracebox(org + jumpstepheightvec, m1, m2, move + jumpstepheightvec, movemode, e);
 280                                         if (trace_fraction < 1 || trace_startsolid)
 281                                         {
 282                                                 vector v = trace_endpos - jumpstepheightvec + jumpheight_vec;
 283                                                 if(navigation_checkladders(e, v, m1, m2, end, end2, movemode))
 284                                                 {
 285                                                         if(autocvar_bot_debug_tracewalk)
 286                                                         {
 287                                                                 debugnode(e, v);
 288                                                                 debugnodestatus(v, DEBUG_NODE_SUCCESS);
 289                                                         }
 290
 291                                                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 292                                                         return true;
 293                                                 }
 294
 295                                                 if(autocvar_bot_debug_tracewalk)
 296                                                         debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 297
 298                                                 traceline( org, move, movemode, e);
 299
 300                                                 if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 301                                                 {
 302                                                         vector nextmove;
 303                                                         move = trace_endpos;
 304                                                         while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 305                                                         {
 306                                                                 nextmove = move + (dir * stepdist);
 307                                                                 traceline( move, nextmove, movemode, e);
 308                                                                 move = nextmove;
 309                                                         }
 310                                                         dist = vlen(vec2(end - move));
 311                                                 }
 312                                                 else
 313                                                 {
 314                                                         if(autocvar_bot_debug_tracewalk)
 315                                                                 debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 316
 317                                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 318                                                         //te_explosion(trace_endpos);
 319                                                         //print(ftos(e.dphitcontentsmask), "\n");
 320                                                         return false; // failed
 321                                                 }
 322                                         }
 323                                         else
 324                                                 move = trace_endpos;
 325                                 }
 326                                 else
 327                                         move = trace_endpos;
 328                         }
 329                         else
 330                                 move = trace_endpos;
 331
 332                         // trace down from stepheight as far as possible and move there,
 333                         // if this starts in solid we try again without the stepup, and
 334                         // if that also fails we assume it is a wall
 335                         // (this is the same logic as the Quake walkmove function used)
 336                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 337
 338                         org = trace_endpos;
 339
 340                         if(org.z < move.z && SUBMERGED(org))
 341                         {
 342                                 // ended up underwater while walking, resurface
 343                                 if(autocvar_bot_debug_tracewalk)
 344                                         debugnode(e, org);
 345                                 RESURFACE(org);
 346                                 swimming = true;
 347                                 swimming_outwater = true;
 348                         }
 349                 }
 350         }
 351
 352         //print("tracewalk: ", vtos(start), " did not arrive at ", vtos(end), " but at ", vtos(org), "\n");
 353
 354         // moved but didn't arrive at the intended destination
 355         if(autocvar_bot_debug_tracewalk)
 356                 debugnodestatus(org, DEBUG_NODE_FAIL);
 357
 358         return false;
 359 }
 360
 361 /////////////////////////////////////////////////////////////////////////////
 362 // goal stack
 363 /////////////////////////////////////////////////////////////////////////////
 364
 365 // completely empty the goal stack, used when deciding where to go
 366 void navigation_clearroute(entity this)
 367 {
 368         this.goalcurrent_prev = this.goalcurrent;
 369         this.goalcurrent_distance = 10000000;
 370         this.goalcurrent_distance_time = 0;
 371         //print("bot ", etos(this), " clear\n");
 372         this.goalentity = NULL;
 373         this.goalcurrent = NULL;
 374         this.goalstack01 = NULL;
 375         this.goalstack02 = NULL;
 376         this.goalstack03 = NULL;
 377         this.goalstack04 = NULL;
 378         this.goalstack05 = NULL;
 379         this.goalstack06 = NULL;
 380         this.goalstack07 = NULL;
 381         this.goalstack08 = NULL;
 382         this.goalstack09 = NULL;
 383         this.goalstack10 = NULL;
 384         this.goalstack11 = NULL;
 385         this.goalstack12 = NULL;
 386         this.goalstack13 = NULL;
 387         this.goalstack14 = NULL;
 388         this.goalstack15 = NULL;
 389         this.goalstack16 = NULL;
 390         this.goalstack17 = NULL;
 391         this.goalstack18 = NULL;
 392         this.goalstack19 = NULL;
 393         this.goalstack20 = NULL;
 394         this.goalstack21 = NULL;
 395         this.goalstack22 = NULL;
 396         this.goalstack23 = NULL;
 397         this.goalstack24 = NULL;
 398         this.goalstack25 = NULL;
 399         this.goalstack26 = NULL;
 400         this.goalstack27 = NULL;
 401         this.goalstack28 = NULL;
 402         this.goalstack29 = NULL;
 403         this.goalstack30 = NULL;
 404         this.goalstack31 = NULL;
 405 }
 406
 407 // add a new goal at the beginning of the stack
 408 // (in other words: add a new prerequisite before going to the later goals)
 409 // NOTE: when a waypoint is added, the WP gets pushed first, then the
 410 // next-closest WP on the shortest path to the WP
 411 // That means, if the stack overflows, the bot will know how to do the FIRST 32
 412 // steps to the goal, and then recalculate the path.
 413 void navigation_pushroute(entity this, entity e)
 414 {
 415         this.goalcurrent_prev = this.goalcurrent;
 416         this.goalcurrent_distance = 10000000;
 417         this.goalcurrent_distance_time = 0;
 418         //print("bot ", etos(this), " push ", etos(e), "\n");
 419         if(this.goalstack31 == this.goalentity)
 420                 this.goalentity = NULL;
 421         this.goalstack31 = this.goalstack30;
 422         this.goalstack30 = this.goalstack29;
 423         this.goalstack29 = this.goalstack28;
 424         this.goalstack28 = this.goalstack27;
 425         this.goalstack27 = this.goalstack26;
 426         this.goalstack26 = this.goalstack25;
 427         this.goalstack25 = this.goalstack24;
 428         this.goalstack24 = this.goalstack23;
 429         this.goalstack23 = this.goalstack22;
 430         this.goalstack22 = this.goalstack21;
 431         this.goalstack21 = this.goalstack20;
 432         this.goalstack20 = this.goalstack19;
 433         this.goalstack19 = this.goalstack18;
 434         this.goalstack18 = this.goalstack17;
 435         this.goalstack17 = this.goalstack16;
 436         this.goalstack16 = this.goalstack15;
 437         this.goalstack15 = this.goalstack14;
 438         this.goalstack14 = this.goalstack13;
 439         this.goalstack13 = this.goalstack12;
 440         this.goalstack12 = this.goalstack11;
 441         this.goalstack11 = this.goalstack10;
 442         this.goalstack10 = this.goalstack09;
 443         this.goalstack09 = this.goalstack08;
 444         this.goalstack08 = this.goalstack07;
 445         this.goalstack07 = this.goalstack06;
 446         this.goalstack06 = this.goalstack05;
 447         this.goalstack05 = this.goalstack04;
 448         this.goalstack04 = this.goalstack03;
 449         this.goalstack03 = this.goalstack02;
 450         this.goalstack02 = this.goalstack01;
 451         this.goalstack01 = this.goalcurrent;
 452         this.goalcurrent = e;
 453 }
 454
 455 // remove first goal from stack
 456 // (in other words: remove a prerequisite for reaching the later goals)
 457 // (used when a spawnfunc_waypoint is reached)
 458 void navigation_poproute(entity this)
 459 {
 460         this.goalcurrent_prev = this.goalcurrent;
 461         this.goalcurrent_distance = 10000000;
 462         this.goalcurrent_distance_time = 0;
 463         //print("bot ", etos(this), " pop\n");
 464         if(this.goalcurrent == this.goalentity)
 465                 this.goalentity = NULL;
 466         this.goalcurrent = this.goalstack01;
 467         this.goalstack01 = this.goalstack02;
 468         this.goalstack02 = this.goalstack03;
 469         this.goalstack03 = this.goalstack04;
 470         this.goalstack04 = this.goalstack05;
 471         this.goalstack05 = this.goalstack06;
 472         this.goalstack06 = this.goalstack07;
 473         this.goalstack07 = this.goalstack08;
 474         this.goalstack08 = this.goalstack09;
 475         this.goalstack09 = this.goalstack10;
 476         this.goalstack10 = this.goalstack11;
 477         this.goalstack11 = this.goalstack12;
 478         this.goalstack12 = this.goalstack13;
 479         this.goalstack13 = this.goalstack14;
 480         this.goalstack14 = this.goalstack15;
 481         this.goalstack15 = this.goalstack16;
 482         this.goalstack16 = this.goalstack17;
 483         this.goalstack17 = this.goalstack18;
 484         this.goalstack18 = this.goalstack19;
 485         this.goalstack19 = this.goalstack20;
 486         this.goalstack20 = this.goalstack21;
 487         this.goalstack21 = this.goalstack22;
 488         this.goalstack22 = this.goalstack23;
 489         this.goalstack23 = this.goalstack24;
 490         this.goalstack24 = this.goalstack25;
 491         this.goalstack25 = this.goalstack26;
 492         this.goalstack26 = this.goalstack27;
 493         this.goalstack27 = this.goalstack28;
 494         this.goalstack28 = this.goalstack29;
 495         this.goalstack29 = this.goalstack30;
 496         this.goalstack30 = this.goalstack31;
 497         this.goalstack31 = NULL;
 498 }
 499
 500 // walking to wp (walkfromwp == false) v2 and v2_height will be used as
 501 // waypoint destination coordinates instead of v (only useful for box waypoints)
 502 // for normal waypoints v2 == v and v2_height == 0
 503 float navigation_waypoint_will_link(vector v, vector org, entity ent, vector v2, float v2_height, float walkfromwp, float bestdist)
 504 {
 505         if (vdist(v - org, <, bestdist))
 506         {
 507                 traceline(v, org, true, ent);
 508                 if (trace_fraction == 1)
 509                 {
 510                         if (walkfromwp)
 511                         {
 512                                 if (tracewalk(ent, v, PL_MIN_CONST, PL_MAX_CONST, org, 0, bot_navigation_movemode))
 513                                         return true;
 514                         }
 515                         else
 516                         {
 517                                 if (tracewalk(ent, org, PL_MIN_CONST, PL_MAX_CONST, v2, v2_height, bot_navigation_movemode))
 518                                         return true;
 519                         }
 520                 }
 521         }
 522         return false;
 523 }
 524
 525 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
 526 entity navigation_findnearestwaypoint_withdist_except(entity ent, float walkfromwp, float bestdist, entity except)
 527 {
 528         vector pm1 = ent.origin + ent.mins;
 529         vector pm2 = ent.origin + ent.maxs;
 530
 531         // do two scans, because box test is cheaper
 532         IL_EACH(g_waypoints, it != ent && it != except,
 533         {
 534                 if(boxesoverlap(pm1, pm2, it.absmin, it.absmax))
 535                         return it;
 536         });
 537
 538         vector org = ent.origin + 0.5 * (ent.mins + ent.maxs);
 539         org.z = ent.origin.z + ent.mins.z - PL_MIN_CONST.z; // player height
 540         // TODO possibly make other code have the same support for bboxes
 541         if(ent.tag_entity)
 542                 org = org + ent.tag_entity.origin;
 543         if (navigation_testtracewalk)
 544                 te_plasmaburn(org);
 545
 546         entity best = NULL;
 547         vector v;
 548
 549         if(!autocvar_g_waypointeditor && !ent.navigation_dynamicgoal)
 550         {
 551                 waypoint_clearlinks(ent); // initialize wpXXmincost fields
 552                 IL_EACH(g_waypoints, it != ent,
 553                 {
 554                         if(walkfromwp && (it.wpflags & WAYPOINTFLAG_NORELINK))
 555                                 continue;
 556
 557                         vector v2;
 558                         float v2_height;
 559                         if(it.wpisbox)
 560                         {
 561                                 vector wm1 = it.origin + it.mins;
 562                                 vector wm2 = it.origin + it.maxs;
 563                                 v.x = bound(wm1_x, org.x, wm2_x);
 564                                 v.y = bound(wm1_y, org.y, wm2_y);
 565                                 v.z = bound(wm1_z, org.z, wm2_z);
 566                                 v2.x = v.x;
 567                                 v2.y = v.y;
 568                                 v2.z = wm1.z;
 569                                 v2_height = wm2.z - wm1.z;
 570                         }
 571                         else
 572                         {
 573                                 v = it.origin;
 574                                 v2 = v;
 575                                 v2_height = 0;
 576                         }
 577                         if(navigation_waypoint_will_link(v, org, ent, v2, v2_height, walkfromwp, 1050))
 578                                 navigation_item_addlink(it, ent);
 579                 });
 580         }
 581
 582         // box check failed, try walk
 583         IL_EACH(g_waypoints, it != ent,
 584         {
 585                 if(walkfromwp && (it.wpflags & WAYPOINTFLAG_NORELINK))
 586                         continue;
 587
 588                 vector v2;
 589                 float v2_height;
 590                 if(it.wpisbox)
 591                 {
 592                         vector wm1 = it.origin + it.mins;
 593                         vector wm2 = it.origin + it.maxs;
 594                         v.x = bound(wm1_x, org.x, wm2_x);
 595                         v.y = bound(wm1_y, org.y, wm2_y);
 596                         v.z = bound(wm1_z, org.z, wm2_z);
 597                         v2.x = v.x;
 598                         v2.y = v.y;
 599                         v2.z = wm1.z;
 600                         v2_height = wm2.z - wm1.z;
 601                 }
 602                 else
 603                 {
 604                         v = it.origin;
 605                         v2 = v;
 606                         v2_height = 0;
 607                 }
 608                 if(navigation_waypoint_will_link(v, org, ent, v2, v2_height, walkfromwp, bestdist))
 609                 {
 610                         bestdist = vlen(v - org);
 611                         best = it;
 612                 }
 613         });
 614         return best;
 615 }
 616 entity navigation_findnearestwaypoint(entity ent, float walkfromwp)
 617 {
 618         entity wp = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, NULL);
 619         if (autocvar_g_waypointeditor_auto)
 620         {
 621                 entity wp2 = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, wp);
 622                 if (wp && !wp2)
 623                         wp.wpflags |= WAYPOINTFLAG_PROTECTED;
 624         }
 625         return wp;
 626 }
 627
 628 // finds the waypoints near the bot initiating a navigation query
 629 float navigation_markroutes_nearestwaypoints(entity this, float maxdist)
 630 {
 631         vector v, m1, m2;
 632         //navigation_testtracewalk = true;
 633         int c = 0;
 634         float v_height;
 635         IL_EACH(g_waypoints, !it.wpconsidered,
 636         {
 637                 if (it.wpisbox)
 638                 {
 639                         m1 = it.origin + it.mins;
 640                         m2 = it.origin + it.maxs;
 641                         v = this.origin;
 642                         v.x = bound(m1_x, v.x, m2_x);
 643                         v.y = bound(m1_y, v.y, m2_y);
 644                         v.z = m1.z;
 645                         v_height = m2.z - m1.z;
 646                 }
 647                 else
 648                 {
 649                         v = it.origin;
 650                         v_height = 0;
 651                 }
 652                 vector diff = v - this.origin;
 653                 diff.z = max(0, diff.z);
 654                 if(vdist(diff, <, maxdist))
 655                 {
 656                         it.wpconsidered = true;
 657                         if (tracewalk(this, this.origin, this.mins, this.maxs, v, v_height, bot_navigation_movemode))
 658                         {
 659                                 it.wpnearestpoint = v;
 660                                 it.wpcost = waypoint_gettravelcost(this.origin, v) + it.dmg;
 661                                 it.wpfire = 1;
 662                                 it.enemy = NULL;
 663                                 c = c + 1;
 664                         }
 665                 }
 666         });
 667         //navigation_testtracewalk = false;
 668         return c;
 669 }
 670
 671 // updates a path link if a spawnfunc_waypoint link is better than the current one
 672 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost, vector p)
 673 {
 674         vector m1;
 675         vector m2;
 676         vector v;
 677         if (wp.wpisbox)
 678         {
 679                 m1 = wp.absmin;
 680                 m2 = wp.absmax;
 681                 v.x = bound(m1_x, p.x, m2_x);
 682                 v.y = bound(m1_y, p.y, m2_y);
 683                 v.z = bound(m1_z, p.z, m2_z);
 684         }
 685         else
 686                 v = wp.origin;
 687         if (w.wpflags & WAYPOINTFLAG_TELEPORT)
 688                 cost += w.wp00mincost; // assuming teleport has exactly one destination
 689         else
 690                 cost += waypoint_gettravelcost(p, v);
 691         if (wp.wpcost > cost)
 692         {
 693                 wp.wpcost = cost;
 694                 wp.enemy = w;
 695                 wp.wpfire = 1;
 696                 wp.wpnearestpoint = v;
 697         }
 698 }
 699
 700 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
 701 void navigation_markroutes(entity this, entity fixed_source_waypoint)
 702 {
 703         float cost, cost2;
 704         vector p;
 705
 706         IL_EACH(g_waypoints, true,
 707         {
 708                 it.wpconsidered = false;
 709                 it.wpnearestpoint = '0 0 0';
 710                 it.wpcost = 10000000;
 711                 it.wpfire = 0;
 712                 it.enemy = NULL;
 713         });
 714
 715         if(fixed_source_waypoint)
 716         {
 717                 fixed_source_waypoint.wpconsidered = true;
 718                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 719                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg;
 720                 fixed_source_waypoint.wpfire = 1;
 721                 fixed_source_waypoint.enemy = NULL;
 722         }
 723         else
 724         {
 725                 // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
 726                 // as this search is expensive we will use lower values if the bot is on the air
 727                 float increment, maxdistance;
 728                 if(IS_ONGROUND(this))
 729                 {
 730                         increment = 750;
 731                         maxdistance = 50000;
 732                 }
 733                 else
 734                 {
 735                         increment = 500;
 736                         maxdistance = 1500;
 737                 }
 738
 739                 for(int j = increment; !navigation_markroutes_nearestwaypoints(this, j) && j < maxdistance; j += increment);
 740         }
 741
 742         bool searching = true;
 743         while (searching)
 744         {
 745                 searching = false;
 746                 IL_EACH(g_waypoints, it.wpfire,
 747                 {
 748                         searching = true;
 749                         it.wpfire = 0;
 750                         cost = it.wpcost;
 751                         p = it.wpnearestpoint;
 752                         entity wp;
 753                         wp = it.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp00mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 754                         wp = it.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp01mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 755                         wp = it.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp02mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 756                         wp = it.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp03mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 757                         wp = it.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp04mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 758                         wp = it.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp05mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 759                         wp = it.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp06mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 760                         wp = it.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp07mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 761                         wp = it.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp08mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 762                         wp = it.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp09mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 763                         wp = it.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp10mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 764                         wp = it.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp11mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 765                         wp = it.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp12mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 766                         wp = it.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp13mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 767                         wp = it.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp14mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 768                         wp = it.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp15mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 769                         wp = it.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp16mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 770                         wp = it.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp17mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 771                         wp = it.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp18mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 772                         wp = it.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp19mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 773                         wp = it.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp20mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 774                         wp = it.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp21mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 775                         wp = it.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp22mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 776                         wp = it.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp23mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 777                         wp = it.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp24mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 778                         wp = it.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp25mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 779                         wp = it.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp26mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 780                         wp = it.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp27mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 781                         wp = it.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp28mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 782                         wp = it.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp29mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 783                         wp = it.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp30mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 784                         wp = it.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp31mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 785                         }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
 786                 });
 787         }
 788 }
 789
 790 // queries the entire spawnfunc_waypoint network for pathes leading to the bot
 791 void navigation_markroutes_inverted(entity fixed_source_waypoint)
 792 {
 793         float cost, cost2;
 794         vector p;
 795         IL_EACH(g_waypoints, true,
 796         {
 797                 it.wpconsidered = false;
 798                 it.wpnearestpoint = '0 0 0';
 799                 it.wpcost = 10000000;
 800                 it.wpfire = 0;
 801                 it.enemy = NULL;
 802         });
 803
 804         if(fixed_source_waypoint)
 805         {
 806                 fixed_source_waypoint.wpconsidered = true;
 807                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 808                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg; // the cost to get from X to fixed_source_waypoint
 809                 fixed_source_waypoint.wpfire = 1;
 810                 fixed_source_waypoint.enemy = NULL;
 811         }
 812         else
 813         {
 814                 error("need to start with a waypoint\n");
 815         }
 816
 817         bool searching = true;
 818         while (searching)
 819         {
 820                 searching = false;
 821                 IL_EACH(g_waypoints, it.wpfire,
 822                 {
 823                         searching = true;
 824                         it.wpfire = 0;
 825                         cost = it.wpcost; // cost to walk from it to home
 826                         p = it.wpnearestpoint;
 827                         entity wp = it;
 828                         IL_EACH(g_waypoints, it != wp,
 829                         {
 830                                 if(!waypoint_islinked(it, wp))
 831                                         continue;
 832                                 cost2 = cost + it.dmg;
 833                                 navigation_markroutes_checkwaypoint(wp, it, cost2, p);
 834                         });
 835                 });
 836         }
 837 }
 838
 839 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
 840 void navigation_routerating(entity this, entity e, float f, float rangebias)
 841 {
 842         if (!e)
 843                 return;
 844
 845         if(e.blacklisted)
 846                 return;
 847
 848         rangebias = waypoint_getlinearcost(rangebias);
 849         f = waypoint_getlinearcost(f);
 850
 851         if (IS_PLAYER(e))
 852         {
 853                 bool rate_wps = false;
 854                 if((e.flags & FL_INWATER) || (e.flags & FL_PARTIALGROUND))
 855                         rate_wps = true;
 856
 857                 if(!IS_ONGROUND(e))
 858                 {
 859                         traceline(e.origin, e.origin + '0 0 -1500', true, NULL);
 860                         int t = pointcontents(trace_endpos + '0 0 1');
 861                         if(t != CONTENT_SOLID )
 862                         {
 863                                 if(t == CONTENT_WATER || t == CONTENT_SLIME || t == CONTENT_LAVA)
 864                                         rate_wps = true;
 865                                 else if(tracebox_hits_trigger_hurt(e.origin, e.mins, e.maxs, trace_endpos))
 866                                         return;
 867                         }
 868                 }
 869
 870                 if(rate_wps)
 871                 {
 872                         entity theEnemy = e;
 873                         entity best_wp = NULL;
 874                         float best_dist = 10000;
 875                         IL_EACH(g_waypoints, vdist(it.origin - theEnemy.origin, <, 500)
 876                                 && vdist(it.origin - this.origin, >, 100)
 877                                 && !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 878                         {
 879                                 float dist = vlen(it.origin - theEnemy.origin);
 880                                 if (dist < best_dist)
 881                                 {
 882                                         best_wp = it;
 883                                         best_dist = dist;
 884                                 }
 885                         });
 886                         if (!best_wp)
 887                                 return;
 888                         e = best_wp;
 889                 }
 890         }
 891
 892         vector goal_org = (e.absmin + e.absmax) * 0.5;
 893
 894         //print("routerating ", etos(e), " = ", ftos(f), " - ", ftos(rangebias), "\n");
 895
 896         // Evaluate path using jetpack
 897         if(g_jetpack)
 898         if(this.items & IT_JETPACK)
 899         if(autocvar_bot_ai_navigation_jetpack)
 900         if(vdist(this.origin - goal_org, >, autocvar_bot_ai_navigation_jetpack_mindistance))
 901         {
 902                 vector pointa, pointb;
 903
 904                 LOG_DEBUG("jetpack ai: evaluating path for ", e.classname);
 905
 906                 // Point A
 907                 traceline(this.origin, this.origin + '0 0 65535', MOVE_NORMAL, this);
 908                 pointa = trace_endpos - '0 0 1';
 909
 910                 // Point B
 911                 traceline(goal_org, goal_org + '0 0 65535', MOVE_NORMAL, e);
 912                 pointb = trace_endpos - '0 0 1';
 913
 914                 // Can I see these two points from the sky?
 915                 traceline(pointa, pointb, MOVE_NORMAL, this);
 916
 917                 if(trace_fraction==1)
 918                 {
 919                         LOG_DEBUG("jetpack ai: can bridge these two points");
 920
 921                         // Lower the altitude of these points as much as possible
 922                         float zdistance, xydistance, cost, t, fuel;
 923                         vector down, npa, npb;
 924
 925                         down = '0 0 -1' * (STAT(PL_MAX, this).z - STAT(PL_MIN, this).z) * 10;
 926
 927                         do{
 928                                 npa = pointa + down;
 929                                 npb = pointb + down;
 930
 931                                 if(npa.z<=this.absmax.z)
 932                                         break;
 933
 934                                 if(npb.z<=e.absmax.z)
 935                                         break;
 936
 937                                 traceline(npa, npb, MOVE_NORMAL, this);
 938                                 if(trace_fraction==1)
 939                                 {
 940                                         pointa = npa;
 941                                         pointb = npb;
 942                                 }
 943                         }
 944                         while(trace_fraction == 1);
 945
 946
 947                         // Rough estimation of fuel consumption
 948                         // (ignores acceleration and current xyz velocity)
 949                         xydistance = vlen(pointa - pointb);
 950                         zdistance = fabs(pointa.z - this.origin.z);
 951
 952                         t = zdistance / autocvar_g_jetpack_maxspeed_up;
 953                         t += xydistance / autocvar_g_jetpack_maxspeed_side;
 954                         fuel = t * autocvar_g_jetpack_fuel * 0.8;
 955
 956                         LOG_DEBUG("jetpack ai: required fuel ", ftos(fuel), " this.ammo_fuel ", ftos(this.ammo_fuel));
 957
 958                         // enough fuel ?
 959                         if(this.ammo_fuel>fuel)
 960                         {
 961                                 // Estimate cost
 962                                 // (as onground costs calculation is mostly based on distances, here we do the same establishing some relationship
 963                                 //  - between air and ground speeds)
 964
 965                                 cost = xydistance / (autocvar_g_jetpack_maxspeed_side/autocvar_sv_maxspeed);
 966                                 cost += zdistance / (autocvar_g_jetpack_maxspeed_up/autocvar_sv_maxspeed);
 967                                 cost *= 1.5;
 968
 969                                 // Compare against other goals
 970                                 f = f * rangebias / (rangebias + cost);
 971
 972                                 if (navigation_bestrating < f)
 973                                 {
 974                                         LOG_DEBUG("jetpack path: added goal ", e.classname, " (with rating ", ftos(f), ")");
 975                                         navigation_bestrating = f;
 976                                         navigation_bestgoal = e;
 977                                         this.navigation_jetpack_goal = e;
 978                                         this.navigation_jetpack_point = pointb;
 979                                 }
 980                                 return;
 981                         }
 982                 }
 983         }
 984
 985         entity nwp;
 986         //te_wizspike(e.origin);
 987         //bprint(etos(e));
 988         //bprint("\n");
 989         // update the cached spawnfunc_waypoint link on a dynamic item entity
 990         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
 991         {
 992                 nwp = e;
 993         }
 994         else
 995         {
 996                 if(autocvar_g_waypointeditor && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
 997                         e.nearestwaypoint = NULL;
 998
 999                 if ((!e.nearestwaypoint || e.navigation_dynamicgoal)
1000                         && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
1001                 {
1002                         nwp = navigation_findnearestwaypoint(e, true);
1003                         if(nwp)
1004                         {
1005                                 e.nearestwaypoint = nwp;
1006
1007                                 vector m1 = nwp.absmin, m2 = nwp.absmax;
1008                                 m1.x = nwp.origin.x; m1.y = nwp.origin.y;
1009                                 m2.x = nwp.origin.x; m2.y = nwp.origin.y;
1010                                 vector ve = (e.absmin - e.absmax) * 0.5;
1011                                 ve.x = bound(m1.x, ve.x, m2.x);
1012                                 ve.y = bound(m1.y, ve.y, m2.y);
1013                                 ve.z = bound(m1.z, ve.z, m2.z);
1014
1015                                 m1 = e.absmin; m2 = e.absmax;
1016                                 m1.x = e.origin.x; m1.y = e.origin.y;
1017                                 m2.x = e.origin.x; m2.y = e.origin.y;
1018                                 vector vnwp = nwp.origin;
1019                                 vnwp.x = bound(m1.x, vnwp.x, m2.x);
1020                                 vnwp.y = bound(m1.y, vnwp.y, m2.y);
1021                                 vnwp.z = bound(m1.z, vnwp.z, m2.z);
1022                                 e.nearestwaypoint_dist = vlen(ve - vnwp);
1023                         }
1024                         else
1025                         {
1026                                 LOG_DEBUG("FAILED to find a nearest waypoint to '", e.classname, "' #", etos(e));
1027
1028                                 if(!e.navigation_dynamicgoal)
1029                                         e.blacklisted = true;
1030
1031                                 if(e.blacklisted)
1032                                 {
1033                                         LOG_DEBUG("The entity '", e.classname, "' is going to be excluded from path finding during this match");
1034                                         return;
1035                                 }
1036                         }
1037
1038                         if(e.navigation_dynamicgoal)
1039                                 e.nearestwaypointtimeout = time + 2;
1040                         else if(autocvar_g_waypointeditor)
1041                                 e.nearestwaypointtimeout = time + 3 + random() * 2;
1042                 }
1043                 nwp = e.nearestwaypoint;
1044         }
1045
1046         LOG_DEBUG("-- checking ", e.classname, " (with cost ", ftos(nwp.wpcost), ")");
1047         if (nwp)
1048         if (nwp.wpcost < 10000000)
1049         {
1050                 //te_wizspike(nwp.wpnearestpoint);
1051                 float cost = nwp.wpcost + waypoint_gettravelcost(nwp.wpnearestpoint, goal_org);
1052                 LOG_DEBUG(e.classname, " ", ftos(f), "/(1+", ftos(cost), "/", ftos(rangebias), ") = ");
1053                 f = f * rangebias / (rangebias + cost);
1054                 LOG_DEBUG("considering ", e.classname, " (with rating ", ftos(f), ")");
1055                 if (navigation_bestrating < f)
1056                 {
1057                         LOG_DEBUG("ground path: added goal ", e.classname, " (with rating ", ftos(f), ")");
1058                         navigation_bestrating = f;
1059                         navigation_bestgoal = e;
1060                 }
1061         }
1062 }
1063
1064 // adds an item to the the goal stack with the path to a given item
1065 bool navigation_routetogoal(entity this, entity e, vector startposition)
1066 {
1067         // if there is no goal, just exit
1068         if (!e)
1069                 return false;
1070
1071         if(e.wpflags & WAYPOINTFLAG_TELEPORT)
1072         {
1073                 // force teleport destination as route destination
1074                 e.wp00.enemy = e;
1075                 e = e.wp00;
1076         }
1077
1078         this.goalentity = e;
1079
1080         // put the entity on the goal stack
1081         //print("routetogoal ", etos(e), "\n");
1082         navigation_pushroute(this, e);
1083
1084         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
1085         {
1086                 this.wp_goal_prev1 = this.wp_goal_prev0;
1087                 this.wp_goal_prev0 = e;
1088         }
1089
1090         if(g_jetpack)
1091         if(e==this.navigation_jetpack_goal)
1092                 return true;
1093
1094         // if it can reach the goal there is nothing more to do
1095         vector dest = (e.absmin + e.absmax) * 0.5;
1096         dest.z = e.absmin.z;
1097         float dest_height = e.absmax.z - e.absmin.z;
1098         if (tracewalk(this, startposition, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1099                 return true;
1100
1101         entity nearest_wp = NULL;
1102         // see if there are waypoints describing a path to the item
1103         if(e.classname != "waypoint" || (e.wpflags & WAYPOINTFLAG_PERSONAL))
1104         {
1105                 e = e.nearestwaypoint;
1106                 nearest_wp = e;
1107         }
1108         else
1109                 e = e.enemy; // we already have added it, so...
1110
1111         if(e == NULL)
1112                 return false;
1113
1114         if(nearest_wp && nearest_wp.enemy)
1115         {
1116                 // often path can be optimized by not adding the nearest waypoint
1117                 if (this.goalentity.nearestwaypoint_dist < 8)
1118                         e = nearest_wp.enemy;
1119                 else
1120                 {
1121                         if (this.goalentity.navigation_dynamicgoal)
1122                         {
1123                                 vector dest = (this.goalentity.absmin + this.goalentity.absmax) * 0.5;
1124                                 dest.z = this.goalentity.absmin.z;
1125                                 float dest_height = this.goalentity.absmax.z - this.goalentity.absmin.z;
1126                                 if(tracewalk(this, nearest_wp.enemy.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1127                                         e = nearest_wp.enemy;
1128                         }
1129                         else if(navigation_item_islinked(nearest_wp.enemy, this.goalentity))
1130                                 e = nearest_wp.enemy;
1131                 }
1132         }
1133
1134         for (;;)
1135         {
1136                 // add the spawnfunc_waypoint to the path
1137                 navigation_pushroute(this, e);
1138                 e = e.enemy;
1139
1140                 if(e==NULL)
1141                         break;
1142         }
1143
1144         return false;
1145 }
1146
1147 // removes any currently touching waypoints from the goal stack
1148 // (this is how bots detect if they reached a goal)
1149 void navigation_poptouchedgoals(entity this)
1150 {
1151         if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1152         {
1153                 // make sure jumppad is really hit, don't rely on distance based checks
1154                 // as they may report a touch even if it didn't really happen
1155                 if(this.lastteleporttime > 0
1156                         && time - this.lastteleporttime < ((this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL) ? 2 : 0.15))
1157                 {
1158                         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1159                         if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1160                         {
1161                                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1162                                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1163                         }
1164                         navigation_poproute(this);
1165                 }
1166                 else
1167                         return;
1168         }
1169
1170         // If for some reason the bot is closer to the next goal, pop the current one
1171         if(this.goalstack01 && !wasfreed(this.goalstack01))
1172         if(vlen2(this.goalcurrent.origin - this.origin) > vlen2(this.goalstack01.origin - this.origin))
1173         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
1174         {
1175                 vector dest = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
1176                 dest.z = this.goalstack01.absmin.z;
1177                 float dest_height = this.goalstack01.absmax.z - this.goalstack01.absmin.z;
1178                 if(tracewalk(this, this.origin, this.mins, this.maxs, dest, dest_height, bot_navigation_movemode))
1179                 {
1180                         LOG_DEBUG("path optimized for ", this.netname, ", removed a goal from the queue");
1181                         navigation_poproute(this);
1182                         // TODO this may also be a nice idea to do "early" (e.g. by
1183                         // manipulating the vlen() comparisons) to shorten paths in
1184                         // general - this would make bots walk more "on rails" than
1185                         // "zigzagging" which they currently do with sufficiently
1186                         // random-like waypoints, and thus can make a nice bot
1187                         // personality property
1188                 }
1189         }
1190
1191         // Loose goal touching check when running
1192         if(this.aistatus & AI_STATUS_RUNNING)
1193         if(this.goalcurrent.classname=="waypoint")
1194         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
1195         {
1196                 if(vdist(this.origin - this.goalcurrent.origin, <, 150))
1197                 {
1198                         traceline(this.origin + this.view_ofs , this.goalcurrent.origin, true, NULL);
1199                         if(trace_fraction==1)
1200                         {
1201                                 // Detect personal waypoints
1202                                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1203                                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1204                                 {
1205                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1206                                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1207                                 }
1208
1209                                 navigation_poproute(this);
1210                         }
1211                 }
1212         }
1213
1214         while (this.goalcurrent && !IS_PLAYER(this.goalcurrent))
1215         {
1216                 vector gc_min = this.goalcurrent.absmin;
1217                 vector gc_max = this.goalcurrent.absmax;
1218                 if(this.goalcurrent.classname == "waypoint" && !this.goalcurrent.wpisbox)
1219                 {
1220                         gc_min = this.goalcurrent.origin - '1 1 1' * 12;
1221                         gc_max = this.goalcurrent.origin + '1 1 1' * 12;
1222                 }
1223                 if(!boxesoverlap(this.absmin, this.absmax, gc_min, gc_max))
1224                         break;
1225
1226                 // Detect personal waypoints
1227                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1228                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1229                 {
1230                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1231                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1232                 }
1233
1234                 navigation_poproute(this);
1235         }
1236 }
1237
1238 // begin a goal selection session (queries spawnfunc_waypoint network)
1239 void navigation_goalrating_start(entity this)
1240 {
1241         if(this.aistatus & AI_STATUS_STUCK)
1242                 return;
1243
1244         this.navigation_jetpack_goal = NULL;
1245         navigation_bestrating = -1;
1246         navigation_clearroute(this);
1247         navigation_bestgoal = NULL;
1248         navigation_markroutes(this, NULL);
1249 }
1250
1251 // ends a goal selection session (updates goal stack to the best goal)
1252 void navigation_goalrating_end(entity this)
1253 {
1254         if(this.aistatus & AI_STATUS_STUCK)
1255                 return;
1256
1257         navigation_routetogoal(this, navigation_bestgoal, this.origin);
1258         LOG_DEBUG("best goal ", this.goalcurrent.classname);
1259
1260         // If the bot got stuck then try to reach the farthest waypoint
1261         if (!this.goalentity && autocvar_bot_wander_enable)
1262         {
1263                 if (!(this.aistatus & AI_STATUS_STUCK))
1264                 {
1265                         LOG_DEBUG(this.netname, " cannot walk to any goal");
1266                         this.aistatus |= AI_STATUS_STUCK;
1267                 }
1268         }
1269 }
1270
1271 void botframe_updatedangerousobjects(float maxupdate)
1272 {
1273         vector m1, m2, v, o;
1274         float c, d, danger;
1275         c = 0;
1276         IL_EACH(g_waypoints, true,
1277         {
1278                 danger = 0;
1279                 m1 = it.absmin;
1280                 m2 = it.absmax;
1281                 IL_EACH(g_bot_dodge, it.bot_dodge,
1282                 {
1283                         v = it.origin;
1284                         v.x = bound(m1_x, v.x, m2_x);
1285                         v.y = bound(m1_y, v.y, m2_y);
1286                         v.z = bound(m1_z, v.z, m2_z);
1287                         o = (it.absmin + it.absmax) * 0.5;
1288                         d = waypoint_getlinearcost(it.bot_dodgerating) - waypoint_gettravelcost(o, v);
1289                         if (d > 0)
1290                         {
1291                                 traceline(o, v, true, NULL);
1292                                 if (trace_fraction == 1)
1293                                         danger = danger + d;
1294                         }
1295                 });
1296                 it.dmg = danger;
1297                 c = c + 1;
1298                 if (c >= maxupdate)
1299                         break;
1300         });
1301 }
1302
1303 void navigation_unstuck(entity this)
1304 {
1305         float search_radius = 1000;
1306
1307         if (!autocvar_bot_wander_enable)
1308                 return;
1309
1310         if (!bot_waypoint_queue_owner)
1311         {
1312                 LOG_DEBUG(this.netname, " stuck, taking over the waypoints queue");
1313                 bot_waypoint_queue_owner = this;
1314                 bot_waypoint_queue_bestgoal = NULL;
1315                 bot_waypoint_queue_bestgoalrating = 0;
1316         }
1317
1318         if(bot_waypoint_queue_owner!=this)
1319                 return;
1320
1321         if (bot_waypoint_queue_goal)
1322         {
1323                 // evaluate the next goal on the queue
1324                 float d = vlen2(this.origin - bot_waypoint_queue_goal.origin);
1325                 LOG_DEBUG(this.netname, " evaluating ", bot_waypoint_queue_goal.classname, " with distance ", ftos(d));
1326                 vector dest = (bot_waypoint_queue_goal.absmin + bot_waypoint_queue_goal.absmax) * 0.5;
1327                 dest.z = bot_waypoint_queue_goal.absmin.z;
1328                 float dest_height = bot_waypoint_queue_goal.absmax.z - bot_waypoint_queue_goal.absmin.z;
1329                 if(tracewalk(bot_waypoint_queue_goal, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1330                 {
1331                         if( d > bot_waypoint_queue_bestgoalrating)
1332                         {
1333                                 bot_waypoint_queue_bestgoalrating = d;
1334                                 bot_waypoint_queue_bestgoal = bot_waypoint_queue_goal;
1335                         }
1336                 }
1337                 bot_waypoint_queue_goal = bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal;
1338
1339                 if (!bot_waypoint_queue_goal)
1340                 {
1341                         if (bot_waypoint_queue_bestgoal)
1342                         {
1343                                 LOG_DEBUG(this.netname, " stuck, reachable waypoint found, heading to it");
1344                                 navigation_routetogoal(this, bot_waypoint_queue_bestgoal, this.origin);
1345                                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1346                                 this.aistatus &= ~AI_STATUS_STUCK;
1347                         }
1348                         else
1349                         {
1350                                 LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1351                         }
1352
1353                         bot_waypoint_queue_owner = NULL;
1354                 }
1355         }
1356         else
1357         {
1358                 if(bot_strategytoken!=this)
1359                         return;
1360
1361                 // build a new queue
1362                 LOG_DEBUG(this.netname, " stuck, scanning reachable waypoints within ", ftos(search_radius)," qu");
1363
1364                 entity first = NULL;
1365
1366                 FOREACH_ENTITY_RADIUS(this.origin, search_radius, it.classname == "waypoint" && !(it.wpflags & WAYPOINTFLAG_GENERATED),
1367                 {
1368                         if(bot_waypoint_queue_goal)
1369                                 bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = it;
1370                         else
1371                                 first = it;
1372
1373                         bot_waypoint_queue_goal = it;
1374                         bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = NULL;
1375                 });
1376
1377                 if (first)
1378                         bot_waypoint_queue_goal = first;
1379                 else
1380                 {
1381                         LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1382                         bot_waypoint_queue_owner = NULL;
1383                 }
1384         }
1385 }
1386
1387 // Support for debugging tracewalk visually
1388
1389 void debugresetnodes()
1390 {
1391         debuglastnode = '0 0 0';
1392 }
1393
1394 void debugnode(entity this, vector node)
1395 {
1396         if (!IS_PLAYER(this))
1397                 return;
1398
1399         if(debuglastnode=='0 0 0')
1400         {
1401                 debuglastnode = node;
1402                 return;
1403         }
1404
1405         te_lightning2(NULL, node, debuglastnode);
1406         debuglastnode = node;
1407 }
1408
1409 void debugnodestatus(vector position, float status)
1410 {
1411         vector c;
1412
1413         switch (status)
1414         {
1415                 case DEBUG_NODE_SUCCESS:
1416                         c = '0 15 0';
1417                         break;
1418                 case DEBUG_NODE_WARNING:
1419                         c = '15 15 0';
1420                         break;
1421                 case DEBUG_NODE_FAIL:
1422                         c = '15 0 0';
1423                         break;
1424                 default:
1425                         c = '15 15 15';
1426         }
1427
1428         te_customflash(position, 40,  2, c);
1429 }
1430
1431 // Support for debugging the goal stack visually
1432
1433 .float goalcounter;
1434 .vector lastposition;
1435
1436 // Debug the goal stack visually
1437 void debuggoalstack(entity this)
1438 {
1439         entity goal;
1440         vector org, go;
1441
1442         if(this.goalcounter==0)goal=this.goalcurrent;
1443         else if(this.goalcounter==1)goal=this.goalstack01;
1444         else if(this.goalcounter==2)goal=this.goalstack02;
1445         else if(this.goalcounter==3)goal=this.goalstack03;
1446         else if(this.goalcounter==4)goal=this.goalstack04;
1447         else if(this.goalcounter==5)goal=this.goalstack05;
1448         else if(this.goalcounter==6)goal=this.goalstack06;
1449         else if(this.goalcounter==7)goal=this.goalstack07;
1450         else if(this.goalcounter==8)goal=this.goalstack08;
1451         else if(this.goalcounter==9)goal=this.goalstack09;
1452         else if(this.goalcounter==10)goal=this.goalstack10;
1453         else if(this.goalcounter==11)goal=this.goalstack11;
1454         else if(this.goalcounter==12)goal=this.goalstack12;
1455         else if(this.goalcounter==13)goal=this.goalstack13;
1456         else if(this.goalcounter==14)goal=this.goalstack14;
1457         else if(this.goalcounter==15)goal=this.goalstack15;
1458         else if(this.goalcounter==16)goal=this.goalstack16;
1459         else if(this.goalcounter==17)goal=this.goalstack17;
1460         else if(this.goalcounter==18)goal=this.goalstack18;
1461         else if(this.goalcounter==19)goal=this.goalstack19;
1462         else if(this.goalcounter==20)goal=this.goalstack20;
1463         else if(this.goalcounter==21)goal=this.goalstack21;
1464         else if(this.goalcounter==22)goal=this.goalstack22;
1465         else if(this.goalcounter==23)goal=this.goalstack23;
1466         else if(this.goalcounter==24)goal=this.goalstack24;
1467         else if(this.goalcounter==25)goal=this.goalstack25;
1468         else if(this.goalcounter==26)goal=this.goalstack26;
1469         else if(this.goalcounter==27)goal=this.goalstack27;
1470         else if(this.goalcounter==28)goal=this.goalstack28;
1471         else if(this.goalcounter==29)goal=this.goalstack29;
1472         else if(this.goalcounter==30)goal=this.goalstack30;
1473         else if(this.goalcounter==31)goal=this.goalstack31;
1474         else goal=NULL;
1475
1476         if(goal==NULL)
1477         {
1478                 this.goalcounter = 0;
1479                 this.lastposition='0 0 0';
1480                 return;
1481         }
1482
1483         if(this.lastposition=='0 0 0')
1484                 org = this.origin;
1485         else
1486                 org = this.lastposition;
1487
1488
1489         go = ( goal.absmin + goal.absmax ) * 0.5;
1490         te_lightning2(NULL, org, go);
1491         this.lastposition = go;
1492
1493         this.goalcounter++;
1494 }