qcsrc/lib/net.qh

   1 #ifndef NET_H
   2 #define NET_H
   3
   4 #ifdef SVQC
   5         .int Version;  // deprecated, use SendFlags
   6         .int SendFlags;
   7         .bool(entity to, int sendflags) SendEntity;
   8         .bool(entity this, entity to, int sendflags) SendEntity3;
   9
  10         bool SendEntity_self(entity to, int sendflags) { return self.SendEntity3(self, to, sendflags); }
  11
  12         void Net_LinkEntity(entity e, bool docull, float dt, bool(entity this, entity to, int sendflags) sendfunc)
  13         {
  14                 if (e.classname == "") e.classname = "net_linked";
  15
  16                 if (e.model == "" || self.modelindex == 0)
  17                 {
  18                         vector mi = e.mins;
  19                         vector ma = e.maxs;
  20                         _setmodel(e, "null");
  21                         setsize(e, mi, ma);
  22                 }
  23
  24                 e.SendEntity = SendEntity_self;
  25                 e.SendEntity3 = sendfunc;
  26                 e.SendFlags = 0xFFFFFF;
  27
  28                 if (!docull) e.effects |= EF_NODEPTHTEST;
  29
  30                 if (dt)
  31                 {
  32                         e.nextthink = time + dt;
  33                         e.think = SUB_Remove_self;
  34                 }
  35         }
  36
  37         .void() uncustomizeentityforclient;
  38         .float uncustomizeentityforclient_set;
  39
  40         void SetCustomizer(entity e, float() customizer, void() uncustomizer)
  41         {
  42                 e.customizeentityforclient = customizer;
  43                 e.uncustomizeentityforclient = uncustomizer;
  44                 e.uncustomizeentityforclient_set = !!uncustomizer;
  45         }
  46
  47         void UncustomizeEntitiesRun()
  48         {
  49                 for (entity e = NULL; (e = findfloat(e, uncustomizeentityforclient_set, 1)); )
  50                         WITH(entity, self, e, e.uncustomizeentityforclient());
  51         }
  52
  53 #endif
  54
  55 #include "registry.qh"
  56 #include "sort.qh"
  57
  58 .string netname;
  59 .int m_id;
  60 .bool(entity this, bool isNew) m_read;
  61
  62 #ifdef CSQC
  63         #define Net_Accept(classname) \
  64                 do \
  65                 { \
  66                         if (!this)    this = new(classname); \
  67                 } \
  68                 while (0)
  69         #define Net_Reject() \
  70                 do \
  71                 { \
  72                         if (this)     remove(this); \
  73                 } \
  74                 while (0)
  75         #define NET_HANDLE(id, param) \
  76                 bool Net_Handle_##id(entity this, param)
  77 #else
  78         #define WriteHeader(to, id) \
  79                 do \
  80                 { \
  81                         if (NET_##id##_istemp) WriteByte(to, SVC_TEMPENTITY); \
  82                         WriteByte(to, NET_##id.m_id); \
  83                 } \
  84                 while (0)
  85 #endif
  86
  87 #ifdef CSQC
  88         #define REGISTER_NET_LINKED(id) \
  89                 [[accumulate]] NET_HANDLE(id, bool isnew) \
  90                 { \
  91                         this = self; \
  92                         this.sourceLocFile = __FILE__; \
  93                         this.sourceLocLine = __LINE__; \
  94                         if (!this) isnew = true; \
  95                 } \
  96                 REGISTER(LinkedEntities, NET, id, m_id, new(net_linked_packet)) \
  97                 { \
  98                         make_pure(this); \
  99                         this.netname = #id; \
 100                         this.m_read = Net_Handle_##id; \
 101                 }
 102 #else
 103         #define REGISTER_NET_LINKED(id) \
 104                 const bool NET_##id##_istemp = false; \
 105                 REGISTER(LinkedEntities, NET, id, m_id, new(net_linked_packet)) \
 106                 { \
 107                         make_pure(this); \
 108                         this.netname = #id; \
 109                 }
 110 #endif
 111
 112 REGISTRY(LinkedEntities, BITS(8) - 1)
 113 #define LinkedEntities_from(i) _LinkedEntities_from(i, NULL)
 114 REGISTER_REGISTRY(LinkedEntities)
 115 REGISTRY_SORT(LinkedEntities)
 116 REGISTRY_CHECK(LinkedEntities)
 117 STATIC_INIT(RegisterLinkedEntities_renumber)
 118 {
 119         for (int i = 0; i < LinkedEntities_COUNT; ++i)
 120                 LinkedEntities_from(i).m_id = 1 + i;
 121 }
 122
 123 #ifdef CSQC
 124         #define REGISTER_NET_TEMP(id) \
 125                 NET_HANDLE(id, bool); \
 126                 REGISTER(TempEntities, NET, id, m_id, new(net_temp_packet)) \
 127                 { \
 128                         make_pure(this); \
 129                         this.netname = #id; \
 130                         this.m_read = Net_Handle_##id; \
 131                 }
 132 #else
 133         #define REGISTER_NET_TEMP(id) \
 134                 const bool NET_##id##_istemp = true; \
 135                 REGISTER(TempEntities, NET, id, m_id, new(net_temp_packet)) \
 136                 { \
 137                         make_pure(this); \
 138                         this.netname = #id; \
 139                 }
 140 #endif
 141
 142 REGISTRY(TempEntities, BITS(8) - 80)
 143 #define TempEntities_from(i) _TempEntities_from(i, NULL)
 144 REGISTER_REGISTRY(TempEntities)
 145 REGISTRY_SORT(TempEntities)
 146 REGISTRY_CHECK(TempEntities)
 147 STATIC_INIT(RegisterTempEntities_renumber)
 148 {
 149         for (int i = 0; i < TempEntities_COUNT; ++i)
 150                 TempEntities_from(i).m_id = 80 + i;
 151 }
 152
 153 #ifndef MENUQC
 154         const float APPROXPASTTIME_ACCURACY_REQUIREMENT = 0.05;
 155         #define APPROXPASTTIME_MAX (16384 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 156         #define APPROXPASTTIME_RANGE (64 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 157
 158         #ifdef CSQC
 159                 entity ReadCSQCEntity()
 160                 {
 161                         int f = ReadShort();
 162                         if (f == 0) return world;
 163                         return findfloat(world, entnum, f);
 164                 }
 165                 int ReadInt24_t()
 166                 {
 167                         int v = ReadShort() << 8; // note: this is signed
 168                         v += ReadByte();          // note: this is unsigned
 169                         return v;
 170                 }
 171                 vector ReadInt48_t()
 172                 {
 173                         vector v;
 174                         v.x = ReadInt24_t();
 175                         v.y = ReadInt24_t();
 176                         v.z = 0;
 177                         return v;
 178                 }
 179                 vector ReadInt72_t()
 180                 {
 181                         vector v;
 182                         v.x = ReadInt24_t();
 183                         v.y = ReadInt24_t();
 184                         v.z = ReadInt24_t();
 185                         return v;
 186                 }
 187
 188                 #define ReadFloat() ReadCoord()
 189         vector ReadVector() { vector v; v.x = ReadFloat(); v_y = ReadFloat(); v.z = ReadFloat(); return v; }
 190                 vector ReadVector2D() { vector v; v.x = ReadFloat(); v.y = ReadFloat(); v.z = 0; return v; }
 191
 192                 float ReadApproxPastTime()
 193                 {
 194                         float dt = ReadByte();
 195
 196                         // map from range...PPROXPASTTIME_MAX / 256
 197                         dt = (APPROXPASTTIME_MAX / 256) * (dt / (256 - dt));
 198
 199                         return servertime - dt;
 200                 }
 201
 202         #else
 203                 const int MSG_ENTITY = 5;
 204
 205                 void WriteInt24_t(float dst, float val)
 206                 {
 207                         float v;
 208                         WriteShort(dst, (v = floor(val >> 8)));
 209                         WriteByte(dst, val - (v << 8));  // 0..255
 210                 }
 211                 void WriteInt48_t(float dst, vector val)
 212                 {
 213                         WriteInt24_t(dst, val.x);
 214                         WriteInt24_t(dst, val.y);
 215                 }
 216                 void WriteInt72_t(float dst, vector val)
 217                 {
 218                         WriteInt24_t(dst, val.x);
 219                         WriteInt24_t(dst, val.y);
 220                         WriteInt24_t(dst, val.z);
 221                 }
 222
 223         #define WriteFloat(to, f) WriteCoord(to, f)
 224                 #define WriteVector(to, v) do { WriteFloat(to, v.x); WriteFloat(to, v.y); WriteFloat(to, v.z); } while (0)
 225         #define WriteVector2D(to, v) do { WriteFloat(to, v.x); WriteFloat(to, v.y); } while (0)
 226
 227                 // this will use the value:
 228                 //   128
 229                 // accuracy near zero is APPROXPASTTIME_MAX/(256*255)
 230                 // accuracy at x is 1/derivative, i.e.
 231                 //   APPROXPASTTIME_MAX * (1 + 256 * (dt / APPROXPASTTIME_MAX))^2 / 65536
 232                 void WriteApproxPastTime(float dst, float t)
 233                 {
 234                         float dt = time - t;
 235
 236                         // warning: this is approximate; do not resend when you don't have to!
 237                         // be careful with sendflags here!
 238                         // we want: 0 -> 0.05, 1 -> 0.1, ..., 255 -> 12.75
 239
 240                         // map to range...
 241                         dt = 256 * (dt / ((APPROXPASTTIME_MAX / 256) + dt));
 242
 243                         // round...
 244                         dt = rint(bound(0, dt, 255));
 245
 246                         WriteByte(dst, dt);
 247                 }
 248
 249                 // allow writing to also pass through to spectators (like so spectators see the same centerprints as players for example)
 250                 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname, statement) \
 251                         entity varname; varname = msg_entity; \
 252                         FOR_EACH_REALCLIENT(msg_entity) \
 253                         if (msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) \
 254                                 statement msg_entity = varname
 255                 #define WRITESPECTATABLE_MSG_ONE(statement) \
 256                         do \
 257                         { \
 258                                 WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement); \
 259                         } \
 260                         while (0)
 261                 #define WRITESPECTATABLE(msg, statement) \
 262                         if (msg == MSG_ONE) WRITESPECTATABLE_MSG_ONE(statement); \
 263                         else \
 264                                 statement float WRITESPECTATABLE_workaround = 0
 265         #endif
 266 #endif
 267
 268 #endif