qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include "../../mutators/_mod.qh"
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 entity bot_spawn()
  45 {
  46         entity bot = spawnclient();
  47         if (bot)
  48         {
  49                 bot_spawn_setup(bot);
  50         }
  51         return bot;
  52 }
  53
  54 void bot_spawn_setup(entity bot)
  55 {
  56         setItemGroupCount();
  57         currentbots = currentbots + 1;
  58         bot_setnameandstuff(bot);
  59         ClientConnect(bot);
  60         PutClientInServer(bot);
  61 }
  62
  63 void bot_remove(entity bot)
  64 {
  65         currentbots = currentbots - 1;
  66         dropclient(bot);
  67 }
  68
  69 void bot_think(entity this)
  70 {
  71         if (this.bot_nextthink > time)
  72                 return;
  73
  74         this.flags &= ~FL_GODMODE;
  75         if(autocvar_bot_god)
  76                 this.flags |= FL_GODMODE;
  77
  78         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  79
  80         //if (this.bot_painintensity > 0)
  81         //      this.bot_painintensity = this.bot_painintensity - (skill + 1) * 40 * frametime;
  82
  83         //this.bot_painintensity = this.bot_painintensity + this.bot_oldhealth - this.health;
  84         //this.bot_painintensity = bound(0, this.bot_painintensity, 100);
  85
  86         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  87         {
  88                 this.movement = '0 0 0';
  89                 this.bot_nextthink = time + 0.5;
  90                 return;
  91         }
  92
  93         if (this.fixangle)
  94         {
  95                 this.v_angle = this.angles;
  96                 this.v_angle_z = 0;
  97                 this.fixangle = false;
  98         }
  99
 100         this.dmg_take = 0;
 101         this.dmg_save = 0;
 102         this.dmg_inflictor = NULL;
 103
 104         // calculate an aiming latency based on the skill setting
 105         // (simulated network latency + naturally delayed reflexes)
 106         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 107         // minimum ping 20+10 random
 108         this.ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 109         // skill 10 = ping 0.2 (adrenaline)
 110         // skill 0 = ping 0.7 (slightly drunk)
 111
 112         // clear buttons
 113         PHYS_INPUT_BUTTON_ATCK(this) = false;
 114         PHYS_INPUT_BUTTON_JUMP(this) = false;
 115         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 116         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 117         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 118         PHYS_INPUT_BUTTON_HOOK(this) = false;
 119         PHYS_INPUT_BUTTON_INFO(this) = false;
 120         PHYS_INPUT_BUTTON_DRAG(this) = false;
 121         PHYS_INPUT_BUTTON_CHAT(this) = false;
 122         PHYS_INPUT_BUTTON_USE(this) = false;
 123
 124         if (time < game_starttime)
 125         {
 126                 // block the bot during the countdown to game start
 127                 this.movement = '0 0 0';
 128                 this.bot_nextthink = game_starttime;
 129                 return;
 130         }
 131
 132         // if dead, just wait until we can respawn
 133         if (IS_DEAD(this))
 134         {
 135                 this.movement = '0 0 0';
 136                 if (this.deadflag == DEAD_DEAD)
 137                 {
 138                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 139                         this.bot_strategytime = 0;
 140                 }
 141         }
 142         else if(this.aistatus & AI_STATUS_STUCK)
 143                 navigation_unstuck(this);
 144
 145         // now call the current bot AI (havocbot for example)
 146         this.bot_ai(this);
 147 }
 148
 149 void bot_setnameandstuff(entity this)
 150 {
 151         string readfile, s;
 152         float file, tokens, prio;
 153
 154         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 155         string name, prefix, suffix;
 156
 157         if(autocvar_g_campaign)
 158         {
 159                 prefix = "";
 160                 suffix = "";
 161         }
 162         else
 163         {
 164                 prefix = autocvar_bot_prefix;
 165                 suffix = autocvar_bot_suffix;
 166         }
 167
 168         file = fopen(autocvar_bot_config_file, FILE_READ);
 169
 170         if(file < 0)
 171         {
 172                 LOG_INFO(strcat("Error: Can not open the bot configuration file '",autocvar_bot_config_file,"'\n"));
 173                 readfile = "";
 174         }
 175         else
 176         {
 177                 RandomSelection_Init();
 178                 while((readfile = fgets(file)))
 179                 {
 180                         if(substring(readfile, 0, 2) == "//")
 181                                 continue;
 182                         if(substring(readfile, 0, 1) == "#")
 183                                 continue;
 184                         tokens = tokenizebyseparator(readfile, "\t");
 185                         if(tokens == 0)
 186                                 continue;
 187                         s = argv(0);
 188                         prio = 1;
 189                         FOREACH_CLIENT(IS_BOT_CLIENT(it), LAMBDA(
 190                                 if(s == it.cleanname)
 191                                 {
 192                                         prio = 0;
 193                                         break;
 194                                 }
 195                         ));
 196                         RandomSelection_AddString(readfile, 1, prio);
 197                 }
 198                 readfile = RandomSelection_chosen_string;
 199                 fclose(file);
 200         }
 201
 202         tokens = tokenizebyseparator(readfile, "\t");
 203         if(argv(0) != "") bot_name = argv(0);
 204         else bot_name = "Bot";
 205
 206         if(argv(1) != "") bot_model = argv(1);
 207         else bot_model = "";
 208
 209         if(argv(2) != "") bot_skin = argv(2);
 210         else bot_skin = "0";
 211
 212         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 213         else bot_shirt = ftos(floor(random() * 15));
 214
 215         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 216         else bot_pants = ftos(floor(random() * 15));
 217
 218         this.bot_forced_team = stof(argv(5));
 219
 220         prio = 6;
 221
 222         #define READSKILL(f, w, r) MACRO_BEGIN { \
 223                 if(argv(prio) != "") \
 224                         this.f = stof(argv(prio)) * w; \
 225                 else \
 226                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 227                 prio++; \
 228         } MACRO_END
 229         //print(bot_name, ": ping=", argv(9), "\n");
 230
 231         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 232         READSKILL(bot_moveskill, 2, 0); // move skill
 233         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 234
 235         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 236
 237         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 238         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 239         READSKILL(bot_rangepreference, 1, 0); // read skill
 240
 241         READSKILL(bot_aimskill, 2, 0); // aim skill
 242         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 243         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 244
 245         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 246         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 247
 248         this.bot_config_loaded = true;
 249
 250         // this is really only a default, JoinBestTeam is called later
 251         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 252         this.bot_preferredcolors = this.clientcolors;
 253
 254         // pick the name
 255         if (autocvar_bot_usemodelnames)
 256                 name = bot_model;
 257         else
 258                 name = bot_name;
 259
 260         // number bots with identical names
 261         int j = 0;
 262         FOREACH_CLIENT(IS_BOT_CLIENT(it), LAMBDA(
 263                 if(it.cleanname == name)
 264                         ++j;
 265         ));
 266         if (j)
 267                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 268         else
 269                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 270
 271         this.cleanname = strzone(name);
 272
 273         // pick the model and skin
 274         if(substring(bot_model, -4, 1) != ".")
 275                 bot_model = strcat(bot_model, ".iqm");
 276         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 277         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 278
 279         this.cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the NULL
 280         this.cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
 281 }
 282
 283 void bot_custom_weapon_priority_setup()
 284 {
 285         float tokens, i, w;
 286
 287         bot_custom_weapon = false;
 288
 289         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 290                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 291                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 292                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 293         )
 294                 return;
 295
 296         // Parse distances
 297         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 298
 299         if (tokens!=2)
 300                 return;
 301
 302         bot_distance_far = stof(argv(0));
 303         bot_distance_close = stof(argv(1));
 304
 305         if(bot_distance_far < bot_distance_close){
 306                 bot_distance_far = stof(argv(1));
 307                 bot_distance_close = stof(argv(0));
 308         }
 309
 310         // Initialize list of weapons
 311         bot_weapons_far[0] = -1;
 312         bot_weapons_mid[0] = -1;
 313         bot_weapons_close[0] = -1;
 314
 315         // Parse far distance weapon priorities
 316         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 317
 318         int c = 0;
 319         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 320                 w = stof(argv(i));
 321                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 322                         bot_weapons_far[c] = w;
 323                         ++c;
 324                 }
 325         }
 326         if(c < Weapons_COUNT)
 327                 bot_weapons_far[c] = -1;
 328
 329         // Parse mid distance weapon priorities
 330         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 331
 332         c = 0;
 333         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 334                 w = stof(argv(i));
 335                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 336                         bot_weapons_mid[c] = w;
 337                         ++c;
 338                 }
 339         }
 340         if(c < Weapons_COUNT)
 341                 bot_weapons_mid[c] = -1;
 342
 343         // Parse close distance weapon priorities
 344         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 345
 346         c = 0;
 347         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 348                 w = stof(argv(i));
 349                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 350                         bot_weapons_close[c] = w;
 351                         ++c;
 352                 }
 353         }
 354         if(c < Weapons_COUNT)
 355                 bot_weapons_close[c] = -1;
 356
 357         bot_custom_weapon = true;
 358 }
 359
 360 void bot_endgame()
 361 {
 362         bot_relinkplayerlist();
 363         entity e = bot_list;
 364         while (e)
 365         {
 366                 setcolor(e, e.bot_preferredcolors);
 367                 e = e.nextbot;
 368         }
 369         // if dynamic waypoints are ever implemented, save them here
 370 }
 371
 372 void bot_relinkplayerlist()
 373 {
 374         player_count = 0;
 375         currentbots = 0;
 376         bot_list = NULL;
 377
 378         entity prevbot = NULL;
 379         FOREACH_CLIENT(true,
 380         {
 381                 ++player_count;
 382
 383                 if(IS_BOT_CLIENT(it))
 384                 {
 385                         if(prevbot)
 386                                 prevbot.nextbot = it;
 387                         else
 388                                 bot_list = it;
 389                         prevbot = it;
 390                         ++currentbots;
 391                 }
 392         });
 393         if(prevbot)
 394                 prevbot.nextbot = NULL;
 395         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 396         bot_strategytoken = bot_list;
 397         bot_strategytoken_taken = true;
 398 }
 399
 400 void bot_clientdisconnect(entity this)
 401 {
 402         if (!IS_BOT_CLIENT(this))
 403                 return;
 404         bot_clearqueue(this);
 405         if(this.cleanname)
 406                 strunzone(this.cleanname);
 407         if(this.netname_freeme)
 408                 strunzone(this.netname_freeme);
 409         if(this.playermodel_freeme)
 410                 strunzone(this.playermodel_freeme);
 411         if(this.playerskin_freeme)
 412                 strunzone(this.playerskin_freeme);
 413         this.cleanname = string_null;
 414         this.netname_freeme = string_null;
 415         this.playermodel_freeme = string_null;
 416         this.playerskin_freeme = string_null;
 417         if(this.bot_cmd_current)
 418                 delete(this.bot_cmd_current);
 419         if(bot_waypoint_queue_owner == this)
 420                 bot_waypoint_queue_owner = NULL;
 421 }
 422
 423 void bot_clientconnect(entity this)
 424 {
 425         if (!IS_BOT_CLIENT(this)) return;
 426         this.bot_preferredcolors = this.clientcolors;
 427         this.bot_nextthink = time - random();
 428         this.lag_func = bot_lagfunc;
 429         this.isbot = true;
 430         this.createdtime = this.bot_nextthink;
 431
 432         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 433                 bot_setnameandstuff(this);
 434
 435         if(this.bot_forced_team==1)
 436                 this.team = NUM_TEAM_1;
 437         else if(this.bot_forced_team==2)
 438                 this.team = NUM_TEAM_2;
 439         else if(this.bot_forced_team==3)
 440                 this.team = NUM_TEAM_3;
 441         else if(this.bot_forced_team==4)
 442                 this.team = NUM_TEAM_4;
 443         else
 444                 JoinBestTeam(this, false, true);
 445
 446         havocbot_setupbot(this);
 447 }
 448
 449 void bot_removefromlargestteam()
 450 {
 451         CheckAllowedTeams(NULL);
 452         GetTeamCounts(NULL);
 453
 454         entity best = NULL;
 455         float besttime = 0;
 456         int bestcount = 0;
 457
 458         int bcount = 0;
 459         FOREACH_CLIENT(it.isbot,
 460         {
 461                 ++bcount;
 462
 463                 if(!best)
 464                 {
 465                         best = it;
 466                         besttime = it.createdtime;
 467                 }
 468
 469                 int thiscount = 0;
 470
 471                 switch(it.team)
 472                 {
 473                         case NUM_TEAM_1: thiscount = c1; break;
 474                         case NUM_TEAM_2: thiscount = c2; break;
 475                         case NUM_TEAM_3: thiscount = c3; break;
 476                         case NUM_TEAM_4: thiscount = c4; break;
 477                 }
 478
 479                 if(thiscount > bestcount)
 480                 {
 481                         bestcount = thiscount;
 482                         besttime = it.createdtime;
 483                         best = it;
 484                 }
 485                 else if(thiscount == bestcount && besttime < it.createdtime)
 486                 {
 487                         besttime = it.createdtime;
 488                         best = it;
 489                 }
 490         });
 491         if(!bcount)
 492                 return; // no bots to remove
 493         bot_remove(best);
 494 }
 495
 496 void bot_removenewest()
 497 {
 498         entity best = NULL;
 499         MUTATOR_CALLHOOK(Bot_SelectRemove, best);
 500         best = M_ARGV(0, entity);
 501         if ( best )
 502         {
 503                 if ( !IS_BOT_CLIENT(best) )
 504                 {
 505                         LOG_WARN("Mutator selected a non-bot as a bot to remove\n");
 506                         best = NULL;
 507                 }
 508                 else
 509                 {
 510                         bot_remove(best);
 511                         return;
 512                 }
 513         }
 514
 515         if(teamplay)
 516         {
 517                 bot_removefromlargestteam();
 518                 return;
 519         }
 520
 521         float besttime = 0;
 522         int bcount = 0;
 523
 524         FOREACH_CLIENT(it.isbot,
 525         {
 526                 ++bcount;
 527
 528                 if(!best)
 529                 {
 530                         best = it;
 531                         besttime = it.createdtime;
 532                 }
 533
 534                 if(besttime < it.createdtime)
 535                 {
 536                         besttime = it.createdtime;
 537                         best = it;
 538                 }
 539         });
 540
 541         if(!bcount)
 542                 return; // no bots to remove
 543
 544         bot_remove(best);
 545 }
 546
 547 void autoskill(float factor)
 548 {
 549         float bestbot;
 550         float bestplayer;
 551
 552         bestbot = -1;
 553         bestplayer = -1;
 554         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 555                 if(IS_REAL_CLIENT(it))
 556                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 557                 else
 558                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 559         ));
 560
 561         LOG_TRACE("autoskill: best player got ", ftos(bestplayer), ", ");
 562         LOG_TRACE("best bot got ", ftos(bestbot), "; ");
 563         if(bestbot < 0 || bestplayer < 0)
 564         {
 565                 LOG_TRACE("not doing anything");
 566                 // don't return, let it reset all counters below
 567         }
 568         else if(bestbot <= bestplayer * factor - 2)
 569         {
 570                 if(autocvar_skill < 17)
 571                 {
 572                         LOG_TRACE("2 frags difference, increasing skill");
 573                         cvar_set("skill", ftos(autocvar_skill + 1));
 574                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 575                 }
 576         }
 577         else if(bestbot >= bestplayer * factor + 2)
 578         {
 579                 if(autocvar_skill > 0)
 580                 {
 581                         LOG_TRACE("2 frags difference, decreasing skill");
 582                         cvar_set("skill", ftos(autocvar_skill - 1));
 583                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 584                 }
 585         }
 586         else
 587         {
 588                 LOG_TRACE("not doing anything");
 589                 return;
 590                 // don't reset counters, wait for them to accumulate
 591         }
 592
 593         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.totalfrags_lastcheck = it.totalfrags));
 594 }
 595
 596 void bot_calculate_stepheightvec()
 597 {
 598         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 599         jumpstepheightvec = stepheightvec +
 600                 ((autocvar_sv_jumpvelocity * autocvar_sv_jumpvelocity) / (2 * autocvar_sv_gravity)) * '0 0 0.85';
 601                 // 0.75 factor is for safety to make the jumps easy
 602 }
 603
 604 float bot_fixcount()
 605 {
 606         int activerealplayers = 0;
 607         int realplayers = 0;
 608         int bots = 0;
 609
 610         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers, bots)) {
 611                 activerealplayers = M_ARGV(0, int);
 612                 realplayers = M_ARGV(1, int);
 613         bots = M_ARGV(2, int);
 614         } else {
 615                 FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 616                         if(IS_PLAYER(it))
 617                                 ++activerealplayers;
 618                         ++realplayers;
 619                 ));
 620         }
 621
 622         // add/remove bots if needed to make sure there are at least
 623         // minplayers+bot_number, or remove all bots if no one is playing
 624         // But don't remove bots immediately on level change, as the real players
 625         // usually haven't rejoined yet
 626         bots_would_leave = false;
 627         if (bots)
 628         {
 629                 // Nothing to do, number of bots set by the hook
 630         }
 631         else if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 632         {
 633                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 634         }
 635         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 636         {
 637                 float realminplayers, minplayers;
 638                 realminplayers = autocvar_minplayers;
 639                 minplayers = max(0, floor(realminplayers));
 640
 641                 float realminbots, minbots;
 642                 realminbots = autocvar_bot_number;
 643                 minbots = max(0, floor(realminbots));
 644
 645                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
 646                 if(bots > minbots)
 647                         bots_would_leave = true;
 648         }
 649         else
 650         {
 651                 // if there are no players, remove bots
 652                 bots = 0;
 653         }
 654
 655         // only add one bot per frame to avoid utter chaos
 656         if(time > botframe_nextthink)
 657         {
 658                 //dprint(ftos(bots), " ? ", ftos(currentbots), "\n");
 659                 while (currentbots < bots)
 660                 {
 661                         if (bot_spawn() == NULL)
 662                         {
 663                                 bprint("Can not add bot, server full.\n");
 664                                 return false;
 665                         }
 666                 }
 667                 while (currentbots > bots)
 668                         bot_removenewest();
 669         }
 670
 671         return true;
 672 }
 673
 674 void bot_remove_from_bot_list(entity this)
 675 {
 676         entity e = bot_list;
 677         entity prev_bot = NULL;
 678         while (e)
 679         {
 680                 if(e == this)
 681                 {
 682                         if(!prev_bot)
 683                                 bot_list = this.nextbot;
 684                         else
 685                                 prev_bot.nextbot = this.nextbot;
 686                         if(bot_strategytoken == this)
 687                         {
 688                                 bot_strategytoken = this.nextbot;
 689                                 bot_strategytoken_taken = true;
 690                         }
 691                         this.nextbot = NULL;
 692                         break;
 693                 }
 694                 prev_bot = e;
 695                 e = e.nextbot;
 696         }
 697 }
 698
 699 void bot_clear(entity this)
 700 {
 701         bot_remove_from_bot_list(this);
 702         if(bot_waypoint_queue_owner == this)
 703                 bot_waypoint_queue_owner = NULL;
 704         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 705 }
 706
 707 void bot_serverframe()
 708 {
 709         if (game_stopped)
 710                 return;
 711
 712         if (time < 2)
 713                 return;
 714
 715         bot_calculate_stepheightvec();
 716         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 717
 718         if(time > autoskill_nextthink)
 719         {
 720                 float a;
 721                 a = autocvar_skill_auto;
 722                 if(a)
 723                         autoskill(a);
 724                 autoskill_nextthink = time + 5;
 725         }
 726
 727         if(time > botframe_nextthink)
 728         {
 729                 if(!bot_fixcount())
 730                         botframe_nextthink = time + 10;
 731         }
 732
 733         bot_ignore_bots = autocvar_bot_ignore_bots;
 734
 735         if(botframe_spawnedwaypoints)
 736         {
 737                 if(autocvar_waypoint_benchmark)
 738                         localcmd("quit\n");
 739         }
 740
 741         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 742         if (botframe_spawnedwaypoints)
 743         {
 744                 if(botframe_cachedwaypointlinks)
 745                 {
 746                         if(!botframe_loadedforcedlinks)
 747                                 waypoint_load_links_hardwired();
 748                 }
 749                 else
 750                 {
 751                         // TODO: Make this check cleaner
 752                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 753                         {
 754                                 waypoint_save_links();
 755                                 break;
 756                         });
 757                 }
 758         }
 759         else
 760         {
 761                 botframe_spawnedwaypoints = true;
 762                 waypoint_loadall();
 763                 if(!waypoint_load_links())
 764                         waypoint_schedulerelinkall();
 765         }
 766
 767         if (bot_list)
 768         {
 769                 // cycle the goal token from one bot to the next each frame
 770                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 771                 //  frame, which causes choppy framerates)
 772                 if (bot_strategytoken_taken)
 773                 {
 774                         bot_strategytoken_taken = false;
 775                         if (bot_strategytoken)
 776                                 bot_strategytoken = bot_strategytoken.nextbot;
 777                         if (!bot_strategytoken)
 778                                 bot_strategytoken = bot_list;
 779                 }
 780
 781                 if (botframe_nextdangertime < time)
 782                 {
 783                         float interval;
 784                         interval = autocvar_bot_ai_dangerdetectioninterval;
 785                         if (botframe_nextdangertime < time - interval * 1.5)
 786                                 botframe_nextdangertime = time;
 787                         botframe_nextdangertime = botframe_nextdangertime + interval;
 788                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 789                 }
 790         }
 791
 792         if (autocvar_g_waypointeditor)
 793                 botframe_showwaypointlinks();
 794
 795         if (autocvar_g_waypointeditor_auto)
 796                 botframe_autowaypoints();
 797
 798         if(time > bot_cvar_nextthink)
 799         {
 800                 if(currentbots>0)
 801                         bot_custom_weapon_priority_setup();
 802                 bot_cvar_nextthink = time + 5;
 803         }
 804 }