qcsrc/common/weapons/w_shockwave.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ SHOCKWAVE,
   4 /* function */ W_Shockwave,
   5 /* ammotype */ ammo_none,
   6 /* impulse  */ 2,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN,
   8 /* rating   */ BOT_PICKUP_RATING_LOW,
   9 /* color        */ '0.5 0.25 0',
  10 /* model    */ "shotgun",
  11 /* netname  */ "shockwave",
  12 /* fullname */ _("Shockwave")
  13 );
  14
  15 #define SHOCKWAVE_SETTINGS(w_cvar,w_prop) SHOCKWAVE_SETTINGS_LIST(w_cvar, w_prop, SHOCKWAVE, shockwave)
  16 #define SHOCKWAVE_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  17         w_cvar(id, sn, NONE, blast_animtime) \
  18         w_cvar(id, sn, NONE, blast_damage) \
  19         w_cvar(id, sn, NONE, blast_distance) \
  20         w_cvar(id, sn, NONE, blast_edgedamage) \
  21         w_cvar(id, sn, NONE, blast_force) \
  22         w_cvar(id, sn, NONE, blast_force_forwardbias) \
  23         w_cvar(id, sn, NONE, blast_force_zscale) \
  24         w_cvar(id, sn, NONE, blast_jump_damage) \
  25         w_cvar(id, sn, NONE, blast_jump_edgedamage) \
  26         w_cvar(id, sn, NONE, blast_jump_force) \
  27         w_cvar(id, sn, NONE, blast_jump_force_velocitybias) \
  28         w_cvar(id, sn, NONE, blast_jump_force_zscale) \
  29         w_cvar(id, sn, NONE, blast_jump_multiplier_accuracy) \
  30         w_cvar(id, sn, NONE, blast_jump_multiplier_distance) \
  31         w_cvar(id, sn, NONE, blast_jump_multiplier_min) \
  32         w_cvar(id, sn, NONE, blast_jump_radius) \
  33         w_cvar(id, sn, NONE, blast_multiplier_accuracy) \
  34         w_cvar(id, sn, NONE, blast_multiplier_distance) \
  35         w_cvar(id, sn, NONE, blast_multiplier_min) \
  36         w_cvar(id, sn, NONE, blast_refire) \
  37         w_cvar(id, sn, NONE, blast_splash_damage) \
  38         w_cvar(id, sn, NONE, blast_splash_edgedamage) \
  39         w_cvar(id, sn, NONE, blast_splash_force) \
  40         w_cvar(id, sn, NONE, blast_splash_force_forwardbias) \
  41         w_cvar(id, sn, NONE, blast_splash_multiplier_accuracy) \
  42         w_cvar(id, sn, NONE, blast_splash_multiplier_distance) \
  43         w_cvar(id, sn, NONE, blast_splash_multiplier_min) \
  44         w_cvar(id, sn, NONE, blast_splash_radius) \
  45         w_cvar(id, sn, NONE, blast_spread_max) \
  46         w_cvar(id, sn, NONE, blast_spread_min) \
  47         w_cvar(id, sn, NONE, melee_animtime) \
  48         w_cvar(id, sn, NONE, melee_damage) \
  49         w_cvar(id, sn, NONE, melee_delay) \
  50         w_cvar(id, sn, NONE, melee_force) \
  51         w_cvar(id, sn, NONE, melee_multihit) \
  52         w_cvar(id, sn, NONE, melee_no_doubleslap) \
  53         w_cvar(id, sn, NONE, melee_nonplayerdamage) \
  54         w_cvar(id, sn, NONE, melee_range) \
  55         w_cvar(id, sn, NONE, melee_refire) \
  56         w_cvar(id, sn, NONE, melee_swing_side) \
  57         w_cvar(id, sn, NONE, melee_swing_up) \
  58         w_cvar(id, sn, NONE, melee_time) \
  59         w_cvar(id, sn, NONE, melee_traces) \
  60         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  61         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  62         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  63         w_prop(id, sn, float,  weaponstart, weaponstart) \
  64         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  65
  66 #ifdef SVQC
  67 SHOCKWAVE_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  68 #endif
  69 #else
  70 #ifdef SVQC
  71 void spawnfunc_weapon_shockwave()
  72 {
  73         //if(autocvar_sv_q3acompat_machineshockwaveswap) // WEAPONTODO
  74         if(autocvar_sv_q3acompat_machineshotgunswap)
  75         if(self.classname != "droppedweapon")
  76         {
  77                 weapon_defaultspawnfunc(WEP_MACHINEGUN);
  78                 return;
  79         }
  80         weapon_defaultspawnfunc(WEP_SHOCKWAVE);
  81 }
  82
  83 #define MAX_SHOCKWAVE_HITS 10
  84
  85 .float swing_prev;
  86 .entity swing_alreadyhit;
  87 .float shockwave_blasttime;
  88 entity shockwave_hit[MAX_SHOCKWAVE_HITS];
  89 float shockwave_hit_damage[MAX_SHOCKWAVE_HITS];
  90 vector shockwave_hit_force[MAX_SHOCKWAVE_HITS];
  91
  92 // MELEE ATTACK MODE
  93 void W_Shockwave_Melee_Think()
  94 {
  95         // declarations
  96         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  97         entity target_victim;
  98         vector targpos;
  99
 100         // check to see if we can still continue, otherwise give up now
 101         if((self.realowner.deadflag != DEAD_NO) && WEP_CVAR(shockwave, melee_no_doubleslap))
 102         {
 103                 remove(self);
 104                 return;
 105         }
 106
 107         // set start time of melee
 108         if(!self.cnt)
 109         {
 110                 self.cnt = time;
 111                 W_PlayStrengthSound(self.realowner);
 112         }
 113
 114         // update values for v_* vectors
 115         makevectors(self.realowner.v_angle);
 116
 117         // calculate swing percentage based on time
 118         meleetime = WEP_CVAR(shockwave, melee_time) * W_WeaponRateFactor();
 119         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
 120         f = ((1 - swing) * WEP_CVAR(shockwave, melee_traces));
 121
 122         // perform the traces needed for this frame
 123         for(i=self.swing_prev; i < f; ++i)
 124         {
 125                 swing_factor = ((1 - (i / WEP_CVAR(shockwave, melee_traces))) * 2 - 1);
 126
 127                 targpos = (self.realowner.origin + self.realowner.view_ofs
 128                         + (v_forward * WEP_CVAR(shockwave, melee_range))
 129                         + (v_up * swing_factor * WEP_CVAR(shockwave, melee_swing_up))
 130                         + (v_right * swing_factor * WEP_CVAR(shockwave, melee_swing_side)));
 131
 132                 WarpZone_traceline_antilag(
 133                         self.realowner,
 134                         (self.realowner.origin + self.realowner.view_ofs),
 135                         targpos,
 136                         FALSE,
 137                         self.realowner,
 138                         ANTILAG_LATENCY(self.realowner)
 139                 );
 140
 141                 // draw lightning beams for debugging
 142                 te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
 143                 te_customflash(targpos, 40,  2, '1 1 1');
 144
 145                 is_player = (trace_ent.classname == "player" || trace_ent.classname == "body");
 146
 147                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self if necessary
 148                         && (trace_ent.takedamage == DAMAGE_AIM)
 149                         && (trace_ent != self.swing_alreadyhit)
 150                         && (is_player || WEP_CVAR(shockwave, melee_nonplayerdamage)))
 151                 {
 152                         target_victim = trace_ent; // so it persists through other calls
 153
 154                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught
 155                                 swing_damage = (WEP_CVAR(shockwave, melee_damage) * min(1, swing_factor + 1));
 156                         else
 157                                 swing_damage = (WEP_CVAR(shockwave, melee_nonplayerdamage) * min(1, swing_factor + 1));
 158
 159                         // trigger damage with this calculated info
 160                         Damage(
 161                                 target_victim,
 162                                 self.realowner,
 163                                 self.realowner,
 164                                 swing_damage,
 165                                 (WEP_SHOCKWAVE | HITTYPE_SECONDARY),
 166                                 (self.realowner.origin + self.realowner.view_ofs),
 167                                 (v_forward * WEP_CVAR(shockwave, melee_force))
 168                         );
 169
 170                         // handle accuracy
 171                         if(accuracy_isgooddamage(self.realowner, target_victim))
 172                                 { accuracy_add(self.realowner, WEP_SHOCKWAVE, 0, swing_damage); }
 173
 174                         #ifdef DEBUG_SHOCKWAVE
 175                         print(sprintf(
 176                                 "MELEE: %s hitting %s with %f damage (factor: %f) at %f time.\n",
 177                                 self.realowner.netname,
 178                                 target_victim.netname,
 179                                 swing_damage,
 180                                 swing_factor,
 181                                 time
 182                         ));
 183                         #endif
 184
 185                         // allow multiple hits with one swing, but not against the same player twice
 186                         if(WEP_CVAR(shockwave, melee_multihit))
 187                         {
 188                                 self.swing_alreadyhit = target_victim;
 189                                 continue; // move along to next trace
 190                         }
 191                         else
 192                         {
 193                                 remove(self);
 194                                 return;
 195                         }
 196                 }
 197         }
 198
 199         if(time >= self.cnt + meleetime)
 200         {
 201                 // melee is finished
 202                 remove(self);
 203                 return;
 204         }
 205         else
 206         {
 207                 // set up next frame
 208                 self.swing_prev = i;
 209                 self.nextthink = time;
 210         }
 211 }
 212
 213 void W_Shockwave_Melee()
 214 {
 215         sound(self, CH_WEAPON_A, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 216         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(shockwave, melee_animtime), w_ready);
 217
 218         entity meleetemp;
 219         meleetemp = spawn();
 220         meleetemp.owner = meleetemp.realowner = self;
 221         meleetemp.think = W_Shockwave_Melee_Think;
 222         meleetemp.nextthink = time + WEP_CVAR(shockwave, melee_delay) * W_WeaponRateFactor();
 223         W_SetupShot_Range(self, TRUE, 0, "", 0, WEP_CVAR(shockwave, melee_damage), WEP_CVAR(shockwave, melee_range));
 224 }
 225
 226 // SHOCKWAVE ATTACK MODE
 227 float W_Shockwave_Attack_CheckSpread(
 228         vector targetorg,
 229         vector nearest_on_line,
 230         vector sw_shotorg,
 231         vector attack_endpos)
 232 {
 233         float spreadlimit;
 234         float distance_of_attack = vlen(sw_shotorg - attack_endpos);
 235         float distance_from_line = vlen(targetorg - nearest_on_line);
 236
 237         spreadlimit = (distance_of_attack ? min(1, (vlen(sw_shotorg - nearest_on_line) / distance_of_attack)) : 1);
 238         spreadlimit =
 239                 (
 240                         (WEP_CVAR(shockwave, blast_spread_min) * (1 - spreadlimit))
 241                         +
 242                         (WEP_CVAR(shockwave, blast_spread_max) * spreadlimit)
 243                 );
 244
 245         if(
 246                 (spreadlimit && (distance_from_line <= spreadlimit))
 247                 &&
 248                 ((vlen(normalize(targetorg - sw_shotorg) - normalize(attack_endpos - sw_shotorg)) * RAD2DEG) <= 90)
 249         )
 250                 { return bound(0, (distance_from_line / spreadlimit), 1); }
 251         else
 252                 { return FALSE; }
 253 }
 254
 255 float W_Shockwave_Attack_IsVisible(
 256         entity head,
 257         vector nearest_on_line,
 258         vector sw_shotorg,
 259         vector attack_endpos)
 260 {
 261         vector nearest_to_attacker = head.WarpZone_findradius_nearest;
 262         vector center = (head.origin + (head.mins + head.maxs) * 0.5);
 263         vector corner;
 264         float i;
 265
 266         // STEP ONE: Check if the nearest point is clear
 267         if(W_Shockwave_Attack_CheckSpread(nearest_to_attacker, nearest_on_line, sw_shotorg, attack_endpos))
 268         {
 269                 WarpZone_TraceLine(sw_shotorg, nearest_to_attacker, MOVE_NOMONSTERS, self);
 270                 if(trace_fraction == 1) { return TRUE; } // yes, the nearest point is clear and we can allow the damage
 271         }
 272
 273         // STEP TWO: Check if shotorg to center point is clear
 274         if(W_Shockwave_Attack_CheckSpread(center, nearest_on_line, sw_shotorg, attack_endpos))
 275         {
 276                 WarpZone_TraceLine(sw_shotorg, center, MOVE_NOMONSTERS, self);
 277                 if(trace_fraction == 1) { return TRUE; } // yes, the center point is clear and we can allow the damage
 278         }
 279
 280         // STEP THREE: Check each corner to see if they are clear
 281         for(i=1; i<=8; ++i)
 282         {
 283                 corner = get_corner_position(head, i);
 284                 if(W_Shockwave_Attack_CheckSpread(corner, nearest_on_line, sw_shotorg, attack_endpos))
 285                 {
 286                         WarpZone_TraceLine(sw_shotorg, corner, MOVE_NOMONSTERS, self);
 287                         if(trace_fraction == 1) { return TRUE; } // yes, this corner is clear and we can allow the damage
 288                 }
 289         }
 290
 291         return FALSE;
 292 }
 293
 294 float W_Shockwave_Attack_CheckHit(
 295         float queue,
 296         entity head,
 297         vector final_force,
 298         float final_damage)
 299 {
 300         // WEAPONTODO: check if we hit MAX_SHOCKWAVE_HITS
 301         if(!head) { return FALSE; }
 302         float i;
 303
 304         for(i = 0; i <= queue; ++i)
 305         {
 306                 if(shockwave_hit[i] == head)
 307                 {
 308                         if(vlen(final_force) > vlen(shockwave_hit_force[i])) { shockwave_hit_force[i] = final_force; }
 309                         if(final_damage > shockwave_hit_damage[i]) { shockwave_hit_damage[i] = final_damage; }
 310                         return FALSE;
 311                 }
 312         }
 313
 314         shockwave_hit[queue] = head;
 315         shockwave_hit_force[queue] = final_force;
 316         shockwave_hit_damage[queue] = final_damage;
 317         return TRUE;
 318 }
 319
 320 void W_Shockwave_Attack()
 321 {
 322         // declarations
 323         float multiplier, multiplier_from_accuracy, multiplier_from_distance;
 324         float final_damage;
 325         vector final_force, center, vel;
 326         entity head;
 327
 328         float i, queue = 0;
 329
 330         // set up the shot direction
 331         W_SetupShot(self, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, WEP_CVAR(shockwave, blast_damage));
 332         vector attack_endpos = (w_shotorg + (w_shotdir * WEP_CVAR(shockwave, blast_distance)));
 333         WarpZone_TraceLine(w_shotorg, attack_endpos, MOVE_NOMONSTERS, self);
 334         vector attack_hitpos = trace_endpos;
 335         float distance_to_end = vlen(w_shotorg - attack_endpos);
 336         float distance_to_hit = vlen(w_shotorg - attack_hitpos);
 337         //entity transform = WarpZone_trace_transform;
 338
 339         // do the firing effect now
 340         //SendCSQCShockwaveParticle(attack_endpos); // WEAPONTODO
 341         Damage_DamageInfo(
 342                 attack_hitpos,
 343                 WEP_CVAR(shockwave, blast_splash_damage),
 344                 WEP_CVAR(shockwave, blast_splash_edgedamage),
 345                 WEP_CVAR(shockwave, blast_splash_radius),
 346                 w_shotdir * WEP_CVAR(shockwave, blast_splash_force),
 347                 WEP_SHOCKWAVE,
 348                 0,
 349                 self
 350         );
 351
 352         // splash damage/jumping trace
 353         head = WarpZone_FindRadius(
 354                 attack_hitpos,
 355                 max(
 356                         WEP_CVAR(shockwave, blast_splash_radius),
 357                         WEP_CVAR(shockwave, blast_jump_radius)
 358                 ),
 359                 FALSE
 360         );
 361
 362         while(head)
 363         {
 364                 if(head.takedamage)
 365                 {
 366                         float distance_to_head = vlen(attack_hitpos - head.WarpZone_findradius_nearest);
 367
 368                         if((head == self) && (distance_to_head <= WEP_CVAR(shockwave, blast_jump_radius)))
 369                         {
 370                                 // ========================
 371                                 //  BLAST JUMP CALCULATION
 372                                 // ========================
 373
 374                                 // calculate importance of distance and accuracy for this attack
 375                                 multiplier_from_accuracy = (1 -
 376                                         (distance_to_head ?
 377                                                 min(1, (distance_to_head / WEP_CVAR(shockwave, blast_jump_radius)))
 378                                                 :
 379                                                 0
 380                                         )
 381                                 );
 382                                 multiplier_from_distance = (1 -
 383                                         (distance_to_hit ?
 384                                                 min(1, (distance_to_hit / distance_to_end))
 385                                                 :
 386                                                 0
 387                                         )
 388                                 );
 389                                 multiplier =
 390                                         max(
 391                                                 WEP_CVAR(shockwave, blast_jump_multiplier_min),
 392                                                 (
 393                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_jump_multiplier_accuracy))
 394                                                         +
 395                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_jump_multiplier_distance))
 396                                                 )
 397                                         );
 398
 399                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 400                                 final_damage =
 401                                         (
 402                                                 (WEP_CVAR(shockwave, blast_jump_damage) * multiplier)
 403                                                 +
 404                                                 (WEP_CVAR(shockwave, blast_jump_edgedamage) * (1 - multiplier))
 405                                         );
 406
 407                                 // figure out the direction of force
 408                                 vel = normalize(combine_to_vector(head.velocity_x, head.velocity_y, 0));
 409                                 vel *=
 410                                         (
 411                                                 bound(0, (vlen(vel) / autocvar_sv_maxspeed), 1)
 412                                                 *
 413                                                 WEP_CVAR(shockwave, blast_jump_force_velocitybias)
 414                                         );
 415                                 final_force = normalize((CENTER_OR_VIEWOFS(head) - attack_hitpos) + vel);
 416
 417                                 // now multiply the direction by force units
 418                                 final_force *= (WEP_CVAR(shockwave, blast_jump_force) * multiplier);
 419                                 final_force_z *= WEP_CVAR(shockwave, blast_jump_force_zscale);
 420
 421                                 // trigger damage with this calculated info
 422                                 Damage(
 423                                         head,
 424                                         self,
 425                                         self,
 426                                         final_damage,
 427                                         WEP_SHOCKWAVE,
 428                                         head.origin,
 429                                         final_force
 430                                 );
 431
 432                                 #ifdef DEBUG_SHOCKWAVE
 433                                 print(sprintf(
 434                                         "SELF HIT: multiplier = %f, damage = %f, force = %f... "
 435                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 436                                         multiplier,
 437                                         final_damage,
 438                                         vlen(final_force),
 439                                         multiplier_from_accuracy,
 440                                         multiplier_from_distance
 441                                 ));
 442                                 #endif
 443                         }
 444                         else if(distance_to_head <= WEP_CVAR(shockwave, blast_splash_radius))
 445                         {
 446                                 // ==========================
 447                                 //  BLAST SPLASH CALCULATION
 448                                 // ==========================
 449
 450                                 // calculate importance of distance and accuracy for this attack
 451                                 multiplier_from_accuracy = (1 -
 452                                         (distance_to_head ?
 453                                                 min(1, (distance_to_head / WEP_CVAR(shockwave, blast_splash_radius)))
 454                                                 :
 455                                                 0
 456                                         )
 457                                 );
 458                                 multiplier_from_distance = (1 -
 459                                         (distance_to_hit ?
 460                                                 min(1, (distance_to_hit / distance_to_end))
 461                                                 :
 462                                                 0
 463                                         )
 464                                 );
 465                                 multiplier =
 466                                         max(
 467                                                 WEP_CVAR(shockwave, blast_splash_multiplier_min),
 468                                                 (
 469                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_splash_multiplier_accuracy))
 470                                                         +
 471                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_splash_multiplier_distance))
 472                                                 )
 473                                         );
 474
 475                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 476                                 final_damage =
 477                                         (
 478                                                 (WEP_CVAR(shockwave, blast_splash_damage) * multiplier)
 479                                                 +
 480                                                 (WEP_CVAR(shockwave, blast_splash_edgedamage) * (1 - multiplier))
 481                                         );
 482
 483                                 // figure out the direction of force
 484                                 final_force = (w_shotdir * WEP_CVAR(shockwave, blast_splash_force_forwardbias));
 485                                 final_force = normalize(CENTER_OR_VIEWOFS(head) - (attack_hitpos - final_force));
 486                                 //te_lightning2(world, attack_hitpos, (attack_hitpos + (final_force * 200)));
 487
 488                                 // now multiply the direction by force units
 489                                 final_force *= (WEP_CVAR(shockwave, blast_splash_force) * multiplier);
 490                                 final_force_z *= WEP_CVAR(shockwave, blast_force_zscale);
 491
 492                                 // queue damage with this calculated info
 493                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { ++queue; }
 494
 495                                 #ifdef DEBUG_SHOCKWAVE
 496                                 print(sprintf(
 497                                         "SPLASH HIT: multiplier = %f, damage = %f, force = %f... "
 498                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 499                                         multiplier,
 500                                         final_damage,
 501                                         vlen(final_force),
 502                                         multiplier_from_accuracy,
 503                                         multiplier_from_distance
 504                                 ));
 505                                 #endif
 506                         }
 507                 }
 508                 head = head.chain;
 509         }
 510
 511         // cone damage trace
 512         head = WarpZone_FindRadius(w_shotorg, WEP_CVAR(shockwave, blast_distance), FALSE);
 513         while(head)
 514         {
 515                 if((head != self) && head.takedamage)
 516                 {
 517                         // ========================
 518                         //  BLAST CONE CALCULATION
 519                         // ========================
 520
 521                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 522                         center = CENTER_OR_VIEWOFS(head);
 523
 524                         // find the closest point on the enemy to the center of the attack
 525                         float ang; // angle between shotdir and h
 526                         float h; // hypotenuse, which is the distance between attacker to head
 527                         float a; // adjacent side, which is the distance between attacker and the point on w_shotdir that is closest to head.origin
 528
 529                         h = vlen(center - self.origin);
 530                         ang = acos(dotproduct(normalize(center - self.origin), w_shotdir));
 531                         a = h * cos(ang);
 532                         // WEAPONTODO: replace with simpler method
 533
 534                         vector nearest_on_line = (w_shotorg + a * w_shotdir);
 535                         vector nearest_to_attacker = WarpZoneLib_NearestPointOnBox(center + head.mins, center + head.maxs, nearest_on_line);
 536                         float distance_to_target = vlen(w_shotorg - nearest_to_attacker); // WEAPONTODO: use the findradius function for this
 537
 538                         if((distance_to_target <= WEP_CVAR(shockwave, blast_distance))
 539                                 && (W_Shockwave_Attack_IsVisible(head, nearest_on_line, w_shotorg, attack_endpos)))
 540                         {
 541                                 // calculate importance of distance and accuracy for this attack
 542                                 multiplier_from_accuracy = (1 -
 543                                         W_Shockwave_Attack_CheckSpread(
 544                                                 nearest_to_attacker,
 545                                                 nearest_on_line,
 546                                                 w_shotorg,
 547                                                 attack_endpos
 548                                         )
 549                                 );
 550                                 multiplier_from_distance = (1 -
 551                                         (distance_to_hit ?
 552                                                 min(1, (distance_to_target / distance_to_end))
 553                                                 :
 554                                                 0
 555                                         )
 556                                 );
 557                                 multiplier =
 558                                         max(
 559                                                 WEP_CVAR(shockwave, blast_multiplier_min),
 560                                                 (
 561                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_multiplier_accuracy))
 562                                                         +
 563                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_multiplier_distance))
 564                                                 )
 565                                         );
 566
 567                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 568                                 final_damage =
 569                                         (
 570                                                 (WEP_CVAR(shockwave, blast_damage) * multiplier)
 571                                                 +
 572                                                 (WEP_CVAR(shockwave, blast_edgedamage) * (1 - multiplier))
 573                                         );
 574
 575                                 // figure out the direction of force
 576                                 final_force = (w_shotdir * WEP_CVAR(shockwave, blast_force_forwardbias));
 577                                 final_force = normalize(center - (nearest_on_line - final_force));
 578                                 //te_lightning2(world, nearest_on_line, (attack_hitpos + (final_force * 200)));
 579
 580                                 // now multiply the direction by force units
 581                                 final_force *= (WEP_CVAR(shockwave, blast_force) * multiplier);
 582                                 final_force_z *= WEP_CVAR(shockwave, blast_force_zscale);
 583
 584                                 // queue damage with this calculated info
 585                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { ++queue; }
 586
 587                                 #ifdef DEBUG_SHOCKWAVE
 588                                 print(sprintf(
 589                                         "BLAST HIT: multiplier = %f, damage = %f, force = %f... "
 590                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 591                                         multiplier,
 592                                         final_damage,
 593                                         vlen(final_force),
 594                                         multiplier_from_accuracy,
 595                                         multiplier_from_distance
 596                                 ));
 597                                 #endif
 598                         }
 599                 }
 600                 head = head.chain;
 601         }
 602
 603         for(i = 0; i <= queue; ++i)
 604         {
 605                 head = shockwave_hit[i];
 606                 final_force = shockwave_hit_force[i];
 607                 final_damage = shockwave_hit_damage[i];
 608
 609                 Damage(
 610                         head,
 611                         self,
 612                         self,
 613                         final_damage,
 614                         WEP_SHOCKWAVE,
 615                         head.origin,
 616                         final_force
 617                 );
 618
 619                 #ifdef DEBUG_SHOCKWAVE
 620                 print(sprintf(
 621                         "SHOCKWAVE by %s: damage = %f, force = %f.\n",
 622                         self.netname,
 623                         final_damage,
 624                         vlen(final_force)
 625                 ));
 626                 #endif
 627
 628                 shockwave_hit[i] = world;
 629                 shockwave_hit_force[i] = '0 0 0';
 630                 shockwave_hit_damage[i] = 0;
 631         }
 632 }
 633
 634 float W_Shockwave(float req)
 635 {
 636         switch(req)
 637         {
 638                 case WR_AIM:
 639                 {
 640                         if(vlen(self.origin - self.enemy.origin) <= WEP_CVAR(shockwave, melee_range))
 641                                 { self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE); }
 642                         else
 643                                 { self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE); }
 644
 645                         return TRUE;
 646                 }
 647                 case WR_THINK:
 648                 {
 649                         if(self.BUTTON_ATCK)
 650                         {
 651                                 if(time >= self.shockwave_blasttime) // handle refire separately so the secondary can be fired straight after a primary
 652                                 {
 653                                         if(weapon_prepareattack(0, WEP_CVAR(shockwave, blast_animtime)))
 654                                         {
 655                                                 W_Shockwave_Attack();
 656                                                 self.shockwave_blasttime = time + WEP_CVAR(shockwave, blast_refire) * W_WeaponRateFactor();
 657                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(shockwave, blast_animtime), w_ready);
 658                                         }
 659                                 }
 660                         }
 661                         else if(self.BUTTON_ATCK2)
 662                         {
 663                                 //if(self.clip_load >= 0) // we are not currently reloading
 664                                 if(!self.crouch) // no crouchmelee please
 665                                 if(weapon_prepareattack(1, WEP_CVAR(shockwave, melee_refire)))
 666                                 {
 667                                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 668                                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shockwave_Melee);
 669                                 }
 670                         }
 671
 672                         return TRUE;
 673                 }
 674                 case WR_INIT:
 675                 {
 676                         precache_model("models/uziflash.md3");
 677                         precache_model("models/weapons/g_shockwave.md3");
 678                         precache_model("models/weapons/v_shockwave.md3");
 679                         precache_model("models/weapons/h_shockwave.iqm");
 680                         precache_sound("misc/itempickup.wav");
 681                         precache_sound("weapons/shockwave_fire.wav");
 682                         precache_sound("weapons/shockwave_melee.wav");
 683                         SHOCKWAVE_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 684                         return TRUE;
 685                 }
 686                 case WR_CHECKAMMO1:
 687                 case WR_CHECKAMMO2:
 688                 {
 689                         // shockwave has infinite ammo
 690                         return TRUE;
 691                 }
 692                 case WR_CONFIG:
 693                 {
 694                         SHOCKWAVE_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 695                         return TRUE;
 696                 }
 697                 case WR_SUICIDEMESSAGE:
 698                 {
 699                         return WEAPON_THINKING_WITH_PORTALS;
 700                 }
 701                 case WR_KILLMESSAGE:
 702                 {
 703                         if(w_deathtype & HITTYPE_SECONDARY)
 704                                 return WEAPON_SHOCKWAVE_MURDER_SLAP;
 705                         else
 706                                 return WEAPON_SHOCKWAVE_MURDER;
 707                 }
 708         }
 709         return TRUE;
 710 }
 711 #endif
 712 #ifdef CSQC
 713 float W_Shockwave(float req)
 714 {
 715         switch(req)
 716         {
 717                 case WR_IMPACTEFFECT:
 718                 {
 719                         vector org2;
 720                         org2 = w_org + w_backoff * 2;
 721                         pointparticles(particleeffectnum("shockwave_impact"), org2, w_backoff * 1000, 1);
 722                         return TRUE;
 723                 }
 724                 case WR_INIT:
 725                 {
 726                         //precache_sound("weapons/ric1.wav");
 727                         //precache_sound("weapons/ric2.wav");
 728                         //precache_sound("weapons/ric3.wav");
 729                         return FALSE;
 730                 }
 731                 case WR_ZOOMRETICLE:
 732                 {
 733                         // no weapon specific image for this weapon
 734                         return FALSE;
 735                 }
 736         }
 737         return TRUE;
 738 }
 739 #endif
 740 #endif