qcsrc/menu/xonotic/weaponslist.qc

   1 #ifndef WEAPONSLIST_H
   2 #define WEAPONSLIST_H
   3 CLASS(XonoticWeaponsList, XonoticListBox)
   4         METHOD(XonoticWeaponsList, configureXonoticWeaponsList, void(entity))
   5         METHOD(XonoticWeaponsList, toString, string(entity))
   6         ATTRIB(XonoticWeaponsList, rowsPerItem, float, 1)
   7         METHOD(XonoticWeaponsList, draw, void(entity))
   8         METHOD(XonoticWeaponsList, drawListBoxItem, void(entity, float, vector, float))
   9         METHOD(XonoticWeaponsList, resizeNotify, void(entity, vector, vector, vector, vector))
  10         METHOD(XonoticWeaponsList, keyDown, float(entity, float, float, float))
  11         ATTRIB(XonoticWeaponsList, realFontSize, vector, '0 0 0')
  12         ATTRIB(XonoticWeaponsList, realUpperMargin, float, 0)
  13         METHOD(XonoticWeaponsList, mouseDrag, float(entity, vector))
  14 ENDCLASS(XonoticWeaponsList)
  15 entity makeXonoticWeaponsList();
  16 void WeaponsList_MoveUp_Click(entity btn, entity me);
  17 void WeaponsList_MoveDown_Click(entity box, entity me);
  18 #endif
  19
  20 #ifdef IMPLEMENTATION
  21 entity makeXonoticWeaponsList()
  22 {
  23         entity me;
  24         me = NEW(XonoticWeaponsList);
  25         me.configureXonoticWeaponsList(me);
  26         return me;
  27 }
  28 void XonoticWeaponsList_configureXonoticWeaponsList(entity me)
  29 {
  30         me.configureXonoticListBox(me);
  31 }
  32 void XonoticWeaponsList_draw(entity me)
  33 {
  34         // read in cvar?
  35         string s, t;
  36         s = W_NumberWeaponOrder(cvar_string("cl_weaponpriority"));
  37         t = W_FixWeaponOrder(s, 1);
  38         if(t != s)
  39                 cvar_set("cl_weaponpriority", W_NameWeaponOrder(t));
  40         me.nItems = tokenize_console(t);
  41         SUPER(XonoticWeaponsList).draw(me);
  42 }
  43 void WeaponsList_MoveUp_Click(entity box, entity me)
  44 {
  45         if(me.selectedItem > 0)
  46         {
  47                 cvar_set("cl_weaponpriority", swapInPriorityList(cvar_string("cl_weaponpriority"), me.selectedItem - 1, me.selectedItem));
  48                 me.selectedItem -= 1;
  49         }
  50 }
  51 void WeaponsList_MoveDown_Click(entity box, entity me)
  52 {
  53         if(me.selectedItem < me.nItems - 1)
  54         {
  55                 cvar_set("cl_weaponpriority", swapInPriorityList(cvar_string("cl_weaponpriority"), me.selectedItem, me.selectedItem + 1));
  56                 me.selectedItem += 1;
  57         }
  58 }
  59 void XonoticWeaponsList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  60 {
  61         SUPER(XonoticWeaponsList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  62
  63         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
  64         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
  65         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
  66 }
  67 float XonoticWeaponsList_mouseDrag(entity me, vector pos)
  68 {
  69         int i = me.selectedItem;
  70         float f = SUPER(XonoticWeaponsList).mouseDrag(me, pos);
  71
  72         if(me.pressed != 1) // don't change priority if the person is just scrolling
  73         {
  74                 if(me.selectedItem != i)
  75                         cvar_set("cl_weaponpriority", swapInPriorityList(cvar_string("cl_weaponpriority"), me.selectedItem, i));
  76         }
  77
  78         return f;
  79 }
  80 string XonoticWeaponsList_toString(entity me)
  81 {
  82         float n, i;
  83         string s;
  84         entity e;
  85         n = tokenize_console(W_NumberWeaponOrder(cvar_string("cl_weaponpriority")));
  86         s = "";
  87         for(i = 0; i < n; ++i)
  88         {
  89                 e = get_weaponinfo(stof(argv(i)));
  90                 s = strcat(s, e.message, ", ");
  91         }
  92         return substring(s, 0, strlen(s) - 2);
  93 }
  94 void XonoticWeaponsList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
  95 {
  96         entity e;
  97         if(isSelected)
  98                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  99         e = get_weaponinfo(stof(argv(i)));
 100         string msg = e.message;
 101         if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 102                 msg = sprintf(_("%s (mutator weapon)"), msg);
 103
 104         vector save_fontscale = draw_fontscale;
 105         float f = draw_CondensedFontFactor(msg, false, me.realFontSize, 1);
 106         draw_fontscale.x *= f;
 107         vector fs = me.realFontSize;
 108         fs.x *= f;
 109         draw_Text(me.realUpperMargin * eY, msg, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
 110         draw_fontscale = save_fontscale;
 111 }
 112
 113 float XonoticWeaponsList_keyDown(entity me, float scan, float ascii, float shift)
 114 {
 115         if(ascii == 43) // +
 116         {
 117                 WeaponsList_MoveUp_Click(NULL, me);
 118                 return 1;
 119         }
 120         else if(ascii == 45) // -
 121         {
 122                 WeaponsList_MoveDown_Click(NULL, me);
 123                 return 1;
 124         }
 125         else if(SUPER(XonoticWeaponsList).keyDown(me, scan, ascii, shift))
 126                 return 1;
 127         return 0;
 128 }
 129 #endif