qcsrc/menu/menu.qc

   1 #include "menu.qh"
   2
   3 #include "item.qh"
   4
   5 #include "anim/animhost.qh"
   6
   7 #include "item/dialog.qh"
   8 #include "item/listbox.qh"
   9 #include "item/nexposee.qh"
  10
  11 #include "xonotic/commandbutton.qh"
  12 #include "xonotic/mainwindow.qh"
  13 #include "xonotic/serverlist.qh"
  14 #include "xonotic/slider_resolution.qh"
  15
  16 .string cvarName;
  17
  18 #include "xonotic/util.qh"
  19
  20 #include "../common/items/all.qh"
  21 #include <common/weapons/all.qh>
  22 #include "../common/mapinfo.qh"
  23 #include "../common/mutators/base.qh"
  24
  25 int mouseButtonsPressed;
  26 vector menuMousePos;
  27 int menuShiftState;
  28 float menuPrevTime;
  29 float menuAlpha;
  30 float menuLogoAlpha;
  31 float prevMenuAlpha;
  32 bool menuInitialized;
  33 bool menuNotTheFirstFrame;
  34 int menuMouseMode;
  35
  36 float conwidth_s, conheight_s;
  37 float vidwidth_s, vidheight_s, vidpixelheight_s;
  38 float realconwidth, realconheight;
  39
  40 void m_sync()
  41 {
  42         updateCompression();
  43         vidwidth_s = vidheight_s = vidpixelheight_s = 0;  // Force updateConwidths on next draw
  44
  45         loadAllCvars(main);
  46 }
  47
  48 void m_gamestatus()
  49 {
  50         gamestatus = 0;
  51         if (isserver()) gamestatus |= GAME_ISSERVER;
  52         if (clientstate() == CS_CONNECTED || isdemo()) gamestatus |= GAME_CONNECTED;
  53         if (cvar("developer")) gamestatus |= GAME_DEVELOPER;
  54 }
  55
  56 void m_init()
  57 {
  58         bool restarting = false;
  59         cvar_set("_menu_alpha", "0");
  60         prvm_language = cvar_string("prvm_language");
  61         if (prvm_language == "")
  62         {
  63                 prvm_language = "en";
  64                 cvar_set("prvm_language", prvm_language);
  65                 localcmd("\nmenu_restart\n");
  66                 restarting = true;
  67         }
  68         prvm_language = strzone(prvm_language);
  69         cvar_set("_menu_prvm_language", prvm_language);
  70
  71 #ifdef WATERMARK
  72                 LOG_INFOF("^4MQC Build information: ^1%s\n", WATERMARK);
  73 #endif
  74
  75         // list all game dirs (TEST)
  76         if (cvar("developer"))
  77         {
  78                 for (int i = 0; ; ++i)
  79                 {
  80                         string s = getgamedirinfo(i, GETGAMEDIRINFO_NAME);
  81                         if (!s) break;
  82                         LOG_TRACE(s, ": ", getgamedirinfo(i, GETGAMEDIRINFO_DESCRIPTION));
  83                 }
  84         }
  85
  86         // needs to be done so early because of the constants they create
  87         static_init();
  88         static_init_late();
  89         static_init_precache();
  90
  91         RegisterSLCategories();
  92
  93         float ddsload = cvar("r_texture_dds_load");
  94         float texcomp = cvar("gl_texturecompression");
  95         updateCompression();
  96         if (ddsload != cvar("r_texture_dds_load") || texcomp != cvar("gl_texturecompression")) localcmd("\nr_restart\n");
  97
  98         if (!restarting)
  99         {
 100                 if (cvar("_menu_initialized"))  // always show menu after menu_restart
 101                         m_display();
 102                 else m_hide();
 103                 cvar_set("_menu_initialized", "1");
 104         }
 105 }
 106
 107 const float MENU_ASPECT = 1280 / 1024;
 108
 109 void draw_reset_cropped()
 110 {
 111         draw_reset(conwidth, conheight, 0.5 * (realconwidth - conwidth), 0.5 * (realconheight - conheight));
 112 }
 113 void draw_reset_full()
 114 {
 115         draw_reset(realconwidth, realconheight, 0, 0);
 116 }
 117
 118 void UpdateConWidthHeight(float w, float h, float p)
 119 {
 120         if (w != vidwidth_s || h != vidheight_s || p != vidpixelheight_s)
 121         {
 122                 if (updateConwidths(w, h, p)) localcmd(sprintf("\nexec %s\n", cvar_string("menu_font_cfg")));
 123                 vidwidth_s = w;
 124                 vidheight_s = h;
 125                 vidpixelheight_s = p;
 126         }
 127         conwidth_s = conwidth;
 128         conheight_s = conheight;
 129         realconwidth = cvar("vid_conwidth");
 130         realconheight = cvar("vid_conheight");
 131         if (realconwidth / realconheight > MENU_ASPECT)
 132         {
 133                 // widescreen
 134                 conwidth = realconheight * MENU_ASPECT;
 135                 conheight = realconheight;
 136         }
 137         else
 138         {
 139                 // squarescreen
 140                 conwidth = realconwidth;
 141                 conheight = realconwidth / MENU_ASPECT;
 142         }
 143         if (main)
 144         {
 145                 if (conwidth_s != conwidth || conheight_s != conheight)
 146                 {
 147                         draw_reset_cropped();
 148                         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
 149                 }
 150         }
 151         else
 152         {
 153                 vidwidth_s = vidheight_s = vidpixelheight_s = 0;  // retry next frame
 154         }
 155 }
 156
 157 string m_goto_buffer;
 158 void m_init_delayed()
 159 {
 160         draw_reset_cropped();
 161
 162         menuInitialized = false;
 163         if (!preMenuInit()) return;
 164         menuInitialized = true;
 165
 166         int fh = -1;
 167         if (cvar_string("menu_skin") != "")
 168         {
 169                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
 170                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
 171         }
 172         if (fh < 0 && cvar_defstring("menu_skin") != "")
 173         {
 174                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
 175                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
 176                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
 177         }
 178         if (fh < 0)
 179         {
 180                 draw_currentSkin = "gfx/menu/default";
 181                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
 182         }
 183         if (fh < 0) error("cannot load any menu skin\n");
 184         draw_currentSkin = strzone(draw_currentSkin);
 185         for (string s; (s = fgets(fh)); )
 186         {
 187                 // these two are handled by skinlist.qc
 188                 if (substring(s, 0, 6) == "title ") continue;
 189                 if (substring(s, 0, 7) == "author ") continue;
 190                 int n = tokenize_console(s);
 191                 if (n < 2) continue;
 192                 Skin_ApplySetting(argv(0), substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 193         }
 194         fclose(fh);
 195
 196         int glob = search_begin(strcat(draw_currentSkin, "/*.tga"), true, true);
 197         if (glob >= 0)
 198         {
 199                 for (int i = 0, n = search_getsize(glob); i < n; ++i)
 200                         precache_pic(search_getfilename(glob, i));
 201                 search_end(glob);
 202         }
 203
 204         draw_setMousePointer(SKINGFX_CURSOR, SKINSIZE_CURSOR, SKINOFFSET_CURSOR);
 205
 206         anim = NEW(AnimHost);
 207         main = NEW(MainWindow);
 208         main.configureMainWindow(main);
 209
 210         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
 211         main.focused = true;
 212         menuShiftState = 0;
 213         menuMousePos = '0.5 0.5 0';
 214
 215         m_sync();
 216
 217         if (m_goto_buffer)
 218         {
 219                 m_goto(m_goto_buffer);
 220                 strunzone(m_goto_buffer);
 221                 m_goto_buffer = string_null;
 222         }
 223
 224         if (Menu_Active) m_display();  // delayed menu display
 225 }
 226
 227 void m_keyup(float key, float ascii)
 228 {
 229         if (!menuInitialized) return;
 230         if (!Menu_Active) return;
 231         draw_reset_cropped();
 232         main.keyUp(main, key, ascii, menuShiftState);
 233         if (key >= K_MOUSE1 && key <= K_MOUSE3)
 234         {
 235                 --mouseButtonsPressed;
 236                 if (!mouseButtonsPressed) main.mouseRelease(main, menuMousePos);
 237                 if (mouseButtonsPressed < 0)
 238                 {
 239                         mouseButtonsPressed = 0;
 240                         LOG_TRACE("Warning: released an already released button\n");
 241                 }
 242         }
 243         if (key == K_ALT) menuShiftState &= ~S_ALT;
 244         if (key == K_CTRL) menuShiftState &= ~S_CTRL;
 245         if (key == K_SHIFT) menuShiftState &= ~S_SHIFT;
 246 }
 247
 248 void m_keydown(float key, float ascii)
 249 {
 250         if (!menuInitialized) return;
 251         if (!Menu_Active) return;
 252
 253         if (menuMouseMode && key >= K_MOUSE1 && key <= K_MOUSE3)
 254         {
 255                 // detect a click outside of the game window
 256                 vector p = getmousepos();
 257                 if (p.x < 0 || p.x > realconwidth || p.y < 0 || p.y > realconheight)
 258                 {
 259                         ++mouseButtonsPressed;
 260                         return;
 261                 }
 262         }
 263
 264         if (keyGrabber)
 265         {
 266                 entity e = keyGrabber;
 267                 keyGrabber = NULL;
 268                 e.keyGrabbed(e, key, ascii);
 269         }
 270         else
 271         {
 272                 draw_reset_cropped();
 273                 if (!mouseButtonsPressed && key >= K_MOUSE1 && key <= K_MOUSE3)
 274                         main.mousePress(main, menuMousePos);
 275                 if (!main.keyDown(main, key, ascii, menuShiftState))
 276                 {
 277                         // disable menu on unhandled ESC
 278                         if (key == K_ESCAPE)
 279                                 if (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))  // don't back out to console only
 280                                         m_hide();
 281                 }
 282         }
 283         if (key >= K_MOUSE1 && key <= K_MOUSE3)
 284         {
 285                 ++mouseButtonsPressed;
 286                 if (mouseButtonsPressed > 10)
 287                 {
 288                         mouseButtonsPressed = 10;
 289                         LOG_TRACE("Warning: pressed an already pressed button\n");
 290                 }
 291         }
 292         if (key == K_ALT) menuShiftState |= S_ALT;
 293         if (key == K_CTRL) menuShiftState |= S_CTRL;
 294         if (key == K_SHIFT) menuShiftState |= S_SHIFT;
 295 }
 296
 297 enum {
 298         SCALEMODE_CROP,
 299         SCALEMODE_LETTERBOX,
 300         SCALEMODE_WIDTH,
 301         SCALEMODE_HEIGHT,
 302         SCALEMODE_STRETCH,
 303 };
 304 void draw_Picture_Aligned(vector algn, float scalemode, string img, float a)
 305 {
 306         vector sz = draw_PictureSize(img);
 307         bool width_is_larger = (sz.x * draw_scale.y >= sz.y * draw_scale.x);
 308         vector isz_w = '1 0 0' + '0 1 0' * ((sz.y / sz.x) * (draw_scale.x / draw_scale.y));
 309         vector isz_h = '0 1 0' + '1 0 0' * ((sz.x / sz.y) * (draw_scale.y / draw_scale.x));
 310         vector isz;
 311         switch (scalemode)
 312         {
 313                 default:
 314                 case SCALEMODE_CROP:
 315                         isz = (width_is_larger ? isz_h : isz_w);
 316                         break;
 317                 case SCALEMODE_LETTERBOX:
 318                         isz = (width_is_larger ? isz_w : isz_h);
 319                         break;
 320                 case SCALEMODE_WIDTH:
 321                         isz = isz_w;
 322                         break;
 323                 case SCALEMODE_HEIGHT:
 324                         isz = isz_h;
 325                         break;
 326                 case SCALEMODE_STRETCH:
 327                         isz = '1 1 0';
 328                         break;
 329         }
 330         vector org = eX * (algn.x * (1 - isz.x)) + eY * (algn.y * (1 - isz.y));
 331         draw_Picture(org, img, isz, '1 1 1', a);
 332 }
 333
 334 void drawBackground(string img, float a, string algn, float force1)
 335 {
 336         if (main.mainNexposee.ModalController_state == 0) return;
 337         vector v = '0 0 0';
 338         int scalemode = SCALEMODE_CROP;
 339         for (int i = 0, l = 0; i < strlen(algn); ++i)
 340         {
 341                 string c = substring(algn, i, 1);
 342                 switch (c)
 343                 {
 344                         case "c":
 345                                 scalemode = SCALEMODE_CROP;
 346                                 goto nopic;
 347                         case "l":
 348                                 scalemode = SCALEMODE_LETTERBOX;
 349                                 goto nopic;
 350                         case "h":
 351                                 scalemode = SCALEMODE_HEIGHT;
 352                                 goto nopic;
 353                         case "w":
 354                                 scalemode = SCALEMODE_WIDTH;
 355                                 goto nopic;
 356                         case "s":
 357                                 scalemode = SCALEMODE_STRETCH;
 358                                 goto nopic;
 359                         case "1": case "4": case "7":
 360                                 v.x = 0.0;
 361                                 break;
 362                         case "2": case "5": case "8":
 363                                 v.x = 0.5;
 364                                 break;
 365                         case "3": case "6": case "9":
 366                                 v.x = 1.0;
 367                                 break;
 368                         default:
 369                                 v.x = random();
 370                                 break;
 371                 }
 372                 switch (c)
 373                 {
 374                         case "7": case "8": case "9":
 375                                 v.y = 0.0;
 376                                 break;
 377                         case "4": case "5": case "6":
 378                                 v.y = 0.5;
 379                                 break;
 380                         case "1": case "2": case "3":
 381                                 v.y = 1.0;
 382                                 break;
 383                         default:
 384                                 v.y = random();
 385                                 break;
 386                 }
 387                 if (l == 0)
 388                 {
 389                         draw_Picture_Aligned(v, scalemode, img, a);
 390                 }
 391                 else if (force1)
 392                 {
 393                         // force all secondary layers to use alpha 1. Prevents ugly issues
 394                         // with overlap. It's a flag because it cannot be used for the
 395                         // ingame background
 396                         draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l + 1)), 1);
 397                 }
 398                 else
 399                 {
 400                         draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l + 1)), a);
 401                 }
 402                 ++l;
 403 LABEL(nopic)
 404         }
 405 }
 406
 407 int menu_tooltips;
 408 int menu_tooltips_old;
 409 vector menuTooltipAveragedMousePos;
 410 entity menuTooltipItem;
 411 vector menuTooltipOrigin;
 412 vector menuTooltipSize;
 413 float menuTooltipAlpha;
 414 string menuTooltipText;
 415 int menuTooltipState;  // 0: static, 1: fading in, 2: fading out, 3: forced fading out
 416 bool m_testmousetooltipbox(vector pos)
 417 {
 418         return !(
 419             (pos.x >= menuTooltipOrigin.x && pos.x < menuTooltipOrigin.x + menuTooltipSize.x)
 420             && (pos.y >= menuTooltipOrigin.y && pos.y < menuTooltipOrigin.y + menuTooltipSize.y)
 421                 );
 422 }
 423 bool m_testtooltipbox(vector tooltippos)
 424 {
 425         if (tooltippos.x < 0) return false;
 426         if (tooltippos.y < 0) return false;
 427         if (tooltippos.x + menuTooltipSize.x > 1) return false;
 428         if (tooltippos.y + menuTooltipSize.y > 1) return false;
 429         menuTooltipOrigin = tooltippos;
 430         return true;
 431 }
 432 bool m_allocatetooltipbox(vector pos)
 433 {
 434         vector avoidplus;
 435         avoidplus.x = (SKINAVOID_TOOLTIP_x + SKINSIZE_CURSOR_x - SKINOFFSET_CURSOR_x * SKINSIZE_CURSOR_x) / conwidth;
 436         avoidplus.y = (SKINAVOID_TOOLTIP_y + SKINSIZE_CURSOR_y - SKINOFFSET_CURSOR_y * SKINSIZE_CURSOR_y) / conheight;
 437         avoidplus.z = 0;
 438
 439         vector avoidminus;
 440         avoidminus.x = (SKINAVOID_TOOLTIP_x + SKINOFFSET_CURSOR_x * SKINSIZE_CURSOR_x) / conwidth + menuTooltipSize.x;
 441         avoidminus.y = (SKINAVOID_TOOLTIP_y + SKINOFFSET_CURSOR_y * SKINSIZE_CURSOR_y) / conheight + menuTooltipSize.y;
 442         avoidminus.z = 0;
 443
 444         // bottom right
 445         vector v = pos + avoidplus;
 446         if (m_testtooltipbox(v)) return true;
 447
 448         // bottom center
 449         v.x = pos.x - menuTooltipSize.x * 0.5;
 450         if (m_testtooltipbox(v)) return true;
 451
 452         // bottom left
 453         v.x = pos.x - avoidminus.x;
 454         if (m_testtooltipbox(v)) return true;
 455
 456         // top left
 457         v.y = pos.y - avoidminus.y;
 458         if (m_testtooltipbox(v)) return true;
 459
 460         // top center
 461         v.x = pos.x - menuTooltipSize.x * 0.5;
 462         if (m_testtooltipbox(v)) return true;
 463
 464         // top right
 465         v.x = pos.x + avoidplus.x;
 466         if (m_testtooltipbox(v)) return true;
 467
 468         return false;
 469 }
 470 entity m_findtooltipitem(entity root, vector pos)
 471 {
 472         entity best = NULL;
 473         for (entity it = root; it.instanceOfContainer; )
 474         {
 475                 while (it.instanceOfNexposee && it.focusedChild)
 476                 {
 477                         it = it.focusedChild;
 478                         pos = globalToBox(pos, it.Container_origin, it.Container_size);
 479                 }
 480                 if (it.instanceOfNexposee)
 481                 {
 482                         it = it.itemFromPoint(it, pos);
 483                         if (it.tooltip) best = it;
 484                         else if (menu_tooltips == 2 && (it.cvarName || it.onClickCommand)) best = it;
 485                         it = NULL;
 486                 }
 487                 else if (it.instanceOfModalController)
 488                 {
 489                         it = it.focusedChild;
 490                 }
 491                 else
 492                 {
 493                         it = it.itemFromPoint(it, pos);
 494                 }
 495                 if (!it) break;
 496                 if (it.tooltip) best = it;
 497                 else if (menu_tooltips == 2 && (it.cvarName || it.onClickCommand)) best = it;
 498                 pos = globalToBox(pos, it.Container_origin, it.Container_size);
 499         }
 500
 501         return best;
 502 }
 503 string gettooltip()
 504 {
 505         if (menu_tooltips == 2)
 506         {
 507                 string s;
 508                 if (menuTooltipItem.cvarName)
 509                 {
 510                         if (getCvarsMulti(menuTooltipItem)) s =
 511                                     strcat("[", menuTooltipItem.cvarName, " ", getCvarsMulti(menuTooltipItem), "]");
 512                         else s = strcat("[", menuTooltipItem.cvarName, "]");
 513                 }
 514                 else if (menuTooltipItem.onClickCommand)
 515                 {
 516                         s = strcat("<", menuTooltipItem.onClickCommand, ">");
 517                 }
 518                 else
 519                 {
 520                         return menuTooltipItem.tooltip;
 521                 }
 522                 if (menuTooltipItem.tooltip) return strcat(menuTooltipItem.tooltip, " ", s);
 523                 return s;
 524         }
 525         return menuTooltipItem.tooltip;
 526 }
 527 void m_tooltip(vector pos)
 528 {
 529         static string prev_tooltip;
 530         entity it;
 531         menu_tooltips = cvar("menu_tooltips");
 532         if (!menu_tooltips)
 533         {
 534                 // don't return immediately, fade out the active tooltip first
 535                 if (menuTooltipItem == NULL) return;
 536                 it = NULL;
 537                 menu_tooltips_old = menu_tooltips;
 538         }
 539         else
 540         {
 541                 float f = bound(0, frametime * 2, 1);
 542                 menuTooltipAveragedMousePos = menuTooltipAveragedMousePos * (1 - f) + pos * f;
 543                 if (vdist(pos - menuTooltipAveragedMousePos, <, 0.01))
 544                 {
 545                         it = m_findtooltipitem(main, pos);
 546
 547                         if (it.instanceOfListBox && it.isScrolling(it)) it = NULL;
 548
 549                         if (it && prev_tooltip != it.tooltip)
 550                         {
 551                                 // fade out if tooltip of a certain item has changed
 552                                 menuTooltipState = 3;
 553                                 if (prev_tooltip) strunzone(prev_tooltip);
 554                                 prev_tooltip = strzone(it.tooltip);
 555                         }
 556                         else if (menuTooltipItem && !m_testmousetooltipbox(pos))
 557                         {
 558                                 menuTooltipState = 3;  // fade out if mouse touches it
 559                         }
 560                 }
 561                 else
 562                 {
 563                         it = NULL;
 564                 }
 565         }
 566         vector fontsize = '1 0 0' * (SKINFONTSIZE_TOOLTIP / conwidth) + '0 1 0' * (SKINFONTSIZE_TOOLTIP / conheight);
 567
 568         // float menuTooltipState; // 0: static, 1: fading in, 2: fading out, 3: forced fading out
 569         if (it != menuTooltipItem)
 570         {
 571                 switch (menuTooltipState)
 572                 {
 573                         case 0:
 574                                 if (menuTooltipItem)
 575                                 {
 576                                         // another item: fade out first
 577                                         menuTooltipState = 2;
 578                                 }
 579                                 else
 580                                 {
 581                                         // new item: fade in
 582                                         menuTooltipState = 1;
 583                                         menuTooltipItem = it;
 584
 585                                         menuTooltipOrigin.x = -1;  // unallocated
 586
 587                                         if (menuTooltipText) strunzone(menuTooltipText);
 588                                         menuTooltipText = strzone(gettooltip());
 589
 590                                         int i = 0;
 591                                         float w = 0;
 592                                         for (getWrappedLine_remaining = menuTooltipText; getWrappedLine_remaining && i <= 16; ++i)
 593                                         {
 594                                                 string s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
 595                                                 if (i == 16)
 596                                                         s = "...";
 597                                                 float f = draw_TextWidth(s, false, fontsize);
 598                                                 if (f > w) w = f;
 599                                         }
 600                                         menuTooltipSize.x = w + 2 * (SKINMARGIN_TOOLTIP_x / conwidth);
 601                                         menuTooltipSize.y = i * fontsize.y + 2 * (SKINMARGIN_TOOLTIP_y / conheight);
 602                                         menuTooltipSize.z = 0;
 603                                 }
 604                                 break;
 605                         case 1:
 606                                 // changing item while fading in: fade out first
 607                                 menuTooltipState = 2;
 608                                 break;
 609                         case 2:
 610                                 // changing item while fading out: can't
 611                                 break;
 612                 }
 613         }
 614         else if (menuTooltipState == 2)  // re-fade in?
 615         {
 616                 menuTooltipState = 1;
 617         }
 618
 619         switch (menuTooltipState)
 620         {
 621                 case 1:  // fade in
 622                         menuTooltipAlpha = bound(0, menuTooltipAlpha + 5 * frametime, 1);
 623                         if (menuTooltipAlpha == 1) menuTooltipState = 0;
 624                         break;
 625                 case 2:  // fade out
 626                 case 3:  // forced fade out
 627                         menuTooltipAlpha = bound(0, menuTooltipAlpha - 2 * frametime, 1);
 628                         if (menuTooltipAlpha == 0)
 629                         {
 630                                 menuTooltipState = 0;
 631                                 menuTooltipItem = NULL;
 632                         }
 633                         break;
 634         }
 635
 636         if (menuTooltipItem == NULL)
 637         {
 638                 if (menuTooltipText)
 639                 {
 640                         strunzone(menuTooltipText);
 641                         menuTooltipText = string_null;
 642                 }
 643                 return;
 644         }
 645         else
 646         {
 647                 if (menu_tooltips != menu_tooltips_old)
 648                 {
 649                         if (menu_tooltips != 0 && menu_tooltips_old != 0) menuTooltipItem = NULL; // reload tooltip next frame
 650                         menu_tooltips_old = menu_tooltips;
 651                 }
 652                 else if (menuTooltipOrigin.x < 0)                                             // unallocated?
 653                 {
 654                         m_allocatetooltipbox(pos);
 655                 }
 656                 if (menuTooltipOrigin.x >= 0)
 657                 {
 658                         // draw the tooltip!
 659                         vector p = SKINBORDER_TOOLTIP;
 660                         p.x *= 1 / conwidth;
 661                         p.y *= 1 / conheight;
 662                         draw_BorderPicture(menuTooltipOrigin, SKINGFX_TOOLTIP, menuTooltipSize, '1 1 1', menuTooltipAlpha, p);
 663                         p = menuTooltipOrigin;
 664                         p.x += SKINMARGIN_TOOLTIP_x / conwidth;
 665                         p.y += SKINMARGIN_TOOLTIP_y / conheight;
 666                         int i = 0;
 667                         for (getWrappedLine_remaining = menuTooltipText; getWrappedLine_remaining && i <= 16; ++i, p.y += fontsize.y)
 668                         {
 669                                 string s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
 670                                 if (i == 16)
 671                                         s = "...";
 672                                 draw_Text(p, s, fontsize, SKINCOLOR_TOOLTIP, SKINALPHA_TOOLTIP * menuTooltipAlpha, false);
 673                         }
 674                 }
 675         }
 676 }
 677
 678 float autocvar_menu_force_on_disconnection;
 679 void m_draw(float width, float height)
 680 {
 681         if (autocvar_menu_force_on_disconnection > 0)
 682         {
 683                 static float connected_time;
 684                 if (clientstate() == CS_DISCONNECTED)
 685                 {
 686                         if (connected_time && time - connected_time > autocvar_menu_force_on_disconnection)
 687                         {
 688                                 m_toggle(true);
 689                                 connected_time = 0;
 690                         }
 691                 }
 692                 else
 693                         connected_time = time;
 694         }
 695
 696         m_gamestatus();
 697
 698         execute_next_frame();
 699
 700         menuMouseMode = cvar("menu_mouse_absolute");
 701
 702         if (anim) anim.tickAll(anim);
 703
 704         UpdateConWidthHeight(width, height, cvar("vid_pixelheight"));
 705
 706         if (!menuInitialized)
 707         {
 708                 // TODO draw an info image about this situation
 709                 m_init_delayed();
 710                 return;
 711         }
 712         if (!menuNotTheFirstFrame)
 713         {
 714                 menuNotTheFirstFrame = true;
 715                 if (Menu_Active && !cvar("menu_video_played"))
 716         {
 717             localcmd("cd loop $menu_cdtrack; play sound/announcer/default/welcome.wav\n");
 718             menuLogoAlpha = -0.8;  // no idea why, but when I start this at zero, it jumps instead of fading FIXME
 719         }
 720                 // ALWAYS set this cvar; if we start but menu is not active, this means we want no background music!
 721                 localcmd("set menu_video_played 1\n");
 722         }
 723
 724         float t = gettime();
 725         float realFrametime = frametime = min(0.2, t - menuPrevTime);
 726         menuPrevTime = t;
 727         time += frametime;
 728
 729         t = cvar("menu_slowmo");
 730         if (t)
 731         {
 732                 frametime *= t;
 733                 realFrametime *= t;
 734         }
 735         else
 736         {
 737                 t = 1;
 738         }
 739
 740         if (Menu_Active)
 741         {
 742                 if (getmousetarget() == (menuMouseMode ? MT_CLIENT : MT_MENU)
 743                     && (getkeydest() == KEY_MENU || getkeydest() == KEY_MENU_GRABBED))
 744                         setkeydest(keyGrabber ? KEY_MENU_GRABBED : KEY_MENU);
 745                 else m_hide();
 746         }
 747
 748         if (cvar("cl_capturevideo")) frametime = t / cvar("cl_capturevideo_fps");  // make capturevideo work smoothly
 749
 750         prevMenuAlpha = menuAlpha;
 751         if (Menu_Active)
 752         {
 753                 if (menuAlpha == 0 && menuLogoAlpha < 2)
 754                 {
 755                         menuLogoAlpha += 2 * frametime;
 756                 }
 757                 else
 758                 {
 759                         menuAlpha = min(1, menuAlpha + 5 * frametime);
 760                         menuLogoAlpha = 2;
 761                 }
 762         }
 763         else
 764         {
 765                 menuAlpha = max(0, menuAlpha - 5 * frametime);
 766                 menuLogoAlpha = 2;
 767         }
 768
 769         draw_reset_cropped();
 770
 771         if (!(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
 772         {
 773                 if (menuLogoAlpha > 0)
 774                 {
 775                         draw_reset_full();
 776                         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_BACKGROUND, 1);
 777                         drawBackground(SKINGFX_BACKGROUND, bound(0, menuLogoAlpha, 1), SKINALIGN_BACKGROUND, true);
 778                         draw_reset_cropped();
 779                         if (menuAlpha <= 0 && SKINALPHA_CURSOR_INTRO > 0)
 780                         {
 781                                 draw_alpha = SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1);
 782                                 draw_drawMousePointer(menuMousePos);
 783                                 draw_alpha = 1;
 784                         }
 785                 }
 786         }
 787         else if (SKINALPHA_BACKGROUND_INGAME)
 788         {
 789                 if (menuAlpha > 0)
 790                 {
 791                         draw_reset_full();
 792                         drawBackground(SKINGFX_BACKGROUND_INGAME, menuAlpha * SKINALPHA_BACKGROUND_INGAME,
 793                                 SKINALIGN_BACKGROUND_INGAME, false);
 794                         draw_reset_cropped();
 795                 }
 796         }
 797
 798         if (menuAlpha != prevMenuAlpha) cvar_set("_menu_alpha", ftos(menuAlpha));
 799
 800         draw_reset_cropped();
 801         preMenuDraw();
 802         draw_reset_cropped();
 803
 804         if (menuAlpha <= 0)
 805         {
 806                 if (prevMenuAlpha > 0) main.initializeDialog(main, main.firstChild);
 807                 draw_reset_cropped();
 808                 postMenuDraw();
 809                 return;
 810         }
 811
 812         draw_alpha *= menuAlpha;
 813
 814         if (menuMouseMode)
 815         {
 816                 vector rawMousePos = getmousepos();
 817                 vector newMouse = globalToBox(rawMousePos, draw_shift, draw_scale);
 818                 if (rawMousePos != '0 0 0' && newMouse != menuMousePos)
 819                 {
 820                         menuMousePos = newMouse;
 821                         if (mouseButtonsPressed) main.mouseDrag(main, menuMousePos);
 822                         else main.mouseMove(main, menuMousePos);
 823                 }
 824         }
 825         else if (frametime > 0)
 826         {
 827                 vector dMouse = getmousepos() * (frametime / realFrametime);  // for capturevideo
 828                 if (dMouse != '0 0 0')
 829                 {
 830                         vector minpos = globalToBox('0 0 0', draw_shift, draw_scale);
 831                         vector maxpos = globalToBox(eX * (realconwidth - 1) + eY * (realconheight - 1), draw_shift, draw_scale);
 832                         dMouse = globalToBoxSize(dMouse, draw_scale);
 833                         menuMousePos += dMouse * cvar("menu_mouse_speed");
 834                         menuMousePos.x = bound(minpos.x, menuMousePos.x, maxpos.x);
 835                         menuMousePos.y = bound(minpos.y, menuMousePos.y, maxpos.y);
 836                         if (mouseButtonsPressed) main.mouseDrag(main, menuMousePos);
 837                         else main.mouseMove(main, menuMousePos);
 838                 }
 839         }
 840         main.draw(main);
 841
 842         m_tooltip(menuMousePos);
 843
 844         draw_alpha = max(draw_alpha, SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1));
 845
 846         draw_drawMousePointer(menuMousePos);
 847
 848         draw_reset_cropped();
 849         postMenuDraw();
 850
 851         frametime = 0;
 852         IL_ENDFRAME();
 853 }
 854
 855 void m_display()
 856 {
 857         Menu_Active = true;
 858         setkeydest(KEY_MENU);
 859         setmousetarget((menuMouseMode ? MT_CLIENT : MT_MENU));
 860
 861         if (!menuInitialized) return;
 862
 863         if (mouseButtonsPressed) main.mouseRelease(main, menuMousePos);
 864         mouseButtonsPressed = 0;
 865
 866         main.focusEnter(main);
 867         main.showNotify(main);
 868 }
 869
 870 void m_hide()
 871 {
 872         Menu_Active = false;
 873         setkeydest(KEY_GAME);
 874         setmousetarget(MT_CLIENT);
 875
 876         if (!menuInitialized) return;
 877
 878         main.focusLeave(main);
 879         main.hideNotify(main);
 880 }
 881
 882 void m_toggle(int mode)
 883 {
 884         if (Menu_Active)
 885         {
 886                 if (mode == 1) return;
 887                 m_hide();
 888         }
 889         else
 890         {
 891                 if (mode == 0) return;
 892                 m_display();
 893         }
 894 }
 895
 896 void Shutdown()
 897 {
 898         m_hide();
 899         FOREACH_ENTITY_ORDERED(it.destroy, {
 900                 if (it.classname == "vtbl") continue;
 901                 it.destroy(it);
 902         });
 903 }
 904
 905 void m_focus_item_chain(entity outermost, entity innermost)
 906 {
 907         if (innermost.parent != outermost) m_focus_item_chain(outermost, innermost.parent);
 908         innermost.parent.setFocus(innermost.parent, innermost);
 909 }
 910
 911 void m_activate_window(entity wnd)
 912 {
 913         entity par = wnd.parent;
 914         if (par) m_activate_window(par);
 915
 916         if (par.instanceOfModalController)
 917         {
 918                 if (wnd.tabSelectingButton)
 919                         // tabs
 920                         TabButton_Click(wnd.tabSelectingButton, wnd);
 921                 else
 922                         // root
 923                         par.initializeDialog(par, wnd);
 924         }
 925         else if (par.instanceOfNexposee)
 926         {
 927                 // nexposee (sorry for violating abstraction here)
 928                 par.selectedChild = wnd;
 929                 par.animationState = 1;
 930                 Container_setFocus(par, NULL);
 931         }
 932         else if (par.instanceOfContainer)
 933         {
 934                 // other containers
 935                 if (par.focused) par.setFocus(par, wnd);
 936         }
 937 }
 938
 939 void m_setpointerfocus(entity wnd)
 940 {
 941         if (!wnd.instanceOfContainer) return;
 942         entity focus = wnd.preferredFocusedGrandChild(wnd);
 943         if (!focus) return;
 944         menuMousePos = focus.origin + 0.5 * focus.size;
 945         menuMousePos.x *= 1 / conwidth;
 946         menuMousePos.y *= 1 / conheight;
 947         entity par = wnd.parent;
 948         if (par.focused) par.setFocus(par, wnd);
 949         if (wnd.focused) m_focus_item_chain(wnd, focus);
 950 }
 951
 952 void m_goto(string itemname)
 953 {
 954         if (!menuInitialized)
 955         {
 956                 if (m_goto_buffer) strunzone(m_goto_buffer);
 957                 m_goto_buffer = strzone(itemname);
 958                 return;
 959         }
 960         if (itemname == "")  // this can be called by GameCommand
 961         {
 962                 if (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))
 963                 {
 964                         m_hide();
 965                 }
 966                 else
 967                 {
 968                         m_activate_window(main.mainNexposee);
 969                         m_display();
 970                 }
 971         }
 972         else
 973         {
 974                 entity e;
 975                 for (e = NULL; (e = find(e, name, itemname)); )
 976                         if (e.classname != "vtbl") break;
 977
 978                 if ((e) && (!e.requiresConnection || (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))))
 979                 {
 980                         m_hide();
 981                         m_activate_window(e);
 982                         m_setpointerfocus(e);
 983                         m_display();
 984                 }
 985         }
 986 }
 987
 988 void m_play_focus_sound()
 989 {
 990         static float menuLastFocusSoundTime;
 991         if (cvar("menu_sounds") < 2) return;
 992         if (time - menuLastFocusSoundTime <= 0.25) return;
 993         localsound(MENU_SOUND_FOCUS);
 994         menuLastFocusSoundTime = time;
 995 }
 996
 997 void m_play_click_sound(string soundfile)
 998 {
 999         if (!cvar("menu_sounds")) return;
1000         localsound(soundfile);
1001 }