qcsrc/menu/menu.qc

   1 ///////////////////////////////////////////////
   2 // Menu Source File
   3 ///////////////////////
   4 // This file belongs to dpmod/darkplaces
   5 // AK contains all menu functions (especially the required ones)
   6 ///////////////////////////////////////////////
   7
   8 float mouseButtonsPressed;
   9 vector menuMousePos;
  10 float menuShiftState;
  11 float menuPrevTime;
  12 float menuAlpha;
  13 float menuLogoAlpha;
  14 float prevMenuAlpha;
  15 float menuInitialized;
  16 float menuNotTheFirstFrame;
  17 float menuMouseMode;
  18
  19 void SUB_Null() { }
  20
  21 void m_sync()
  22 {
  23         updateCompression();
  24         updateConwidths();
  25
  26         loadAllCvars(main);
  27 }
  28
  29 void m_init()
  30 {
  31         cvar_set("_menu_alpha", "0");
  32         prvm_language = strzone(cvar_string("prvm_language"));
  33
  34         check_unacceptable_compiler_bugs();
  35
  36 #ifdef WATERMARK
  37         print(sprintf(_("^4MQC Build information: ^1%s\n"), WATERMARK()));
  38 #endif
  39
  40         // list all game dirs (TEST)
  41         if(cvar("developer"))
  42         {
  43                 float i;
  44                 string s;
  45                 for(i = 0; ; ++i)
  46                 {
  47                         s = getgamedirinfo(i, GETGAMEDIRINFO_NAME);
  48                         if not(s)
  49                                 break;
  50                         dprint(s, ": ", getgamedirinfo(i, GETGAMEDIRINFO_DESCRIPTION));
  51                 }
  52         }
  53 }
  54
  55 float MENU_ASPECT = 1.25; // 1280x1024
  56 float MENU_MINHEIGHT = 600;
  57 float conwidth_s, conheight_s, realconwidth, realconheight, screenconwidth, screenconheight;
  58 void draw_reset_cropped()
  59 {
  60         draw_reset(screenconwidth, screenconheight, 0.5 * (realconwidth - screenconwidth), 0.5 * (realconheight - screenconheight));
  61 }
  62 void draw_reset_full()
  63 {
  64         draw_reset(realconwidth, realconheight, 0, 0);
  65 }
  66 void UpdateConWidthHeight()
  67 {
  68         conwidth_s = conwidth;
  69         conheight_s = conheight;
  70         realconwidth = cvar("vid_conwidth");
  71         realconheight = cvar("vid_conheight");
  72         if(realconwidth / realconheight > MENU_ASPECT)
  73         {
  74                 // widescreen
  75                 conwidth = realconheight * MENU_ASPECT;
  76                 conheight = realconheight;
  77         }
  78         else
  79         {
  80                 // squarescreen
  81                 conwidth = realconwidth;
  82                 conheight = realconwidth / MENU_ASPECT;
  83         }
  84         screenconwidth = conwidth;
  85         screenconheight = conheight;
  86         if(conwidth < MENU_MINHEIGHT * MENU_ASPECT)
  87         {
  88                 conheight *= MENU_MINHEIGHT * MENU_ASPECT / conwidth;
  89                 conwidth = MENU_MINHEIGHT * MENU_ASPECT;
  90         }
  91         if(conheight < MENU_MINHEIGHT)
  92         {
  93                 conwidth *= MENU_MINHEIGHT / conheight;
  94                 conheight = MENU_MINHEIGHT;
  95         }
  96         if(main)
  97         {
  98                 if(conwidth_s != conwidth || conheight_s != conheight)
  99                 {
 100                         draw_reset_cropped();
 101                         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
 102                 }
 103         }
 104 }
 105
 106 void m_init_delayed()
 107 {
 108         float fh, glob, n, i;
 109         string s;
 110
 111         conwidth = conheight = -1;
 112         UpdateConWidthHeight();
 113         draw_reset_cropped();
 114
 115         menuInitialized = 0;
 116         if(!preMenuInit())
 117                 return;
 118         menuInitialized = 1;
 119
 120         RegisterWeapons();
 121
 122         fh = -1;
 123         if(cvar_string("menu_skin") != "")
 124         {
 125                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
 126                 fh = fopen(language_filename(strcat(draw_currentSkin, "/skinvalues.txt")), FILE_READ);
 127         }
 128         if(fh < 0)
 129         if(cvar_defstring("menu_skin") != "")
 130         {
 131                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
 132                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
 133                 fh = fopen(language_filename(strcat(draw_currentSkin, "/skinvalues.txt")), FILE_READ);
 134         }
 135         if(fh < 0)
 136         {
 137                 draw_currentSkin = "gfx/menu/default";
 138                 fh = fopen(language_filename(strcat(draw_currentSkin, "/skinvalues.txt")), FILE_READ);
 139         }
 140         if(fh < 0)
 141         {
 142                 error("cannot load any menu skin\n");
 143         }
 144         draw_currentSkin = strzone(draw_currentSkin);
 145         while((s = fgets(fh)))
 146         {
 147                 // these two are handled by skinlist.qc
 148                 if(substring(s, 0, 6) == "title ")
 149                         continue;
 150                 if(substring(s, 0, 7) == "author ")
 151                         continue;
 152                 n = tokenize_console(s);
 153                 if(n >= 2)
 154                         Skin_ApplySetting(argv(0), substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 155         }
 156         fclose(fh);
 157
 158         glob = search_begin(strcat(draw_currentSkin, "/*.tga"), TRUE, TRUE);
 159         if(glob >= 0)
 160         {
 161                 n = search_getsize(glob);
 162                 for(i = 0; i < n; ++i)
 163                         precache_pic(search_getfilename(glob, i));
 164                 search_end(glob);
 165         }
 166
 167         draw_setMousePointer(SKINGFX_CURSOR, SKINSIZE_CURSOR, SKINOFFSET_CURSOR);
 168
 169         loadTooltips();
 170         anim = spawnAnimHost();
 171         main = spawnMainWindow(); main.configureMainWindow(main);
 172         unloadTooltips();
 173
 174         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
 175         main.focused = 1;
 176         menuShiftState = 0;
 177         menuMousePos = '0.5 0.5 0';
 178
 179         m_sync();
 180
 181         if(Menu_Active)
 182                 m_display(); // delayed menu display
 183 }
 184
 185 void m_keyup (float key, float ascii)
 186 {
 187         if(!menuInitialized)
 188                 return;
 189         if(!Menu_Active)
 190                 return;
 191         draw_reset_cropped();
 192         main.keyUp(main, key, ascii, menuShiftState);
 193         if(key >= K_MOUSE1 && key <= K_MOUSE3)
 194         {
 195                 --mouseButtonsPressed;
 196                 if(!mouseButtonsPressed)
 197                         main.mouseRelease(main, menuMousePos);
 198                 if(mouseButtonsPressed < 0)
 199                 {
 200                         mouseButtonsPressed = 0;
 201                         dprint("Warning: released an already released button\n");
 202                 }
 203         }
 204         if(key == K_ALT) menuShiftState -= (menuShiftState & S_ALT);
 205         if(key == K_CTRL) menuShiftState -= (menuShiftState & S_CTRL);
 206         if(key == K_SHIFT) menuShiftState -= (menuShiftState & S_SHIFT);
 207 }
 208
 209 void m_keydown(float key, float ascii)
 210 {
 211         if(!menuInitialized)
 212                 return;
 213         if(!Menu_Active)
 214                 return;
 215         if(keyGrabber)
 216         {
 217                 entity e;
 218                 e = keyGrabber;
 219                 keyGrabber = NULL;
 220                 e.keyGrabbed(e, key, ascii);
 221         }
 222         else
 223         {
 224                 draw_reset_cropped();
 225                 if(key >= K_MOUSE1 && key <= K_MOUSE3)
 226                         if(!mouseButtonsPressed)
 227                                 main.mousePress(main, menuMousePos);
 228                 if(!main.keyDown(main, key, ascii, menuShiftState))
 229                         if(key == K_ESCAPE)
 230                                 if(gamestatus & (GAME_ISSERVER | GAME_CONNECTED)) // don't back out to console only
 231                                         m_hide(); // disable menu on unhandled ESC
 232         }
 233         if(key >= K_MOUSE1 && key <= K_MOUSE3)
 234         {
 235                 ++mouseButtonsPressed;
 236                 if(mouseButtonsPressed > 10)
 237                 {
 238                         mouseButtonsPressed = 10;
 239                         dprint("Warning: pressed an already pressed button\n");
 240                 }
 241         }
 242         if(key == K_ALT) menuShiftState |= S_ALT;
 243         if(key == K_CTRL) menuShiftState |= S_CTRL;
 244         if(key == K_SHIFT) menuShiftState |= S_SHIFT;
 245 }
 246
 247 float SCALEMODE_CROP = 0;
 248 float SCALEMODE_LETTERBOX = 1;
 249 float SCALEMODE_WIDTH = 2;
 250 float SCALEMODE_HEIGHT = 3;
 251 float SCALEMODE_STRETCH = 4;
 252 void draw_Picture_Aligned(vector algn, float scalemode, string img, float a)
 253 {
 254         vector sz, org, isz, isz_w, isz_h;
 255         float width_is_larger;
 256
 257         sz = draw_PictureSize(img);
 258         width_is_larger = (sz_x * draw_scale_y >= sz_y * draw_scale_x);
 259         isz_w = '1 0 0' + '0 1 0' * ((sz_y / sz_x) * (draw_scale_x / draw_scale_y));
 260         isz_h = '0 1 0' + '1 0 0' * ((sz_x / sz_y) * (draw_scale_y / draw_scale_x));
 261
 262         switch(scalemode)
 263         {
 264                 default:
 265                 case SCALEMODE_CROP:
 266                         isz = (width_is_larger ? isz_h : isz_w);
 267                         break;
 268                 case SCALEMODE_LETTERBOX:
 269                         isz = (width_is_larger ? isz_w : isz_h);
 270                         break;
 271                 case SCALEMODE_WIDTH:
 272                         isz = isz_w;
 273                         break;
 274                 case SCALEMODE_HEIGHT:
 275                         isz = isz_h;
 276                         break;
 277                 case SCALEMODE_STRETCH:
 278                         isz = '1 1 0';
 279                         break;
 280         }
 281
 282         org = eX * (algn_x * (1 - isz_x)) + eY * (algn_y * (1 - isz_y));
 283         draw_Picture(org, img, isz, '1 1 1', a);
 284 }
 285
 286 void drawBackground(string img, float a, string algn, float force1)
 287 {
 288         if(main.mainNexposee.ModalController_state == 0)
 289                 return;
 290
 291         vector v;
 292         float i, l;
 293         string c;
 294         float scalemode;
 295
 296         v_z = 0;
 297
 298         scalemode = SCALEMODE_CROP;
 299
 300         for(i = 0; i < strlen(algn); ++i)
 301         {
 302                 c = substring(algn, i, 1);
 303                 switch(c)
 304                 {
 305                         case "c": scalemode = SCALEMODE_CROP; goto nopic;
 306                         case "l": scalemode = SCALEMODE_LETTERBOX; goto nopic;
 307                         case "h": scalemode = SCALEMODE_HEIGHT; goto nopic;
 308                         case "w": scalemode = SCALEMODE_WIDTH; goto nopic;
 309                         case "s": scalemode = SCALEMODE_STRETCH; goto nopic;
 310                         case "1": case "4": case "7": v_x = 0.0; break;
 311                         case "2": case "5": case "8": v_x = 0.5; break;
 312                         case "3": case "6": case "9": v_x = 1.0; break;
 313                         default: v_x = random(); break;
 314                 }
 315                 switch(c)
 316                 {
 317                         case "7": case "8": case "9": v_y = 0.0; break;
 318                         case "4": case "5": case "6": v_y = 0.5; break;
 319                         case "1": case "2": case "3": v_y = 1.0; break;
 320                         default: v_y = random(); break;
 321                 }
 322                 if(l == 0)
 323                         draw_Picture_Aligned(v, scalemode, img, a);
 324                 else if(force1)
 325                         // force all secondary layers to use alpha 1. Prevents ugly issues
 326                         // with overlap. It's a flag because it cannot be used for the
 327                         // ingame background
 328                         draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l+1)), 1);
 329                 else
 330                         draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l+1)), a);
 331                 ++l;
 332 :nopic
 333         }
 334 }
 335
 336 float menu_tooltips;
 337 float menu_tooltips_old;
 338 vector menuTooltipAveragedMousePos;
 339 entity menuTooltipItem;
 340 vector menuTooltipOrigin;
 341 vector menuTooltipSize;
 342 float menuTooltipAlpha;
 343 string menuTooltipText;
 344 float menuTooltipState; // 0: static, 1: fading in, 2: fading out
 345 float m_testmousetooltipbox(vector pos)
 346 {
 347         if(pos_x >= menuTooltipOrigin_x && pos_x < menuTooltipOrigin_x + menuTooltipSize_x)
 348         if(pos_y >= menuTooltipOrigin_y && pos_y < menuTooltipOrigin_y + menuTooltipSize_y)
 349                 return FALSE;
 350         return TRUE;
 351 }
 352 float m_testtooltipbox(vector tooltippos)
 353 {
 354         if(tooltippos_x < 0)
 355                 return FALSE;
 356         if(tooltippos_y < 0)
 357                 return FALSE;
 358         if(tooltippos_x + menuTooltipSize_x > 1)
 359                 return FALSE;
 360         if(tooltippos_y + menuTooltipSize_y > 1)
 361                 return FALSE;
 362         menuTooltipOrigin = tooltippos;
 363         return TRUE;
 364 }
 365 float m_allocatetooltipbox(vector pos)
 366 {
 367         vector avoidplus, avoidminus;
 368         vector v;
 369
 370         avoidplus_x = (SKINAVOID_TOOLTIP_x + SKINSIZE_CURSOR_x - SKINOFFSET_CURSOR_x * SKINSIZE_CURSOR_x) / conwidth;
 371         avoidplus_y = (SKINAVOID_TOOLTIP_y + SKINSIZE_CURSOR_y - SKINOFFSET_CURSOR_y * SKINSIZE_CURSOR_y) / conheight;
 372         avoidplus_z = 0;
 373
 374         avoidminus_x = (SKINAVOID_TOOLTIP_x + SKINOFFSET_CURSOR_x * SKINSIZE_CURSOR_x) / conwidth + menuTooltipSize_x;
 375         avoidminus_y = (SKINAVOID_TOOLTIP_y + SKINOFFSET_CURSOR_y * SKINSIZE_CURSOR_y) / conheight + menuTooltipSize_y;
 376         avoidminus_z = 0;
 377
 378         // bottom right
 379         v = pos + avoidplus;
 380         if(m_testtooltipbox(v))
 381                 return TRUE;
 382
 383         // bottom center
 384         v_x = pos_x - menuTooltipSize_x * 0.5;
 385         if(m_testtooltipbox(v))
 386                 return TRUE;
 387
 388         // bottom left
 389         v_x = pos_x - avoidminus_x;
 390         if(m_testtooltipbox(v))
 391                 return TRUE;
 392
 393         // top left
 394         v_y = pos_y - avoidminus_y;
 395         if(m_testtooltipbox(v))
 396                 return TRUE;
 397
 398         // top center
 399         v_x = pos_x - menuTooltipSize_x * 0.5;
 400         if(m_testtooltipbox(v))
 401                 return TRUE;
 402
 403         // top right
 404         v_x = pos_x + avoidplus_x;
 405         if(m_testtooltipbox(v))
 406                 return TRUE;
 407
 408         return FALSE;
 409 }
 410 entity m_findtooltipitem(entity root, vector pos)
 411 {
 412         entity it;
 413         entity best;
 414
 415         best = world;
 416         it = root;
 417
 418         while(it.instanceOfContainer)
 419         {
 420                 while(it.instanceOfNexposee && it.focusedChild)
 421                 {
 422                         it = it.focusedChild;
 423                         pos = globalToBox(pos, it.Container_origin, it.Container_size);
 424                 }
 425                 if(it.instanceOfNexposee)
 426                 {
 427                         it = it.itemFromPoint(it, pos);
 428                         if(it.tooltip)
 429                                 best = it;
 430                         else if(menu_tooltips == 2 && (it.cvarName || it.onClickCommand))
 431                                 best = it;
 432                         it = world;
 433                 }
 434                 else if(it.instanceOfModalController)
 435                         it = it.focusedChild;
 436                 else
 437                         it = it.itemFromPoint(it, pos);
 438                 if(!it)
 439                         break;
 440                 if(it.tooltip)
 441                         best = it;
 442                 else if(menu_tooltips == 2 && (it.cvarName || it.onClickCommand))
 443                         best = it;
 444                 pos = globalToBox(pos, it.Container_origin, it.Container_size);
 445         }
 446
 447         return best;
 448 }
 449 string gettooltip()
 450 {
 451         if (menu_tooltips == 2)
 452         {
 453                 string s;
 454                 if (menuTooltipItem.cvarName)
 455                 {
 456                         if (getCvarsMulti(menuTooltipItem))
 457                                 s = strcat("[", menuTooltipItem.cvarName, " ", getCvarsMulti(menuTooltipItem), "]");
 458                         else
 459                                 s = strcat("[", menuTooltipItem.cvarName, "]");
 460                 }
 461                 else if (menuTooltipItem.onClickCommand)
 462                         s = strcat("<", menuTooltipItem.onClickCommand, ">");
 463                 else
 464                         return menuTooltipItem.tooltip;
 465                 if (menuTooltipItem.tooltip)
 466                         return strcat(menuTooltipItem.tooltip, " ", s);
 467                 return s;
 468         }
 469         return menuTooltipItem.tooltip;
 470 }
 471 void m_tooltip(vector pos)
 472 {
 473         float f, i, w;
 474         entity it;
 475         vector fontsize, p;
 476         string s;
 477
 478         menu_tooltips = cvar("menu_tooltips");
 479         if (!menu_tooltips)
 480         {
 481                 // don't return immediately, fade out the active tooltip first
 482                 if (menuTooltipItem == world)
 483                         return;
 484                 it = world;
 485                 menu_tooltips_old = menu_tooltips;
 486         }
 487         else
 488         {
 489                 f = bound(0, frametime * 2, 1);
 490                 menuTooltipAveragedMousePos = menuTooltipAveragedMousePos * (1 - f) + pos * f;
 491                 f = vlen(pos - menuTooltipAveragedMousePos);
 492                 if(f < 0.01)
 493                         it = m_findtooltipitem(main, pos);
 494                 else
 495                         it = world;
 496         }
 497         fontsize = '1 0 0' * (SKINFONTSIZE_TOOLTIP / conwidth) + '0 1 0' * (SKINFONTSIZE_TOOLTIP / conheight);
 498
 499         // float menuTooltipState; // 0: static, 1: fading in, 2: fading out
 500         if(it != menuTooltipItem)
 501         {
 502                 switch(menuTooltipState)
 503                 {
 504                         case 0:
 505                                 if(menuTooltipItem)
 506                                 {
 507                                         // another item: fade out first
 508                                         menuTooltipState = 2;
 509                                 }
 510                                 else
 511                                 {
 512                                         // new item: fade in
 513                                         menuTooltipState = 1;
 514                                         menuTooltipItem = it;
 515
 516                                         menuTooltipOrigin_x = -1; // unallocated
 517
 518                                         if (menuTooltipText)
 519                                                 strunzone(menuTooltipText);
 520                                         menuTooltipText = strzone(gettooltip());
 521
 522                                         i = 0;
 523                                         w = 0;
 524                                         getWrappedLine_remaining = menuTooltipText;
 525                                         while(getWrappedLine_remaining)
 526                                         {
 527                                                 s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
 528                                                 ++i;
 529                                                 f = draw_TextWidth(s, FALSE, fontsize);
 530                                                 if(f > w)
 531                                                         w = f;
 532                                         }
 533                                         menuTooltipSize_x = w + 2 * (SKINMARGIN_TOOLTIP_x / conwidth);
 534                                         menuTooltipSize_y = i * fontsize_y + 2 * (SKINMARGIN_TOOLTIP_y / conheight);
 535                                         menuTooltipSize_z = 0;
 536                                 }
 537                                 break;
 538                         case 1:
 539                                 // changing item while fading in: fade out first
 540                                 menuTooltipState = 2;
 541                                 break;
 542                         case 2:
 543                                 // changing item while fading out: can't
 544                                 break;
 545                 }
 546         }
 547         else if(menuTooltipState == 2) // re-fade in?
 548                 menuTooltipState = 1;
 549
 550         if(menuTooltipItem)
 551                 if(!m_testmousetooltipbox(pos))
 552                         menuTooltipState = 2; // fade out if mouse touches it
 553
 554         switch(menuTooltipState)
 555         {
 556                 case 1:
 557                         menuTooltipAlpha = bound(0, menuTooltipAlpha + 5 * frametime, 1);
 558                         if(menuTooltipAlpha == 1)
 559                                 menuTooltipState = 0;
 560                         break;
 561                 case 2:
 562                         menuTooltipAlpha = bound(0, menuTooltipAlpha - 2 * frametime, 1);
 563                         if(menuTooltipAlpha == 0)
 564                         {
 565                                 menuTooltipState = 0;
 566                                 menuTooltipItem = world;
 567                         }
 568                         break;
 569         }
 570
 571         if(menuTooltipItem == world)
 572         {
 573                 if (menuTooltipText)
 574                 {
 575                         strunzone(menuTooltipText);
 576                         menuTooltipText = string_null;
 577                 }
 578                 return;
 579         }
 580         else
 581         {
 582                 if(menu_tooltips != menu_tooltips_old)
 583                 {
 584                         if (menu_tooltips != 0 && menu_tooltips_old != 0)
 585                                 menuTooltipItem = world; // reload tooltip next frame
 586                         menu_tooltips_old = menu_tooltips;
 587                 }
 588                 else if(menuTooltipOrigin_x < 0) // unallocated?
 589                         m_allocatetooltipbox(pos);
 590
 591                 if(menuTooltipOrigin_x >= 0)
 592                 {
 593                         // draw the tooltip!
 594                         p = SKINBORDER_TOOLTIP;
 595                         p_x *= 1 / conwidth;
 596                         p_y *= 1 / conheight;
 597                         draw_BorderPicture(menuTooltipOrigin, SKINGFX_TOOLTIP, menuTooltipSize, '1 1 1', menuTooltipAlpha, p);
 598                         p = menuTooltipOrigin;
 599                         p_x += SKINMARGIN_TOOLTIP_x / conwidth;
 600                         p_y += SKINMARGIN_TOOLTIP_y / conheight;
 601                         getWrappedLine_remaining = menuTooltipText;
 602                         while(getWrappedLine_remaining)
 603                         {
 604                                 s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
 605                                 draw_Text(p, s, fontsize, '1 1 1', SKINALPHA_TOOLTIP * menuTooltipAlpha, FALSE);
 606                                 p_y += fontsize_y;
 607                         }
 608                 }
 609         }
 610 }
 611
 612 void m_draw()
 613 {
 614         float t;
 615         float realFrametime;
 616
 617         menuMouseMode = cvar("menu_mouse_absolute");
 618
 619         if (anim)
 620                 anim.tickAll(anim);
 621
 622         if(main)
 623                 UpdateConWidthHeight();
 624
 625         if(!menuInitialized)
 626         {
 627                 // TODO draw an info image about this situation
 628                 m_init_delayed();
 629                 return;
 630         }
 631         if(!menuNotTheFirstFrame)
 632         {
 633                 menuNotTheFirstFrame = 1;
 634                 if(Menu_Active)
 635                 if(!cvar("menu_video_played"))
 636                 {
 637                         localcmd("cd loop $menu_cdtrack; play sound/announcer/default/welcome.ogg\n");
 638                         menuLogoAlpha = -0.8; // no idea why, but when I start this at zero, it jumps instead of fading FIXME
 639                 }
 640                 // ALWAYS set this cvar; if we start but menu is not active, this means we want no background music!
 641                 localcmd("set menu_video_played 1\n");
 642         }
 643
 644         t = gettime();
 645         realFrametime = frametime = min(0.2, t - menuPrevTime);
 646         menuPrevTime = t;
 647         time += frametime;
 648
 649         t = cvar("menu_slowmo");
 650         if(t)
 651         {
 652                 frametime *= t;
 653                 realFrametime *= t;
 654         }
 655         else
 656                 t = 1;
 657
 658         if(Menu_Active)
 659         {
 660                 if(getmousetarget() == (menuMouseMode ? MT_CLIENT : MT_MENU) && (getkeydest() == KEY_MENU || getkeydest() == KEY_MENU_GRABBED))
 661                         setkeydest(keyGrabber ? KEY_MENU_GRABBED : KEY_MENU);
 662                 else
 663                         m_hide();
 664         }
 665
 666         if(cvar("cl_capturevideo"))
 667                 frametime = t / cvar("cl_capturevideo_fps"); // make capturevideo work smoothly
 668
 669         gamestatus = 0;
 670         if(isserver())
 671                 gamestatus = gamestatus | GAME_ISSERVER;
 672         if(clientstate() == CS_CONNECTED)
 673                 gamestatus = gamestatus | GAME_CONNECTED;
 674         if(cvar("developer"))
 675                 gamestatus = gamestatus | GAME_DEVELOPER;
 676
 677         prevMenuAlpha = menuAlpha;
 678         if(Menu_Active)
 679         {
 680                 if(menuAlpha == 0 && menuLogoAlpha < 2)
 681                 {
 682                         menuLogoAlpha = menuLogoAlpha + frametime * 2;
 683                 }
 684                 else
 685                 {
 686                         menuAlpha = min(1, menuAlpha + frametime * 5);
 687                         menuLogoAlpha = 2;
 688                 }
 689         }
 690         else
 691         {
 692                 menuAlpha = max(0, menuAlpha - frametime * 5);
 693                 menuLogoAlpha = 2;
 694         }
 695
 696         draw_reset_cropped();
 697
 698         if(!(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
 699         {
 700                 if(menuLogoAlpha > 0)
 701                 {
 702                         draw_reset_full();
 703                         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_BACKGROUND, 1);
 704                         drawBackground(SKINGFX_BACKGROUND, bound(0, menuLogoAlpha, 1), SKINALIGN_BACKGROUND, TRUE);
 705                         draw_reset_cropped();
 706                         if(menuAlpha <= 0 && SKINALPHA_CURSOR_INTRO > 0)
 707                         {
 708                                 draw_alpha = SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1);
 709                                 draw_drawMousePointer(menuMousePos);
 710                                 draw_alpha = 1;
 711                         }
 712                 }
 713         }
 714         else if(SKINALPHA_BACKGROUND_INGAME)
 715         {
 716                 if(menuAlpha > 0)
 717                 {
 718                         draw_reset_full();
 719                         drawBackground(SKINGFX_BACKGROUND_INGAME, menuAlpha * SKINALPHA_BACKGROUND_INGAME, SKINALIGN_BACKGROUND_INGAME, FALSE);
 720                         draw_reset_cropped();
 721                 }
 722         }
 723
 724         if(menuAlpha != prevMenuAlpha)
 725                 cvar_set("_menu_alpha", ftos(menuAlpha));
 726
 727         draw_reset_cropped();
 728         preMenuDraw();
 729         draw_reset_cropped();
 730
 731         if(menuAlpha <= 0)
 732         {
 733                 if(prevMenuAlpha > 0)
 734                         main.initializeDialog(main, main.firstChild);
 735                 draw_reset_cropped();
 736                 postMenuDraw();
 737                 return;
 738         }
 739
 740         draw_alpha *= menuAlpha;
 741
 742         if(menuMouseMode)
 743         {
 744                 vector newMouse;
 745                 newMouse = globalToBox(getmousepos(), draw_shift, draw_scale);
 746                 if(newMouse != '0 0 0')
 747                         if(newMouse != menuMousePos)
 748                         {
 749                                 menuMousePos = newMouse;
 750                                 if(mouseButtonsPressed)
 751                                         main.mouseDrag(main, menuMousePos);
 752                                 else
 753                                         main.mouseMove(main, menuMousePos);
 754                         }
 755         }
 756         else
 757         {
 758                 if(frametime > 0)
 759                 {
 760                         vector dMouse, minpos, maxpos;
 761                         dMouse = getmousepos() * (frametime / realFrametime); // for capturevideo
 762                         if(dMouse != '0 0 0')
 763                         {
 764                                 minpos = globalToBox('0 0 0', draw_shift, draw_scale);
 765                                 maxpos = globalToBox(eX * (realconwidth - 1) + eY * (realconheight - 1), draw_shift, draw_scale);
 766                                 dMouse = globalToBoxSize(dMouse, draw_scale);
 767                                 menuMousePos += dMouse * cvar("menu_mouse_speed");
 768                                 menuMousePos_x = bound(minpos_x, menuMousePos_x, maxpos_x);
 769                                 menuMousePos_y = bound(minpos_y, menuMousePos_y, maxpos_y);
 770                                 if(mouseButtonsPressed)
 771                                         main.mouseDrag(main, menuMousePos);
 772                                 else
 773                                         main.mouseMove(main, menuMousePos);
 774                         }
 775                 }
 776         }
 777         main.draw(main);
 778
 779         m_tooltip(menuMousePos);
 780
 781         draw_alpha = max(draw_alpha, SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1));
 782
 783         draw_drawMousePointer(menuMousePos);
 784
 785         draw_reset_cropped();
 786         postMenuDraw();
 787
 788         frametime = 0;
 789 }
 790
 791 void m_display()
 792 {
 793         Menu_Active = true;
 794         setkeydest(KEY_MENU);
 795         setmousetarget((menuMouseMode ? MT_CLIENT : MT_MENU));
 796
 797         if(!menuInitialized)
 798                 return;
 799
 800         if(mouseButtonsPressed)
 801                 main.mouseRelease(main, menuMousePos);
 802         mouseButtonsPressed = 0;
 803
 804         main.focusEnter(main);
 805         main.showNotify(main);
 806 }
 807
 808 void m_hide()
 809 {
 810         Menu_Active = false;
 811         setkeydest(KEY_GAME);
 812         setmousetarget(MT_CLIENT);
 813
 814         if(!menuInitialized)
 815                 return;
 816
 817         main.focusLeave(main);
 818         main.hideNotify(main);
 819 }
 820
 821 void m_toggle(float mode)
 822 {
 823         if(Menu_Active)
 824         {
 825                 if (mode == 1)
 826                         return;
 827                 m_hide();
 828         }
 829         else
 830         {
 831                 if (mode == 0)
 832                         return;
 833                 m_display();
 834         }
 835 }
 836
 837 void Shutdown()
 838 {
 839         entity e;
 840
 841         m_hide();
 842         for(e = NULL; (e = nextent(e)) != NULL; )
 843         {
 844                 if(e.classname != "vtbl")
 845                         if(e.destroy)
 846                                 e.destroy(e);
 847         }
 848 }
 849
 850 void m_focus_item_chain(entity outermost, entity innermost)
 851 {
 852         if(innermost.parent != outermost)
 853                 m_focus_item_chain(outermost, innermost.parent);
 854         innermost.parent.setFocus(innermost.parent, innermost);
 855 }
 856
 857 void m_activate_window(entity wnd)
 858 {
 859         entity par;
 860         par = wnd.parent;
 861         if(par)
 862                 m_activate_window(par);
 863
 864         if(par.instanceOfModalController)
 865         {
 866                 if(wnd.tabSelectingButton)
 867                         // tabs
 868                         TabButton_Click(wnd.tabSelectingButton, wnd);
 869                 else
 870                         // root
 871                         par.initializeDialog(par, wnd);
 872         }
 873         else if(par.instanceOfNexposee)
 874         {
 875                 // nexposee (sorry for violating abstraction here)
 876                 par.selectedChild = wnd;
 877                 par.animationState = 1;
 878                 Container_setFocus(par, NULL);
 879         }
 880         else if(par.instanceOfContainer)
 881         {
 882                 // other containers
 883                 if(par.focused)
 884                         par.setFocus(par, wnd);
 885         }
 886 }
 887
 888 void m_setpointerfocus(entity wnd)
 889 {
 890         if(wnd.instanceOfContainer)
 891         {
 892                 entity focus = wnd.preferredFocusedGrandChild(wnd);
 893                 if(focus)
 894                 {
 895                         menuMousePos = focus.origin + 0.5 * focus.size;
 896                         menuMousePos_x *= 1 / conwidth;
 897                         menuMousePos_y *= 1 / conheight;
 898                         if(wnd.focused) // why does this never happen?
 899                                 m_focus_item_chain(wnd, focus);
 900                 }
 901         }
 902 }
 903
 904 void m_goto(string itemname)
 905 {
 906         entity e;
 907         if(!menuInitialized)
 908                 return;
 909         if(itemname == "") // this can be called by GameCommand
 910         {
 911                 if(gamestatus & (GAME_ISSERVER | GAME_CONNECTED))
 912                         m_hide();
 913                 else
 914                 {
 915                         m_activate_window(main.mainNexposee);
 916                         m_display();
 917                 }
 918         }
 919         else
 920         {
 921                 for(e = NULL; (e = find(e, name, itemname)); )
 922                         if(e.classname != "vtbl")
 923                                 break;
 924                 if(e)
 925                 {
 926                         m_hide();
 927                         m_activate_window(e);
 928                         m_setpointerfocus(e);
 929                         m_display();
 930                 }
 931         }
 932 }
 933
 934 void m_goto_skin_selector()
 935 {
 936         if(!menuInitialized)
 937                 return;
 938         // TODO add code to switch back to the skin selector (no idea how to do it now)
 939         m_goto("skinselector");
 940 }
 941
 942 void m_goto_language_selector()
 943 {
 944         if(!menuInitialized)
 945                 return;
 946         // TODO add code to switch back to the language selector (no idea how to do it now)
 947         m_goto("languageselector");
 948 }
 949
 950 void m_goto_video_settings()
 951 {
 952         if(!menuInitialized)
 953                 return;
 954         // TODO add code to switch back to the video settings (no idea how to do it now)
 955         m_goto("videosettings");
 956 }