qcsrc/menu/item/borderimage.qc

   1 #include "borderimage.qh"
   2 #ifndef ITEM_BORDERIMAGE_H
   3         #define ITEM_BORDERIMAGE_H
   4         #include "label.qc"
   5         CLASS(BorderImage, Label)
   6                 METHOD(BorderImage, configureBorderImage, void(entity, string, float, vector, string, float));
   7                 METHOD(BorderImage, resizeNotify, void(entity, vector, vector, vector, vector));
   8                 METHOD(BorderImage, recalcPositionWithText, void(entity, string));
   9                 ATTRIB(BorderImage, isBold, float, 1)
  10                 METHOD(BorderImage, draw, void(entity));
  11                 ATTRIB(BorderImage, src, string, string_null)
  12                 ATTRIB(BorderImage, borderHeight, float, 0)
  13                 ATTRIB(BorderImage, borderVec, vector, '0 0 0')
  14                 ATTRIB(BorderImage, color, vector, '1 1 1')
  15                 ATTRIB(BorderImage, closeButton, entity, NULL)
  16                 ATTRIB(BorderImage, realFontSize_Nexposeed, vector, '0 0 0')
  17                 ATTRIB(BorderImage, realOrigin_Nexposeed, vector, '0 0 0')
  18                 ATTRIB(BorderImage, isNexposeeTitleBar, float, 0)
  19                 ATTRIB(BorderImage, zoomedOutTitleBarPosition, float, 0)
  20                 ATTRIB(BorderImage, zoomedOutTitleBar, float, 0)
  21                 ATTRIB(BorderImage, overrideRealOrigin, vector, '0 1 0')
  22                 ATTRIB(BorderImage, saveRelOrigin, vector, '0 0 0')
  23                 ATTRIB(BorderImage, saveRelSize, vector, '0 0 0')
  24         ENDCLASS(BorderImage)
  25 #endif
  26
  27 #ifdef IMPLEMENTATION
  28         void BorderImage_recalcPositionWithText(entity me, string t)
  29         {
  30                 if (me.isNexposeeTitleBar)
  31                 {
  32                         vector scrs;
  33                         scrs = eX * conwidth + eY * conheight;
  34                         me.resizeNotify(me, me.saveRelOrigin, me.saveRelSize, boxToGlobal(me.parent.Nexposee_smallOrigin, '0 0 0', scrs), boxToGlobalSize(me.parent.Nexposee_smallSize, scrs));
  35                         SUPER(BorderImage).recalcPositionWithText(me, t);
  36                         me.realOrigin_y = me.realFontSize.y * me.zoomedOutTitleBarPosition;
  37                         me.realOrigin_Nexposeed = me.realOrigin;
  38                         me.realFontSize_Nexposeed = me.realFontSize;
  39                         me.resizeNotify(me, me.saveRelOrigin, me.saveRelSize, boxToGlobal(me.parent.Nexposee_initialOrigin, '0 0 0', scrs), boxToGlobalSize(me.parent.Nexposee_initialSize, scrs));
  40                 }
  41                 SUPER(BorderImage).recalcPositionWithText(me, t);
  42         }
  43         void BorderImage_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  44         {
  45                 me.isNexposeeTitleBar = 0;
  46                 if (me.zoomedOutTitleBar)
  47                         if (me.parent.parent.instanceOfNexposee)
  48                                 if (me.parent.instanceOfDialog)
  49                                         if (me == me.parent.frame) me.isNexposeeTitleBar = 1;
  50                 me.saveRelOrigin = relOrigin;
  51                 me.saveRelSize = relSize;
  52                 SUPER(BorderImage).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  53                 me.borderVec_x = me.borderHeight / absSize.x;
  54                 me.borderVec_y = me.borderHeight / absSize.y;
  55                 me.realOrigin_y = 0.5 * (me.borderVec.y - me.realFontSize.y);
  56                 if (me.closeButton)
  57                 {
  58                         // move the close button to the right place
  59                         me.closeButton.Container_origin = '1 0 0' * (1 - me.borderVec.x);
  60                         me.closeButton.Container_size = me.borderVec;
  61                         me.closeButton.color = me.color;
  62                         me.closeButton.colorC = me.color;
  63                         me.closeButton.colorF = me.color;
  64                 }
  65         }
  66         void BorderImage_configureBorderImage(entity me, string theTitle, float sz, vector theColor, string path, float theBorderHeight)
  67         {
  68                 me.configureLabel(me, theTitle, sz, 0.5);
  69                 me.src = path;
  70                 me.color = theColor;
  71                 me.borderHeight = theBorderHeight;
  72         }
  73         void BorderImage_draw(entity me)
  74         {
  75                 if (me.src) draw_BorderPicture('0 0 0', me.src, '1 1 0', me.color, 1, me.borderVec);
  76
  77                 if (me.fontSize > 0)
  78                 {
  79                         if (me.recalcPos) me.recalcPositionWithText(me, me.text);
  80
  81                         if (me.isNexposeeTitleBar)
  82                         {
  83                                 vector ro, rf, df;
  84
  85                                 // me.parent.Nexposee_animationFactor 0 (small) or 1 (full)
  86                                 // default values are for 1
  87                                 ro = me.realOrigin;
  88                                 rf = me.realFontSize;
  89                                 df = draw_fontscale;
  90                                 me.realOrigin = ro * me.parent.Nexposee_animationFactor + me.realOrigin_Nexposeed * (1 - me.parent.Nexposee_animationFactor);
  91                                 me.realFontSize = rf * me.parent.Nexposee_animationFactor + me.realFontSize_Nexposeed * (1 - me.parent.Nexposee_animationFactor);
  92                                 draw_fontscale = globalToBoxSize(boxToGlobalSize(df, me.realFontSize), rf);
  93
  94                                 SUPER(BorderImage).draw(me);
  95
  96                                 // me.Nexposee_animationState 0 (small) or 1 (full)
  97                                 // default values are for 1
  98                                 me.realOrigin = ro;
  99                                 me.realFontSize = rf;
 100                                 draw_fontscale = df;
 101                         }
 102                         else
 103                         {
 104                                 SUPER(BorderImage).draw(me);
 105                         }
 106                 }
 107                 else
 108                 {
 109                         SUPER(BorderImage).draw(me);
 110                 }
 111         }
 112 #endif