qcsrc/menu/xonotic/util.qc

   1 #include "util.qh"
   2
   3 #include "../item.qc"
   4
   5 #include "../menu.qh"
   6 #include "../../common/campaign_common.qh"
   7 #include "../../common/constants.qh"
   8 #include "../../common/mapinfo.qh"
   9 #include "../../common/util.qh"
  10 #include "../../common/command/generic.qh"
  11
  12 float GL_CheckExtension(string ext)
  13 {
  14         return strhasword(cvar_string("gl_info_extensions"), ext);
  15 }
  16
  17 float GL_Have_TextureCompression()
  18 {
  19         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
  20 }
  21
  22 .entity parent, firstChild, nextSibling;
  23 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  24 {
  25         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  26 }
  27
  28 .string cvarName;
  29 void SUB_Null_ee(entity e1, entity e2)
  30 {
  31 }
  32
  33 .void(entity) saveCvars;
  34 void saveCvarsOf(entity ignore, entity e)
  35 {
  36         if(e.saveCvars)
  37                 e.saveCvars(e);
  38 }
  39
  40 .void(entity) loadCvars;
  41 void loadCvarsOf(entity ignore, entity e)
  42 {
  43         if(e.loadCvars)
  44                 e.loadCvars(e);
  45 }
  46 void saveAllCvars(entity root)
  47 {
  48         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  49 }
  50 void loadAllCvars(entity root)
  51 {
  52         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  53 }
  54
  55 .string cvarNames_Multi;
  56 .void(entity me) saveCvars_Multi;
  57 string getCvarsMulti(entity me)
  58 {
  59         if (me.cvarNames_Multi)
  60                 return me.cvarNames_Multi;
  61         return string_null;
  62 }
  63 void saveCvarsMulti(entity me)
  64 {
  65         float n, i;
  66         string s;
  67
  68         me.saveCvars_Multi(me);
  69         s = cvar_string(me.cvarName);
  70
  71         n = tokenize_console(me.cvarNames_Multi);
  72         for(i = 0; i < n; ++i)
  73         {
  74                 if(substring(argv(i), 0, 1) == "!")
  75                         cvar_set(substring(argv(i), 1, strlen(argv(i))), ((s == "0") ? "1" : "0"));
  76                 else
  77                         cvar_set(argv(i), s);
  78
  79                 CheckSendCvars(me, argv(i));
  80         }
  81 }
  82 void makeMulti(entity e, string otherCvars)
  83 {
  84         e.cvarNames_Multi = otherCvars;
  85         e.saveCvars_Multi = e.saveCvars;
  86         e.saveCvars = saveCvarsMulti;
  87 }
  88
  89 .void(entity me) saveCvars_Callback;
  90 .entity saveCvars_Callback_ent;
  91 .void(entity me, entity cb) saveCvars_Callback_func;
  92 void saveCvarsCallback(entity me)
  93 {
  94         me.saveCvars_Callback(me);
  95         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
  96 }
  97 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
  98 {
  99         e.saveCvars_Callback = e.saveCvars;
 100         e.saveCvars = saveCvarsCallback;
 101         e.saveCvars_Callback_ent = cbent;
 102         e.saveCvars_Callback_func = cbfunc;
 103 }
 104
 105 .void(entity) draw_setDependent;
 106 .string cvar_setDependent;
 107 .float cvarMin_setDependent;
 108 .float cvarMax_setDependent;
 109 .string cvar2_setDependent;
 110 .float cvar2Min_setDependent;
 111 .float cvar2Max_setDependent;
 112 .string cvar3_setDependent;
 113 .float cvar3Min_setDependent;
 114 .float cvar3Max_setDependent;
 115 .float op_setDependent;
 116 .string cvarString_setDependent;
 117 .string cvarValue_setDependent;
 118 .float(entity) func_setDependent;
 119 .bool disabled;
 120 void setDependent_Check(entity e)
 121 {
 122         float f;
 123         string s;
 124         if(e.func_setDependent)
 125         {
 126                 e.disabled = !(e.func_setDependent(e));
 127         }
 128         else if(e.cvarString_setDependent)
 129         {
 130                 s = cvar_string(e.cvarString_setDependent);
 131                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 132         }
 133         else
 134         {
 135                 if(e.cvar_setDependent)
 136                 {
 137                         f = cvar(e.cvar_setDependent);
 138                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 139                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 140                         else
 141                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 142                 }
 143                 if(e.cvar2_setDependent)
 144                 {
 145                         f = cvar(e.cvar2_setDependent);
 146                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 147                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 148                         else
 149                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 150                 }
 151                 if(e.cvar3_setDependent)
 152                 {
 153                         f = cvar(e.cvar3_setDependent);
 154                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 155                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 156                         else
 157                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 158                 }
 159         }
 160 }
 161 void setDependent_Draw(entity e)
 162 {
 163         setDependent_Check(e);
 164         e.draw_setDependent(e);
 165 }
 166 .void(entity) draw;
 167 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 168 {
 169         e.draw_setDependent = e.draw;
 170         e.cvar_setDependent = theCvarName;
 171         e.cvarMin_setDependent = theCvarMin;
 172         e.cvarMax_setDependent = theCvarMax;
 173         e.cvar2_setDependent = string_null;
 174         e.cvar3_setDependent = string_null;
 175         e.func_setDependent = func_null;
 176         e.draw = setDependent_Draw;
 177         setDependent_Check(e);
 178 }
 179 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 180 {
 181         e.draw_setDependent = e.draw;
 182         e.cvarString_setDependent = theCvarName;
 183         e.cvarValue_setDependent = theCvarValue;
 184         e.cvar_setDependent = string_null;
 185         e.cvar2_setDependent = string_null;
 186         e.cvar3_setDependent = string_null;
 187         e.func_setDependent = func_null;
 188         e.draw = setDependent_Draw;
 189         setDependent_Check(e);
 190 }
 191 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 192 {
 193         e.draw_setDependent = e.draw;
 194         e.cvar_setDependent = theCvarName;
 195         e.cvarMin_setDependent = theCvarMin;
 196         e.cvarMax_setDependent = theCvarMax;
 197         e.cvar2_setDependent = theCvar2Name;
 198         e.cvar2Min_setDependent = theCvar2Min;
 199         e.cvar2Max_setDependent = theCvar2Max;
 200         e.cvar3_setDependent = string_null;
 201         e.op_setDependent = 0;
 202         e.func_setDependent = func_null;
 203         e.draw = setDependent_Draw;
 204         setDependent_Check(e);
 205 }
 206 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 207 {
 208         e.draw_setDependent = e.draw;
 209         e.cvar_setDependent = theCvarName;
 210         e.cvarMin_setDependent = theCvarMin;
 211         e.cvarMax_setDependent = theCvarMax;
 212         e.cvar2_setDependent = theCvar2Name;
 213         e.cvar2Min_setDependent = theCvar2Min;
 214         e.cvar2Max_setDependent = theCvar2Max;
 215         e.cvar3_setDependent = string_null;
 216         e.op_setDependent = 1;
 217         e.func_setDependent = func_null;
 218         e.draw = setDependent_Draw;
 219         setDependent_Check(e);
 220 }
 221 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 222 {
 223         e.draw_setDependent = e.draw;
 224         e.cvar_setDependent = theCvarName;
 225         e.cvarMin_setDependent = theCvarMin;
 226         e.cvarMax_setDependent = theCvarMax;
 227         e.cvar2_setDependent = theCvar2Name;
 228         e.cvar2Min_setDependent = theCvar2Min;
 229         e.cvar2Max_setDependent = theCvar2Max;
 230         e.cvar3_setDependent = theCvar3Name;
 231         e.cvar3Min_setDependent = theCvar3Min;
 232         e.cvar3Max_setDependent = theCvar3Max;
 233         e.op_setDependent = 0;
 234         e.func_setDependent = func_null;
 235         e.draw = setDependent_Draw;
 236         setDependent_Check(e);
 237 }
 238 void setDependentWeird(entity e, float(entity) func)
 239 {
 240         e.draw_setDependent = e.draw;
 241         e.func_setDependent = func;
 242         e.draw = setDependent_Draw;
 243         setDependent_Check(e);
 244 }
 245
 246 void setZonedTooltip(entity e, string theTooltip, string theCvar)
 247 {
 248         if(theTooltip == "") // no tooltip, use cvar description then
 249         {
 250                 if(theCvar != "" && prvm_language == "en")
 251                 {
 252                         string t = cvar_description(theCvar);
 253                         if(t != "" && t != "custom cvar")
 254                                 theTooltip = t;
 255                 }
 256         }
 257         else if(theTooltip == "-") // no cvar description as tooltip
 258         {
 259                 theTooltip = string_null;
 260         }
 261
 262         if(e.tooltip)
 263                 strunzone(e.tooltip);
 264         e.tooltip = (theTooltip != "") ? strzone(theTooltip) : string_null;
 265 }
 266
 267 void clearTooltip(entity e)
 268 {
 269         setZonedTooltip(e, string_null, string_null);
 270 }
 271
 272 // URI SYSTEM ////////////////////////////////////////////////////////
 273
 274 float _Nex_ExtResponseSystem_Queried;
 275 string _Nex_ExtResponseSystem_UpdateTo;
 276 string _Nex_ExtResponseSystem_UpdateToURL;
 277 string _Nex_ExtResponseSystem_Packs;
 278 float _Nex_ExtResponseSystem_PacksStep;
 279
 280 /** engine callback */
 281 void URI_Get_Callback(float id, float status, string data)
 282 {
 283         if(url_URI_Get_Callback(id, status, data))
 284         {
 285                 // handled
 286         }
 287         else if (id == URI_GET_DISCARD)
 288         {
 289                 // discard
 290         }
 291         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 292         {
 293                 // sv_cmd curl
 294                 Curl_URI_Get_Callback(id, status, data);
 295         }
 296         else if (id == URI_GET_UPDATENOTIFICATION)
 297         {
 298                 UpdateNotification_URI_Get_Callback(id, status, data);
 299         }
 300         else
 301         {
 302                 LOG_INFOF("Received HTTP request data for an invalid id %d.\n", id);
 303         }
 304 }
 305
 306 void DisableServerBackwardsCompatibility()
 307 {
 308         cvar_set("gameversion_min", ftos(100 * floor(cvar("gameversion") / 100)));
 309 }
 310
 311 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 312 {
 313         float n;
 314
 315         if(_Nex_ExtResponseSystem_UpdateTo)
 316         {
 317                 LOG_TRACE("error: UpdateNotification_URI_Get_Callback has been called before\n");
 318                 return;
 319         }
 320         if(status != 0)
 321         {
 322                 LOG_TRACEF("error receiving update notification: status is %d\n", status);
 323                 return;
 324         }
 325         if(substring(data, 0, 1) == "<")
 326         {
 327                 LOG_TRACE("error: received HTML instead of an update notification\n");
 328                 return;
 329         }
 330         if(strstrofs(data, "\r", 0) != -1)
 331         {
 332                 LOG_TRACE("error: received carriage returns from update notification server\n");
 333                 return;
 334         }
 335
 336         if(data == "")
 337                 n = 0;
 338         else
 339                 n = tokenizebyseparator(data, "\n");
 340
 341         float i;
 342         string s;
 343
 344         string un_version = "";
 345         string un_download = "";
 346         string un_url = "";
 347         string un_bannedservers = "";
 348         string un_emergency_pk3s = "";
 349         string un_promoted = "";
 350         string un_recommended = "";
 351         string un_compatexpire = "";
 352
 353         for(i = 0; i < n; ++i)
 354         {
 355                 s = substring(argv(i), 2, -1);
 356                 if(s == "") { continue; } // ignore empty lines
 357
 358                 switch(substring(argv(i), 0, 1))
 359                 {
 360                         case "V":
 361                         {
 362                                 un_version = s;
 363                                 break;
 364                         }
 365                         case "C":
 366                         {
 367                                 un_compatexpire = s;
 368                                 break;
 369                         }
 370                         case "D":
 371                         {
 372                                 un_download = s;
 373                                 break;
 374                         }
 375                         case "U":
 376                         {
 377                                 un_url = s;
 378                                 break;
 379                         }
 380                         case "B":
 381                         {
 382                                 APPEND_TO_STRING(un_bannedservers, " ", s);
 383                                 break;
 384                         }
 385                         case "E":
 386                         {
 387                                 if(cvar("menu_updatecheck_getpacks"))
 388                                         APPEND_TO_STRING(un_emergency_pk3s, " ", s);
 389                                 break;
 390                         }
 391                         case "P":
 392                         {
 393                                 APPEND_TO_STRING(un_promoted, " ", s);
 394                                 break;
 395                         }
 396                         case "R":
 397                         {
 398                                 APPEND_TO_STRING(un_recommended, " ", s);
 399                                 break;
 400                         }
 401                 }
 402         }
 403
 404         if(un_version != "")
 405         {
 406                 if(vercmp(cvar_string("g_xonoticversion"), un_version) < 0)
 407                 {
 408                         // update needed
 409                         _Nex_ExtResponseSystem_UpdateTo = strzone(un_version);
 410                         if(un_download) { LOG_INFOF(_("Update can be downloaded at:\n%s\n"), un_download); }
 411                         if(un_url) { _Nex_ExtResponseSystem_UpdateToURL = strzone(un_url); }
 412                         DisableServerBackwardsCompatibility();
 413                 }
 414                 else if(cvar_string("g_xonoticversion") == un_version)
 415                 {
 416                         if(un_compatexpire != "")
 417                         {
 418                                 string curdate = strftime(false, "%Y%m%d%H%M%S");
 419                                 if (strcmp(curdate, un_compatexpire) >= 0)
 420                                         DisableServerBackwardsCompatibility();
 421                         }
 422                 }
 423         }
 424
 425         if(un_emergency_pk3s != "")
 426         {
 427                 _Nex_ExtResponseSystem_Packs = strzone(un_emergency_pk3s);
 428                 _Nex_ExtResponseSystem_PacksStep = 1;
 429         }
 430
 431         if(un_promoted != "")
 432         {
 433                 _Nex_ExtResponseSystem_PromotedServers = strzone(un_promoted);
 434                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 1;
 435         }
 436
 437         if(un_recommended != "")
 438         {
 439                 _Nex_ExtResponseSystem_RecommendedServers = strzone(un_recommended);
 440                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 1;
 441         }
 442 }
 443
 444 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 445
 446 void updateCheck()
 447 {
 448         if(cvar("menu_updatecheck"))
 449         {
 450                 if(!_Nex_ExtResponseSystem_Queried)
 451                 {
 452                         _Nex_ExtResponseSystem_Queried = 1;
 453                         float startcnt;
 454                         string uri;
 455
 456                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 457
 458                         // for privacy, munge the start count a little
 459                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 460                         uri = sprintf("http://update.xonotic.org/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 461                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 462                 }
 463         }
 464
 465         if(_Nex_ExtResponseSystem_PacksStep > 0)
 466         {
 467                 float n, i;
 468                 float allgood;
 469                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 470                 allgood = true;
 471                 for(i = 0; i+1 < n; i += 2)
 472                 {
 473                         if(fexists(argv(i+1)))
 474                                 continue;
 475                         allgood = false;
 476                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 477                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 478                 }
 479                 if(allgood)
 480                 {
 481                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 482                         {
 483                                 if(!Menu_Active)
 484                                         cvar_set("_menu_initialized", "0");
 485                                         // HACK: cause m_hide call on next start
 486                                 localcmd("\nmenu_restart\n");
 487                         }
 488                         _Nex_ExtResponseSystem_PacksStep = 0;
 489                 }
 490                 else
 491                         _Nex_ExtResponseSystem_PacksStep = 2;
 492         }
 493
 494 }
 495
 496 float preMenuInit()
 497 {
 498         vector sz;
 499         vector boxA, boxB;
 500
 501         updateCheck();
 502
 503         MapInfo_Cache_Create();
 504         MapInfo_Enumerate();
 505         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 506         {
 507                 draw_reset_cropped();
 508
 509                 sz = eX * 0.025 + eY * 0.025 * (draw_scale.x / draw_scale.y);
 510                 draw_CenterText('0.5 0.5 0' - 1.25 * sz.y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 511
 512                 boxA = '0.05 0.5 0' + 0.25 * sz.y * eY;
 513                 boxB = '0.95 0.5 0' + 1.25 * sz.y * eY;
 514                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 515
 516                 boxA += sz * 0.1;
 517                 boxB -= sz * 0.1;
 518                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 519
 520                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 521                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 522
 523                 return false;
 524         }
 525         return true;
 526 }
 527
 528 string campaign_name_previous;
 529 float campaign_won_previous;
 530 #ifdef WATERMARK
 531 string autocvar_menu_watermark = WATERMARK;
 532 #else
 533 string autocvar_menu_watermark = "";
 534 #endif
 535 void postMenuDraw()
 536 {
 537         if(autocvar_menu_watermark != "")
 538         {
 539                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 540         }
 541 }
 542 void DialogOpenButton_Click_withCoords(entity button, entity tab, vector theOrigin, vector theSize);
 543 .entity winnerDialog;
 544 void preMenuDraw()
 545 {
 546         vector fs, sz = '0 0 0', line, mid;
 547
 548         updateCheck();
 549
 550         if(_Nex_ExtResponseSystem_UpdateTo != "")
 551         {
 552                 // TODO rather turn this into a dialog
 553                 fs = ((1/draw_scale.x) * eX + (1/draw_scale.y) * eY) * 12;
 554                 line = eY * fs.y;
 555                 string l1, l2;
 556                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 557                 l2 = "http://www.xonotic.org/";
 558                 if(_Nex_ExtResponseSystem_UpdateToURL)
 559                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 560
 561                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 562                                 draw_TextWidth(l1, 0, fs),
 563                                 draw_TextWidth(l2, 0, fs)
 564                         );
 565                 sz_y = 3 * fs.y;
 566
 567                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 568                 mid = eX * (0.5 + 0.5 * (1 - sz.x) * cos(time * 0.071))
 569                     + eY * (0.5 + 0.5 * (1 - sz.y) * sin(time * 0.071));
 570
 571                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 572                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 573                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 574         }
 575         if (!campaign_name_previous)
 576                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 577         if(campaign_name == campaign_name_previous)
 578         {
 579                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 580                 {
 581                         if(!campaign_won_previous)
 582                         {
 583                                 m_display();
 584                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 585                         }
 586                         campaign_won_previous = 1;
 587                 }
 588                 else
 589                         campaign_won_previous = 0;
 590         }
 591         else
 592         {
 593                 strunzone(campaign_name_previous);
 594                 campaign_name_previous = strzone(campaign_name);
 595                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 596         }
 597 }
 598
 599 string resolvemod(string m)
 600 {
 601         if(m == "=")
 602                 return getcurrentmod();
 603         else
 604                 return m;
 605 }
 606
 607 float updateCompression()
 608 {
 609         float have_dds, have_jpg, have_tga;
 610         float can_dds;
 611         have_dds = (fexists("dds/particles/particlefont.dds"));
 612         have_jpg = (fexists("particles/particlefont.jpg"));
 613         have_tga = (fexists("particles/particlefont.tga"));
 614         can_dds = GL_Have_TextureCompression();
 615         if(have_dds && (have_jpg || have_tga))
 616         {
 617                 // both? Let's only use good quality precompressed files
 618                 // but ONLY if we actually support it!
 619                 if(can_dds)
 620                 {
 621                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 622                         cvar_set("gl_texturecompression", "0");
 623                         return 1;
 624
 625                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 626                         //return 2;
 627                 }
 628                 else
 629                 {
 630                         cvar_set("gl_texturecompression", "0");
 631                         cvar_set("r_texture_dds_load", "0");
 632                         return 0;
 633                 }
 634         }
 635         else if(have_dds)
 636         {
 637                 // DDS only? We probably always want texture compression
 638                 cvar_set("gl_texturecompression", "1");
 639                 cvar_set("r_texture_dds_load", "1");
 640                 if(!can_dds)
 641                         LOG_INFO(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 642                 return 0;
 643         }
 644         else
 645         {
 646                 // TGA only? Allow runtime compression
 647                 if(can_dds)
 648                 {
 649                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 650                         return 2;
 651                 }
 652                 else
 653                 {
 654                         cvar_set("gl_texturecompression", "0");
 655                         cvar_set("r_texture_dds_load", "0");
 656                         return 0;
 657                 }
 658         }
 659 }
 660
 661 // note: include only those that should be in the menu!
 662 #define GAMETYPES \
 663         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 664         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 665         GAMETYPE(MAPINFO_TYPE_CTF) \
 666         GAMETYPE(MAPINFO_TYPE_CA) \
 667         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 668         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 669         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 670         GAMETYPE(MAPINFO_TYPE_LMS) \
 671         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 672         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 673         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 674         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 675         if (cvar("developer")) GAMETYPE(MAPINFO_TYPE_RACE) \
 676         GAMETYPE(MAPINFO_TYPE_CTS) \
 677         /* GAMETYPE(MAPINFO_TYPE_INVASION) */ \
 678         /**/
 679
 680 int GameType_GetID(int cnt)
 681 {
 682         int i = 0;
 683
 684         #define GAMETYPE(id) { if (i++ == cnt) return id; }
 685         GAMETYPES
 686         #undef GAMETYPE
 687
 688         unused_float = i;
 689
 690         return 0;
 691 }
 692
 693 int GameType_GetCount()
 694 {
 695         int i = 0;
 696
 697         #define GAMETYPE(id) ++i;
 698         GAMETYPES
 699         #undef GAMETYPE
 700
 701         return i;
 702 }
 703
 704 string GameType_GetName(int cnt)
 705 {
 706         int i = GameType_GetID(cnt);
 707
 708         if(i)
 709                 return MapInfo_Type_ToText(i);
 710
 711         return "";
 712 }
 713
 714 string GameType_GetIcon(int cnt)
 715 {
 716         int i = GameType_GetID(cnt);
 717
 718         if(i)
 719                 return strcat("gametype_", MapInfo_Type_ToString(i));
 720
 721         return "";
 722 }
 723
 724 .void(entity) TR;
 725 .void(entity, float, float, entity) TD;
 726 .void(entity, float) TDempty;
 727 entity makeXonoticTextLabel(float theAlign, string theText);
 728 entity makeXonoticTextSlider(string);
 729 .void(entity, string, string) addValue;
 730 .void(entity) configureXonoticTextSliderValues;
 731 entity makeXonoticColorpickerString(string theCvar, string theDefaultCvar);
 732 entity makeXonoticCheckBoxString(string, string, string, string);
 733 entity makeXonoticCheckBox(float, string, string);
 734 .bool sendCvars;
 735
 736 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 737 {
 738         float i;
 739         entity e;
 740
 741         me.TR(me);
 742                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 743                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 744                                 e.addValue(e, _("Default"), "");
 745                                 e.addValue(e, _("Disable"), "0");
 746                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 747                                 e.configureXonoticTextSliderValues(e);
 748         me.TR(me);
 749                 me.TDempty(me, 0.2);
 750                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 751                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 752                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 753         me.TR(me);
 754                 me.TDempty(me, 0.2);
 755                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 756         me.TR(me);
 757                 me.TDempty(me, 0.2);
 758                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 759                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 760                                 e.addValue(e, _("Default"), "");
 761                                 e.addValue(e, _("Disable"), "0");
 762                                 for(i = 1; i <= 10; ++i)
 763                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 764                                 e.configureXonoticTextSliderValues(e);
 765         me.TR(me);
 766                 me.TDempty(me, 0.2);
 767                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 768                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 769                                 e.addValue(e, _("Default"), "");
 770                                 for(i = 1; i <= 10; ++i)
 771                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 772                                 e.configureXonoticTextSliderValues(e);
 773         me.TR(me);
 774                 me.TDempty(me, 0.2);
 775                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 776                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 777                                 e.addValue(e, _("Default"), "");
 778                                 e.addValue(e, _("Disable"), "0");
 779                                 for(i = 1; i <= 10; ++i)
 780                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 781                                 e.configureXonoticTextSliderValues(e);
 782         me.TR(me);
 783                 me.TDempty(me, 0.4);
 784                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 785         me.TR(me);
 786                 me.TDempty(me, 0.2);
 787                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 788                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 789                                 e.addValue(e, _("Default"), "");
 790                                 for(i = 0; i <= 10; ++i)
 791                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 792                                 e.configureXonoticTextSliderValues(e);
 793 }
 794
 795 float getFadedAlpha(float currentAlpha, float startAlpha, float targetAlpha)
 796 {
 797         if(startAlpha < targetAlpha)
 798                 currentAlpha = min(currentAlpha + frametime * 0.5, targetAlpha);
 799         else
 800                 currentAlpha = max(currentAlpha - frametime * 0.5, targetAlpha);
 801         return currentAlpha;
 802 }
 803
 804 void CheckSendCvars(entity me, string cvarnamestring)
 805 {
 806         if(me.sendCvars)
 807         {
 808                 LOG_INFOF("Sending cvar: %s -> %s\n", cvarnamestring, cvar_string(cvarnamestring));
 809                 if(gamestatus & (GAME_CONNECTED | GAME_ISSERVER))
 810                 {
 811                         cmd(sprintf("\nsendcvar %s\n", cvarnamestring));
 812                 }
 813         }
 814 }