qcsrc/menu/xonotic/util.qc

   1 #include "util.qh"
   2 #include "../menu.qh"
   3 #include "../../common/campaign_common.qh"
   4 #include "../../common/constants.qh"
   5 #include "../../common/mapinfo.qh"
   6 #include "../../common/util.qh"
   7 #include "../../common/command/generic.qh"
   8
   9 float GL_CheckExtension(string ext)
  10 {
  11         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
  12 }
  13
  14 float GL_Have_TextureCompression()
  15 {
  16         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
  17 }
  18
  19 .entity parent, firstChild, nextSibling;
  20 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  21 {
  22         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  23 }
  24
  25 .string cvarName;
  26 void SUB_Null_ee(entity e1, entity e2)
  27 {
  28 }
  29
  30 .void(entity) saveCvars;
  31 void saveCvarsOf(entity ignore, entity e)
  32 {
  33         if(e.saveCvars)
  34                 e.saveCvars(e);
  35 }
  36
  37 .void(entity) loadCvars;
  38 void loadCvarsOf(entity ignore, entity e)
  39 {
  40         if(e.loadCvars)
  41                 e.loadCvars(e);
  42 }
  43 void saveAllCvars(entity root)
  44 {
  45         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  46 }
  47 void loadAllCvars(entity root)
  48 {
  49         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  50 }
  51
  52 .string cvarNames_Multi;
  53 .void(entity me) saveCvars_Multi;
  54 string getCvarsMulti(entity me)
  55 {
  56         if (me.cvarNames_Multi)
  57                 return me.cvarNames_Multi;
  58         return string_null;
  59 }
  60 void saveCvarsMulti(entity me)
  61 {
  62         float n, i;
  63         string s;
  64
  65         me.saveCvars_Multi(me);
  66         s = cvar_string(me.cvarName);
  67
  68         n = tokenize_console(me.cvarNames_Multi);
  69         for(i = 0; i < n; ++i)
  70         {
  71                 if(substring(argv(i), 0, 1) == "!")
  72                         cvar_set(substring(argv(i), 1, strlen(argv(i))), ((s == "0") ? "1" : "0"));
  73                 else
  74                         cvar_set(argv(i), s);
  75
  76                 CheckSendCvars(me, argv(i));
  77         }
  78 }
  79 void makeMulti(entity e, string otherCvars)
  80 {
  81         e.cvarNames_Multi = otherCvars;
  82         e.saveCvars_Multi = e.saveCvars;
  83         e.saveCvars = saveCvarsMulti;
  84 }
  85
  86 .void(entity me) saveCvars_Callback;
  87 .entity saveCvars_Callback_ent;
  88 .void(entity me, entity cb) saveCvars_Callback_func;
  89 void saveCvarsCallback(entity me)
  90 {
  91         me.saveCvars_Callback(me);
  92         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
  93 }
  94 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
  95 {
  96         e.saveCvars_Callback = e.saveCvars;
  97         e.saveCvars = saveCvarsCallback;
  98         e.saveCvars_Callback_ent = cbent;
  99         e.saveCvars_Callback_func = cbfunc;
 100 }
 101
 102 .void(entity) draw_setDependent;
 103 .string cvar_setDependent;
 104 .float cvarMin_setDependent;
 105 .float cvarMax_setDependent;
 106 .string cvar2_setDependent;
 107 .float cvar2Min_setDependent;
 108 .float cvar2Max_setDependent;
 109 .string cvar3_setDependent;
 110 .float cvar3Min_setDependent;
 111 .float cvar3Max_setDependent;
 112 .float op_setDependent;
 113 .string cvarString_setDependent;
 114 .string cvarValue_setDependent;
 115 .float(entity) func_setDependent;
 116 .bool disabled;
 117 void setDependent_Check(entity e)
 118 {
 119         float f;
 120         string s;
 121         if(e.func_setDependent)
 122         {
 123                 e.disabled = !(e.func_setDependent(e));
 124         }
 125         else if(e.cvarString_setDependent)
 126         {
 127                 s = cvar_string(e.cvarString_setDependent);
 128                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 129         }
 130         else
 131         {
 132                 if(e.cvar_setDependent)
 133                 {
 134                         f = cvar(e.cvar_setDependent);
 135                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 136                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 137                         else
 138                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 139                 }
 140                 if(e.cvar2_setDependent)
 141                 {
 142                         f = cvar(e.cvar2_setDependent);
 143                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 144                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 145                         else
 146                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 147                 }
 148                 if(e.cvar3_setDependent)
 149                 {
 150                         f = cvar(e.cvar3_setDependent);
 151                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 152                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 153                         else
 154                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 155                 }
 156         }
 157 }
 158 void setDependent_Draw(entity e)
 159 {
 160         setDependent_Check(e);
 161         e.draw_setDependent(e);
 162 }
 163 .void(entity) draw;
 164 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 165 {
 166         e.draw_setDependent = e.draw;
 167         e.cvar_setDependent = theCvarName;
 168         e.cvarMin_setDependent = theCvarMin;
 169         e.cvarMax_setDependent = theCvarMax;
 170         e.cvar2_setDependent = string_null;
 171         e.cvar3_setDependent = string_null;
 172         e.func_setDependent = func_null;
 173         e.draw = setDependent_Draw;
 174         setDependent_Check(e);
 175 }
 176 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 177 {
 178         e.draw_setDependent = e.draw;
 179         e.cvarString_setDependent = theCvarName;
 180         e.cvarValue_setDependent = theCvarValue;
 181         e.cvar_setDependent = string_null;
 182         e.cvar2_setDependent = string_null;
 183         e.cvar3_setDependent = string_null;
 184         e.func_setDependent = func_null;
 185         e.draw = setDependent_Draw;
 186         setDependent_Check(e);
 187 }
 188 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 189 {
 190         e.draw_setDependent = e.draw;
 191         e.cvar_setDependent = theCvarName;
 192         e.cvarMin_setDependent = theCvarMin;
 193         e.cvarMax_setDependent = theCvarMax;
 194         e.cvar2_setDependent = theCvar2Name;
 195         e.cvar2Min_setDependent = theCvar2Min;
 196         e.cvar2Max_setDependent = theCvar2Max;
 197         e.cvar3_setDependent = string_null;
 198         e.op_setDependent = 0;
 199         e.func_setDependent = func_null;
 200         e.draw = setDependent_Draw;
 201         setDependent_Check(e);
 202 }
 203 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 204 {
 205         e.draw_setDependent = e.draw;
 206         e.cvar_setDependent = theCvarName;
 207         e.cvarMin_setDependent = theCvarMin;
 208         e.cvarMax_setDependent = theCvarMax;
 209         e.cvar2_setDependent = theCvar2Name;
 210         e.cvar2Min_setDependent = theCvar2Min;
 211         e.cvar2Max_setDependent = theCvar2Max;
 212         e.cvar3_setDependent = string_null;
 213         e.op_setDependent = 1;
 214         e.func_setDependent = func_null;
 215         e.draw = setDependent_Draw;
 216         setDependent_Check(e);
 217 }
 218 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 219 {
 220         e.draw_setDependent = e.draw;
 221         e.cvar_setDependent = theCvarName;
 222         e.cvarMin_setDependent = theCvarMin;
 223         e.cvarMax_setDependent = theCvarMax;
 224         e.cvar2_setDependent = theCvar2Name;
 225         e.cvar2Min_setDependent = theCvar2Min;
 226         e.cvar2Max_setDependent = theCvar2Max;
 227         e.cvar3_setDependent = theCvar3Name;
 228         e.cvar3Min_setDependent = theCvar3Min;
 229         e.cvar3Max_setDependent = theCvar3Max;
 230         e.op_setDependent = 0;
 231         e.func_setDependent = func_null;
 232         e.draw = setDependent_Draw;
 233         setDependent_Check(e);
 234 }
 235 void setDependentWeird(entity e, float(entity) func)
 236 {
 237         e.draw_setDependent = e.draw;
 238         e.func_setDependent = func;
 239         e.draw = setDependent_Draw;
 240         setDependent_Check(e);
 241 }
 242
 243 void setZonedTooltip(entity e, string theTooltip, string theCvar)
 244 {
 245         if(theTooltip == "") // no tooltip, use cvar description then
 246         {
 247                 if(theCvar != "" && prvm_language == "en")
 248                 {
 249                         string t = cvar_description(theCvar);
 250                         if(t != "" && t != "custom cvar")
 251                                 theTooltip = t;
 252                 }
 253         }
 254         else if(theTooltip == "-") // no cvar description as tooltip
 255         {
 256                 theTooltip = string_null;
 257         }
 258
 259         if(e.tooltip)
 260                 strunzone(e.tooltip);
 261         e.tooltip = (theTooltip != "") ? strzone(theTooltip) : string_null;
 262 }
 263
 264 void clearTooltip(entity e)
 265 {
 266         setZonedTooltip(e, string_null, string_null);
 267 }
 268
 269 // URI SYSTEM ////////////////////////////////////////////////////////
 270
 271 float _Nex_ExtResponseSystem_Queried;
 272 string _Nex_ExtResponseSystem_UpdateTo;
 273 string _Nex_ExtResponseSystem_UpdateToURL;
 274 string _Nex_ExtResponseSystem_Packs;
 275 float _Nex_ExtResponseSystem_PacksStep;
 276
 277 void URI_Get_Callback(float id, float status, string data)
 278 {
 279         if(url_URI_Get_Callback(id, status, data))
 280         {
 281                 // handled
 282         }
 283         else if (id == URI_GET_DISCARD)
 284         {
 285                 // discard
 286         }
 287         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 288         {
 289                 // sv_cmd curl
 290                 Curl_URI_Get_Callback(id, status, data);
 291         }
 292         else if (id == URI_GET_UPDATENOTIFICATION)
 293         {
 294                 UpdateNotification_URI_Get_Callback(id, status, data);
 295         }
 296         else
 297         {
 298                 LOG_INFOF("Received HTTP request data for an invalid id %d.\n", id);
 299         }
 300 }
 301
 302 void DisableServerBackwardsCompatibility()
 303 {
 304         cvar_set("gameversion_min", ftos(100 * floor(cvar("gameversion") / 100)));
 305 }
 306
 307 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 308 {
 309         float n;
 310
 311         if(_Nex_ExtResponseSystem_UpdateTo)
 312         {
 313                 LOG_TRACE("error: UpdateNotification_URI_Get_Callback has been called before\n");
 314                 return;
 315         }
 316         if(status != 0)
 317         {
 318                 LOG_TRACEF("error receiving update notification: status is %d\n", status);
 319                 return;
 320         }
 321         if(substring(data, 0, 1) == "<")
 322         {
 323                 LOG_TRACE("error: received HTML instead of an update notification\n");
 324                 return;
 325         }
 326         if(strstrofs(data, "\r", 0) != -1)
 327         {
 328                 LOG_TRACE("error: received carriage returns from update notification server\n");
 329                 return;
 330         }
 331
 332         if(data == "")
 333                 n = 0;
 334         else
 335                 n = tokenizebyseparator(data, "\n");
 336
 337         float i;
 338         string s;
 339
 340         string un_version = "";
 341         string un_download = "";
 342         string un_url = "";
 343         string un_bannedservers = "";
 344         string un_emergency_pk3s = "";
 345         string un_promoted = "";
 346         string un_recommended = "";
 347         string un_compatexpire = "";
 348
 349         for(i = 0; i < n; ++i)
 350         {
 351                 s = substring(argv(i), 2, -1);
 352                 if(s == "") { continue; } // ignore empty lines
 353
 354                 switch(substring(argv(i), 0, 1))
 355                 {
 356                         case "V":
 357                         {
 358                                 un_version = s;
 359                                 break;
 360                         }
 361                         case "C":
 362                         {
 363                                 un_compatexpire = s;
 364                                 break;
 365                         }
 366                         case "D":
 367                         {
 368                                 un_download = s;
 369                                 break;
 370                         }
 371                         case "U":
 372                         {
 373                                 un_url = s;
 374                                 break;
 375                         }
 376                         case "B":
 377                         {
 378                                 APPEND_TO_STRING(un_bannedservers, " ", s);
 379                                 break;
 380                         }
 381                         case "E":
 382                         {
 383                                 if(cvar("menu_updatecheck_getpacks"))
 384                                         APPEND_TO_STRING(un_emergency_pk3s, " ", s);
 385                                 break;
 386                         }
 387                         case "P":
 388                         {
 389                                 APPEND_TO_STRING(un_promoted, " ", s);
 390                                 break;
 391                         }
 392                         case "R":
 393                         {
 394                                 APPEND_TO_STRING(un_recommended, " ", s);
 395                                 break;
 396                         }
 397                 }
 398         }
 399
 400         if(un_version != "")
 401         {
 402                 if(vercmp(cvar_string("g_xonoticversion"), un_version) < 0)
 403                 {
 404                         // update needed
 405                         _Nex_ExtResponseSystem_UpdateTo = strzone(un_version);
 406                         if(un_download) { LOG_INFOF(_("Update can be downloaded at:\n%s\n"), un_download); }
 407                         if(un_url) { _Nex_ExtResponseSystem_UpdateToURL = strzone(un_url); }
 408                         DisableServerBackwardsCompatibility();
 409                 }
 410                 else if(cvar_string("g_xonoticversion") == un_version)
 411                 {
 412                         if(un_compatexpire != "")
 413                         {
 414                                 string curdate = strftime(false, "%Y%m%d%H%M%S");
 415                                 if (strcmp(curdate, un_compatexpire) >= 0)
 416                                         DisableServerBackwardsCompatibility();
 417                         }
 418                 }
 419         }
 420
 421         if(un_emergency_pk3s != "")
 422         {
 423                 _Nex_ExtResponseSystem_Packs = strzone(un_emergency_pk3s);
 424                 _Nex_ExtResponseSystem_PacksStep = 1;
 425         }
 426
 427         if(un_promoted != "")
 428         {
 429                 _Nex_ExtResponseSystem_PromotedServers = strzone(un_promoted);
 430                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 1;
 431         }
 432
 433         if(un_recommended != "")
 434         {
 435                 _Nex_ExtResponseSystem_RecommendedServers = strzone(un_recommended);
 436                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 1;
 437         }
 438 }
 439
 440 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 441
 442 void updateCheck()
 443 {
 444         if(cvar("menu_updatecheck"))
 445         {
 446                 if(!_Nex_ExtResponseSystem_Queried)
 447                 {
 448                         _Nex_ExtResponseSystem_Queried = 1;
 449                         float startcnt;
 450                         string uri;
 451
 452                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 453
 454                         // for privacy, munge the start count a little
 455                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 456                         uri = sprintf("http://update.xonotic.org/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 457                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 458                 }
 459         }
 460
 461         if(_Nex_ExtResponseSystem_PacksStep > 0)
 462         {
 463                 float n, i;
 464                 float allgood;
 465                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 466                 allgood = true;
 467                 for(i = 0; i+1 < n; i += 2)
 468                 {
 469                         if(fexists(argv(i+1)))
 470                                 continue;
 471                         allgood = false;
 472                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 473                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 474                 }
 475                 if(allgood)
 476                 {
 477                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 478                         {
 479                                 if(!Menu_Active)
 480                                         cvar_set("_menu_initialized", "0");
 481                                         // HACK: cause m_hide call on next start
 482                                 localcmd("\nmenu_restart\n");
 483                         }
 484                         _Nex_ExtResponseSystem_PacksStep = 0;
 485                 }
 486                 else
 487                         _Nex_ExtResponseSystem_PacksStep = 2;
 488         }
 489
 490 }
 491
 492 float preMenuInit()
 493 {
 494         vector sz;
 495         vector boxA, boxB;
 496
 497         updateCheck();
 498
 499         MapInfo_Cache_Create();
 500         MapInfo_Enumerate();
 501         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 502         {
 503                 draw_reset_cropped();
 504
 505                 sz = eX * 0.025 + eY * 0.025 * (draw_scale.x / draw_scale.y);
 506                 draw_CenterText('0.5 0.5 0' - 1.25 * sz.y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 507
 508                 boxA = '0.05 0.5 0' + 0.25 * sz.y * eY;
 509                 boxB = '0.95 0.5 0' + 1.25 * sz.y * eY;
 510                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 511
 512                 boxA += sz * 0.1;
 513                 boxB -= sz * 0.1;
 514                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 515
 516                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 517                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 518
 519                 return false;
 520         }
 521         return true;
 522 }
 523
 524 string campaign_name_previous;
 525 float campaign_won_previous;
 526 #ifdef WATERMARK
 527 string autocvar_menu_watermark = WATERMARK;
 528 #else
 529 string autocvar_menu_watermark = "";
 530 #endif
 531 void postMenuDraw()
 532 {
 533         if(autocvar_menu_watermark != "")
 534         {
 535                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 536         }
 537 }
 538 void DialogOpenButton_Click_withCoords(entity button, entity tab, vector theOrigin, vector theSize);
 539 .entity winnerDialog;
 540 void preMenuDraw()
 541 {
 542         vector fs, sz = '0 0 0', line, mid;
 543
 544         updateCheck();
 545
 546         if(_Nex_ExtResponseSystem_UpdateTo != "")
 547         {
 548                 // TODO rather turn this into a dialog
 549                 fs = ((1/draw_scale.x) * eX + (1/draw_scale.y) * eY) * 12;
 550                 line = eY * fs.y;
 551                 string l1, l2;
 552                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 553                 l2 = "http://www.xonotic.org/";
 554                 if(_Nex_ExtResponseSystem_UpdateToURL)
 555                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 556
 557                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 558                                 draw_TextWidth(l1, 0, fs),
 559                                 draw_TextWidth(l2, 0, fs)
 560                         );
 561                 sz_y = 3 * fs.y;
 562
 563                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 564                 mid = eX * (0.5 + 0.5 * (1 - sz.x) * cos(time * 0.071))
 565                     + eY * (0.5 + 0.5 * (1 - sz.y) * sin(time * 0.071));
 566
 567                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 568                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 569                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 570         }
 571         if (!campaign_name_previous)
 572                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 573         if(campaign_name == campaign_name_previous)
 574         {
 575                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 576                 {
 577                         if(!campaign_won_previous)
 578                         {
 579                                 m_display();
 580                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 581                         }
 582                         campaign_won_previous = 1;
 583                 }
 584                 else
 585                         campaign_won_previous = 0;
 586         }
 587         else
 588         {
 589                 strunzone(campaign_name_previous);
 590                 campaign_name_previous = strzone(campaign_name);
 591                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 592         }
 593 }
 594
 595 string resolvemod(string m)
 596 {
 597         if(m == "=")
 598                 return getcurrentmod();
 599         else
 600                 return m;
 601 }
 602
 603 float updateCompression()
 604 {
 605         float have_dds, have_jpg, have_tga;
 606         float can_dds;
 607         have_dds = (fexists("dds/particles/particlefont.dds"));
 608         have_jpg = (fexists("particles/particlefont.jpg"));
 609         have_tga = (fexists("particles/particlefont.tga"));
 610         can_dds = GL_Have_TextureCompression();
 611         if(have_dds && (have_jpg || have_tga))
 612         {
 613                 // both? Let's only use good quality precompressed files
 614                 // but ONLY if we actually support it!
 615                 if(can_dds)
 616                 {
 617                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 618                         cvar_set("gl_texturecompression", "0");
 619                         return 1;
 620
 621                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 622                         //return 2;
 623                 }
 624                 else
 625                 {
 626                         cvar_set("gl_texturecompression", "0");
 627                         cvar_set("r_texture_dds_load", "0");
 628                         return 0;
 629                 }
 630         }
 631         else if(have_dds)
 632         {
 633                 // DDS only? We probably always want texture compression
 634                 cvar_set("gl_texturecompression", "1");
 635                 cvar_set("r_texture_dds_load", "1");
 636                 if(!can_dds)
 637                         LOG_INFO(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 638                 return 0;
 639         }
 640         else
 641         {
 642                 // TGA only? Allow runtime compression
 643                 if(can_dds)
 644                 {
 645                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 646                         return 2;
 647                 }
 648                 else
 649                 {
 650                         cvar_set("gl_texturecompression", "0");
 651                         cvar_set("r_texture_dds_load", "0");
 652                         return 0;
 653                 }
 654         }
 655 }
 656
 657 // note: include only those that should be in the menu!
 658 #define GAMETYPES \
 659         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 660         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 661         GAMETYPE(MAPINFO_TYPE_CTF) \
 662         GAMETYPE(MAPINFO_TYPE_CA) \
 663         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 664         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 665         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 666         GAMETYPE(MAPINFO_TYPE_LMS) \
 667         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 668         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 669         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 670         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 671         if (cvar("developer")) GAMETYPE(MAPINFO_TYPE_RACE) \
 672         GAMETYPE(MAPINFO_TYPE_CTS) \
 673         /* GAMETYPE(MAPINFO_TYPE_INVASION) */ \
 674         /**/
 675
 676 int GameType_GetID(int cnt)
 677 {
 678         int i = 0;
 679
 680         #define GAMETYPE(id) { if (i++ == cnt) return id; }
 681         GAMETYPES
 682         #undef GAMETYPE
 683
 684         unused_float = i;
 685
 686         return 0;
 687 }
 688
 689 int GameType_GetCount()
 690 {
 691         int i = 0;
 692
 693         #define GAMETYPE(id) ++i;
 694         GAMETYPES
 695         #undef GAMETYPE
 696
 697         return i;
 698 }
 699
 700 string GameType_GetName(int cnt)
 701 {
 702         int i = GameType_GetID(cnt);
 703
 704         if(i)
 705                 return MapInfo_Type_ToText(i);
 706
 707         return "";
 708 }
 709
 710 string GameType_GetIcon(int cnt)
 711 {
 712         int i = GameType_GetID(cnt);
 713
 714         if(i)
 715                 return strcat("gametype_", MapInfo_Type_ToString(i));
 716
 717         return "";
 718 }
 719
 720 .void(entity) TR;
 721 .void(entity, float, float, entity) TD;
 722 .void(entity, float) TDempty;
 723 entity makeXonoticTextLabel(float theAlign, string theText);
 724 entity makeXonoticTextSlider(string);
 725 .void(entity, string, string) addValue;
 726 .void(entity) configureXonoticTextSliderValues;
 727 entity makeXonoticColorpickerString(string theCvar, string theDefaultCvar);
 728 entity makeXonoticCheckBoxString(string, string, string, string);
 729 entity makeXonoticCheckBox(float, string, string);
 730 .bool sendCvars;
 731
 732 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 733 {
 734         float i;
 735         entity e;
 736
 737         me.TR(me);
 738                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 739                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 740                                 e.addValue(e, _("Default"), "");
 741                                 e.addValue(e, _("Disable"), "0");
 742                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 743                                 e.configureXonoticTextSliderValues(e);
 744         me.TR(me);
 745                 me.TDempty(me, 0.2);
 746                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 747                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 748                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 749         me.TR(me);
 750                 me.TDempty(me, 0.2);
 751                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 752         me.TR(me);
 753                 me.TDempty(me, 0.2);
 754                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 755                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 756                                 e.addValue(e, _("Default"), "");
 757                                 e.addValue(e, _("Disable"), "0");
 758                                 for(i = 1; i <= 10; ++i)
 759                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 760                                 e.configureXonoticTextSliderValues(e);
 761         me.TR(me);
 762                 me.TDempty(me, 0.2);
 763                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 764                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 765                                 e.addValue(e, _("Default"), "");
 766                                 for(i = 1; i <= 10; ++i)
 767                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 768                                 e.configureXonoticTextSliderValues(e);
 769         me.TR(me);
 770                 me.TDempty(me, 0.2);
 771                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 772                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 773                                 e.addValue(e, _("Default"), "");
 774                                 e.addValue(e, _("Disable"), "0");
 775                                 for(i = 1; i <= 10; ++i)
 776                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 777                                 e.configureXonoticTextSliderValues(e);
 778         me.TR(me);
 779                 me.TDempty(me, 0.4);
 780                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 781         me.TR(me);
 782                 me.TDempty(me, 0.2);
 783                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 784                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 785                                 e.addValue(e, _("Default"), "");
 786                                 for(i = 0; i <= 10; ++i)
 787                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 788                                 e.configureXonoticTextSliderValues(e);
 789 }
 790
 791 float getFadedAlpha(float currentAlpha, float startAlpha, float targetAlpha)
 792 {
 793         if(startAlpha < targetAlpha)
 794                 currentAlpha = min(currentAlpha + frametime * 0.5, targetAlpha);
 795         else
 796                 currentAlpha = max(currentAlpha - frametime * 0.5, targetAlpha);
 797         return currentAlpha;
 798 }
 799
 800 void CheckSendCvars(entity me, string cvarnamestring)
 801 {
 802         if(me.sendCvars)
 803         {
 804                 LOG_INFOF("Sending cvar: %s -> %s\n", cvarnamestring, cvar_string(cvarnamestring));
 805                 if(gamestatus & (GAME_CONNECTED | GAME_ISSERVER))
 806                 {
 807                         cmd(sprintf("\nsendcvar %s\n", cvarnamestring));
 808                 }
 809         }
 810 }