qcsrc/common/weapons/w_shockwave.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ SHOCKWAVE,
   4 /* function */ W_Shockwave,
   5 /* ammotype */ ammo_none,
   6 /* impulse  */ 2,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN,
   8 /* rating   */ BOT_PICKUP_RATING_LOW,
   9 /* color        */ '0.5 0.25 0',
  10 /* model    */ "shotgun",
  11 /* netname  */ "shockwave",
  12 /* fullname */ _("Shockwave")
  13 );
  14
  15 #define SHOCKWAVE_SETTINGS(w_cvar,w_prop) SHOCKWAVE_SETTINGS_LIST(w_cvar, w_prop, SHOCKWAVE, shockwave)
  16 #define SHOCKWAVE_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  17         w_cvar(id, sn, NONE, blast_animtime) \
  18         w_cvar(id, sn, NONE, blast_damage) \
  19         w_cvar(id, sn, NONE, blast_distance) \
  20         w_cvar(id, sn, NONE, blast_edgedamage) \
  21         w_cvar(id, sn, NONE, blast_force) \
  22         w_cvar(id, sn, NONE, blast_force_forwardbias) \
  23         w_cvar(id, sn, NONE, blast_force_zscale) \
  24         w_cvar(id, sn, NONE, blast_jump_damage) \
  25         w_cvar(id, sn, NONE, blast_jump_edgedamage) \
  26         w_cvar(id, sn, NONE, blast_jump_force) \
  27         w_cvar(id, sn, NONE, blast_jump_force_velocitybias) \
  28         w_cvar(id, sn, NONE, blast_jump_force_zscale) \
  29         w_cvar(id, sn, NONE, blast_jump_multiplier_accuracy) \
  30         w_cvar(id, sn, NONE, blast_jump_multiplier_distance) \
  31         w_cvar(id, sn, NONE, blast_jump_multiplier_min) \
  32         w_cvar(id, sn, NONE, blast_jump_radius) \
  33         w_cvar(id, sn, NONE, blast_multiplier_accuracy) \
  34         w_cvar(id, sn, NONE, blast_multiplier_distance) \
  35         w_cvar(id, sn, NONE, blast_multiplier_min) \
  36         w_cvar(id, sn, NONE, blast_refire) \
  37         w_cvar(id, sn, NONE, blast_splash_damage) \
  38         w_cvar(id, sn, NONE, blast_splash_edgedamage) \
  39         w_cvar(id, sn, NONE, blast_splash_force) \
  40         w_cvar(id, sn, NONE, blast_splash_force_forwardbias) \
  41         w_cvar(id, sn, NONE, blast_splash_multiplier_accuracy) \
  42         w_cvar(id, sn, NONE, blast_splash_multiplier_distance) \
  43         w_cvar(id, sn, NONE, blast_splash_multiplier_min) \
  44         w_cvar(id, sn, NONE, blast_splash_radius) \
  45         w_cvar(id, sn, NONE, blast_spread_max) \
  46         w_cvar(id, sn, NONE, blast_spread_min) \
  47         w_cvar(id, sn, NONE, melee_animtime) \
  48         w_cvar(id, sn, NONE, melee_damage) \
  49         w_cvar(id, sn, NONE, melee_delay) \
  50         w_cvar(id, sn, NONE, melee_force) \
  51         w_cvar(id, sn, NONE, melee_multihit) \
  52         w_cvar(id, sn, NONE, melee_no_doubleslap) \
  53         w_cvar(id, sn, NONE, melee_nonplayerdamage) \
  54         w_cvar(id, sn, NONE, melee_range) \
  55         w_cvar(id, sn, NONE, melee_refire) \
  56         w_cvar(id, sn, NONE, melee_swing_side) \
  57         w_cvar(id, sn, NONE, melee_swing_up) \
  58         w_cvar(id, sn, NONE, melee_time) \
  59         w_cvar(id, sn, NONE, melee_traces) \
  60         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  61         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  62         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  63         w_prop(id, sn, float,  weaponstart, weaponstart) \
  64         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  65
  66 #ifdef SVQC
  67 SHOCKWAVE_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  68 #endif
  69 #else
  70 #ifdef SVQC
  71 void spawnfunc_weapon_shockwave()
  72 {
  73         //if(autocvar_sv_q3acompat_machineshockwaveswap) // WEAPONTODO
  74         if(autocvar_sv_q3acompat_machineshotgunswap)
  75         if(self.classname != "droppedweapon")
  76         {
  77                 weapon_defaultspawnfunc(WEP_MACHINEGUN);
  78                 return;
  79         }
  80         weapon_defaultspawnfunc(WEP_SHOCKWAVE);
  81 }
  82
  83 #define MAX_SHOCKWAVE_HITS 10
  84
  85 .float swing_prev;
  86 .entity swing_alreadyhit;
  87 .float shockwave_blasttime;
  88 entity shockwave_hit[MAX_SHOCKWAVE_HITS];
  89 float shockwave_hit_damage[MAX_SHOCKWAVE_HITS];
  90 vector shockwave_hit_force[MAX_SHOCKWAVE_HITS];
  91
  92 // MELEE ATTACK MODE
  93 void W_Shockwave_Melee_Think()
  94 {
  95         // declarations
  96         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  97         entity target_victim;
  98         vector targpos;
  99
 100         // check to see if we can still continue, otherwise give up now
 101         if((self.realowner.deadflag != DEAD_NO) && WEP_CVAR(shockwave, melee_no_doubleslap))
 102         {
 103                 remove(self);
 104                 return;
 105         }
 106
 107         // set start time of melee
 108         if(!self.cnt)
 109         {
 110                 self.cnt = time;
 111                 W_PlayStrengthSound(self.realowner);
 112         }
 113
 114         // update values for v_* vectors
 115         makevectors(self.realowner.v_angle);
 116
 117         // calculate swing percentage based on time
 118         meleetime = WEP_CVAR(shockwave, melee_time) * W_WeaponRateFactor();
 119         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
 120         f = ((1 - swing) * WEP_CVAR(shockwave, melee_traces));
 121
 122         // perform the traces needed for this frame
 123         for(i=self.swing_prev; i < f; ++i)
 124         {
 125                 swing_factor = ((1 - (i / WEP_CVAR(shockwave, melee_traces))) * 2 - 1);
 126
 127                 targpos = (self.realowner.origin + self.realowner.view_ofs
 128                         + (v_forward * WEP_CVAR(shockwave, melee_range))
 129                         + (v_up * swing_factor * WEP_CVAR(shockwave, melee_swing_up))
 130                         + (v_right * swing_factor * WEP_CVAR(shockwave, melee_swing_side)));
 131
 132                 WarpZone_traceline_antilag(
 133                         self.realowner,
 134                         (self.realowner.origin + self.realowner.view_ofs),
 135                         targpos,
 136                         FALSE,
 137                         self.realowner,
 138                         ANTILAG_LATENCY(self.realowner)
 139                 );
 140
 141                 // draw lightning beams for debugging
 142                 te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
 143                 te_customflash(targpos, 40,  2, '1 1 1');
 144
 145                 is_player = (trace_ent.classname == "player" || trace_ent.classname == "body");
 146
 147                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self if necessary
 148                         && (trace_ent.takedamage == DAMAGE_AIM)
 149                         && (trace_ent != self.swing_alreadyhit)
 150                         && (is_player || WEP_CVAR(shockwave, melee_nonplayerdamage)))
 151                 {
 152                         target_victim = trace_ent; // so it persists through other calls
 153
 154                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught
 155                                 swing_damage = (WEP_CVAR(shockwave, melee_damage) * min(1, swing_factor + 1));
 156                         else
 157                                 swing_damage = (WEP_CVAR(shockwave, melee_nonplayerdamage) * min(1, swing_factor + 1));
 158
 159                         // trigger damage with this calculated info
 160                         Damage(
 161                                 target_victim,
 162                                 self.realowner,
 163                                 self.realowner,
 164                                 swing_damage,
 165                                 (WEP_SHOCKWAVE | HITTYPE_SECONDARY),
 166                                 (self.realowner.origin + self.realowner.view_ofs),
 167                                 (v_forward * WEP_CVAR(shockwave, melee_force))
 168                         );
 169
 170                         // handle accuracy
 171                         if(accuracy_isgooddamage(self.realowner, target_victim))
 172                                 { accuracy_add(self.realowner, WEP_SHOCKWAVE, 0, swing_damage); }
 173
 174                         #ifdef DEBUG_SHOCKWAVE
 175                         print(sprintf(
 176                                 "MELEE: %s hitting %s with %f damage (factor: %f) at %f time.\n",
 177                                 self.realowner.netname,
 178                                 target_victim.netname,
 179                                 swing_damage,
 180                                 swing_factor,
 181                                 time
 182                         ));
 183                         #endif
 184
 185                         // allow multiple hits with one swing, but not against the same player twice
 186                         if(WEP_CVAR(shockwave, melee_multihit))
 187                         {
 188                                 self.swing_alreadyhit = target_victim;
 189                                 continue; // move along to next trace
 190                         }
 191                         else
 192                         {
 193                                 remove(self);
 194                                 return;
 195                         }
 196                 }
 197         }
 198
 199         if(time >= self.cnt + meleetime)
 200         {
 201                 // melee is finished
 202                 remove(self);
 203                 return;
 204         }
 205         else
 206         {
 207                 // set up next frame
 208                 self.swing_prev = i;
 209                 self.nextthink = time;
 210         }
 211 }
 212
 213 void W_Shockwave_Melee()
 214 {
 215         sound(self, CH_WEAPON_A, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 216         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(shockwave, melee_animtime), w_ready);
 217
 218         entity meleetemp;
 219         meleetemp = spawn();
 220         meleetemp.owner = meleetemp.realowner = self;
 221         meleetemp.think = W_Shockwave_Melee_Think;
 222         meleetemp.nextthink = time + WEP_CVAR(shockwave, melee_delay) * W_WeaponRateFactor();
 223         W_SetupShot_Range(self, TRUE, 0, "", 0, WEP_CVAR(shockwave, melee_damage), WEP_CVAR(shockwave, melee_range));
 224 }
 225
 226 // SHOCKWAVE ATTACK MODE
 227 float W_Shockwave_Attack_CheckSpread(
 228         vector targetorg,
 229         vector nearest_on_line,
 230         vector sw_shotorg,
 231         vector attack_endpos)
 232 {
 233         float spreadlimit;
 234         float distance_of_attack = vlen(sw_shotorg - attack_endpos);
 235         float distance_from_line = vlen(targetorg - nearest_on_line);
 236
 237         spreadlimit = (distance_of_attack ? min(1, (vlen(sw_shotorg - nearest_on_line) / distance_of_attack)) : 1);
 238         spreadlimit =
 239                 (
 240                         (WEP_CVAR(shockwave, blast_spread_min) * (1 - spreadlimit))
 241                         +
 242                         (WEP_CVAR(shockwave, blast_spread_max) * spreadlimit)
 243                 );
 244
 245         if(
 246                 (spreadlimit && (distance_from_line <= spreadlimit))
 247                 &&
 248                 ((vlen(normalize(targetorg - sw_shotorg) - normalize(attack_endpos - sw_shotorg)) * RAD2DEG) <= 90)
 249         )
 250                 { return bound(0, (distance_from_line / spreadlimit), 1); }
 251         else
 252                 { return FALSE; }
 253 }
 254
 255 float W_Shockwave_Attack_IsVisible(
 256         entity head,
 257         vector nearest_on_line,
 258         vector sw_shotorg,
 259         vector attack_endpos)
 260 {
 261         vector nearest_to_attacker = head.WarpZone_findradius_nearest;
 262         vector center = (head.origin + (head.mins + head.maxs) * 0.5);
 263         vector corner;
 264         float i;
 265
 266         // STEP ONE: Check if the nearest point is clear
 267         if(W_Shockwave_Attack_CheckSpread(nearest_to_attacker, nearest_on_line, sw_shotorg, attack_endpos))
 268         {
 269                 WarpZone_TraceLine(sw_shotorg, nearest_to_attacker, MOVE_NOMONSTERS, self);
 270                 if(trace_fraction == 1) { return TRUE; } // yes, the nearest point is clear and we can allow the damage
 271         }
 272
 273         // STEP TWO: Check if shotorg to center point is clear
 274         if(W_Shockwave_Attack_CheckSpread(center, nearest_on_line, sw_shotorg, attack_endpos))
 275         {
 276                 WarpZone_TraceLine(sw_shotorg, center, MOVE_NOMONSTERS, self);
 277                 if(trace_fraction == 1) { return TRUE; } // yes, the center point is clear and we can allow the damage
 278         }
 279
 280         // STEP THREE: Check each corner to see if they are clear
 281         for(i=1; i<=8; ++i)
 282         {
 283                 corner = get_corner_position(head, i);
 284                 if(W_Shockwave_Attack_CheckSpread(corner, nearest_on_line, sw_shotorg, attack_endpos))
 285                 {
 286                         WarpZone_TraceLine(sw_shotorg, corner, MOVE_NOMONSTERS, self);
 287                         if(trace_fraction == 1) { return TRUE; } // yes, this corner is clear and we can allow the damage
 288                 }
 289         }
 290
 291         return FALSE;
 292 }
 293
 294 float W_Shockwave_Attack_CheckHit(
 295         float queue,
 296         entity head,
 297         vector final_force,
 298         float final_damage)
 299 {
 300         if(!head) { return FALSE; }
 301         float i;
 302
 303         for(i = 0; i <= queue; ++i)
 304         {
 305                 if(shockwave_hit[i] == head)
 306                 {
 307                         if(vlen(final_force) > vlen(shockwave_hit_force[i])) { shockwave_hit_force[i] = final_force; }
 308                         if(final_damage > shockwave_hit_damage[i]) { shockwave_hit_damage[i] = final_damage; }
 309                         return FALSE;
 310                 }
 311         }
 312
 313         shockwave_hit[queue] = head;
 314         shockwave_hit_force[queue] = final_force;
 315         shockwave_hit_damage[queue] = final_damage;
 316         return TRUE;
 317 }
 318
 319 void W_Shockwave_Attack()
 320 {
 321         // declarations
 322         float multiplier, multiplier_from_accuracy, multiplier_from_distance;
 323         float final_damage;
 324         vector final_force, center, vel;
 325         entity head;
 326
 327         float i, queue = 0;
 328
 329         // set up the shot direction
 330         W_SetupShot(self, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, WEP_CVAR(shockwave, blast_damage));
 331         vector attack_endpos = (w_shotorg + (w_shotdir * WEP_CVAR(shockwave, blast_distance)));
 332         WarpZone_TraceLine(w_shotorg, attack_endpos, MOVE_NOMONSTERS, self);
 333         vector attack_hitpos = trace_endpos;
 334         float distance_to_end = vlen(w_shotorg - attack_endpos);
 335         float distance_to_hit = vlen(w_shotorg - attack_hitpos);
 336         //entity transform = WarpZone_trace_transform;
 337
 338         // do the firing effect now
 339         //SendCSQCShockwaveParticle(attack_endpos); // WEAPONTODO
 340         Damage_DamageInfo(
 341                 attack_hitpos,
 342                 WEP_CVAR(shockwave, blast_splash_damage),
 343                 WEP_CVAR(shockwave, blast_splash_edgedamage),
 344                 WEP_CVAR(shockwave, blast_splash_radius),
 345                 w_shotdir * WEP_CVAR(shockwave, blast_splash_force),
 346                 WEP_SHOCKWAVE,
 347                 0,
 348                 self
 349         );
 350
 351         // splash damage/jumping trace
 352         head = WarpZone_FindRadius(
 353                 attack_hitpos,
 354                 max(
 355                         WEP_CVAR(shockwave, blast_splash_radius),
 356                         WEP_CVAR(shockwave, blast_jump_radius)
 357                 ),
 358                 FALSE
 359         );
 360
 361         while(head)
 362         {
 363                 if(head.takedamage)
 364                 {
 365                         float distance_to_head = vlen(attack_hitpos - head.WarpZone_findradius_nearest);
 366
 367                         if((head == self) && (distance_to_head <= WEP_CVAR(shockwave, blast_jump_radius)))
 368                         {
 369                                 // ========================
 370                                 //  BLAST JUMP CALCULATION
 371                                 // ========================
 372
 373                                 // calculate importance of distance and accuracy for this attack
 374                                 multiplier_from_accuracy = (1 -
 375                                         (distance_to_head ?
 376                                                 min(1, (distance_to_head / WEP_CVAR(shockwave, blast_jump_radius)))
 377                                                 :
 378                                                 0
 379                                         )
 380                                 );
 381                                 multiplier_from_distance = (1 -
 382                                         (distance_to_hit ?
 383                                                 min(1, (distance_to_hit / distance_to_end))
 384                                                 :
 385                                                 0
 386                                         )
 387                                 );
 388                                 multiplier =
 389                                         max(
 390                                                 WEP_CVAR(shockwave, blast_jump_multiplier_min),
 391                                                 (
 392                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_jump_multiplier_accuracy))
 393                                                         +
 394                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_jump_multiplier_distance))
 395                                                 )
 396                                         );
 397
 398                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 399                                 final_damage =
 400                                         (
 401                                                 (WEP_CVAR(shockwave, blast_jump_damage) * multiplier)
 402                                                 +
 403                                                 (WEP_CVAR(shockwave, blast_jump_edgedamage) * (1 - multiplier))
 404                                         );
 405
 406                                 // figure out the direction of force
 407                                 vel = normalize(combine_to_vector(head.velocity_x, head.velocity_y, 0));
 408                                 vel *=
 409                                         (
 410                                                 bound(0, (vlen(vel) / autocvar_sv_maxspeed), 1)
 411                                                 *
 412                                                 WEP_CVAR(shockwave, blast_jump_force_velocitybias)
 413                                         );
 414                                 final_force = normalize((CENTER_OR_VIEWOFS(head) - attack_hitpos) + vel);
 415
 416                                 // now multiply the direction by force units
 417                                 final_force *= (WEP_CVAR(shockwave, blast_jump_force) * multiplier);
 418                                 final_force_z *= WEP_CVAR(shockwave, blast_jump_force_zscale);
 419
 420                                 // trigger damage with this calculated info
 421                                 Damage(
 422                                         head,
 423                                         self,
 424                                         self,
 425                                         final_damage,
 426                                         WEP_SHOCKWAVE,
 427                                         head.origin,
 428                                         final_force
 429                                 );
 430
 431                                 #ifdef DEBUG_SHOCKWAVE
 432                                 print(sprintf(
 433                                         "SELF HIT: multiplier = %f, damage = %f, force = %f... "
 434                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 435                                         multiplier,
 436                                         final_damage,
 437                                         vlen(final_force),
 438                                         multiplier_from_accuracy,
 439                                         multiplier_from_distance
 440                                 ));
 441                                 #endif
 442                         }
 443                         else if(distance_to_head <= WEP_CVAR(shockwave, blast_splash_radius))
 444                         {
 445                                 // ==========================
 446                                 //  BLAST SPLASH CALCULATION
 447                                 // ==========================
 448
 449                                 // calculate importance of distance and accuracy for this attack
 450                                 multiplier_from_accuracy = (1 -
 451                                         (distance_to_head ?
 452                                                 min(1, (distance_to_head / WEP_CVAR(shockwave, blast_splash_radius)))
 453                                                 :
 454                                                 0
 455                                         )
 456                                 );
 457                                 multiplier_from_distance = (1 -
 458                                         (distance_to_hit ?
 459                                                 min(1, (distance_to_hit / distance_to_end))
 460                                                 :
 461                                                 0
 462                                         )
 463                                 );
 464                                 multiplier =
 465                                         max(
 466                                                 WEP_CVAR(shockwave, blast_splash_multiplier_min),
 467                                                 (
 468                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_splash_multiplier_accuracy))
 469                                                         +
 470                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_splash_multiplier_distance))
 471                                                 )
 472                                         );
 473
 474                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 475                                 final_damage =
 476                                         (
 477                                                 (WEP_CVAR(shockwave, blast_splash_damage) * multiplier)
 478                                                 +
 479                                                 (WEP_CVAR(shockwave, blast_splash_edgedamage) * (1 - multiplier))
 480                                         );
 481
 482                                 // figure out the direction of force
 483                                 final_force = (w_shotdir * WEP_CVAR(shockwave, blast_splash_force_forwardbias));
 484                                 final_force = normalize(CENTER_OR_VIEWOFS(head) - (attack_hitpos - final_force));
 485                                 //te_lightning2(world, attack_hitpos, (attack_hitpos + (final_force * 200)));
 486
 487                                 // now multiply the direction by force units
 488                                 final_force *= (WEP_CVAR(shockwave, blast_splash_force) * multiplier);
 489                                 final_force_z *= WEP_CVAR(shockwave, blast_force_zscale);
 490
 491                                 // queue damage with this calculated info
 492                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { queue = min(queue + 1, MAX_SHOCKWAVE_HITS); }
 493
 494                                 #ifdef DEBUG_SHOCKWAVE
 495                                 print(sprintf(
 496                                         "SPLASH HIT: multiplier = %f, damage = %f, force = %f... "
 497                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 498                                         multiplier,
 499                                         final_damage,
 500                                         vlen(final_force),
 501                                         multiplier_from_accuracy,
 502                                         multiplier_from_distance
 503                                 ));
 504                                 #endif
 505                         }
 506                 }
 507                 head = head.chain;
 508         }
 509
 510         // cone damage trace
 511         head = WarpZone_FindRadius(w_shotorg, WEP_CVAR(shockwave, blast_distance), FALSE);
 512         while(head)
 513         {
 514                 if((head != self) && head.takedamage)
 515                 {
 516                         // ========================
 517                         //  BLAST CONE CALCULATION
 518                         // ========================
 519
 520                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 521                         center = CENTER_OR_VIEWOFS(head);
 522
 523                         // find the closest point on the enemy to the center of the attack
 524                         float ang; // angle between shotdir and h
 525                         float h; // hypotenuse, which is the distance between attacker to head
 526                         float a; // adjacent side, which is the distance between attacker and the point on w_shotdir that is closest to head.origin
 527
 528                         h = vlen(center - self.origin);
 529                         ang = acos(dotproduct(normalize(center - self.origin), w_shotdir));
 530                         a = h * cos(ang);
 531                         // WEAPONTODO: replace with simpler method
 532
 533                         vector nearest_on_line = (w_shotorg + a * w_shotdir);
 534                         vector nearest_to_attacker = WarpZoneLib_NearestPointOnBox(center + head.mins, center + head.maxs, nearest_on_line);
 535
 536                         if((vlen(head.WarpZone_findradius_dist) <= WEP_CVAR(shockwave, blast_distance))
 537                                 && (W_Shockwave_Attack_IsVisible(head, nearest_on_line, w_shotorg, attack_endpos)))
 538                         {
 539                                 // calculate importance of distance and accuracy for this attack
 540                                 multiplier_from_accuracy = (1 -
 541                                         W_Shockwave_Attack_CheckSpread(
 542                                                 nearest_to_attacker,
 543                                                 nearest_on_line,
 544                                                 w_shotorg,
 545                                                 attack_endpos
 546                                         )
 547                                 );
 548                                 multiplier_from_distance = (1 -
 549                                         (distance_to_hit ?
 550                                                 min(1, (vlen(head.WarpZone_findradius_dist) / distance_to_end))
 551                                                 :
 552                                                 0
 553                                         )
 554                                 );
 555                                 multiplier =
 556                                         max(
 557                                                 WEP_CVAR(shockwave, blast_multiplier_min),
 558                                                 (
 559                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_multiplier_accuracy))
 560                                                         +
 561                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_multiplier_distance))
 562                                                 )
 563                                         );
 564
 565                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 566                                 final_damage =
 567                                         (
 568                                                 (WEP_CVAR(shockwave, blast_damage) * multiplier)
 569                                                 +
 570                                                 (WEP_CVAR(shockwave, blast_edgedamage) * (1 - multiplier))
 571                                         );
 572
 573                                 // figure out the direction of force
 574                                 final_force = (w_shotdir * WEP_CVAR(shockwave, blast_force_forwardbias));
 575                                 final_force = normalize(center - (nearest_on_line - final_force));
 576                                 //te_lightning2(world, nearest_on_line, (attack_hitpos + (final_force * 200)));
 577
 578                                 // now multiply the direction by force units
 579                                 final_force *= (WEP_CVAR(shockwave, blast_force) * multiplier);
 580                                 final_force_z *= WEP_CVAR(shockwave, blast_force_zscale);
 581
 582                                 // queue damage with this calculated info
 583                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { queue = min(queue + 1, MAX_SHOCKWAVE_HITS); }
 584
 585                                 #ifdef DEBUG_SHOCKWAVE
 586                                 print(sprintf(
 587                                         "BLAST HIT: multiplier = %f, damage = %f, force = %f... "
 588                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 589                                         multiplier,
 590                                         final_damage,
 591                                         vlen(final_force),
 592                                         multiplier_from_accuracy,
 593                                         multiplier_from_distance
 594                                 ));
 595                                 #endif
 596                         }
 597                 }
 598                 head = head.chain;
 599         }
 600
 601         for(i = 0; i <= queue; ++i)
 602         {
 603                 head = shockwave_hit[i];
 604                 final_force = shockwave_hit_force[i];
 605                 final_damage = shockwave_hit_damage[i];
 606
 607                 Damage(
 608                         head,
 609                         self,
 610                         self,
 611                         final_damage,
 612                         WEP_SHOCKWAVE,
 613                         head.origin,
 614                         final_force
 615                 );
 616
 617                 #ifdef DEBUG_SHOCKWAVE
 618                 print(sprintf(
 619                         "SHOCKWAVE by %s: damage = %f, force = %f.\n",
 620                         self.netname,
 621                         final_damage,
 622                         vlen(final_force)
 623                 ));
 624                 #endif
 625
 626                 shockwave_hit[i] = world;
 627                 shockwave_hit_force[i] = '0 0 0';
 628                 shockwave_hit_damage[i] = 0;
 629         }
 630 }
 631
 632 float W_Shockwave(float req)
 633 {
 634         switch(req)
 635         {
 636                 case WR_AIM:
 637                 {
 638                         if(vlen(self.origin - self.enemy.origin) <= WEP_CVAR(shockwave, melee_range))
 639                                 { self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE); }
 640                         else
 641                                 { self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE); }
 642
 643                         return TRUE;
 644                 }
 645                 case WR_THINK:
 646                 {
 647                         if(self.BUTTON_ATCK)
 648                         {
 649                                 if(time >= self.shockwave_blasttime) // handle refire separately so the secondary can be fired straight after a primary
 650                                 {
 651                                         if(weapon_prepareattack(0, WEP_CVAR(shockwave, blast_animtime)))
 652                                         {
 653                                                 W_Shockwave_Attack();
 654                                                 self.shockwave_blasttime = time + WEP_CVAR(shockwave, blast_refire) * W_WeaponRateFactor();
 655                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(shockwave, blast_animtime), w_ready);
 656                                         }
 657                                 }
 658                         }
 659                         else if(self.BUTTON_ATCK2)
 660                         {
 661                                 //if(self.clip_load >= 0) // we are not currently reloading
 662                                 if(!self.crouch) // no crouchmelee please
 663                                 if(weapon_prepareattack(1, WEP_CVAR(shockwave, melee_refire)))
 664                                 {
 665                                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 666                                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shockwave_Melee);
 667                                 }
 668                         }
 669
 670                         return TRUE;
 671                 }
 672                 case WR_INIT:
 673                 {
 674                         precache_model("models/uziflash.md3");
 675                         precache_model("models/weapons/g_shockwave.md3");
 676                         precache_model("models/weapons/v_shockwave.md3");
 677                         precache_model("models/weapons/h_shockwave.iqm");
 678                         precache_sound("misc/itempickup.wav");
 679                         precache_sound("weapons/shockwave_fire.wav");
 680                         precache_sound("weapons/shockwave_melee.wav");
 681                         SHOCKWAVE_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 682                         return TRUE;
 683                 }
 684                 case WR_CHECKAMMO1:
 685                 case WR_CHECKAMMO2:
 686                 {
 687                         // shockwave has infinite ammo
 688                         return TRUE;
 689                 }
 690                 case WR_CONFIG:
 691                 {
 692                         SHOCKWAVE_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 693                         return TRUE;
 694                 }
 695                 case WR_SUICIDEMESSAGE:
 696                 {
 697                         return WEAPON_THINKING_WITH_PORTALS;
 698                 }
 699                 case WR_KILLMESSAGE:
 700                 {
 701                         if(w_deathtype & HITTYPE_SECONDARY)
 702                                 return WEAPON_SHOCKWAVE_MURDER_SLAP;
 703                         else
 704                                 return WEAPON_SHOCKWAVE_MURDER;
 705                 }
 706         }
 707         return TRUE;
 708 }
 709 #endif
 710 #ifdef CSQC
 711 float W_Shockwave(float req)
 712 {
 713         switch(req)
 714         {
 715                 case WR_IMPACTEFFECT:
 716                 {
 717                         vector org2;
 718                         org2 = w_org + w_backoff * 2;
 719                         pointparticles(particleeffectnum("shockwave_impact"), org2, w_backoff * 1000, 1);
 720                         return TRUE;
 721                 }
 722                 case WR_INIT:
 723                 {
 724                         //precache_sound("weapons/ric1.wav");
 725                         //precache_sound("weapons/ric2.wav");
 726                         //precache_sound("weapons/ric3.wav");
 727                         return FALSE;
 728                 }
 729                 case WR_ZOOMRETICLE:
 730                 {
 731                         // no weapon specific image for this weapon
 732                         return FALSE;
 733                 }
 734         }
 735         return TRUE;
 736 }
 737 #endif
 738 #endif