qcsrc/common/weapons/weapon/seeker.qc

   1 #include "seeker.qh"
   2
   3 #ifdef SVQC
   4
   5 METHOD(Seeker, m_spawnfunc_hookreplace, Weapon(Seeker this, entity e))
   6 {
   7     if (autocvar_sv_nexuizcompat_weaponswap && !Item_IsLoot(e) && (this.spawnflags & WEP_FLAG_MUTATORBLOCKED))
   8     {
   9         return ITEM_HealthBig;
  10     }
  11     return this;
  12 }
  13
  14 // ============================
  15 // Begin: Missile functions, these are general functions to be manipulated by other code
  16 // ============================
  17 void W_Seeker_Missile_Explode(entity this, entity directhitentity)
  18 {
  19         this.event_damage = func_null;
  20         RadiusDamage(this, this.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), NULL, NULL, WEP_CVAR(seeker, missile_force), this.projectiledeathtype, this.weaponentity_fld, directhitentity);
  21
  22         delete(this);
  23 }
  24
  25 void W_Seeker_Missile_Explode_think(entity this)
  26 {
  27         W_Seeker_Missile_Explode(this, NULL);
  28 }
  29
  30 void W_Seeker_Missile_Touch(entity this, entity toucher)
  31 {
  32         PROJECTILE_TOUCH(this, toucher);
  33
  34         W_Seeker_Missile_Explode(this, toucher);
  35 }
  36
  37 void W_Seeker_Missile_Think(entity this)
  38 {
  39         entity e;
  40         vector desireddir, olddir, newdir, eorg;
  41         float turnrate;
  42         float dist;
  43         float spd;
  44
  45         if(time > this.cnt)
  46         {
  47                 this.projectiledeathtype |= HITTYPE_SPLASH;
  48                 W_Seeker_Missile_Explode(this, NULL);
  49         }
  50
  51         spd = vlen(this.velocity);
  52         spd = bound(
  53                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
  54                 WEP_CVAR(seeker, missile_speed_max),
  55                 spd + WEP_CVAR(seeker, missile_accel) * frametime
  56         );
  57
  58         if(this.enemy != NULL)
  59                 if(this.enemy.takedamage != DAMAGE_AIM || IS_DEAD(this.enemy))
  60                         this.enemy = NULL;
  61
  62         if(this.enemy != NULL)
  63         {
  64                 e               = this.enemy;
  65                 eorg            = 0.5 * (e.absmin + e.absmax);
  66                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
  67                 desireddir      = normalize(eorg - this.origin);
  68                 olddir          = normalize(this.velocity); // get my current direction
  69                 dist            = vlen(eorg - this.origin);
  70
  71                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
  72                 if(WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
  73                 {
  74                         // Is it a better idea (shorter distance) to trace to the target itself?
  75                         if( vdist(this.origin + olddir * this.wait, <, dist))
  76                                 traceline(this.origin, this.origin + olddir * this.wait, false, this);
  77                         else
  78                                 traceline(this.origin, eorg, false, this);
  79
  80                         // Setup adaptive tracelength
  81                         this.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(this.origin - trace_endpos), this.wait = WEP_CVAR(seeker, missile_smart_trace_max));
  82
  83                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
  84                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
  85                 }
  86
  87                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
  88                 this.velocity = newdir * spd; // make me fly in the new direction at my flight speed
  89         }
  90         else
  91                 dist = 0;
  92
  93         // Proxy
  94         if(WEP_CVAR(seeker, missile_proxy))
  95         {
  96                 if(dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
  97                 {
  98                         if(this.autoswitch == 0)
  99                         {
 100                                 this.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 101                         }
 102                         else
 103                         {
 104                                 if(this.autoswitch <= time)
 105                                 {
 106                                         W_Seeker_Missile_Explode(this, NULL);
 107                                         this.autoswitch = 0;
 108                                 }
 109                         }
 110                 }
 111                 else
 112                 {
 113                         if(this.autoswitch != 0)
 114                                 this.autoswitch = 0;
 115                 }
 116         }
 117         ///////////////
 118
 119         if(IS_DEAD(this.enemy))
 120         {
 121                 this.enemy = NULL;
 122                 this.cnt = time + 1 + (random() * 4);
 123                 this.nextthink = this.cnt;
 124                 return;
 125         }
 126
 127         //this.angles = vectoangles(this.velocity);                     // turn model in the new flight direction
 128         this.nextthink = time;// + 0.05; // csqc projectiles
 129         UpdateCSQCProjectile(this);
 130 }
 131
 132
 133
 134 void W_Seeker_Missile_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 135 {
 136         if(GetResource(this, RES_HEALTH) <= 0)
 137                 return;
 138
 139         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 140                 return; // g_projectiles_damage says to halt
 141
 142         if(this.realowner == attacker)
 143                 TakeResource(this, RES_HEALTH, (damage * 0.25));
 144         else
 145                 TakeResource(this, RES_HEALTH, damage);
 146
 147         if(GetResource(this, RES_HEALTH) <= 0)
 148                 W_PrepareExplosionByDamage(this, attacker, W_Seeker_Missile_Explode_think);
 149 }
 150
 151 /*
 152 void W_Seeker_Missile_Animate(entity this)
 153 {
 154         this.frame = this.frame +1;
 155         this.nextthink = time + 0.05;
 156
 157         if(this.enemy != NULL)
 158                 if(this.enemy.takedamage != DAMAGE_AIM || IS_DEAD(this.enemy))
 159                         this.enemy = NULL;
 160
 161         if(this.frame == 5)
 162         {
 163                 this.think           = W_Seeker_Missile_Think;
 164                 this.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 165
 166                 if(autocvar_g_balance_seeker_missile_proxy)
 167                         this.move_movetype    = MOVETYPE_BOUNCEMISSILE;
 168                 else
 169                         this.move_movetype    = MOVETYPE_FLYMISSILE;
 170         }
 171
 172         UpdateCSQCProjectile(this);
 173 }
 174 */
 175
 176 void W_Seeker_Fire_Missile(Weapon thiswep, entity actor, .entity weaponentity, vector f_diff, entity m_target)
 177 {
 178         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, missile_ammo), weaponentity);
 179
 180         makevectors(actor.v_angle);
 181         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_SEEKER_FIRE, CH_WEAPON_A, 0, ((m_target != NULL) ? thiswep.m_id | HITTYPE_SECONDARY : thiswep.m_id));
 182         w_shotorg += f_diff;
 183         Send_Effect(EFFECT_SEEKER_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 184
 185         //actor.detornator         = false;
 186
 187         entity missile                 = new(seeker_missile);
 188         missile.owner           = missile.realowner = actor;
 189         missile.bot_dodge       = true;
 190         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 191
 192         setthink(missile, W_Seeker_Missile_Think);
 193         settouch(missile, W_Seeker_Missile_Touch);
 194         missile.event_damage    = W_Seeker_Missile_Damage;
 195         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 196         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 197         missile.enemy           = m_target;
 198         missile.solid           = SOLID_BBOX;
 199         missile.scale           = 2;
 200         missile.takedamage      = DAMAGE_YES;
 201         missile.weaponentity_fld = weaponentity;
 202         SetResourceExplicit(missile, RES_HEALTH, WEP_CVAR(seeker, missile_health));
 203         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 204         missile.damagedbycontents = true;
 205         IL_PUSH(g_damagedbycontents, missile);
 206         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
 207
 208         if(missile.enemy != NULL)
 209                 missile.projectiledeathtype = thiswep.m_id | HITTYPE_SECONDARY;
 210         else
 211                 missile.projectiledeathtype = thiswep.m_id;
 212
 213
 214         setorigin(missile, w_shotorg);
 215         setsize(missile, '-4 -4 -4', '4 4 4');
 216         set_movetype(missile, MOVETYPE_FLYMISSILE);
 217         missile.flags = FL_PROJECTILE;
 218         IL_PUSH(g_projectiles, missile);
 219         IL_PUSH(g_bot_dodge, missile);
 220         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 221
 222         W_SetupProjVelocity_UP_PRE(missile, seeker, missile_);
 223
 224         missile.angles = vectoangles(missile.velocity);
 225
 226         CSQCProjectile(missile, false, PROJECTILE_SEEKER, true);
 227
 228         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 229 }
 230
 231 // ============================
 232 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 233 // ============================
 234 void W_Seeker_Flac_Explode(entity this, entity directhitentity)
 235 {
 236         this.event_damage = func_null;
 237
 238         RadiusDamage(this, this.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), NULL, NULL, WEP_CVAR(seeker, flac_force), this.projectiledeathtype, this.weaponentity_fld, directhitentity);
 239
 240         delete(this);
 241 }
 242
 243 void W_Seeker_Flac_Touch(entity this, entity toucher)
 244 {
 245         W_Seeker_Flac_Explode(this, toucher);
 246 }
 247
 248 void W_Seeker_Flac_Explode_use(entity this, entity actor, entity trigger)
 249 {
 250         W_Seeker_Flac_Explode(this, trigger);
 251 }
 252
 253 void W_Seeker_Fire_Flac(Weapon thiswep, entity actor, .entity weaponentity)
 254 {
 255         entity missile;
 256         vector f_diff;
 257         float c;
 258
 259         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, flac_ammo), weaponentity);
 260
 261         c = actor.(weaponentity).bulletcounter % 4;
 262         switch(c)
 263         {
 264                 case 0:
 265                         f_diff = '-1.25 -3.75 0';
 266                         break;
 267                 case 1:
 268                         f_diff = '+1.25 -3.75 0';
 269                         break;
 270                 case 2:
 271                         f_diff = '-1.25 +3.75 0';
 272                         break;
 273                 case 3:
 274                 default:
 275                         f_diff = '+1.25 +3.75 0';
 276                         break;
 277         }
 278         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_FLAC_FIRE, CH_WEAPON_A, WEP_CVAR(seeker, flac_damage), thiswep.m_id | HITTYPE_SECONDARY);
 279         w_shotorg += f_diff;
 280
 281         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 282
 283         missile                                 = new(missile);
 284         missile.owner                   = missile.realowner = actor;
 285         missile.bot_dodge               = true;
 286         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 287         settouch(missile, W_Seeker_Flac_Touch);
 288         missile.use                     = W_Seeker_Flac_Explode_use;
 289         setthink(missile, adaptor_think2use_hittype_splash);
 290         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 291         missile.solid                   = SOLID_BBOX;
 292         set_movetype(missile, MOVETYPE_FLY);
 293         missile.projectiledeathtype = thiswep.m_id | HITTYPE_SECONDARY;
 294         missile.weaponentity_fld = weaponentity;
 295         missile.flags = FL_PROJECTILE;
 296         IL_PUSH(g_projectiles, missile);
 297         IL_PUSH(g_bot_dodge, missile);
 298         missile.missile_flags       = MIF_SPLASH;
 299
 300         // csqc projectiles
 301         //missile.angles                                = vectoangles(missile.velocity);
 302         //missile.scale = 0.4; // BUG: the model is too big
 303
 304         setorigin(missile, w_shotorg);
 305         setsize(missile, '-2 -2 -2', '2 2 2');
 306
 307         W_SetupProjVelocity_UP_PRE(missile, seeker, flac_);
 308         CSQCProjectile(missile, true, PROJECTILE_FLAC, true);
 309
 310         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 311 }
 312
 313 // ============================
 314 // Begin: Tag and rocket controllers
 315 // ============================
 316 entity W_Seeker_Tagged_Info(entity isowner, .entity weaponentity, entity istarget)
 317 {
 318         IL_EACH(g_seeker_trackers, it.classname == "tag_tracker" && it.realowner == isowner,
 319         {
 320                 if(it.tag_target == istarget && it.weaponentity_fld == weaponentity)
 321                         return it;
 322         });
 323
 324         return NULL;
 325 }
 326
 327 void W_Seeker_Attack(Weapon thiswep, entity actor, .entity weaponentity)
 328 {
 329         entity closest_target = NULL;
 330
 331         IL_EACH(g_seeker_trackers, it.classname == "tag_tracker" && it.realowner == actor,
 332         {
 333                 if(closest_target)
 334                 {
 335                         if(vlen2(actor.origin - it.tag_target.origin) < vlen2(actor.origin - closest_target.origin))
 336                                 closest_target = it.tag_target;
 337                 }
 338                 else
 339                         closest_target = it.tag_target;
 340         });
 341
 342         if(closest_target)
 343         {
 344                 traceline(actor.origin + actor.view_ofs, closest_target.origin, MOVE_NOMONSTERS, actor);
 345                 if(!closest_target || (trace_fraction < 1 && trace_ent != closest_target))
 346                         closest_target = NULL;
 347         }
 348
 349         W_Seeker_Fire_Missile(thiswep, actor, weaponentity, '0 0 0', closest_target);
 350 }
 351
 352 void W_Seeker_Vollycontroller_Think(entity this) // TODO: Merge this with W_Seeker_Attack
 353 {
 354         this.cnt = this.cnt - 1;
 355
 356         Weapon thiswep = WEP_SEEKER;
 357         .entity weaponentity = this.weaponentity_fld;
 358         if((!(this.realowner.items & IT_UNLIMITED_AMMO) && GetResource(this.realowner, thiswep.ammo_type) < WEP_CVAR(seeker, missile_ammo)) || (this.cnt <= -1) || (IS_DEAD(this.realowner)) || (this.realowner.(weaponentity).m_switchweapon != thiswep))
 359         {
 360                 delete(this);
 361                 return;
 362         }
 363
 364         this.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor(this.realowner);
 365
 366         entity own = this.realowner;
 367
 368         entity oldenemy = own.enemy;
 369         own.enemy = this.enemy;
 370
 371         switch(own.cnt % 4)
 372         {
 373                 case 0:
 374                         W_Seeker_Fire_Missile(thiswep, own, weaponentity, '-1.25 -3.75 0', own.enemy); // TODO
 375                         break;
 376                 case 1:
 377                         W_Seeker_Fire_Missile(thiswep, own, weaponentity, '+1.25 -3.75 0', own.enemy); // TODO
 378                         break;
 379                 case 2:
 380                         W_Seeker_Fire_Missile(thiswep, own, weaponentity, '-1.25 +3.75 0', own.enemy); // TODO
 381                         break;
 382                 case 3:
 383                 default:
 384                         W_Seeker_Fire_Missile(thiswep, own, weaponentity, '+1.25 +3.75 0', own.enemy); // TODO
 385                         break;
 386         }
 387
 388         own.enemy = oldenemy;
 389 }
 390
 391 void W_Seeker_Tracker_Think(entity this)
 392 {
 393         .entity weaponentity = this.weaponentity_fld;
 394         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 395         if((IS_DEAD(this.realowner)) || (IS_DEAD(this.tag_target)) || (this.realowner.(weaponentity).m_switchweapon != WEP_SEEKER)
 396         || (time > this.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 397         {
 398                 if(this)
 399                 {
 400                         WaypointSprite_Kill(this.tag_target.wps_tag_tracker);
 401                         delete(this);
 402                 }
 403                 return;
 404         }
 405
 406         // Update the think method information
 407         this.nextthink = time;
 408 }
 409
 410 // ============================
 411 // Begin: Tag projectile
 412 // ============================
 413 void W_Seeker_Tag_Explode(entity this)
 414 {
 415         //if(other==this.realowner)
 416         //    return;
 417         Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE, 0, this);
 418
 419         delete(this);
 420 }
 421
 422 void W_Seeker_Tag_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 423 {
 424         if(GetResource(this, RES_HEALTH) <= 0)
 425                 return;
 426         TakeResource(this, RES_HEALTH, damage);
 427         if(GetResource(this, RES_HEALTH) <= 0)
 428                 W_Seeker_Tag_Explode(this);
 429 }
 430
 431 void W_Seeker_Tag_Touch(entity this, entity toucher)
 432 {
 433         vector dir;
 434         vector org2;
 435         entity e;
 436
 437         PROJECTILE_TOUCH(this, toucher);
 438
 439         dir     = normalize(this.realowner.origin - this.origin);
 440         org2    = findbetterlocation(this.origin, 8);
 441
 442         te_knightspike(org2);
 443
 444         this.event_damage = func_null;
 445         Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE | HITTYPE_SECONDARY, toucher.species, this);
 446
 447         if(toucher.takedamage == DAMAGE_AIM && !IS_DEAD(toucher))
 448         {
 449                 // check to see if this person is already tagged by me
 450                 .entity weaponentity = this.weaponentity_fld;
 451                 entity tag = W_Seeker_Tagged_Info(this.realowner, weaponentity, toucher);
 452
 453                 if(tag != NULL)
 454                 {
 455                         if(toucher.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 456                                 WaypointSprite_Kill(toucher.wps_tag_tracker);
 457
 458                         tag.tag_time = time;
 459                 }
 460                 else
 461                 {
 462                         //sprint(this.realowner, strcat("You just tagged ^2", toucher.netname, "^7 with a tracking device!\n"));
 463                         e             = new(tag_tracker);
 464                         e.weaponentity_fld = this.weaponentity_fld;
 465                         e.cnt         = WEP_CVAR(seeker, missile_count);
 466                         e.owner       = this.owner;
 467                         e.realowner   = this.realowner;
 468                         IL_PUSH(g_seeker_trackers, e);
 469
 470                         if(WEP_CVAR(seeker, type) == 1)
 471                         {
 472                                 e.tag_target  = toucher;
 473                                 e.tag_time    = time;
 474                                 setthink(e, W_Seeker_Tracker_Think);
 475                         }
 476                         else
 477                         {
 478                                 e.enemy     = toucher;
 479                                 setthink(e, W_Seeker_Vollycontroller_Think);
 480                         }
 481
 482                         e.nextthink   = time;
 483                 }
 484
 485                 if(WEP_CVAR(seeker, type) == 1)
 486                 {
 487                         WaypointSprite_Spawn(WP_Seeker, WEP_CVAR(seeker, tag_tracker_lifetime), 0, toucher, '0 0 64', this.realowner, 0, toucher, wps_tag_tracker, true, RADARICON_TAGGED);
 488                         WaypointSprite_UpdateRule(toucher.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 489                 }
 490         }
 491
 492         delete(this);
 493         return;
 494 }
 495
 496 void W_Seeker_Fire_Tag(Weapon thiswep, entity actor, .entity weaponentity)
 497 {
 498         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, tag_ammo), weaponentity);
 499
 500         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_TAG_FIRE, CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count), thiswep.m_id | HITTYPE_BOUNCE | HITTYPE_SECONDARY);
 501
 502         entity missile          = new(seeker_tag);
 503         missile.weaponentity_fld = weaponentity;
 504         missile.owner           = missile.realowner = actor;
 505         missile.bot_dodge       = true;
 506         missile.bot_dodgerating = 50;
 507         settouch(missile, W_Seeker_Tag_Touch);
 508         setthink(missile, SUB_Remove);
 509         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 510         set_movetype(missile, MOVETYPE_FLY);
 511         missile.solid           = SOLID_BBOX;
 512
 513         missile.takedamage       = DAMAGE_YES;
 514         missile.event_damage     = W_Seeker_Tag_Damage;
 515         SetResourceExplicit(missile, RES_HEALTH, WEP_CVAR(seeker, tag_health));
 516         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 517
 518         setorigin(missile, w_shotorg);
 519         setsize(missile, '-2 -2 -2', '2 2 2');
 520
 521         missile.flags = FL_PROJECTILE;
 522         IL_PUSH(g_projectiles, missile);
 523         IL_PUSH(g_bot_dodge, missile);
 524         //missile.missile_flags = MIF_..?;
 525
 526         set_movetype(missile, MOVETYPE_FLY);
 527         W_SetupProjVelocity_PRE(missile, seeker, tag_);
 528         missile.angles = vectoangles(missile.velocity);
 529
 530         CSQCProjectile(missile, true, PROJECTILE_TAG, false); // has sound
 531
 532         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 533 }
 534
 535 // ============================
 536 // Begin: Genereal weapon functions
 537 // ============================
 538
 539 METHOD(Seeker, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 540 {
 541     if(WEP_CVAR(seeker, type) == 1)
 542     {
 543         if(W_Seeker_Tagged_Info(actor, weaponentity, actor.enemy) != NULL)
 544             PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), false);
 545         else
 546             PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 547     }
 548     else
 549         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 550 }
 551 METHOD(Seeker, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 552 {
 553     if(autocvar_g_balance_seeker_reload_ammo && actor.(weaponentity).clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) { // forced reload
 554         thiswep.wr_reload(thiswep, actor, weaponentity);
 555     } else if(fire & 1)
 556     {
 557         if(WEP_CVAR(seeker, type) == 1)
 558         {
 559             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, missile_refire)))
 560             {
 561                 W_Seeker_Attack(thiswep, actor, weaponentity);
 562                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 563             }
 564         }
 565         else
 566         {
 567             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 568             {
 569                 W_Seeker_Fire_Tag(thiswep, actor, weaponentity);
 570                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 571             }
 572         }
 573     }
 574
 575     else if(fire & 2)
 576     {
 577         if(WEP_CVAR(seeker, type) == 1)
 578         {
 579             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 580             {
 581                 W_Seeker_Fire_Tag(thiswep, actor, weaponentity);
 582                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 583             }
 584         }
 585         else
 586         {
 587             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, flac_refire)))
 588             {
 589                 W_Seeker_Fire_Flac(thiswep, actor, weaponentity);
 590                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 591             }
 592         }
 593     }
 594 }
 595 METHOD(Seeker, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 596 {
 597     float ammo_amount;
 598     if(WEP_CVAR(seeker, type) == 1)
 599     {
 600         ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR(seeker, missile_ammo);
 601         ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR(seeker, missile_ammo);
 602     }
 603     else
 604     {
 605         ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR(seeker, tag_ammo);
 606         ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 607     }
 608     return ammo_amount;
 609 }
 610 METHOD(Seeker, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 611 {
 612     float ammo_amount;
 613     if(WEP_CVAR(seeker, type) == 1)
 614     {
 615         ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR(seeker, tag_ammo);
 616         ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 617     }
 618     else
 619     {
 620         ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR(seeker, flac_ammo);
 621         ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR(seeker, flac_ammo);
 622     }
 623     return ammo_amount;
 624 }
 625 METHOD(Seeker, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 626 {
 627     W_Reload(actor, weaponentity, min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), SND_RELOAD);
 628 }
 629 METHOD(Seeker, wr_suicidemessage, Notification(entity thiswep))
 630 {
 631     return WEAPON_SEEKER_SUICIDE;
 632 }
 633 METHOD(Seeker, wr_killmessage, Notification(entity thiswep))
 634 {
 635     if(w_deathtype & HITTYPE_SECONDARY)
 636         return WEAPON_SEEKER_MURDER_TAG;
 637     else
 638         return WEAPON_SEEKER_MURDER_SPRAY;
 639 }
 640
 641 #endif
 642 #ifdef CSQC
 643
 644 METHOD(Seeker, wr_impacteffect, void(entity thiswep, entity actor))
 645 {
 646     vector org2;
 647     org2 = w_org + w_backoff * 6;
 648     if(w_deathtype & HITTYPE_BOUNCE)
 649     {
 650         if(w_deathtype & HITTYPE_SECONDARY)
 651         {
 652             if(!w_issilent)
 653                 sound(actor, CH_SHOTS, SND_TAG_IMPACT, 1, ATTEN_NORM);
 654         }
 655         else
 656         {
 657             pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 658             if(!w_issilent)
 659             {
 660                 if(w_random<0.15)
 661                     sound(actor, CH_SHOTS, SND_TAGEXP1, 1, ATTEN_NORM);
 662                 else if(w_random<0.7)
 663                     sound(actor, CH_SHOTS, SND_TAGEXP2, 1, ATTEN_NORM);
 664                 else
 665                     sound(actor, CH_SHOTS, SND_TAGEXP3, 1, ATTEN_NORM);
 666             }
 667         }
 668     }
 669     else
 670     {
 671         pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 672         if(!w_issilent)
 673         {
 674             if(w_random<0.15)
 675                 sound(actor, CH_SHOTS, SND_SEEKEREXP1, 1, ATTEN_NORM);
 676             else if(w_random<0.7)
 677                 sound(actor, CH_SHOTS, SND_SEEKEREXP2, 1, ATTEN_NORM);
 678             else
 679                 sound(actor, CH_SHOTS, SND_SEEKEREXP3, 1, ATTEN_NORM);
 680         }
 681     }
 682 }
 683
 684 #endif