qcsrc/menu/item/slider.qc

   1 // Note:
   2 //   to use this, you FIRST call configureSliderVisuals, then configureSliderValues
   3 #ifndef ITEM_SLIDER_H
   4 #define ITEM_SLIDER_H
   5 #include "label.qc"
   6 CLASS(Slider, Label)
   7         METHOD(Slider, resizeNotify, void(entity, vector, vector, vector, vector))
   8         METHOD(Slider, configureSliderVisuals, void(entity, float, float, float, string))
   9         METHOD(Slider, configureSliderValues, void(entity, float, float, float, float, float, float))
  10         METHOD(Slider, draw, void(entity))
  11         METHOD(Slider, keyDown, float(entity, float, float, float))
  12         METHOD(Slider, keyUp, float(entity, float, float, float))
  13         METHOD(Slider, mousePress, float(entity, vector))
  14         METHOD(Slider, mouseDrag, float(entity, vector))
  15         METHOD(Slider, mouseRelease, float(entity, vector))
  16         METHOD(Slider, valueToText, string(entity, float))
  17         METHOD(Slider, toString, string(entity))
  18         METHOD(Slider, setValue, void(entity, float))
  19         METHOD(Slider, setSliderValue, void(entity, float))
  20         METHOD(Slider, showNotify, void(entity))
  21         ATTRIB(Slider, src, string, string_null)
  22         ATTRIB(Slider, focusable, float, 1)
  23         ATTRIB(Slider, allowFocusSound, float, 1)
  24         ATTRIB(Slider, value, float, 0)
  25         ATTRIB(Slider, animated, float, 1)
  26         ATTRIB(Slider, sliderValue, float, 0)
  27         ATTRIB(Slider, sliderAnim, entity, world)
  28         ATTRIB(Slider, valueMin, float, 0)
  29         ATTRIB(Slider, valueMax, float, 0)
  30         ATTRIB(Slider, valueStep, float, 0)
  31         ATTRIB(Slider, valueDigits, float, 0)
  32         ATTRIB(Slider, valueKeyStep, float, 0)
  33         ATTRIB(Slider, valuePageStep, float, 0)
  34         ATTRIB(Slider, valueDisplayMultiplier, float, 1.0)
  35         ATTRIB(Slider, textSpace, float, 0)
  36         ATTRIB(Slider, controlWidth, float, 0)
  37         ATTRIB(Slider, pressed, float, 0)
  38         ATTRIB(Slider, pressOffset, float, 0)
  39         ATTRIB(Slider, previousValue, float, 0)
  40         ATTRIB(Slider, tolerance, vector, '0 0 0')
  41         ATTRIB(Slider, disabled, float, 0)
  42         ATTRIB(Slider, color, vector, '1 1 1')
  43         ATTRIB(Slider, color2, vector, '1 1 1')
  44         ATTRIB(Slider, colorD, vector, '1 1 1')
  45         ATTRIB(Slider, colorC, vector, '1 1 1')
  46         ATTRIB(Slider, colorF, vector, '1 1 1')
  47         ATTRIB(Slider, disabledAlpha, float, 0.3)
  48 ENDCLASS(Slider)
  49 #endif
  50
  51 #ifdef IMPLEMENTATION
  52 void Slider_setValue(entity me, float val)
  53 {
  54         if (me.animated) {
  55                 float t = 0.5;
  56                 if(!me.sliderAnim)
  57                         me.sliderAnim = makeHostedEasing(me, Slider_setSliderValue, easingQuadOut, t, me.sliderValue, val);
  58                 else
  59                         me.sliderAnim.update(me.sliderAnim, t, me.sliderValue, val);
  60         } else {
  61                 me.setSliderValue(me, val);
  62         }
  63         me.value = val;
  64 }
  65 void Slider_setSliderValue(entity me, float val)
  66 {
  67         me.sliderValue = val;
  68 }
  69 string Slider_toString(entity me)
  70 {
  71         return sprintf("%d (%s)", me.value, me.valueToText(me, me.value));
  72 }
  73 void Slider_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  74 {
  75         SUPER(Slider).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  76         me.controlWidth = absSize.y / absSize.x;
  77 }
  78 string Slider_valueToText(entity me, float val)
  79 {
  80         if(almost_in_bounds(me.valueMin, val, me.valueMax))
  81                 return ftos_decimals(val * me.valueDisplayMultiplier, me.valueDigits);
  82         return "";
  83 }
  84 void Slider_configureSliderVisuals(entity me, float sz, float theAlign, float theTextSpace, string gfx)
  85 {
  86         SUPER(Slider).configureLabel(me, string_null, sz, theAlign);
  87         me.textSpace = theTextSpace;
  88         me.keepspaceLeft = (theTextSpace == 0) ? 0 : (1 - theTextSpace);
  89         me.src = gfx;
  90 }
  91 void Slider_configureSliderValues(entity me, float theValueMin, float theValue, float theValueMax, float theValueStep, float theValueKeyStep, float theValuePageStep)
  92 {
  93         me.value = theValue;
  94         me.sliderValue = theValue;
  95         me.valueStep = theValueStep;
  96         me.valueMin = theValueMin;
  97         me.valueMax = theValueMax;
  98         me.valueKeyStep = theValueKeyStep;
  99         me.valuePageStep = theValuePageStep;
 100         me.valueDigits = 3;
 101         if(fabs(floor(me.valueStep * 100 + 0.5) - (me.valueStep * 100)) < 0.01) // about a whole number of 100ths
 102                 me.valueDigits = 2;
 103         if(fabs(floor(me.valueStep * 10 + 0.5) - (me.valueStep * 10)) < 0.01) // about a whole number of 10ths
 104                 me.valueDigits = 1;
 105         if(fabs(floor(me.valueStep * 1 + 0.5) - (me.valueStep * 1)) < 0.01) // about a whole number
 106                 me.valueDigits = 0;
 107 }
 108 float Slider_keyDown(entity me, float key, float ascii, float shift)
 109 {
 110         float inRange;
 111         if(me.disabled)
 112                 return 0;
 113         inRange = (almost_in_bounds(me.valueMin, me.value, me.valueMax));
 114         if(key == K_LEFTARROW || key == K_KP_LEFTARROW || key == K_MWHEELDOWN)
 115         {
 116                 if(inRange)
 117                         me.setValue(me, median(me.valueMin, me.value - me.valueKeyStep, me.valueMax));
 118                 else
 119                         me.setValue(me, me.valueMax);
 120                 return 1;
 121         }
 122         if(key == K_RIGHTARROW || key == K_KP_RIGHTARROW || key == K_MWHEELUP)
 123         {
 124                 if(inRange)
 125                         me.setValue(me, median(me.valueMin, me.value + me.valueKeyStep, me.valueMax));
 126                 else
 127                         me.setValue(me, me.valueMin);
 128                 return 1;
 129         }
 130         if(key == K_PGDN || key == K_KP_PGDN)
 131         {
 132                 if(inRange)
 133                         me.setValue(me, median(me.valueMin, me.value - me.valuePageStep, me.valueMax));
 134                 else
 135                         me.setValue(me, me.valueMax);
 136                 return 1;
 137         }
 138         if(key == K_PGUP || key == K_KP_PGUP)
 139         {
 140                 if(inRange)
 141                         me.setValue(me, median(me.valueMin, me.value + me.valuePageStep, me.valueMax));
 142                 else
 143                         me.setValue(me, me.valueMin);
 144                 return 1;
 145         }
 146         if(key == K_HOME || key == K_KP_HOME)
 147         {
 148                 me.setValue(me, me.valueMin);
 149                 return 1;
 150         }
 151         if(key == K_END || key == K_KP_END)
 152         {
 153                 me.setValue(me, me.valueMax);
 154                 return 1;
 155         }
 156         // TODO more keys (NOTE also add them to Slider_keyUp)
 157         return 0;
 158 }
 159 float Slider_keyUp(entity me, float key, float ascii, float shift)
 160 {
 161         if(me.disabled)
 162                 return 0;
 163         switch(key)
 164         {
 165                 case K_LEFTARROW:
 166                 case K_KP_LEFTARROW:
 167                 case K_RIGHTARROW:
 168                 case K_KP_RIGHTARROW:
 169                 case K_PGUP:
 170                 case K_KP_PGUP:
 171                 case K_PGDN:
 172                 case K_KP_PGDN:
 173                 case K_HOME:
 174                 case K_KP_HOME:
 175                 case K_END:
 176                 case K_KP_END:
 177                         m_play_click_sound(MENU_SOUND_SLIDE);
 178         }
 179         return 0;
 180 }
 181 float Slider_mouseDrag(entity me, vector pos)
 182 {
 183         float hit;
 184         float v, animed;
 185         if(me.disabled)
 186                 return 0;
 187
 188         if(me.pressed)
 189         {
 190                 hit = 1;
 191                 if(pos.x < 0 - me.tolerance.x) hit = 0;
 192                 if(pos.y < 0 - me.tolerance.y) hit = 0;
 193                 if(pos.x >= 1 - me.textSpace + me.tolerance.x) hit = 0;
 194                 if(pos.y >= 1 + me.tolerance.y) hit = 0;
 195                 if(hit)
 196                 {
 197                         anim.removeObjAnim(anim, me);
 198                         animed = me.animated;
 199                         me.animated = false;
 200
 201                         v = median(0, (pos.x - me.pressOffset - 0.5 * me.controlWidth) / (1 - me.textSpace - me.controlWidth), 1) * (me.valueMax - me.valueMin) + me.valueMin;
 202                         if(me.valueStep)
 203                                 v = floor(0.5 + v / me.valueStep) * me.valueStep;
 204                         me.setValue(me, v);
 205
 206                         me.animated = animed;
 207                 }
 208                 else
 209                         me.setValue(me, me.previousValue);
 210         }
 211
 212         return 1;
 213 }
 214 float Slider_mousePress(entity me, vector pos)
 215 {
 216         float controlCenter;
 217         if(me.disabled)
 218                 return 0;
 219         if(pos.x < 0) return 0;
 220         if(pos.y < 0) return 0;
 221         if(pos.x >= 1 - me.textSpace) return 0;
 222         if(pos.y >= 1) return 0;
 223         controlCenter = (me.value - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth) + 0.5 * me.controlWidth;
 224         if(fabs(pos.x - controlCenter) <= 0.5 * me.controlWidth)
 225         {
 226                 me.pressed = 1;
 227                 me.pressOffset = pos.x - controlCenter;
 228                 me.previousValue = me.value;
 229                 //me.mouseDrag(me, pos);
 230         }
 231         else
 232         {
 233                 float clickValue, pageValue, inRange;
 234                 clickValue = median(0, (pos.x - me.pressOffset - 0.5 * me.controlWidth) / (1 - me.textSpace - me.controlWidth), 1) * (me.valueMax - me.valueMin) + me.valueMin;
 235                 inRange = (almost_in_bounds(me.valueMin, me.value, me.valueMax));
 236                 if(pos.x < controlCenter)
 237                 {
 238                         pageValue = me.value - me.valuePageStep;
 239                         if(me.valueStep)
 240                                 clickValue = floor(clickValue / me.valueStep) * me.valueStep;
 241                         pageValue = max(pageValue, clickValue);
 242                         if(inRange)
 243                                 me.setValue(me, median(me.valueMin, pageValue, me.valueMax));
 244                         else
 245                                 me.setValue(me, me.valueMax);
 246                 }
 247                 else
 248                 {
 249                         pageValue = me.value + me.valuePageStep;
 250                         if(me.valueStep)
 251                                 clickValue = ceil(clickValue / me.valueStep) * me.valueStep;
 252                         pageValue = min(pageValue, clickValue);
 253                         if(inRange)
 254                                 me.setValue(me, median(me.valueMin, pageValue, me.valueMax));
 255                         else
 256                                 me.setValue(me, me.valueMax);
 257                 }
 258                 if(pageValue == clickValue)
 259                 {
 260                         controlCenter = (me.value - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth) + 0.5 * me.controlWidth;
 261                         me.pressed = 1;
 262                         me.pressOffset = pos.x - controlCenter;
 263                         me.previousValue = me.value;
 264                         //me.mouseDrag(me, pos);
 265                 }
 266         }
 267         return 1;
 268 }
 269 float Slider_mouseRelease(entity me, vector pos)
 270 {
 271         me.pressed = 0;
 272         if(me.disabled)
 273                 return 0;
 274         m_play_click_sound(MENU_SOUND_SLIDE);
 275         return 1;
 276 }
 277 void Slider_showNotify(entity me)
 278 {
 279         me.focusable = !me.disabled;
 280 }
 281 void Slider_draw(entity me)
 282 {
 283         float controlLeft;
 284         float save;
 285         me.focusable = !me.disabled;
 286         save = draw_alpha;
 287         if(me.disabled)
 288                 draw_alpha *= me.disabledAlpha;
 289         draw_ButtonPicture('0 0 0', strcat(me.src, "_s"), eX * (1 - me.textSpace) + eY, me.color2, 1);
 290         if(almost_in_bounds(me.valueMin, me.sliderValue, me.valueMax))
 291         {
 292                 controlLeft = (me.sliderValue - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth);
 293                 if(me.disabled)
 294                         draw_Picture(eX * controlLeft, strcat(me.src, "_d"), eX * me.controlWidth + eY, me.colorD, 1);
 295                 else if(me.pressed)
 296                         draw_Picture(eX * controlLeft, strcat(me.src, "_c"), eX * me.controlWidth + eY, me.colorC, 1);
 297                 else if(me.focused)
 298                         draw_Picture(eX * controlLeft, strcat(me.src, "_f"), eX * me.controlWidth + eY, me.colorF, 1);
 299                 else
 300                         draw_Picture(eX * controlLeft, strcat(me.src, "_n"), eX * me.controlWidth + eY, me.color, 1);
 301         }
 302
 303         if(me.sliderAnim)
 304         if(me.sliderAnim.isFinished(me.sliderAnim))
 305         {
 306                 anim.removeObjAnim(anim, me);
 307                 me.sliderAnim = world;
 308         }
 309
 310         me.setText(me, me.valueToText(me, me.value));
 311         draw_alpha = save;
 312         SUPER(Slider).draw(me);
 313         me.text = string_null; // TEMPSTRING!
 314 }
 315 #endif