qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/mapinfo.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/physics/player.qh>
   7 #include <common/stats.qh>
   8 #include <common/teams.qh>
   9 #include <common/util.qh>
  10 #include <common/weapons/_all.qh>
  11 #include <lib/csqcmodel/sv_model.qh>
  12 #include <lib/warpzone/common.qh>
  13 #include <lib/warpzone/util_server.qh>
  14 #include <server/antilag.qh>
  15 #include <server/bot/default/aim.qh>
  16 #include <server/bot/default/cvars.qh>
  17 #include <server/bot/default/havocbot/havocbot.qh>
  18 #include <server/bot/default/havocbot/scripting.qh>
  19 #include <server/bot/default/navigation.qh>
  20 #include <server/bot/default/scripting.qh>
  21 #include <server/bot/default/waypoints.qh>
  22 #include <server/campaign.qh>
  23 #include <server/client.qh>
  24 #include <server/damage.qh>
  25 #include <server/items/items.qh>
  26 #include <server/mutators/_mod.qh>
  27 #include <server/race.qh>
  28 #include <server/scores_rules.qh>
  29 #include <server/teamplay.qh>
  30 #include <server/weapons/accuracy.qh>
  31 #include <server/world.qh>
  32
  33 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  34
  35 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  36 void bot_setclientfields(entity this)
  37 {
  38         CS_CVAR(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  39         CS_CVAR(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  40 }
  41
  42 entity bot_spawn()
  43 {
  44         entity bot = spawnclient();
  45         if (bot)
  46         {
  47                 setItemGroupCount();
  48                 currentbots = currentbots + 1;
  49                 bot_setnameandstuff(bot);
  50                 ClientConnect(bot);
  51                 bot_setclientfields(bot);
  52                 PutClientInServer(bot);
  53         }
  54         return bot;
  55 }
  56
  57 void bot_think(entity this)
  58 {
  59         if (this.bot_nextthink > time)
  60                 return;
  61
  62         this.flags &= ~FL_GODMODE;
  63         if(autocvar_bot_god)
  64                 this.flags |= FL_GODMODE;
  65
  66         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  67
  68         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  69         {
  70                 if (IS_PLAYER(this))
  71                 {
  72                         .entity weaponentity = weaponentities[0];
  73                         if(this.(weaponentity).m_weapon == WEP_Null)
  74                                 W_NextWeapon(this, 0, weaponentity);
  75                 }
  76                 CS(this).movement = '0 0 0';
  77                 this.bot_nextthink = time + 0.5;
  78                 return;
  79         }
  80
  81         if (this.fixangle)
  82         {
  83                 this.v_angle = this.angles;
  84                 this.v_angle_z = 0;
  85                 this.fixangle = false;
  86         }
  87
  88         this.dmg_take = 0;
  89         this.dmg_save = 0;
  90         this.dmg_inflictor = NULL;
  91
  92         // calculate an aiming latency based on the skill setting
  93         // (simulated network latency + naturally delayed reflexes)
  94         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  95         // minimum ping 20+10 random
  96         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
  97         // skill 10 = ping 0.2 (adrenaline)
  98         // skill 0 = ping 0.7 (slightly drunk)
  99
 100         // clear buttons
 101         PHYS_INPUT_BUTTON_ATCK(this) = false;
 102         // keep jump button pressed for a short while, useful with ramp jumps
 103         PHYS_INPUT_BUTTON_JUMP(this) = (!IS_DEAD(this) && time < this.bot_jump_time + 0.2);
 104         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 105         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 106         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 107         PHYS_INPUT_BUTTON_HOOK(this) = false;
 108         PHYS_INPUT_BUTTON_INFO(this) = false;
 109         PHYS_INPUT_BUTTON_DRAG(this) = false;
 110         PHYS_INPUT_BUTTON_CHAT(this) = false;
 111         PHYS_INPUT_BUTTON_USE(this) = false;
 112
 113         if (time < game_starttime)
 114         {
 115                 // block the bot during the countdown to game start
 116                 CS(this).movement = '0 0 0';
 117                 this.bot_nextthink = game_starttime;
 118                 return;
 119         }
 120
 121         // if dead, just wait until we can respawn
 122         if (IS_DEAD(this) || IS_OBSERVER(this))
 123         {
 124                 if (bot_waypoint_queue_owner == this)
 125                         bot_waypoint_queue_owner = NULL;
 126                 this.aistatus = 0;
 127                 CS(this).movement = '0 0 0';
 128                 if (IS_OBSERVER(this))
 129                         return;
 130                 if (IS_DEAD(this))
 131                 {
 132                         if (!navigation_goalrating_timeout(this))
 133                                 navigation_goalrating_timeout_force(this);
 134                         // jump must not be pressed for at least one frame in order for
 135                         // PlayerThink to detect the key down event
 136                         if (this.deadflag == DEAD_DYING)
 137                                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 138                         else if (this.deadflag == DEAD_DEAD)
 139                                 PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 140                 }
 141         }
 142         else if(this.aistatus & AI_STATUS_STUCK)
 143                 navigation_unstuck(this);
 144
 145         // now call the current bot AI (havocbot for example)
 146         this.bot_ai(this);
 147 }
 148
 149 void bot_setnameandstuff(entity this)
 150 {
 151         string readfile, s;
 152         int file, tokens, prio;
 153
 154         file = fopen(autocvar_bot_config_file, FILE_READ);
 155
 156         if(file < 0)
 157         {
 158                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 159                 readfile = "";
 160         }
 161         else
 162         {
 163                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 164                 TeamBalance_GetTeamCounts(balance, NULL);
 165                 int smallest_team = -1;
 166                 int smallest_count = -1;
 167                 if (teamplay)
 168                 {
 169                         for (int i = 1; i <= AvailableTeams(); ++i)
 170                         {
 171                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 172                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 173                                 // since it keeps a spot for the real player in the desired team
 174                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 175                                 if (smallest_count < 0 || count < smallest_count)
 176                                 {
 177                                         smallest_team = i;
 178                                         smallest_count = count;
 179                                 }
 180                         }
 181                 }
 182                 TeamBalance_Destroy(balance);
 183                 RandomSelection_Init();
 184                 while((readfile = fgets(file)))
 185                 {
 186                         if(substring(readfile, 0, 2) == "//")
 187                                 continue;
 188                         if(substring(readfile, 0, 1) == "#")
 189                                 continue;
 190                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 191                         // will create 1 empty token because there's no separator (bug?)
 192                         if (readfile == "")
 193                                 continue;
 194                         tokens = tokenizebyseparator(readfile, "\t");
 195                         if(tokens == 0)
 196                                 continue;
 197                         s = argv(0);
 198                         prio = 0;
 199                         bool conflict = false;
 200                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 201                                 if (s == it.cleanname)
 202                                 {
 203                                         conflict = true;
 204                                         break;
 205                                 }
 206                         });
 207                         if (!conflict)
 208                                 prio += 1;
 209                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 210                         {
 211                                 int forced_team = stof(argv(5));
 212                                 if (!Team_IsValidIndex(forced_team))
 213                                         forced_team = 0;
 214                                 if (!forced_team || forced_team == smallest_team)
 215                                         prio += 2;
 216                         }
 217                         RandomSelection_AddString(readfile, 1, prio);
 218                 }
 219                 readfile = RandomSelection_chosen_string;
 220                 fclose(file);
 221         }
 222
 223         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 224
 225         tokens = tokenizebyseparator(readfile, "\t");
 226         if(argv(0) != "") bot_name = argv(0);
 227         else bot_name = "Bot";
 228
 229         if(argv(1) != "") bot_model = argv(1);
 230         else bot_model = "";
 231
 232         if(argv(2) != "") bot_skin = argv(2);
 233         else bot_skin = "0";
 234
 235         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 236         else bot_shirt = ftos(floor(random() * 15));
 237
 238         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 239         else bot_pants = ftos(floor(random() * 15));
 240
 241         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 242                 this.bot_forced_team = stof(argv(5));
 243         else
 244                 this.bot_forced_team = 0;
 245
 246         prio = 6;
 247
 248         #define READSKILL(f, w, r) MACRO_BEGIN \
 249                 if(argv(prio) != "") \
 250                         this.f = stof(argv(prio)) * w; \
 251                 else \
 252                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 253                 prio++; \
 254         MACRO_END
 255         //print(bot_name, ": ping=", argv(9), "\n");
 256
 257         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 258         READSKILL(bot_moveskill, 2, 0); // move skill
 259         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 260
 261         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 262
 263         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 264         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 265         READSKILL(bot_rangepreference, 1, 0); // read skill
 266
 267         READSKILL(bot_aimskill, 2, 0); // aim skill
 268         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 269         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 270
 271         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 272         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 273
 274         if (file >= 0 && argv(prio) != "")
 275                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 276
 277         this.bot_config_loaded = true;
 278
 279         // this is really only a default, TeamBalance_JoinBestTeam is called later
 280         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 281         this.bot_preferredcolors = this.clientcolors;
 282
 283         string prefix = (autocvar_g_campaign ? "" : autocvar_bot_prefix);
 284         string suffix = (autocvar_g_campaign ? "" : autocvar_bot_suffix);
 285         string name = (autocvar_bot_usemodelnames ? bot_model : bot_name);
 286
 287         if (name == "")
 288         {
 289                 name = ftos(etof(this));
 290                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 291         }
 292         else
 293         {
 294                 // number bots with identical names
 295                 int j = 0;
 296                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 297                         if(it.cleanname == name)
 298                                 ++j;
 299                 });
 300                 if (j)
 301                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 302                 else
 303                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 304         }
 305         this.cleanname = strzone(name);
 306
 307         // pick the model and skin
 308         if(substring(bot_model, -4, 1) != ".")
 309                 bot_model = strcat(bot_model, ".iqm");
 310         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 311         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 312 }
 313
 314 void bot_custom_weapon_priority_setup()
 315 {
 316         static string bot_priority_far_prev;
 317         static string bot_priority_mid_prev;
 318         static string bot_priority_close_prev;
 319         static string bot_priority_distances_prev;
 320         float tokens, i, w;
 321
 322         bot_custom_weapon = false;
 323
 324         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 325                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 326                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 327                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 328         )
 329                 return;
 330
 331         if (bot_priority_distances_prev != autocvar_bot_ai_custom_weapon_priority_distances)
 332         {
 333                 strcpy(bot_priority_distances_prev, autocvar_bot_ai_custom_weapon_priority_distances);
 334                 tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 335
 336                 if (tokens!=2)
 337                         return;
 338
 339                 bot_distance_far = stof(argv(0));
 340                 bot_distance_close = stof(argv(1));
 341
 342                 if(bot_distance_far < bot_distance_close){
 343                         bot_distance_far = stof(argv(1));
 344                         bot_distance_close = stof(argv(0));
 345                 }
 346         }
 347
 348         int c;
 349
 350         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
 351                 if (bot_priority_##dist##_prev != autocvar_bot_ai_custom_weapon_priority_##dist) { \
 352                         strcpy(bot_priority_##dist##_prev, autocvar_bot_ai_custom_weapon_priority_##dist); \
 353                         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
 354                         bot_weapons_##dist[0] = -1; \
 355                         c = 0; \
 356                         for(i = 0; i < tokens && c < REGISTRY_COUNT(Weapons); ++i) { \
 357                                 w = stof(argv(i)); \
 358                                 if (w >= WEP_FIRST && w <= WEP_LAST) { \
 359                                         bot_weapons_##dist[c] = w; \
 360                                         ++c; \
 361                                 } \
 362                         } \
 363                         if (c < REGISTRY_COUNT(Weapons)) \
 364                                 bot_weapons_##dist[c] = -1; \
 365                 } \
 366         MACRO_END
 367
 368         PARSE_WEAPON_PRIORITIES(far);
 369         PARSE_WEAPON_PRIORITIES(mid);
 370         PARSE_WEAPON_PRIORITIES(close);
 371
 372         bot_custom_weapon = true;
 373 }
 374
 375 void bot_endgame()
 376 {
 377         bot_relinkplayerlist();
 378         entity e = bot_list;
 379         while (e)
 380         {
 381                 setcolor(e, e.bot_preferredcolors);
 382                 e = e.nextbot;
 383         }
 384         // if dynamic waypoints are ever implemented, save them here
 385 }
 386
 387 void bot_relinkplayerlist()
 388 {
 389         player_count = 0;
 390         currentbots = 0;
 391         bot_list = NULL;
 392
 393         entity prevbot = NULL;
 394         FOREACH_CLIENT(true,
 395         {
 396                 ++player_count;
 397
 398                 if(IS_BOT_CLIENT(it))
 399                 {
 400                         if (!IS_OBSERVER(it) && !bot_ispaused(it))
 401                         {
 402                                 if(prevbot)
 403                                         prevbot.nextbot = it;
 404                                 else
 405                                         bot_list = it;
 406                                 prevbot = it;
 407                         }
 408                         ++currentbots;
 409                 }
 410         });
 411         if(prevbot)
 412                 prevbot.nextbot = NULL;
 413         bot_strategytoken = bot_list;
 414         bot_strategytoken_taken = true;
 415 }
 416
 417 void bot_clientdisconnect(entity this)
 418 {
 419         if (!IS_BOT_CLIENT(this))
 420                 return;
 421         bot_clearqueue(this);
 422         strfree(this.cleanname);
 423         strfree(this.netname_freeme);
 424         strfree(this.playermodel_freeme);
 425         strfree(this.playerskin_freeme);
 426         if(this.bot_cmd_current)
 427                 delete(this.bot_cmd_current);
 428         if(bot_waypoint_queue_owner == this)
 429                 bot_waypoint_queue_owner = NULL;
 430 }
 431
 432 void bot_clientconnect(entity this)
 433 {
 434         if (!IS_BOT_CLIENT(this)) return;
 435         this.bot_preferredcolors = this.clientcolors;
 436         this.bot_nextthink = time - random();
 437         this.lag_func = bot_lagfunc;
 438         this.isbot = true;
 439         this.createdtime = this.bot_nextthink;
 440
 441         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 442         {
 443                 bot_setnameandstuff(this);
 444                 bot_setclientfields(this);
 445         }
 446
 447         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 448         {
 449                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 450         }
 451         else
 452         {
 453                 this.bot_forced_team = 0;
 454                 TeamBalance_JoinBestTeam(this);
 455         }
 456
 457         havocbot_setupbot(this);
 458 }
 459
 460 void bot_removefromlargestteam()
 461 {
 462         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 463         TeamBalance_GetTeamCounts(balance, NULL);
 464
 465         entity best = NULL;
 466         float besttime = 0;
 467         int bestcount = 0;
 468
 469         int bcount = 0;
 470         FOREACH_CLIENT(it.isbot,
 471         {
 472                 ++bcount;
 473
 474                 if(!best)
 475                 {
 476                         best = it;
 477                         besttime = it.createdtime;
 478                 }
 479
 480                 int thiscount = 0;
 481
 482                 if (Team_IsValidTeam(it.team))
 483                 {
 484                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 485                                 Team_TeamToIndex(it.team));
 486                 }
 487
 488                 if(thiscount > bestcount)
 489                 {
 490                         bestcount = thiscount;
 491                         besttime = it.createdtime;
 492                         best = it;
 493                 }
 494                 else if(thiscount == bestcount && besttime < it.createdtime)
 495                 {
 496                         besttime = it.createdtime;
 497                         best = it;
 498                 }
 499         });
 500         TeamBalance_Destroy(balance);
 501         if(!bcount)
 502                 return; // no bots to remove
 503         currentbots = currentbots - 1;
 504         dropclient(best);
 505 }
 506
 507 void bot_removenewest()
 508 {
 509         if(teamplay)
 510         {
 511                 bot_removefromlargestteam();
 512                 return;
 513         }
 514
 515         float besttime = 0;
 516         entity best = NULL;
 517         int bcount = 0;
 518
 519         FOREACH_CLIENT(it.isbot,
 520         {
 521                 ++bcount;
 522
 523                 if(!best)
 524                 {
 525                         best = it;
 526                         besttime = it.createdtime;
 527                 }
 528
 529                 if(besttime < it.createdtime)
 530                 {
 531                         besttime = it.createdtime;
 532                         best = it;
 533                 }
 534         });
 535
 536         if(!bcount)
 537                 return; // no bots to remove
 538
 539         currentbots = currentbots - 1;
 540         dropclient(best);
 541 }
 542
 543 void autoskill(float factor)
 544 {
 545         int bestbot = -1;
 546         int bestplayer = -1;
 547         FOREACH_CLIENT(IS_PLAYER(it), {
 548                 if(IS_REAL_CLIENT(it))
 549                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 550                 else
 551                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 552         });
 553
 554         string msg = strcat("autoskill: best player got ", ftos(bestplayer), ", ""best bot got ", ftos(bestbot), "; ");
 555         if(bestbot < 0 || bestplayer < 0)
 556         {
 557                 msg = strcat(msg, "not doing anything");
 558                 // don't return, let it reset all counters below
 559         }
 560         else if(bestbot <= bestplayer * factor - 2)
 561         {
 562                 if(autocvar_skill < 17)
 563                 {
 564                         msg = strcat(msg, "2 frags difference, increasing skill");
 565                         cvar_set("skill", ftos(autocvar_skill + 1));
 566                         bprint("^2BOT SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 567                 }
 568         }
 569         else if(bestbot >= bestplayer * factor + 2)
 570         {
 571                 if(autocvar_skill > 0)
 572                 {
 573                         msg = strcat(msg, "2 frags difference, decreasing skill");
 574                         cvar_set("skill", ftos(autocvar_skill - 1));
 575                         bprint("^1BOT SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 576                 }
 577         }
 578         else
 579         {
 580                 msg = strcat(msg, "not doing anything");
 581                 return;
 582                 // don't reset counters, wait for them to accumulate
 583         }
 584         LOG_DEBUG(msg);
 585
 586         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 587 }
 588
 589 void bot_calculate_stepheightvec()
 590 {
 591         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 592         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 593         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 594         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 595 }
 596
 597 bool bot_fixcount(bool multiple_per_frame)
 598 {
 599         int activerealplayers = 0;
 600         int realplayers = 0;
 601         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 602                 activerealplayers = M_ARGV(0, int);
 603                 realplayers = M_ARGV(1, int);
 604         } else {
 605                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 606                         if(IS_PLAYER(it))
 607                                 ++activerealplayers;
 608                         ++realplayers;
 609                 });
 610         }
 611
 612         int bots;
 613         // But don't remove bots immediately on level change, as the real players
 614         // usually haven't rejoined yet
 615         bots_would_leave = false;
 616         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 617                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 618         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 619         {
 620                 int minplayers = max(0, floor(autocvar_minplayers));
 621                 if (teamplay)
 622                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 623                 int minbots = max(0, floor(autocvar_bot_number));
 624
 625                 // add bots to reach minplayers if needed
 626                 bots = max(minbots, minplayers - activerealplayers);
 627                 // cap bots to the max players allowed by the server
 628                 int player_limit = GetPlayerLimit();
 629                 if(player_limit)
 630                         bots = min(bots, max(player_limit - activerealplayers, 0));
 631                 bots = min(bots, maxclients - realplayers);
 632
 633                 if(bots > minbots)
 634                         bots_would_leave = true;
 635         }
 636         else
 637         {
 638                 // if there are no players, remove bots
 639                 bots = 0;
 640         }
 641
 642         // only add one bot per frame to avoid utter chaos
 643         if(time > botframe_nextthink)
 644         {
 645                 while (currentbots < bots)
 646                 {
 647                         if (bot_spawn() == NULL)
 648                         {
 649                                 bprint("Can not add bot, server full.\n");
 650                                 return false;
 651                         }
 652                         if (!multiple_per_frame)
 653                         {
 654                                 break;
 655                         }
 656                 }
 657                 while (currentbots > bots && bots >= 0)
 658                         bot_removenewest();
 659         }
 660
 661         return true;
 662 }
 663
 664 void bot_serverframe()
 665 {
 666         if (intermission_running && currentbots > 0)
 667         {
 668                 // after the end of the match all bots stay unless all human players disconnect
 669                 int realplayers = 0;
 670                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 671                 if (!realplayers)
 672                 {
 673                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 674                         currentbots = 0;
 675                 }
 676                 return;
 677         }
 678
 679         if (game_stopped)
 680                 return;
 681
 682         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 683         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 684         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 685         // either intentionally or automatically (sv_spectate 0)
 686         if (time < 2.5)
 687         {
 688                 currentbots = -1;
 689                 return;
 690         }
 691
 692         if (currentbots == -1)
 693         {
 694                 // count bots already in the server from the previous match
 695                 currentbots = 0;
 696                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 697         }
 698
 699         if(autocvar_skill != skill)
 700         {
 701                 float wpcost_update = false;
 702                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 703                         wpcost_update = true;
 704                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 705                         wpcost_update = true;
 706
 707                 skill = autocvar_skill;
 708                 if (wpcost_update)
 709                         waypoint_updatecost_foralllinks();
 710         }
 711
 712         bot_calculate_stepheightvec();
 713         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 714
 715         if(time > autoskill_nextthink)
 716         {
 717                 float a;
 718                 a = autocvar_skill_auto;
 719                 if(a)
 720                         autoskill(a);
 721                 autoskill_nextthink = time + 5;
 722         }
 723
 724         if(time > botframe_nextthink)
 725         {
 726                 if(!bot_fixcount(false))
 727                         botframe_nextthink = time + 10;
 728         }
 729
 730         if(botframe_spawnedwaypoints)
 731         {
 732                 if(autocvar_waypoint_benchmark)
 733                         localcmd("quit\n");
 734         }
 735
 736         if (currentbots > 0 || waypointeditor_enabled || autocvar_g_waypointeditor_auto)
 737         if (botframe_spawnedwaypoints)
 738         {
 739                 if(botframe_cachedwaypointlinks)
 740                 {
 741                         if(!botframe_loadedforcedlinks)
 742                                 waypoint_load_hardwiredlinks();
 743                 }
 744                 else
 745                 {
 746                         // TODO: Make this check cleaner
 747                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 748                         {
 749                                 waypoint_save_links();
 750                                 break;
 751                         });
 752                 }
 753         }
 754         else
 755         {
 756                 botframe_spawnedwaypoints = true;
 757                 waypoint_loadall();
 758                 waypoint_load_links();
 759         }
 760
 761         if (bot_list)
 762         {
 763                 // cycle the goal token from one bot to the next each frame
 764                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 765                 //  frame, which causes choppy framerates)
 766                 if (bot_strategytoken_taken)
 767                 {
 768                         // give goal token to the first bot without goals; if all bots don't have
 769                         // any goal (or are dead/frozen) simply give it to the next one
 770                         bot_strategytoken_taken = false;
 771                         entity bot_strategytoken_save = bot_strategytoken;
 772                         while (true)
 773                         {
 774                                 if (bot_strategytoken)
 775                                         bot_strategytoken = bot_strategytoken.nextbot;
 776                                 if (!bot_strategytoken)
 777                                         bot_strategytoken = bot_list;
 778
 779                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 780                                         && !bot_strategytoken.goalcurrent)
 781                                         break;
 782
 783                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 784                                         break;
 785                                 if (bot_strategytoken == bot_strategytoken_save)
 786                                         bot_strategytoken_save = NULL; // looped through all the bots
 787                         }
 788                 }
 789
 790                 if (botframe_nextdangertime < time)
 791                 {
 792                         float interval;
 793                         interval = autocvar_bot_ai_dangerdetectioninterval;
 794                         if (botframe_nextdangertime < time - interval * 1.5)
 795                                 botframe_nextdangertime = time;
 796                         botframe_nextdangertime = botframe_nextdangertime + interval;
 797                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 798                 }
 799         }
 800
 801         if (waypointeditor_enabled)
 802                 botframe_showwaypointlinks();
 803
 804         if (autocvar_g_waypointeditor_auto)
 805                 botframe_autowaypoints();
 806
 807         if (currentbots > 0)
 808                 bot_custom_weapon_priority_setup();
 809 }