qcsrc/menu/xonotic/languagelist.qc

   1 #ifndef LANGUAGELIST_H
   2 #define LANGUAGELIST_H
   3 CLASS(XonoticLanguageList, XonoticListBox)
   4         METHOD(XonoticLanguageList, configureXonoticLanguageList, void(entity))
   5         ATTRIB(XonoticLanguageList, rowsPerItem, float, 1)
   6         METHOD(XonoticLanguageList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(XonoticLanguageList, resizeNotify, void(entity, vector, vector, vector, vector))
   8         METHOD(XonoticLanguageList, setSelected, void(entity, float))
   9         METHOD(XonoticLanguageList, loadCvars, void(entity))
  10         METHOD(XonoticLanguageList, saveCvars, void(entity))
  11
  12         ATTRIB(XonoticLanguageList, realFontSize, vector, '0 0 0')
  13         ATTRIB(XonoticLanguageList, realUpperMargin, float, 0)
  14         ATTRIB(XonoticLanguageList, columnNameOrigin, float, 0)
  15         ATTRIB(XonoticLanguageList, columnNameSize, float, 0)
  16         ATTRIB(XonoticLanguageList, columnPercentageOrigin, float, 0)
  17         ATTRIB(XonoticLanguageList, columnPercentageSize, float, 0)
  18
  19         METHOD(XonoticLanguageList, doubleClickListBoxItem, void(entity, float, vector))
  20         METHOD(XonoticLanguageList, keyDown, float(entity, float, float, float)) // enter handling
  21
  22         METHOD(XonoticLanguageList, destroy, void(entity))
  23
  24         ATTRIB(XonoticLanguageList, languagelist, float, -1)
  25         METHOD(XonoticLanguageList, getLanguages, void(entity))
  26         METHOD(XonoticLanguageList, setLanguage, void(entity))
  27         METHOD(XonoticLanguageList, languageParameter, string(entity, float, float))
  28
  29         ATTRIB(XonoticLanguageList, name, string, "languageselector") // change this to make it noninteractive (for first run dialog)
  30 ENDCLASS(XonoticLanguageList)
  31
  32 entity makeXonoticLanguageList();
  33 void SetLanguage_Click(entity btn, entity me);
  34 #endif
  35
  36 #ifdef IMPLEMENTATION
  37
  38 const float LANGPARM_ID = 0;
  39 const float LANGPARM_NAME = 1;
  40 const float LANGPARM_NAME_LOCALIZED = 2;
  41 const float LANGPARM_PERCENTAGE = 3;
  42 const float LANGPARM_COUNT = 4;
  43
  44 entity makeXonoticLanguageList()
  45 {
  46         entity me;
  47         me = NEW(XonoticLanguageList);
  48         me.configureXonoticLanguageList(me);
  49         return me;
  50 }
  51
  52 void XonoticLanguageList_configureXonoticLanguageList(entity me)
  53 {
  54         me.configureXonoticListBox(me);
  55         me.getLanguages(me);
  56         me.loadCvars(me);
  57 }
  58
  59 void XonoticLanguageList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
  60 {
  61         string s, p;
  62         if(isSelected)
  63                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  64
  65         s = me.languageParameter(me, i, LANGPARM_NAME_LOCALIZED);
  66
  67         vector save_fontscale = draw_fontscale;
  68         float f = draw_CondensedFontFactor(s, false, me.realFontSize, 1);
  69         draw_fontscale.x *= f;
  70         vector fs = me.realFontSize;
  71         fs.x *= f;
  72         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  73         draw_fontscale = save_fontscale;
  74
  75         p = me.languageParameter(me, i, LANGPARM_PERCENTAGE);
  76         if(p != "")
  77         {
  78                 vector save_fontscale = draw_fontscale;
  79                 float f = draw_CondensedFontFactor(p, false, me.realFontSize, 1);
  80                 draw_fontscale.x *= f;
  81                 vector fs = me.realFontSize;
  82                 fs.x *= f;
  83                 draw_Text(me.realUpperMargin * eY + (me.columnPercentageOrigin + (me.columnPercentageSize - draw_TextWidth(p, 0, fs))) * eX, p, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  84                 draw_fontscale = save_fontscale;
  85         }
  86 }
  87
  88 void XonoticLanguageList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  89 {
  90         SUPER(XonoticLanguageList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  91         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
  92         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
  93         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
  94         me.columnPercentageSize = me.realFontSize.x * 3;
  95         me.columnPercentageOrigin = 1 - me.columnPercentageSize;
  96         me.columnNameOrigin = 0;
  97         me.columnNameSize = me.columnPercentageOrigin;
  98 }
  99
 100 void XonoticLanguageList_setSelected(entity me, float i)
 101 {
 102         SUPER(XonoticLanguageList).setSelected(me, i);
 103         me.saveCvars(me);
 104 }
 105
 106 void XonoticLanguageList_loadCvars(entity me)
 107 {
 108         string s;
 109         float i, n;
 110         s = cvar_string("_menu_prvm_language");
 111         n = me.nItems;
 112
 113         // default to English
 114         for(i = 0; i < n; ++i)
 115         {
 116                 if(me.languageParameter(me, i, LANGPARM_ID) == "en")
 117                 {
 118                         me.selectedItem = i;
 119                         break;
 120                 }
 121         }
 122
 123         // otherwise, find the language
 124         for(i = 0; i < n; ++i)
 125         {
 126                 if(me.languageParameter(me, i, LANGPARM_ID) == s)
 127                 {
 128                         me.selectedItem = i;
 129                         break;
 130                 }
 131         }
 132
 133         // save it off (turning anything unknown into "en")
 134         me.saveCvars(me);
 135 }
 136
 137 void XonoticLanguageList_saveCvars(entity me)
 138 {
 139         cvar_set("_menu_prvm_language", me.languageParameter(me, me.selectedItem, LANGPARM_ID));
 140 }
 141
 142 void XonoticLanguageList_doubleClickListBoxItem(entity me, float i, vector where)
 143 {
 144         m_play_click_sound(MENU_SOUND_EXECUTE);
 145         me.setLanguage(me);
 146 }
 147
 148 float XonoticLanguageList_keyDown(entity me, float scan, float ascii, float shift)
 149 {
 150         if(scan == K_ENTER || scan == K_KP_ENTER)
 151         {
 152                 m_play_click_sound(MENU_SOUND_EXECUTE);
 153                 me.setLanguage(me);
 154                 return 1;
 155         }
 156         else
 157                 return SUPER(XonoticLanguageList).keyDown(me, scan, ascii, shift);
 158 }
 159
 160 void XonoticLanguageList_destroy(entity me)
 161 {
 162         buf_del(me.languagelist);
 163 }
 164
 165 void XonoticLanguageList_getLanguages(entity me)
 166 {
 167         float buf, i, n, fh;
 168         string s;
 169
 170         buf = buf_create();
 171
 172         fh = fopen("languages.txt", FILE_READ);
 173         i = 0;
 174         while((s = fgets(fh)))
 175         {
 176                 n = tokenize_console(s);
 177                 if(n < 3)
 178                         continue;
 179                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_ID, argv(0));
 180                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME, argv(1));
 181                 float k = strstrofs(argv(2), "(", 0);
 182                 if(k > 0)
 183                 if(substring(argv(2), strlen(argv(2)) - 1, 1) == ")")
 184                 {
 185                         string percent = substring(argv(2), k + 1, -2);
 186                         if(percent != "100%")
 187                                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_PERCENTAGE, percent);
 188                 }
 189                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME_LOCALIZED, (k < 0) ? argv(2) : substring(argv(2), 0, k - 1));
 190                 ++i;
 191         }
 192         fclose(fh);
 193
 194         me.languagelist = buf;
 195         me.nItems = i;
 196 }
 197
 198 void XonoticLanguageList_setLanguage(entity me)
 199 {
 200         if(prvm_language != cvar_string("_menu_prvm_language"))
 201         {
 202                 if(!(gamestatus & GAME_CONNECTED))
 203                         localcmd("\nprvm_language \"$_menu_prvm_language\"; menu_restart; menu_cmd languageselect\n");
 204                 else
 205                         DialogOpenButton_Click(me, main.languageWarningDialog);
 206         }
 207 }
 208
 209 string XonoticLanguageList_languageParameter(entity me, float i, float key)
 210 {
 211         return bufstr_get(me.languagelist, i * LANGPARM_COUNT + key);
 212 }
 213
 214 void SetLanguage_Click(entity btn, entity me)
 215 {
 216         me.setLanguage(me);
 217 }
 218
 219 #endif