qcsrc/common/weapons/weapon/shotgun.qc

   1 #include "shotgun.qh"
   2
   3 #ifdef SVQC
   4
   5 // enable to debug melee range
   6 //#define SHOTGUN_MELEEDEBUG
   7
   8 void W_Shotgun_Attack(Weapon thiswep, entity actor, .entity weaponentity, float isprimary, float ammocount, float damage, float bullets, float spread, float solidpenetration, float force, entity bullet_trail_effect)
   9 {
  10         W_DecreaseAmmo(thiswep, actor, ammocount, weaponentity);
  11
  12         W_SetupShot(actor, weaponentity, true, 5, SND_SHOTGUN_FIRE, ((isprimary) ? CH_WEAPON_A : CH_WEAPON_SINGLE), damage * bullets, thiswep.m_id);
  13
  14         // TRICK: do the antilag outside the regular fireBullet function, so it isn't performed unnecessarily on every single bullet!
  15         float lag = antilag_getlag(actor);
  16         if(lag && bullets > 0)
  17                 antilag_takeback_all(actor, lag);
  18
  19         for(int sc = 0;sc < bullets;sc = sc + 1)
  20                 fireBullet_antilag(actor, weaponentity, w_shotorg, w_shotdir, spread, solidpenetration, damage, force, thiswep.m_id, bullet_trail_effect, false);
  21
  22         if(lag && bullets > 0)
  23                 antilag_restore_all(actor);
  24
  25         Send_Effect(EFFECT_SHOTGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, ammocount);
  26
  27         // casing code
  28         if(autocvar_g_casings >= 1)
  29         {
  30                 makevectors(actor.v_angle); // for some reason, this is lost
  31                 //for(int sc = 0;sc < WEP_CVAR_PRI(shotgun, ammo);sc = sc + 1)
  32                         SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, actor, weaponentity);
  33         }
  34
  35         // muzzle flash for 1st person view
  36         entity flash = spawn();
  37         setmodel(flash, MDL_SHOTGUN_MUZZLEFLASH); // precision set below
  38         setthink(flash, SUB_Remove);
  39         flash.nextthink = time + 0.06;
  40         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  41         W_AttachToShotorg(actor, weaponentity, flash, '5 0 0');
  42 }
  43
  44 .float swing_prev;
  45 .entity swing_alreadyhit;
  46 void W_Shotgun_Melee_Think(entity this)
  47 {
  48         // declarations
  49         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  50         entity target_victim;
  51         vector targpos;
  52
  53         if(!this.cnt) // set start time of melee
  54         {
  55                 this.cnt = time;
  56                 W_PlayStrengthSound(this.realowner);
  57         }
  58
  59         makevectors(this.realowner.v_angle); // update values for v_* vectors
  60
  61         // calculate swing percentage based on time
  62         meleetime = WEP_CVAR_SEC(shotgun, melee_time) * W_WeaponRateFactor(this.realowner);
  63         swing = bound(0, (this.cnt + meleetime - time) / meleetime, 10);
  64         f = ((1 - swing) * WEP_CVAR_SEC(shotgun, melee_traces));
  65
  66         // check to see if we can still continue, otherwise give up now
  67         if(IS_DEAD(this.realowner) && WEP_CVAR_SEC(shotgun, melee_no_doubleslap))
  68         {
  69                 delete(this);
  70                 return;
  71         }
  72
  73         // if okay, perform the traces needed for this frame
  74         for(i=this.swing_prev; i < f; ++i)
  75         {
  76                 swing_factor = ((1 - (i / WEP_CVAR_SEC(shotgun, melee_traces))) * 2 - 1);
  77
  78                 targpos = (this.realowner.origin + this.realowner.view_ofs
  79                         + (v_forward * WEP_CVAR_SEC(shotgun, melee_range))
  80                         + (v_up * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_up))
  81                         + (v_right * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_side)));
  82
  83                 WarpZone_traceline_antilag(this.realowner, this.realowner.origin + this.realowner.view_ofs, targpos, false, this.realowner, ((IS_CLIENT(this.realowner)) ? ANTILAG_LATENCY(this.realowner) : 0));
  84
  85                 // draw lightning beams for debugging
  86         #ifdef SHOTGUN_MELEEDEBUG
  87                 te_lightning2(NULL, targpos, this.realowner.origin + this.realowner.view_ofs + v_forward * 5 - v_up * 5);
  88                 te_customflash(targpos, 40,  2, '1 1 1');
  89         #endif
  90
  91                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
  92
  93                 if((trace_fraction < 1) // if trace is good, apply the damage and remove this
  94                         && (trace_ent.takedamage != DAMAGE_NO)
  95                         && (trace_ent != this.swing_alreadyhit)
  96                         && (is_player || WEP_CVAR_SEC(shotgun, melee_nonplayerdamage)))
  97                 {
  98                         target_victim = trace_ent; // so it persists through other calls
  99
 100                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
 101                                 swing_damage = (WEP_CVAR_SEC(shotgun, damage) * min(1, swing_factor + 1));
 102                         else
 103                                 swing_damage = (WEP_CVAR_SEC(shotgun, melee_nonplayerdamage) * min(1, swing_factor + 1));
 104
 105                         //print(strcat(this.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
 106
 107                         Damage(target_victim, this.realowner, this.realowner,
 108                                 swing_damage, WEP_SHOTGUN.m_id | HITTYPE_SECONDARY, this.weaponentity_fld,
 109                                 this.realowner.origin + this.realowner.view_ofs,
 110                                 v_forward * WEP_CVAR_SEC(shotgun, force));
 111
 112                         if(accuracy_isgooddamage(this.realowner, target_victim)) { accuracy_add(this.realowner, WEP_SHOTGUN, 0, swing_damage); }
 113
 114                         // draw large red flash for debugging
 115                 #ifdef SHOTGUN_MELEEDEBUG
 116                         te_customflash(targpos, 200, 2, '15 0 0');
 117                 #endif
 118
 119                         if(WEP_CVAR_SEC(shotgun, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
 120                         {
 121                                 this.swing_alreadyhit = target_victim;
 122                                 continue; // move along to next trace
 123                         }
 124                         else
 125                         {
 126                                 delete(this);
 127                                 return;
 128                         }
 129                 }
 130         }
 131
 132         if(time >= this.cnt + meleetime)
 133         {
 134                 // melee is finished
 135                 delete(this);
 136                 return;
 137         }
 138         else
 139         {
 140                 // set up next frame
 141                 this.swing_prev = i;
 142                 this.nextthink = time;
 143         }
 144 }
 145
 146 void W_Shotgun_Attack2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 147 {
 148         sound(actor, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTEN_NORM);
 149         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(shotgun, animtime), w_ready);
 150
 151         entity meleetemp = new_pure(meleetemp);
 152         meleetemp.realowner = actor;
 153         setthink(meleetemp, W_Shotgun_Melee_Think);
 154         meleetemp.nextthink = time + WEP_CVAR_SEC(shotgun, melee_delay) * W_WeaponRateFactor(actor);
 155         meleetemp.weaponentity_fld = weaponentity;
 156         W_SetupShot_Range(actor, weaponentity, true, 0, SND_Null, 0, WEP_CVAR_SEC(shotgun, damage), WEP_CVAR_SEC(shotgun, melee_range), WEP_SHOTGUN.m_id | HITTYPE_SECONDARY);
 157 }
 158
 159 // alternate secondary weapon frames
 160 void W_Shotgun_Attack3_Frame2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 161 {
 162         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 163         if (!(actor.items & IT_UNLIMITED_AMMO))
 164         {
 165                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 166                 w_ready(thiswep, actor, weaponentity, fire);
 167                 return;
 168         }
 169
 170         sound(actor, CH_WEAPON_SINGLE, SND_Null, VOL_BASE, ATTN_NORM); // kill previous sound
 171         W_Shotgun_Attack(thiswep, actor, weaponentity, true,
 172                 WEP_CVAR_PRI(shotgun, ammo),
 173                 WEP_CVAR_PRI(shotgun, damage),
 174                 WEP_CVAR_PRI(shotgun, bullets),
 175                 WEP_CVAR_PRI(shotgun, spread),
 176                 WEP_CVAR_PRI(shotgun, solidpenetration),
 177                 WEP_CVAR_PRI(shotgun, force),
 178                 EFFECT_BULLET_WEAK); // actually is secondary, but we trick the last shot into playing full reload sound
 179         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), w_ready);
 180 }
 181 void W_Shotgun_Attack3_Frame1(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 182 {
 183         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 184         if (!(actor.items & IT_UNLIMITED_AMMO))
 185         {
 186                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 187                 w_ready(thiswep, actor, weaponentity, fire);
 188                 return;
 189         }
 190
 191         W_Shotgun_Attack(thiswep, actor, weaponentity, false,
 192                 WEP_CVAR_PRI(shotgun, ammo),
 193                 WEP_CVAR_PRI(shotgun, damage),
 194                 WEP_CVAR_PRI(shotgun, bullets),
 195                 WEP_CVAR_PRI(shotgun, spread),
 196                 WEP_CVAR_PRI(shotgun, solidpenetration),
 197                 WEP_CVAR_PRI(shotgun, force),
 198                 EFFECT_BULLET_WEAK);
 199         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame2);
 200 }
 201
 202 .float shotgun_primarytime;
 203
 204 METHOD(Shotgun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 205 {
 206     if(vdist(actor.origin - actor.enemy.origin, <=, WEP_CVAR_SEC(shotgun, melee_range)))
 207         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
 208     else
 209         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
 210 }
 211
 212 METHOD(Shotgun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 213 {
 214     if(WEP_CVAR(shotgun, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(shotgun, ammo)) // forced reload
 215     {
 216         // don't force reload an empty shotgun if its melee attack is active
 217         if(WEP_CVAR(shotgun, secondary) < 2) {
 218             thiswep.wr_reload(thiswep, actor, weaponentity);
 219         }
 220     }
 221     else
 222     {
 223         if(fire & 1)
 224         {
 225             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 226             {
 227                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(shotgun, animtime)))
 228                 {
 229                     W_Shotgun_Attack(thiswep, actor, weaponentity, true,
 230                                                 WEP_CVAR_PRI(shotgun, ammo),
 231                                                 WEP_CVAR_PRI(shotgun, damage),
 232                                                 WEP_CVAR_PRI(shotgun, bullets),
 233                                                 WEP_CVAR_PRI(shotgun, spread),
 234                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 235                                                 WEP_CVAR_PRI(shotgun, force),
 236                                                 EFFECT_BULLET_WEAK);
 237                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_PRI(shotgun, refire) * W_WeaponRateFactor(actor);
 238                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(shotgun, animtime), w_ready);
 239                 }
 240             }
 241         }
 242         else if((fire & 2) && WEP_CVAR(shotgun, secondary) == 2)
 243         {
 244             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 245             {
 246                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(shotgun, alt_animtime)))
 247                 {
 248                     W_Shotgun_Attack(thiswep, actor, weaponentity, false,
 249                                                 WEP_CVAR_PRI(shotgun, ammo),
 250                                                 WEP_CVAR_PRI(shotgun, damage),
 251                                                 WEP_CVAR_PRI(shotgun, bullets),
 252                                                 WEP_CVAR_PRI(shotgun, spread),
 253                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 254                                                 WEP_CVAR_PRI(shotgun, force),
 255                                                 EFFECT_BULLET_WEAK);
 256                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_SEC(shotgun, alt_refire) * W_WeaponRateFactor(actor);
 257                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame1);
 258                 }
 259             }
 260         }
 261     }
 262     if(actor.(weaponentity).clip_load >= 0) // we are not currently reloading
 263     if(WEP_CVAR(shotgun, secondary) == 1)
 264     if(((fire & 1) && GetResource(actor, thiswep.ammo_type) <= 0 && !(actor.items & IT_UNLIMITED_AMMO)) || (fire & 2))
 265     if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(shotgun, refire)))
 266     {
 267         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 268         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 269     }
 270 }
 271 METHOD(Shotgun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 272 {
 273     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 274     ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 275     return ammo_amount;
 276 }
 277 METHOD(Shotgun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 278 {
 279     if(IS_BOT_CLIENT(actor))
 280     if(vdist(actor.origin - actor.enemy.origin, >, WEP_CVAR_SEC(shotgun, melee_range)))
 281         return false; // bots cannot use secondary out of range (fixes constant melee when out of ammo)
 282     switch(WEP_CVAR(shotgun, secondary))
 283     {
 284         case 1: return true; // melee does not use ammo
 285         case 2: // secondary triple shot
 286         {
 287             float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 288             ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 289             return ammo_amount;
 290         }
 291         default: return false; // secondary unavailable
 292     }
 293 }
 294 METHOD(Shotgun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 295 {
 296     W_Reload(actor, weaponentity, WEP_CVAR_PRI(shotgun, ammo), SND_RELOAD); // WEAPONTODO
 297 }
 298 METHOD(Shotgun, wr_suicidemessage, Notification(entity thiswep))
 299 {
 300     return WEAPON_THINKING_WITH_PORTALS;
 301 }
 302 METHOD(Shotgun, wr_killmessage, Notification(entity thiswep))
 303 {
 304     if(w_deathtype & HITTYPE_SECONDARY)
 305         return WEAPON_SHOTGUN_MURDER_SLAP;
 306     else
 307         return WEAPON_SHOTGUN_MURDER;
 308 }
 309
 310 #endif
 311 #ifdef CSQC
 312 .float prevric;
 313
 314 METHOD(Shotgun, wr_impacteffect, void(entity thiswep, entity actor))
 315 {
 316     vector org2 = w_org + w_backoff * 2;
 317     pointparticles(EFFECT_SHOTGUN_IMPACT, org2, w_backoff * 1000, 1);
 318     if(!w_issilent && time - actor.prevric > 0.25)
 319     {
 320         if(w_random < 0.05)
 321             sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 322         actor.prevric = time;
 323     }
 324 }
 325
 326 #endif