qcsrc/common/weapons/w_shockwave.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ SHOCKWAVE,
   4 /* function */ W_Shockwave,
   5 /* ammotype */ IT_SHELLS,
   6 /* impulse  */ 2,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN,
   8 /* rating   */ BOT_PICKUP_RATING_LOW,
   9 /* model    */ "shotgun",
  10 /* netname  */ "shockwave",
  11 /* fullname */ _("Shockwave")
  12 );
  13
  14 #define SHOCKWAVE_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_damage) \
  16         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_distance) \
  17         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_edgedamage) \
  18         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_force) \
  19         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_force_forwardbias) \
  20         /*w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_force_velocitybias)*/ \
  21         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_force_zscale) \
  22         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_damage) \
  23         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_edgedamage) \
  24         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_force) \
  25         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_force_velocitybias) \
  26         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_force_zscale) \
  27         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_multiplier_accuracy) \
  28         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_multiplier_distance) \
  29         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_multiplier_min) \
  30         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_radius) \
  31         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_multiplier_accuracy) \
  32         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_multiplier_distance) \
  33         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_multiplier_min) \
  34         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_damage) \
  35         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_edgedamage) \
  36         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_force) \
  37         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_force_forwardbias) \
  38         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_multiplier_accuracy) \
  39         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_multiplier_distance) \
  40         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_multiplier_min) \
  41         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_radius) \
  42         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_spread_max) \
  43         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_spread_min) \
  44         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_animtime) \
  45         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_damage) \
  46         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_delay) \
  47         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_force) \
  48         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_multihit) \
  49         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_no_doubleslap) \
  50         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_nonplayerdamage) \
  51         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_range) \
  52         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_refire) \
  53         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_swing_side) \
  54         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_swing_up) \
  55         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_time) \
  56         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_traces) \
  57         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_ammo) \
  58         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_animtime) \
  59         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_bulletconstant) \
  60         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_bullets) \
  61         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_damage) \
  62         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_force) \
  63         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_refire) \
  64         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_speed) \
  65         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_spread) \
  66         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, primary) \
  67         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, secondary) \
  68         w_prop(WEP_SHOCKWAVE, shockwave, reloading_ammo, reload_ammo) \
  69         w_prop(WEP_SHOCKWAVE, shockwave, reloading_time, reload_time) \
  70         w_prop(WEP_SHOCKWAVE, shockwave, switchdelay_raise, switchdelay_raise) \
  71         w_prop(WEP_SHOCKWAVE, shockwave, switchdelay_drop, switchdelay_drop)
  72
  73 #ifdef SVQC
  74 SHOCKWAVE_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  75 #endif
  76 #else
  77 #ifdef SVQC
  78 void spawnfunc_weapon_shockwave()
  79 {
  80         //if(autocvar_sv_q3acompat_machineshockwaveswap)
  81         if(autocvar_sv_q3acompat_machineshotgunswap)
  82         if(self.classname != "droppedweapon")
  83         {
  84                 weapon_defaultspawnfunc(WEP_UZI);
  85                 return;
  86         }
  87         weapon_defaultspawnfunc(WEP_SHOCKWAVE);
  88 }
  89
  90 .float swing_prev;
  91 .entity swing_alreadyhit;
  92 .float shockwave_pelletstime;
  93 entity shockwave_hit[32];
  94 float shockwave_hit_damage[32];
  95 vector shockwave_hit_force[32];
  96
  97 // LEGACY ATTACK MODE: Scattered bullets
  98 void W_Shockwave_Pellets(void)
  99 {
 100         float sc;
 101         entity flash;
 102
 103         W_DecreaseAmmo(ammo_shells, WEP_CVAR(shockwave, pellets_ammo), WEP_CVAR(shockwave, reload_ammo));
 104
 105         W_SetupShot(self, TRUE, 5, "weapons/shockwave_fire.wav", CH_WEAPON_A, WEP_CVAR(shockwave, pellets_damage) * WEP_CVAR(shockwave, pellets_bullets));
 106
 107         for(sc = 0; sc < WEP_CVAR(shockwave, pellets_bullets); ++sc)
 108         {
 109                 fireBallisticBullet(
 110                         w_shotorg,
 111                         w_shotdir,
 112                         WEP_CVAR(shockwave, pellets_spread),
 113                         WEP_CVAR(shockwave, pellets_speed),
 114                         5,
 115                         WEP_CVAR(shockwave, pellets_damage),
 116                         WEP_CVAR(shockwave, pellets_force),
 117                         WEP_SHOCKWAVE,
 118                         0,
 119                         WEP_CVAR(shockwave, pellets_bulletconstant)
 120                 );
 121         }
 122         endFireBallisticBullet();
 123
 124         pointparticles(particleeffectnum("shockwave_muzzleflash"), w_shotorg, w_shotdir * 1000, WEP_CVAR(shockwave, pellets_ammo));
 125
 126         // casing code
 127         if(autocvar_g_casings >= 1)
 128         {
 129                 for(sc = 0;sc < WEP_CVAR(shockwave, pellets_ammo); ++sc)
 130                 {
 131                         SpawnCasing(
 132                                 (
 133                                         ((random () * 50 + 50) * v_right)
 134                                         -
 135                                         (v_forward * (random () * 25 + 25))
 136                                         -
 137                                         ((random () * 5 - 30) * v_up)
 138                                 ),
 139                                 2,
 140                                 vectoangles(v_forward),
 141                                 '0 250 0',
 142                                 100,
 143                                 1,
 144                                 self
 145                         );
 146                 }
 147         }
 148
 149         // muzzle flash for 1st person view
 150         flash = spawn();
 151         setmodel(flash, "models/uziflash.md3"); // precision set below
 152         flash.think = SUB_Remove;
 153         flash.nextthink = time + 0.06;
 154         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 155         W_AttachToShotorg(flash, '5 0 0');
 156 }
 157
 158 // MELEE ATTACK MODE
 159 void W_Shockwave_Melee_Think()
 160 {
 161         // declarations
 162         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
 163         entity target_victim;
 164         vector targpos;
 165
 166         if(!self.cnt) // set start time of melee
 167         {
 168                 self.cnt = time;
 169                 W_PlayStrengthSound(self.realowner);
 170         }
 171
 172         makevectors(self.realowner.v_angle); // update values for v_* vectors
 173
 174         // calculate swing percentage based on time
 175         meleetime = WEP_CVAR(shockwave, melee_time) * W_WeaponRateFactor();
 176         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
 177         f = ((1 - swing) * WEP_CVAR(shockwave, melee_traces));
 178
 179         // check to see if we can still continue, otherwise give up now
 180         if((self.realowner.deadflag != DEAD_NO) && WEP_CVAR(shockwave, melee_no_doubleslap))
 181         {
 182                 remove(self);
 183                 return;
 184         }
 185
 186         // if okay, perform the traces needed for this frame
 187         for(i=self.swing_prev; i < f; ++i)
 188         {
 189                 swing_factor = ((1 - (i / WEP_CVAR(shockwave, melee_traces))) * 2 - 1);
 190
 191                 targpos = (self.realowner.origin + self.realowner.view_ofs
 192                         + (v_forward * WEP_CVAR(shockwave, melee_range))
 193                         + (v_up * swing_factor * WEP_CVAR(shockwave, melee_swing_up))
 194                         + (v_right * swing_factor * WEP_CVAR(shockwave, melee_swing_side)));
 195
 196                 WarpZone_traceline_antilag(self.realowner, self.realowner.origin + self.realowner.view_ofs, targpos, FALSE, self.realowner, ANTILAG_LATENCY(self.realowner));
 197
 198                 // draw lightning beams for debugging
 199                 te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
 200                 te_customflash(targpos, 40,  2, '1 1 1');
 201
 202                 is_player = (trace_ent.classname == "player" || trace_ent.classname == "body");
 203
 204                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self
 205                         && (trace_ent.takedamage == DAMAGE_AIM)
 206                         && (trace_ent != self.swing_alreadyhit)
 207                         && (is_player || WEP_CVAR(shockwave, melee_nonplayerdamage)))
 208                 {
 209                         target_victim = trace_ent; // so it persists through other calls
 210
 211                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
 212                                 swing_damage = (WEP_CVAR(shockwave, melee_damage * min(1, swing_factor + 1)));
 213                         else
 214                                 swing_damage = (WEP_CVAR(shockwave, melee_nonplayerdamage * min(1, swing_factor + 1)));
 215
 216                         //print(strcat(self.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
 217
 218                         Damage(target_victim, self.realowner, self.realowner,
 219                                 swing_damage, WEP_SHOCKWAVE | HITTYPE_SECONDARY,
 220                                 self.realowner.origin + self.realowner.view_ofs,
 221                                 v_forward * WEP_CVAR(shockwave, melee_force));
 222
 223                         if(accuracy_isgooddamage(self.realowner, target_victim)) { accuracy_add(self.realowner, WEP_SHOCKWAVE, 0, swing_damage); }
 224
 225                         if(WEP_CVAR(shockwave, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
 226                         {
 227                                 self.swing_alreadyhit = target_victim;
 228                                 continue; // move along to next trace
 229                         }
 230                         else
 231                         {
 232                                 remove(self);
 233                                 return;
 234                         }
 235                 }
 236         }
 237
 238         if(time >= self.cnt + meleetime)
 239         {
 240                 // melee is finished
 241                 remove(self);
 242                 return;
 243         }
 244         else
 245         {
 246                 // set up next frame
 247                 self.swing_prev = i;
 248                 self.nextthink = time;
 249         }
 250 }
 251
 252 void W_Shockwave_Melee()
 253 {
 254         sound(self, CH_WEAPON_A, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 255         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(shockwave, melee_animtime), w_ready);
 256
 257         entity meleetemp;
 258         meleetemp = spawn();
 259         meleetemp.owner = meleetemp.realowner = self;
 260         meleetemp.think = W_Shockwave_Melee_Think;
 261         meleetemp.nextthink = time + WEP_CVAR(shockwave, melee_delay) * W_WeaponRateFactor();
 262         W_SetupShot_Range(self, TRUE, 0, "", 0, WEP_CVAR(shockwave, melee_damage), WEP_CVAR(shockwave, melee_range));
 263 }
 264
 265 // SHOCKWAVE ATTACK MODE
 266 float W_Shockwave_Attack_CheckSpread(
 267         vector targetorg,
 268         vector nearest_on_line,
 269         vector sw_shotorg,
 270         vector attack_endpos)
 271 {
 272         float spreadlimit;
 273         float distance_of_attack = vlen(sw_shotorg - attack_endpos);
 274         float distance_from_line = vlen(targetorg - nearest_on_line);
 275
 276         spreadlimit = (distance_of_attack ? min(1, (vlen(sw_shotorg - nearest_on_line) / distance_of_attack)) : 1);
 277         spreadlimit =
 278                 (
 279                         (WEP_CVAR(shockwave, blast_spread_min) * (1 - spreadlimit))
 280                         +
 281                         (WEP_CVAR(shockwave, blast_spread_max) * spreadlimit)
 282                 );
 283
 284         if(
 285                 (spreadlimit && (distance_from_line <= spreadlimit))
 286                 &&
 287                 ((vlen(normalize(targetorg - sw_shotorg) - normalize(attack_endpos - sw_shotorg)) * RAD2DEG) <= 90)
 288         )
 289                 { return bound(0, (distance_from_line / spreadlimit), 1); }
 290         else
 291                 { return FALSE; }
 292 }
 293
 294 float W_Shockwave_Attack_IsVisible(
 295         entity head,
 296         vector nearest_on_line,
 297         vector sw_shotorg,
 298         vector attack_endpos)
 299 {
 300         vector nearest_to_attacker = head.WarpZone_findradius_nearest;
 301         vector center = (head.origin + (head.mins + head.maxs) * 0.5);
 302         vector corner;
 303         float i;
 304
 305         // STEP ONE: Check if the nearest point is clear
 306         if(W_Shockwave_Attack_CheckSpread(nearest_to_attacker, nearest_on_line, sw_shotorg, attack_endpos))
 307         {
 308                 WarpZone_TraceLine(sw_shotorg, nearest_to_attacker, MOVE_NOMONSTERS, self);
 309                 if(trace_fraction == 1) { return TRUE; } // yes, the nearest point is clear and we can allow the damage
 310         }
 311
 312         // STEP TWO: Check if shotorg to center point is clear
 313         if(W_Shockwave_Attack_CheckSpread(center, nearest_on_line, sw_shotorg, attack_endpos))
 314         {
 315                 WarpZone_TraceLine(sw_shotorg, center, MOVE_NOMONSTERS, self);
 316                 if(trace_fraction == 1) { return TRUE; } // yes, the center point is clear and we can allow the damage
 317         }
 318
 319         // STEP THREE: Check each corner to see if they are clear
 320         for(i=1; i<=8; ++i)
 321         {
 322                 corner = get_corner_position(head, i);
 323                 if(W_Shockwave_Attack_CheckSpread(corner, nearest_on_line, sw_shotorg, attack_endpos))
 324                 {
 325                         WarpZone_TraceLine(sw_shotorg, corner, MOVE_NOMONSTERS, self);
 326                         if(trace_fraction == 1) { return TRUE; } // yes, this corner is clear and we can allow the damage
 327                 }
 328         }
 329
 330         return FALSE;
 331 }
 332
 333 float W_Shockwave_Attack_CheckHit(
 334         float queue,
 335         entity head,
 336         vector final_force,
 337         float final_damage)
 338 {
 339         if(!head) { return FALSE; }
 340         float i;
 341
 342         ++queue;
 343
 344         for(i = 1; i <= queue; ++i)
 345         {
 346                 if(shockwave_hit[i] == head)
 347                 {
 348                         if(vlen(final_force) > vlen(shockwave_hit_force[i])) { shockwave_hit_force[i] = final_force; }
 349                         if(final_damage > shockwave_hit_damage[i]) { shockwave_hit_damage[i] = final_damage; }
 350                         return FALSE;
 351                 }
 352         }
 353
 354         shockwave_hit[queue] = head;
 355         shockwave_hit_force[queue] = final_force;
 356         shockwave_hit_damage[queue] = final_damage;
 357         return TRUE;
 358 }
 359
 360 void W_Shockwave_Attack()
 361 {
 362         // declarations
 363         float multiplier, multiplier_from_accuracy, multiplier_from_distance;
 364         float final_damage; //, final_spread;
 365         vector final_force, center, vel;
 366         entity head, next;
 367
 368         float i, queue = 0;
 369
 370         // set up the shot direction
 371         W_SetupShot(self, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, WEP_CVAR(shockwave, blast_damage));
 372         vector attack_endpos = (w_shotorg + (w_shotdir * WEP_CVAR(shockwave, blast_distance)));
 373         WarpZone_TraceLine(w_shotorg, attack_endpos, MOVE_NOMONSTERS, self);
 374         vector attack_hitpos = trace_endpos;
 375         float distance_to_end = vlen(w_shotorg - attack_endpos);
 376         float distance_to_hit = vlen(w_shotorg - attack_hitpos);
 377         //entity transform = WarpZone_trace_transform;
 378
 379         // do the firing effect now
 380         //SendCSQCShockwaveParticle(attack_endpos); // WEAPONTODO
 381         Damage_DamageInfo(
 382                 attack_hitpos,
 383                 WEP_CVAR(shockwave, blast_splash_damage),
 384                 WEP_CVAR(shockwave, blast_splash_edgedamage),
 385                 WEP_CVAR(shockwave, blast_splash_radius),
 386                 w_shotdir * WEP_CVAR(shockwave, blast_splash_force),
 387                 WEP_SHOCKWAVE,
 388                 0,
 389                 self
 390         );
 391
 392         // splash damage/jumping trace
 393         head = WarpZone_FindRadius(
 394                 attack_hitpos,
 395                 max(
 396                         WEP_CVAR(shockwave, blast_splash_radius),
 397                         WEP_CVAR(shockwave, blast_jump_radius)
 398                 ),
 399                 FALSE
 400         );
 401
 402         while(head)
 403         {
 404                 next = head.chain;
 405
 406                 if(head.takedamage)
 407                 {
 408                         float distance_to_head = vlen(attack_hitpos - head.WarpZone_findradius_nearest);
 409
 410                         if((head == self) && (distance_to_head <= WEP_CVAR(shockwave, blast_jump_radius)))
 411                         {
 412                                 // calculate importance of distance and accuracy for this attack
 413                                 multiplier_from_accuracy = (1 - (distance_to_head ? min(1, (distance_to_head / WEP_CVAR(shockwave, blast_jump_radius))) : 0));
 414                                 multiplier_from_distance = (1 - (distance_to_hit ? min(1, (distance_to_hit / distance_to_end)) : 0));
 415                                 multiplier =
 416                                         max(
 417                                                 WEP_CVAR(shockwave, blast_jump_multiplier_min),
 418                                                 (
 419                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_jump_multiplier_accuracy))
 420                                                         +
 421                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_jump_multiplier_distance))
 422                                                 )
 423                                         );
 424
 425                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 426                                 final_damage =
 427                                         (
 428                                                 (WEP_CVAR(shockwave, blast_jump_damage) * multiplier)
 429                                                 +
 430                                                 (WEP_CVAR(shockwave, blast_jump_edgedamage) * (1 - multiplier))
 431                                         );
 432
 433                                 // figure out the direction of force
 434                                 vel = normalize(combine_to_vector(head.velocity_x, head.velocity_y, 0));
 435                                 vel *=
 436                                         (
 437                                                 bound(0, (vlen(vel) / autocvar_sv_maxspeed), 1)
 438                                                 *
 439                                                 WEP_CVAR(shockwave, blast_jump_force_velocitybias)
 440                                         );
 441
 442                                 final_force = normalize((CENTER_OR_VIEWOFS(head) - attack_hitpos) + vel);
 443
 444                                 // now multiply the direction by force units
 445                                 final_force *= (WEP_CVAR(shockwave, blast_jump_force) * multiplier);
 446                                 final_force_z *= WEP_CVAR(shockwave, blast_jump_force_zscale);
 447
 448                                 // trigger damage with this calculated info
 449                                 Damage(
 450                                         head,
 451                                         self,
 452                                         self,
 453                                         final_damage,
 454                                         WEP_SHOCKWAVE,
 455                                         head.origin,
 456                                         final_force
 457                                 );
 458
 459                                 #ifdef DEBUG_SHOCKWAVE
 460                                 print(sprintf(
 461                                         "SELF HIT: multiplier = %f, damage = %f, force = %f... "
 462                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 463                                         multiplier,
 464                                         final_damage,
 465                                         vlen(final_force),
 466                                         multiplier_from_accuracy,
 467                                         multiplier_from_distance
 468                                 );
 469                                 #endif
 470                         }
 471                         else if(distance_to_head <= WEP_CVAR(shockwave, blast_splash_radius))
 472                         {
 473                                 multiplier_from_accuracy = (1 - (distance_to_head ? min(1, (distance_to_head / WEP_CVAR(shockwave, blast_splash_radius))) : 0));
 474                                 multiplier_from_distance = (1 - (distance_to_hit ? min(1, (distance_to_hit / distance_to_end)) : 0));
 475                                 multiplier =
 476                                         max(
 477                                                 WEP_CVAR(shockwave, blast_splash_multiplier_min),
 478                                                 (
 479                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_splash_multiplier_accuracy))
 480                                                         +
 481                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_splash_multiplier_distance))
 482                                                 )
 483                                         );
 484
 485                                 final_force = normalize(CENTER_OR_VIEWOFS(head) - (attack_hitpos - (w_shotdir * WEP_CVAR(shockwave, blast_splash_force_forwardbias))));
 486                                 //te_lightning2(world, attack_hitpos, (attack_hitpos + (final_force * 200)));
 487                                 final_force = ((final_force * WEP_CVAR(shockwave, blast_splash_force)) * multiplier);
 488                                 final_force_z *= WEP_CVAR(shockwave, blast_force_zscale);
 489                                 final_damage =
 490                                         (
 491                                                 (WEP_CVAR(shockwave, blast_splash_damage) * multiplier)
 492                                                 +
 493                                                 (WEP_CVAR(shockwave, blast_splash_edgedamage) * (1 - multiplier))
 494                                         );
 495
 496                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { ++queue; }
 497                                 //print("SPLASH HIT: multiplier = ", ftos(multiplier), strcat(", damage = ", ftos(final_damage), ", force = ", ftos(vlen(final_force))),"... multiplier_from_accuracy = ", ftos(multiplier_from_accuracy), ", multiplier_from_distance = ", ftos(multiplier_from_distance), ".\n");
 498                         }
 499                 }
 500                 head = next;
 501         }
 502
 503         // cone damage trace
 504         head = WarpZone_FindRadius(w_shotorg, WEP_CVAR(shockwave, blast_distance), FALSE);
 505         while(head)
 506         {
 507                 next = head.chain;
 508
 509                 if((head != self) && head.takedamage)
 510                 {
 511                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 512                         center = CENTER_OR_VIEWOFS(head);
 513
 514                         // find the closest point on the enemy to the center of the attack
 515                         float ang; // angle between shotdir and h
 516                         float h; // hypotenuse, which is the distance between attacker to head
 517                         float a; // adjacent side, which is the distance between attacker and the point on w_shotdir that is closest to head.origin
 518
 519                         h = vlen(center - self.origin);
 520                         ang = acos(dotproduct(normalize(center - self.origin), w_shotdir));
 521                         a = h * cos(ang);
 522                         // WEAPONTODO: replace with simpler method
 523
 524                         vector nearest_on_line = (w_shotorg + a * w_shotdir);
 525                         vector nearest_to_attacker = WarpZoneLib_NearestPointOnBox(center + head.mins, center + head.maxs, nearest_on_line);
 526                         float distance_to_target = vlen(w_shotorg - nearest_to_attacker); // todo: use the findradius function for this
 527
 528                         if((distance_to_target <= WEP_CVAR(shockwave, blast_distance))
 529                                 && (W_Shockwave_Attack_IsVisible(head, nearest_on_line, w_shotorg, attack_endpos)))
 530                         {
 531                                 multiplier_from_accuracy = (1 - W_Shockwave_Attack_CheckSpread(nearest_to_attacker, nearest_on_line, w_shotorg, attack_endpos));
 532                                 multiplier_from_distance = (1 - (distance_to_hit ? min(1, (distance_to_target / distance_to_end)) : 0));
 533                                 multiplier =
 534                                         max(
 535                                                 WEP_CVAR(shockwave, blast_multiplier_min),
 536                                                 (
 537                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_multiplier_accuracy))
 538                                                         +
 539                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_multiplier_distance))
 540                                                 )
 541                                         );
 542
 543                                 final_force = normalize(center - (nearest_on_line - (w_shotdir * WEP_CVAR(shockwave, blast_force_forwardbias))));
 544                                 //te_lightning2(world, nearest_on_line, (attack_hitpos + (final_force * 200)));
 545                                 final_force = ((final_force * WEP_CVAR(shockwave, blast_force)) * multiplier);
 546                                 final_force_z *= WEP_CVAR(shockwave, blast_force_zscale);
 547                                 final_damage = (WEP_CVAR(shockwave, blast_damage) * multiplier + WEP_CVAR(shockwave, blast_edgedamage) * (1 - multiplier));
 548
 549                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { ++queue; }
 550                                 //print("CONE HIT: multiplier = ", ftos(multiplier), strcat(", damage = ", ftos(final_damage), ", force = ", ftos(vlen(final_force))),"... multiplier_from_accuracy = ", ftos(multiplier_from_accuracy), ", multiplier_from_distance = ", ftos(multiplier_from_distance), ".\n");
 551                         }
 552                 }
 553                 head = next;
 554         }
 555
 556         for(i = 1; i <= queue; ++i)
 557         {
 558                 head = shockwave_hit[i];
 559                 final_force = shockwave_hit_force[i];
 560                 final_damage = shockwave_hit_damage[i];
 561
 562                 Damage(head, self, self, final_damage, WEP_SHOCKWAVE, head.origin, final_force);
 563                 print("SHOCKWAVE by ", self.netname, ": damage = ", ftos(final_damage), ", force = ", ftos(vlen(final_force)), ".\n");
 564
 565                 shockwave_hit[i] = world;
 566                 shockwave_hit_force[i] = '0 0 0';
 567                 shockwave_hit_damage[i] = 0;
 568         }
 569         //print("queue was ", ftos(queue), ".\n\n");
 570 }
 571
 572 float W_Shockwave(float req)
 573 {
 574         float ammo_amount;
 575         switch(req)
 576         {
 577                 case WR_AIM:
 578                 {
 579                         if(vlen(self.origin - self.enemy.origin) <= WEP_CVAR(shockwave, melee_range))
 580                                 { self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE); }
 581                         else
 582                                 { self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE); }
 583
 584                         return TRUE;
 585                 }
 586                 case WR_THINK:
 587                 {
 588                         if(WEP_CVAR(shockwave, reload_ammo) && self.clip_load < WEP_CVAR(shockwave, pellets_ammo)) // forced reload
 589                         {
 590                                 // don't force reload an empty shockwave if its melee attack is active
 591                                 if(!(WEP_CVAR(shockwave, secondary) && self.ammo_shells < WEP_CVAR(shockwave, pellets_ammo)))
 592                                         WEP_ACTION(self.weapon, WR_RELOAD);
 593                         }
 594                         else
 595                         {
 596                                 if(self.BUTTON_ATCK)
 597                                 {
 598                                         switch(WEP_CVAR(shockwave, primary))
 599                                         {
 600                                                 case 1:
 601                                                 {
 602                                                         if(time >= self.shockwave_pelletstime) // handle refire separately so the secondary can be fired straight after a primary
 603                                                         {
 604                                                                 if(weapon_prepareattack(0, WEP_CVAR(shockwave, pellets_animtime)))
 605                                                                 {
 606                                                                         W_Shockwave_Attack();
 607                                                                         self.shockwave_pelletstime = time + WEP_CVAR(shockwave, pellets_refire) * W_WeaponRateFactor();
 608                                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(shockwave, pellets_animtime), w_ready);
 609                                                                 }
 610                                                         }
 611                                                         break;
 612                                                 }
 613                                                 case 2:
 614                                                 {
 615                                                         if(time >= self.shockwave_pelletstime) // handle refire separately so the secondary can be fired straight after a primary
 616                                                         {
 617                                                                 if(weapon_prepareattack(0, WEP_CVAR(shockwave, pellets_animtime)))
 618                                                                 {
 619                                                                         W_Shockwave_Pellets();
 620                                                                         self.shockwave_pelletstime = time + WEP_CVAR(shockwave, pellets_refire) * W_WeaponRateFactor();
 621                                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(shockwave, pellets_animtime), w_ready);
 622                                                                 }
 623                                                         }
 624                                                         break;
 625                                                 }
 626                                         }
 627                                 }
 628
 629                                 if(self.clip_load >= 0) // we are not currently reloading
 630                                 if(!self.crouch) // no crouchmelee please
 631                                 if(self.BUTTON_ATCK2 && WEP_CVAR(shockwave, secondary))
 632                                 if(weapon_prepareattack(1, WEP_CVAR(shockwave, melee_refire)))
 633                                 {
 634                                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 635                                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shockwave_Melee);
 636                                 }
 637                         }
 638
 639                         return TRUE;
 640                 }
 641                 case WR_INIT:
 642                 {
 643                         precache_model("models/uziflash.md3");
 644                         precache_model("models/weapons/g_shockwave.md3");
 645                         precache_model("models/weapons/v_shockwave.md3");
 646                         precache_model("models/weapons/h_shockwave.iqm");
 647                         precache_sound("misc/itempickup.wav");
 648                         precache_sound("weapons/shockwave_fire.wav");
 649                         precache_sound("weapons/shockwave_melee.wav");
 650                         SHOCKWAVE_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 651                         return TRUE;
 652                 }
 653                 case WR_SETUP:
 654                 {
 655                         self.current_ammo = ammo_shells;
 656                         return TRUE;
 657                 }
 658                 case WR_CHECKAMMO1:
 659                 {
 660                         ammo_amount = self.ammo_shells >= WEP_CVAR(shockwave, pellets_ammo);
 661                         ammo_amount += self.(weapon_load[WEP_SHOCKWAVE]) >= WEP_CVAR(shockwave, pellets_ammo);
 662                         return ammo_amount;
 663                 }
 664                 case WR_CHECKAMMO2:
 665                 {
 666                         // melee attack is always available
 667                         return TRUE;
 668                 }
 669                 case WR_CONFIG:
 670                 {
 671                         SHOCKWAVE_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 672                         return TRUE;
 673                 }
 674                 case WR_RELOAD:
 675                 {
 676                         W_Reload(WEP_CVAR(shockwave, pellets_ammo), "weapons/reload.wav");
 677                         return TRUE;
 678                 }
 679                 case WR_SUICIDEMESSAGE:
 680                 {
 681                         return WEAPON_THINKING_WITH_PORTALS;
 682                 }
 683                 case WR_KILLMESSAGE:
 684                 {
 685                         if(w_deathtype & HITTYPE_SECONDARY)
 686                                 return WEAPON_SHOCKWAVE_MURDER_SLAP;
 687                         else
 688                                 return WEAPON_SHOCKWAVE_MURDER;
 689                 }
 690         }
 691         return TRUE;
 692 }
 693 #endif
 694 #ifdef CSQC
 695 float W_Shockwave(float req)
 696 {
 697         switch(req)
 698         {
 699                 case WR_IMPACTEFFECT:
 700                 {
 701                         vector org2;
 702                         org2 = w_org + w_backoff * 2;
 703                         pointparticles(particleeffectnum("shockwave_impact"), org2, w_backoff * 1000, 1);
 704                         return TRUE;
 705                 }
 706                 case WR_INIT:
 707                 {
 708                         //precache_sound("weapons/ric1.wav");
 709                         //precache_sound("weapons/ric2.wav");
 710                         //precache_sound("weapons/ric3.wav");
 711                         return FALSE;
 712                 }
 713         }
 714         return TRUE;
 715 }
 716 #endif
 717 #endif