qcsrc/menu/xonotic/dialog_multiplayer_create.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticServerCreateTab) EXTENDS(XonoticTab)
   3         METHOD(XonoticServerCreateTab, fill, void(entity))
   4         METHOD(XonoticServerCreateTab, gameTypeChangeNotify, void(entity))
   5         ATTRIB(XonoticServerCreateTab, title, string, "Create")
   6         ATTRIB(XonoticServerCreateTab, intendedWidth, float, 0.9)
   7         ATTRIB(XonoticServerCreateTab, rows, float, 22)
   8         ATTRIB(XonoticServerCreateTab, columns, float, 6.5)
   9
  10         ATTRIB(XonoticServerCreateTab, mapListBox, entity, NULL)
  11         ATTRIB(XonoticServerCreateTab, sliderFraglimit, entity, NULL)
  12         ATTRIB(XonoticServerCreateTab, sliderTimelimit, entity, NULL)
  13         ATTRIB(XonoticServerCreateTab, checkboxFraglimit, entity, NULL)
  14         ATTRIB(XonoticServerCreateTab, checkboxFraglimitMapinfo, entity, NULL)
  15 ENDCLASS(XonoticServerCreateTab)
  16 entity makeXonoticServerCreateTab();
  17 #endif
  18
  19 #ifdef IMPLEMENTATION
  20
  21 entity makeXonoticServerCreateTab()
  22 {
  23         entity me;
  24         me = spawnXonoticServerCreateTab();
  25         me.configureDialog(me);
  26         return me;
  27 }
  28
  29 void XonoticServerCreateTab_fill(entity me)
  30 {
  31         entity e, e0;
  32         float n;
  33
  34         me.TR(me);
  35                 me.TD(me, 1, 3, e = makeXonoticTextLabel(0, "Game type:"));
  36         me.TR(me);
  37                 me.TD(me, 9, 3, e = makeXonoticGametypeList());
  38         me.TR(me);
  39         me.TR(me);
  40         me.TR(me);
  41         me.TR(me);
  42         me.TR(me);
  43         me.TR(me);
  44         me.TR(me);
  45         me.TR(me);
  46         me.TR(me);
  47                 me.TD(me, 1, 3, e = makeXonoticTextLabel(0, "Match settings:"));
  48         me.TR(me);
  49                 me.sliderTimelimit = makeXonoticSlider(1.0, 60.0, 0.5, "timelimit_override");
  50                 me.TD(me, 1, 1, e = makeXonoticSliderCheckBox(0, 1, me.sliderTimelimit, "Time limit:"));
  51                 me.TD(me, 1, 2, me.sliderTimelimit);
  52         me.TR(me);
  53                 me.TDempty(me, 0.2);
  54                 me.TD(me, 1, 2.8, e = makeXonoticSliderCheckBox(-1, 0, me.sliderTimelimit, "Use map specified default"));
  55         me.TR(me);
  56                 me.sliderFraglimit = makeXonoticSlider(1.0, 2000.0, 5, "fraglimit_override");
  57                 me.TD(me, 1, 1, e = makeXonoticSliderCheckBox(0, 1, me.sliderFraglimit, "Point limit:"));
  58                         me.checkboxFraglimit = e;
  59                 me.TD(me, 1, 2, me.sliderFraglimit);
  60         me.TR(me);
  61                 me.TDempty(me, 0.2);
  62                 me.TD(me, 1, 2.8, e = makeXonoticSliderCheckBox(-1, 0, me.sliderFraglimit, "Use map specified default"));
  63                         me.checkboxFraglimitMapinfo = e;
  64         me.TR(me);
  65                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, "Player slots:"));
  66                 me.TD(me, 1, 2, makeXonoticSlider(1, 32, 1, "menu_maxplayers"));
  67         me.TR(me);
  68                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, "Number of bots:"));
  69                 me.TD(me, 1, 2, makeXonoticSlider(0, 9, 1, "bot_number"));
  70         me.TR(me);
  71                 me.TDempty(me, 0.2);
  72                 me.TD(me, 1, 0.8, e = makeXonoticTextLabel(0, "Bot skill:"));
  73                         setDependent(e, "bot_number", 0, -1);
  74                 me.TD(me, 1, 2, e = makeXonoticTextSlider("skill"));
  75                         e.addValue(e, "Botlike", "0");
  76                         e.addValue(e, "Beginner", "1");
  77                         e.addValue(e, "You will win", "2");
  78                         e.addValue(e, "You can win", "3");
  79                         e.addValue(e, "You might win", "4");
  80                         e.addValue(e, "Advanced", "5");
  81                         e.addValue(e, "Expert", "6");
  82                         e.addValue(e, "Pro", "7");
  83                         e.addValue(e, "Assassin", "8");
  84                         e.addValue(e, "Unhuman", "9");
  85                         e.addValue(e, "Godlike", "10");
  86                         e.configureXonoticTextSliderValues(e);
  87                         setDependent(e, "bot_number", 0, -1);
  88         me.TR(me);
  89         me.TR(me);
  90                 me.TDempty(me, 0.5);
  91                 me.TD(me, 1, 2, e = makeXonoticButton("Advanced settings...", '0 0 0'));
  92                         e.onClick = DialogOpenButton_Click;
  93                         e.onClickEntity = main.advancedDialog;
  94                         main.advancedDialog.refilterEntity = me.mapListBox;
  95                 me.TR(me);
  96                 me.TR(me);
  97                 me.TD(me, 1, 1, e = makeXonoticButton("Mutators...", '0 0 0'));
  98                         e.onClick = DialogOpenButton_Click;
  99                         e.onClickEntity = main.mutatorsDialog;
 100                         main.mutatorsDialog.refilterEntity = me.mapListBox;
 101                 me.TD(me, 1, 2, e0 = makeXonoticTextLabel(0, string_null));
 102                         e0.textEntity = main.mutatorsDialog;
 103                         e0.allowCut = 1;
 104
 105         me.gotoRC(me, 0, 3.5); me.setFirstColumn(me, me.currentColumn);
 106                 me.mapListBox = makeXonoticMapList();
 107                 me.TD(me, 1, 3, e = makeXonoticTextLabel(0, "Map list:"));
 108                         makeCallback(e, me.mapListBox, me.mapListBox.refilterCallback);
 109         me.TR(me);
 110                 me.TD(me, me.rows - 4, 3, me.mapListBox);
 111         me.gotoRC(me, me.rows - 3, 3.5);
 112                 me.TDempty(me, 0.25);
 113                 me.TD(me, 1, 1.125, e = makeXonoticButton("Select all", '0 0 0'));
 114                         e.onClick = MapList_All;
 115                         e.onClickEntity = me.mapListBox;
 116                 me.TD(me, 1, 1.125, e = makeXonoticButton("Select none", '0 0 0'));
 117                         e.onClick = MapList_None;
 118                         e.onClickEntity = me.mapListBox;
 119                 me.TDempty(me, 0.25);
 120
 121         me.gotoRC(me, me.rows - 1, 0);
 122                 me.TD(me, 1, me.columns, e = makeXonoticButton("Start Multiplayer!", '0 0 0'));
 123                         e.onClick = MapList_LoadMap;
 124                         e.onClickEntity = me.mapListBox;
 125                         me.mapListBox.startButton = e;
 126
 127         me.gameTypeChangeNotify(me);
 128 }
 129
 130 void GameType_ConfigureSliders(entity e, entity l, entity l2, string pLabel, float pMin, float pMax, float pStep, string pCvar)
 131 {
 132         if(pCvar == "")
 133         {
 134                 e.configureXonoticSlider(e, pMin, pMax, pStep, string_null);
 135                 l.setText(l, pLabel);
 136                 e.disabled = l.disabled = l2.disabled = TRUE;
 137         }
 138         else
 139         {
 140                 e.configureXonoticSlider(e, pMin, pMax, pStep, pCvar);
 141                 l.setText(l, pLabel);
 142                 e.disabled = l.disabled = l2.disabled = FALSE;
 143         }
 144 }
 145
 146 void XonoticServerCreateTab_gameTypeChangeNotify(entity me)
 147 {
 148         // tell the map list to update
 149         float gt;
 150         entity e, l, l2;
 151         gt = MapInfo_CurrentGametype();
 152         e = me.sliderFraglimit;
 153         l = me.checkboxFraglimit;
 154         l2 = me.checkboxFraglimitMapinfo;
 155         switch(gt)
 156         {
 157                 case MAPINFO_TYPE_CTF:        GameType_ConfigureSliders(e, l, l2, "Capture limit:",   1,   20, 1, "capturelimit_override");     break;
 158                 case MAPINFO_TYPE_DOMINATION: GameType_ConfigureSliders(e, l, l2, "Point limit:",    50,  500, 10, "g_domination_point_limit"); break;
 159                 case MAPINFO_TYPE_KEYHUNT:    GameType_ConfigureSliders(e, l, l2, "Point limit:",   200, 1500, 50, "g_keyhunt_point_limit");    break;
 160                 case MAPINFO_TYPE_RUNEMATCH:  GameType_ConfigureSliders(e, l, l2, "Point limit:",    50,  500, 10, "g_runematch_point_limit");  break;
 161                 case MAPINFO_TYPE_LMS:        GameType_ConfigureSliders(e, l, l2, "Lives:",           3,   50,  1, "g_lms_lives_override");     break;
 162                 case MAPINFO_TYPE_RACE:       GameType_ConfigureSliders(e, l, l2, "Laps:",            1,   25,  1, "g_race_laps_limit");        break;
 163                 case MAPINFO_TYPE_NEXBALL:    GameType_ConfigureSliders(e, l, l2, "Goals:",           1,   50,  1, "g_nexball_goallimit");      break;
 164                 case MAPINFO_TYPE_ASSAULT:    GameType_ConfigureSliders(e, l, l2, "Point limit:",    50,  500, 10, "");                         break;
 165                 case MAPINFO_TYPE_ONSLAUGHT:  GameType_ConfigureSliders(e, l, l2, "Point limit:",    50,  500, 10, "");                         break;
 166                 case MAPINFO_TYPE_CTS:        GameType_ConfigureSliders(e, l, l2, "Point limit:",    50,  500, 10, "");                         break;
 167                 default:                      GameType_ConfigureSliders(e, l, l2, "Frag limit:",      5,  100,  5, "fraglimit_override");       break;
 168         }
 169         me.mapListBox.refilter(me.mapListBox);
 170 }
 171
 172 #endif