qcsrc/common/weapons/weapon/hook.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Hook, Weapon)
   3 /* ammotype  */ ATTRIB(Hook, ammo_field, .int, ammo_fuel)
   4 /* impulse   */ ATTRIB(Hook, impulse, int, 0)
   5 /* flags     */ ATTRIB(Hook, spawnflags, int, WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
   6 /* rating    */ ATTRIB(Hook, bot_pickupbasevalue, float, 0);
   7 /* color     */ ATTRIB(Hook, wpcolor, vector, '0 0.5 0');
   8 /* modelname */ ATTRIB(Hook, mdl, string, "hookgun");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Hook, m_model, Model, MDL_HOOK_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Hook, w_crosshair, string, "gfx/crosshairhook");
  13 /* crosshair */ ATTRIB(Hook, w_crosshair_size, float, 0.5);
  14 /* wepimg    */ ATTRIB(Hook, model2, string, "weaponhook");
  15 /* refname   */ ATTRIB(Hook, netname, string, "hook");
  16 /* wepname   */ ATTRIB(Hook, m_name, string, _("Grappling Hook"));
  17         ATTRIB(Hook, ammo_factor, float, 1)
  18
  19 #define X(BEGIN, P, END, class, prefix) \
  20         BEGIN(class) \
  21                 P(class, prefix, ammo, float, PRI) \
  22                 P(class, prefix, animtime, float, BOTH) \
  23                 P(class, prefix, damageforcescale, float, SEC) \
  24                 P(class, prefix, damage, float, SEC) \
  25                 P(class, prefix, duration, float, SEC) \
  26                 P(class, prefix, edgedamage, float, SEC) \
  27                 P(class, prefix, force, float, SEC) \
  28                 P(class, prefix, gravity, float, SEC) \
  29                 P(class, prefix, health, float, SEC) \
  30                 P(class, prefix, hooked_ammo, float, PRI) \
  31                 P(class, prefix, hooked_time_free, float, PRI) \
  32                 P(class, prefix, hooked_time_max, float, PRI) \
  33                 P(class, prefix, lifetime, float, SEC) \
  34                 P(class, prefix, power, float, SEC) \
  35                 P(class, prefix, radius, float, SEC) \
  36                 P(class, prefix, refire, float, BOTH) \
  37                 P(class, prefix, speed, float, SEC) \
  38         P(class, prefix, switchdelay_drop, float, NONE) \
  39                 P(class, prefix, switchdelay_raise, float, NONE) \
  40         P(class, prefix, weaponreplace, string, NONE) \
  41         P(class, prefix, weaponstartoverride, float, NONE) \
  42         P(class, prefix, weaponstart, float, NONE) \
  43         P(class, prefix, weaponthrowable, float, NONE) \
  44         END()
  45     W_PROPS(X, Hook, hook)
  46 #undef X
  47
  48 ENDCLASS(Hook)
  49 REGISTER_WEAPON(HOOK, hook, NEW(Hook));
  50
  51 CLASS(OffhandHook, OffhandWeapon)
  52 #ifdef SVQC
  53     METHOD(OffhandHook, offhand_think, void(OffhandHook this, entity actor, bool key_pressed))
  54     {
  55         Weapon wep = WEP_HOOK;
  56         .entity weaponentity = weaponentities[1];
  57         wep.wr_think(wep, actor, weaponentity, key_pressed ? 1 : 0);
  58     }
  59 #endif
  60 ENDCLASS(OffhandHook)
  61 OffhandHook OFFHAND_HOOK; STATIC_INIT(OFFHAND_HOOK) { OFFHAND_HOOK = NEW(OffhandHook); }
  62
  63 #ifdef SVQC
  64
  65 .float dmg;
  66 .float dmg_edge;
  67 .float dmg_radius;
  68 .float dmg_force;
  69 .float dmg_power;
  70 .float dmg_duration;
  71 .float dmg_last;
  72 .float hook_refire;
  73 .float hook_time_hooked;
  74 .float hook_time_fueldecrease;
  75 #endif
  76 #endif
  77 #ifdef IMPLEMENTATION
  78 #ifdef SVQC
  79
  80 spawnfunc(weapon_hook) { weapon_defaultspawnfunc(this, WEP_HOOK); }
  81
  82 void W_Hook_ExplodeThink()
  83 {SELFPARAM();
  84         float dt, dmg_remaining_next, f;
  85
  86         dt = time - self.teleport_time;
  87         dmg_remaining_next = pow(bound(0, 1 - dt / self.dmg_duration, 1), self.dmg_power);
  88
  89         f = self.dmg_last - dmg_remaining_next;
  90         self.dmg_last = dmg_remaining_next;
  91
  92         RadiusDamage(self, self.realowner, self.dmg * f, self.dmg_edge * f, self.dmg_radius, self.realowner, world, self.dmg_force * f, self.projectiledeathtype, world);
  93         self.projectiledeathtype |= HITTYPE_BOUNCE;
  94         //RadiusDamage(self, world, self.dmg * f, self.dmg_edge * f, self.dmg_radius, world, world, self.dmg_force * f, self.projectiledeathtype, world);
  95
  96         if(dt < self.dmg_duration)
  97                 self.nextthink = time + 0.05; // soon
  98         else
  99                 remove(self);
 100 }
 101
 102 void W_Hook_Explode2()
 103 {SELFPARAM();
 104         self.event_damage = func_null;
 105         self.touch = func_null;
 106         self.effects |= EF_NODRAW;
 107
 108         self.think = W_Hook_ExplodeThink;
 109         self.nextthink = time;
 110         self.dmg = WEP_CVAR_SEC(hook, damage);
 111         self.dmg_edge = WEP_CVAR_SEC(hook, edgedamage);
 112         self.dmg_radius = WEP_CVAR_SEC(hook, radius);
 113         self.dmg_force = WEP_CVAR_SEC(hook, force);
 114         self.dmg_power = WEP_CVAR_SEC(hook, power);
 115         self.dmg_duration = WEP_CVAR_SEC(hook, duration);
 116         self.teleport_time = time;
 117         self.dmg_last = 1;
 118         self.movetype = MOVETYPE_NONE;
 119 }
 120
 121 void W_Hook_Explode2_use(entity this, entity actor, entity trigger)
 122 {
 123         WITHSELF(this, W_Hook_Explode2());
 124 }
 125
 126 void W_Hook_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 127 {
 128         if(this.health <= 0)
 129                 return;
 130
 131         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 132                 return; // g_projectiles_damage says to halt
 133
 134         this.health = this.health - damage;
 135
 136         if(this.health <= 0)
 137                 W_PrepareExplosionByDamage(this, this.realowner, W_Hook_Explode2);
 138 }
 139
 140 void W_Hook_Touch2()
 141 {SELFPARAM();
 142         PROJECTILE_TOUCH;
 143         this.use(this, NULL, NULL);
 144 }
 145
 146 void W_Hook_Attack2(Weapon thiswep, entity actor)
 147 {
 148         //W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(hook, ammo)); // WEAPONTODO: Figure out how to handle ammo with hook secondary (gravitybomb)
 149         W_SetupShot(actor, false, 4, SND_HOOKBOMB_FIRE, CH_WEAPON_A, WEP_CVAR_SEC(hook, damage));
 150
 151         entity gren = new(hookbomb);
 152         gren.owner = gren.realowner = actor;
 153         gren.bot_dodge = true;
 154         gren.bot_dodgerating = WEP_CVAR_SEC(hook, damage);
 155         gren.movetype = MOVETYPE_TOSS;
 156         PROJECTILE_MAKETRIGGER(gren);
 157         gren.projectiledeathtype = WEP_HOOK.m_id | HITTYPE_SECONDARY;
 158         setorigin(gren, w_shotorg);
 159         setsize(gren, '0 0 0', '0 0 0');
 160
 161         gren.nextthink = time + WEP_CVAR_SEC(hook, lifetime);
 162         gren.think = adaptor_think2use_hittype_splash;
 163         gren.use = W_Hook_Explode2_use;
 164         gren.touch = W_Hook_Touch2;
 165
 166         gren.takedamage = DAMAGE_YES;
 167         gren.health = WEP_CVAR_SEC(hook, health);
 168         gren.damageforcescale = WEP_CVAR_SEC(hook, damageforcescale);
 169         gren.event_damage = W_Hook_Damage;
 170         gren.damagedbycontents = true;
 171         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 172
 173         gren.velocity = '0 0 1' * WEP_CVAR_SEC(hook, speed);
 174         if (autocvar_g_projectiles_newton_style)
 175                 gren.velocity = gren.velocity + actor.velocity;
 176
 177         gren.gravity = WEP_CVAR_SEC(hook, gravity);
 178         //W_SetupProjVelocity_Basic(gren); // just falling down!
 179
 180         gren.angles = '0 0 0';
 181         gren.flags = FL_PROJECTILE;
 182
 183         CSQCProjectile(gren, true, PROJECTILE_HOOKBOMB, true);
 184
 185         MUTATOR_CALLHOOK(EditProjectile, actor, gren);
 186 }
 187
 188 METHOD(Hook, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 189 {
 190     SELFPARAM();
 191     if (fire & 1) {
 192         if(!actor.hook)
 193         if(!(actor.hook_state & HOOK_WAITING_FOR_RELEASE))
 194         if(time > actor.hook_refire)
 195         if(weapon_prepareattack(thiswep, actor, weaponentity, false, -1))
 196         {
 197             W_DecreaseAmmo(thiswep, actor, thiswep.ammo_factor * WEP_CVAR_PRI(hook, ammo));
 198             actor.hook_state |= HOOK_FIRING;
 199             actor.hook_state |= HOOK_WAITING_FOR_RELEASE;
 200             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(hook, animtime), w_ready);
 201         }
 202     } else {
 203         actor.hook_state |= HOOK_REMOVING;
 204         actor.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 205     }
 206
 207     if(fire & 2)
 208     {
 209         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(hook, refire)))
 210         {
 211             W_Hook_Attack2(thiswep, actor);
 212             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(hook, animtime), w_ready);
 213         }
 214     }
 215
 216     if(actor.hook)
 217     {
 218         // if hooked, no bombs, and increase the timer
 219         actor.hook_refire = max(actor.hook_refire, time + WEP_CVAR_PRI(hook, refire) * W_WeaponRateFactor());
 220
 221         // hook also inhibits health regeneration, but only for 1 second
 222         if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 223             actor.pauseregen_finished = max(actor.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
 224     }
 225
 226     if(actor.hook && actor.hook.state == 1)
 227     {
 228         float hooked_time_max = WEP_CVAR_PRI(hook, hooked_time_max);
 229         if(hooked_time_max > 0)
 230         {
 231             if( time > actor.hook_time_hooked + hooked_time_max )
 232                 actor.hook_state |= HOOK_REMOVING;
 233         }
 234
 235         float hooked_fuel = thiswep.ammo_factor * WEP_CVAR_PRI(hook, hooked_ammo);
 236         if(hooked_fuel > 0)
 237         {
 238             if( time > actor.hook_time_fueldecrease )
 239             {
 240                 if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 241                 {
 242                     if( actor.ammo_fuel >= (time - actor.hook_time_fueldecrease) * hooked_fuel )
 243                     {
 244                         W_DecreaseAmmo(thiswep, actor, (time - actor.hook_time_fueldecrease) * hooked_fuel);
 245                         actor.hook_time_fueldecrease = time;
 246                         // decrease next frame again
 247                     }
 248                     else
 249                     {
 250                         actor.ammo_fuel = 0;
 251                         actor.hook_state |= HOOK_REMOVING;
 252                         W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
 253                     }
 254                 }
 255             }
 256         }
 257     }
 258     else
 259     {
 260         actor.hook_time_hooked = time;
 261         actor.hook_time_fueldecrease = time + WEP_CVAR_PRI(hook, hooked_time_free);
 262     }
 263
 264     actor.hook_state = BITSET(actor.hook_state, HOOK_PULLING, (!PHYS_INPUT_BUTTON_CROUCH(actor) || !autocvar_g_balance_grapplehook_crouchslide));
 265
 266     if (actor.hook_state & HOOK_FIRING)
 267     {
 268         if (actor.hook)
 269             RemoveGrapplingHook(actor);
 270         WITHSELF(actor, FireGrapplingHook());
 271         actor.hook_state &= ~HOOK_FIRING;
 272         actor.hook_refire = max(actor.hook_refire, time + autocvar_g_balance_grapplehook_refire * W_WeaponRateFactor());
 273     }
 274     else if (actor.hook_state & HOOK_REMOVING)
 275     {
 276         if (actor.hook)
 277             RemoveGrapplingHook(actor);
 278         actor.hook_state &= ~HOOK_REMOVING;
 279     }
 280 }
 281 METHOD(Hook, wr_setup, void(entity thiswep))
 282 {
 283     SELFPARAM();
 284     self.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 285 }
 286 METHOD(Hook, wr_checkammo1, bool(Hook thiswep))
 287 {
 288     SELFPARAM();
 289     if (!thiswep.ammo_factor) return true;
 290     if(self.hook)
 291         return self.ammo_fuel > 0;
 292     else
 293         return self.ammo_fuel >= WEP_CVAR_PRI(hook, ammo);
 294 }
 295 METHOD(Hook, wr_checkammo2, bool(Hook thiswep))
 296 {
 297     // infinite ammo for now
 298     return true; // self.ammo_cells >= WEP_CVAR_SEC(hook, ammo); // WEAPONTODO: see above
 299 }
 300 METHOD(Hook, wr_resetplayer, void(entity thiswep))
 301 {
 302     SELFPARAM();
 303     RemoveGrapplingHook(self);
 304     self.hook_time = 0;
 305     self.hook_refire = time;
 306 }
 307 METHOD(Hook, wr_killmessage, Notification(entity thiswep))
 308 {
 309     return WEAPON_HOOK_MURDER;
 310 }
 311
 312 #endif
 313 #ifdef CSQC
 314
 315 METHOD(Hook, wr_impacteffect, void(entity thiswep))
 316 {
 317     SELFPARAM();
 318     vector org2;
 319     org2 = w_org + w_backoff * 2;
 320     pointparticles(EFFECT_HOOK_EXPLODE, org2, '0 0 0', 1);
 321     if(!w_issilent)
 322         sound(self, CH_SHOTS, SND_HOOKBOMB_IMPACT, VOL_BASE, ATTN_NORM);
 323 }
 324
 325 #endif
 326
 327 #ifdef CSQC
 328 #include <lib/csqcmodel/interpolate.qh>
 329 #include <lib/warpzone/common.qh>
 330
 331 float autocvar_cl_grapplehook_alpha = 1;
 332
 333 void Draw_CylindricLine(vector from, vector to, float thickness, string texture, float aspect, float shift, vector rgb, float theAlpha, float drawflag, vector vieworg);
 334
 335 entityclass(Hook);
 336 class(Hook) .entity HookType; // ENT_CLIENT_*
 337 class(Hook) .vector origin;
 338 class(Hook) .vector velocity;
 339 class(Hook) .float HookSilent;
 340 class(Hook) .float HookRange;
 341
 342 string Draw_GrapplingHook_trace_callback_tex;
 343 float Draw_GrapplingHook_trace_callback_rnd;
 344 vector Draw_GrapplingHook_trace_callback_rgb;
 345 float Draw_GrapplingHook_trace_callback_a;
 346 void Draw_GrapplingHook_trace_callback(vector start, vector hit, vector end)
 347 {
 348         float i;
 349         vector vorg;
 350         vorg = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 351         for(i = 0; i < Draw_GrapplingHook_trace_callback_a; ++i)
 352                 Draw_CylindricLine(hit, start, 8, Draw_GrapplingHook_trace_callback_tex, 0.25, Draw_GrapplingHook_trace_callback_rnd, Draw_GrapplingHook_trace_callback_rgb, min(1, Draw_GrapplingHook_trace_callback_a - i), DRAWFLAG_NORMAL, vorg);
 353         Draw_GrapplingHook_trace_callback_rnd += 0.25 * vlen(hit - start) / 8;
 354 }
 355
 356 class(Hook) .float teleport_time;
 357 void Draw_GrapplingHook(entity this)
 358 {
 359         vector a, b, atrans;
 360         string tex;
 361         vector rgb;
 362         float t;
 363         vector vs;
 364         float intensity, offset;
 365
 366         if(this.teleport_time)
 367         if(time > this.teleport_time)
 368         {
 369                 sound (this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM); // safeguard
 370                 this.teleport_time = 0;
 371         }
 372
 373         InterpolateOrigin_Do(this);
 374
 375         int s = W_GetGunAlignment(world);
 376
 377         switch(this.HookType)
 378         {
 379                 default:
 380                 case NET_ENT_CLIENT_HOOK:
 381                         vs = hook_shotorigin[s];
 382                         break;
 383                 case NET_ENT_CLIENT_ARC_BEAM:
 384                         vs = lightning_shotorigin[s];
 385                         break;
 386         }
 387
 388         if((this.owner.sv_entnum == player_localentnum - 1) && autocvar_chase_active <= 0)
 389         {
 390                 switch(this.HookType)
 391                 {
 392                         default:
 393                         case NET_ENT_CLIENT_HOOK:
 394                                 a = view_origin + view_forward * vs.x + view_right * -vs.y + view_up * vs.z;
 395                                 b = this.origin;
 396                                 break;
 397                         case NET_ENT_CLIENT_ARC_BEAM:
 398                                 if(this.HookRange)
 399                                         b = view_origin + view_forward * this.HookRange;
 400                                 else
 401                                         b = view_origin + view_forward * vlen(this.velocity - this.origin); // honor original length of beam!
 402                                 WarpZone_TraceLine(view_origin, b, MOVE_NORMAL, world);
 403                                 b = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 404                                 a = view_origin + view_forward * vs.x + view_right * -vs.y + view_up * vs.z;
 405                                 break;
 406                 }
 407         }
 408         else
 409         {
 410                 switch(this.HookType)
 411                 {
 412                         default:
 413                         case NET_ENT_CLIENT_HOOK:
 414                                 a = this.velocity;
 415                                 b = this.origin;
 416                                 break;
 417                         case NET_ENT_CLIENT_ARC_BEAM:
 418                                 a = this.origin;
 419                                 b = this.velocity;
 420                                 break;
 421                 }
 422         }
 423
 424         t = entcs_GetTeamColor(this.owner.sv_entnum);
 425
 426         switch(this.HookType)
 427         {
 428                 default:
 429                 case NET_ENT_CLIENT_HOOK:
 430                         intensity = autocvar_cl_grapplehook_alpha;
 431                         offset = 0;
 432                         switch(t)
 433                         {
 434                                 case NUM_TEAM_1: tex = "particles/hook_red"; rgb = '1 0.3 0.3'; break;
 435                                 case NUM_TEAM_2: tex = "particles/hook_blue"; rgb = '0.3 0.3 1'; break;
 436                                 case NUM_TEAM_3: tex = "particles/hook_yellow"; rgb = '1 1 0.3'; break;
 437                                 case NUM_TEAM_4: tex = "particles/hook_pink"; rgb = '1 0.3 1'; break;
 438                                 default: tex = "particles/hook_white"; rgb = entcs_GetColor(this.sv_entnum - 1); break;
 439                         }
 440                         break;
 441                 case NET_ENT_CLIENT_ARC_BEAM: // todo
 442                         intensity = bound(0.2, 1 + Noise_Pink(this, frametime) * 1 + Noise_Burst(this, frametime, 0.03) * 0.3, 2);
 443                         offset = Noise_Brown(this, frametime) * 10;
 444                         tex = "particles/lgbeam";
 445                         rgb = '1 1 1';
 446                         break;
 447         }
 448
 449         Draw_GrapplingHook_trace_callback_tex = tex;
 450         Draw_GrapplingHook_trace_callback_rnd = offset;
 451         Draw_GrapplingHook_trace_callback_rgb = rgb;
 452         Draw_GrapplingHook_trace_callback_a = intensity;
 453         WarpZone_TraceBox_ThroughZone(a, '0 0 0', '0 0 0', b, ((this.HookType == NET_ENT_CLIENT_HOOK) ? MOVE_NOTHING : MOVE_NORMAL), world, world, Draw_GrapplingHook_trace_callback);
 454         Draw_GrapplingHook_trace_callback_tex = string_null;
 455
 456         atrans = WarpZone_TransformOrigin(WarpZone_trace_transform, a);
 457
 458         switch(this.HookType)
 459         {
 460                 default:
 461                 case NET_ENT_CLIENT_HOOK:
 462                         if(vdist(trace_endpos - atrans, >, 0.5))
 463                         {
 464                                 setorigin(this, trace_endpos); // hook endpoint!
 465                                 this.angles = vectoangles(trace_endpos - atrans);
 466                                 this.drawmask = MASK_NORMAL;
 467                         }
 468                         else
 469                         {
 470                                 this.drawmask = 0;
 471                         }
 472                         break;
 473                 case NET_ENT_CLIENT_ARC_BEAM:
 474                         setorigin(this, a); // beam origin!
 475                         break;
 476         }
 477
 478         switch(this.HookType)
 479         {
 480                 default:
 481                 case NET_ENT_CLIENT_HOOK:
 482                         break;
 483                 case NET_ENT_CLIENT_ARC_BEAM:
 484                         pointparticles(EFFECT_ARC_LIGHTNING2, trace_endpos, normalize(atrans - trace_endpos), frametime * intensity); // todo: new effect
 485                         break;
 486         }
 487 }
 488
 489 void Remove_GrapplingHook(entity this)
 490 {
 491         sound (this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 492
 493         if(csqcplayer && csqcplayer.hook == this)
 494                 csqcplayer.hook = NULL;
 495 }
 496
 497 NET_HANDLE(ENT_CLIENT_HOOK, bool bIsNew)
 498 {
 499         self.HookType = NET_ENT_CLIENT_HOOK;
 500
 501         int sf = ReadByte();
 502
 503         self.HookSilent = (sf & 0x80);
 504         self.iflags = IFLAG_VELOCITY | IFLAG_ORIGIN;
 505
 506         InterpolateOrigin_Undo(self);
 507
 508         if(sf & 1)
 509         {
 510                 int myowner = ReadByte();
 511                 self.owner = playerslots[myowner - 1];
 512                 self.sv_entnum = myowner;
 513                 if(csqcplayer && myowner == player_localentnum)
 514                         csqcplayer.hook = self;
 515                 switch(self.HookType)
 516                 {
 517                         default:
 518                         case NET_ENT_CLIENT_HOOK:
 519                                 self.HookRange = 0;
 520                                 break;
 521                         case NET_ENT_CLIENT_ARC_BEAM:
 522                                 self.HookRange = ReadCoord();
 523                                 break;
 524                 }
 525         }
 526         if(sf & 2)
 527         {
 528                 self.origin_x = ReadCoord();
 529                 self.origin_y = ReadCoord();
 530                 self.origin_z = ReadCoord();
 531                 setorigin(self, self.origin);
 532         }
 533         if(sf & 4)
 534         {
 535                 self.velocity_x = ReadCoord();
 536                 self.velocity_y = ReadCoord();
 537                 self.velocity_z = ReadCoord();
 538         }
 539
 540         InterpolateOrigin_Note(this);
 541
 542         if(bIsNew || !self.teleport_time)
 543         {
 544                 self.draw = Draw_GrapplingHook;
 545                 self.entremove = Remove_GrapplingHook;
 546
 547                 switch(self.HookType)
 548                 {
 549                         default:
 550                         case NET_ENT_CLIENT_HOOK:
 551                                 // for the model
 552                                 setmodel(self, MDL_HOOK);
 553                                 self.drawmask = MASK_NORMAL;
 554                                 break;
 555                         case NET_ENT_CLIENT_ARC_BEAM:
 556                                 sound (self, CH_SHOTS_SINGLE, SND_LGBEAM_FLY, VOL_BASE, ATTEN_NORM);
 557                                 break;
 558                 }
 559         }
 560
 561         self.teleport_time = time + 10;
 562         return true;
 563 }
 564
 565 // TODO: hook: temporarily transform self.origin for drawing the model along warpzones!
 566 #endif
 567
 568 #endif