qcsrc/menu/xonotic/cvarlist.qc

   1 #include "cvarlist.qh"
   2
   3 #include "inputbox.qh"
   4 #include "../item/container.qh"
   5
   6 entity makeXonoticCvarList()
   7 {
   8         entity me;
   9         me = NEW(XonoticCvarList);
  10         me.configureXonoticCvarList(me);
  11         return me;
  12 }
  13 void XonoticCvarList_configureXonoticCvarList(entity me)
  14 {
  15         me.configureXonoticListBox(me);
  16         me.handle = buf_create();
  17         me.nItems = 0;
  18 }
  19 void CvarList_Load(entity me, string filter)
  20 {
  21         if(me.handle < 0)
  22                 return;
  23
  24         buf_cvarlist(me.handle, filter, "_");
  25         me.nItems = buf_getsize(me.handle);
  26         if(autocvar_menu_cvarlist_onlymodified)
  27         {
  28                 float newbuf = buf_create();
  29                 for (int i = 0; i < me.nItems; ++i)
  30                 {
  31                         string k = bufstr_get(me.handle, i);
  32                         if(cvar_string(k) != cvar_defstring(k))
  33                                 bufstr_add(newbuf, k, false);
  34                 }
  35                 buf_del(me.handle);
  36                 me.handle = newbuf;
  37                 me.nItems = buf_getsize(me.handle);
  38         }
  39 }
  40 void XonoticCvarList_showNotify(entity me)
  41 {
  42         bool force_initial_selection = false;
  43         if(me.handle >= 0 && me.nItems <= 0) // me.handle not loaded yet?
  44                 force_initial_selection = true;
  45         CvarList_Load(me, me.controlledTextbox.text);
  46         if(force_initial_selection)
  47                 me.setSelected(me, 0);
  48 }
  49 void XonoticCvarList_destroy(entity me)
  50 {
  51         buf_del(me.handle);
  52 }
  53 string autocvar_menu_forced_saved_cvars;
  54 string autocvar_menu_reverted_nonsaved_cvars;
  55 float XonoticCvarList_updateCvarType(entity me)
  56 {
  57         float t;
  58         t = cvar_type(me.cvarName);
  59         me.cvarType = "";
  60         float needsForcing;
  61         if(strhasword(autocvar_menu_forced_saved_cvars, me.cvarName))
  62         {
  63                 me.cvarType = strcat(me.cvarType, ", ", _("forced to be saved to config.cfg"));
  64                 needsForcing = 0;
  65         }
  66         else if(strhasword(autocvar_menu_reverted_nonsaved_cvars, me.cvarName))
  67         {
  68                 // Currently claims to be saved, but won't be on next startup.
  69                 me.cvarType = strcat(me.cvarType, ", ", _("will not be saved"));
  70                 needsForcing = 1;
  71         }
  72         else if(t & CVAR_TYPEFLAG_SAVED)
  73         {
  74                 me.cvarType = strcat(me.cvarType, ", ", _("will be saved to config.cfg"));
  75                 needsForcing = 0;
  76         }
  77         else
  78         {
  79                 me.cvarType = strcat(me.cvarType, ", ", _("will not be saved"));
  80                 needsForcing = 1;
  81         }
  82         if(t & CVAR_TYPEFLAG_PRIVATE)
  83                 me.cvarType = strcat(me.cvarType, ", ", _("private"));
  84         if(t & CVAR_TYPEFLAG_ENGINE)
  85                 me.cvarType = strcat(me.cvarType, ", ", _("engine setting"));
  86         if(t & CVAR_TYPEFLAG_READONLY)
  87                 me.cvarType = strcat(me.cvarType, ", ", _("read only"));
  88         me.cvarType = strzone(substring(me.cvarType, 2, strlen(me.cvarType) - 2));
  89         me.cvarTypeBox.setText(me.cvarTypeBox, me.cvarType);
  90         return needsForcing;
  91 }
  92 void XonoticCvarList_setSelected(entity me, float i)
  93 {
  94         string s;
  95
  96         SUPER(XonoticCvarList).setSelected(me, i);
  97         if(me.nItems == 0)
  98                 return;
  99
 100         if(me.cvarName)
 101                 strunzone(me.cvarName);
 102         if(me.cvarDescription)
 103                 strunzone(me.cvarDescription);
 104         if(me.cvarType)
 105                 strunzone(me.cvarType);
 106         if(me.cvarDefault)
 107                 strunzone(me.cvarDefault);
 108         me.cvarName = strzone(bufstr_get(me.handle, me.selectedItem));
 109         me.cvarDescription = strzone(cvar_description(me.cvarName));
 110         me.cvarDefault = strzone(cvar_defstring(me.cvarName));
 111         me.cvarNameBox.setText(me.cvarNameBox, me.cvarName);
 112         me.cvarDescriptionBox.setText(me.cvarDescriptionBox, me.cvarDescription);
 113         float needsForcing = me.updateCvarType(me);
 114         me.cvarDefaultBox.setText(me.cvarDefaultBox, me.cvarDefault);
 115
 116         // this one can handle tempstrings
 117         s = cvar_string(me.cvarName);
 118         me.cvarNeedsForcing = 0;
 119         me.cvarValueBox.setText(me.cvarValueBox, s);
 120         me.cvarNeedsForcing = needsForcing;
 121         me.cvarValueBox.cursorPos = strlen(s);
 122 }
 123 void CvarList_Filter_Change(entity box, entity me)
 124 {
 125         CvarList_Load(me, box.text);
 126         me.setSelected(me, 0);
 127 }
 128 void CvarList_Filter_ModifiedCvars(entity box, entity me)
 129 {
 130         cvar_set("menu_cvarlist_onlymodified", ftos(!autocvar_menu_cvarlist_onlymodified));
 131         box.setChecked(box, autocvar_menu_cvarlist_onlymodified);
 132         CvarList_Load(me, me.controlledTextbox.text);
 133         me.setSelected(me, 0);
 134 }
 135 void XonoticCvarList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 136 {
 137         SUPER(XonoticCvarList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 138
 139         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
 140         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
 141         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 142
 143         me.columnNameOrigin = 0;
 144         me.columnValueSize = me.realFontSize.x * 20;
 145         me.columnNameSize = 1 - me.columnValueSize - me.realFontSize.x;
 146         me.columnValueOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x;
 147 }
 148 void XonoticCvarList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 149 {
 150         string k, v, d;
 151         float t;
 152
 153         vector theColor;
 154         float theAlpha;
 155
 156         string s;
 157
 158         if(isSelected)
 159                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 160         else if(isFocused)
 161         {
 162                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 163                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 164         }
 165
 166         k = bufstr_get(me.handle, i);
 167
 168         v = cvar_string(k);
 169         d = cvar_defstring(k);
 170         t = cvar_type(k);
 171         if(strhasword(autocvar_menu_forced_saved_cvars, k))
 172                 theAlpha = SKINALPHA_CVARLIST_SAVED;
 173         else if(strhasword(autocvar_menu_reverted_nonsaved_cvars, k))
 174                 theAlpha = SKINALPHA_CVARLIST_TEMPORARY;
 175         else if(t & CVAR_TYPEFLAG_SAVED)
 176                 theAlpha = SKINALPHA_CVARLIST_SAVED;
 177         else
 178                 theAlpha = SKINALPHA_CVARLIST_TEMPORARY;
 179         if(v == d)
 180                 theColor = SKINCOLOR_CVARLIST_UNCHANGED;
 181         else
 182                 theColor = SKINCOLOR_CVARLIST_CHANGED;
 183
 184         s = draw_TextShortenToWidth(k, me.columnNameSize, 0, me.realFontSize);
 185         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
 186         s = draw_TextShortenToWidth(v, me.columnValueSize, 0, me.realFontSize);
 187         draw_Text(me.realUpperMargin * eY + me.columnValueOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
 188 }
 189
 190 float XonoticCvarList_keyDown(entity me, float scan, float ascii, float shift)
 191 {
 192         if (scan == K_MOUSE3 || ((shift & S_CTRL) && scan == K_SPACE))
 193         {
 194                 CvarList_Revert_Click(NULL, me);
 195                 return 1;
 196         }
 197         else if(scan == K_ENTER)
 198         {
 199                 me.cvarValueBox.parent.setFocus(me.cvarValueBox.parent, me.cvarValueBox);
 200                 return 1;
 201         }
 202         else if(SUPER(XonoticCvarList).keyDown(me, scan, ascii, shift))
 203                 return 1;
 204         else if(!me.controlledTextbox)
 205                 return 0;
 206         else
 207                 return me.controlledTextbox.keyDown(me.controlledTextbox, scan, ascii, shift);
 208 }
 209
 210 float XonoticCvarList_mouseRelease(entity me, vector pos)
 211 {
 212         if(me.pressed == 2)
 213                 me.cvarValueBox.parent.setFocus(me.cvarValueBox.parent, me.cvarValueBox);
 214         return SUPER(XonoticCvarList).mouseRelease(me, pos);
 215 }
 216
 217 void CvarList_Value_Change(entity box, entity me)
 218 {
 219         cvar_set(me.cvarNameBox.text, box.text);
 220         if(me.cvarNeedsForcing)
 221         {
 222                 localcmd(sprintf("\nseta %1$s \"$%1$s\"\n", me.cvarName));
 223                 cvar_set("menu_reverted_nonsaved_cvars", substring(strreplace(strcat(" ", me.cvarName, " "), " ", strcat(" ", autocvar_menu_reverted_nonsaved_cvars, " ")), 1, -2));
 224                 if (autocvar_menu_forced_saved_cvars == "")
 225                         cvar_set("menu_forced_saved_cvars", me.cvarName);
 226                 else
 227                         cvar_set("menu_forced_saved_cvars", strcat(autocvar_menu_forced_saved_cvars, " ", me.cvarName));
 228                 me.cvarNeedsForcing = 0;
 229                 me.updateCvarType(me);
 230         }
 231 }
 232
 233 void CvarList_Revert_Click(entity btn, entity me)
 234 {
 235         me.cvarValueBox.setText(me.cvarValueBox, me.cvarDefault);
 236         me.cvarValueBox.cursorPos = strlen(me.cvarDefault);
 237         if(strhasword(autocvar_menu_forced_saved_cvars, me.cvarName))
 238         {
 239                 cvar_set("menu_forced_saved_cvars", substring(strreplace(strcat(" ", me.cvarName, " "), " ", strcat(" ", autocvar_menu_forced_saved_cvars, " ")), 1, -2));
 240                 if (autocvar_menu_reverted_nonsaved_cvars == "")
 241                         cvar_set("menu_reverted_nonsaved_cvars", me.cvarName);
 242                 else
 243                         cvar_set("menu_reverted_nonsaved_cvars", strcat(autocvar_menu_reverted_nonsaved_cvars, " ", me.cvarName));
 244         }
 245         me.cvarNeedsForcing = me.updateCvarType(me);
 246 }
 247
 248 void CvarList_End_Editing(entity box, entity me)
 249 {
 250         box.parent.setFocus(box.parent, me);
 251 }