qcsrc/common/weapons/w_shockwave.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ SHOCKWAVE,
   4 /* function */ W_Shockwave,
   5 /* ammotype */ IT_SHELLS,
   6 /* impulse  */ 2,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN,
   8 /* rating   */ BOT_PICKUP_RATING_LOW,
   9 /* model    */ "shotgun",
  10 /* netname  */ "shockwave",
  11 /* fullname */ _("Shockwave")
  12 );
  13
  14 #define SHOCKWAVE_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_damage) \
  16         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_distance) \
  17         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_edgedamage) \
  18         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_force) \
  19         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_force_forwardbias) \
  20         /*w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_force_velocitybias)*/ \
  21         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_force_zscale) \
  22         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_damage) \
  23         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_edgedamage) \
  24         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_force) \
  25         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_force_velocitybias) \
  26         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_force_zscale) \
  27         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_multiplier_accuracy) \
  28         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_multiplier_distance) \
  29         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_multiplier_min) \
  30         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_radius) \
  31         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_multiplier_accuracy) \
  32         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_multiplier_distance) \
  33         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_multiplier_min) \
  34         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_damage) \
  35         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_edgedamage) \
  36         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_force) \
  37         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_force_forwardbias) \
  38         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_multiplier_accuracy) \
  39         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_multiplier_distance) \
  40         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_multiplier_min) \
  41         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_radius) \
  42         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_spread_max) \
  43         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_spread_min) \
  44         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_animtime) \
  45         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_damage) \
  46         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_delay) \
  47         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_force) \
  48         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_multihit) \
  49         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_no_doubleslap) \
  50         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_nonplayerdamage) \
  51         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_range) \
  52         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_refire) \
  53         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_swing_side) \
  54         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_swing_up) \
  55         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_time) \
  56         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_traces) \
  57         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_ammo) \
  58         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_animtime) \
  59         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_bulletconstant) \
  60         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_bullets) \
  61         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_damage) \
  62         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_force) \
  63         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_refire) \
  64         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_speed) \
  65         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_spread) \
  66         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, secondary) \
  67         w_prop(WEP_SHOCKWAVE, shockwave, reloading_ammo, reload_ammo) \
  68         w_prop(WEP_SHOCKWAVE, shockwave, reloading_time, reload_time) \
  69         w_prop(WEP_SHOCKWAVE, shockwave, switchdelay_raise, switchdelay_raise) \
  70         w_prop(WEP_SHOCKWAVE, shockwave, switchdelay_drop, switchdelay_drop)
  71
  72 #ifdef SVQC
  73 SHOCKWAVE_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  74 #endif
  75 #else
  76 #ifdef SVQC
  77 void spawnfunc_weapon_shockwave()
  78 {
  79         //if(autocvar_sv_q3acompat_machineshockwaveswap)
  80         if(autocvar_sv_q3acompat_machineshotgunswap)
  81         if(self.classname != "droppedweapon")
  82         {
  83                 weapon_defaultspawnfunc(WEP_UZI);
  84                 return;
  85         }
  86         weapon_defaultspawnfunc(WEP_SHOCKWAVE);
  87 }
  88
  89 .float swing_prev;
  90 .entity swing_alreadyhit;
  91 .float shockwave_pelletstime;
  92 entity shockwave_hit[32];
  93 float shockwave_hit_damage[32];
  94 vector shockwave_hit_force[32];
  95
  96 // LEGACY ATTACK MODE: Scattered bullets
  97 void W_Shockwave_Pellets(void)
  98 {
  99         float sc;
 100         entity flash;
 101
 102         W_DecreaseAmmo(ammo_shells, WEP_CVAR(shockwave, pellets_ammo), WEP_CVAR(shockwave, reload_ammo));
 103
 104         W_SetupShot(self, TRUE, 5, "weapons/shockwave_fire.wav", CH_WEAPON_A, WEP_CVAR(shockwave, pellets_damage) * WEP_CVAR(shockwave, pellets_bullets));
 105
 106         for(sc = 0; sc < WEP_CVAR(shockwave, pellets_bullets); ++sc)
 107         {
 108                 fireBallisticBullet(
 109                         w_shotorg,
 110                         w_shotdir,
 111                         WEP_CVAR(shockwave, pellets_spread),
 112                         WEP_CVAR(shockwave, pellets_speed),
 113                         5,
 114                         WEP_CVAR(shockwave, pellets_damage),
 115                         WEP_CVAR(shockwave, pellets_force),
 116                         WEP_SHOCKWAVE,
 117                         0,
 118                         WEP_CVAR(shockwave, pellets_bulletconstant)
 119                 );
 120         }
 121         endFireBallisticBullet();
 122
 123         pointparticles(particleeffectnum("shockwave_muzzleflash"), w_shotorg, w_shotdir * 1000, WEP_CVAR(shockwave, pellets_ammo));
 124
 125         // casing code
 126         if(autocvar_g_casings >= 1)
 127         {
 128                 for(sc = 0;sc < WEP_CVAR(shockwave, pellets_ammo); ++sc)
 129                 {
 130                         SpawnCasing(
 131                                 (
 132                                         ((random () * 50 + 50) * v_right)
 133                                         -
 134                                         (v_forward * (random () * 25 + 25))
 135                                         -
 136                                         ((random () * 5 - 30) * v_up)
 137                                 ),
 138                                 2,
 139                                 vectoangles(v_forward),
 140                                 '0 250 0',
 141                                 100,
 142                                 1,
 143                                 self
 144                         );
 145                 }
 146         }
 147
 148         // muzzle flash for 1st person view
 149         flash = spawn();
 150         setmodel(flash, "models/uziflash.md3"); // precision set below
 151         flash.think = SUB_Remove;
 152         flash.nextthink = time + 0.06;
 153         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 154         W_AttachToShotorg(flash, '5 0 0');
 155 }
 156
 157 // MELEE ATTACK MODE
 158 void W_Shockwave_Melee_Think()
 159 {
 160         // declarations
 161         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
 162         entity target_victim;
 163         vector targpos;
 164
 165         if(!self.cnt) // set start time of melee
 166         {
 167                 self.cnt = time;
 168                 W_PlayStrengthSound(self.realowner);
 169         }
 170
 171         makevectors(self.realowner.v_angle); // update values for v_* vectors
 172
 173         // calculate swing percentage based on time
 174         meleetime = WEP_CVAR(shockwave, melee_time) * W_WeaponRateFactor();
 175         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
 176         f = ((1 - swing) * WEP_CVAR(shockwave, melee_traces));
 177
 178         // check to see if we can still continue, otherwise give up now
 179         if((self.realowner.deadflag != DEAD_NO) && WEP_CVAR(shockwave, melee_no_doubleslap))
 180         {
 181                 remove(self);
 182                 return;
 183         }
 184
 185         // if okay, perform the traces needed for this frame
 186         for(i=self.swing_prev; i < f; ++i)
 187         {
 188                 swing_factor = ((1 - (i / WEP_CVAR(shockwave, melee_traces))) * 2 - 1);
 189
 190                 targpos = (self.realowner.origin + self.realowner.view_ofs
 191                         + (v_forward * WEP_CVAR(shockwave, melee_range))
 192                         + (v_up * swing_factor * WEP_CVAR(shockwave, melee_swing_up))
 193                         + (v_right * swing_factor * WEP_CVAR(shockwave, melee_swing_side)));
 194
 195                 WarpZone_traceline_antilag(self.realowner, self.realowner.origin + self.realowner.view_ofs, targpos, FALSE, self.realowner, ANTILAG_LATENCY(self.realowner));
 196
 197                 // draw lightning beams for debugging
 198                 te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
 199                 te_customflash(targpos, 40,  2, '1 1 1');
 200
 201                 is_player = (trace_ent.classname == "player" || trace_ent.classname == "body");
 202
 203                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self
 204                         && (trace_ent.takedamage == DAMAGE_AIM)
 205                         && (trace_ent != self.swing_alreadyhit)
 206                         && (is_player || WEP_CVAR(shockwave, melee_nonplayerdamage)))
 207                 {
 208                         target_victim = trace_ent; // so it persists through other calls
 209
 210                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
 211                                 swing_damage = (WEP_CVAR(shockwave, melee_damage * min(1, swing_factor + 1)));
 212                         else
 213                                 swing_damage = (WEP_CVAR(shockwave, melee_nonplayerdamage * min(1, swing_factor + 1)));
 214
 215                         //print(strcat(self.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
 216
 217                         Damage(target_victim, self.realowner, self.realowner,
 218                                 swing_damage, WEP_SHOCKWAVE | HITTYPE_SECONDARY,
 219                                 self.realowner.origin + self.realowner.view_ofs,
 220                                 v_forward * WEP_CVAR(shockwave, melee_force));
 221
 222                         if(accuracy_isgooddamage(self.realowner, target_victim)) { accuracy_add(self.realowner, WEP_SHOCKWAVE, 0, swing_damage); }
 223
 224                         if(WEP_CVAR(shockwave, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
 225                         {
 226                                 self.swing_alreadyhit = target_victim;
 227                                 continue; // move along to next trace
 228                         }
 229                         else
 230                         {
 231                                 remove(self);
 232                                 return;
 233                         }
 234                 }
 235         }
 236
 237         if(time >= self.cnt + meleetime)
 238         {
 239                 // melee is finished
 240                 remove(self);
 241                 return;
 242         }
 243         else
 244         {
 245                 // set up next frame
 246                 self.swing_prev = i;
 247                 self.nextthink = time;
 248         }
 249 }
 250
 251 void W_Shockwave_Melee()
 252 {
 253         sound(self, CH_WEAPON_A, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 254         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(shockwave, melee_animtime), w_ready);
 255
 256         entity meleetemp;
 257         meleetemp = spawn();
 258         meleetemp.owner = meleetemp.realowner = self;
 259         meleetemp.think = W_Shockwave_Melee_Think;
 260         meleetemp.nextthink = time + WEP_CVAR(shockwave, melee_delay) * W_WeaponRateFactor();
 261         W_SetupShot_Range(self, TRUE, 0, "", 0, WEP_CVAR(shockwave, melee_damage), WEP_CVAR(shockwave, melee_range));
 262 }
 263
 264 // SHOCKWAVE ATTACK MODE
 265 float W_Shockwave_Attack_CheckSpread(
 266         vector targetorg,
 267         vector nearest_on_line,
 268         vector sw_shotorg,
 269         vector attack_endpos)
 270 {
 271         float spreadlimit;
 272         float distance_of_attack = vlen(sw_shotorg - attack_endpos);
 273         float distance_from_line = vlen(targetorg - nearest_on_line);
 274
 275         spreadlimit = (distance_of_attack ? min(1, (vlen(sw_shotorg - nearest_on_line) / distance_of_attack)) : 1);
 276         spreadlimit = (WEP_CVAR(shockwave, blast_spread_min) * (1 - spreadlimit) + WEP_CVAR(shockwave, blast_spread_max) * spreadlimit);
 277
 278         if(
 279                 (spreadlimit && (distance_from_line <= spreadlimit))
 280                 &&
 281                 ((vlen(normalize(targetorg - sw_shotorg) - normalize(attack_endpos - sw_shotorg)) * RAD2DEG) <= 90)
 282         )
 283                 { return bound(0, (distance_from_line / spreadlimit), 1); }
 284         else
 285                 { return FALSE; }
 286 }
 287
 288 float W_Shockwave_Attack_IsVisible(
 289         entity head,
 290         vector nearest_on_line,
 291         vector sw_shotorg,
 292         vector attack_endpos)
 293 {
 294         vector nearest_to_attacker = head.WarpZone_findradius_nearest;
 295         vector center = (head.origin + (head.mins + head.maxs) * 0.5);
 296         vector corner;
 297         float i;
 298
 299         // STEP ONE: Check if the nearest point is clear
 300         if(W_Shockwave_Attack_CheckSpread(nearest_to_attacker, nearest_on_line, sw_shotorg, attack_endpos))
 301         {
 302                 WarpZone_TraceLine(sw_shotorg, nearest_to_attacker, MOVE_NOMONSTERS, self);
 303                 if(trace_fraction == 1) { return TRUE; } // yes, the nearest point is clear and we can allow the damage
 304         }
 305
 306         // STEP TWO: Check if shotorg to center point is clear
 307         if(W_Shockwave_Attack_CheckSpread(center, nearest_on_line, sw_shotorg, attack_endpos))
 308         {
 309                 WarpZone_TraceLine(sw_shotorg, center, MOVE_NOMONSTERS, self);
 310                 if(trace_fraction == 1) { return TRUE; } // yes, the center point is clear and we can allow the damage
 311         }
 312
 313         // STEP THREE: Check each corner to see if they are clear
 314         for(i=1; i<=8; ++i)
 315         {
 316                 corner = get_corner_position(head, i);
 317                 if(W_Shockwave_Attack_CheckSpread(corner, nearest_on_line, sw_shotorg, attack_endpos))
 318                 {
 319                         WarpZone_TraceLine(sw_shotorg, corner, MOVE_NOMONSTERS, self);
 320                         if(trace_fraction == 1) { return TRUE; } // yes, this corner is clear and we can allow the damage
 321                 }
 322         }
 323
 324         return FALSE;
 325 }
 326
 327 float W_Shockwave_Attack_CheckHit(
 328         float queue,
 329         entity head,
 330         vector final_force,
 331         float final_damage)
 332 {
 333         if not(head) { return FALSE; }
 334         float i;
 335
 336         ++queue;
 337
 338         for(i = 1; i <= queue; ++i)
 339         {
 340                 if(shockwave_hit[i] == head)
 341                 {
 342                         if(vlen(final_force) > vlen(shockwave_hit_force[i])) { shockwave_hit_force[i] = final_force; }
 343                         if(final_damage > shockwave_hit_damage[i]) { shockwave_hit_damage[i] = final_damage; }
 344                         return FALSE;
 345                 }
 346         }
 347
 348         shockwave_hit[queue] = head;
 349         shockwave_hit_force[queue] = final_force;
 350         shockwave_hit_damage[queue] = final_damage;
 351         return TRUE;
 352 }
 353
 354 void W_Shockwave_Attack()
 355 {
 356         // declarations
 357         float multiplier, multiplier_from_accuracy, multiplier_from_distance;
 358         float final_damage; //, final_spread;
 359         vector final_force, center, vel;
 360         entity head, next;
 361
 362         float i, queue = 0;
 363
 364         // set up the shot direction
 365         W_SetupShot(self, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, WEP_CVAR(shockwave, blast_damage));
 366         vector attack_endpos = (w_shotorg + (w_shotdir * WEP_CVAR(shockwave, blast_distance)));
 367         WarpZone_TraceLine(w_shotorg, attack_endpos, MOVE_NOMONSTERS, self);
 368         vector attack_hitpos = trace_endpos;
 369         float distance_to_end = vlen(w_shotorg - attack_endpos);
 370         float distance_to_hit = vlen(w_shotorg - attack_hitpos);
 371         //entity transform = WarpZone_trace_transform;
 372
 373         // do the firing effect now
 374         //SendCSQCShockwaveParticle(attack_endpos); // WEAPONTODO
 375         Damage_DamageInfo(attack_hitpos, WEP_CVAR(shockwave, blast_splash_damage), WEP_CVAR(shockwave, blast_splash_edgedamage), WEP_CVAR(shockwave, blast_splash_radius), w_shotdir * WEP_CVAR(shockwave, blast_splash_force), WEP_SHOCKWAVE, 0, self);
 376
 377         // splash damage/jumping trace
 378         head = WarpZone_FindRadius(attack_hitpos, max(WEP_CVAR(shockwave, blast_splash_radius), WEP_CVAR(shockwave, blast_jump_radius)), FALSE);
 379         while(head)
 380         {
 381                 next = head.chain;
 382
 383                 if(head.takedamage)
 384                 {
 385                         center = CENTER_OR_VIEWOFS(head);
 386
 387                         float distance_to_head = vlen(attack_hitpos - head.WarpZone_findradius_nearest);
 388
 389                         if((head == self) && (distance_to_head <= WEP_CVAR(shockwave, blast_jump_radius)))
 390                         {
 391                                 multiplier_from_accuracy = (1 - (distance_to_head ? min(1, (distance_to_head / WEP_CVAR(shockwave, blast_jump_radius))) : 0));
 392                                 multiplier_from_distance = (1 - (distance_to_hit ? min(1, (distance_to_hit / distance_to_end)) : 0));
 393                                 multiplier = max(WEP_CVAR(shockwave, blast_jump_multiplier_min), ((multiplier_from_accuracy * WEP_CVAR(shockwave, blast_jump_multiplier_accuracy)) + (multiplier_from_distance * WEP_CVAR(shockwave, blast_jump_multiplier_distance))));
 394
 395                                 final_force = ((normalize(center - attack_hitpos) * WEP_CVAR(shockwave, blast_jump_force)) * multiplier);
 396                                 vel = head.velocity; vel_z = 0;
 397                                 vel = normalize(vel) * bound(0, vlen(vel) / autocvar_sv_maxspeed, 1) * WEP_CVAR(shockwave, blast_jump_force_velocitybias);
 398                                 final_force = (vlen(final_force) * normalize(normalize(final_force) + vel));
 399                                 final_force_z *= WEP_CVAR(shockwave, blast_jump_force_zscale);
 400                                 final_damage = (WEP_CVAR(shockwave, blast_jump_damage) * multiplier + WEP_CVAR(shockwave, blast_jump_edgedamage) * (1 - multiplier));
 401
 402                                 Damage(head, self, self, final_damage, WEP_SHOCKWAVE, head.origin, final_force);
 403                                 //print("SELF HIT: multiplier = ", ftos(multiplier), strcat(", damage = ", ftos(final_damage), ", force = ", ftos(vlen(final_force))),"... multiplier_from_accuracy = ", ftos(multiplier_from_accuracy), ", multiplier_from_distance = ", ftos(multiplier_from_distance), ".\n");
 404                         }
 405                         else if (distance_to_head <= WEP_CVAR(shockwave, blast_splash_radius))
 406                         {
 407                                 multiplier_from_accuracy = (1 - (distance_to_head ? min(1, (distance_to_head / WEP_CVAR(shockwave, blast_splash_radius))) : 0));
 408                                 multiplier_from_distance = (1 - (distance_to_hit ? min(1, (distance_to_hit / distance_to_end)) : 0));
 409                                 multiplier = max(WEP_CVAR(shockwave, blast_splash_multiplier_min), ((multiplier_from_accuracy * WEP_CVAR(shockwave, blast_splash_multiplier_accuracy)) + (multiplier_from_distance * WEP_CVAR(shockwave, blast_splash_multiplier_distance))));
 410
 411                                 final_force = normalize(center - (attack_hitpos - (w_shotdir * WEP_CVAR(shockwave, blast_splash_force_forwardbias))));
 412                                 //te_lightning2(world, attack_hitpos, (attack_hitpos + (final_force * 200)));
 413                                 final_force = ((final_force * WEP_CVAR(shockwave, blast_splash_force)) * multiplier);
 414                                 final_force_z *= WEP_CVAR(shockwave, blast_force_zscale);
 415                                 final_damage = (WEP_CVAR(shockwave, blast_splash_damage) * multiplier + WEP_CVAR(shockwave, blast_splash_edgedamage) * (1 - multiplier));
 416
 417                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { ++queue; }
 418                                 //print("SPLASH HIT: multiplier = ", ftos(multiplier), strcat(", damage = ", ftos(final_damage), ", force = ", ftos(vlen(final_force))),"... multiplier_from_accuracy = ", ftos(multiplier_from_accuracy), ", multiplier_from_distance = ", ftos(multiplier_from_distance), ".\n");
 419                         }
 420                 }
 421                 head = next;
 422         }
 423
 424         // cone damage trace
 425         head = WarpZone_FindRadius(w_shotorg, WEP_CVAR(shockwave, blast_distance), FALSE);
 426         while(head)
 427         {
 428                 next = head.chain;
 429
 430                 if((head != self) && head.takedamage)
 431                 {
 432                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 433                         center = CENTER_OR_VIEWOFS(head);
 434
 435                         // find the closest point on the enemy to the center of the attack
 436                         float ang; // angle between shotdir and h
 437                         float h; // hypotenuse, which is the distance between attacker to head
 438                         float a; // adjacent side, which is the distance between attacker and the point on w_shotdir that is closest to head.origin
 439
 440                         h = vlen(center - self.origin);
 441                         ang = acos(dotproduct(normalize(center - self.origin), w_shotdir));
 442                         a = h * cos(ang);
 443
 444                         vector nearest_on_line = (w_shotorg + a * w_shotdir);
 445                         vector nearest_to_attacker = WarpZoneLib_NearestPointOnBox(center + head.mins, center + head.maxs, nearest_on_line);
 446                         float distance_to_target = vlen(w_shotorg - nearest_to_attacker); // todo: use the findradius function for this
 447
 448                         if((distance_to_target <= WEP_CVAR(shockwave, blast_distance))
 449                                 && (W_Shockwave_Attack_IsVisible(head, nearest_on_line, w_shotorg, attack_endpos)))
 450                         {
 451                                 multiplier_from_accuracy = (1 - W_Shockwave_Attack_CheckSpread(nearest_to_attacker, nearest_on_line, w_shotorg, attack_endpos));
 452                                 multiplier_from_distance = (1 - (distance_to_hit ? min(1, (distance_to_target / distance_to_end)) : 0));
 453                                 multiplier = max(WEP_CVAR(shockwave, blast_multiplier_min), ((multiplier_from_accuracy * WEP_CVAR(shockwave, blast_multiplier_accuracy)) + (multiplier_from_distance * WEP_CVAR(shockwave, blast_multiplier_distance))));
 454
 455                                 final_force = normalize(center - (nearest_on_line - (w_shotdir * WEP_CVAR(shockwave, blast_force_forwardbias))));
 456                                 //te_lightning2(world, nearest_on_line, (attack_hitpos + (final_force * 200)));
 457                                 final_force = ((final_force * WEP_CVAR(shockwave, blast_force)) * multiplier);
 458                                 final_force_z *= WEP_CVAR(shockwave, blast_force_zscale);
 459                                 final_damage = (WEP_CVAR(shockwave, blast_damage) * multiplier + WEP_CVAR(shockwave, blast_edgedamage) * (1 - multiplier));
 460
 461                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { ++queue; }
 462                                 //print("CONE HIT: multiplier = ", ftos(multiplier), strcat(", damage = ", ftos(final_damage), ", force = ", ftos(vlen(final_force))),"... multiplier_from_accuracy = ", ftos(multiplier_from_accuracy), ", multiplier_from_distance = ", ftos(multiplier_from_distance), ".\n");
 463                         }
 464                 }
 465                 head = next;
 466         }
 467
 468         for(i = 1; i <= queue; ++i)
 469         {
 470                 head = shockwave_hit[i];
 471                 final_force = shockwave_hit_force[i];
 472                 final_damage = shockwave_hit_damage[i];
 473
 474                 Damage(head, self, self, final_damage, WEP_SHOCKWAVE, head.origin, final_force);
 475                 print("SHOCKWAVE by ", self.netname, ": damage = ", ftos(final_damage), ", force = ", ftos(vlen(final_force)), ".\n");
 476
 477                 shockwave_hit[i] = world;
 478                 shockwave_hit_force[i] = '0 0 0';
 479                 shockwave_hit_damage[i] = 0;
 480         }
 481         //print("queue was ", ftos(queue), ".\n\n");
 482 }
 483
 484 float W_Shockwave(float req)
 485 {
 486         float ammo_amount;
 487         switch(req)
 488         {
 489                 case WR_AIM:
 490                 {
 491                         if(vlen(self.origin-self.enemy.origin) <= WEP_CVAR(shockwave, melee_range))
 492                                 { self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE); }
 493                         else
 494                                 { self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE); }
 495
 496                         return TRUE;
 497                 }
 498                 case WR_THINK:
 499                 {
 500                         if(autocvar_g_balance_shockwave_reload_ammo && self.clip_load < WEP_CVAR(shockwave, pellets_ammo)) // forced reload
 501                         {
 502                                 // don't force reload an empty shockwave if its melee attack is active
 503                                 if(!(autocvar_g_balance_shockwave_secondary && self.ammo_shells < WEP_CVAR(shockwave, pellets_ammo)))
 504                                         WEP_ACTION(self.weapon, WR_RELOAD);
 505                         }
 506                         else
 507                         {
 508                                 if (self.BUTTON_ATCK)
 509                                 {
 510                                         if (time >= self.shockwave_pelletstime) // handle refire separately so the secondary can be fired straight after a primary
 511                                         {
 512                                                 if(weapon_prepareattack(0, WEP_CVAR(shockwave, pellets_animtime)))
 513                                                 {
 514                                                         W_Shockwave_Attack();
 515                                                         self.shockwave_pelletstime = time + WEP_CVAR(shockwave, pellets_refire) * W_WeaponRateFactor();
 516                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(shockwave, pellets_animtime), w_ready);
 517                                                 }
 518                                         }
 519                                 }
 520                         }
 521                         if (self.clip_load >= 0) // we are not currently reloading
 522                         if (!self.crouch) // no crouchmelee please
 523                         if (self.BUTTON_ATCK2 && autocvar_g_balance_shockwave_secondary)
 524                         if (weapon_prepareattack(1, WEP_CVAR(shockwave, melee_refire)))
 525                         {
 526                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 527                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shockwave_Melee);
 528                         }
 529
 530                         return TRUE;
 531                 }
 532                 case WR_INIT:
 533                 {
 534                         precache_model("models/uziflash.md3");
 535                         precache_model("models/weapons/g_shockwave.md3");
 536                         precache_model("models/weapons/v_shockwave.md3");
 537                         precache_model("models/weapons/h_shockwave.iqm");
 538                         precache_sound("misc/itempickup.wav");
 539                         precache_sound("weapons/shockwave_fire.wav");
 540                         precache_sound("weapons/shockwave_melee.wav");
 541                         SHOCKWAVE_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 542                         return TRUE;
 543                 }
 544                 case WR_SETUP:
 545                 {
 546                         self.current_ammo = ammo_shells;
 547                         return TRUE;
 548                 }
 549                 case WR_CHECKAMMO1:
 550                 {
 551                         ammo_amount = self.ammo_shells >= WEP_CVAR(shockwave, pellets_ammo);
 552                         ammo_amount += self.(weapon_load[WEP_SHOCKWAVE]) >= WEP_CVAR(shockwave, pellets_ammo);
 553                         return ammo_amount;
 554                 }
 555                 case WR_CHECKAMMO2:
 556                 {
 557                         // melee attack is always available
 558                         return TRUE;
 559                 }
 560                 case WR_CONFIG:
 561                 {
 562                         SHOCKWAVE_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 563                         return TRUE;
 564                 }
 565                 case WR_RELOAD:
 566                 {
 567                         W_Reload(WEP_CVAR(shockwave, pellets_ammo), "weapons/reload.wav");
 568                         return TRUE;
 569                 }
 570                 case WR_SUICIDEMESSAGE:
 571                 {
 572                         return WEAPON_THINKING_WITH_PORTALS;
 573                 }
 574                 case WR_KILLMESSAGE:
 575                 {
 576                         if(w_deathtype & HITTYPE_SECONDARY)
 577                                 return WEAPON_SHOCKWAVE_MURDER_SLAP;
 578                         else
 579                                 return WEAPON_SHOCKWAVE_MURDER;
 580                 }
 581         }
 582         return TRUE;
 583 }
 584 #endif
 585 #ifdef CSQC
 586 float W_Shockwave(float req)
 587 {
 588         switch(req)
 589         {
 590                 case WR_IMPACTEFFECT:
 591                 {
 592                         vector org2;
 593                         org2 = w_org + w_backoff * 2;
 594                         pointparticles(particleeffectnum("shockwave_impact"), org2, w_backoff * 1000, 1);
 595                         return TRUE;
 596                 }
 597                 case WR_INIT:
 598                 {
 599                         //precache_sound("weapons/ric1.wav");
 600                         //precache_sound("weapons/ric2.wav");
 601                         //precache_sound("weapons/ric3.wav");
 602                         return FALSE;
 603                 }
 604         }
 605         return TRUE;
 606 }
 607 #endif
 608 #endif