qcsrc/menu/xonotic/campaign.qc

   1 #include "campaign.qh"
   2
   3 #include <common/campaign_common.qh>
   4 #include "inputbox.qh"
   5
   6 string campaign_longdesc_wrapped[CAMPAIGN_MAX_ENTRIES];
   7
   8 void rewrapCampaign(float w, float l0, float emptyheight, vector theFontSize)
   9 {
  10         int i, j;
  11         int n;
  12         float l;
  13         string r, s;
  14         for (i = 0; i < campaign_entries; ++i) {
  15                 l = l0;
  16                 if (campaign_longdesc_wrapped[i]) {
  17                         strunzone(campaign_longdesc_wrapped[i]);
  18                 }
  19                 n = tokenizebyseparator(campaign_longdesc[i], "\n");
  20                 r = "";
  21                 for (j = 0; j < n; ++j) {
  22                         s = argv(j);
  23                         if (s == "") {
  24                                 l -= emptyheight;
  25                                 r = strcat(r, "\n");
  26                                 continue;
  27                         }
  28
  29                         getWrappedLine_remaining = s;
  30                         while (getWrappedLine_remaining) {
  31                                 s = getWrappedLine(w, theFontSize, draw_TextWidth_WithoutColors);
  32                                 if (--l < 0) { goto toolong; }
  33                                 r = strcat(r, s, "\n");
  34                         }
  35                 }
  36                 goto nottoolong;
  37                 LABEL(toolong)
  38                 while (substring(r, strlen(r) - 1, 1) == "\n") {
  39                         r = substring(r, 0, strlen(r) - 1);
  40                 }
  41                 r = strcat(r, "...\n");
  42                 LABEL(nottoolong)
  43                 campaign_longdesc_wrapped[i] = strzone(substring(r, 0, strlen(r) - 1));
  44         }
  45 }
  46
  47 entity makeXonoticCampaignList()
  48 {
  49         entity me;
  50         me = NEW(XonoticCampaignList);
  51         me.configureXonoticCampaignList(me);
  52         return me;
  53 }
  54 void XonoticCampaignList_configureXonoticCampaignList(entity me)
  55 {
  56         me.configureXonoticListBox(me);
  57         me.campaignGlob = search_begin("maps/campaign*.txt", true, true);
  58         me.loadCvars(me);
  59         me.campaignGo(me, 0); // takes care of enabling/disabling buttons too
  60 }
  61
  62 void XonoticCampaignList_destroy(entity me)
  63 {
  64         if (me.campaignGlob >= 0) {
  65                 search_end(me.campaignGlob);
  66         }
  67 }
  68
  69 void XonoticCampaignList_loadCvars(entity me)
  70 {
  71         // read campaign cvars
  72         if (campaign_name) {
  73                 strunzone(campaign_name);
  74         }
  75         if (me.cvarName) {
  76                 strunzone(me.cvarName);
  77         }
  78         campaign_name = strzone(cvar_string("g_campaign_name"));
  79         me.cvarName = strzone(strcat("g_campaign", campaign_name, "_index"));
  80         registercvar(me.cvarName, "", 0); // saved by server QC anyway
  81         CampaignFile_Unload();
  82         CampaignFile_Load(0, CAMPAIGN_MAX_ENTRIES);
  83         me.campaignIndex = bound(0, cvar(me.cvarName), campaign_entries);
  84         cvar_set(me.cvarName, ftos(me.campaignIndex));
  85         if (me.columnNameSize) {
  86                 rewrapCampaign(me.columnNameSize, me.rowsPerItem - 3, me.emptyLineHeight, me.realFontSize);
  87         }
  88         me.nItems = min(me.campaignIndex + 2, campaign_entries);
  89         me.setSelected(me, min(me.campaignIndex, me.nItems - 1));
  90         if (me.nItems - 1 > me.campaignIndex) {
  91                 me.scrollToItem(me, me.nItems - 1);
  92         }
  93         if (me.labelTitle) {
  94                 me.labelTitle.setText(me.labelTitle, campaign_title);
  95         }
  96 }
  97
  98 void XonoticCampaignList_saveCvars(entity me)
  99 {
 100         // write campaign cvars
 101         // no reason to do this!
 102         // cvar_set("g_campaign_name", campaign_name);
 103         // cvar_set(me.cvarName, ftos(me.campaignIndex)); // NOTE: only server QC does that!
 104 }
 105
 106 void XonoticCampaignList_campaignGo(entity me, float step)
 107 {
 108         float canNext, canPrev;
 109         string s;
 110         float i, j, n;
 111
 112         canNext = canPrev = 0;
 113
 114         if (me.campaignGlob >= 0) {
 115                 n = search_getsize(me.campaignGlob);
 116                 if (n > 0) {
 117                         j = -1;
 118                         s = strcat("maps/campaign", campaign_name, ".txt");
 119                         for (i = 0; i < n; ++i) {
 120                                 if (search_getfilename(me.campaignGlob, i) == s) {
 121                                         j = i;
 122                                 }
 123                         }
 124                         if (j < 0) {
 125                                 s = strcat("maps/campaign", cvar_defstring("g_campaign_name"), ".txt");
 126                                 for (i = 0; i < n; ++i) {
 127                                         if (search_getfilename(me.campaignGlob, i) == s) {
 128                                                 j = i;
 129                                         }
 130                                 }
 131                         }
 132                         if (j < 0) {
 133                                 if (step >= 0) {
 134                                         j = 0;
 135                                 } else {
 136                                         j = n - 1;
 137                                 }
 138                         } else {
 139                                 j = mod(j + step, n);
 140                         }
 141                         s = search_getfilename(me.campaignGlob, j);
 142                         s = substring(s, 13, strlen(s) - 17);
 143                         cvar_set("g_campaign_name", s);
 144                         me.loadCvars(me);
 145                         canNext = (j != n - 1);
 146                         canPrev = (j != 0);
 147                 }
 148         }
 149
 150         if (me.buttonNext) {
 151                 me.buttonNext.disabled = !canNext;
 152         }
 153         if (me.buttonPrev) {
 154                 me.buttonPrev.disabled = !canPrev;
 155         }
 156 }
 157
 158 void MultiCampaign_Next(entity btn, entity me)
 159 {
 160         me.campaignGo(me, +1);
 161 }
 162 void MultiCampaign_Prev(entity btn, entity me)
 163 {
 164         me.campaignGo(me, -1);
 165 }
 166
 167 void XonoticCampaignList_draw(entity me)
 168 {
 169         if (cvar(me.cvarName) != me.campaignIndex || cvar_string("g_campaign_name") != campaign_name) {
 170                 me.loadCvars(me);
 171         }
 172         SUPER(XonoticCampaignList).draw(me);
 173 }
 174
 175 void XonoticCampaignList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 176 {
 177         me.itemAbsSize = '0 0 0';
 178         SUPER(XonoticCampaignList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 179
 180         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 181         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 182         me.realUpperMargin1 = 0.5 * me.realFontSize.y;
 183         me.realUpperMargin2 = me.realUpperMargin1 + 2 * me.realFontSize.y;
 184
 185         me.checkMarkSize = (eX * (me.itemAbsSize.y / me.itemAbsSize.x) + eY) * 0.5;
 186
 187         me.columnPreviewOrigin = 0;
 188         me.columnPreviewSize = me.itemAbsSize.y / me.itemAbsSize.x * 4 / 3;
 189         me.columnCheckMarkSize = me.checkMarkSize.x;
 190         me.columnNameSize = 1 - me.columnPreviewSize - me.columnCheckMarkSize - 4 * me.realFontSize.x;
 191         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize.x;
 192         me.columnCheckMarkOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x * 2;
 193
 194         me.checkMarkOrigin = eY + eX * (me.columnCheckMarkOrigin + me.columnCheckMarkSize) - me.checkMarkSize;
 195
 196         rewrapCampaign(me.columnNameSize, me.rowsPerItem - 3, me.emptyLineHeight, me.realFontSize);
 197 }
 198 void XonoticCampaignList_doubleClickListBoxItem(entity me, float i, vector where)
 199 {
 200         CampaignList_LoadMap(me, me);
 201 }
 202 void XonoticCampaignList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 203 {
 204         string s;
 205         vector theColor;
 206         float theAlpha;
 207         float j, n;
 208         vector o;
 209
 210         if (i < me.campaignIndex) {
 211                 theAlpha = SKINALPHA_CAMPAIGN_SELECTABLE;
 212                 theColor = SKINCOLOR_CAMPAIGN_SELECTABLE;
 213         } else if (i == me.campaignIndex) {
 214                 theAlpha = SKINALPHA_CAMPAIGN_CURRENT;
 215                 theColor = SKINCOLOR_CAMPAIGN_CURRENT;
 216         } else {
 217                 theAlpha = SKINALPHA_CAMPAIGN_FUTURE;
 218                 theColor = SKINCOLOR_CAMPAIGN_FUTURE;
 219         }
 220
 221         if (isSelected) {
 222                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 223         } else if (isFocused) {
 224                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 225                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 226         }
 227
 228         if (draw_PictureSize(strcat("/maps/", campaign_mapname[i])) == '0 0 0') {
 229                 draw_Picture(me.columnPreviewOrigin * eX, "nopreview_map", me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 230         } else {
 231                 draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", campaign_mapname[i]), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 232         }
 233
 234         if (i < me.campaignIndex) {
 235                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 236         }
 237         if (i <= me.campaignIndex) {
 238                 s = campaign_shortdesc[i]; // fteqcc sucks
 239         } else {
 240                 s = "???";
 241         }
 242         s = draw_TextShortenToWidth(sprintf(_("Level %d: %s"), i + 1, s), me.columnNameSize, 0, me.realFontSize);
 243         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, theColor, theAlpha, 0);
 244
 245         if (i <= me.campaignIndex) {
 246                 s = campaign_longdesc_wrapped[i];
 247                 n = tokenizebyseparator(s, "\n");
 248                 o = me.realUpperMargin2 * eY + me.columnNameOrigin * eX;
 249                 for (j = 0; j < n; ++j) {
 250                         if (argv(j) != "") {
 251                                 draw_Text(o, argv(j), me.realFontSize, theColor, theAlpha * SKINALPHA_CAMPAIGN_DESCRIPTION, 0);
 252                                 o.y += me.realFontSize.y;
 253                         } else {
 254                                 o.y += me.realFontSize.y * me.emptyLineHeight;
 255                         }
 256                 }
 257         }
 258 }
 259 void CampaignList_LoadMap(entity btn, entity me)
 260 {
 261         if (me.selectedItem >= me.nItems || me.selectedItem < 0) {
 262                 return;
 263         }
 264         CampaignSetup(me.selectedItem);
 265 }
 266
 267 void XonoticCampaignList_setSelected(entity me, float i)
 268 {
 269         // prevent too late items from being played
 270         SUPER(XonoticCampaignList).setSelected(me, min(i, me.campaignIndex));
 271 }
 272
 273 float XonoticCampaignList_keyDown(entity me, float scan, float ascii, float shift)
 274 {
 275         if (scan == K_ENTER || scan == K_SPACE || scan == K_KP_ENTER) {
 276                 CampaignList_LoadMap(me, me);
 277         } else {
 278                 return SUPER(XonoticCampaignList).keyDown(me, scan, ascii, shift);
 279         }
 280         return 1;
 281 }