qcsrc/menu/xonotic/skinlist.qc

   1 #include "skinlist.qh"
   2
   3 const float SKINPARM_NAME = 0;
   4 const float SKINPARM_TITLE = 1;
   5 const float SKINPARM_AUTHOR = 2;
   6 const float SKINPARM_PREVIEW = 3;
   7 const float SKINPARM_COUNT = 4;
   8
   9 entity makeXonoticSkinList()
  10 {
  11         entity me;
  12         me = NEW(XonoticSkinList);
  13         me.configureXonoticSkinList(me);
  14         return me;
  15 }
  16
  17 void XonoticSkinList_configureXonoticSkinList(entity me)
  18 {
  19         me.configureXonoticListBox(me);
  20         me.getSkins(me);
  21         me.loadCvars(me);
  22 }
  23
  24 void XonoticSkinList_loadCvars(entity me)
  25 {
  26         string s;
  27         float i, n;
  28         s = cvar_string("menu_skin");
  29         n = me.nItems;
  30         for (i = 0; i < n; ++i) {
  31                 if (me.skinParameter(me, i, SKINPARM_NAME) == s) {
  32                         me.setSelected(me, i);
  33                         break;
  34                 }
  35         }
  36 }
  37
  38 void XonoticSkinList_saveCvars(entity me)
  39 {
  40         cvar_set("menu_skin", me.skinParameter(me, me.selectedItem, SKINPARM_NAME));
  41 }
  42
  43 string XonoticSkinList_skinParameter(entity me, float i, float key)
  44 {
  45         return bufstr_get(me.skinlist, i * SKINPARM_COUNT + key);
  46 }
  47
  48 void XonoticSkinList_getSkins(entity me)
  49 {
  50         float glob, buf, i, n, fh;
  51         string s, name;
  52
  53         buf = buf_create();
  54         glob = search_begin("gfx/menu/*/skinvalues.txt", true, true);
  55         if (glob < 0) {
  56                 me.skinlist = buf;
  57                 me.nItems = 0;
  58                 return;
  59         }
  60
  61         n = search_getsize(glob);
  62         for (i = 0; i < n; ++i) {
  63                 s = search_getfilename(glob, i);
  64                 name = substring(s, 9, strlen(s) - 24); // the * part
  65                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_NAME, name);
  66                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_TITLE, _("<TITLE>"));
  67                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_AUTHOR, _("<AUTHOR>"));
  68                 if (draw_PictureSize(strcat("/gfx/menu/", substring(s, 9, strlen(s) - 24), "/skinpreview")) == '0 0 0') {
  69                         bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_PREVIEW, "nopreview_menuskin");
  70                 } else {
  71                         bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_PREVIEW, strcat("/gfx/menu/", substring(s, 9, strlen(s) - 24), "/skinpreview"));
  72                 }
  73                 fh = fopen(s, FILE_READ);
  74                 if (fh < 0) {
  75                         LOG_INFO("Warning: can't open skinvalues.txt file");
  76                         continue;
  77                 }
  78                 while ((s = fgets(fh))) {
  79                         // these two are handled by skinlist.qc
  80                         if (substring(s, 0, 6) == "title ") {
  81                                 if (name == cvar_defstring("menu_skin")) {
  82                                         bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_TITLE, strcat(substring(s, 6, strlen(s) - 6), " (", _("Default"), ")"));
  83                                 } else {
  84                                         bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_TITLE, substring(s, 6, strlen(s) - 6));
  85                                 }
  86                         } else if (substring(s, 0, 7) == "author ") {
  87                                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_AUTHOR, substring(s, 7, strlen(s) - 7));
  88                         }
  89                 }
  90                 fclose(fh);
  91         }
  92
  93         search_end(glob);
  94
  95         me.skinlist = buf;
  96         me.nItems = n;
  97 }
  98
  99 void XonoticSkinList_destroy(entity me)
 100 {
 101         buf_del(me.skinlist);
 102 }
 103
 104 void XonoticSkinList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 105 {
 106         me.itemAbsSize = '0 0 0';
 107         SUPER(XonoticSkinList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 108
 109         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 110         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 111         me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize.y);
 112         me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize.y;
 113
 114         me.columnPreviewOrigin = 0;
 115         me.columnPreviewSize = me.itemAbsSize.y / me.itemAbsSize.x * 4 / 3;
 116         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize.x;
 117         me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize.x;
 118 }
 119
 120 void XonoticSkinList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 121 {
 122         string s;
 123
 124         if (isSelected) {
 125                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 126         } else if (isFocused) {
 127                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 128                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 129         }
 130
 131         s = me.skinParameter(me, i, SKINPARM_PREVIEW);
 132         draw_Picture(me.columnPreviewOrigin * eX, s, me.columnPreviewSize * eX + eY, '1 1 1', 1);
 133
 134         s = me.skinParameter(me, i, SKINPARM_TITLE);
 135         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 136         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_SKINLIST_TITLE, SKINALPHA_TEXT, 0);
 137
 138         s = me.skinParameter(me, i, SKINPARM_AUTHOR);
 139         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 140         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_SKINLIST_AUTHOR, SKINALPHA_TEXT, 0);
 141 }
 142
 143 void XonoticSkinList_setSkin(entity me)
 144 {
 145         me.saveCvars(me);
 146         localcmd("\nmenu_restart\nmenu_cmd skinselect\n");
 147 }
 148
 149 void SetSkin_Click(entity btn, entity me)
 150 {
 151         me.setSkin(me);
 152 }
 153
 154 void XonoticSkinList_doubleClickListBoxItem(entity me, float i, vector where)
 155 {
 156         m_play_click_sound(MENU_SOUND_EXECUTE);
 157         me.setSkin(me);
 158 }
 159
 160 float XonoticSkinList_keyDown(entity me, float scan, float ascii, float shift)
 161 {
 162         if (scan == K_ENTER || scan == K_KP_ENTER) {
 163                 m_play_click_sound(MENU_SOUND_EXECUTE);
 164                 me.setSkin(me);
 165                 return 1;
 166         } else {
 167                 return SUPER(XonoticSkinList).keyDown(me, scan, ascii, shift);
 168         }
 169 }