qcsrc/common/weapons/weapon/arc.qc

   1 #include "arc.qh"
   2
   3 #ifdef SVQC
   4 #include <common/gamemodes/gamemode/onslaught/sv_generator.qh>
   5 #include <common/gamemodes/gamemode/onslaught/sv_onslaught.qh>
   6
   7 bool W_Arc_Beam_Send(entity this, entity to, int sf)
   8 {
   9         WriteHeader(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
  10
  11         // Truncate information when this beam is displayed to the owner client
  12         // - The owner client has no use for beam start position or directions,
  13         //    it always figures this information out for itself with csqc code.
  14         // - Spectating the owner also truncates this information.
  15         float drawlocal = ((to == this.owner) || ((to.enemy == this.owner) && IS_SPEC(to)));
  16         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
  17
  18         WriteByte(MSG_ENTITY, sf);
  19         WriteByte(MSG_ENTITY, weaponslot(this.weaponentity_fld));
  20
  21         if(sf & ARC_SF_SETTINGS) // settings information
  22         {
  23                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
  24                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
  25                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
  26                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
  27                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
  28                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
  29
  30                 WriteByte(MSG_ENTITY, drawlocal);
  31                 WriteByte(MSG_ENTITY, etof(this.owner));
  32         }
  33         if(sf & ARC_SF_START) // starting location
  34         {
  35                 WriteVector(MSG_ENTITY, this.beam_start);
  36         }
  37         if(sf & ARC_SF_WANTDIR) // want/aim direction
  38         {
  39                 WriteVector(MSG_ENTITY, this.beam_wantdir);
  40         }
  41         if(sf & ARC_SF_BEAMDIR) // beam direction
  42         {
  43                 WriteAngleVector(MSG_ENTITY, this.beam_dir);
  44         }
  45         if(sf & ARC_SF_BEAMTYPE) // beam type
  46         {
  47                 WriteByte(MSG_ENTITY, this.beam_type);
  48         }
  49
  50         return true;
  51 }
  52
  53 void Reset_ArcBeam(entity player, vector forward)
  54 {
  55         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  56         {
  57                 .entity weaponentity = weaponentities[slot];
  58                 if(!player.(weaponentity).arc_beam)
  59                         continue;
  60                 player.(weaponentity).arc_beam.beam_dir = forward;
  61                 player.(weaponentity).arc_beam.beam_teleporttime = time;
  62         }
  63 }
  64
  65 float Arc_GetHeat_Percent(entity player, .entity weaponentity)
  66 {
  67         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
  68         {
  69                 player.arc_overheat = 0;
  70                 return 0;
  71         }
  72
  73         if ( player.(weaponentity).arc_beam )
  74                 return player.(weaponentity).arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
  75
  76         if ( player.arc_overheat > time )
  77         {
  78                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
  79                         * player.arc_cooldown;
  80         }
  81
  82         return 0;
  83 }
  84 void Arc_Player_SetHeat(entity player, .entity weaponentity)
  85 {
  86         player.(weaponentity).arc_heat_percent = Arc_GetHeat_Percent(player, weaponentity);
  87         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
  88 }
  89
  90 void W_Arc_Bolt_Explode(entity this, entity directhitentity)
  91 {
  92         this.event_damage = func_null;
  93         RadiusDamage(this, this.realowner, WEP_CVAR(arc, bolt_damage), WEP_CVAR(arc, bolt_edgedamage), WEP_CVAR(arc, bolt_radius), NULL, NULL, WEP_CVAR(arc, bolt_force), this.projectiledeathtype, this.weaponentity_fld, directhitentity);
  94
  95         delete(this);
  96 }
  97
  98 void W_Arc_Bolt_Explode_use(entity this, entity actor, entity trigger)
  99 {
 100         W_Arc_Bolt_Explode(this, trigger);
 101 }
 102
 103 void W_Arc_Bolt_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 104 {
 105         if(GetResource(this, RES_HEALTH) <= 0)
 106                 return;
 107
 108         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1))
 109                 return; // g_projectiles_damage says to halt
 110
 111         TakeResource(this, RES_HEALTH, damage);
 112         this.angles = vectoangles(this.velocity);
 113
 114         if(GetResource(this, RES_HEALTH) <= 0)
 115                 W_PrepareExplosionByDamage(this, attacker, getthink(this));
 116 }
 117
 118 void W_Arc_Bolt_Touch(entity this, entity toucher)
 119 {
 120         PROJECTILE_TOUCH(this, toucher);
 121         this.use(this, NULL, toucher);
 122 }
 123
 124 void W_Arc_Attack_Bolt(Weapon thiswep, entity actor, .entity weaponentity)
 125 {
 126         entity missile;
 127
 128         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(arc, bolt_ammo), weaponentity);
 129
 130         W_SetupShot(actor, weaponentity, false, 2, SND_LASERGUN_FIRE, CH_WEAPON_A, WEP_CVAR(arc, bolt_damage), WEP_ARC.m_id | HITTYPE_SECONDARY);
 131
 132         W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, w_shotdir);
 133
 134         missile = new(missile);
 135         missile.owner = missile.realowner = actor;
 136         missile.bot_dodge = true;
 137         IL_PUSH(g_bot_dodge, missile);
 138         missile.bot_dodgerating = WEP_CVAR(arc, bolt_damage);
 139
 140         missile.takedamage = DAMAGE_YES;
 141         SetResourceExplicit(missile, RES_HEALTH, WEP_CVAR(arc, bolt_health));
 142         missile.damageforcescale = WEP_CVAR(arc, bolt_damageforcescale);
 143         missile.event_damage = W_Arc_Bolt_Damage;
 144         missile.damagedbycontents = true;
 145         IL_PUSH(g_damagedbycontents, missile);
 146
 147         settouch(missile, W_Arc_Bolt_Touch);
 148         missile.use = W_Arc_Bolt_Explode_use;
 149         setthink(missile, adaptor_think2use_hittype_splash);
 150         missile.nextthink = time + WEP_CVAR(arc, bolt_lifetime);
 151         PROJECTILE_MAKETRIGGER(missile);
 152         missile.projectiledeathtype = WEP_ARC.m_id | HITTYPE_SECONDARY;
 153         missile.weaponentity_fld = weaponentity;
 154         setorigin(missile, w_shotorg);
 155         setsize(missile, '0 0 0', '0 0 0');
 156
 157         set_movetype(missile, MOVETYPE_FLY);
 158         W_SetupProjVelocity_PRE(missile, arc, bolt_);
 159
 160         missile.angles = vectoangles(missile.velocity);
 161         missile.flags = FL_PROJECTILE;
 162         missile.missile_flags = MIF_SPLASH;
 163
 164         CSQCProjectile(missile, true, PROJECTILE_ARC_BOLT, true);
 165
 166         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 167 }
 168
 169 void W_Arc_Beam_Think(entity this)
 170 {
 171         .entity weaponentity = this.weaponentity_fld;
 172         entity own = this.owner;
 173         if(this != own.(weaponentity).arc_beam)
 174         {
 175                 delete(this);
 176                 return;
 177         }
 178
 179         float burst = 0;
 180         if( (PHYS_INPUT_BUTTON_ATCK2(own) && !WEP_CVAR(arc, bolt)) || this.beam_bursting)
 181         {
 182                 if(!this.beam_bursting)
 183                         this.beam_bursting = true;
 184                 burst = ARC_BT_BURSTMASK;
 185         }
 186
 187         Weapon thiswep = WEP_ARC;
 188
 189         // TODO: use standard weapon use checks here!
 190         if(
 191                 !IS_PLAYER(own)
 192                 ||
 193                 IS_DEAD(own)
 194                 ||
 195                 game_stopped
 196                 ||
 197                 !weapon_prepareattack_check(thiswep, own, weaponentity, this.beam_bursting, -1)
 198                 ||
 199                 own.(weaponentity).m_switchweapon != WEP_ARC
 200                 ||
 201                 (!PHYS_INPUT_BUTTON_ATCK(own) && !burst )
 202                 ||
 203                 own.vehicle
 204                 ||
 205                 (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max))
 206         )
 207         {
 208                 if ( WEP_CVAR(arc, cooldown) > 0 )
 209                 {
 210                         float cooldown_speed = 0;
 211                         if ( this.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 212                         {
 213                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 214                         }
 215                         else if ( !burst )
 216                         {
 217                                 cooldown_speed = this.beam_heat / WEP_CVAR(arc, beam_refire);
 218                         }
 219
 220                         if ( cooldown_speed )
 221                         {
 222                                 if ( WEP_CVAR(arc, cooldown_release) || (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max)) )
 223                                         own.arc_overheat = time + this.beam_heat / cooldown_speed;
 224                                 own.arc_cooldown = cooldown_speed;
 225                         }
 226
 227                         if ( WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max) )
 228                         {
 229                                 Send_Effect(EFFECT_ARC_OVERHEAT,
 230                                         this.beam_start, this.beam_wantdir, 1 );
 231                                 sound(this, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 232                         }
 233                 }
 234
 235                 if(this == own.(weaponentity).arc_beam) { own.(weaponentity).arc_beam = NULL; }
 236                 if(!thiswep.wr_checkammo1(thiswep, own, weaponentity) && !(own.items & IT_UNLIMITED_AMMO))
 237                 {
 238                         // note: this doesn't force the switch
 239                         W_SwitchToOtherWeapon(own, weaponentity);
 240                 }
 241                 own.(weaponentity).arc_BUTTON_ATCK_prev = false; // allow switching weapons
 242                 delete(this);
 243                 return;
 244         }
 245
 246         // decrease ammo
 247         float coefficient = frametime;
 248         if(!(own.items & IT_UNLIMITED_AMMO))
 249         {
 250                 float rootammo;
 251                 if(burst)
 252                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 253                 else
 254                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 255
 256                 if(rootammo)
 257                 {
 258                         coefficient = min(coefficient, GetResource(own, thiswep.ammo_type) / rootammo);
 259                         SetResource(own, thiswep.ammo_type, max(0, GetResource(own, thiswep.ammo_type) - (rootammo * frametime)));
 260                 }
 261         }
 262         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 263         this.beam_heat = min( WEP_CVAR(arc, overheat_max), this.beam_heat + heat_speed*frametime );
 264
 265         makevectors(own.v_angle);
 266
 267         W_SetupShot_Range(
 268                 own,
 269                 weaponentity,
 270                 true,
 271                 0,
 272                 SND_Null,
 273                 0,
 274                 WEP_CVAR(arc, beam_damage) * coefficient,
 275                 WEP_CVAR(arc, beam_range),
 276                 thiswep.m_id
 277         );
 278
 279         // After teleport, "lock" the beam until the teleport is confirmed.
 280         if (time < this.beam_teleporttime + ANTILAG_LATENCY(own)) {
 281                 w_shotdir = this.beam_dir;
 282         }
 283
 284         // network information: shot origin and want/aim direction
 285         if(this.beam_start != w_shotorg)
 286         {
 287                 this.SendFlags |= ARC_SF_START;
 288                 this.beam_start = w_shotorg;
 289         }
 290         if(this.beam_wantdir != w_shotdir)
 291         {
 292                 this.SendFlags |= ARC_SF_WANTDIR;
 293                 this.beam_wantdir = w_shotdir;
 294         }
 295
 296         if(!this.beam_initialized)
 297         {
 298                 this.beam_dir = w_shotdir;
 299                 this.beam_initialized = true;
 300         }
 301
 302         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 303         // idea: blend together this.beam_dir with the inverted direction the player is moving in
 304         // might have to make some special accomodation so that it only uses view_right and view_up
 305
 306         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 307
 308         float segments;
 309         if(this.beam_dir != w_shotdir)
 310         {
 311                 // calculate how much we're going to move the end of the beam to the want position
 312                 // WEAPONTODO (server and client):
 313                 // blendfactor never actually becomes 0 in this situation, which is a problem
 314                 // regarding precision... this means that this.beam_dir and w_shotdir approach
 315                 // eachother, however they never actually become the same value with this method.
 316                 // Perhaps we should do some form of rounding/snapping?
 317                 float angle = vlen(w_shotdir - this.beam_dir) * RAD2DEG;
 318                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 319                 {
 320                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 321                         float blendfactor = bound(
 322                                 0,
 323                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 324                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 325                         );
 326                         if(vdist(this.beam_dir - w_shotdir, <, 0.01))
 327                                 this.beam_dir = w_shotdir;
 328                         else
 329                                 this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 330                 }
 331                 else
 332                 {
 333                         // the radius is not too far yet, no worries :D
 334                         float blendfactor = bound(
 335                                 0,
 336                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 337                                 1
 338                         );
 339                         if(vdist(this.beam_dir - w_shotdir, <, 0.01))
 340                                 this.beam_dir = w_shotdir;
 341                         else
 342                                 this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 343                 }
 344
 345                 // network information: beam direction
 346                 this.SendFlags |= ARC_SF_BEAMDIR;
 347
 348                 // calculate how many segments are needed
 349                 float max_allowed_segments;
 350
 351                 if(WEP_CVAR(arc, beam_distancepersegment))
 352                 {
 353                         max_allowed_segments = min(
 354                                 ARC_MAX_SEGMENTS,
 355                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 356                         );
 357                 }
 358                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 359
 360                 if(WEP_CVAR(arc, beam_degreespersegment))
 361                 {
 362                         segments = bound(
 363                                 1,
 364                                 (
 365                                         min(
 366                                                 angle,
 367                                                 WEP_CVAR(arc, beam_maxangle)
 368                                         )
 369                                         /
 370                                         WEP_CVAR(arc, beam_degreespersegment)
 371                                 ),
 372                                 max_allowed_segments
 373                         );
 374                 }
 375                 else { segments = 1; }
 376         }
 377         else { segments = 1; }
 378
 379         vector beam_endpos = (w_shotorg + (this.beam_dir * WEP_CVAR(arc, beam_range)));
 380         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 381
 382         float i;
 383         float new_beam_type = 0;
 384         vector last_origin = w_shotorg;
 385         for(i = 1; i <= segments; ++i)
 386         {
 387                 // WEAPONTODO (client):
 388                 // In order to do nice fading and pointing on the starting segment, we must always
 389                 // have that drawn as a separate triangle... However, that is difficult to do when
 390                 // keeping in mind the above problems and also optimizing the amount of segments
 391                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 392
 393                 vector new_origin = bezier_quadratic_getpoint(
 394                         w_shotorg,
 395                         beam_controlpoint,
 396                         beam_endpos,
 397                         i / segments);
 398                 vector new_dir = normalize(new_origin - last_origin);
 399
 400                 WarpZone_traceline_antilag(
 401                         own,
 402                         last_origin,
 403                         new_origin,
 404                         MOVE_NORMAL,
 405                         own,
 406                         ANTILAG_LATENCY(own)
 407                 );
 408
 409                 // Do all the transforms for warpzones right now, as we already
 410                 // "are" in the post-trace system (if we hit a player, that's
 411                 // always BEHIND the last passed wz).
 412                 last_origin = trace_endpos;
 413                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 414                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 415                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 416                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 417
 418                 bool is_player = (
 419                         IS_PLAYER(trace_ent)
 420                         ||
 421                         trace_ent.classname == "body"
 422                         ||
 423                         IS_MONSTER(trace_ent)
 424                 );
 425
 426                 if(trace_ent)
 427                 {
 428                         if(SAME_TEAM(own, trace_ent))
 429                         {
 430                                 float roothealth = ((burst) ? WEP_CVAR(arc, burst_healing_hps) : WEP_CVAR(arc, beam_healing_hps));
 431                                 float rootarmor = ((burst) ? WEP_CVAR(arc, burst_healing_aps) : WEP_CVAR(arc, beam_healing_aps));
 432                                 float hplimit = ((IS_PLAYER(trace_ent)) ? WEP_CVAR(arc, beam_healing_hmax) : RES_LIMIT_NONE);
 433                                 Heal(trace_ent, own, (roothealth * coefficient), hplimit);
 434                                 if(IS_PLAYER(trace_ent) && rootarmor)
 435                                 {
 436                                         if(GetResource(trace_ent, RES_ARMOR) <= WEP_CVAR(arc, beam_healing_amax))
 437                                         {
 438                                                 GiveResourceWithLimit(trace_ent, RES_ARMOR, (rootarmor * coefficient), WEP_CVAR(arc, beam_healing_amax));
 439                                                 trace_ent.pauserotarmor_finished = max(
 440                                                         trace_ent.pauserotarmor_finished,
 441                                                         time + autocvar_g_balance_pause_armor_rot
 442                                                 );
 443                                         }
 444                                 }
 445                                 if(roothealth || rootarmor)
 446                                         new_beam_type = ARC_BT_HEAL;
 447                         }
 448                         else if(trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 449                         {
 450                                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 451                                 // NO. trace_endpos should be just fine. If not,
 452                                 // that's an engine bug that needs proper debugging.
 453                                 vector hitorigin = trace_endpos;
 454
 455                                 float falloff = ExponentialFalloff(
 456                                         WEP_CVAR(arc, beam_falloff_mindist),
 457                                         WEP_CVAR(arc, beam_falloff_maxdist),
 458                                         WEP_CVAR(arc, beam_falloff_halflifedist),
 459                                         vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 460                                 );
 461
 462                                 float rootdamage;
 463                                 if(is_player)
 464                                 {
 465                                         if(burst)
 466                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 467                                         else
 468                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 469                                 }
 470                                 else
 471                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 472
 473                                 if(accuracy_isgooddamage(own, trace_ent))
 474                                 {
 475                                         accuracy_add(
 476                                                 own,
 477                                                 WEP_ARC,
 478                                                 0,
 479                                                 rootdamage * coefficient * falloff
 480                                         );
 481                                 }
 482
 483                                 Damage(
 484                                         trace_ent,
 485                                         own,
 486                                         own,
 487                                         rootdamage * coefficient * falloff,
 488                                         WEP_ARC.m_id,
 489                                         weaponentity,
 490                                         hitorigin,
 491                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 492                                 );
 493
 494                                 new_beam_type = ARC_BT_HIT;
 495                         }
 496                         break;
 497                 }
 498                 else if(trace_fraction != 1)
 499                 {
 500                         // we collided with geometry
 501                         new_beam_type = ARC_BT_WALL;
 502                         break;
 503                 }
 504         }
 505
 506         // te_explosion(trace_endpos);
 507
 508         // if we're bursting, use burst visual effects
 509         new_beam_type |= burst;
 510
 511         // network information: beam type
 512         if(new_beam_type != this.beam_type)
 513         {
 514                 this.SendFlags |= ARC_SF_BEAMTYPE;
 515                 this.beam_type = new_beam_type;
 516         }
 517
 518         own.(weaponentity).beam_prev = time;
 519         this.nextthink = time;
 520 }
 521
 522 void W_Arc_Beam(float burst, entity actor, .entity weaponentity)
 523 {
 524
 525         // only play fire sound if 1 sec has passed since player let go the fire button
 526         if(time - actor.(weaponentity).beam_prev > 1)
 527                 sound(actor, CH_WEAPON_A, SND_ARC_FIRE, VOL_BASE, ATTN_NORM);
 528
 529         entity beam = actor.(weaponentity).arc_beam = new(W_Arc_Beam);
 530         beam.weaponentity_fld = weaponentity;
 531         beam.solid = SOLID_NOT;
 532         setthink(beam, W_Arc_Beam_Think);
 533         beam.owner = actor;
 534         set_movetype(beam, MOVETYPE_NONE);
 535         beam.bot_dodge = true;
 536         IL_PUSH(g_bot_dodge, beam);
 537         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 538         beam.beam_bursting = burst;
 539         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 540
 541         getthink(beam)(beam);
 542 }
 543 void W_Arc_Attack(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 544 {
 545         if(!actor.(weaponentity).arc_beam || wasfreed(actor.(weaponentity).arc_beam))
 546         {
 547                 w_ready(thiswep, actor, weaponentity, fire);
 548                 return;
 549         }
 550
 551         // attack handled by the beam itself, this is just a loop to keep the attack happening!
 552
 553         // NOTE: arc doesn't use a refire
 554         //ATTACK_FINISHED(actor, weaponentity) = time + WEP_CVAR_PRI(arc, refire) * W_WeaponRateFactor(actor);
 555         actor.(weaponentity).wframe = WFRAME_FIRE1;
 556         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), W_Arc_Attack);
 557 }
 558 void Arc_Smoke(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 559 {
 560         // TODO: spamming this without checking any refires is asking for trouble!
 561         makevectors(actor.v_angle);
 562         W_SetupShot_Range(actor,weaponentity,false,0,SND_Null,0,0,0,thiswep.m_id); // TODO: probably doesn't need deathtype, since this is just a prefire effect
 563
 564         vector smoke_origin = w_shotorg + actor.velocity*frametime;
 565         if ( actor.arc_overheat > time )
 566         {
 567                 if ( random() < actor.(weaponentity).arc_heat_percent )
 568                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 569                 if ( (fire & 1) || (fire & 2) )
 570                 {
 571                         Send_Effect(EFFECT_ARC_OVERHEAT_FIRE, smoke_origin, w_shotdir, 1 );
 572                         if ( !actor.arc_smoke_sound )
 573                         {
 574                                 actor.arc_smoke_sound = 1;
 575                                 sound(actor, CH_SHOTS_SINGLE, SND_ARC_LOOP_OVERHEAT, VOL_BASE, ATTN_NORM);
 576                         }
 577                 }
 578         }
 579         else if ( actor.(weaponentity).arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 580                         actor.(weaponentity).arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 581         {
 582                 if ( random() < (actor.(weaponentity).arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 583                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 584                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 585         }
 586
 587         bool attacking = PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor);
 588         bool stop_smoke_sound = actor.arc_overheat <= time || !attacking;
 589         if ((actor.arc_smoke_sound && stop_smoke_sound) || actor.(weaponentity).m_switchweapon != thiswep)
 590         {
 591                 actor.arc_smoke_sound = 0;
 592                 sound(actor, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 593         }
 594 }
 595
 596 METHOD(Arc, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 597 {
 598     if(WEP_CVAR(arc, beam_botaimspeed))
 599     {
 600         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 601                 actor,
 602                 weaponentity,
 603             WEP_CVAR(arc, beam_botaimspeed),
 604             0,
 605             WEP_CVAR(arc, beam_botaimlifetime),
 606             false
 607         );
 608     }
 609     else
 610     {
 611         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 612                 actor,
 613                 weaponentity,
 614             1000000,
 615             0,
 616             0.001,
 617             false
 618         );
 619     }
 620 }
 621 METHOD(Arc, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 622 {
 623     Arc_Player_SetHeat(actor, weaponentity);
 624     Arc_Smoke(thiswep, actor, weaponentity, fire);
 625
 626     bool beam_fire2 = ((fire & 2) && !WEP_CVAR(arc, bolt));
 627
 628     if (time >= actor.arc_overheat)
 629     if ((fire & 1) || beam_fire2 || actor.(weaponentity).arc_beam.beam_bursting)
 630     {
 631         #if 0
 632         if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 633         {
 634             #if 0
 635             if(actor.animstate_startframe == actor.anim_shoot.x && actor.animstate_numframes == actor.anim_shoot.y)
 636                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 637             else
 638             #endif
 639                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), w_ready);
 640         }
 641         #endif
 642
 643         if((!actor.(weaponentity).arc_beam) || wasfreed(actor.(weaponentity).arc_beam))
 644         {
 645             if(weapon_prepareattack(thiswep, actor, weaponentity, boolean(beam_fire2), 0))
 646             {
 647                 W_Arc_Beam(boolean(beam_fire2), actor, weaponentity);
 648
 649                 if(!actor.(weaponentity).arc_BUTTON_ATCK_prev)
 650                 {
 651                         actor.(weaponentity).wframe = WFRAME_FIRE1;
 652                     weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), W_Arc_Attack);
 653                     actor.(weaponentity).arc_BUTTON_ATCK_prev = true;
 654                 }
 655             }
 656         }
 657
 658         return;
 659     }
 660     else if(fire & 2)
 661     {
 662         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR(arc, bolt_refire)))
 663         {
 664             W_Arc_Attack_Bolt(thiswep, actor, weaponentity);
 665             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, bolt_refire), w_ready);
 666         }
 667     }
 668
 669     if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 670     {
 671         sound(actor, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 672         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 673         ATTACK_FINISHED(actor, weaponentity) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor(actor);
 674     }
 675     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 676
 677     #if 0
 678     if(fire & 2)
 679     if(weapon_prepareattack(thiswep, actor, weaponentity, true, autocvar_g_balance_arc_secondary_refire))
 680     {
 681         W_Arc_Attack2();
 682         actor.arc_count = autocvar_g_balance_arc_secondary_count;
 683         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 684         actor.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor(actor);
 685     }
 686     #endif
 687 }
 688 METHOD(Arc, wr_init, void(entity thiswep))
 689 {
 690     if(!arc_shotorigin[0])
 691     {
 692         arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 693         arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 694         arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 695         arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 696     }
 697 }
 698 METHOD(Arc, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 699 {
 700     return ((!WEP_CVAR(arc, beam_ammo)) || (GetResource(actor, thiswep.ammo_type) > 0));
 701 }
 702 METHOD(Arc, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 703 {
 704     if(WEP_CVAR(arc, bolt))
 705     {
 706         float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR(arc, bolt_ammo);
 707         ammo_amount += actor.(weaponentity).(weapon_load[WEP_ARC.m_id]) >= WEP_CVAR(arc, bolt_ammo);
 708         return ammo_amount;
 709     }
 710     else
 711         return WEP_CVAR(arc, overheat_max) > 0 &&
 712             ((!WEP_CVAR(arc, burst_ammo)) || (GetResource(actor, thiswep.ammo_type) > 0));
 713 }
 714 METHOD(Arc, wr_killmessage, Notification(entity thiswep))
 715 {
 716     if(w_deathtype & HITTYPE_SECONDARY)
 717         return WEAPON_ARC_MURDER_SPRAY;
 718     else
 719         return WEAPON_ARC_MURDER;
 720 }
 721 METHOD(Arc, wr_drop, void(entity thiswep, entity actor, .entity weaponentity))
 722 {
 723     weapon_dropevent_item.arc_overheat = actor.arc_overheat;
 724     weapon_dropevent_item.arc_cooldown = actor.arc_cooldown;
 725     actor.arc_overheat = 0;
 726     actor.arc_cooldown = 0;
 727     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 728 }
 729 METHOD(Arc, wr_pickup, void(entity thiswep, entity actor, .entity weaponentity))
 730 {
 731     if ( !client_hasweapon(actor, thiswep, weaponentity, false, false) &&
 732         weapon_dropevent_item.arc_overheat > time )
 733     {
 734         actor.arc_overheat = weapon_dropevent_item.arc_overheat;
 735         actor.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 736     }
 737 }
 738 METHOD(Arc, wr_resetplayer, void(entity thiswep, entity actor))
 739 {
 740     actor.arc_overheat = 0;
 741     actor.arc_cooldown = 0;
 742     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 743     {
 744         .entity weaponentity = weaponentities[slot];
 745         actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 746     }
 747 }
 748 METHOD(Arc, wr_playerdeath, void(entity thiswep, entity actor, .entity weaponentity))
 749 {
 750     actor.arc_overheat = 0;
 751     actor.arc_cooldown = 0;
 752     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 753 }
 754 #endif
 755 #ifdef CSQC
 756 bool autocvar_cl_arcbeam_teamcolor = true;
 757 bool autocvar_cl_arcbeam_simple = true;
 758
 759 .int beam_slot;
 760
 761 METHOD(Arc, wr_impacteffect, void(entity thiswep, entity actor))
 762 {
 763     if(w_deathtype & HITTYPE_SECONDARY)
 764     {
 765         vector org2;
 766         org2 = w_org + w_backoff * 6;
 767         pointparticles(EFFECT_ARC_BOLT_EXPLODE, org2, w_backoff * 1000, 1);
 768         if(!w_issilent) { sound(actor, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 769     }
 770 }
 771
 772 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 773 {
 774         entity beam = Draw_ArcBeam_callback_entity;
 775         vector transformed_view_org;
 776         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 777
 778         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 779         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 780         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 781
 782         vector hitorigin;
 783
 784         // draw segment
 785         #if 0
 786         if(trace_fraction != 1)
 787         {
 788                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 789                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 790                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 791         }
 792         else
 793         {
 794                 hitorigin = hit;
 795         }
 796         #else
 797         hitorigin = hit;
 798         #endif
 799
 800         // decide upon thickness
 801         float thickness = beam.beam_thickness;
 802
 803         // draw primary beam render
 804         vector top    = hitorigin + (thickdir * thickness);
 805         vector bottom = hitorigin - (thickdir * thickness);
 806
 807         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 808         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 809
 810         if(autocvar_cl_arcbeam_simple)
 811                 Draw_CylindricLine(start, end, thickness, beam.beam_image, 0.25, -time * 3, beam.beam_color, beam.beam_alpha, DRAWFLAG_NORMAL, transformed_view_org);
 812         else
 813         {
 814                 R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL, false); // DRAWFLAG_ADDITIVE
 815                 R_PolygonVertex(
 816                         top,
 817                         '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 818                         beam.beam_color,
 819                         beam.beam_alpha
 820                 );
 821                 R_PolygonVertex(
 822                         last_top,
 823                         '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 824                         beam.beam_color,
 825                         beam.beam_alpha
 826                 );
 827                 R_PolygonVertex(
 828                         last_bottom,
 829                         '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 830                         beam.beam_color,
 831                         beam.beam_alpha
 832                 );
 833                 R_PolygonVertex(
 834                         bottom,
 835                         '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 836                         beam.beam_color,
 837                         beam.beam_alpha
 838                 );
 839                 R_EndPolygon();
 840         }
 841
 842         // draw trailing particles
 843         // NOTES:
 844         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 845         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 846         if(beam.beam_traileffect)
 847         {
 848                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 849         }
 850
 851         // set up for the next
 852         Draw_ArcBeam_callback_last_thickness = thickness;
 853         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 854         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 855 }
 856
 857 void Reset_ArcBeam()
 858 {
 859         entity e;
 860         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 861                 e.beam_initialized = false;
 862         }
 863         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 864                 e.beam_initialized = false;
 865         }
 866 }
 867
 868 void Draw_ArcBeam(entity this)
 869 {
 870         float dt = time - this.move_time;
 871         this.move_time = time;
 872         if(dt <= 0) { return; }
 873
 874         if(!this.beam_usevieworigin)
 875         {
 876                 InterpolateOrigin_Do(this);
 877         }
 878
 879         // origin = beam starting origin
 880         // v_angle = wanted/aim direction
 881         // angles = current direction of beam
 882
 883         vector start_pos;
 884         vector wantdir; //= view_forward;
 885         vector beamdir; //= this.beam_dir;
 886
 887         float segments;
 888         if(this.beam_usevieworigin)
 889         {
 890                 // WEAPONTODO:
 891                 // Currently we have to replicate nearly the same method of figuring
 892                 // out the shotdir that the server does... Ideally in the future we
 893                 // should be able to acquire this from a generalized function built
 894                 // into a weapon system for client code.
 895
 896                 // find where we are aiming
 897                 vector myviewangle = ((autocvar_chase_active) ? warpzone_save_view_angles : view_angles);
 898                 vector forward, right, up;
 899                 MAKE_VECTORS(myviewangle, forward, right, up);
 900                 entity wepent = viewmodels[this.beam_slot];
 901
 902                 this.beam_usevieworigin = (autocvar_chase_active) ? 1 : 2;
 903
 904                 // decide upon start position
 905                 if(this.beam_usevieworigin == 2)
 906                         { start_pos = warpzone_save_view_origin; }
 907                 else if(csqcplayer)
 908                         { start_pos = csqcplayer.origin + csqcplayer.view_ofs; }
 909                 else
 910                         { start_pos = this.origin; }
 911
 912                 // trace forward with an estimation
 913                 WarpZone_TraceLine(
 914                         start_pos,
 915                         start_pos + forward * this.beam_range,
 916                         MOVE_NOMONSTERS,
 917                         this
 918                 );
 919
 920                 int v_shot_idx;  // used later
 921                 (v_shot_idx = gettagindex(wepent, "shot")) || (v_shot_idx = gettagindex(wepent, "tag_shot"));
 922                 if(v_shot_idx && this.beam_usevieworigin == 2)
 923                         start_pos = gettaginfo(wepent, v_shot_idx) - '0 0 2';
 924
 925                 // untransform in case our trace went through a warpzone
 926                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 927
 928                 // un-adjust trueaim if shotend is too close
 929                 if(vdist(end_pos - start_pos, <, g_trueaim_minrange))
 930                         end_pos = start_pos + (forward * g_trueaim_minrange);
 931
 932                 // move shot origin to the actual gun muzzle origin
 933                 vector origin_offset = '0 0 0';
 934                 if(!v_shot_idx || this.beam_usevieworigin != 2)
 935                 {
 936                         this.beam_shotorigin = wepent.movedir;
 937                         origin_offset = right * -this.beam_shotorigin.y + up * this.beam_shotorigin.z;
 938                 }
 939                 else
 940                         this.beam_shotorigin = '0 0 0';
 941
 942                 start_pos = start_pos + origin_offset;
 943
 944                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
 945                 traceline(start_pos, start_pos + forward * this.beam_shotorigin.x, MOVE_NORMAL, this);
 946                 start_pos = trace_endpos;
 947
 948                 // calculate the aim direction now
 949                 wantdir = normalize(end_pos - start_pos);
 950
 951                 if(!this.beam_initialized)
 952                 {
 953                         this.beam_dir = wantdir;
 954                         this.beam_initialized = true;
 955
 956                         this.beam_muzzleentity.drawmask = MASK_NORMAL; // NOTE: this works around the muzzle entity flashing on the middle of the screen for a frame
 957                 }
 958
 959                 if(this.beam_dir != wantdir)
 960                 {
 961                         // calculate how much we're going to move the end of the beam to the want position
 962                         // WEAPONTODO (server and client):
 963                         // blendfactor never actually becomes 0 in this situation, which is a problem
 964                         // regarding precision... this means that this.beam_dir and w_shotdir approach
 965                         // eachother, however they never actually become the same value with this method.
 966                         // Perhaps we should do some form of rounding/snapping?
 967                         float angle = vlen(wantdir - this.beam_dir) * RAD2DEG;
 968                         if(angle && (angle > this.beam_maxangle))
 969                         {
 970                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 971                                 float blendfactor = bound(
 972                                         0,
 973                                         (1 - (this.beam_returnspeed * dt)),
 974                                         min(this.beam_maxangle / angle, 1)
 975                                 );
 976                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 977                         }
 978                         else
 979                         {
 980                                 // the radius is not too far yet, no worries :D
 981                                 float blendfactor = bound(
 982                                         0,
 983                                         (1 - (this.beam_returnspeed * dt)),
 984                                         1
 985                                 );
 986                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 987                         }
 988
 989                         // calculate how many segments are needed
 990                         float max_allowed_segments;
 991
 992                         if(this.beam_distancepersegment)
 993                         {
 994                                 max_allowed_segments = min(
 995                                         ARC_MAX_SEGMENTS,
 996                                         1 + (vlen(wantdir / this.beam_distancepersegment))
 997                                 );
 998                         }
 999                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1000
1001                         if(this.beam_degreespersegment)
1002                         {
1003                                 segments = bound(
1004                                         1,
1005                                         (
1006                                                 min(
1007                                                         angle,
1008                                                         this.beam_maxangle
1009                                                 )
1010                                                 /
1011                                                 this.beam_degreespersegment
1012                                         ),
1013                                         max_allowed_segments
1014                                 );
1015                         }
1016                         else { segments = 1; }
1017                 }
1018                 else { segments = 1; }
1019
1020                 // set the beam direction which the rest of the code will refer to
1021                 beamdir = this.beam_dir;
1022
1023                 // finally, set this.angles to the proper direction so that muzzle attachment points in proper direction
1024                 this.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1025         }
1026         else
1027         {
1028                 // set the values from the provided info from the networked entity
1029                 start_pos = this.origin;
1030                 wantdir = this.v_angle;
1031                 beamdir = this.angles;
1032
1033                 if(beamdir != wantdir)
1034                 {
1035                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1036
1037                         // calculate how many segments are needed
1038                         float max_allowed_segments;
1039
1040                         if(this.beam_distancepersegment)
1041                         {
1042                                 max_allowed_segments = min(
1043                                         ARC_MAX_SEGMENTS,
1044                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1045                                 );
1046                         }
1047                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1048
1049                         if(this.beam_degreespersegment)
1050                         {
1051                                 segments = bound(
1052                                         1,
1053                                         (
1054                                                 min(
1055                                                         angle,
1056                                                         this.beam_maxangle
1057                                                 )
1058                                                 /
1059                                                 this.beam_degreespersegment
1060                                         ),
1061                                         max_allowed_segments
1062                                 );
1063                         }
1064                         else { segments = 1; }
1065                 }
1066                 else { segments = 1; }
1067         }
1068
1069         setorigin(this, start_pos);
1070         this.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1071
1072         vector beam_endpos = (start_pos + (beamdir * this.beam_range));
1073         vector beam_controlpoint = start_pos + wantdir * (this.beam_range * (1 - this.beam_tightness));
1074
1075         Draw_ArcBeam_callback_entity = this;
1076         Draw_ArcBeam_callback_last_thickness = 0;
1077         Draw_ArcBeam_callback_last_top = start_pos;
1078         Draw_ArcBeam_callback_last_bottom = start_pos;
1079
1080         vector last_origin = start_pos;
1081         vector original_start_pos = start_pos;
1082
1083         float i;
1084         for(i = 1; i <= segments; ++i)
1085         {
1086                 // WEAPONTODO (client):
1087                 // In order to do nice fading and pointing on the starting segment, we must always
1088                 // have that drawn as a separate triangle... However, that is difficult to do when
1089                 // keeping in mind the above problems and also optimizing the amount of segments
1090                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1091
1092                 vector new_origin = bezier_quadratic_getpoint(
1093                         start_pos,
1094                         beam_controlpoint,
1095                         beam_endpos,
1096                         i / segments);
1097
1098                 WarpZone_TraceBox_ThroughZone(
1099                         last_origin,
1100                         '0 0 0',
1101                         '0 0 0',
1102                         new_origin,
1103                         MOVE_NORMAL,
1104                         NULL,
1105                         NULL,
1106                         Draw_ArcBeam_callback
1107                 );
1108
1109                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1110                 // system (if we hit a player, that's always BEHIND the last passed wz).
1111                 last_origin = trace_endpos;
1112                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1113                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1114                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1115                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1116                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1117                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1118
1119                 if(trace_fraction < 1) { break; }
1120         }
1121
1122         // visual effects for startpoint and endpoint
1123         if(this.beam_hiteffect)
1124         {
1125                 // FIXME we really should do this on the server so it actually
1126                 // matches gameplay. What this client side stuff is doing is no
1127                 // more than guesswork.
1128                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1129                 pointparticles(
1130                         this.beam_hiteffect,
1131                         last_origin,
1132                         beamdir * -1,
1133                         dt * 2
1134                 );
1135         }
1136         if(this.beam_hitlight[0])
1137         {
1138                 adddynamiclight(
1139                         last_origin,
1140                         this.beam_hitlight[0],
1141                         vec3(
1142                                 this.beam_hitlight[1],
1143                                 this.beam_hitlight[2],
1144                                 this.beam_hitlight[3]
1145                         )
1146                 );
1147         }
1148         if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1149         {
1150                 pointparticles(
1151                         this.beam_muzzleeffect,
1152                         original_start_pos + wantdir * 20,
1153                         wantdir * 1000,
1154                         dt * 0.1
1155                 );
1156         }
1157         if(this.beam_muzzlelight[0])
1158         {
1159                 adddynamiclight(
1160                         original_start_pos + wantdir * 20,
1161                         this.beam_muzzlelight[0],
1162                         vec3(
1163                                 this.beam_muzzlelight[1],
1164                                 this.beam_muzzlelight[2],
1165                                 this.beam_muzzlelight[3]
1166                         )
1167                 );
1168         }
1169
1170         // cleanup
1171         Draw_ArcBeam_callback_entity = NULL;
1172         Draw_ArcBeam_callback_last_thickness = 0;
1173         Draw_ArcBeam_callback_last_top = '0 0 0';
1174         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1175 }
1176
1177 void Remove_ArcBeam(entity this)
1178 {
1179         delete(this.beam_muzzleentity);
1180         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
1181 }
1182
1183 NET_HANDLE(ENT_CLIENT_ARC_BEAM, bool isnew)
1184 {
1185         int sf = ReadByte();
1186         int slot = ReadByte();
1187         entity flash;
1188
1189         this.beam_slot = slot;
1190
1191         if(isnew)
1192         {
1193                 int gunalign = W_GunAlign(viewmodels[slot], STAT(GUNALIGN)) - 1;
1194
1195                 this.beam_shotorigin = arc_shotorigin[gunalign]; // get a starting point
1196
1197                 // set other main attributes of the beam
1198                 this.draw = Draw_ArcBeam;
1199                 IL_PUSH(g_drawables, this);
1200                 this.entremove = Remove_ArcBeam;
1201                 this.move_time = time;
1202                 loopsound(this, CH_SHOTS_SINGLE, SND_ARC_LOOP, VOL_BASE, ATTEN_NORM);
1203
1204                 flash = spawn();
1205                 flash.owner = this;
1206                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1207                 //flash.drawmask = MASK_NORMAL;
1208                 flash.solid = SOLID_NOT;
1209                 flash.avelocity_z = 5000;
1210                 setattachment(flash, this, "");
1211                 setorigin(flash, '0 0 0');
1212
1213                 this.beam_muzzleentity = flash;
1214         }
1215         else
1216         {
1217                 flash = this.beam_muzzleentity;
1218         }
1219
1220         if(sf & ARC_SF_SETTINGS) // settings information
1221         {
1222                 this.beam_degreespersegment = ReadShort();
1223                 this.beam_distancepersegment = ReadShort();
1224                 this.beam_maxangle = ReadShort();
1225                 this.beam_range = ReadCoord();
1226                 this.beam_returnspeed = ReadShort();
1227                 this.beam_tightness = (ReadByte() / 10);
1228
1229                 if(ReadByte())
1230                 {
1231                         this.beam_usevieworigin = (autocvar_chase_active) ? 1 : 2;
1232                 }
1233                 else
1234                 {
1235                         this.beam_usevieworigin = 0;
1236                 }
1237
1238                 this.sv_entnum = ReadByte();
1239         }
1240
1241         if(!this.beam_usevieworigin)
1242         {
1243                 // this.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1244                 this.iflags = IFLAG_ORIGIN;
1245
1246                 InterpolateOrigin_Undo(this);
1247         }
1248
1249         if(sf & ARC_SF_START) // starting location
1250         {
1251                 this.origin = ReadVector();
1252         }
1253         else if(this.beam_usevieworigin) // infer the location from player location
1254         {
1255                 if(this.beam_usevieworigin == 2)
1256                 {
1257                         // use view origin
1258                         this.origin = view_origin;
1259                 }
1260                 else
1261                 {
1262                         // use player origin so that third person display still works
1263                         this.origin = entcs_receiver(player_localnum).origin + ('0 0 1' * STAT(VIEWHEIGHT));
1264                 }
1265         }
1266
1267         setorigin(this, this.origin);
1268
1269         if(sf & ARC_SF_WANTDIR) // want/aim direction
1270         {
1271                 this.v_angle = ReadVector();
1272         }
1273
1274         if(sf & ARC_SF_BEAMDIR) // beam direction
1275         {
1276                 this.angles = ReadAngleVector();
1277         }
1278
1279         if(sf & ARC_SF_BEAMTYPE) // beam type
1280         {
1281                 this.beam_type = ReadByte();
1282
1283                 vector beamcolor = ((autocvar_cl_arcbeam_teamcolor) ? colormapPaletteColor(entcs_GetClientColors(this.sv_entnum - 1) & 0x0F, true) : '1 1 1');
1284                 switch(this.beam_type)
1285                 {
1286                         case ARC_BT_MISS:
1287                         {
1288                                 this.beam_color = beamcolor;
1289                                 this.beam_alpha = 0.5;
1290                                 this.beam_thickness = 8;
1291                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1292                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1293                                 this.beam_hitlight[0] = 0;
1294                                 this.beam_hitlight[1] = 1;
1295                                 this.beam_hitlight[2] = 1;
1296                                 this.beam_hitlight[3] = 1;
1297                                 this.beam_muzzleeffect = EFFECT_Null;
1298                                 this.beam_muzzlelight[0] = 0;
1299                                 this.beam_muzzlelight[1] = 1;
1300                                 this.beam_muzzlelight[2] = 1;
1301                                 this.beam_muzzlelight[3] = 1;
1302                                 this.beam_image = "particles/lgbeam";
1303                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1304                                 {
1305                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1306                                         flash.alpha = this.beam_alpha;
1307                                         flash.colormod = this.beam_color;
1308                                         flash.scale = 0.35;
1309                                 }
1310                                 break;
1311                         }
1312                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1313                         {
1314                                 this.beam_color = beamcolor;
1315                                 this.beam_alpha = 0.5;
1316                                 this.beam_thickness = 8;
1317                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1318                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1319                                 this.beam_hitlight[0] = 0;
1320                                 this.beam_hitlight[1] = 1;
1321                                 this.beam_hitlight[2] = 1;
1322                                 this.beam_hitlight[3] = 1;
1323                                 this.beam_muzzleeffect = EFFECT_Null; // (EFFECT_GRENADE_MUZZLEFLASH);
1324                                 this.beam_muzzlelight[0] = 0;
1325                                 this.beam_muzzlelight[1] = 1;
1326                                 this.beam_muzzlelight[2] = 1;
1327                                 this.beam_muzzlelight[3] = 1;
1328                                 this.beam_image = "particles/lgbeam";
1329                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1330                                 {
1331                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1332                                         flash.alpha = this.beam_alpha;
1333                                         flash.colormod = this.beam_color;
1334                                         flash.scale = 0.35;
1335                                 }
1336                                 break;
1337                         }
1338                         case ARC_BT_HEAL:
1339                         {
1340                                 this.beam_color = beamcolor;
1341                                 this.beam_alpha = 0.5;
1342                                 this.beam_thickness = 8;
1343                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1344                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT);
1345                                 this.beam_hitlight[0] = 0;
1346                                 this.beam_hitlight[1] = 1;
1347                                 this.beam_hitlight[2] = 1;
1348                                 this.beam_hitlight[3] = 1;
1349                                 this.beam_muzzleeffect = EFFECT_Null;
1350                                 this.beam_muzzlelight[0] = 0;
1351                                 this.beam_muzzlelight[1] = 1;
1352                                 this.beam_muzzlelight[2] = 1;
1353                                 this.beam_muzzlelight[3] = 1;
1354                                 this.beam_image = "particles/lgbeam";
1355                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1356                                 {
1357                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1358                                         flash.alpha = this.beam_alpha;
1359                                         flash.colormod = this.beam_color;
1360                                         flash.scale = 0.35;
1361                                 }
1362                                 break;
1363                         }
1364                         case ARC_BT_HIT:
1365                         {
1366                                 this.beam_color = beamcolor;
1367                                 this.beam_alpha = 0.5;
1368                                 this.beam_thickness = 8;
1369                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1370                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1371                                 this.beam_hitlight[0] = 20;
1372                                 this.beam_hitlight[1] = 1;
1373                                 this.beam_hitlight[2] = 0;
1374                                 this.beam_hitlight[3] = 0;
1375                                 this.beam_muzzleeffect = EFFECT_Null;
1376                                 this.beam_muzzlelight[0] = 50;
1377                                 this.beam_muzzlelight[1] = 1;
1378                                 this.beam_muzzlelight[2] = 0;
1379                                 this.beam_muzzlelight[3] = 0;
1380                                 this.beam_image = "particles/lgbeam";
1381                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1382                                 {
1383                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1384                                         flash.alpha = this.beam_alpha;
1385                                         flash.colormod = this.beam_color;
1386                                         flash.scale = 0.35;
1387                                 }
1388                                 break;
1389                         }
1390                         case ARC_BT_BURST_MISS:
1391                         {
1392                                 this.beam_color = beamcolor;
1393                                 this.beam_alpha = 0.5;
1394                                 this.beam_thickness = 14;
1395                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1396                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1397                                 this.beam_hitlight[0] = 0;
1398                                 this.beam_hitlight[1] = 1;
1399                                 this.beam_hitlight[2] = 1;
1400                                 this.beam_hitlight[3] = 1;
1401                                 this.beam_muzzleeffect = EFFECT_Null;
1402                                 this.beam_muzzlelight[0] = 0;
1403                                 this.beam_muzzlelight[1] = 1;
1404                                 this.beam_muzzlelight[2] = 1;
1405                                 this.beam_muzzlelight[3] = 1;
1406                                 this.beam_image = "particles/lgbeam";
1407                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1408                                 {
1409                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1410                                         flash.alpha = this.beam_alpha;
1411                                         flash.colormod = this.beam_color;
1412                                         flash.scale = 0.35;
1413                                 }
1414                                 break;
1415                         }
1416                         case ARC_BT_BURST_WALL:
1417                         {
1418                                 this.beam_color = beamcolor;
1419                                 this.beam_alpha = 0.5;
1420                                 this.beam_thickness = 14;
1421                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1422                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1423                                 this.beam_hitlight[0] = 0;
1424                                 this.beam_hitlight[1] = 1;
1425                                 this.beam_hitlight[2] = 1;
1426                                 this.beam_hitlight[3] = 1;
1427                                 this.beam_muzzleeffect = EFFECT_Null;
1428                                 this.beam_muzzlelight[0] = 0;
1429                                 this.beam_muzzlelight[1] = 1;
1430                                 this.beam_muzzlelight[2] = 1;
1431                                 this.beam_muzzlelight[3] = 1;
1432                                 this.beam_image = "particles/lgbeam";
1433                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1434                                 {
1435                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1436                                         flash.alpha = this.beam_alpha;
1437                                         flash.colormod = this.beam_color;
1438                                         flash.scale = 0.35;
1439                                 }
1440                                 break;
1441                         }
1442                         case ARC_BT_BURST_HEAL:
1443                         {
1444                                 this.beam_color = beamcolor;
1445                                 this.beam_alpha = 0.5;
1446                                 this.beam_thickness = 14;
1447                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1448                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT2);
1449                                 this.beam_hitlight[0] = 0;
1450                                 this.beam_hitlight[1] = 1;
1451                                 this.beam_hitlight[2] = 1;
1452                                 this.beam_hitlight[3] = 1;
1453                                 this.beam_muzzleeffect = EFFECT_Null;
1454                                 this.beam_muzzlelight[0] = 0;
1455                                 this.beam_muzzlelight[1] = 1;
1456                                 this.beam_muzzlelight[2] = 1;
1457                                 this.beam_muzzlelight[3] = 1;
1458                                 this.beam_image = "particles/lgbeam";
1459                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1460                                 {
1461                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1462                                         flash.alpha = this.beam_alpha;
1463                                         flash.colormod = this.beam_color;
1464                                         flash.scale = 0.35;
1465                                 }
1466                                 break;
1467                         }
1468                         case ARC_BT_BURST_HIT:
1469                         {
1470                                 this.beam_color = beamcolor;
1471                                 this.beam_alpha = 0.5;
1472                                 this.beam_thickness = 14;
1473                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1474                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1475                                 this.beam_hitlight[0] = 0;
1476                                 this.beam_hitlight[1] = 1;
1477                                 this.beam_hitlight[2] = 1;
1478                                 this.beam_hitlight[3] = 1;
1479                                 this.beam_muzzleeffect = EFFECT_Null;
1480                                 this.beam_muzzlelight[0] = 0;
1481                                 this.beam_muzzlelight[1] = 1;
1482                                 this.beam_muzzlelight[2] = 1;
1483                                 this.beam_muzzlelight[3] = 1;
1484                                 this.beam_image = "particles/lgbeam";
1485                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1486                                 {
1487                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1488                                         flash.alpha = this.beam_alpha;
1489                                         flash.colormod = this.beam_color;
1490                                         flash.scale = 0.35;
1491                                 }
1492                                 break;
1493                         }
1494
1495                         // shouldn't be possible, but lets make it colorful if it does :D
1496                         default:
1497                         {
1498                                 this.beam_color = randomvec();
1499                                 this.beam_alpha = 1;
1500                                 this.beam_thickness = 8;
1501                                 this.beam_traileffect = NULL;
1502                                 this.beam_hiteffect = NULL;
1503                                 this.beam_hitlight[0] = 0;
1504                                 this.beam_hitlight[1] = 1;
1505                                 this.beam_hitlight[2] = 1;
1506                                 this.beam_hitlight[3] = 1;
1507                                 this.beam_muzzleeffect = EFFECT_Null;
1508                                 this.beam_muzzlelight[0] = 0;
1509                                 this.beam_muzzlelight[1] = 1;
1510                                 this.beam_muzzlelight[2] = 1;
1511                                 this.beam_muzzlelight[3] = 1;
1512                                 this.beam_image = "particles/lgbeam";
1513                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1514                                 {
1515                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1516                                         flash.alpha = this.beam_alpha;
1517                                         flash.colormod = this.beam_color;
1518                                         flash.scale = 0.35;
1519                                 }
1520                                 break;
1521                         }
1522                 }
1523         }
1524
1525         if(!this.beam_usevieworigin)
1526         {
1527                 InterpolateOrigin_Note(this);
1528         }
1529         return true;
1530 }
1531
1532 #endif