qcsrc/lib/warpzone/common.qc

   1 #include "common.qh"
   2
   3 #if defined(CSQC)
   4     #include <client/items/items.qh>
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7     #include <common/weapons/_all.qh>
   8 #endif
   9
  10 void WarpZone_Accumulator_Clear(entity acc)
  11 {
  12         acc.warpzone_transform = '0 0 0';
  13         acc.warpzone_shift = '0 0 0';
  14 }
  15 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  16 {
  17         vector tr, st;
  18         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  19         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  20         acc.warpzone_transform = tr;
  21         acc.warpzone_shift = st;
  22 }
  23 void WarpZone_Accumulator_Add(entity acc, entity wz)
  24 {
  25         WarpZone_Accumulator_AddTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  26 }
  27 void WarpZone_Accumulator_AddInverseTransform(entity acc, vector t, vector s)
  28 {
  29         vector tt, ss;
  30         tt = AnglesTransform_Invert(t);
  31         ss = AnglesTransform_PrePostShift_GetPostShift(s, tt, '0 0 0');
  32         WarpZone_Accumulator_AddTransform(acc, tt, ss);
  33         // yes, this probably can be done simpler... but this way is "obvious" :)
  34 }
  35 void WarpZone_Accumulator_AddInverse(entity acc, entity wz)
  36 {
  37         WarpZone_Accumulator_AddInverseTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  38 }
  39
  40 float autocvar_cl_warpzone_usetrace = 1;
  41 vector WarpZone_camera_transform(entity this, vector org, vector ang)
  42 {
  43         vector vf, vr, vu;
  44         if(this.warpzone_fadestart)
  45                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
  46                         return org;
  47                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  48                         // unneeded on client, on server this helps a lot
  49         vf = v_forward;
  50         vr = v_right;
  51         vu = v_up;
  52         org = WarpZone_TransformOrigin(this, org);
  53         vf = WarpZone_TransformVelocity(this, vf);
  54         vr = WarpZone_TransformVelocity(this, vr);
  55         vu = WarpZone_TransformVelocity(this, vu);
  56         if(autocvar_cl_warpzone_usetrace)
  57                 traceline(this.warpzone_targetorigin, org, MOVE_NOMONSTERS, NULL);
  58         else
  59                 trace_endpos = this.warpzone_targetorigin;
  60         v_forward = vf;
  61         v_right = vr;
  62         v_up = vu;
  63         return org;
  64 }
  65
  66 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  67 {
  68         e.warpzone_transform = AnglesTransform_RightDivide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  69         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  70         e.warpzone_origin = my_org;
  71         e.warpzone_targetorigin = other_org;
  72         e.warpzone_angles = my_ang;
  73         e.warpzone_targetangles = other_ang;
  74         vector forward, right, up;
  75         FIXED_MAKE_VECTORS(my_ang, forward, right, up);
  76         e.warpzone_forward = forward;
  77         FIXED_MAKE_VECTORS(other_ang, forward, right, up);
  78         e.warpzone_targetforward = forward;
  79         setcamera_transform(e, WarpZone_camera_transform);
  80 }
  81
  82 vector WarpZone_Camera_camera_transform(entity this, vector org, vector ang)
  83 {
  84         // a fixed camera view
  85         if(this.warpzone_fadestart)
  86                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
  87                         return org;
  88                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  89                         // unneeded on client, on server this helps a lot
  90         trace_endpos = this.warpzone_origin;
  91         makevectors(this.warpzone_angles);
  92         return this.warpzone_origin;
  93 }
  94
  95 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  96 {
  97         e.warpzone_origin = my_org;
  98         e.warpzone_angles = my_ang;
  99         setcamera_transform(e, WarpZone_Camera_camera_transform);
 100 }
 101
 102 .entity enemy;
 103
 104 float WarpZoneLib_BoxTouchesBrush_Recurse(vector mi, vector ma, entity e, entity ig)
 105 {
 106         float f, s;
 107         entity se;
 108
 109         tracebox('0 0 0', mi, ma, '0 0 0', MOVE_NOMONSTERS, ig);
 110 #ifdef CSQC
 111         if (trace_networkentity)
 112         {
 113                 LOG_TRACE("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush");
 114                 // we cannot continue, as a player blocks us...
 115                 // so, abort
 116                 return 0;
 117         }
 118 #endif
 119         if (!trace_ent)
 120                 return 0;
 121         if (trace_ent == e)
 122                 return 1;
 123
 124         se = trace_ent;
 125         s = se.solid;
 126         se.solid = SOLID_NOT;
 127         f = WarpZoneLib_BoxTouchesBrush_Recurse(mi, ma, e, ig);
 128         se.solid = s;
 129
 130         return f;
 131 }
 132
 133 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 134 {
 135         // bones_was_here: TODO: when findbox() builtin is available, use it to
 136         // optimise this into a single non-recursive function that only calls tracebox once
 137
 138         float f, s;
 139
 140         if(!e.modelindex || e.warpzone_isboxy)
 141                 return 1;
 142
 143         s = e.solid;
 144         e.solid = SOLID_BSP;
 145         f = WarpZoneLib_BoxTouchesBrush_Recurse(mi, ma, e, ig);
 146         e.solid = s;
 147
 148         return f;
 149 }
 150
 151 entity WarpZone_Find(vector mi, vector ma)
 152 {
 153         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 154         if(!warpzone_warpzones_exist)
 155                 return NULL;
 156         IL_EACH(g_warpzones, WarpZoneLib_BoxTouchesBrush(mi, ma, it, NULL),
 157         {
 158                 return it;
 159         });
 160         return NULL;
 161 }
 162
 163 void WarpZone_MakeAllSolid()
 164 {
 165         if(!warpzone_warpzones_exist)
 166                 return;
 167         IL_EACH(g_warpzones, true,
 168         {
 169                 it.solid = SOLID_BSP;
 170         });
 171 }
 172
 173 void WarpZone_MakeAllOther()
 174 {
 175         if(!warpzone_warpzones_exist)
 176                 return;
 177         IL_EACH(g_warpzones, true,
 178         {
 179                 it.solid = SOLID_TRIGGER;
 180         });
 181 }
 182
 183 void WarpZone_Trace_InitTransform()
 184 {
 185         if(!WarpZone_trace_transform)
 186         {
 187                 WarpZone_trace_transform = new_pure(warpzone_trace_transform);
 188         }
 189         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 190 }
 191 void WarpZone_Trace_AddTransform(entity wz)
 192 {
 193         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 194 }
 195
 196 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 197 {
 198         float nomonsters_adjusted;
 199         float frac, sol, i;
 200         float contentshack;
 201         entity wz;
 202         vector vf, vr, vu;
 203
 204         WarpZone_trace_forent = forent;
 205         WarpZone_trace_firstzone = NULL;
 206         WarpZone_trace_lastzone = NULL;
 207         WarpZone_Trace_InitTransform();
 208         if(!warpzone_warpzones_exist)
 209         {
 210                 if(nomonsters == MOVE_NOTHING)
 211                 {
 212                         trace_endpos = end;
 213                         trace_fraction = 1;
 214                         if(cb)
 215                                 cb(org, trace_endpos, end);
 216                         return;
 217                 }
 218                 else
 219                 {
 220                         tracebox(org, mi, ma, end, nomonsters, WarpZone_trace_forent);
 221                         if(cb)
 222                                 cb(org, trace_endpos, end);
 223                         return;
 224                 }
 225         }
 226
 227         vf = v_forward;
 228         vr = v_right;
 229         vu = v_up;
 230
 231         switch(nomonsters)
 232         {
 233                 case MOVE_WORLDONLY:
 234                 case MOVE_NOTHING:
 235                         nomonsters_adjusted = MOVE_NOMONSTERS;
 236                         break;
 237                 default:
 238                         nomonsters_adjusted = nomonsters;
 239                         break;
 240         }
 241         if((contentshack = (WarpZone_trace_forent.dphitcontentsmask && !(WarpZone_trace_forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 242                 BITSET_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 243
 244         // if starting in warpzone, first transform
 245         wz = WarpZone_Find(org + mi, org + ma);
 246         if(wz)
 247         {
 248                 WarpZone_trace_firstzone = wz;
 249                 WarpZone_trace_lastzone = wz;
 250                 if(zone && wz != zone)
 251                 {
 252                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 253                         sol = 1;
 254                         trace_fraction = 0;
 255                         trace_endpos = org;
 256                         goto fail;
 257                 }
 258                 WarpZone_Trace_AddTransform(wz);
 259                 org = WarpZone_TransformOrigin(wz, org);
 260                 end = WarpZone_TransformOrigin(wz, end);
 261         }
 262         WarpZone_MakeAllSolid();
 263         sol = -1;
 264         frac = 0;
 265         i = 16;
 266         for (;;)
 267         {
 268                 if(--i < 1)
 269                 {
 270                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
 271                         trace_ent = NULL;
 272                         break;
 273                 }
 274                 tracebox(org, mi, ma, end, nomonsters_adjusted, WarpZone_trace_forent);
 275                 if(cb)
 276                         cb(org, trace_endpos, end);
 277                 if(sol < 0)
 278                         sol = trace_startsolid;
 279
 280                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 281                 if(trace_fraction >= 1)
 282                         break;
 283                 if(trace_ent.classname != "trigger_warpzone")
 284                 {
 285                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & WarpZone_trace_forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 286                         {
 287                                 // continue the trace, ignoring this hit (we only care for warpzones)
 288                                 org = trace_endpos + normalize(end - org);
 289                                 continue;
 290                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 291                                 // otherwise, players could block entrances that way
 292                         }
 293                         break;
 294                 }
 295                 /*if(trace_ent == wz)
 296                 {
 297                         // FIXME can this check be removed? Do we really need it?
 298                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
 299                         trace_ent = NULL;
 300                         break;
 301                 }*/
 302                 wz = trace_ent;
 303                 if(!WarpZone_trace_firstzone)
 304                         WarpZone_trace_firstzone = wz;
 305                 WarpZone_trace_lastzone = wz;
 306                 if(zone && wz != zone)
 307                         break;
 308                 WarpZone_Trace_AddTransform(wz);
 309                 // we hit a warpzone... so, let's perform the trace after the warp again
 310                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 311                 end = WarpZone_TransformOrigin(wz, end);
 312
 313                 // we got warped, so let's step back a bit
 314                 tracebox(org, mi, ma, org + normalize(org - end) * 32, nomonsters_adjusted, WarpZone_trace_forent);
 315                 org = trace_endpos;
 316         }
 317         WarpZone_MakeAllOther();
 318 LABEL(fail)
 319         if(contentshack)
 320                 BITCLR_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 321         trace_startsolid = sol;
 322         v_forward = vf;
 323         v_right = vr;
 324         v_up = vu;
 325 }
 326
 327 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 328 {
 329         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, NULL, WarpZone_trace_callback_t_null);
 330 }
 331
 332 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 333 {
 334         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 335 }
 336
 337 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 338 {
 339         float g, dt, i;
 340         vector vf, vr, vu, v0, o0;
 341         entity wz;
 342
 343         o0 = e.origin;
 344         v0 = e.velocity;
 345         g = cvar("sv_gravity") * e.gravity;
 346
 347         WarpZone_trace_forent = forent;
 348         WarpZone_trace_firstzone = NULL;
 349         WarpZone_trace_lastzone = NULL;
 350         WarpZone_Trace_InitTransform();
 351         WarpZone_tracetoss_time = 0;
 352         if(!warpzone_warpzones_exist)
 353         {
 354                 tracetoss(e, WarpZone_trace_forent);
 355                 if(cb)
 356                         cb(e.origin, trace_endpos, trace_endpos);
 357                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 358                 WarpZone_tracetoss_time += dt;
 359                 e.velocity_z -= dt * g;
 360                 WarpZone_tracetoss_velocity = e.velocity;
 361                 e.velocity = v0;
 362                 return;
 363         }
 364
 365         vf = v_forward;
 366         vr = v_right;
 367         vu = v_up;
 368
 369         // if starting in warpzone, first transform
 370         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 371         if(wz)
 372         {
 373                 WarpZone_trace_firstzone = wz;
 374                 WarpZone_trace_lastzone = wz;
 375                 if(zone && wz != zone)
 376                 {
 377                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 378
 379                         WarpZone_tracetoss_time = 0;
 380                         trace_endpos = o0;
 381                         goto fail;
 382                 }
 383                 WarpZone_Trace_AddTransform(wz);
 384                 vector org = WarpZone_TransformOrigin(wz, e.origin);
 385                 setorigin(e, org);
 386                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 387         }
 388         WarpZone_MakeAllSolid();
 389         i = 16;
 390         for (;;)
 391         {
 392                 if(--i < 1)
 393                 {
 394                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
 395                         trace_ent = NULL;
 396                         break;
 397                 }
 398                 tracetoss(e, WarpZone_trace_forent);
 399                 if(cb)
 400                         cb(e.origin, trace_endpos, trace_endpos);
 401                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 402                 WarpZone_tracetoss_time += dt;
 403                 e.origin = trace_endpos;
 404                 e.velocity_z -= dt * g;
 405                 if(trace_fraction >= 1)
 406                         break;
 407                 if(trace_ent.classname != "trigger_warpzone")
 408                         break;
 409                 if(trace_ent == wz)
 410                 {
 411                         // FIXME can this check be removed? Do we really need it?
 412                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
 413                         trace_ent = NULL;
 414                         break;
 415                 }
 416                 wz = trace_ent;
 417                 if(!WarpZone_trace_firstzone)
 418                         WarpZone_trace_firstzone = wz;
 419                 WarpZone_trace_lastzone = wz;
 420                 if(zone && wz != zone)
 421                         break;
 422                 WarpZone_Trace_AddTransform(wz);
 423                 // we hit a warpzone... so, let's perform the trace after the warp again
 424                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 425                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 426
 427                 // we got warped, so let's step back a bit
 428                 e.velocity = -e.velocity;
 429                 tracetoss(e, WarpZone_trace_forent);
 430                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 431                 WarpZone_tracetoss_time -= dt;
 432                 e.origin = trace_endpos;
 433                 e.velocity = -e.velocity;
 434         }
 435         WarpZone_MakeAllOther();
 436 LABEL(fail)
 437         WarpZone_tracetoss_velocity = e.velocity;
 438         v_forward = vf;
 439         v_right = vr;
 440         v_up = vu;
 441         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 442         e.velocity = v0;
 443         e.origin = o0;
 444 }
 445
 446 void WarpZone_TraceToss(entity e, entity forent)
 447 {
 448         WarpZone_TraceToss_ThroughZone(e, forent, NULL, WarpZone_trace_callback_t_null);
 449 }
 450
 451 entity WarpZone_TrailParticles_trace_callback_own;
 452 float WarpZone_TrailParticles_trace_callback_eff;
 453 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 454 {
 455         __trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 456 }
 457
 458 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 459 {
 460         WarpZone_TrailParticles_trace_callback_own = own;
 461         WarpZone_TrailParticles_trace_callback_eff = eff;
 462         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_trace_callback);
 463 }
 464
 465 #ifdef CSQC
 466 float WarpZone_TrailParticles_trace_callback_f;
 467 float WarpZone_TrailParticles_trace_callback_flags;
 468 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
 469 {
 470         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
 471 }
 472
 473 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, int boxflags)
 474 {
 475         WarpZone_TrailParticles_trace_callback_own = own;
 476         WarpZone_TrailParticles_trace_callback_eff = eff;
 477         WarpZone_TrailParticles_trace_callback_f = f;
 478         WarpZone_TrailParticles_trace_callback_flags = boxflags | PARTICLES_DRAWASTRAIL;
 479         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_WithMultiplier_trace_callback);
 480 }
 481 #endif
 482
 483 float WarpZone_PlaneDist(entity wz, vector v)
 484 {
 485         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 486 }
 487
 488 float WarpZone_TargetPlaneDist(entity wz, vector v)
 489 {
 490         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 491 }
 492
 493 vector WarpZone_TransformOrigin(entity wz, vector v)
 494 {
 495         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 496 }
 497
 498 vector WarpZone_TransformVelocity(entity wz, vector v)
 499 {
 500         return AnglesTransform_Apply(wz.warpzone_transform, v);
 501 }
 502
 503 vector WarpZone_TransformAngles(entity wz, vector v)
 504 {
 505         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 506 }
 507
 508 vector WarpZone_TransformVAngles(entity wz, vector ang)
 509 {
 510 #ifdef KEEP_ROLL
 511         float roll;
 512         roll = ang.z;
 513         ang.z = 0;
 514 #endif
 515
 516         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 517
 518 #ifdef KEEP_ROLL
 519         ang = AnglesTransform_Normalize(ang, true);
 520         ang = AnglesTransform_CancelRoll(ang);
 521         ang.z = roll;
 522 #else
 523         ang = AnglesTransform_Normalize(ang, false);
 524 #endif
 525
 526         return ang;
 527 }
 528
 529 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 530 {
 531         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 532 }
 533
 534 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 535 {
 536         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 537 }
 538
 539 vector WarpZone_UnTransformAngles(entity wz, vector v)
 540 {
 541         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 542 }
 543
 544 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 545 {
 546         float roll;
 547
 548         roll = ang.z;
 549         ang.z = 0;
 550
 551         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 552         ang = AnglesTransform_Normalize(ang, true);
 553         ang = AnglesTransform_CancelRoll(ang);
 554
 555         ang.z = roll;
 556         return ang;
 557 }
 558
 559 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 560 {
 561         vector nearest;
 562         nearest.x = bound(mi.x, org.x, ma.x);
 563         nearest.y = bound(mi.y, org.y, ma.y);
 564         nearest.z = bound(mi.z, org.z, ma.z);
 565         return nearest;
 566 }
 567
 568 // blacklist of entities that WarpZone_FindRadius doesn't care about
 569 bool WarpZoneLib_BadEntity(entity e)
 570 {
 571         if (is_pure(e)) return true;
 572         string s = e.classname;
 573
 574         switch(s)
 575         {
 576                 case "weaponentity":
 577                 case "exteriorweaponentity":
 578                 case "sprite_waypoint":
 579                 case "waypoint":
 580                 case "spawnfunc":
 581                 case "weaponchild":
 582                 case "chatbubbleentity":
 583                 case "buff_model":
 584                 //case "net_linked": // actually some real entities are linked without classname, fail
 585                 case "":
 586                         return true;
 587         }
 588
 589         if (startsWith(s, "target_")) return true;
 590
 591         if (startsWith(s, "info_")) return true;
 592
 593         return false;
 594 }
 595
 596 .float WarpZone_findradius_hit;
 597 .entity WarpZone_findradius_next;
 598 void WarpZone_FindRadius_Recurse(
 599     /** blast origin of current search */
 600     vector org,
 601     float rad,
 602     /** original blast origin */
 603     vector org0,
 604     /** how to untransform (victim to blast system) */
 605     vector transform,
 606     vector shift,
 607     bool needlineofsight)
 608 {
 609         if (rad <= 0) return;
 610         entity wz = NULL;
 611         FOREACH_ENTITY_RADIUS(org, rad, !WarpZoneLib_BadEntity(it), {
 612                 vector p = WarpZoneLib_NearestPointOnBox(it.origin + it.mins, it.origin + it.maxs, org0);
 613                 if (needlineofsight)
 614                 {
 615                         traceline(org, p, MOVE_NOMONSTERS, it);
 616                         if (trace_fraction < 1) continue;
 617                 }
 618                 if (!it.WarpZone_findradius_hit || vlen2(it.WarpZone_findradius_dist) > vlen2(org0 - p))
 619                 {
 620                         it.WarpZone_findradius_nearest = p;
 621                         it.WarpZone_findradius_dist = org0 - p;
 622                         it.WarpZone_findradius_findorigin = org;
 623                         it.WarpZone_findradius_findradius = rad;
 624                         if (it.classname == "warpzone_refsys")
 625                         {
 626                                 // ignore, especially: do not overwrite the refsys parameters
 627                         }
 628                         else if (it.classname == "trigger_warpzone")
 629                         {
 630                                 it.WarpZone_findradius_next = wz;
 631                                 wz = it;
 632                                 it.WarpZone_findradius_hit = 1;
 633                                 it.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 634                                 it.enemy.WarpZone_findradius_hit = 1;
 635                         }
 636                         else
 637                         {
 638                                 it.warpzone_transform = transform;
 639                                 it.warpzone_shift = shift;
 640                                 it.WarpZone_findradius_hit = 1;
 641                         }
 642                 }
 643     });
 644         for(entity e = wz; e; e = e.WarpZone_findradius_next)
 645         {
 646                 if (WarpZoneLib_BadEntity(e)) continue;
 647
 648                 vector org0_new = WarpZone_TransformOrigin(e, org);
 649                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 650                 vector org_new = trace_endpos;
 651
 652                 vector transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 653                 vector shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 654                 WarpZone_FindRadius_Recurse(
 655                         org_new,
 656                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 657                         org0_new,
 658                         transform_new, shift_new,
 659                         needlineofsight);
 660                 e.WarpZone_findradius_hit = 0;
 661                 e.enemy.WarpZone_findradius_hit = 0;
 662         }
 663 }
 664 entity WarpZone_FindRadius(vector org, float rad, bool needlineofsight)
 665 {
 666     // FIXME: why can't we do this? (sometimes finds nothing, breaking explosions)
 667     // if (!warpzone_warpzones_exist && !needlineofsight) return findradius(org, rad);
 668         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 669         entity list_first = findchainfloat(WarpZone_findradius_hit, 1);
 670         FOREACH_LIST(list, chain, true, it.WarpZone_findradius_hit = 0);
 671         return list_first;
 672 }
 673
 674 .entity WarpZone_refsys;
 675 void WarpZone_RefSys_GC(entity this)
 676 {
 677         // garbage collect unused reference systems
 678         this.nextthink = time + 1;
 679         if(this.owner.WarpZone_refsys != this)
 680                 delete(this);
 681 }
 682 void WarpZone_RefSys_CheckCreate(entity me)
 683 {
 684         if(me.WarpZone_refsys.owner != me)
 685         {
 686                 me.WarpZone_refsys = new(warpzone_refsys);
 687                 me.WarpZone_refsys.owner = me;
 688                 setthink(me.WarpZone_refsys, WarpZone_RefSys_GC);
 689                 me.WarpZone_refsys.nextthink = time + 1;
 690                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 691         }
 692 }
 693 void WarpZone_RefSys_Clear(entity me)
 694 {
 695         if(me.WarpZone_refsys)
 696         {
 697                 delete(me.WarpZone_refsys);
 698                 me.WarpZone_refsys = NULL;
 699         }
 700 }
 701 void WarpZone_RefSys_AddTransform(entity me, vector t, vector s)
 702 {
 703         if(t != '0 0 0' || s != '0 0 0')
 704         {
 705                 WarpZone_RefSys_CheckCreate(me);
 706                 WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 707         }
 708 }
 709 void WarpZone_RefSys_Add(entity me, entity wz)
 710 {
 711         WarpZone_RefSys_AddTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 712 }
 713 void WarpZone_RefSys_AddInverseTransform(entity me, vector t, vector s)
 714 {
 715         if(t != '0 0 0' || s != '0 0 0')
 716         {
 717                 WarpZone_RefSys_CheckCreate(me);
 718                 WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, t, s);
 719         }
 720 }
 721 void WarpZone_RefSys_AddInverse(entity me, entity wz)
 722 {
 723         WarpZone_RefSys_AddInverseTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 724 }
 725 .vector WarpZone_refsys_incremental_shift;
 726 .vector WarpZone_refsys_incremental_transform;
 727 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 728 {
 729         //vector t, s;
 730         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 731         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 732                 return;
 733         WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, me.WarpZone_refsys_incremental_transform, me.WarpZone_refsys_incremental_shift);
 734         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref.WarpZone_refsys);
 735         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 736         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 737 }
 738 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 739 {
 740         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 741         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 742 }
 743 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 744 {
 745         if(from.WarpZone_refsys)
 746                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 747         if(to.WarpZone_refsys)
 748                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 749         return org;
 750 }
 751 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 752 {
 753         if(from.WarpZone_refsys)
 754                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 755         if(to.WarpZone_refsys)
 756                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 757         return vel;
 758 }
 759 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 760 {
 761         if(from.WarpZone_refsys)
 762                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 763         if(to.WarpZone_refsys)
 764                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 765         return ang;
 766 }
 767 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 768 {
 769         if(from.WarpZone_refsys)
 770                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 771         if(to.WarpZone_refsys)
 772                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 773         return ang;
 774 }
 775 void WarpZone_RefSys_Copy(entity me, entity from)
 776 {
 777         if(from.WarpZone_refsys)
 778         {
 779                 WarpZone_RefSys_CheckCreate(me);
 780                 me.WarpZone_refsys.warpzone_shift = from.WarpZone_refsys.warpzone_shift;
 781                 me.WarpZone_refsys.warpzone_transform = from.WarpZone_refsys.warpzone_transform;
 782         }
 783         else
 784                 WarpZone_RefSys_Clear(me);
 785 }
 786 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 787 {
 788         entity e = spawn();
 789         WarpZone_RefSys_Copy(e, me);
 790         return e;
 791 }
 792
 793 bool WarpZoneLib_ExactTrigger_Touch(entity this, entity toucher)
 794 {
 795         vector emin = toucher.absmin, emax = toucher.absmax;
 796         if(STAT(Q3COMPAT))
 797         {
 798                 // DP's tracebox enlarges absolute bounding boxes by a single quake unit
 799                 // we must undo that here to allow accurate touching
 800                 emin += '1 1 1';
 801                 emax -= '1 1 1';
 802         }
 803         return !WarpZoneLib_BoxTouchesBrush(emin, emax, this, toucher);
 804 }
 805
 806
 807 void WarpZoneLib_MoveOutOfSolid_Expand(entity e, vector by)
 808 {
 809         const float eps = 0.0625;
 810         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
 811         if (trace_startsolid)
 812                 return;
 813         if (trace_fraction < 1)
 814         {
 815                 // hit something
 816                 // adjust origin in the other direction...
 817                 setorigin(e, e.origin - by * (1 - trace_fraction));
 818         }
 819 }
 820
 821 bool WarpZoneLib_MoveOutOfSolid(entity e)
 822 {
 823         vector o = e.origin;
 824         traceline(o, o, MOVE_WORLDONLY, e);
 825         if (trace_startsolid)
 826                 return false;
 827
 828         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
 829         if (!trace_startsolid)
 830                 return true;
 831
 832         vector m0 = e.mins;
 833         vector m1 = e.maxs;
 834         e.mins = '0 0 0';
 835         e.maxs = '0 0 0';
 836         WarpZoneLib_MoveOutOfSolid_Expand(e, eX * m0.x); e.mins_x = m0.x;
 837         WarpZoneLib_MoveOutOfSolid_Expand(e, eX * m1.x); e.maxs_x = m1.x;
 838         WarpZoneLib_MoveOutOfSolid_Expand(e, eY * m0.y); e.mins_y = m0.y;
 839         WarpZoneLib_MoveOutOfSolid_Expand(e, eY * m1.y); e.maxs_y = m1.y;
 840         WarpZoneLib_MoveOutOfSolid_Expand(e, eZ * m0.z); e.mins_z = m0.z;
 841         WarpZoneLib_MoveOutOfSolid_Expand(e, eZ * m1.z); e.maxs_z = m1.z;
 842         setorigin(e, e.origin);
 843
 844         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 845         if (trace_startsolid)
 846         {
 847                 setorigin(e, o);
 848                 return false;
 849         }
 850
 851         return true;
 852 }