qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/mapinfo.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/physics/player.qh>
   7 #include <common/stats.qh>
   8 #include <common/teams.qh>
   9 #include <common/util.qh>
  10 #include <common/weapons/_all.qh>
  11 #include <lib/csqcmodel/sv_model.qh>
  12 #include <lib/warpzone/common.qh>
  13 #include <lib/warpzone/util_server.qh>
  14 #include <server/antilag.qh>
  15 #include <server/bot/default/aim.qh>
  16 #include <server/bot/default/cvars.qh>
  17 #include <server/bot/default/havocbot/havocbot.qh>
  18 #include <server/bot/default/havocbot/scripting.qh>
  19 #include <server/bot/default/navigation.qh>
  20 #include <server/bot/default/scripting.qh>
  21 #include <server/bot/default/waypoints.qh>
  22 #include <server/campaign.qh>
  23 #include <server/client.qh>
  24 #include <server/damage.qh>
  25 #include <server/items/items.qh>
  26 #include <server/mutators/_mod.qh>
  27 #include <server/race.qh>
  28 #include <server/scores_rules.qh>
  29 #include <server/teamplay.qh>
  30 #include <server/weapons/accuracy.qh>
  31 #include <server/weapons/selection.qh>
  32 #include <server/world.qh>
  33 #include <server/command/vote.qh>
  34
  35 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  36
  37 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  38 void bot_setclientfields(entity this)
  39 {
  40         CS_CVAR(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  41         CS_CVAR(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  42 }
  43
  44 entity bot_spawn()
  45 {
  46         entity bot = spawnclient();
  47         if (bot)
  48         {
  49                 setItemGroupCount();
  50                 currentbots = currentbots + 1;
  51                 bot_setnameandstuff(bot);
  52                 ClientConnect(bot);
  53                 bot_setclientfields(bot);
  54                 PutClientInServer(bot);
  55         }
  56         return bot;
  57 }
  58
  59 void bot_think(entity this)
  60 {
  61         if (this.bot_nextthink > time)
  62                 return;
  63
  64         this.flags &= ~FL_GODMODE;
  65         if(autocvar_bot_god)
  66                 this.flags |= FL_GODMODE;
  67
  68         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * min(14 / (skill + this.bot_aiskill + 14), 1));
  69
  70         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  71         {
  72                 if (IS_PLAYER(this))
  73                 {
  74                         .entity weaponentity = weaponentities[0];
  75                         if(this.(weaponentity).m_weapon == WEP_Null)
  76                                 W_NextWeapon(this, 0, weaponentity);
  77                 }
  78                 CS(this).movement = '0 0 0';
  79                 this.bot_nextthink = time + 0.5;
  80                 return;
  81         }
  82
  83         if (this.fixangle)
  84         {
  85                 this.v_angle = this.angles;
  86                 this.v_angle_z = 0;
  87                 this.fixangle = false;
  88         }
  89
  90         this.dmg_take = 0;
  91         this.dmg_save = 0;
  92         this.dmg_inflictor = NULL;
  93
  94         // calculate an aiming latency based on the skill setting
  95         // (simulated network latency + naturally delayed reflexes)
  96         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  97         // minimum ping 20+10 random
  98         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
  99         // skill 10 = ping 0.2 (adrenaline)
 100         // skill 0 = ping 0.7 (slightly drunk)
 101
 102         // clear buttons
 103         PHYS_INPUT_BUTTON_ATCK(this) = false;
 104         // keep jump button pressed for a short while, useful with ramp jumps
 105         PHYS_INPUT_BUTTON_JUMP(this) = (!IS_DEAD(this) && time < this.bot_jump_time + 0.2);
 106         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 107         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 108         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 109         PHYS_INPUT_BUTTON_HOOK(this) = false;
 110         PHYS_INPUT_BUTTON_INFO(this) = false;
 111         PHYS_INPUT_BUTTON_DRAG(this) = false;
 112         PHYS_INPUT_BUTTON_CHAT(this) = false;
 113         PHYS_INPUT_BUTTON_USE(this) = false;
 114
 115         if (time < game_starttime)
 116         {
 117                 .entity weaponentity = weaponentities[0];
 118                 if(this.(weaponentity).m_weapon == WEP_Null)
 119                         W_NextWeapon(this, 0, weaponentity);
 120                 // block the bot during the countdown to game start
 121                 CS(this).movement = '0 0 0';
 122                 return;
 123         }
 124
 125         // if dead, just wait until we can respawn
 126         if (IS_DEAD(this) || IS_OBSERVER(this))
 127         {
 128                 if (bot_waypoint_queue_owner == this)
 129                         bot_waypoint_queue_owner = NULL;
 130                 this.aistatus = 0;
 131                 CS(this).movement = '0 0 0';
 132                 if (IS_OBSERVER(this))
 133                         return;
 134                 if (IS_DEAD(this))
 135                 {
 136                         if (!navigation_goalrating_timeout(this))
 137                                 navigation_goalrating_timeout_force(this);
 138                         // jump must not be pressed for at least one frame in order for
 139                         // PlayerThink to detect the key down event
 140                         if (this.deadflag == DEAD_DYING)
 141                                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 142                         else if (this.deadflag == DEAD_DEAD)
 143                                 PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 144                 }
 145         }
 146         else if(this.aistatus & AI_STATUS_STUCK)
 147                 navigation_unstuck(this);
 148
 149         if (warmup_stage && !this.ready)
 150         {
 151                 this.ready = true;
 152                 ReadyCount(); // this must be delayed until the bot has spawned
 153         }
 154
 155         // now call the current bot AI (havocbot for example)
 156         this.bot_ai(this);
 157 }
 158
 159 void bot_setnameandstuff(entity this)
 160 {
 161         string readfile, s;
 162         int file, tokens, prio;
 163
 164         file = fopen(autocvar_bot_config_file, FILE_READ);
 165
 166         if(file < 0)
 167         {
 168                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 169                 readfile = "";
 170         }
 171         else
 172         {
 173                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 174                 TeamBalance_GetTeamCounts(balance, NULL);
 175                 int smallest_team = -1;
 176                 int smallest_count = -1;
 177                 if (teamplay)
 178                 {
 179                         for (int i = 1; i <= AVAILABLE_TEAMS; ++i)
 180                         {
 181                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 182                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 183                                 // since it keeps a spot for the real player in the desired team
 184                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 185                                 if (smallest_count < 0 || count < smallest_count)
 186                                 {
 187                                         smallest_team = i;
 188                                         smallest_count = count;
 189                                 }
 190                         }
 191                 }
 192                 TeamBalance_Destroy(balance);
 193                 RandomSelection_Init();
 194                 while((readfile = fgets(file)))
 195                 {
 196                         if(substring(readfile, 0, 2) == "//")
 197                                 continue;
 198                         if(substring(readfile, 0, 1) == "#")
 199                                 continue;
 200                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 201                         // will create 1 empty token because there's no separator (bug?)
 202                         if (readfile == "")
 203                                 continue;
 204                         tokens = tokenizebyseparator(readfile, "\t");
 205                         if(tokens == 0)
 206                                 continue;
 207                         s = argv(0);
 208                         prio = 0;
 209                         bool conflict = false;
 210                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 211                                 if (s == it.cleanname)
 212                                 {
 213                                         conflict = true;
 214                                         break;
 215                                 }
 216                         });
 217                         if (!conflict)
 218                                 prio += 1;
 219                         if (teamplay && !(autocvar_bot_vs_human && AVAILABLE_TEAMS == 2))
 220                         {
 221                                 int forced_team = stof(argv(5));
 222                                 if (!Team_IsValidIndex(forced_team))
 223                                         forced_team = 0;
 224                                 if (!forced_team || forced_team == smallest_team)
 225                                         prio += 2;
 226                         }
 227                         RandomSelection_AddString(readfile, 1, prio);
 228                 }
 229                 readfile = RandomSelection_chosen_string;
 230                 fclose(file);
 231         }
 232
 233         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 234
 235         tokens = tokenizebyseparator(readfile, "\t");
 236         if(argv(0) != "") bot_name = argv(0);
 237         else bot_name = "Bot";
 238
 239         if(argv(1) != "") bot_model = argv(1);
 240         else bot_model = "";
 241
 242         if(argv(2) != "") bot_skin = argv(2);
 243         else bot_skin = "0";
 244
 245         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 246         else bot_shirt = ftos(floor(random() * 15));
 247
 248         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 249         else bot_pants = ftos(floor(random() * 15));
 250
 251         if (teamplay && !(autocvar_bot_vs_human && AVAILABLE_TEAMS == 2))
 252         {
 253                 this.bot_forced_team = stof(argv(5));
 254                 if (!Team_IsValidIndex(this.bot_forced_team))
 255                         this.bot_forced_team = 0;
 256         }
 257         else
 258                 this.bot_forced_team = 0;
 259
 260         prio = 6;
 261
 262         #define READSKILL(f, w, r) MACRO_BEGIN \
 263                 if(argv(prio) != "") \
 264                         this.f = stof(argv(prio)) * w; \
 265                 else \
 266                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 267                 prio++; \
 268         MACRO_END
 269         //print(bot_name, ": ping=", argv(9), "\n");
 270
 271         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 272         READSKILL(bot_moveskill, 2, 0); // move skill
 273         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 274
 275         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 276
 277         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 278         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 279         READSKILL(bot_rangepreference, 1, 0); // read skill
 280
 281         READSKILL(bot_aimskill, 2, 0); // aim skill
 282         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 283         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 284
 285         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 286         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 287
 288         if (file >= 0 && argv(prio) != "")
 289                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 290
 291         this.bot_config_loaded = true;
 292
 293         // this is really only a default, TeamBalance_JoinBestTeam is called later
 294         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 295         this.bot_preferredcolors = this.clientcolors;
 296
 297         string prefix = (autocvar_g_campaign ? "" : autocvar_bot_prefix);
 298         string suffix = (autocvar_g_campaign ? "" : autocvar_bot_suffix);
 299         string name = (autocvar_bot_usemodelnames ? bot_model : bot_name);
 300
 301         if (name == "")
 302         {
 303                 name = ftos(etof(this));
 304                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 305         }
 306         else
 307         {
 308                 // number bots with identical names
 309                 int j = 0;
 310                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 311                         if(it.cleanname == name)
 312                                 ++j;
 313                 });
 314                 if (j)
 315                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 316                 else
 317                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 318         }
 319         this.cleanname = strzone(name);
 320
 321         // pick the model and skin
 322         if(substring(bot_model, -4, 1) != ".")
 323                 bot_model = strcat(bot_model, ".iqm");
 324         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 325         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 326 }
 327
 328 void bot_custom_weapon_priority_setup()
 329 {
 330         static string bot_priority_far_prev;
 331         static string bot_priority_mid_prev;
 332         static string bot_priority_close_prev;
 333         static string bot_priority_distances_prev;
 334         float tokens, i, w;
 335
 336         bot_custom_weapon = false;
 337
 338         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 339                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 340                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 341                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 342         )
 343                 return;
 344
 345         if (bot_priority_distances_prev != autocvar_bot_ai_custom_weapon_priority_distances)
 346         {
 347                 strcpy(bot_priority_distances_prev, autocvar_bot_ai_custom_weapon_priority_distances);
 348                 tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 349
 350                 if (tokens!=2)
 351                         return;
 352
 353                 bot_distance_far = stof(argv(0));
 354                 bot_distance_close = stof(argv(1));
 355
 356                 if(bot_distance_far < bot_distance_close){
 357                         bot_distance_far = stof(argv(1));
 358                         bot_distance_close = stof(argv(0));
 359                 }
 360         }
 361
 362         int c;
 363
 364         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
 365                 if (bot_priority_##dist##_prev != autocvar_bot_ai_custom_weapon_priority_##dist) { \
 366                         strcpy(bot_priority_##dist##_prev, autocvar_bot_ai_custom_weapon_priority_##dist); \
 367                         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
 368                         bot_weapons_##dist[0] = -1; \
 369                         c = 0; \
 370                         for(i = 0; i < tokens && c < REGISTRY_COUNT(Weapons); ++i) { \
 371                                 w = stof(argv(i)); \
 372                                 if (w >= WEP_FIRST && w <= WEP_LAST) { \
 373                                         bot_weapons_##dist[c] = w; \
 374                                         ++c; \
 375                                 } \
 376                         } \
 377                         if (c < REGISTRY_COUNT(Weapons)) \
 378                                 bot_weapons_##dist[c] = -1; \
 379                 } \
 380         MACRO_END
 381
 382         PARSE_WEAPON_PRIORITIES(far);
 383         PARSE_WEAPON_PRIORITIES(mid);
 384         PARSE_WEAPON_PRIORITIES(close);
 385
 386         bot_custom_weapon = true;
 387 }
 388
 389 void bot_endgame()
 390 {
 391         bot_relinkplayerlist();
 392         entity e = bot_list;
 393         while (e)
 394         {
 395                 setcolor(e, e.bot_preferredcolors);
 396                 e = e.nextbot;
 397         }
 398         // if dynamic waypoints are ever implemented, save them here
 399 }
 400
 401 void bot_relinkplayerlist()
 402 {
 403         player_count = 0;
 404         currentbots = 0;
 405         bot_list = NULL;
 406
 407         entity prevbot = NULL;
 408         FOREACH_CLIENT(true,
 409         {
 410                 ++player_count;
 411
 412                 if(IS_BOT_CLIENT(it))
 413                 {
 414                         if (!IS_OBSERVER(it) && !bot_ispaused(it))
 415                         {
 416                                 if(prevbot)
 417                                         prevbot.nextbot = it;
 418                                 else
 419                                         bot_list = it;
 420                                 prevbot = it;
 421                         }
 422                         ++currentbots;
 423                 }
 424         });
 425         if(prevbot)
 426                 prevbot.nextbot = NULL;
 427         bot_strategytoken = bot_list;
 428         bot_strategytoken_taken = true;
 429 }
 430
 431 void bot_clientdisconnect(entity this)
 432 {
 433         if (!IS_BOT_CLIENT(this))
 434                 return;
 435         bot_clearqueue(this);
 436         strfree(this.cleanname);
 437         strfree(this.netname_freeme);
 438         strfree(this.playermodel_freeme);
 439         strfree(this.playerskin_freeme);
 440         if(this.bot_cmd_current)
 441                 delete(this.bot_cmd_current);
 442         if(bot_waypoint_queue_owner == this)
 443                 bot_waypoint_queue_owner = NULL;
 444 }
 445
 446 void bot_clientconnect(entity this)
 447 {
 448         if (!IS_BOT_CLIENT(this)) return;
 449         this.bot_preferredcolors = this.clientcolors;
 450         this.bot_nextthink = time - random();
 451         this.isbot = true;
 452         this.createdtime = this.bot_nextthink;
 453
 454         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 455         {
 456                 bot_setnameandstuff(this);
 457                 bot_setclientfields(this);
 458         }
 459
 460         havocbot_setupbot(this);
 461 }
 462
 463 void bot_removefromlargestteam()
 464 {
 465         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 466         TeamBalance_GetTeamCounts(balance, NULL);
 467
 468         entity best = NULL;
 469         float besttime = 0;
 470         int bestcount = 0;
 471
 472         int bcount = 0;
 473         FOREACH_CLIENT(it.isbot,
 474         {
 475                 ++bcount;
 476
 477                 if(!best)
 478                 {
 479                         best = it;
 480                         besttime = it.createdtime;
 481                 }
 482
 483                 int thiscount = 0;
 484
 485                 if (Team_IsValidTeam(it.team))
 486                 {
 487                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 488                                 Team_TeamToIndex(it.team));
 489                 }
 490
 491                 if(thiscount > bestcount)
 492                 {
 493                         bestcount = thiscount;
 494                         besttime = it.createdtime;
 495                         best = it;
 496                 }
 497                 else if(thiscount == bestcount && besttime < it.createdtime)
 498                 {
 499                         besttime = it.createdtime;
 500                         best = it;
 501                 }
 502         });
 503         TeamBalance_Destroy(balance);
 504         if(!bcount)
 505                 return; // no bots to remove
 506         currentbots = currentbots - 1;
 507         dropclient(best);
 508 }
 509
 510 void bot_removenewest()
 511 {
 512         if(teamplay)
 513         {
 514                 bot_removefromlargestteam();
 515                 return;
 516         }
 517
 518         float besttime = 0;
 519         entity best = NULL;
 520         int bcount = 0;
 521
 522         FOREACH_CLIENT(it.isbot,
 523         {
 524                 ++bcount;
 525
 526                 if(!best)
 527                 {
 528                         best = it;
 529                         besttime = it.createdtime;
 530                 }
 531
 532                 if(besttime < it.createdtime)
 533                 {
 534                         besttime = it.createdtime;
 535                         best = it;
 536                 }
 537         });
 538
 539         if(!bcount)
 540                 return; // no bots to remove
 541
 542         currentbots = currentbots - 1;
 543         dropclient(best);
 544 }
 545
 546 void autoskill(float factor)
 547 {
 548         int bestbot = -1;
 549         int bestplayer = -1;
 550         FOREACH_CLIENT(IS_PLAYER(it), {
 551                 if(IS_REAL_CLIENT(it))
 552                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 553                 else
 554                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 555         });
 556
 557         string msg = strcat("autoskill: best player got ", ftos(bestplayer), ", ""best bot got ", ftos(bestbot), "; ");
 558         if(bestbot < 0 || bestplayer < 0)
 559         {
 560                 msg = strcat(msg, "not doing anything");
 561                 // don't return, let it reset all counters below
 562         }
 563         else if(bestbot <= bestplayer * factor - 2)
 564         {
 565                 if(autocvar_skill < 17)
 566                 {
 567                         msg = strcat(msg, "2 frags difference, increasing skill");
 568                         cvar_set("skill", ftos(autocvar_skill + 1));
 569                         bprint("^2BOT SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 570                 }
 571         }
 572         else if(bestbot >= bestplayer * factor + 2)
 573         {
 574                 if(autocvar_skill > 0)
 575                 {
 576                         msg = strcat(msg, "2 frags difference, decreasing skill");
 577                         cvar_set("skill", ftos(autocvar_skill - 1));
 578                         bprint("^1BOT SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 579                 }
 580         }
 581         else
 582         {
 583                 msg = strcat(msg, "not doing anything");
 584                 return;
 585                 // don't reset counters, wait for them to accumulate
 586         }
 587         LOG_DEBUG(msg);
 588
 589         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 590 }
 591
 592 void bot_calculate_stepheightvec()
 593 {
 594         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 595         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 596         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 597         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 598 }
 599
 600 bool bot_fixcount(bool multiple_per_frame)
 601 {
 602         int activerealplayers = 0;
 603         int realplayers = 0;
 604         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 605                 activerealplayers = M_ARGV(0, int);
 606                 realplayers = M_ARGV(1, int);
 607         } else {
 608                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 609                         if(IS_PLAYER(it))
 610                                 ++activerealplayers;
 611                         ++realplayers;
 612                 });
 613         }
 614
 615         int bots;
 616         // But don't remove bots immediately on level change, as the real players
 617         // usually haven't rejoined yet
 618         bots_would_leave = false;
 619         if (autocvar_bot_vs_human && AVAILABLE_TEAMS == 2)
 620                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 621         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 622         {
 623                 int minplayers = max(0, floor(autocvar_minplayers));
 624                 if (teamplay)
 625                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AVAILABLE_TEAMS);
 626                 int minbots = max(0, floor(autocvar_bot_number));
 627
 628                 // add bots to reach minplayers if needed
 629                 bots = max(minbots, minplayers - activerealplayers);
 630                 // cap bots to the max players allowed by the server
 631                 int player_limit = GetPlayerLimit();
 632                 if(player_limit)
 633                         bots = min(bots, max(player_limit - activerealplayers, 0));
 634                 bots = min(bots, maxclients - realplayers);
 635
 636                 if(bots > minbots)
 637                         bots_would_leave = true;
 638         }
 639         else
 640         {
 641                 // if there are no players, remove bots
 642                 bots = 0;
 643         }
 644
 645         // only add one bot per frame to avoid utter chaos
 646         if(time > botframe_nextthink)
 647         {
 648                 while (currentbots < bots)
 649                 {
 650                         if (bot_spawn() == NULL)
 651                         {
 652                                 bprint("Can not add bot, server full.\n");
 653                                 return false;
 654                         }
 655                         if (!multiple_per_frame)
 656                         {
 657                                 break;
 658                         }
 659                 }
 660                 while (currentbots > bots && bots >= 0)
 661                         bot_removenewest();
 662         }
 663
 664         return true;
 665 }
 666
 667 void bot_serverframe()
 668 {
 669         if (intermission_running && currentbots > 0)
 670         {
 671                 // after the end of the match all bots stay unless all human players disconnect
 672                 int realplayers = 0;
 673                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 674                 if (!realplayers)
 675                 {
 676                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 677                         currentbots = 0;
 678                 }
 679                 return;
 680         }
 681
 682         if (game_stopped)
 683                 return;
 684
 685         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 686         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 687         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 688         // either intentionally or automatically (sv_spectate 0)
 689         // A working workaround for this bug was implemented in commit fbd145044, see entcs_attach
 690         if (time < 2.5)
 691         {
 692                 currentbots = -1;
 693                 return;
 694         }
 695
 696         if (currentbots == -1)
 697         {
 698                 // count bots already in the server from the previous match
 699                 currentbots = 0;
 700                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 701         }
 702
 703         if(autocvar_skill != skill)
 704         {
 705                 float wpcost_update = false;
 706                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 707                         wpcost_update = true;
 708                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 709                         wpcost_update = true;
 710
 711                 skill = autocvar_skill;
 712                 if (wpcost_update)
 713                         waypoint_updatecost_foralllinks();
 714         }
 715
 716         bot_calculate_stepheightvec();
 717         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 718
 719         if(time > autoskill_nextthink)
 720         {
 721                 float a;
 722                 a = autocvar_skill_auto;
 723                 if(a)
 724                         autoskill(a);
 725                 autoskill_nextthink = time + 5;
 726         }
 727
 728         if(time > botframe_nextthink)
 729         {
 730                 if(!bot_fixcount(false))
 731                         botframe_nextthink = time + 10;
 732         }
 733
 734         if(botframe_spawnedwaypoints)
 735         {
 736                 if(autocvar_waypoint_benchmark)
 737                         localcmd("quit\n");
 738         }
 739
 740         if (currentbots > 0 || waypointeditor_enabled || autocvar_g_waypointeditor_auto)
 741         if (botframe_spawnedwaypoints)
 742         {
 743                 if(botframe_cachedwaypointlinks)
 744                 {
 745                         if(!botframe_loadedforcedlinks)
 746                                 waypoint_load_hardwiredlinks();
 747                 }
 748                 else
 749                 {
 750                         // TODO: Make this check cleaner
 751                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 752                         {
 753                                 waypoint_save_links();
 754                                 break;
 755                         });
 756                 }
 757         }
 758         else
 759         {
 760                 botframe_spawnedwaypoints = true;
 761                 waypoint_loadall();
 762                 waypoint_load_links();
 763         }
 764
 765         if (bot_list)
 766         {
 767                 // cycle the goal token from one bot to the next each frame
 768                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 769                 //  frame, which causes choppy framerates)
 770                 if (bot_strategytoken_taken)
 771                 {
 772                         // give goal token to the first bot without goals; if all bots don't have
 773                         // any goal (or are dead/frozen) simply give it to the next one
 774                         bot_strategytoken_taken = false;
 775                         entity bot_strategytoken_save = bot_strategytoken;
 776                         while (true)
 777                         {
 778                                 if (bot_strategytoken)
 779                                         bot_strategytoken = bot_strategytoken.nextbot;
 780                                 if (!bot_strategytoken)
 781                                         bot_strategytoken = bot_list;
 782
 783                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 784                                         && !bot_strategytoken.goalcurrent)
 785                                         break;
 786
 787                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 788                                         break;
 789                                 if (bot_strategytoken == bot_strategytoken_save)
 790                                         bot_strategytoken_save = NULL; // looped through all the bots
 791                         }
 792                 }
 793
 794                 if (botframe_nextdangertime < time)
 795                 {
 796                         float interval;
 797                         interval = autocvar_bot_ai_dangerdetectioninterval;
 798                         if (botframe_nextdangertime < time - interval * 1.5)
 799                                 botframe_nextdangertime = time;
 800                         botframe_nextdangertime = botframe_nextdangertime + interval;
 801                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 802                 }
 803         }
 804
 805         if (waypointeditor_enabled)
 806                 botframe_showwaypointlinks();
 807
 808         if (autocvar_g_waypointeditor_auto)
 809                 botframe_autowaypoints();
 810
 811         if (currentbots > 0)
 812                 bot_custom_weapon_priority_setup();
 813 }