qcsrc/menu/xonotic/soundlist.qc

   1 #include "soundlist.qh"
   2
   3 #include "inputbox.qh"
   4 #include "playlist.qh"
   5
   6 entity makeXonoticSoundList()
   7 {
   8         entity me;
   9         me = NEW(XonoticSoundList);
  10         me.configureXonoticSoundList(me);
  11         return me;
  12 }
  13
  14 void XonoticSoundList_configureXonoticSoundList(entity me)
  15 {
  16         me.configureXonoticListBox(me);
  17         me.nItems = 0;
  18 }
  19
  20 string XonoticSoundList_soundName(entity me, int i)
  21 {
  22         string s;
  23         s = search_getfilename(me.listSound, i);
  24         s = substring(s, 15, strlen(s) - 15 - 4); // sound/cdtracks/, .ogg
  25         return s;
  26 }
  27
  28
  29 void XonoticSoundList_getSounds(entity me)
  30 {
  31         string s;
  32
  33         if (me.filterString) {
  34                 // subdirectory in filterString allowed
  35                 s = strcat("sound/cdtracks/*", me.filterString, "*.ogg");
  36         } else {
  37                 s = "sound/cdtracks/*.ogg";
  38         }
  39
  40         if (me.listSound >= 0) {
  41                 search_end(me.listSound);
  42         }
  43
  44         me.listSound = search_begin(s, false, true);
  45
  46         me.nItems = (me.listSound < 0) ? 0 : search_getsize(me.listSound);
  47 }
  48
  49 void XonoticSoundList_destroy(entity me)
  50 {
  51         if (me.listSound >= 0) {
  52                 search_end(me.listSound);
  53         }
  54 }
  55
  56 void XonoticSoundList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  57 {
  58         me.itemAbsSize = '0 0 0';
  59         SUPER(XonoticSoundList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  60
  61         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
  62         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
  63         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
  64
  65         me.columnNumberOrigin = 0;
  66         me.columnNumberSize = me.realFontSize.x * 3;
  67
  68         me.columnNameOrigin = me.columnNumberSize;
  69         me.columnNameSize = 1 - me.columnNameOrigin - me.realFontSize.x;
  70 }
  71
  72 void XonoticSoundList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
  73 {
  74         string s;
  75         if (isSelected) {
  76                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  77         } else if (isFocused) {
  78                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
  79                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
  80         }
  81
  82         s = me.soundName(me, i);
  83         if (s == cvar_string("menu_cdtrack")) { // current menu track
  84                 draw_CenterText((me.columnNumberOrigin + 0.5 * me.columnNumberSize) * eX + me.realUpperMargin * eY, "[C]", me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
  85         } else if (s == cvar_defstring("menu_cdtrack")) { // default menu track
  86                 draw_CenterText((me.columnNumberOrigin + 0.5 * me.columnNumberSize) * eX + me.realUpperMargin * eY, "[D]", me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
  87         }
  88
  89         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
  90         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
  91 }
  92
  93 void XonoticSoundList_showNotify(entity me)
  94 {
  95         me.getSounds(me);
  96 }
  97
  98 void SoundList_Menu_Track_Change(entity box, entity me)
  99 {
 100         cvar_set("menu_cdtrack", me.soundName(me, me.selectedItem));
 101 }
 102
 103 void SoundList_Menu_Track_Reset(entity box, entity me)
 104 {
 105         cvar_set("menu_cdtrack", cvar_defstring("menu_cdtrack"));
 106 }
 107
 108 void SoundList_Filter_Change(entity box, entity me)
 109 {
 110         if (me.filterString) {
 111                 strunzone(me.filterString);
 112         }
 113
 114         if (box.text != "") {
 115                 me.filterString = strzone(box.text);
 116         } else {
 117                 me.filterString = string_null;
 118         }
 119
 120         me.getSounds(me);
 121 }
 122
 123 void SoundList_Add(entity box, entity me)
 124 {
 125         me.playlist.addToPlayList(me.playlist, me.soundName(me, me.selectedItem));
 126 }
 127
 128 void SoundList_Add_All(entity box, entity me)
 129 {
 130         int i;
 131         for (i = 0; i < me.nItems; ++i) {
 132                 me.playlist.addToPlayList(me.playlist, me.soundName(me, i));
 133         }
 134 }
 135
 136 void XonoticSoundList_doubleClickListBoxItem(entity me, int i, vector where)
 137 {
 138         me.playlist.addToPlayList(me.playlist, me.soundName(me, i));
 139 }
 140
 141 float XonoticSoundList_keyDown(entity me, float scan, float ascii, float shift)
 142 {
 143         if (scan == K_ENTER || scan == K_KP_ENTER || scan == K_SPACE) {
 144                 me.playlist.addToPlayList(me.playlist, me.soundName(me, me.selectedItem));
 145                 return 1;
 146         } else {
 147                 return SUPER(XonoticSoundList).keyDown(me, scan, ascii, shift);
 148         }
 149 }