qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/mapinfo.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/physics/player.qh>
   7 #include <common/stats.qh>
   8 #include <common/teams.qh>
   9 #include <common/util.qh>
  10 #include <common/weapons/_all.qh>
  11 #include <lib/csqcmodel/sv_model.qh>
  12 #include <lib/warpzone/common.qh>
  13 #include <lib/warpzone/util_server.qh>
  14 #include <server/antilag.qh>
  15 #include <server/bot/default/aim.qh>
  16 #include <server/bot/default/cvars.qh>
  17 #include <server/bot/default/havocbot/havocbot.qh>
  18 #include <server/bot/default/havocbot/scripting.qh>
  19 #include <server/bot/default/navigation.qh>
  20 #include <server/bot/default/scripting.qh>
  21 #include <server/bot/default/waypoints.qh>
  22 #include <server/campaign.qh>
  23 #include <server/client.qh>
  24 #include <server/damage.qh>
  25 #include <server/items/items.qh>
  26 #include <server/mutators/_mod.qh>
  27 #include <server/race.qh>
  28 #include <server/scores_rules.qh>
  29 #include <server/teamplay.qh>
  30 #include <server/weapons/accuracy.qh>
  31 #include <server/weapons/selection.qh>
  32 #include <server/world.qh>
  33
  34 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  35
  36 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  37 void bot_setclientfields(entity this)
  38 {
  39         CS_CVAR(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  40         CS_CVAR(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  41 }
  42
  43 entity bot_spawn()
  44 {
  45         entity bot = spawnclient();
  46         if (bot)
  47         {
  48                 setItemGroupCount();
  49                 currentbots = currentbots + 1;
  50                 bot_setnameandstuff(bot);
  51                 ClientConnect(bot);
  52                 bot_setclientfields(bot);
  53                 PutClientInServer(bot);
  54         }
  55         return bot;
  56 }
  57
  58 void bot_think(entity this)
  59 {
  60         if (this.bot_nextthink > time)
  61                 return;
  62
  63         this.flags &= ~FL_GODMODE;
  64         if(autocvar_bot_god)
  65                 this.flags |= FL_GODMODE;
  66
  67         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  68
  69         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  70         {
  71                 CS(this).movement = '0 0 0';
  72                 this.bot_nextthink = time + 0.5;
  73                 return;
  74         }
  75
  76         if (this.fixangle)
  77         {
  78                 this.v_angle = this.angles;
  79                 this.v_angle_z = 0;
  80                 this.fixangle = false;
  81         }
  82
  83         this.dmg_take = 0;
  84         this.dmg_save = 0;
  85         this.dmg_inflictor = NULL;
  86
  87         // calculate an aiming latency based on the skill setting
  88         // (simulated network latency + naturally delayed reflexes)
  89         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  90         // minimum ping 20+10 random
  91         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
  92         // skill 10 = ping 0.2 (adrenaline)
  93         // skill 0 = ping 0.7 (slightly drunk)
  94
  95         // clear buttons
  96         PHYS_INPUT_BUTTON_ATCK(this) = false;
  97         // keep jump button pressed for a short while, useful with ramp jumps
  98         PHYS_INPUT_BUTTON_JUMP(this) = (!IS_DEAD(this) && time < this.bot_jump_time + 0.2);
  99         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 100         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 101         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 102         PHYS_INPUT_BUTTON_HOOK(this) = false;
 103         PHYS_INPUT_BUTTON_INFO(this) = false;
 104         PHYS_INPUT_BUTTON_DRAG(this) = false;
 105         PHYS_INPUT_BUTTON_CHAT(this) = false;
 106         PHYS_INPUT_BUTTON_USE(this) = false;
 107
 108         if (time < game_starttime)
 109         {
 110                 .entity weaponentity = weaponentities[0];
 111                 if(this.(weaponentity).m_weapon == WEP_Null)
 112                         W_NextWeapon(this, 0, weaponentity);
 113                 // block the bot during the countdown to game start
 114                 CS(this).movement = '0 0 0';
 115                 this.bot_nextthink = game_starttime;
 116                 return;
 117         }
 118
 119         // if dead, just wait until we can respawn
 120         if (IS_DEAD(this) || IS_OBSERVER(this))
 121         {
 122                 if (bot_waypoint_queue_owner == this)
 123                         bot_waypoint_queue_owner = NULL;
 124                 this.aistatus = 0;
 125                 CS(this).movement = '0 0 0';
 126                 if (IS_OBSERVER(this))
 127                         return;
 128                 if (IS_DEAD(this))
 129                 {
 130                         if (!navigation_goalrating_timeout(this))
 131                                 navigation_goalrating_timeout_force(this);
 132                         // jump must not be pressed for at least one frame in order for
 133                         // PlayerThink to detect the key down event
 134                         if (this.deadflag == DEAD_DYING)
 135                                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 136                         else if (this.deadflag == DEAD_DEAD)
 137                                 PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 138                 }
 139         }
 140         else if(this.aistatus & AI_STATUS_STUCK)
 141                 navigation_unstuck(this);
 142
 143         // now call the current bot AI (havocbot for example)
 144         this.bot_ai(this);
 145 }
 146
 147 void bot_setnameandstuff(entity this)
 148 {
 149         string readfile, s;
 150         int file, tokens, prio;
 151
 152         file = fopen(autocvar_bot_config_file, FILE_READ);
 153
 154         if(file < 0)
 155         {
 156                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 157                 readfile = "";
 158         }
 159         else
 160         {
 161                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 162                 TeamBalance_GetTeamCounts(balance, NULL);
 163                 int smallest_team = -1;
 164                 int smallest_count = -1;
 165                 if (teamplay)
 166                 {
 167                         for (int i = 1; i <= AvailableTeams(); ++i)
 168                         {
 169                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 170                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 171                                 // since it keeps a spot for the real player in the desired team
 172                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 173                                 if (smallest_count < 0 || count < smallest_count)
 174                                 {
 175                                         smallest_team = i;
 176                                         smallest_count = count;
 177                                 }
 178                         }
 179                 }
 180                 TeamBalance_Destroy(balance);
 181                 RandomSelection_Init();
 182                 while((readfile = fgets(file)))
 183                 {
 184                         if(substring(readfile, 0, 2) == "//")
 185                                 continue;
 186                         if(substring(readfile, 0, 1) == "#")
 187                                 continue;
 188                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 189                         // will create 1 empty token because there's no separator (bug?)
 190                         if (readfile == "")
 191                                 continue;
 192                         tokens = tokenizebyseparator(readfile, "\t");
 193                         if(tokens == 0)
 194                                 continue;
 195                         s = argv(0);
 196                         prio = 0;
 197                         bool conflict = false;
 198                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 199                                 if (s == it.cleanname)
 200                                 {
 201                                         conflict = true;
 202                                         break;
 203                                 }
 204                         });
 205                         if (!conflict)
 206                                 prio += 1;
 207                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 208                         {
 209                                 int forced_team = stof(argv(5));
 210                                 if (!Team_IsValidIndex(forced_team))
 211                                         forced_team = 0;
 212                                 if (!forced_team || forced_team == smallest_team)
 213                                         prio += 2;
 214                         }
 215                         RandomSelection_AddString(readfile, 1, prio);
 216                 }
 217                 readfile = RandomSelection_chosen_string;
 218                 fclose(file);
 219         }
 220
 221         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 222
 223         tokens = tokenizebyseparator(readfile, "\t");
 224         if(argv(0) != "") bot_name = argv(0);
 225         else bot_name = "Bot";
 226
 227         if(argv(1) != "") bot_model = argv(1);
 228         else bot_model = "";
 229
 230         if(argv(2) != "") bot_skin = argv(2);
 231         else bot_skin = "0";
 232
 233         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 234         else bot_shirt = ftos(floor(random() * 15));
 235
 236         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 237         else bot_pants = ftos(floor(random() * 15));
 238
 239         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 240         {
 241                 this.bot_forced_team = stof(argv(5));
 242                 if (!Team_IsValidIndex(this.bot_forced_team))
 243                         this.bot_forced_team = 0;
 244         }
 245         else
 246                 this.bot_forced_team = 0;
 247
 248         prio = 6;
 249
 250         #define READSKILL(f, w, r) MACRO_BEGIN \
 251                 if(argv(prio) != "") \
 252                         this.f = stof(argv(prio)) * w; \
 253                 else \
 254                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 255                 prio++; \
 256         MACRO_END
 257         //print(bot_name, ": ping=", argv(9), "\n");
 258
 259         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 260         READSKILL(bot_moveskill, 2, 0); // move skill
 261         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 262
 263         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 264
 265         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 266         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 267         READSKILL(bot_rangepreference, 1, 0); // read skill
 268
 269         READSKILL(bot_aimskill, 2, 0); // aim skill
 270         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 271         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 272
 273         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 274         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 275
 276         if (file >= 0 && argv(prio) != "")
 277                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 278
 279         this.bot_config_loaded = true;
 280
 281         // this is really only a default, TeamBalance_JoinBestTeam is called later
 282         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 283         this.bot_preferredcolors = this.clientcolors;
 284
 285         string prefix = (autocvar_g_campaign ? "" : autocvar_bot_prefix);
 286         string suffix = (autocvar_g_campaign ? "" : autocvar_bot_suffix);
 287         string name = (autocvar_bot_usemodelnames ? bot_model : bot_name);
 288
 289         if (name == "")
 290         {
 291                 name = ftos(etof(this));
 292                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 293         }
 294         else
 295         {
 296                 // number bots with identical names
 297                 int j = 0;
 298                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 299                         if(it.cleanname == name)
 300                                 ++j;
 301                 });
 302                 if (j)
 303                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 304                 else
 305                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 306         }
 307         this.cleanname = strzone(name);
 308
 309         // pick the model and skin
 310         if(substring(bot_model, -4, 1) != ".")
 311                 bot_model = strcat(bot_model, ".iqm");
 312         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 313         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 314 }
 315
 316 void bot_custom_weapon_priority_setup()
 317 {
 318         static string bot_priority_far_prev;
 319         static string bot_priority_mid_prev;
 320         static string bot_priority_close_prev;
 321         static string bot_priority_distances_prev;
 322         float tokens, i, w;
 323
 324         bot_custom_weapon = false;
 325
 326         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 327                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 328                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 329                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 330         )
 331                 return;
 332
 333         if (bot_priority_distances_prev != autocvar_bot_ai_custom_weapon_priority_distances)
 334         {
 335                 strcpy(bot_priority_distances_prev, autocvar_bot_ai_custom_weapon_priority_distances);
 336                 tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 337
 338                 if (tokens!=2)
 339                         return;
 340
 341                 bot_distance_far = stof(argv(0));
 342                 bot_distance_close = stof(argv(1));
 343
 344                 if(bot_distance_far < bot_distance_close){
 345                         bot_distance_far = stof(argv(1));
 346                         bot_distance_close = stof(argv(0));
 347                 }
 348         }
 349
 350         int c;
 351
 352         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
 353                 if (bot_priority_##dist##_prev != autocvar_bot_ai_custom_weapon_priority_##dist) { \
 354                         strcpy(bot_priority_##dist##_prev, autocvar_bot_ai_custom_weapon_priority_##dist); \
 355                         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
 356                         bot_weapons_##dist[0] = -1; \
 357                         c = 0; \
 358                         for(i = 0; i < tokens && c < REGISTRY_COUNT(Weapons); ++i) { \
 359                                 w = stof(argv(i)); \
 360                                 if (w >= WEP_FIRST && w <= WEP_LAST) { \
 361                                         bot_weapons_##dist[c] = w; \
 362                                         ++c; \
 363                                 } \
 364                         } \
 365                         if (c < REGISTRY_COUNT(Weapons)) \
 366                                 bot_weapons_##dist[c] = -1; \
 367                 } \
 368         MACRO_END
 369
 370         PARSE_WEAPON_PRIORITIES(far);
 371         PARSE_WEAPON_PRIORITIES(mid);
 372         PARSE_WEAPON_PRIORITIES(close);
 373
 374         bot_custom_weapon = true;
 375 }
 376
 377 void bot_endgame()
 378 {
 379         bot_relinkplayerlist();
 380         entity e = bot_list;
 381         while (e)
 382         {
 383                 setcolor(e, e.bot_preferredcolors);
 384                 e = e.nextbot;
 385         }
 386         // if dynamic waypoints are ever implemented, save them here
 387 }
 388
 389 void bot_relinkplayerlist()
 390 {
 391         player_count = 0;
 392         currentbots = 0;
 393         bot_list = NULL;
 394
 395         entity prevbot = NULL;
 396         FOREACH_CLIENT(true,
 397         {
 398                 ++player_count;
 399
 400                 if(IS_BOT_CLIENT(it))
 401                 {
 402                         if (!IS_OBSERVER(it) && !bot_ispaused(it))
 403                         {
 404                                 if(prevbot)
 405                                         prevbot.nextbot = it;
 406                                 else
 407                                         bot_list = it;
 408                                 prevbot = it;
 409                         }
 410                         ++currentbots;
 411                 }
 412         });
 413         if(prevbot)
 414                 prevbot.nextbot = NULL;
 415         bot_strategytoken = bot_list;
 416         bot_strategytoken_taken = true;
 417 }
 418
 419 void bot_clientdisconnect(entity this)
 420 {
 421         if (!IS_BOT_CLIENT(this))
 422                 return;
 423         bot_clearqueue(this);
 424         strfree(this.cleanname);
 425         strfree(this.netname_freeme);
 426         strfree(this.playermodel_freeme);
 427         strfree(this.playerskin_freeme);
 428         if(this.bot_cmd_current)
 429                 delete(this.bot_cmd_current);
 430         if(bot_waypoint_queue_owner == this)
 431                 bot_waypoint_queue_owner = NULL;
 432 }
 433
 434 void bot_clientconnect(entity this)
 435 {
 436         if (!IS_BOT_CLIENT(this)) return;
 437         this.bot_preferredcolors = this.clientcolors;
 438         this.bot_nextthink = time - random();
 439         this.lag_func = bot_lagfunc;
 440         this.isbot = true;
 441         this.createdtime = this.bot_nextthink;
 442
 443         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 444         {
 445                 bot_setnameandstuff(this);
 446                 bot_setclientfields(this);
 447         }
 448
 449         havocbot_setupbot(this);
 450 }
 451
 452 void bot_removefromlargestteam()
 453 {
 454         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 455         TeamBalance_GetTeamCounts(balance, NULL);
 456
 457         entity best = NULL;
 458         float besttime = 0;
 459         int bestcount = 0;
 460
 461         int bcount = 0;
 462         FOREACH_CLIENT(it.isbot,
 463         {
 464                 ++bcount;
 465
 466                 if(!best)
 467                 {
 468                         best = it;
 469                         besttime = it.createdtime;
 470                 }
 471
 472                 int thiscount = 0;
 473
 474                 if (Team_IsValidTeam(it.team))
 475                 {
 476                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 477                                 Team_TeamToIndex(it.team));
 478                 }
 479
 480                 if(thiscount > bestcount)
 481                 {
 482                         bestcount = thiscount;
 483                         besttime = it.createdtime;
 484                         best = it;
 485                 }
 486                 else if(thiscount == bestcount && besttime < it.createdtime)
 487                 {
 488                         besttime = it.createdtime;
 489                         best = it;
 490                 }
 491         });
 492         TeamBalance_Destroy(balance);
 493         if(!bcount)
 494                 return; // no bots to remove
 495         currentbots = currentbots - 1;
 496         dropclient(best);
 497 }
 498
 499 void bot_removenewest()
 500 {
 501         if(teamplay)
 502         {
 503                 bot_removefromlargestteam();
 504                 return;
 505         }
 506
 507         float besttime = 0;
 508         entity best = NULL;
 509         int bcount = 0;
 510
 511         FOREACH_CLIENT(it.isbot,
 512         {
 513                 ++bcount;
 514
 515                 if(!best)
 516                 {
 517                         best = it;
 518                         besttime = it.createdtime;
 519                 }
 520
 521                 if(besttime < it.createdtime)
 522                 {
 523                         besttime = it.createdtime;
 524                         best = it;
 525                 }
 526         });
 527
 528         if(!bcount)
 529                 return; // no bots to remove
 530
 531         currentbots = currentbots - 1;
 532         dropclient(best);
 533 }
 534
 535 void autoskill(float factor)
 536 {
 537         int bestbot = -1;
 538         int bestplayer = -1;
 539         FOREACH_CLIENT(IS_PLAYER(it), {
 540                 if(IS_REAL_CLIENT(it))
 541                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 542                 else
 543                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 544         });
 545
 546         string msg = strcat("autoskill: best player got ", ftos(bestplayer), ", ""best bot got ", ftos(bestbot), "; ");
 547         if(bestbot < 0 || bestplayer < 0)
 548         {
 549                 msg = strcat(msg, "not doing anything");
 550                 // don't return, let it reset all counters below
 551         }
 552         else if(bestbot <= bestplayer * factor - 2)
 553         {
 554                 if(autocvar_skill < 17)
 555                 {
 556                         msg = strcat(msg, "2 frags difference, increasing skill");
 557                         cvar_set("skill", ftos(autocvar_skill + 1));
 558                         bprint("^2BOT SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 559                 }
 560         }
 561         else if(bestbot >= bestplayer * factor + 2)
 562         {
 563                 if(autocvar_skill > 0)
 564                 {
 565                         msg = strcat(msg, "2 frags difference, decreasing skill");
 566                         cvar_set("skill", ftos(autocvar_skill - 1));
 567                         bprint("^1BOT SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 568                 }
 569         }
 570         else
 571         {
 572                 msg = strcat(msg, "not doing anything");
 573                 return;
 574                 // don't reset counters, wait for them to accumulate
 575         }
 576         LOG_DEBUG(msg);
 577
 578         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 579 }
 580
 581 void bot_calculate_stepheightvec()
 582 {
 583         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 584         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 585         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 586         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 587 }
 588
 589 bool bot_fixcount(bool multiple_per_frame)
 590 {
 591         int activerealplayers = 0;
 592         int realplayers = 0;
 593         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 594                 activerealplayers = M_ARGV(0, int);
 595                 realplayers = M_ARGV(1, int);
 596         } else {
 597                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 598                         if(IS_PLAYER(it))
 599                                 ++activerealplayers;
 600                         ++realplayers;
 601                 });
 602         }
 603
 604         int bots;
 605         // But don't remove bots immediately on level change, as the real players
 606         // usually haven't rejoined yet
 607         bots_would_leave = false;
 608         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 609                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 610         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 611         {
 612                 int minplayers = max(0, floor(autocvar_minplayers));
 613                 if (teamplay)
 614                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 615                 int minbots = max(0, floor(autocvar_bot_number));
 616
 617                 // add bots to reach minplayers if needed
 618                 bots = max(minbots, minplayers - activerealplayers);
 619                 // cap bots to the max players allowed by the server
 620                 int player_limit = GetPlayerLimit();
 621                 if(player_limit)
 622                         bots = min(bots, max(player_limit - activerealplayers, 0));
 623                 bots = min(bots, maxclients - realplayers);
 624
 625                 if(bots > minbots)
 626                         bots_would_leave = true;
 627         }
 628         else
 629         {
 630                 // if there are no players, remove bots
 631                 bots = 0;
 632         }
 633
 634         // only add one bot per frame to avoid utter chaos
 635         if(time > botframe_nextthink)
 636         {
 637                 while (currentbots < bots)
 638                 {
 639                         if (bot_spawn() == NULL)
 640                         {
 641                                 bprint("Can not add bot, server full.\n");
 642                                 return false;
 643                         }
 644                         if (!multiple_per_frame)
 645                         {
 646                                 break;
 647                         }
 648                 }
 649                 while (currentbots > bots && bots >= 0)
 650                         bot_removenewest();
 651         }
 652
 653         return true;
 654 }
 655
 656 void bot_serverframe()
 657 {
 658         if (intermission_running && currentbots > 0)
 659         {
 660                 // after the end of the match all bots stay unless all human players disconnect
 661                 int realplayers = 0;
 662                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 663                 if (!realplayers)
 664                 {
 665                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 666                         currentbots = 0;
 667                 }
 668                 return;
 669         }
 670
 671         if (game_stopped)
 672                 return;
 673
 674         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 675         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 676         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 677         // either intentionally or automatically (sv_spectate 0)
 678         // A working workaround for this bug was implemented in commit fbd145044, see entcs_attach
 679         if (time < 2.5)
 680         {
 681                 currentbots = -1;
 682                 return;
 683         }
 684
 685         if (currentbots == -1)
 686         {
 687                 // count bots already in the server from the previous match
 688                 currentbots = 0;
 689                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 690         }
 691
 692         if(autocvar_skill != skill)
 693         {
 694                 float wpcost_update = false;
 695                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 696                         wpcost_update = true;
 697                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 698                         wpcost_update = true;
 699
 700                 skill = autocvar_skill;
 701                 if (wpcost_update)
 702                         waypoint_updatecost_foralllinks();
 703         }
 704
 705         bot_calculate_stepheightvec();
 706         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 707
 708         if(time > autoskill_nextthink)
 709         {
 710                 float a;
 711                 a = autocvar_skill_auto;
 712                 if(a)
 713                         autoskill(a);
 714                 autoskill_nextthink = time + 5;
 715         }
 716
 717         if(time > botframe_nextthink)
 718         {
 719                 if(!bot_fixcount(false))
 720                         botframe_nextthink = time + 10;
 721         }
 722
 723         if(botframe_spawnedwaypoints)
 724         {
 725                 if(autocvar_waypoint_benchmark)
 726                         localcmd("quit\n");
 727         }
 728
 729         if (currentbots > 0 || waypointeditor_enabled || autocvar_g_waypointeditor_auto)
 730         if (botframe_spawnedwaypoints)
 731         {
 732                 if(botframe_cachedwaypointlinks)
 733                 {
 734                         if(!botframe_loadedforcedlinks)
 735                                 waypoint_load_hardwiredlinks();
 736                 }
 737                 else
 738                 {
 739                         // TODO: Make this check cleaner
 740                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 741                         {
 742                                 waypoint_save_links();
 743                                 break;
 744                         });
 745                 }
 746         }
 747         else
 748         {
 749                 botframe_spawnedwaypoints = true;
 750                 waypoint_loadall();
 751                 waypoint_load_links();
 752         }
 753
 754         if (bot_list)
 755         {
 756                 // cycle the goal token from one bot to the next each frame
 757                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 758                 //  frame, which causes choppy framerates)
 759                 if (bot_strategytoken_taken)
 760                 {
 761                         // give goal token to the first bot without goals; if all bots don't have
 762                         // any goal (or are dead/frozen) simply give it to the next one
 763                         bot_strategytoken_taken = false;
 764                         entity bot_strategytoken_save = bot_strategytoken;
 765                         while (true)
 766                         {
 767                                 if (bot_strategytoken)
 768                                         bot_strategytoken = bot_strategytoken.nextbot;
 769                                 if (!bot_strategytoken)
 770                                         bot_strategytoken = bot_list;
 771
 772                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 773                                         && !bot_strategytoken.goalcurrent)
 774                                         break;
 775
 776                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 777                                         break;
 778                                 if (bot_strategytoken == bot_strategytoken_save)
 779                                         bot_strategytoken_save = NULL; // looped through all the bots
 780                         }
 781                 }
 782
 783                 if (botframe_nextdangertime < time)
 784                 {
 785                         float interval;
 786                         interval = autocvar_bot_ai_dangerdetectioninterval;
 787                         if (botframe_nextdangertime < time - interval * 1.5)
 788                                 botframe_nextdangertime = time;
 789                         botframe_nextdangertime = botframe_nextdangertime + interval;
 790                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 791                 }
 792         }
 793
 794         if (waypointeditor_enabled)
 795                 botframe_showwaypointlinks();
 796
 797         if (autocvar_g_waypointeditor_auto)
 798                 botframe_autowaypoints();
 799
 800         if (currentbots > 0)
 801                 bot_custom_weapon_priority_setup();
 802 }