qcsrc/menu/xonotic/screenshotlist.qc

   1 #include "screenshotlist.qh"
   2
   3 #include "dialog_multiplayer_media_screenshot.qh"
   4 #include "dialog_multiplayer_media_screenshot_viewer.qh"
   5 #include "inputbox.qh"
   6 #include "../item/modalcontroller.qh"
   7
   8 entity makeXonoticScreenshotList()
   9 {
  10         entity me;
  11         me = NEW(XonoticScreenshotList);
  12         me.configureXonoticScreenshotList(me);
  13         return me;
  14 }
  15
  16 void XonoticScreenshotList_configureXonoticScreenshotList(entity me)
  17 {
  18         me.configureXonoticListBox(me);
  19         me.nItems = 0;
  20 }
  21
  22 string XonoticScreenshotList_screenshotName(entity me, float i)
  23 {
  24         string s;
  25         s = bufstr_get(me.listScreenshot, i);
  26
  27         if (substring(s, 0, 1) == "/") {
  28                 s = substring(s, 1, strlen(s) - 1); // remove the first forward slash
  29         }
  30         return s;
  31 }
  32
  33 // if subdir is true look in subdirectories too (1 level)
  34 void getScreenshots_for_ext(entity me, string ext, float subdir)
  35 {
  36         string s;
  37         if (subdir) {
  38                 s = "screenshots/*/";
  39         } else {
  40                 s = "screenshots/";
  41         }
  42         if (me.filterString) {
  43                 s = strcat(s, me.filterString, ext);
  44         } else {
  45                 s = strcat(s, "*", ext);
  46         }
  47
  48         float list, i, n;
  49         list = search_begin(s, false, true);
  50         if (list >= 0) {
  51                 n = search_getsize(list);
  52                 for (i = 0; i < n; ++i) {
  53                         s = search_getfilename(list, i);                                          // get initial full file name
  54                         s = substring(s, 12, (strlen(s) - 12 - 4));                               // remove "screenshots/" prefix and ".<ext>" suffix
  55                         s = strdecolorize(s);                                                     // remove any pre-existing colors
  56                         if (subdir) {
  57                                 s = strreplace("/", "^7/", s);                                        // clear colors at the forward slash
  58                                 s = strcat("/", rgb_to_hexcolor(SKINCOLOR_SCREENSHOTLIST_SUBDIR), s); // add a forward slash for sorting, then color
  59                                 bufstr_add(me.listScreenshot, s, true);
  60                         } else { bufstr_add(me.listScreenshot, s, true); }
  61                 }
  62                 search_end(list);
  63         }
  64
  65         if (subdir) {
  66                 getScreenshots_for_ext(me, ext, false);
  67         }
  68 }
  69
  70 void XonoticScreenshotList_getScreenshots(entity me)
  71 {
  72         if (me.listScreenshot >= 0) {
  73                 buf_del(me.listScreenshot);
  74         }
  75         me.listScreenshot = buf_create();
  76         if (me.listScreenshot < 0) {
  77                 me.nItems = 0;
  78                 return;
  79         }
  80         getScreenshots_for_ext(me, ".jpg", true);
  81         getScreenshots_for_ext(me, ".tga", true);
  82         getScreenshots_for_ext(me, ".png", true);
  83         me.nItems = buf_getsize(me.listScreenshot);
  84         if (me.nItems > 0) {
  85                 buf_sort(me.listScreenshot, 128, false);
  86         }
  87 }
  88
  89 void XonoticScreenshotList_destroy(entity me)
  90 {
  91         if (me.nItems > 0) {
  92                 buf_del(me.listScreenshot);
  93         }
  94 }
  95
  96 void XonoticScreenshotList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  97 {
  98         me.itemAbsSize = '0 0 0';
  99         SUPER(XonoticScreenshotList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 100
 101         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 102         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 103         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 104
 105         me.columnNameOrigin = me.realFontSize.x;
 106         me.columnNameSize = 1 - 2 * me.realFontSize.x;
 107 }
 108
 109 void XonoticScreenshotList_setSelected(entity me, float i)
 110 {
 111         if (me.newSlideShowScreenshotTime) {
 112                 me.startSlideShow(me);
 113         }
 114         float selectedItem_save = me.selectedItem;
 115         SUPER(XonoticScreenshotList).setSelected(me, i);
 116         if (me.pressed && me.selectedItem != selectedItem_save) {
 117                 // avoid immediate image loading on quick repeated selection changes
 118                 me.newScreenshotTime = time + 0.22;
 119         } else if (time > me.newScreenshotTime) {
 120                 me.newScreenshotTime = 0;
 121                 me.previewScreenshot(me); // load the preview on selection change
 122         }
 123 }
 124
 125 void XonoticScreenshotList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 126 {
 127         string s;
 128         if (isSelected) {
 129                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 130         } else if (isFocused) {
 131                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 132                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 133         }
 134
 135         s = me.screenshotName(me, i);
 136         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 137         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 1);
 138 }
 139
 140 void XonoticScreenshotList_showNotify(entity me)
 141 {
 142         me.getScreenshots(me);
 143         me.previewScreenshot(me);
 144 }
 145
 146 void ScreenshotList_Refresh_Click(entity btn, entity me)
 147 {
 148         me.getScreenshots(me);
 149         me.setSelected(me, 0); // always select the first element after a list update
 150 }
 151
 152 void ScreenshotList_Filter_Change(entity box, entity me)
 153 {
 154         if (me.filterString) {
 155                 strunzone(me.filterString);
 156         }
 157
 158         if (box.text != "") {
 159                 if (strstrofs(box.text, "*", 0) >= 0 || strstrofs(box.text, "?", 0) >= 0) {
 160                         me.filterString = strzone(box.text);
 161                 } else {
 162                         me.filterString = strzone(strcat("*", box.text, "*"));
 163                 }
 164         } else {
 165                 me.filterString = string_null;
 166         }
 167
 168         ScreenshotList_Refresh_Click(NULL, me);
 169 }
 170
 171 void ScreenshotList_Filter_Would_Change(entity box, entity me)
 172 {
 173         me.filterBox = box;
 174         me.filterTime = time + 0.5;
 175 }
 176
 177 void XonoticScreenshotList_draw(entity me)
 178 {
 179         if (me.filterTime && time > me.filterTime) {
 180                 ScreenshotList_Filter_Change(me.filterBox, me);
 181                 me.filterTime = 0;
 182         }
 183         if (me.newScreenshotTime && time > me.newScreenshotTime) {
 184                 me.previewScreenshot(me);
 185                 me.newScreenshotTime = 0;
 186         } else if (me.newSlideShowScreenshotTime && time > me.newSlideShowScreenshotTime) {
 187                 if (me.selectedItem == me.nItems - 1) { // last screenshot?
 188                         // restart from the first screenshot
 189                         me.setSelected(me, 0);
 190                         me.goScreenshot(me, +0);
 191                 } else {
 192                         me.goScreenshot(me, +1);
 193                 }
 194         }
 195         SUPER(XonoticScreenshotList).draw(me);
 196 }
 197
 198 void XonoticScreenshotList_startSlideShow(entity me)
 199 {
 200         me.newSlideShowScreenshotTime = time + 3;
 201 }
 202
 203 void XonoticScreenshotList_stopSlideShow(entity me)
 204 {
 205         me.newSlideShowScreenshotTime = 0;
 206 }
 207
 208 void XonoticScreenshotList_goScreenshot(entity me, float d)
 209 {
 210         if (!me.screenshotViewerDialog) {
 211                 return;
 212         }
 213         me.setSelected(me, me.selectedItem + d);
 214         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me, me.selectedItem))));
 215 }
 216
 217 void XonoticScreenshotList_startScreenshot(entity me)
 218 {
 219         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me, me.selectedItem))));
 220         // pop up screenshot
 221         DialogOpenButton_Click_withCoords(NULL, me.screenshotViewerDialog, me.origin + eX * (me.columnNameOrigin * me.size.x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size.y), eY * me.itemAbsSize.y + eX * (me.itemAbsSize.x * me.columnNameSize));
 222 }
 223
 224 void XonoticScreenshotList_previewScreenshot(entity me)
 225 {
 226         if (!me.screenshotBrowserDialog) {
 227                 return;
 228         }
 229         if (me.nItems <= 0) {
 230                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, "");
 231         } else {
 232                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me, me.selectedItem))));
 233         }
 234 }
 235
 236 void StartScreenshot_Click(entity btn, entity me)
 237 {
 238         me.startScreenshot(me);
 239 }
 240
 241 void XonoticScreenshotList_doubleClickListBoxItem(entity me, float i, vector where)
 242 {
 243         me.startScreenshot(me);
 244 }
 245
 246 float XonoticScreenshotList_keyDown(entity me, float scan, float ascii, float shift)
 247 {
 248         if (scan == K_ENTER || scan == K_KP_ENTER || scan == K_MOUSE2 || scan == K_SPACE) {
 249                 me.startScreenshot(me);
 250                 return 1;
 251         }
 252         return SUPER(XonoticScreenshotList).keyDown(me, scan, ascii, shift);
 253 }