qcsrc/menu/xonotic/dialog_multiplayer_profile.qc

   1 #include "dialog_multiplayer_profile.qh"
   2
   3 #include "playermodel.qh"
   4 #include "statslist.qh"
   5 #include "languagelist.qh"
   6 #include "textlabel.qh"
   7 #include "commandbutton.qh"
   8 #include "inputbox.qh"
   9 #include "colorpicker.qh"
  10 #include "charmap.qh"
  11 #include "colorbutton.qh"
  12 #include "checkbox.qh"
  13 #include "radiobutton.qh"
  14
  15 #define MENU_CVAR_NAME "_menu_cl_name"
  16 #define MENU_CVAR_COLOR "_menu_cl_color"
  17 #define MENU_CVAR_SKIN "_menu_cl_playerskin"
  18 #define MENU_CVAR_MODEL "_menu_cl_playermodel"
  19
  20 entity makeXonoticProfileTab()
  21 {
  22         entity me;
  23         me = NEW(XonoticProfileTab);
  24         me.configureDialog(me);
  25
  26         // if color unset, set random color (init it)
  27         if (cvar_string("_cl_color") == cvar_defstring("_cl_color"))
  28         {
  29                 // idk what meaning of 16, maybe just COLOR_BUTTONS_COUNT+1
  30                 float randomColor = 16 * floor(random() * COLOR_BUTTONS_COUNT) + floor(random() * COLOR_BUTTONS_COUNT);
  31                 cvar_set("_cl_color", ftos(randomColor));
  32         }
  33
  34         return me;
  35 }
  36
  37 void XonoticProfileTab_draw(entity me)
  38 {
  39         string name = cvar_string("_cl_name");
  40
  41         if(name == "Player")
  42                 me.playerNameLabel.alpha = ((mod(time * 2, 2) < 1) ? 1 : 0);
  43         else
  44                 me.playerNameLabel.alpha = me.playerNameLabelAlpha;
  45
  46         // if values changed from console, update it in menu
  47         if (me.applyButton.disabled)
  48         {
  49                 // name field
  50                 string inputName  = cvar_string(MENU_CVAR_NAME);
  51                 if (name != inputName)
  52                 {
  53                         cvar_set(MENU_CVAR_NAME, name);
  54                         me.nameInput.loadCvars(me.nameInput);
  55                 }
  56
  57                 // color buttons
  58                 string color = cvar_string("_cl_color");
  59                 string inputColor = cvar_string(MENU_CVAR_COLOR);
  60                 if (color != inputColor)
  61                 {
  62                         cvar_set(MENU_CVAR_COLOR, color);
  63                         for (int i = 0; i < COLOR_BUTTONS_COUNT; i++)
  64                         {
  65                                 me.colorButtonGroup1[i].loadCvars(me.colorButtonGroup1[i]);
  66                                 me.colorButtonGroup2[i].loadCvars(me.colorButtonGroup2[i]);
  67                         }
  68                 }
  69
  70                 // player model
  71                 string skin = cvar_string("_cl_playerskin");
  72                 string skinInput = cvar_string(MENU_CVAR_SKIN);
  73                 string model = cvar_string("_cl_playermodel");
  74                 string modelInput = cvar_string(MENU_CVAR_MODEL);
  75                 if (skin != skinInput || model != modelInput)
  76                 {
  77                         cvar_set(MENU_CVAR_SKIN, skin);
  78                         cvar_set(MENU_CVAR_MODEL, model);
  79                         me.playerModelSelector.loadCvars(me.playerModelSelector);
  80                         me.playerModelSelector.go(me.playerModelSelector, 0);
  81                 }
  82         }
  83
  84         SUPER(XonoticProfileTab).draw(me);
  85 }
  86 void language_selector_click(entity me, entity btn)
  87 {
  88         localcmd("\nmenu_cmd languageselect\n");
  89 }
  90 void XonoticProfileTab_fill(entity me)
  91 {
  92         entity e, label;
  93         float i;
  94         me.applyButton = makeXonoticCommandButton(_("Apply immediately"), '0 0 0',
  95                 "_cl_color \"$"MENU_CVAR_COLOR"\""
  96                 "color -1 -1;" // apply colors contained in _cl_color
  97                 "name \"$"MENU_CVAR_NAME"\";"
  98                 "playermodel $"MENU_CVAR_MODEL";"
  99                 "playerskin $"MENU_CVAR_SKIN";"
 100                 , COMMANDBUTTON_APPLY);
 101         me.applyButton.disableOnClick = true;
 102
 103         // ==============
 104         //  NAME SECTION
 105         // ==============
 106         me.gotoRC(me, 0.5, 0);
 107                 me.TD(me, 1, 3, me.playerNameLabel = makeXonoticHeaderLabel(_("Name")));
 108
 109         me.gotoRC(me, 1.5, 0);
 110                 me.TD(me, 1, 3, label = makeXonoticTextLabel(0.5, string_null));
 111                         label.allowCut = 1;
 112                         label.allowColors = 1;
 113                         label.alpha = 1;
 114                         label.isBold = true;
 115                         label.fontSize = SKINFONTSIZE_TITLE;
 116
 117         me.gotoRC(me, 2.5, 0);
 118                 me.TD(me, 1, 3.0, me.nameInput = makeXonoticInputBox_T(1, MENU_CVAR_NAME,
 119                         _("Name under which you will appear in the game")));
 120                         me.nameInput.forbiddenCharacters = "\r\n\\\"$"; // don't care, isn't getting saved
 121                         me.nameInput.maxLength = -127; // negative means encoded length in bytes
 122                         me.nameInput.saveImmediately = 0;  // Sorry, can't do this, it spams "name" commands.
 123                         me.nameInput.enableClearButton = 0;
 124                         me.nameInput.applyButton = me.applyButton;
 125                         label.textEntity = me.nameInput;
 126         me.TR(me);
 127                 me.TD(me, 5, 1, e = makeXonoticColorpicker(me.nameInput));
 128                 me.TD(me, 5, 2, e = makeXonoticCharmap(me.nameInput));
 129
 130         // ===============
 131         //  MODEL SECTION
 132         // ===============
 133         //me.gotoRC(me, 0.5, 3.1); me.setFirstColumn(me, me.currentColumn); // TOP RIGHT
 134         //me.gotoRC(me, 9, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM RIGHT
 135         me.gotoRC(me, 9, 0); me.setFirstColumn(me, me.currentColumn); // BOTTOM LEFT
 136                 me.TD(me, 1, 3, e = makeXonoticHeaderLabel(_("Model")));
 137
 138         me.TR(me);
 139                 //me.TDempty(me, 0); // MODEL LEFT, COLOR RIGHT
 140                 me.TDempty(me, 1); // MODEL RIGHT, COLOR LEFT
 141                 me.playerModelSelector = makeXonoticPlayerModelSelector(MENU_CVAR_SKIN, MENU_CVAR_MODEL);
 142                 me.TD(me, 1, 0.3, e = makeXonoticButton("<<", '0 0 0'));
 143                         e.onClick = PlayerModelSelector_Prev_Click;
 144                         e.onClickEntity = me.playerModelSelector;
 145                         e.applyButton = me.applyButton;
 146                 me.TD(me, 11.5, 1.4, me.playerModelSelector);
 147                 me.TD(me, 1, 0.3, e = makeXonoticButton(">>", '0 0 0'));
 148                         e.onClick = PlayerModelSelector_Next_Click;
 149                         e.onClickEntity = me.playerModelSelector;
 150                         e.applyButton = me.applyButton;
 151
 152         //me.setFirstColumn(me, me.currentColumn + 2); // MODEL LEFT, COLOR RIGHT
 153         me.gotoRC(me, me.currentRow, 0); me.setFirstColumn(me, me.currentColumn); // MODEL RIGHT, COLOR LEFT
 154         me.TR(me);
 155                 me.TD(me, 1, 1, e = makeXonoticHeaderLabel(_("Glowing color")));
 156                 for(i = 0; i < COLOR_BUTTONS_COUNT; ++i)
 157                 {
 158                         if(mod(i, 5) == 0)
 159                                 me.TR(me);
 160                         me.TDNoMargin(me, 1, 0.2, me.colorButtonGroup1[i] = makeXonoticColorButton(MENU_CVAR_COLOR, 1, 0, i), '0 1 0');
 161                                 me.colorButtonGroup1[i].applyButton = me.applyButton;
 162                 }
 163         me.TR(me);
 164         me.TR(me);
 165                 me.TD(me, 1, 1, e = makeXonoticHeaderLabel(_("Detail color")));
 166                 for(i = 0; i < COLOR_BUTTONS_COUNT; ++i)
 167                 {
 168                         if(mod(i, 5) == 0)
 169                                 me.TR(me);
 170                         me.TDNoMargin(me, 1, 0.2, me.colorButtonGroup2[i] = makeXonoticColorButton(MENU_CVAR_COLOR, 2, 1, i), '0 1 0');
 171                                 me.colorButtonGroup2[i].applyButton = me.applyButton;
 172                 }
 173
 174         // ====================
 175         //  STATISTICS SECTION
 176         // ====================
 177         me.gotoRC(me, 0.5, 3.1); me.setFirstColumn(me, me.currentColumn); // TOP RIGHT
 178         //me.gotoRC(me, 9, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM RIGHT
 179         //me.gotoRC(me, 9, 0); me.setFirstColumn(me, me.currentColumn); // BOTTOM LEFT
 180                 me.TD(me, 1, 3, e = makeXonoticHeaderLabel(_("Statistics")));
 181
 182         me.TR(me);
 183                 me.TDempty(me, 0.25);
 184                 me.TD(me, 1, 2.5, e = makeXonoticCheckBox(0, "cl_allow_uidtracking", _("Allow player statistics to track your client")));
 185                         e.sendCvars = true;
 186         me.TR(me);
 187                 me.TDempty(me, 0.25);
 188                 me.TD(me, 1, 2.5, e = makeXonoticCheckBox(0, "cl_allow_uid2name", _("Allow player statistics to use your nickname")));
 189                         e.sendCvars = true;
 190                         setDependent(e, "cl_allow_uidtracking", 1, 1);
 191         me.TR(me);
 192                 me.TDempty(me, 0.25);
 193                 me.TD(me, 1, 2.5, e = makeXonoticCheckBox(0, "cl_allow_uidranking", _("Allow player statistics to rank you in leaderboards")));
 194                         e.sendCvars = true;
 195                         setDependent(e, "cl_allow_uidtracking", 1, 1);
 196         me.gotoRC(me, 4.5, 3.1); // TOP RIGHT
 197         //me.gotoRC(me, 12.5, 3.1); // BOTTOM RIGHT
 198         //me.gotoRC(me, 12.5, 0); // BOTTOM LEFT
 199                 me.TDempty(me, 0.25);
 200                 me.TD(me, 9, 2.5, statslist = makeXonoticStatsList());
 201                 //setDependent(statslist, "cl_allow_uidtracking", 1, 1);
 202
 203         // =================
 204         //  COUNTRY SECTION
 205         // =================
 206         me.gotoRC(me, 16, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM SECTION, TOP POS
 207         //me.gotoRC(me, 13.5, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM SECTION, TOP POS
 208         //me.gotoRC(me, 0.5, 3.1); me.setFirstColumn(me, me.currentColumn); // TOP SECTION, TOP POS
 209                 //me.TD(me, 1, 3, e = makeXonoticHeaderLabel(_("Country")));
 210
 211         me.TR(me);
 212                 me.TDempty(me, 0.75);
 213                 me.TD(me, 1, 1.5, e = makeXonoticButton(_("Select language..."), '0 0 0'));
 214                         e.onClick = language_selector_click;
 215                         e.onClickEntity = me;
 216                 /*
 217                 me.TDempty(me, 0.5);
 218                 me.TD(me, 4.5, 2, e = makeXonoticLanguageList()); // todo: cl_country: create proper country list
 219                 */
 220
 221         me.gotoRC(me, me.rows - 1, 0);
 222                 me.TD(me, 1, me.columns, me.applyButton);
 223 }