qcsrc/common/weapons/weapon/vaporizer.qc

   1 #include "vaporizer.qh"
   2
   3 REGISTER_NET_TEMP(TE_CSQC_VAPORBEAMPARTICLE)
   4
   5 #if defined(SVQC)
   6 void SendCSQCVaporizerBeamParticle(entity player, int hit) {
   7         vector v;
   8         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
   9         WriteHeader(MSG_BROADCAST, TE_CSQC_VAPORBEAMPARTICLE);
  10         WriteVector(MSG_BROADCAST, w_shotorg);
  11         WriteVector(MSG_BROADCAST, v);
  12         WriteByte(MSG_BROADCAST, hit);
  13         WriteByte(MSG_BROADCAST, etof(player));
  14         WriteByte(MSG_BROADCAST, player.team);
  15 }
  16 #elif defined(CSQC)
  17 bool autocvar_cl_vaporizerbeam_particle = false;
  18 float autocvar_cl_vaporizerbeam_lifetime = 0.8;
  19 float autocvar_cl_vaporizerbeam_colorboost = 0.7;
  20
  21 string Draw_VaporizerBeam_trace_callback_tex;
  22 float Draw_VaporizerBeam_trace_callback_rnd;
  23 vector Draw_VaporizerBeam_trace_callback_rgb;
  24 float Draw_VaporizerBeam_trace_callback_a;
  25 void Draw_VaporizerBeam_trace_callback(vector start, vector hit, vector end)
  26 {
  27         float i;
  28         vector vorg;
  29         vorg = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
  30         for(i = 0; i < Draw_VaporizerBeam_trace_callback_a; ++i)
  31                 Draw_CylindricLine(hit, start, 8, Draw_VaporizerBeam_trace_callback_tex, 0.25, Draw_VaporizerBeam_trace_callback_rnd, Draw_VaporizerBeam_trace_callback_rgb, min(1, Draw_VaporizerBeam_trace_callback_a - i), DRAWFLAG_NORMAL, vorg);
  32         Draw_VaporizerBeam_trace_callback_rnd += 0.25 * vlen(hit - start) / 8;
  33 }
  34
  35 .vector vorg1, vorg2;
  36 void VaporizerBeam_Draw(entity this)
  37 {
  38         //draw either the old v2.3 beam or the new beam
  39         particles_alphamin = particles_alphamax = particles_fade = 1;
  40
  41         string tex = "particles/lgbeam";
  42         if(this.cnt)
  43                 tex = "particles/gauntletbeam";
  44         vector rgb;
  45         //entity e = CSQCModel_server2csqc(this.sv_entnum - 1);
  46         //if (e == NULL)
  47         //{
  48                 rgb = colormapPaletteColor(entcs_GetClientColors(this.sv_entnum - 1) & 0x0F, true);
  49                 //rgb = '1 1 1';
  50         //}
  51         //else
  52         //      rgb = e.glowmod;
  53         rgb *= (1 + autocvar_cl_vaporizerbeam_colorboost);
  54
  55         float fail = (this.nextthink - time);
  56
  57         Draw_VaporizerBeam_trace_callback_tex = tex;
  58         Draw_VaporizerBeam_trace_callback_rnd = 0;
  59         Draw_VaporizerBeam_trace_callback_rgb = rgb;
  60         Draw_VaporizerBeam_trace_callback_a = bound(0, fail, 1);
  61         WarpZone_TraceBox_ThroughZone(this.vorg1, '0 0 0', '0 0 0', this.vorg2, MOVE_NOTHING, NULL, NULL, Draw_VaporizerBeam_trace_callback);
  62         Draw_VaporizerBeam_trace_callback_tex = string_null;
  63
  64         /*if(!MUTATOR_CALLHOOK(Particles_VaporizerBeam, this.vorg1, this.vorg2))
  65         if(autocvar_cl_particles_oldvortexbeam)
  66                 WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM_OLD), this.vorg1, this.vorg2, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
  67         else
  68                 WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM), this.vorg1, this.vorg2, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);*/
  69 }
  70
  71 NET_HANDLE(TE_CSQC_VAPORBEAMPARTICLE, bool isNew)
  72 {
  73         Net_Accept(vortex_beam);
  74         setthink(this, SUB_Remove);
  75         this.nextthink = time + bound(0, autocvar_cl_vaporizerbeam_lifetime, 10);
  76         this.draw = VaporizerBeam_Draw;
  77         if (isNew) IL_PUSH(g_drawables, this);
  78         this.drawmask = MASK_NORMAL;
  79
  80         this.vorg1 = ReadVector();
  81         this.vorg2 = ReadVector();
  82         this.cnt = ReadByte();
  83         int myowner = ReadByte();
  84         this.owner = playerslots[myowner - 1];
  85         this.sv_entnum = myowner;
  86         this.team = ReadByte() - 1;
  87
  88         //pointparticles(EFFECT_VORTEX_MUZZLEFLASH, this.vorg1, normalize(this.vorg2 - this.vorg1) * 1000, 1);
  89
  90         if(autocvar_cl_vaporizerbeam_particle)
  91         {
  92                 WarpZone_TrailParticles(NULL, particleeffectnum(((this.cnt) ? EFFECT_VAPORIZER_HIT(this.team) : EFFECT_VAPORIZER(this.team))), this.vorg1, this.vorg2);
  93                 this.draw = func_null;
  94                 this.drawmask = MASK_NORMAL;
  95                 delete(this);
  96         }
  97
  98         return true;
  99 }
 100 #endif
 101
 102 #ifdef SVQC
 103
 104 void W_RocketMinsta_Explosion(entity actor, .entity weaponentity, vector loc)
 105 {
 106         if(accuracy_canbegooddamage(actor))
 107                 accuracy_add(actor, WEP_DEVASTATOR, autocvar_g_rm_damage, 0);
 108         entity dmgent = spawn();
 109         dmgent.owner = dmgent.realowner = actor;
 110         setorigin(dmgent, loc);
 111         RadiusDamage (dmgent, actor, autocvar_g_rm_damage, autocvar_g_rm_edgedamage, autocvar_g_rm_radius, NULL, NULL, autocvar_g_rm_force, WEP_DEVASTATOR.m_id | HITTYPE_SPLASH, weaponentity, NULL);
 112         delete(dmgent);
 113 }
 114
 115 void W_Vaporizer_Attack(Weapon thiswep, entity actor, .entity weaponentity)
 116 {
 117         bool flying = IsFlying(actor); // do this BEFORE to make the trace values from FireRailgunBullet last
 118         float vaporizer_damage = ((WEP_CVAR_PRI(vaporizer, damage) > 0) ? WEP_CVAR_PRI(vaporizer, damage) : 10000);
 119
 120         W_SetupShot(actor, weaponentity, true, 0, SND_Null, CH_WEAPON_A, vaporizer_damage, thiswep.m_id);
 121         // handle sound separately so we can change the volume
 122         // added bonus: no longer plays the strength sound (strength gives no bonus to instakill anyway)
 123         sound (actor, CH_WEAPON_A, SND_MINSTANEXFIRE, VOL_BASE * 0.8, ATTEN_NORM);
 124
 125         yoda = 0;
 126         //impressive_hits = 0;
 127         FireRailgunBullet(actor, weaponentity, w_shotorg, w_shotorg + w_shotdir * max_shot_distance, vaporizer_damage, true, WEP_CVAR_PRI(vaporizer, force), 0, 0, 0, 0, thiswep.m_id);
 128
 129         // do this now, as goodhits is disabled below
 130         vector v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 131         W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, normalize(v - w_shotorg));
 132         SendCSQCVaporizerBeamParticle(actor, impressive_hits);
 133
 134         if(yoda && flying) {
 135                 Give_Medal(actor, YODA);
 136         }
 137
 138         // We're gonna disable Impressive medals for the vaporizer.
 139         /*if(impressive_hits && actor.vaporizer_lasthit)
 140         {
 141                 Give_Medal(actor, IMPRESSIVE);
 142                 impressive_hits = 0; // only every second time
 143         }*/
 144
 145         actor.vaporizer_lasthit = impressive_hits;
 146
 147         if(autocvar_g_rm)
 148         if(!(trace_dphitq3surfaceflags & (Q3SURFACEFLAG_SKY | Q3SURFACEFLAG_NOIMPACT)))
 149                 W_RocketMinsta_Explosion(actor, weaponentity, trace_endpos);
 150
 151         W_DecreaseAmmo(thiswep, actor, ((autocvar_g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo)), weaponentity);
 152 }
 153
 154 void W_RocketMinsta_Laser_Explode (entity this, entity directhitentity)
 155 {
 156         if(directhitentity.takedamage == DAMAGE_AIM)
 157                 if(IS_PLAYER(directhitentity))
 158                         if(DIFF_TEAM(this.realowner, directhitentity))
 159                                 if(!IS_DEAD(directhitentity))
 160                                         if(IsFlying(directhitentity)) {
 161                                                 Give_Medal(this.realowner, ELECTROBITCH);
 162                                         }
 163
 164         this.event_damage = func_null;
 165         this.takedamage = DAMAGE_NO;
 166         RadiusDamage (this, this.realowner, this.rm_damage, this.rm_edmg, autocvar_g_rm_laser_radius, NULL, NULL, this.rm_force, this.projectiledeathtype, this.weaponentity_fld, directhitentity);
 167         delete(this);
 168 }
 169
 170 void W_RocketMinsta_Laser_Explode_use(entity this, entity actor, entity trigger)
 171 {
 172         W_RocketMinsta_Laser_Explode(this, trigger); // we probably don't want trigger used here, but this matches closest to old behaviour
 173 }
 174
 175 void W_RocketMinsta_Laser_Touch(entity this, entity toucher)
 176 {
 177         PROJECTILE_TOUCH(this, toucher);
 178         //W_RocketMinsta_Laser_Explode ();
 179         RadiusDamage(this, this.realowner, this.rm_damage, this.rm_edmg, autocvar_g_rm_laser_radius, NULL, NULL, this.rm_force, this.projectiledeathtype, this.weaponentity_fld, toucher);
 180         delete(this);
 181 }
 182
 183 void W_RocketMinsta_Attack2(entity actor, .entity weaponentity)
 184 {
 185         makevectors(actor.v_angle);
 186
 187         entity proj;
 188         float counter = 0;
 189         float total = autocvar_g_rm_laser_count;
 190         float spread = autocvar_g_rm_laser_spread;
 191         float rndspread = autocvar_g_rm_laser_spread_random;
 192
 193         W_SetupShot_ProjectileSize (actor, weaponentity, '0 0 -3', '0 0 -3', false, 2, SND_CRYLINK_FIRE, CH_WEAPON_A, autocvar_g_rm_laser_damage, WEP_ELECTRO.m_id);
 194
 195         // uses electro effects
 196         W_MuzzleFlash(WEP_ELECTRO, actor, weaponentity, w_shotorg, w_shotdir);
 197
 198     while(counter < total)
 199         {
 200         proj = new(plasma_prim);
 201         proj.owner = proj.realowner = actor;
 202         proj.bot_dodge = true;
 203         proj.bot_dodgerating = autocvar_g_rm_laser_damage;
 204         proj.use = W_RocketMinsta_Laser_Explode_use;
 205         setthink(proj, adaptor_think2use_hittype_splash);
 206         proj.nextthink = time + autocvar_g_rm_laser_lifetime;
 207         PROJECTILE_MAKETRIGGER(proj);
 208         proj.projectiledeathtype = WEP_ELECTRO.m_id;
 209         proj.weaponentity_fld = weaponentity;
 210         setorigin(proj, w_shotorg);
 211
 212                 proj.rm_force = autocvar_g_rm_laser_force / total;
 213                 proj.rm_damage = autocvar_g_rm_laser_damage / total;
 214                 proj.rm_edmg = proj.rm_damage;
 215
 216         //W_SetupProjectileVelocity(proj, autocvar_g_rm_laser_speed, spread * (rndspread ? random() : 1) * autocvar_g_rm_laser_speed);
 217
 218         set_movetype(proj, MOVETYPE_BOUNCEMISSILE);
 219         //W_SETUPPROJECTILEVELOCITY(proj, g_balance_minstanex_laser);
 220                 proj.velocity = (w_shotdir + (((counter + 0.5) / total) * 2 - 1) * v_right * (spread * (rndspread ? random() : 1))) * cvar("g_rm_laser_speed");
 221                 proj.velocity_z = proj.velocity_z + cvar("g_rm_laser_zspread") * (random() - 0.5);
 222                 proj.velocity = W_CalculateProjectileVelocity(actor, actor.velocity, proj.velocity, true);
 223         proj.angles = vectoangles(proj.velocity);
 224         settouch(proj, W_RocketMinsta_Laser_Touch);
 225         setsize(proj, '0 0 -3', '0 0 -3');
 226         proj.flags = FL_PROJECTILE;
 227         IL_PUSH(g_projectiles, proj);
 228         IL_PUSH(g_bot_dodge, proj);
 229         proj.missile_flags = MIF_SPLASH;
 230
 231         CSQCProjectile(proj, true, PROJECTILE_ROCKETMINSTA_LASER, true);
 232
 233         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
 234         counter++;
 235     }
 236 }
 237
 238 void W_RocketMinsta_Attack3 (entity actor, .entity weaponentity)
 239 {
 240         makevectors(actor.v_angle);
 241
 242         entity proj;
 243         float counter = 0;
 244         float total = 1;
 245
 246         W_SetupShot_ProjectileSize (actor, weaponentity, '0 0 -3', '0 0 -3', false, 2, SND_ELECTRO_FIRE2, CH_WEAPON_A, autocvar_g_rm_laser_damage, WEP_ELECTRO.m_id);
 247
 248         // uses electro effects
 249         W_MuzzleFlash(WEP_ELECTRO, actor, weaponentity, w_shotorg, w_shotdir);
 250
 251     while(counter < total)
 252         {
 253         proj = new(plasma_prim);
 254         proj.owner = proj.realowner = actor;
 255         proj.bot_dodge = true;
 256         proj.bot_dodgerating = autocvar_g_rm_laser_damage;
 257         proj.use = W_RocketMinsta_Laser_Explode_use;
 258         setthink(proj, adaptor_think2use_hittype_splash);
 259         proj.nextthink = time + autocvar_g_rm_laser_lifetime;
 260         PROJECTILE_MAKETRIGGER(proj);
 261         proj.projectiledeathtype = WEP_ELECTRO.m_id;
 262         proj.weaponentity_fld = weaponentity;
 263         setorigin(proj, w_shotorg);
 264
 265                 proj.rm_force = autocvar_g_rm_laser_force / total;
 266                 proj.rm_damage = autocvar_g_rm_laser_damage / total;
 267                 proj.rm_edmg = proj.rm_damage;
 268
 269         //W_SetupProjectileVelocity(proj, autocvar_g_rm_laser_speed, spread * (rndspread ? random() : 1) * autocvar_g_rm_laser_speed);
 270
 271         set_movetype(proj, MOVETYPE_BOUNCEMISSILE);
 272                 proj.velocity = w_shotdir * autocvar_g_rm_laser_speed;
 273                 proj.velocity = W_CalculateProjectileVelocity(actor, actor.velocity, proj.velocity, true);
 274         proj.angles = vectoangles(proj.velocity);
 275         settouch(proj, W_RocketMinsta_Laser_Touch);
 276         setsize(proj, '0 0 -3', '0 0 -3');
 277         proj.flags = FL_PROJECTILE;
 278         IL_PUSH(g_projectiles, proj);
 279         IL_PUSH(g_bot_dodge, proj);
 280         proj.missile_flags = MIF_SPLASH;
 281
 282         CSQCProjectile(proj, true, PROJECTILE_ROCKETMINSTA_LASER, true);
 283
 284         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
 285         counter++;
 286     }
 287 }
 288
 289 METHOD(Vaporizer, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 290 {
 291     if((actor.items & IT_UNLIMITED_AMMO) || GetResource(actor, thiswep.ammo_type) > 0)
 292         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 1, false);
 293     else
 294         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, WEP_CVAR_SEC(vaporizer, speed), 0, WEP_CVAR_SEC(vaporizer, lifetime), false); // WEAPONTODO: replace with proper vaporizer cvars
 295 }
 296 METHOD(Vaporizer, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 297 {
 298     float vaporizer_ammo = ((autocvar_g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 299     // if the laser uses load, we also consider its ammo for reloading
 300     if(WEP_CVAR(vaporizer, reload_ammo) && WEP_CVAR_SEC(vaporizer, ammo) && actor.(weaponentity).clip_load < min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo))) { // forced reload
 301         thiswep.wr_reload(thiswep, actor, weaponentity);
 302     } else if(WEP_CVAR(vaporizer, reload_ammo) && actor.(weaponentity).clip_load < vaporizer_ammo) { // forced reload
 303         thiswep.wr_reload(thiswep, actor, weaponentity);
 304     }
 305     if((fire & 1) && (GetResource(actor, RES_CELLS) || !autocvar_g_rm) && !weaponLocked(actor))
 306     {
 307         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(vaporizer, refire)))
 308         {
 309             W_Vaporizer_Attack(thiswep, actor, weaponentity);
 310             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(vaporizer, animtime), w_ready);
 311         }
 312     }
 313     if((fire & 2) || ((fire & 1) && !GetResource(actor, RES_CELLS) && autocvar_g_rm))
 314     {
 315         if((autocvar_g_rm && autocvar_g_rm_laser) || autocvar_g_rm_laser == 2)
 316         {
 317             bool rapid = autocvar_g_rm_laser_rapid;
 318             if(actor.(weaponentity).jump_interval <= time && !actor.(weaponentity).held_down)
 319             {
 320                 if(rapid)
 321                     actor.(weaponentity).held_down = true;
 322                 actor.(weaponentity).jump_interval = time + autocvar_g_rm_laser_refire;
 323                 actor.(weaponentity).jump_interval2 = time + autocvar_g_rm_laser_rapid_delay;
 324                 impressive_hits = 0;
 325                 W_RocketMinsta_Attack2(actor, weaponentity);
 326             }
 327             else if(rapid && actor.(weaponentity).jump_interval2 <= time && actor.(weaponentity).held_down)
 328             {
 329                 actor.(weaponentity).jump_interval2 = time + autocvar_g_rm_laser_rapid_refire;
 330                 impressive_hits = 0;
 331                 W_RocketMinsta_Attack3(actor, weaponentity);
 332                 //weapon_thinkf(actor, WFRAME_FIRE2, autocvar_g_rm_laser_rapid_animtime, w_ready);
 333             }
 334         }
 335         else if (actor.(weaponentity).jump_interval <= time)
 336         {
 337             // handle refire manually, so that primary and secondary can be fired without conflictions (important for instagib)
 338             actor.(weaponentity).jump_interval = time + WEP_CVAR_SEC(vaporizer, refire) * W_WeaponRateFactor(actor);
 339
 340             // decrease ammo for the laser?
 341             if(WEP_CVAR_SEC(vaporizer, ammo))
 342                 W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(vaporizer, ammo), weaponentity);
 343
 344             BLASTER_SECONDARY_ATTACK(vaporizer, actor, weaponentity);
 345
 346             // now do normal refire
 347             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(vaporizer, animtime), w_ready);
 348         }
 349     }
 350     else
 351         actor.(weaponentity).held_down = false;
 352 }
 353 METHOD(Vaporizer, wr_setup, void(entity thiswep, entity actor, .entity weaponentity))
 354 {
 355     //actor.vaporizer_lasthit = 0;
 356 }
 357 METHOD(Vaporizer, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 358 {
 359     float vaporizer_ammo = ((autocvar_g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 360     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= vaporizer_ammo;
 361     ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= vaporizer_ammo;
 362     return ammo_amount;
 363 }
 364 METHOD(Vaporizer, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 365 {
 366     if(!WEP_CVAR_SEC(vaporizer, ammo))
 367         return true;
 368     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_SEC(vaporizer, ammo);
 369     ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_SEC(vaporizer, ammo);
 370     return ammo_amount;
 371 }
 372 METHOD(Vaporizer, wr_resetplayer, void(entity thiswep, entity actor))
 373 {
 374     actor.vaporizer_lasthit = 0;
 375 }
 376 METHOD(Vaporizer, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 377 {
 378     float vaporizer_ammo = ((autocvar_g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 379     float used_ammo;
 380     if(WEP_CVAR_SEC(vaporizer, ammo))
 381         used_ammo = min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo));
 382     else
 383         used_ammo = vaporizer_ammo;
 384
 385     W_Reload(actor, weaponentity, used_ammo, SND_RELOAD);
 386 }
 387 METHOD(Vaporizer, wr_suicidemessage, Notification(entity thiswep))
 388 {
 389     return WEAPON_THINKING_WITH_PORTALS;
 390 }
 391 METHOD(Vaporizer, wr_killmessage, Notification(entity thiswep))
 392 {
 393     return WEAPON_VAPORIZER_MURDER;
 394 }
 395
 396 #endif
 397 #ifdef CSQC
 398
 399 METHOD(Vaporizer, wr_impacteffect, void(entity thiswep, entity actor))
 400 {
 401     vector org2 = w_org + w_backoff * 6;
 402     if(w_deathtype & HITTYPE_SECONDARY)
 403     {
 404         pointparticles(EFFECT_BLASTER_IMPACT, org2, w_backoff * 1000, 1);
 405         if(!w_issilent) { sound(actor, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 406     }
 407     else
 408     {
 409         pointparticles(EFFECT_VORTEX_IMPACT, org2, '0 0 0', 1);
 410         if(!w_issilent) { sound(actor, CH_SHOTS, SND_NEXIMPACT, VOL_BASE, ATTN_NORM); }
 411     }
 412 }
 413 METHOD(Vaporizer, wr_init, void(entity thiswep))
 414 {
 415     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 416     {
 417         precache_pic("gfx/reticle_nex");
 418     }
 419 }
 420 METHOD(Vaporizer, wr_zoom, bool(entity thiswep, entity actor))
 421 {
 422     if(button_zoom || zoomscript_caught)
 423     {
 424         return true;
 425     }
 426     else
 427     {
 428         // no weapon specific image for this weapon
 429         return false;
 430     }
 431 }
 432
 433 #endif