qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include "../../mutators/_mod.qh"
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 entity bot_spawn()
  45 {
  46         entity bot = spawnclient();
  47         if (bot)
  48         {
  49                 bot_spawn_setup(bot);
  50         }
  51         return bot;
  52 }
  53
  54 void bot_spawn_setup(entity bot)
  55 {
  56         setItemGroupCount();
  57         currentbots = currentbots + 1;
  58         bot_setnameandstuff(bot);
  59         ClientConnect(bot);
  60         PutClientInServer(bot);
  61 }
  62
  63 void bot_think(entity this)
  64 {
  65         if (this.bot_nextthink > time)
  66                 return;
  67
  68         this.flags &= ~FL_GODMODE;
  69         if(autocvar_bot_god)
  70                 this.flags |= FL_GODMODE;
  71
  72         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  73
  74         //if (this.bot_painintensity > 0)
  75         //      this.bot_painintensity = this.bot_painintensity - (skill + 1) * 40 * frametime;
  76
  77         //this.bot_painintensity = this.bot_painintensity + this.bot_oldhealth - this.health;
  78         //this.bot_painintensity = bound(0, this.bot_painintensity, 100);
  79
  80         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  81         {
  82                 this.movement = '0 0 0';
  83                 this.bot_nextthink = time + 0.5;
  84                 return;
  85         }
  86
  87         if (this.fixangle)
  88         {
  89                 this.v_angle = this.angles;
  90                 this.v_angle_z = 0;
  91                 this.fixangle = false;
  92         }
  93
  94         this.dmg_take = 0;
  95         this.dmg_save = 0;
  96         this.dmg_inflictor = NULL;
  97
  98         // calculate an aiming latency based on the skill setting
  99         // (simulated network latency + naturally delayed reflexes)
 100         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 101         // minimum ping 20+10 random
 102         this.ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 103         // skill 10 = ping 0.2 (adrenaline)
 104         // skill 0 = ping 0.7 (slightly drunk)
 105
 106         // clear buttons
 107         PHYS_INPUT_BUTTON_ATCK(this) = false;
 108         PHYS_INPUT_BUTTON_JUMP(this) = false;
 109         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 110         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 111         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 112         PHYS_INPUT_BUTTON_HOOK(this) = false;
 113         PHYS_INPUT_BUTTON_INFO(this) = false;
 114         PHYS_INPUT_BUTTON_DRAG(this) = false;
 115         PHYS_INPUT_BUTTON_CHAT(this) = false;
 116         PHYS_INPUT_BUTTON_USE(this) = false;
 117
 118         if (time < game_starttime)
 119         {
 120                 // block the bot during the countdown to game start
 121                 this.movement = '0 0 0';
 122                 this.bot_nextthink = game_starttime;
 123                 return;
 124         }
 125
 126         // if dead, just wait until we can respawn
 127         if (IS_DEAD(this))
 128         {
 129                 this.movement = '0 0 0';
 130                 if (this.deadflag == DEAD_DEAD)
 131                 {
 132                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 133                         this.bot_strategytime = 0;
 134                 }
 135         }
 136         else if(this.aistatus & AI_STATUS_STUCK)
 137                 navigation_unstuck(this);
 138
 139         // now call the current bot AI (havocbot for example)
 140         this.bot_ai(this);
 141 }
 142
 143 void bot_setnameandstuff(entity this)
 144 {
 145         string readfile, s;
 146         float file, tokens, prio;
 147
 148         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 149         string name, prefix, suffix;
 150
 151         if(autocvar_g_campaign)
 152         {
 153                 prefix = "";
 154                 suffix = "";
 155         }
 156         else
 157         {
 158                 prefix = autocvar_bot_prefix;
 159                 suffix = autocvar_bot_suffix;
 160         }
 161
 162         file = fopen(autocvar_bot_config_file, FILE_READ);
 163
 164         if(file < 0)
 165         {
 166                 LOG_INFO(strcat("Error: Can not open the bot configuration file '",autocvar_bot_config_file,"'\n"));
 167                 readfile = "";
 168         }
 169         else
 170         {
 171                 RandomSelection_Init();
 172                 while((readfile = fgets(file)))
 173                 {
 174                         if(substring(readfile, 0, 2) == "//")
 175                                 continue;
 176                         if(substring(readfile, 0, 1) == "#")
 177                                 continue;
 178                         tokens = tokenizebyseparator(readfile, "\t");
 179                         if(tokens == 0)
 180                                 continue;
 181                         s = argv(0);
 182                         prio = 1;
 183                         FOREACH_CLIENT(IS_BOT_CLIENT(it), LAMBDA(
 184                                 if(s == it.cleanname)
 185                                 {
 186                                         prio = 0;
 187                                         break;
 188                                 }
 189                         ));
 190                         RandomSelection_AddString(readfile, 1, prio);
 191                 }
 192                 readfile = RandomSelection_chosen_string;
 193                 fclose(file);
 194         }
 195
 196         tokens = tokenizebyseparator(readfile, "\t");
 197         if(argv(0) != "") bot_name = argv(0);
 198         else bot_name = "Bot";
 199
 200         if(argv(1) != "") bot_model = argv(1);
 201         else bot_model = "";
 202
 203         if(argv(2) != "") bot_skin = argv(2);
 204         else bot_skin = "0";
 205
 206         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 207         else bot_shirt = ftos(floor(random() * 15));
 208
 209         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 210         else bot_pants = ftos(floor(random() * 15));
 211
 212         this.bot_forced_team = stof(argv(5));
 213
 214         prio = 6;
 215
 216         #define READSKILL(f, w, r) MACRO_BEGIN { \
 217                 if(argv(prio) != "") \
 218                         this.f = stof(argv(prio)) * w; \
 219                 else \
 220                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 221                 prio++; \
 222         } MACRO_END
 223         //print(bot_name, ": ping=", argv(9), "\n");
 224
 225         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 226         READSKILL(bot_moveskill, 2, 0); // move skill
 227         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 228
 229         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 230
 231         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 232         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 233         READSKILL(bot_rangepreference, 1, 0); // read skill
 234
 235         READSKILL(bot_aimskill, 2, 0); // aim skill
 236         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 237         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 238
 239         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 240         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 241
 242         this.bot_config_loaded = true;
 243
 244         // this is really only a default, JoinBestTeam is called later
 245         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 246         this.bot_preferredcolors = this.clientcolors;
 247
 248         // pick the name
 249         if (autocvar_bot_usemodelnames)
 250                 name = bot_model;
 251         else
 252                 name = bot_name;
 253
 254         // number bots with identical names
 255         int j = 0;
 256         FOREACH_CLIENT(IS_BOT_CLIENT(it), LAMBDA(
 257                 if(it.cleanname == name)
 258                         ++j;
 259         ));
 260         if (j)
 261                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 262         else
 263                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 264
 265         this.cleanname = strzone(name);
 266
 267         // pick the model and skin
 268         if(substring(bot_model, -4, 1) != ".")
 269                 bot_model = strcat(bot_model, ".iqm");
 270         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 271         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 272
 273         this.cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the NULL
 274         this.cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
 275 }
 276
 277 void bot_custom_weapon_priority_setup()
 278 {
 279         float tokens, i, w;
 280
 281         bot_custom_weapon = false;
 282
 283         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 284                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 285                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 286                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 287         )
 288                 return;
 289
 290         // Parse distances
 291         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 292
 293         if (tokens!=2)
 294                 return;
 295
 296         bot_distance_far = stof(argv(0));
 297         bot_distance_close = stof(argv(1));
 298
 299         if(bot_distance_far < bot_distance_close){
 300                 bot_distance_far = stof(argv(1));
 301                 bot_distance_close = stof(argv(0));
 302         }
 303
 304         // Initialize list of weapons
 305         bot_weapons_far[0] = -1;
 306         bot_weapons_mid[0] = -1;
 307         bot_weapons_close[0] = -1;
 308
 309         // Parse far distance weapon priorities
 310         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 311
 312         int c = 0;
 313         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 314                 w = stof(argv(i));
 315                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 316                         bot_weapons_far[c] = w;
 317                         ++c;
 318                 }
 319         }
 320         if(c < Weapons_COUNT)
 321                 bot_weapons_far[c] = -1;
 322
 323         // Parse mid distance weapon priorities
 324         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 325
 326         c = 0;
 327         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 328                 w = stof(argv(i));
 329                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 330                         bot_weapons_mid[c] = w;
 331                         ++c;
 332                 }
 333         }
 334         if(c < Weapons_COUNT)
 335                 bot_weapons_mid[c] = -1;
 336
 337         // Parse close distance weapon priorities
 338         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 339
 340         c = 0;
 341         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 342                 w = stof(argv(i));
 343                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 344                         bot_weapons_close[c] = w;
 345                         ++c;
 346                 }
 347         }
 348         if(c < Weapons_COUNT)
 349                 bot_weapons_close[c] = -1;
 350
 351         bot_custom_weapon = true;
 352 }
 353
 354 void bot_endgame()
 355 {
 356         bot_relinkplayerlist();
 357         entity e = bot_list;
 358         while (e)
 359         {
 360                 setcolor(e, e.bot_preferredcolors);
 361                 e = e.nextbot;
 362         }
 363         // if dynamic waypoints are ever implemented, save them here
 364 }
 365
 366 void bot_relinkplayerlist()
 367 {
 368         player_count = 0;
 369         currentbots = 0;
 370         bot_list = NULL;
 371
 372         entity prevbot = NULL;
 373         FOREACH_CLIENT(true,
 374         {
 375                 ++player_count;
 376
 377                 if(IS_BOT_CLIENT(it))
 378                 {
 379                         if(prevbot)
 380                                 prevbot.nextbot = it;
 381                         else
 382                                 bot_list = it;
 383                         prevbot = it;
 384                         ++currentbots;
 385                 }
 386         });
 387         if(prevbot)
 388                 prevbot.nextbot = NULL;
 389         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 390         bot_strategytoken = bot_list;
 391         bot_strategytoken_taken = true;
 392 }
 393
 394 void bot_clientdisconnect(entity this)
 395 {
 396         if (!IS_BOT_CLIENT(this))
 397                 return;
 398         bot_clearqueue(this);
 399         if(this.cleanname)
 400                 strunzone(this.cleanname);
 401         if(this.netname_freeme)
 402                 strunzone(this.netname_freeme);
 403         if(this.playermodel_freeme)
 404                 strunzone(this.playermodel_freeme);
 405         if(this.playerskin_freeme)
 406                 strunzone(this.playerskin_freeme);
 407         this.cleanname = string_null;
 408         this.netname_freeme = string_null;
 409         this.playermodel_freeme = string_null;
 410         this.playerskin_freeme = string_null;
 411         if(this.bot_cmd_current)
 412                 delete(this.bot_cmd_current);
 413         if(bot_waypoint_queue_owner == this)
 414                 bot_waypoint_queue_owner = NULL;
 415 }
 416
 417 void bot_clientconnect(entity this)
 418 {
 419         if (!IS_BOT_CLIENT(this)) return;
 420         this.bot_preferredcolors = this.clientcolors;
 421         this.bot_nextthink = time - random();
 422         this.lag_func = bot_lagfunc;
 423         this.isbot = true;
 424         this.createdtime = this.bot_nextthink;
 425
 426         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 427                 bot_setnameandstuff(this);
 428
 429         if(this.bot_forced_team==1)
 430                 this.team = NUM_TEAM_1;
 431         else if(this.bot_forced_team==2)
 432                 this.team = NUM_TEAM_2;
 433         else if(this.bot_forced_team==3)
 434                 this.team = NUM_TEAM_3;
 435         else if(this.bot_forced_team==4)
 436                 this.team = NUM_TEAM_4;
 437         else
 438                 JoinBestTeam(this, false, true);
 439
 440         havocbot_setupbot(this);
 441 }
 442
 443 void bot_removefromlargestteam()
 444 {
 445         CheckAllowedTeams(NULL);
 446         GetTeamCounts(NULL);
 447
 448         entity best = NULL;
 449         float besttime = 0;
 450         int bestcount = 0;
 451
 452         int bcount = 0;
 453         FOREACH_CLIENT(it.isbot,
 454         {
 455                 ++bcount;
 456
 457                 if(!best)
 458                 {
 459                         best = it;
 460                         besttime = it.createdtime;
 461                 }
 462
 463                 int thiscount = 0;
 464
 465                 switch(it.team)
 466                 {
 467                         case NUM_TEAM_1: thiscount = c1; break;
 468                         case NUM_TEAM_2: thiscount = c2; break;
 469                         case NUM_TEAM_3: thiscount = c3; break;
 470                         case NUM_TEAM_4: thiscount = c4; break;
 471                 }
 472
 473                 if(thiscount > bestcount)
 474                 {
 475                         bestcount = thiscount;
 476                         besttime = it.createdtime;
 477                         best = it;
 478                 }
 479                 else if(thiscount == bestcount && besttime < it.createdtime)
 480                 {
 481                         besttime = it.createdtime;
 482                         best = it;
 483                 }
 484         });
 485         if(!bcount)
 486                 return; // no bots to remove
 487         currentbots = currentbots - 1;
 488         dropclient(best);
 489 }
 490
 491 void bot_removenewest()
 492 {
 493         if(teamplay)
 494         {
 495                 bot_removefromlargestteam();
 496                 return;
 497         }
 498
 499         float besttime = 0;
 500         entity best = NULL;
 501         int bcount = 0;
 502
 503         FOREACH_CLIENT(it.isbot,
 504         {
 505                 ++bcount;
 506
 507                 if(!best)
 508                 {
 509                         best = it;
 510                         besttime = it.createdtime;
 511                 }
 512
 513                 if(besttime < it.createdtime)
 514                 {
 515                         besttime = it.createdtime;
 516                         best = it;
 517                 }
 518         });
 519
 520         if(!bcount)
 521                 return; // no bots to remove
 522
 523         currentbots = currentbots - 1;
 524         dropclient(best);
 525 }
 526
 527 void autoskill(float factor)
 528 {
 529         float bestbot;
 530         float bestplayer;
 531
 532         bestbot = -1;
 533         bestplayer = -1;
 534         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 535                 if(IS_REAL_CLIENT(it))
 536                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 537                 else
 538                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 539         ));
 540
 541         LOG_TRACE("autoskill: best player got ", ftos(bestplayer), ", ");
 542         LOG_TRACE("best bot got ", ftos(bestbot), "; ");
 543         if(bestbot < 0 || bestplayer < 0)
 544         {
 545                 LOG_TRACE("not doing anything");
 546                 // don't return, let it reset all counters below
 547         }
 548         else if(bestbot <= bestplayer * factor - 2)
 549         {
 550                 if(autocvar_skill < 17)
 551                 {
 552                         LOG_TRACE("2 frags difference, increasing skill");
 553                         cvar_set("skill", ftos(autocvar_skill + 1));
 554                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 555                 }
 556         }
 557         else if(bestbot >= bestplayer * factor + 2)
 558         {
 559                 if(autocvar_skill > 0)
 560                 {
 561                         LOG_TRACE("2 frags difference, decreasing skill");
 562                         cvar_set("skill", ftos(autocvar_skill - 1));
 563                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 564                 }
 565         }
 566         else
 567         {
 568                 LOG_TRACE("not doing anything");
 569                 return;
 570                 // don't reset counters, wait for them to accumulate
 571         }
 572
 573         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.totalfrags_lastcheck = it.totalfrags));
 574 }
 575
 576 void bot_calculate_stepheightvec()
 577 {
 578         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 579         jumpstepheightvec = stepheightvec +
 580                 ((autocvar_sv_jumpvelocity * autocvar_sv_jumpvelocity) / (2 * autocvar_sv_gravity)) * '0 0 0.85';
 581                 // 0.75 factor is for safety to make the jumps easy
 582 }
 583
 584 float bot_fixcount()
 585 {
 586         int activerealplayers = 0;
 587         int realplayers = 0;
 588         int bots = 0;
 589
 590         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers, bots)) {
 591                 activerealplayers = M_ARGV(0, int);
 592                 realplayers = M_ARGV(1, int);
 593         bots = M_ARGV(2, int);
 594         } else {
 595                 FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 596                         if(IS_PLAYER(it))
 597                                 ++activerealplayers;
 598                         ++realplayers;
 599                 ));
 600         }
 601
 602         // add/remove bots if needed to make sure there are at least
 603         // minplayers+bot_number, or remove all bots if no one is playing
 604         // But don't remove bots immediately on level change, as the real players
 605         // usually haven't rejoined yet
 606         bots_would_leave = false;
 607         if (bots)
 608         {
 609                 // Nothing to do, number of bots set by the hook
 610         }
 611         else if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 612         {
 613                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 614         }
 615         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 616         {
 617                 float realminplayers, minplayers;
 618                 realminplayers = autocvar_minplayers;
 619                 minplayers = max(0, floor(realminplayers));
 620
 621                 float realminbots, minbots;
 622                 realminbots = autocvar_bot_number;
 623                 minbots = max(0, floor(realminbots));
 624
 625                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
 626                 if(bots > minbots)
 627                         bots_would_leave = true;
 628         }
 629         else
 630         {
 631                 // if there are no players, remove bots
 632                 bots = 0;
 633         }
 634
 635         // only add one bot per frame to avoid utter chaos
 636         if(time > botframe_nextthink)
 637         {
 638                 //dprint(ftos(bots), " ? ", ftos(currentbots), "\n");
 639                 while (currentbots < bots)
 640                 {
 641                         if (bot_spawn() == NULL)
 642                         {
 643                                 bprint("Can not add bot, server full.\n");
 644                                 return false;
 645                         }
 646                 }
 647                 while (currentbots > bots)
 648                         bot_removenewest();
 649         }
 650
 651         return true;
 652 }
 653
 654 void bot_remove_from_bot_list(entity this)
 655 {
 656         entity e = bot_list;
 657         entity prev_bot = NULL;
 658         while (e)
 659         {
 660                 if(e == this)
 661                 {
 662                         if(!prev_bot)
 663                                 bot_list = this.nextbot;
 664                         else
 665                                 prev_bot.nextbot = this.nextbot;
 666                         if(bot_strategytoken == this)
 667                         {
 668                                 bot_strategytoken = this.nextbot;
 669                                 bot_strategytoken_taken = true;
 670                         }
 671                         this.nextbot = NULL;
 672                         break;
 673                 }
 674                 prev_bot = e;
 675                 e = e.nextbot;
 676         }
 677 }
 678
 679 void bot_clear(entity this)
 680 {
 681         bot_remove_from_bot_list(this);
 682         if(bot_waypoint_queue_owner == this)
 683                 bot_waypoint_queue_owner = NULL;
 684         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 685 }
 686
 687 void bot_serverframe()
 688 {
 689         if (game_stopped)
 690                 return;
 691
 692         if (time < 2)
 693                 return;
 694
 695         bot_calculate_stepheightvec();
 696         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 697
 698         if(time > autoskill_nextthink)
 699         {
 700                 float a;
 701                 a = autocvar_skill_auto;
 702                 if(a)
 703                         autoskill(a);
 704                 autoskill_nextthink = time + 5;
 705         }
 706
 707         if(time > botframe_nextthink)
 708         {
 709                 if(!bot_fixcount())
 710                         botframe_nextthink = time + 10;
 711         }
 712
 713         bot_ignore_bots = autocvar_bot_ignore_bots;
 714
 715         if(botframe_spawnedwaypoints)
 716         {
 717                 if(autocvar_waypoint_benchmark)
 718                         localcmd("quit\n");
 719         }
 720
 721         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 722         if (botframe_spawnedwaypoints)
 723         {
 724                 if(botframe_cachedwaypointlinks)
 725                 {
 726                         if(!botframe_loadedforcedlinks)
 727                                 waypoint_load_links_hardwired();
 728                 }
 729                 else
 730                 {
 731                         // TODO: Make this check cleaner
 732                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 733                         {
 734                                 waypoint_save_links();
 735                                 break;
 736                         });
 737                 }
 738         }
 739         else
 740         {
 741                 botframe_spawnedwaypoints = true;
 742                 waypoint_loadall();
 743                 if(!waypoint_load_links())
 744                         waypoint_schedulerelinkall();
 745         }
 746
 747         if (bot_list)
 748         {
 749                 // cycle the goal token from one bot to the next each frame
 750                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 751                 //  frame, which causes choppy framerates)
 752                 if (bot_strategytoken_taken)
 753                 {
 754                         bot_strategytoken_taken = false;
 755                         if (bot_strategytoken)
 756                                 bot_strategytoken = bot_strategytoken.nextbot;
 757                         if (!bot_strategytoken)
 758                                 bot_strategytoken = bot_list;
 759                 }
 760
 761                 if (botframe_nextdangertime < time)
 762                 {
 763                         float interval;
 764                         interval = autocvar_bot_ai_dangerdetectioninterval;
 765                         if (botframe_nextdangertime < time - interval * 1.5)
 766                                 botframe_nextdangertime = time;
 767                         botframe_nextdangertime = botframe_nextdangertime + interval;
 768                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 769                 }
 770         }
 771
 772         if (autocvar_g_waypointeditor)
 773                 botframe_showwaypointlinks();
 774
 775         if (autocvar_g_waypointeditor_auto)
 776                 botframe_autowaypoints();
 777
 778         if(time > bot_cvar_nextthink)
 779         {
 780                 if(currentbots>0)
 781                         bot_custom_weapon_priority_setup();
 782                 bot_cvar_nextthink = time + 5;
 783         }
 784 }