qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "roles.qh"
   4
   5 #include <server/defs.qh>
   6 #include <server/miscfunctions.qh>
   7 #include <server/weapons/selection.qh>
   8 #include <server/weapons/weaponsystem.qh>
   9 #include "../cvars.qh"
  10
  11 #include "../aim.qh"
  12 #include "../bot.qh"
  13 #include "../navigation.qh"
  14 #include "../scripting.qh"
  15 #include "../waypoints.qh"
  16
  17 #include <common/constants.qh>
  18 #include <common/impulses/all.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/physics/player.qh>
  21 #include <common/state.qh>
  22 #include <common/items/_mod.qh>
  23 #include <common/wepent.qh>
  24
  25 #include <common/mapobjects/func/ladder.qh>
  26 #include <common/mapobjects/teleporters.qh>
  27 #include <common/mapobjects/trigger/hurt.qh>
  28 #include <common/mapobjects/trigger/jumppads.qh>
  29
  30 #include <lib/warpzone/common.qh>
  31
  32 void havocbot_ai(entity this)
  33 {
  34         if(this.draggedby)
  35                 return;
  36
  37         this.bot_aimdir_executed = false;
  38         // lock aim if teleported or passing through a warpzone
  39         if (this.lastteleporttime && !this.jumppadcount)
  40                 this.bot_aimdir_executed = true;
  41
  42         if(bot_execute_commands(this))
  43                 return;
  44
  45         if (bot_strategytoken == this && !bot_strategytoken_taken)
  46         {
  47                 if(this.havocbot_blockhead)
  48                 {
  49                         this.havocbot_blockhead = false;
  50                 }
  51                 else
  52                 {
  53                         if (!this.jumppadcount && !STAT(FROZEN, this)
  54                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP) && !IS_ONGROUND(this)))
  55                         {
  56                                 // find a new goal
  57                                 this.havocbot_role(this); // little too far down the rabbit hole
  58                         }
  59                 }
  60
  61                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  62                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  63                 if(!this.goalcurrent)
  64                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  65                 {
  66                         // Look for the closest waypoint out of water
  67                         entity newgoal = NULL;
  68                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  69                         {
  70                                 if(it.origin.z < this.origin.z)
  71                                         continue;
  72
  73                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  74                                         continue;
  75
  76                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  77                                         continue;
  78
  79                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  80
  81                                 if(trace_fraction < 1)
  82                                         continue;
  83
  84                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  85                                         newgoal = it;
  86                         });
  87
  88                         if(newgoal)
  89                         {
  90                         //      te_wizspike(newgoal.origin);
  91                                 navigation_pushroute(this, newgoal);
  92                         }
  93                 }
  94
  95                 // token has been used this frame
  96                 bot_strategytoken_taken = true;
  97         }
  98
  99         if (this.goalcurrent && wasfreed(this.goalcurrent))
 100         {
 101                 navigation_clearroute(this);
 102                 navigation_goalrating_timeout_force(this);
 103                 return;
 104         }
 105
 106         if(IS_DEAD(this) || STAT(FROZEN, this))
 107         {
 108                 if (this.goalcurrent)
 109                         navigation_clearroute(this);
 110                 this.enemy = NULL;
 111                 this.bot_aimtarg = NULL;
 112                 return;
 113         }
 114
 115         havocbot_chooseenemy(this);
 116
 117         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 118         {
 119                 .entity weaponentity = weaponentities[slot];
 120                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 121                 if(this.(weaponentity).bot_chooseweapontime < time)
 122                 {
 123                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 124                         havocbot_chooseweapon(this, weaponentity);
 125                 }
 126         }
 127         havocbot_aim(this);
 128         lag_update(this);
 129
 130         if (this.bot_aimtarg)
 131         {
 132                 this.aistatus |= AI_STATUS_ATTACKING;
 133                 this.aistatus &= ~AI_STATUS_ROAMING;
 134
 135                 if(STAT(WEAPONS, this))
 136                 {
 137                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 138                         {
 139                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 140                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 141                         }
 142                         else
 143                         {
 144                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 145                                 {
 146                                         .entity weaponentity = weaponentities[slot];
 147                                         Weapon w = this.(weaponentity).m_weapon;
 148                                         if(w == WEP_Null && slot != 0)
 149                                                 continue;
 150                                         w.wr_aim(w, this, weaponentity);
 151                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 152                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 153                                 }
 154                         }
 155                 }
 156                 else
 157                 {
 158                         if(IS_PLAYER(this.bot_aimtarg))
 159                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 160                 }
 161         }
 162         else if (this.goalcurrent)
 163         {
 164                 this.aistatus |= AI_STATUS_ROAMING;
 165                 this.aistatus &= ~AI_STATUS_ATTACKING;
 166         }
 167
 168         havocbot_movetogoal(this);
 169         if (!this.bot_aimdir_executed && this.goalcurrent)
 170         {
 171                 // Heading
 172                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 173                 dir -= this.origin + this.view_ofs;
 174                 dir.z = 0;
 175                 bot_aimdir(this, dir, 0);
 176         }
 177
 178         // if the bot is not attacking, consider reloading weapons
 179         if (!(this.aistatus & AI_STATUS_ATTACKING))
 180         {
 181                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 182                 {
 183                         .entity weaponentity = weaponentities[slot];
 184
 185                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 186                                 continue;
 187
 188                         // we are currently holding a weapon that's not fully loaded, reload it
 189                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 190                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 191                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 192
 193                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 194                         // the code above executes next frame, starting the reloading then
 195                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 196                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 197                         {
 198                                 FOREACH(Weapons, it != WEP_Null, {
 199                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 200                                         {
 201                                                 this.(weaponentity).m_switchweapon = it;
 202                                                 break;
 203                                         }
 204                                 });
 205                         }
 206                 }
 207         }
 208 }
 209
 210 void havocbot_bunnyhop(entity this, vector dir)
 211 {
 212         bool can_run = false;
 213         if (!(this.aistatus & AI_STATUS_ATTACKING) && this.goalcurrent && !IS_PLAYER(this.goalcurrent)
 214                 && vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed) && !(this.aistatus & AI_STATUS_DANGER_AHEAD)
 215                 && this.waterlevel <= WATERLEVEL_WETFEET && !IS_DUCKED(this)
 216                 && IS_ONGROUND(this) && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
 217         {
 218                 vector vel_angles = vectoangles(this.velocity);
 219                 vector deviation = vel_angles - vectoangles(dir);
 220                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 221                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 222                 if (fabs(deviation.y) < autocvar_bot_ai_bunnyhop_dir_deviation_max)
 223                 {
 224                         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 225                         float vel = vlen(vec2(this.velocity));
 226
 227                         // with the current physics, jump distance grows linearly with the speed
 228                         float jump_distance = 52.661 + 0.606 * vel;
 229                         jump_distance += this.origin.z - gco.z; // roughly take into account vertical distance too
 230                         if (vdist(vec2(gco - this.origin), >, max(0, jump_distance)))
 231                                 can_run = true;
 232                         else if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP)
 233                                 && !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 234                                 && this.goalstack01 && !wasfreed(this.goalstack01) && !(this.goalstack01.wpflags & WAYPOINTFLAG_JUMP)
 235                                 && vdist(vec2(gco - this.goalstack01.origin), >, 70))
 236                         {
 237                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 238                                 vector ang = vectoangles(gco - this.origin);
 239                                 deviation = vectoangles(gno - gco) - vel_angles;
 240                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 241                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 242
 243                                 float max_turn_angle = autocvar_bot_ai_bunnyhop_turn_angle_max;
 244                                 max_turn_angle -= autocvar_bot_ai_bunnyhop_turn_angle_reduction * ((vel - autocvar_sv_maxspeed) / autocvar_sv_maxspeed);
 245                                 if ((ang.x < 90 || ang.x > 360 - autocvar_bot_ai_bunnyhop_downward_pitch_max)
 246                                         && fabs(deviation.y) < max(autocvar_bot_ai_bunnyhop_turn_angle_min, max_turn_angle))
 247                                 {
 248                                         can_run = true;
 249                                 }
 250                         }
 251                 }
 252         }
 253
 254         if (can_run)
 255         {
 256                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 257                 this.bot_jump_time = time;
 258                 this.aistatus |= AI_STATUS_RUNNING;
 259         }
 260         else
 261         {
 262                 if (IS_ONGROUND(this) || this.waterlevel > WATERLEVEL_WETFEET)
 263                         this.aistatus &= ~AI_STATUS_RUNNING;
 264         }
 265 }
 266
 267 void havocbot_keyboard_movement(entity this, vector destorg)
 268 {
 269         if(time <= this.havocbot_keyboardtime)
 270                 return;
 271
 272         float sk = skill + this.bot_moveskill;
 273         this.havocbot_keyboardtime =
 274                 max(
 275                         this.havocbot_keyboardtime
 276                                 + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 277                                 + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 278                 , time);
 279         vector keyboard = CS(this).movement / autocvar_sv_maxspeed;
 280
 281         float trigger = autocvar_bot_ai_keyboard_threshold;
 282
 283         // categorize forward movement
 284         // at skill < 1.5 only forward
 285         // at skill < 2.5 only individual directions
 286         // at skill < 4.5 only individual directions, and forward diagonals
 287         // at skill >= 4.5, all cases allowed
 288         if (keyboard.x > trigger)
 289         {
 290                 keyboard.x = 1;
 291                 if (sk < 2.5)
 292                         keyboard.y = 0;
 293         }
 294         else if (keyboard.x < -trigger && sk > 1.5)
 295         {
 296                 keyboard.x = -1;
 297                 if (sk < 4.5)
 298                         keyboard.y = 0;
 299         }
 300         else
 301         {
 302                 keyboard.x = 0;
 303                 if (sk < 1.5)
 304                         keyboard.y = 0;
 305         }
 306         if (sk < 4.5)
 307                 keyboard.z = 0;
 308
 309         if (keyboard.y > trigger)
 310                 keyboard.y = 1;
 311         else if (keyboard.y < -trigger)
 312                 keyboard.y = -1;
 313         else
 314                 keyboard.y = 0;
 315
 316         if (keyboard.z > trigger)
 317                 keyboard.z = 1;
 318         else if (keyboard.z < -trigger)
 319                 keyboard.z = -1;
 320         else
 321                 keyboard.z = 0;
 322
 323         // make sure bots don't get stuck if havocbot_keyboardtime is very high
 324         if (keyboard == '0 0 0')
 325                 this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 326
 327         this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 328         if (this.havocbot_ducktime > time)
 329                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 330
 331         keyboard = this.havocbot_keyboard;
 332         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 333         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 334         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 335 }
 336
 337 // return true when bot isn't getting closer to the current goal
 338 bool havocbot_checkgoaldistance(entity this, vector gco)
 339 {
 340         if (this.bot_stop_moving_timeout > time)
 341                 return false;
 342         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 343         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 344         float distance_time = this.goalcurrent_distance_time;
 345         if(distance_time < 0)
 346                 distance_time = -distance_time;
 347         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 348         {
 349                 if(!distance_time)
 350                         this.goalcurrent_distance_time = time;
 351                 else if (time - distance_time > 0.5)
 352                         return true;
 353         }
 354         else
 355         {
 356                 // reduce it a little bit so it works even with very small approaches to the goal
 357                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 358                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 359                 this.goalcurrent_distance_time = 0;
 360         }
 361         return false;
 362 }
 363
 364 entity havocbot_select_an_item_of_group(entity this, int gr)
 365 {
 366         entity selected = NULL;
 367         float selected_dist2 = 0;
 368         // select farthest item of this group from bot's position
 369         IL_EACH(g_items, it.item_group == gr && it.solid,
 370         {
 371                 float dist2 = vlen2(this.origin - it.origin);
 372                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 373                 {
 374                         selected = it;
 375                         selected_dist2 = vlen2(this.origin - selected.origin);
 376                 }
 377         });
 378
 379         if (!selected)
 380                 return NULL;
 381
 382         set_tracewalk_dest(selected, this.origin, false);
 383         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 384                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 385         {
 386                 return NULL;
 387         }
 388
 389         return selected;
 390 }
 391
 392 void havocbot_movetogoal(entity this)
 393 {
 394         vector diff;
 395         vector dir;
 396         vector flatdir;
 397         float dodge_enemy_factor = 1;
 398         float maxspeed;
 399         //float dist;
 400         vector dodge;
 401         //if (this.goalentity)
 402         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 403         CS(this).movement = '0 0 0';
 404         maxspeed = autocvar_sv_maxspeed;
 405
 406         PHYS_INPUT_BUTTON_CROUCH(this) = boolean(this.goalcurrent.wpflags & WAYPOINTFLAG_CROUCH);
 407
 408         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 409         // Jetpack navigation
 410         if(this.navigation_jetpack_goal)
 411         if(this.goalcurrent==this.navigation_jetpack_goal)
 412         if(GetResource(this, RES_FUEL))
 413         {
 414                 if(autocvar_bot_debug_goalstack)
 415                 {
 416                         debuggoalstack(this);
 417                         te_wizspike(this.navigation_jetpack_point);
 418                 }
 419
 420                 // Take off
 421                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 422                 {
 423                         // Brake almost completely so it can get a good direction
 424                         if(vdist(this.velocity, >, 10))
 425                                 return;
 426                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 427                 }
 428
 429                 makevectors(this.v_angle.y * '0 1 0');
 430                 dir = normalize(this.navigation_jetpack_point - this.origin);
 431
 432                 // Landing
 433                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 434                 {
 435                         // Calculate brake distance in xy
 436                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 437                         float vel2 = vlen2(vec2(this.velocity));
 438                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 439                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 440                         if(d < db || d < 500)
 441                         {
 442                                 // Brake
 443                                 if (vel2 > (maxspeed * 0.3) ** 2)
 444                                 {
 445                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 446                                         return;
 447                                 }
 448                                 // Switch to normal mode
 449                                 this.navigation_jetpack_goal = NULL;
 450                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 451                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 452                                 return;
 453                         }
 454                 }
 455                 else if(checkpvs(this.origin,this.goalcurrent))
 456                 {
 457                         // If I can see the goal switch to landing code
 458                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 459                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 460                         return;
 461                 }
 462
 463                 // Flying
 464                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 465                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 466                 {
 467                         CS(this).movement_x = dir * v_forward * maxspeed;
 468                         CS(this).movement_y = dir * v_right * maxspeed;
 469                 }
 470                 return;
 471         }
 472
 473         // Handling of jump pads
 474         if(this.jumppadcount)
 475         {
 476                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 477                 {
 478                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 479                         if(navigation_poptouchedgoals(this))
 480                                 return;
 481                 }
 482                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 483                 {
 484                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 485                         // but with some randomness so it can try out different paths
 486                         if(!this.goalcurrent)
 487                         {
 488                                 entity newgoal = NULL;
 489                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 490                                 {
 491                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 492                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 493                                                 continue;
 494
 495                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 496
 497                                         if(trace_fraction < 1)
 498                                                 continue;
 499
 500                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 501                                                 newgoal = it;
 502                                 });
 503
 504                                 if(newgoal)
 505                                 {
 506                                         this.ignoregoal = this.goalcurrent;
 507                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 508                                         navigation_clearroute(this);
 509                                         navigation_routetogoal(this, newgoal, this.origin);
 510                                         if(autocvar_bot_debug_goalstack)
 511                                                 debuggoalstack(this);
 512                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 513                                 }
 514                         }
 515                         else //if (this.goalcurrent)
 516                         {
 517                                 if (this.goalcurrent.bot_pickup)
 518                                 {
 519                                         entity jumppad_wp = this.goalcurrent_prev;
 520                                         navigation_poptouchedgoals(this);
 521                                         if(!this.goalcurrent && jumppad_wp.wp00)
 522                                         {
 523                                                 // head to the jumppad destination once bot reaches the goal item
 524                                                 navigation_pushroute(this, jumppad_wp.wp00);
 525                                         }
 526                                 }
 527                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 528                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 529                                 {
 530                                         if (this.velocity.z < 0)
 531                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 532                                 }
 533                                 else if(havocbot_checkgoaldistance(this, gco))
 534                                 {
 535                                         navigation_clearroute(this);
 536                                         navigation_goalrating_timeout_force(this);
 537                                 }
 538                                 else
 539                                         return;
 540                         }
 541                 }
 542                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 543                 {
 544                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 545                         {
 546                                 vector velxy = this.velocity; velxy_z = 0;
 547                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 548                                 {
 549                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 550                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 551                                 }
 552                                 return;
 553                         }
 554
 555                         // Don't chase players while using a jump pad
 556                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 557                                 return;
 558                 }
 559         }
 560         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 561                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 562
 563         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 564         if (skill > 6 && !(IS_ONGROUND(this)))
 565         {
 566                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 567                         * ((STAT(STRENGTH_FINISHED, this) > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 568                         * ((STAT(INVINCIBLE_FINISHED, this) > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 569
 570                 // save some CPU cycles by checking trigger_hurt after checking
 571                 // that something can be done to evade it (cheaper checks)
 572                 int action_for_trigger_hurt = 0;
 573                 if (this.items & IT_JETPACK)
 574                         action_for_trigger_hurt = 1;
 575                 else if (!this.jumppadcount && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
 576                         && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
 577                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 578                 {
 579                         action_for_trigger_hurt = 2;
 580                 }
 581                 else if (!this.goalcurrent)
 582                         action_for_trigger_hurt = 3;
 583
 584                 if (action_for_trigger_hurt)
 585                 {
 586                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 587                         if(!tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos))
 588                                 action_for_trigger_hurt = 0;
 589                 }
 590
 591                 if(action_for_trigger_hurt == 1) // jetpack
 592                 {
 593                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 594                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 595                         {
 596                                 if(this.velocity.z<0)
 597                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 598                         }
 599                         else
 600                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 601
 602                         // If there is no goal try to move forward
 603
 604                         if(this.goalcurrent==NULL)
 605                                 dir = v_forward;
 606                         else
 607                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 608
 609                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 610                         float xyspeed = xyvelocity * dir;
 611
 612                         if(xyspeed < (maxspeed / 2))
 613                         {
 614                                 makevectors(this.v_angle.y * '0 1 0');
 615                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 616                                 if(trace_fraction==1)
 617                                 {
 618                                         CS(this).movement_x = dir * v_forward * maxspeed;
 619                                         CS(this).movement_y = dir * v_right * maxspeed;
 620                                         if (skill < 10)
 621                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 622                                 }
 623                         }
 624
 625                         this.havocbot_blockhead = true;
 626
 627                         return;
 628                 }
 629                 else if(action_for_trigger_hurt == 2) // rocketjump
 630                 {
 631                         if(this.velocity.z < 0)
 632                         {
 633                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 634                                 {
 635                                         .entity weaponentity = weaponentities[slot];
 636
 637                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 638                                                 continue;
 639
 640                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 641                                         {
 642                                                 CS(this).movement_x = maxspeed;
 643
 644                                                 if(this.rocketjumptime)
 645                                                 {
 646                                                         if(time > this.rocketjumptime)
 647                                                         {
 648                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 649                                                                 this.rocketjumptime = 0;
 650                                                         }
 651                                                         return;
 652                                                 }
 653
 654                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 655                                                 this.v_angle_x = 90;
 656                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 657                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 658                                                 return;
 659                                         }
 660                                 }
 661                         }
 662                 }
 663                 else if(action_for_trigger_hurt == 3) // no goal
 664                 {
 665                         // If there is no goal try to move forward
 666                         CS(this).movement_x = maxspeed;
 667                 }
 668         }
 669
 670         // If we are under water with no goals, swim up
 671         if(this.waterlevel && !this.goalcurrent)
 672         {
 673                 dir = '0 0 0';
 674                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 675                         dir.z = 1;
 676                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 677                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 678                 makevectors(this.v_angle.y * '0 1 0');
 679                 vector v = dir * maxspeed;
 680                 CS(this).movement.x = v * v_forward;
 681                 CS(this).movement.y = v * v_right;
 682                 CS(this).movement.z = v * v_up;
 683         }
 684
 685         // if there is nowhere to go, exit
 686         if (this.goalcurrent == NULL)
 687                 return;
 688
 689
 690         bool locked_goal = false;
 691         if((this.goalentity && wasfreed(this.goalentity))
 692                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 693         {
 694                 navigation_clearroute(this);
 695                 navigation_goalrating_timeout_force(this);
 696                 return;
 697         }
 698         else if(this.goalentity.tag_entity)
 699         {
 700                 navigation_goalrating_timeout_expire(this, 2);
 701         }
 702         else if(this.goalentity.bot_pickup)
 703         {
 704                 if(this.goalentity.bot_pickup_respawning)
 705                 {
 706                         if(this.goalentity.solid) // item respawned
 707                                 this.goalentity.bot_pickup_respawning = false;
 708                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 709                         {
 710                                 if(checkpvs(this.origin, this.goalentity))
 711                                 {
 712                                         this.goalentity.bot_pickup_respawning = false;
 713                                         navigation_goalrating_timeout_expire(this, random());
 714                                 }
 715                                 locked_goal = true; // wait for item to respawn
 716                         }
 717                         else if(this.goalentity == this.goalcurrent)
 718                                 locked_goal = true; // wait for item to respawn
 719                 }
 720                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 721                 {
 722                         if(checkpvs(this.origin, this.goalentity))
 723                         {
 724                                 navigation_goalrating_timeout_expire(this, random());
 725                         }
 726                 }
 727         }
 728         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 729                 locked_goal = true;
 730
 731         if (navigation_shortenpath(this))
 732         {
 733                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 734                         && navigation_goalrating_timeout_can_be_anticipated(this))
 735                 {
 736                         navigation_goalrating_timeout_force(this);
 737                 }
 738         }
 739
 740         bool goalcurrent_can_be_removed = false;
 741         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 742         {
 743                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 744                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 745                 {
 746                         goalcurrent_can_be_removed = true;
 747                         // don't remove if not visible
 748                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 749                         {
 750                                 if (IS_DEAD(this.goalcurrent))
 751                                 {
 752                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 753                                         {
 754                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 755                                                 {
 756                                                         navigation_clearroute(this);
 757                                                         navigation_pushroute(this, it);
 758                                                         // loot can't be immediately rated since it isn't on ground yet
 759                                                         // it will be rated after a second when on ground, meanwhile head to it
 760                                                         navigation_goalrating_timeout_expire(this, 1);
 761                                                         return;
 762                                                 }
 763                                         });
 764                                 }
 765                                 if (!Item_IsLoot(this.goalcurrent))
 766                                 {
 767                                         navigation_goalrating_timeout_force(this);
 768                                         return;
 769                                 }
 770                         }
 771                 }
 772                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 773                 {
 774                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 775                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 776                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 777                         {
 778                                 navigation_goalrating_timeout_force(this);
 779                                 return;
 780                         }
 781                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 782                 }
 783         }
 784
 785         if(!locked_goal)
 786         {
 787                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 788                 // in this case path finding can start directly from a waypoint instead of
 789                 // looking for all the reachable waypoints up to a certain distance
 790                 if (navigation_poptouchedgoals(this))
 791                 {
 792                         if (this.goalcurrent)
 793                         {
 794                                 if (goalcurrent_can_be_removed)
 795                                 {
 796                                         // remove even if not visible
 797                                         navigation_goalrating_timeout_force(this);
 798                                         return;
 799                                 }
 800                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 801                                         navigation_goalrating_timeout_force(this);
 802                         }
 803                         else
 804                         {
 805                                 entity old_goal = this.goalcurrent_prev;
 806                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 807                                 {
 808                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 809                                         // item of the group by telling the bot to head directly to the farthest item.
 810                                         // Next time we let the bot select a goal as usual which can be another item
 811                                         // of this group (the closest one) and so on
 812                                         this.item_group = old_goal.item_group;
 813                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 814                                         if (new_goal)
 815                                                 navigation_pushroute(this, new_goal);
 816                                 }
 817                         }
 818                 }
 819         }
 820
 821         // if ran out of goals try to use an alternative goal or get a new strategy asap
 822         if(this.goalcurrent == NULL)
 823         {
 824                 navigation_goalrating_timeout_force(this);
 825                 return;
 826         }
 827
 828
 829         if(autocvar_bot_debug_goalstack)
 830                 debuggoalstack(this);
 831
 832         bool bunnyhop_forbidden = false;
 833         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 834         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 835         {
 836                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 837                 destorg = this.goalcurrent.origin;
 838         }
 839         else if (this.goalcurrent.wpisbox)
 840         {
 841                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 842                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 843                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 844                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 845                 {
 846                         bunnyhop_forbidden = true;
 847                         destorg = this.goalcurrent.origin;
 848                         if(destorg.z > this.origin.z)
 849                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 850                 }
 851         }
 852
 853         diff = destorg - this.origin;
 854
 855         if (time < this.bot_stop_moving_timeout
 856                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 857         {
 858                 // stop if the locked goal has been reached
 859                 destorg = this.origin;
 860                 diff = dir = '0 0 0';
 861         }
 862         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 863         {
 864                 if (vdist(diff, <, 80))
 865                 {
 866                         // stop if too close to target player (even if frozen)
 867                         destorg = this.origin;
 868                         diff = dir = '0 0 0';
 869                 }
 870                 else
 871                 {
 872                         // move destorg out of target players, otherwise bot will consider them
 873                         // an obstacle that needs to be jumped (especially if frozen)
 874                         dir = normalize(diff);
 875                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 876                         diff = destorg - this.origin;
 877                 }
 878         }
 879         else
 880                 dir = normalize(diff);
 881         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 882
 883         bool danger_detected = false;
 884         vector do_break = '0 0 0';
 885
 886         //if (this.bot_dodgevector_time < time)
 887         {
 888                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 889                 //this.bot_dodgevector_jumpbutton = 1;
 890
 891                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 892                 makevectors(this.v_angle.y * '0 1 0');
 893                 if (this.waterlevel > WATERLEVEL_WETFEET)
 894                 {
 895                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 896                         {
 897                                 if(!this.goalcurrent)
 898                                         this.aistatus |= AI_STATUS_OUT_WATER;
 899                                 else if(destorg.z > this.origin.z)
 900                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 901                         }
 902                         else
 903                         {
 904                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 905                                         (this.aistatus & AI_STATUS_OUT_WATER))
 906                                 {
 907                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 908                                         dir = flatdir;
 909                                 }
 910                                 else
 911                                 {
 912                                         if (destorg.z > this.origin.z)
 913                                                 dir = flatdir;
 914                                 }
 915                         }
 916                 }
 917                 else
 918                 {
 919                         float s;
 920                         vector offset;
 921                         if(this.aistatus & AI_STATUS_OUT_WATER)
 922                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 923
 924                         // jump if going toward an obstacle that doesn't look like stairs we
 925                         // can walk up directly
 926                         vector deviation = '0 0 0';
 927                         float current_speed = vlen(vec2(this.velocity));
 928                         if (current_speed < maxspeed * 0.2)
 929                                 current_speed = maxspeed * 0.2;
 930                         else
 931                         {
 932                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 933                                 while (deviation.y < -180) deviation.y += 360;
 934                                 while (deviation.y > 180) deviation.y -= 360;
 935                         }
 936                         float turning = false;
 937                         vector flat_diff = vec2(diff);
 938                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 939                         vector actual_destorg = this.origin + offset;
 940                         if (this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP))
 941                         {
 942                                 if (time > this.bot_stop_moving_timeout
 943                                         && fabs(deviation.y) > 20 && current_speed > maxspeed * 0.4
 944                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 50))
 945                                 {
 946                                         this.bot_stop_moving_timeout = time + 0.1;
 947                                 }
 948                                 if (current_speed > autocvar_sv_maxspeed * 0.9
 949                                         && vlen2(flat_diff) < vlen2(vec2(this.goalcurrent_prev.origin - destorg))
 950                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), >, 50)
 951                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 150)
 952                                 )
 953                                 {
 954                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 955                                         this.bot_jump_time = time;
 956                                 }
 957                         }
 958                         else if (!this.goalstack01 || (this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER)))
 959                         {
 960                                 if (vlen2(flat_diff) < vlen2(offset))
 961                                 {
 962                                         if ((this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP) && this.goalstack01)
 963                                         {
 964                                                 // oblique warpzones need a jump otherwise bots gets stuck
 965                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 966                                         }
 967                                         else
 968                                         {
 969                                                 actual_destorg.x = destorg.x;
 970                                                 actual_destorg.y = destorg.y;
 971                                         }
 972                                 }
 973                         }
 974                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 975                         {
 976                                 actual_destorg.x = destorg.x;
 977                                 actual_destorg.y = destorg.y;
 978                         }
 979                         else if (vlen2(flat_diff) < vlen2(offset))
 980                         {
 981                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 982                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 983                                 float dist = vlen(vec2(this.origin + offset - destorg));
 984                                 // if current and next goal are close to each other make sure
 985                                 // actual_destorg isn't set beyond next_goal_org
 986                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
 987                                         actual_destorg = next_goal_org;
 988                                 else
 989                                         actual_destorg = vec2(destorg) + dist * next_dir;
 990                                 actual_destorg.z = this.origin.z;
 991                                 turning = true;
 992                         }
 993
 994                         LABEL(jumpobstacle_check);
 995                         dir = flatdir = normalize(actual_destorg - this.origin);
 996
 997                         bool jump_forbidden = false;
 998                         if (!turning && fabs(deviation.y) > 50)
 999                                 jump_forbidden = true;
1000                         else if (IS_DUCKED(this))
1001                         {
1002                                 tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, false, this);
1003                                 if (trace_startsolid)
1004                                         jump_forbidden = true;
1005                         }
1006
1007                         if (!jump_forbidden)
1008                         {
1009                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1010                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1011                                 {
1012                                         s = trace_fraction;
1013                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1014                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1015                                         {
1016                                                 // found an obstacle
1017                                                 if (turning && fabs(deviation.y) > 5)
1018                                                 {
1019                                                         // check if the obstacle is still there without turning
1020                                                         actual_destorg = destorg;
1021                                                         turning = false;
1022                                                         this.bot_tracewalk_time = time + 0.25;
1023                                                         goto jumpobstacle_check;
1024                                                 }
1025                                                 s = trace_fraction;
1026                                                 // don't artificially reduce max jump height in real-time
1027                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1028                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1029                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1030                                                 if (trace_fraction > s)
1031                                                 {
1032                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1033                                                         this.bot_jump_time = time;
1034                                                 }
1035                                                 else
1036                                                 {
1037                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1038                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1039                                                         if (trace_fraction > s)
1040                                                         {
1041                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1042                                                                 this.bot_jump_time = time;
1043                                                         }
1044                                                 }
1045                                         }
1046                                 }
1047                         }
1048
1049                         // if bot for some reason doesn't get close to the current goal find another one
1050                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1051                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1052                         if(havocbot_checkgoaldistance(this, destorg))
1053                         {
1054                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1055                                 {
1056                                         navigation_clearroute(this);
1057                                         navigation_goalrating_timeout_force(this);
1058                                         return;
1059                                 }
1060
1061                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1062                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1063                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1064                                 {
1065                                         navigation_clearroute(this);
1066                                         navigation_goalrating_timeout_force(this);
1067                                         return;
1068                                 }
1069
1070                                 // give bot only another chance to prevent bot getting stuck
1071                                 // in case it thinks it can walk but actually can't
1072                                 this.goalcurrent_distance_z = FLOAT_MAX;
1073                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1074                                 this.goalcurrent_distance_time = -time; // mark second try
1075                         }
1076
1077                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1078                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1079                         {
1080                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1081                         }
1082
1083                         // Check for water/slime/lava and dangerous edges
1084                         // (only when the bot is on the ground or jumping intentionally)
1085
1086                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1087                         vector dst_ahead = this.origin + this.view_ofs + offset;
1088                         vector dst_down = dst_ahead - '0 0 3000';
1089                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1090
1091                         bool unreachable = false;
1092                         s = CONTENT_SOLID;
1093                         if (trace_fraction == 1 && !this.jumppadcount
1094                                 && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1095                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
1096                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1097                         {
1098                                 // Look downwards
1099                                 traceline(dst_ahead , dst_down, true, NULL);
1100                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1101                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1102                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1103                                 {
1104                                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1105                                                 danger_detected = true;
1106                                         else if (trace_endpos.z < min(this.origin.z + this.mins.z, this.goalcurrent.origin.z) - 100)
1107                                                 danger_detected = true;
1108                                         else
1109                                         {
1110                                                 s = pointcontents(trace_endpos + '0 0 1');
1111                                                 if (s != CONTENT_SOLID)
1112                                                 {
1113                                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1114                                                                 danger_detected = true;
1115                                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1116                                                         {
1117                                                                 // the traceline check isn't enough but is good as optimization,
1118                                                                 // when not true (most of the time) this tracebox call is avoided
1119                                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1120                                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1121                                                                 {
1122                                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1123                                                                         {
1124                                                                                 // the goal is probably on an upper platform, assume bot can't get there
1125                                                                                 unreachable = true;
1126                                                                         }
1127                                                                         else
1128                                                                                 danger_detected = true;
1129                                                                 }
1130                                                         }
1131                                                 }
1132                                         }
1133                                 }
1134                         }
1135
1136                         dir = flatdir;
1137                         makevectors(this.v_angle.y * '0 1 0');
1138
1139                         if (danger_detected || (s == CONTENT_WATER))
1140                         {
1141                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1142                                 if(IS_PLAYER(this.goalcurrent))
1143                                         unreachable = true;
1144                         }
1145
1146                         // slow down if bot is in the air and goal is under it
1147                         if (!waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1148                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1149                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1150                         {
1151                                 // tracebox wouldn't work when bot is still on the ledge
1152                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1153                                 if (this.origin.z - trace_endpos.z > 120)
1154                                         do_break = normalize(this.velocity) * -1;
1155                         }
1156
1157                         if(unreachable)
1158                         {
1159                                 navigation_clearroute(this);
1160                                 navigation_goalrating_timeout_force(this);
1161                                 this.ignoregoal = this.goalcurrent;
1162                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1163                         }
1164                 }
1165
1166                 dodge = havocbot_dodge(this);
1167                 if (dodge)
1168                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1169                 if (this.enemy)
1170                 {
1171                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1172                         if (IS_PLAYER(trace_ent))
1173                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1174                 }
1175         //      this.bot_dodgevector = dir;
1176         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1177         }
1178
1179         float ladder_zdir = 0;
1180         if(this.ladder_entity)
1181         {
1182                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1183                 {
1184                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1185                                 ladder_zdir = 1;
1186                 }
1187                 else
1188                 {
1189                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1190                                 ladder_zdir = -1;
1191                 }
1192                 if (ladder_zdir)
1193                 {
1194                         if (vdist(vec2(diff), <, 40))
1195                                 dir.z = ladder_zdir * 4;
1196                         else
1197                                 dir.z = ladder_zdir * 2;
1198                         dir = normalize(dir);
1199                 }
1200         }
1201
1202         if (this.goalcurrent.wpisbox
1203                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1204         {
1205                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1206                 // head to teleport origin
1207                 dir = (this.goalcurrent.origin - this.origin);
1208                 dir.z = 0;
1209                 dir = normalize(dir);
1210         }
1211
1212         // already executed when bot targets an enemy
1213         if (!this.bot_aimdir_executed)
1214         {
1215                 if (time < this.bot_stop_moving_timeout)
1216                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1217                 else
1218                         bot_aimdir(this, dir, 0);
1219         }
1220
1221         vector evadedanger = '0 0 0';
1222         if (!ladder_zdir)
1223         {
1224                 dir *= dodge_enemy_factor;
1225                 if (danger_detected && vdist(this.velocity, >, maxspeed * 0.8) && this.goalcurrent_prev
1226                         && this.goalcurrent.classname == "waypoint")
1227                 {
1228                         vector p = this.origin + this.velocity * 0.2;
1229                         vector evadedanger = point_line_vec(p, vec2(this.goalcurrent_prev.origin) + eZ * p.z,
1230                                 vec2(destorg - this.goalcurrent_prev.origin));
1231                         if (vdist(evadedanger, >, 20))
1232                         {
1233                                 if (vdist(evadedanger, >, 40))
1234                                         do_break = normalize(this.velocity) * -1;
1235                                 evadedanger = normalize(evadedanger);
1236                                 evadedanger *= bound(1, 3 - (skill + this.bot_dodgeskill), 3); // Noobs fear dangers a lot and take more distance from them
1237                         }
1238                         else
1239                                 evadedanger = '0 0 0';
1240                 }
1241                 dir = normalize(dir + dodge + do_break + evadedanger);
1242         }
1243
1244         makevectors(this.v_angle);
1245         //dir = this.bot_dodgevector;
1246         //if (this.bot_dodgevector_jumpbutton)
1247         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1248         CS(this).movement_x = dir * v_forward * maxspeed;
1249         CS(this).movement_y = dir * v_right * maxspeed;
1250         CS(this).movement_z = dir * v_up * maxspeed;
1251
1252         // Emulate keyboard interface
1253         if (skill < 10)
1254                 havocbot_keyboard_movement(this, destorg);
1255
1256         // Bunnyhop!
1257         if (!bunnyhop_forbidden && !evadedanger && !do_break && skill + this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1258                 havocbot_bunnyhop(this, dir);
1259
1260         if (dir * v_up >= autocvar_sv_jumpvelocity * 0.5 && IS_ONGROUND(this))
1261                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1262         if (dodge)
1263         {
1264                 if (dodge * v_up > 0 && random() * frametime >= 0.2 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1265                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1266                 if (dodge * v_up < 0 && random() * frametime >= 0.5 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1267                         this.havocbot_ducktime = time + 0.3 / bound(0.1, skill + this.bot_dodgeskill, 10);
1268         }
1269 }
1270
1271 entity havocbot_gettarget(entity this, bool secondary)
1272 {
1273         entity best = NULL;
1274         vector eye = CENTER_OR_VIEWOFS(this);
1275         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1276         {
1277                 vector v = CENTER_OR_VIEWOFS(it);
1278                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1279                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1280                 if(bot_shouldattack(this, it))
1281                 {
1282                         traceline(eye, v, true, this);
1283                         if (trace_ent == it || trace_fraction >= 1)
1284                                 best = it;
1285                 }
1286         });
1287
1288         return best;
1289 }
1290
1291 void havocbot_chooseenemy(entity this)
1292 {
1293         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1294         {
1295                 this.enemy = NULL;
1296                 return;
1297         }
1298
1299         if (this.enemy)
1300         {
1301                 if (!bot_shouldattack(this, this.enemy))
1302                 {
1303                         // enemy died or something, find a new target
1304                         this.enemy = NULL;
1305                         this.havocbot_chooseenemy_finished = time;
1306                 }
1307                 else if (this.havocbot_stickenemy_time && time < this.havocbot_stickenemy_time)
1308                 {
1309                         // tracking last chosen enemy
1310                         vector targ_pos = (this.enemy.absmin + this.enemy.absmax) * 0.5;
1311                         traceline(this.origin + this.view_ofs, targ_pos, false, NULL);
1312                         if (trace_ent == this.enemy || trace_fraction == 1)
1313                         if (vdist(targ_pos - this.origin, <, 1000))
1314                         {
1315                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1316                                 this.havocbot_chooseenemy_finished = time + 0.5;
1317                                 return;
1318                         }
1319
1320                         // stop preferring this enemy
1321                         this.havocbot_stickenemy_time = 0;
1322                 }
1323         }
1324         if (time < this.havocbot_chooseenemy_finished)
1325                 return;
1326         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1327         vector eye = this.origin + this.view_ofs;
1328         entity best = NULL;
1329         float bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1330
1331         // Backup hit flags
1332         int hf = this.dphitcontentsmask;
1333
1334         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1335
1336         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1337
1338         bool scan_transparent = false;
1339         bool scan_secondary_targets = false;
1340         bool have_secondary_targets = false;
1341         while(true)
1342         {
1343                 scan_secondary_targets = false;
1344 LABEL(scan_targets)
1345                 IL_EACH(g_bot_targets, it.bot_attack,
1346                 {
1347                         if(!scan_secondary_targets)
1348                         {
1349                                 if(it.classname == "misc_breakablemodel")
1350                                 {
1351                                         have_secondary_targets = true;
1352                                         continue;
1353                                 }
1354                         }
1355                         else if(it.classname != "misc_breakablemodel")
1356                                 continue;
1357
1358                         vector v = (it.absmin + it.absmax) * 0.5;
1359                         float rating = vlen2(v - eye);
1360                         if (rating < bestrating && bot_shouldattack(this, it))
1361                         {
1362                                 traceline(eye, v, true, this);
1363                                 if (trace_ent == it || trace_fraction >= 1)
1364                                 {
1365                                         best = it;
1366                                         bestrating = rating;
1367                                 }
1368                         }
1369                 });
1370
1371                 if(!best && have_secondary_targets && !scan_secondary_targets)
1372                 {
1373                         scan_secondary_targets = true;
1374                         // restart the loop
1375                         bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1376                         goto scan_targets;
1377                 }
1378
1379                 // I want to do a second scan if no enemy was found or I don't have weapons
1380                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1381                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1382                         break;
1383                 if(scan_transparent)
1384                         break;
1385
1386                 // Set flags to see through transparent objects
1387                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1388
1389                 scan_transparent = true;
1390         }
1391
1392         // Restore hit flags
1393         this.dphitcontentsmask = hf;
1394
1395         this.enemy = best;
1396         this.havocbot_stickenemy_time = time + autocvar_bot_ai_enemydetectioninterval_stickingtoenemy;
1397         if(best && best.classname == "misc_breakablemodel")
1398                 this.havocbot_stickenemy_time = 0;
1399 }
1400
1401 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1402 {
1403         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1404         // so skip this for them, or they'll never get to reload their weapons at all.
1405         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1406         if(skill < 5)
1407                 return false;
1408
1409         // if this weapon is scheduled for reloading, don't switch to it during combat
1410         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1411         {
1412                 FOREACH(Weapons, it != WEP_Null, {
1413                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1414                                 return true; // other weapon available
1415                 });
1416         }
1417
1418         return false;
1419 }
1420
1421 void havocbot_chooseweapon(entity this, .entity weaponentity)
1422 {
1423         int i;
1424
1425         // ;)
1426         if(g_weaponarena_weapons == WEPSET(TUBA))
1427         {
1428                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1429                 return;
1430         }
1431
1432         // TODO: clean this up by moving it to weapon code
1433         if(this.enemy==NULL)
1434         {
1435                 // If no weapon was chosen get the first available weapon
1436                 if(this.(weaponentity).m_weapon==WEP_Null)
1437                 FOREACH(Weapons, it != WEP_Null, {
1438                         if(client_hasweapon(this, it, weaponentity, true, false))
1439                         {
1440                                 this.(weaponentity).m_switchweapon = it;
1441                                 return;
1442                         }
1443                 });
1444                 return;
1445         }
1446
1447         // Do not change weapon during the next second after a combo
1448         float f = time - this.lastcombotime;
1449         if(f < 1)
1450                 return;
1451
1452         float w;
1453         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1454
1455         // Should it do a weapon combo?
1456         float af, ct, combo_time, combo;
1457
1458         af = ATTACK_FINISHED(this, weaponentity);
1459         ct = autocvar_bot_ai_weapon_combo_threshold;
1460
1461         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1462         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1463         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1464
1465         combo = false;
1466
1467         if(autocvar_bot_ai_weapon_combo)
1468         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1469         if(af > combo_time)
1470         {
1471                 combo = true;
1472                 this.lastcombotime = time;
1473         }
1474
1475         distance *= (2 ** this.bot_rangepreference);
1476
1477         // Custom weapon list based on distance to the enemy
1478         if(bot_custom_weapon){
1479
1480                 // Choose weapons for far distance
1481                 if ( distance > bot_distance_far ) {
1482                         for(i=0; i < REGISTRY_COUNT(Weapons) && bot_weapons_far[i] != -1 ; ++i){
1483                                 w = bot_weapons_far[i];
1484                                 if ( client_hasweapon(this, REGISTRY_GET(Weapons, w), weaponentity, true, false) )
1485                                 {
1486                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1487                                                 continue;
1488                                         this.(weaponentity).m_switchweapon = REGISTRY_GET(Weapons, w);
1489                                         return;
1490                                 }
1491                         }
1492                 }
1493
1494                 // Choose weapons for mid distance
1495                 if ( distance > bot_distance_close) {
1496                         for(i=0; i < REGISTRY_COUNT(Weapons) && bot_weapons_mid[i] != -1 ; ++i){
1497                                 w = bot_weapons_mid[i];
1498                                 if ( client_hasweapon(this, REGISTRY_GET(Weapons, w), weaponentity, true, false) )
1499                                 {
1500                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1501                                                 continue;
1502                                         this.(weaponentity).m_switchweapon = REGISTRY_GET(Weapons, w);
1503                                         return;
1504                                 }
1505                         }
1506                 }
1507
1508                 // Choose weapons for close distance
1509                 for(i=0; i < REGISTRY_COUNT(Weapons) && bot_weapons_close[i] != -1 ; ++i){
1510                         w = bot_weapons_close[i];
1511                         if ( client_hasweapon(this, REGISTRY_GET(Weapons, w), weaponentity, true, false) )
1512                         {
1513                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1514                                         continue;
1515                                 this.(weaponentity).m_switchweapon = REGISTRY_GET(Weapons, w);
1516                                 return;
1517                         }
1518                 }
1519         }
1520 }
1521
1522 void havocbot_aim(entity this)
1523 {
1524         if (time < this.nextaim)
1525                 return;
1526         this.nextaim = time + 0.1;
1527         vector myvel = this.velocity;
1528         if (!this.waterlevel)
1529                 myvel.z = 0;
1530         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1531         else if (this.enemy)
1532         {
1533                 vector enemyvel = this.enemy.velocity;
1534                 if (!this.enemy.waterlevel)
1535                         enemyvel.z = 0;
1536                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1537         }
1538         else
1539                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1540 }
1541
1542 bool havocbot_moveto_refresh_route(entity this)
1543 {
1544         // Refresh path to goal if necessary
1545         entity wp;
1546         wp = this.havocbot_personal_waypoint;
1547         navigation_goalrating_start(this);
1548         navigation_routerating(this, wp, 10000, 10000);
1549         navigation_goalrating_end(this);
1550         return (this.goalentity != NULL);
1551 }
1552
1553 float havocbot_moveto(entity this, vector pos)
1554 {
1555         entity wp;
1556
1557         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1558         {
1559                 // Step 4: Move to waypoint
1560                 if(this.havocbot_personal_waypoint==NULL)
1561                 {
1562                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1563                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1564                         return CMD_STATUS_ERROR;
1565                 }
1566
1567                 if (!bot_strategytoken_taken)
1568                 if(this.havocbot_personal_waypoint_searchtime<time)
1569                 {
1570                         bot_strategytoken_taken = true;
1571                         if(havocbot_moveto_refresh_route(this))
1572                         {
1573                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1574                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1575                                 this.havocbot_personal_waypoint_failcounter = 0;
1576                         }
1577                         else
1578                         {
1579                                 this.havocbot_personal_waypoint_failcounter += 1;
1580                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1581                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1582                                 {
1583                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1584                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1585                                         delete(this.havocbot_personal_waypoint);
1586                                         return CMD_STATUS_ERROR;
1587                                 }
1588                                 else
1589                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1590                         }
1591                 }
1592
1593                 if(autocvar_bot_debug_goalstack)
1594                         debuggoalstack(this);
1595
1596
1597                 // Go!
1598                 havocbot_movetogoal(this);
1599
1600                 if (!this.bot_aimdir_executed && this.goalcurrent)
1601                 {
1602                         // Heading
1603                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1604                         dir -= this.origin + this.view_ofs;
1605                         dir.z = 0;
1606                         bot_aimdir(this, dir, 0);
1607                 }
1608
1609                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1610                 {
1611                         // Step 5: Waypoint reached
1612                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1613                         waypoint_remove(this.havocbot_personal_waypoint);
1614                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1615                         return CMD_STATUS_FINISHED;
1616                 }
1617
1618                 return CMD_STATUS_EXECUTING;
1619         }
1620
1621         // Step 2: Linking waypoint
1622         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1623         {
1624                 // Wait until it is linked
1625                 if(!this.havocbot_personal_waypoint.wplinked)
1626                 {
1627                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1628                         return CMD_STATUS_EXECUTING;
1629                 }
1630
1631                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1632                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1633                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1634
1635                 // Step 3: Route to waypoint
1636                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1637
1638                 return CMD_STATUS_EXECUTING;
1639         }
1640
1641         // Step 1: Spawning waypoint
1642         wp = waypoint_spawnpersonal(this, pos);
1643         if(wp==NULL)
1644         {
1645                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1646                 return CMD_STATUS_ERROR;
1647         }
1648
1649         this.havocbot_personal_waypoint = wp;
1650         this.havocbot_personal_waypoint_failcounter = 0;
1651         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1652
1653         // if pos is inside a teleport, then let's mark it as teleport waypoint
1654         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1655         {
1656                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1657                 this.lastteleporttime = 0;
1658         });
1659
1660 /*
1661         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1662                 print("routing to a teleporter\n");
1663         else
1664                 print("routing to a non-teleporter\n");
1665 */
1666
1667         return CMD_STATUS_EXECUTING;
1668 }
1669
1670 float havocbot_resetgoal(entity this)
1671 {
1672         navigation_clearroute(this);
1673         return CMD_STATUS_FINISHED;
1674 }
1675
1676 void havocbot_setupbot(entity this)
1677 {
1678         this.bot_ai = havocbot_ai;
1679         this.cmd_moveto = havocbot_moveto;
1680         this.cmd_resetgoal = havocbot_resetgoal;
1681
1682         // NOTE: bot is not player yet
1683         havocbot_chooserole(this);
1684 }
1685
1686 vector havocbot_dodge(entity this)
1687 {
1688         // LordHavoc: disabled because this is too expensive
1689         return '0 0 0';
1690 #if 0
1691         entity head;
1692         vector dodge, v, n;
1693         float danger, bestdanger, vl, d;
1694         dodge = '0 0 0';
1695         bestdanger = -20;
1696         // check for dangerous objects near bot or approaching bot
1697         head = findchainfloat(bot_dodge, true);
1698         while(head)
1699         {
1700                 if (head.owner != this)
1701                 {
1702                         vl = vlen(head.velocity);
1703                         if (vl > autocvar_sv_maxspeed * 0.3)
1704                         {
1705                                 n = normalize(head.velocity);
1706                                 v = this.origin - head.origin;
1707                                 d = v * n;
1708                                 if (d > (0 - head.bot_dodgerating))
1709                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1710                                 {
1711                                         // calculate direction and distance from the flight path, by removing the forward axis
1712                                         v = v - (n * (v * n));
1713                                         danger = head.bot_dodgerating - vlen(v);
1714                                         if (bestdanger < danger)
1715                                         {
1716                                                 bestdanger = danger;
1717                                                 // dodge to the side of the object
1718                                                 dodge = normalize(v);
1719                                         }
1720                                 }
1721                         }
1722                         else
1723                         {
1724                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1725                                 if (bestdanger < danger)
1726                                 {
1727                                         bestdanger = danger;
1728                                         dodge = normalize(this.origin - head.origin);
1729                                 }
1730                         }
1731                 }
1732                 head = head.chain;
1733         }
1734         return dodge;
1735 #endif
1736 }