qcsrc/common/weapons/w_shockwave.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ SHOCKWAVE,
   4 /* function */ W_Shockwave,
   5 /* ammotype */ IT_SHELLS,
   6 /* impulse  */ 2,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN,
   8 /* rating   */ BOT_PICKUP_RATING_LOW,
   9 /* model    */ "shotgun",
  10 /* netname  */ "shockwave",
  11 /* fullname */ _("Shockwave")
  12 );
  13
  14 #define SHOCKWAVE_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_damage) \
  16         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_distance) \
  17         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_edgedamage) \
  18         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_force) \
  19         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_force_forwardbias) \
  20         /*w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_force_velocitybias)*/ \
  21         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_force_zscale) \
  22         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_damage) \
  23         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_edgedamage) \
  24         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_force) \
  25         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_force_velocitybias) \
  26         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_force_zscale) \
  27         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_multiplier_accuracy) \
  28         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_multiplier_distance) \
  29         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_multiplier_min) \
  30         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_jump_radius) \
  31         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_multiplier_accuracy) \
  32         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_multiplier_distance) \
  33         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_multiplier_min) \
  34         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_damage) \
  35         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_edgedamage) \
  36         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_force) \
  37         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_force_forwardbias) \
  38         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_multiplier_accuracy) \
  39         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_multiplier_distance) \
  40         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_multiplier_min) \
  41         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_splash_radius) \
  42         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_spread_max) \
  43         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, blast_spread_min) \
  44         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_animtime) \
  45         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_damage) \
  46         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_delay) \
  47         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_force) \
  48         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_multihit) \
  49         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_no_doubleslap) \
  50         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_nonplayerdamage) \
  51         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_range) \
  52         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_refire) \
  53         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_swing_side) \
  54         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_swing_up) \
  55         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_time) \
  56         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, melee_traces) \
  57         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_ammo) \
  58         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_animtime) \
  59         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_bulletconstant) \
  60         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_bullets) \
  61         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_damage) \
  62         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_force) \
  63         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_refire) \
  64         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_speed) \
  65         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, pellets_spread) \
  66         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, primary) \
  67         w_cvar(WEP_SHOCKWAVE, shockwave, MO_NONE, secondary) \
  68         w_prop(WEP_SHOCKWAVE, shockwave, reloading_ammo, reload_ammo) \
  69         w_prop(WEP_SHOCKWAVE, shockwave, reloading_time, reload_time) \
  70         w_prop(WEP_SHOCKWAVE, shockwave, switchdelay_raise, switchdelay_raise) \
  71         w_prop(WEP_SHOCKWAVE, shockwave, switchdelay_drop, switchdelay_drop)
  72
  73 #ifdef SVQC
  74 SHOCKWAVE_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  75 #endif
  76 #else
  77 #ifdef SVQC
  78 void spawnfunc_weapon_shockwave()
  79 {
  80         //if(autocvar_sv_q3acompat_machineshockwaveswap)
  81         if(autocvar_sv_q3acompat_machineshotgunswap)
  82         if(self.classname != "droppedweapon")
  83         {
  84                 weapon_defaultspawnfunc(WEP_UZI);
  85                 return;
  86         }
  87         weapon_defaultspawnfunc(WEP_SHOCKWAVE);
  88 }
  89
  90 .float swing_prev;
  91 .entity swing_alreadyhit;
  92 .float shockwave_pelletstime;
  93 entity shockwave_hit[32];
  94 float shockwave_hit_damage[32];
  95 vector shockwave_hit_force[32];
  96
  97 // LEGACY ATTACK MODE: Scattered bullets
  98 void W_Shockwave_Pellets(void)
  99 {
 100         float sc;
 101         entity flash;
 102
 103         W_DecreaseAmmo(ammo_shells, WEP_CVAR(shockwave, pellets_ammo), WEP_CVAR(shockwave, reload_ammo));
 104
 105         W_SetupShot(self, TRUE, 5, "weapons/shockwave_fire.wav", CH_WEAPON_A, WEP_CVAR(shockwave, pellets_damage) * WEP_CVAR(shockwave, pellets_bullets));
 106
 107         for(sc = 0; sc < WEP_CVAR(shockwave, pellets_bullets); ++sc)
 108         {
 109                 fireBallisticBullet(
 110                         w_shotorg,
 111                         w_shotdir,
 112                         WEP_CVAR(shockwave, pellets_spread),
 113                         WEP_CVAR(shockwave, pellets_speed),
 114                         5,
 115                         WEP_CVAR(shockwave, pellets_damage),
 116                         WEP_CVAR(shockwave, pellets_force),
 117                         WEP_SHOCKWAVE,
 118                         0,
 119                         WEP_CVAR(shockwave, pellets_bulletconstant)
 120                 );
 121         }
 122         endFireBallisticBullet();
 123
 124         pointparticles(particleeffectnum("shockwave_muzzleflash"), w_shotorg, w_shotdir * 1000, WEP_CVAR(shockwave, pellets_ammo));
 125
 126         // casing code
 127         if(autocvar_g_casings >= 1)
 128         {
 129                 for(sc = 0;sc < WEP_CVAR(shockwave, pellets_ammo); ++sc)
 130                 {
 131                         SpawnCasing(
 132                                 (
 133                                         ((random () * 50 + 50) * v_right)
 134                                         -
 135                                         (v_forward * (random () * 25 + 25))
 136                                         -
 137                                         ((random () * 5 - 30) * v_up)
 138                                 ),
 139                                 2,
 140                                 vectoangles(v_forward),
 141                                 '0 250 0',
 142                                 100,
 143                                 1,
 144                                 self
 145                         );
 146                 }
 147         }
 148
 149         // muzzle flash for 1st person view
 150         flash = spawn();
 151         setmodel(flash, "models/uziflash.md3"); // precision set below
 152         flash.think = SUB_Remove;
 153         flash.nextthink = time + 0.06;
 154         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 155         W_AttachToShotorg(flash, '5 0 0');
 156 }
 157
 158 // MELEE ATTACK MODE
 159 void W_Shockwave_Melee_Think()
 160 {
 161         // declarations
 162         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
 163         entity target_victim;
 164         vector targpos;
 165
 166         if(!self.cnt) // set start time of melee
 167         {
 168                 self.cnt = time;
 169                 W_PlayStrengthSound(self.realowner);
 170         }
 171
 172         makevectors(self.realowner.v_angle); // update values for v_* vectors
 173
 174         // calculate swing percentage based on time
 175         meleetime = WEP_CVAR(shockwave, melee_time) * W_WeaponRateFactor();
 176         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
 177         f = ((1 - swing) * WEP_CVAR(shockwave, melee_traces));
 178
 179         // check to see if we can still continue, otherwise give up now
 180         if((self.realowner.deadflag != DEAD_NO) && WEP_CVAR(shockwave, melee_no_doubleslap))
 181         {
 182                 remove(self);
 183                 return;
 184         }
 185
 186         // if okay, perform the traces needed for this frame
 187         for(i=self.swing_prev; i < f; ++i)
 188         {
 189                 swing_factor = ((1 - (i / WEP_CVAR(shockwave, melee_traces))) * 2 - 1);
 190
 191                 targpos = (self.realowner.origin + self.realowner.view_ofs
 192                         + (v_forward * WEP_CVAR(shockwave, melee_range))
 193                         + (v_up * swing_factor * WEP_CVAR(shockwave, melee_swing_up))
 194                         + (v_right * swing_factor * WEP_CVAR(shockwave, melee_swing_side)));
 195
 196                 WarpZone_traceline_antilag(self.realowner, self.realowner.origin + self.realowner.view_ofs, targpos, FALSE, self.realowner, ANTILAG_LATENCY(self.realowner));
 197
 198                 // draw lightning beams for debugging
 199                 te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
 200                 te_customflash(targpos, 40,  2, '1 1 1');
 201
 202                 is_player = (trace_ent.classname == "player" || trace_ent.classname == "body");
 203
 204                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self
 205                         && (trace_ent.takedamage == DAMAGE_AIM)
 206                         && (trace_ent != self.swing_alreadyhit)
 207                         && (is_player || WEP_CVAR(shockwave, melee_nonplayerdamage)))
 208                 {
 209                         target_victim = trace_ent; // so it persists through other calls
 210
 211                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
 212                                 swing_damage = (WEP_CVAR(shockwave, melee_damage * min(1, swing_factor + 1)));
 213                         else
 214                                 swing_damage = (WEP_CVAR(shockwave, melee_nonplayerdamage * min(1, swing_factor + 1)));
 215
 216                         //print(strcat(self.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
 217
 218                         Damage(target_victim, self.realowner, self.realowner,
 219                                 swing_damage, WEP_SHOCKWAVE | HITTYPE_SECONDARY,
 220                                 self.realowner.origin + self.realowner.view_ofs,
 221                                 v_forward * WEP_CVAR(shockwave, melee_force));
 222
 223                         if(accuracy_isgooddamage(self.realowner, target_victim)) { accuracy_add(self.realowner, WEP_SHOCKWAVE, 0, swing_damage); }
 224
 225                         if(WEP_CVAR(shockwave, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
 226                         {
 227                                 self.swing_alreadyhit = target_victim;
 228                                 continue; // move along to next trace
 229                         }
 230                         else
 231                         {
 232                                 remove(self);
 233                                 return;
 234                         }
 235                 }
 236         }
 237
 238         if(time >= self.cnt + meleetime)
 239         {
 240                 // melee is finished
 241                 remove(self);
 242                 return;
 243         }
 244         else
 245         {
 246                 // set up next frame
 247                 self.swing_prev = i;
 248                 self.nextthink = time;
 249         }
 250 }
 251
 252 void W_Shockwave_Melee()
 253 {
 254         sound(self, CH_WEAPON_A, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 255         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(shockwave, melee_animtime), w_ready);
 256
 257         entity meleetemp;
 258         meleetemp = spawn();
 259         meleetemp.owner = meleetemp.realowner = self;
 260         meleetemp.think = W_Shockwave_Melee_Think;
 261         meleetemp.nextthink = time + WEP_CVAR(shockwave, melee_delay) * W_WeaponRateFactor();
 262         W_SetupShot_Range(self, TRUE, 0, "", 0, WEP_CVAR(shockwave, melee_damage), WEP_CVAR(shockwave, melee_range));
 263 }
 264
 265 // SHOCKWAVE ATTACK MODE
 266 float W_Shockwave_Attack_CheckSpread(
 267         vector targetorg,
 268         vector nearest_on_line,
 269         vector sw_shotorg,
 270         vector attack_endpos)
 271 {
 272         float spreadlimit;
 273         float distance_of_attack = vlen(sw_shotorg - attack_endpos);
 274         float distance_from_line = vlen(targetorg - nearest_on_line);
 275
 276         spreadlimit = (distance_of_attack ? min(1, (vlen(sw_shotorg - nearest_on_line) / distance_of_attack)) : 1);
 277         spreadlimit =
 278                 (
 279                         (WEP_CVAR(shockwave, blast_spread_min) * (1 - spreadlimit))
 280                         +
 281                         (WEP_CVAR(shockwave, blast_spread_max) * spreadlimit)
 282                 );
 283
 284         if(
 285                 (spreadlimit && (distance_from_line <= spreadlimit))
 286                 &&
 287                 ((vlen(normalize(targetorg - sw_shotorg) - normalize(attack_endpos - sw_shotorg)) * RAD2DEG) <= 90)
 288         )
 289                 { return bound(0, (distance_from_line / spreadlimit), 1); }
 290         else
 291                 { return FALSE; }
 292 }
 293
 294 float W_Shockwave_Attack_IsVisible(
 295         entity head,
 296         vector nearest_on_line,
 297         vector sw_shotorg,
 298         vector attack_endpos)
 299 {
 300         vector nearest_to_attacker = head.WarpZone_findradius_nearest;
 301         vector center = (head.origin + (head.mins + head.maxs) * 0.5);
 302         vector corner;
 303         float i;
 304
 305         // STEP ONE: Check if the nearest point is clear
 306         if(W_Shockwave_Attack_CheckSpread(nearest_to_attacker, nearest_on_line, sw_shotorg, attack_endpos))
 307         {
 308                 WarpZone_TraceLine(sw_shotorg, nearest_to_attacker, MOVE_NOMONSTERS, self);
 309                 if(trace_fraction == 1) { return TRUE; } // yes, the nearest point is clear and we can allow the damage
 310         }
 311
 312         // STEP TWO: Check if shotorg to center point is clear
 313         if(W_Shockwave_Attack_CheckSpread(center, nearest_on_line, sw_shotorg, attack_endpos))
 314         {
 315                 WarpZone_TraceLine(sw_shotorg, center, MOVE_NOMONSTERS, self);
 316                 if(trace_fraction == 1) { return TRUE; } // yes, the center point is clear and we can allow the damage
 317         }
 318
 319         // STEP THREE: Check each corner to see if they are clear
 320         for(i=1; i<=8; ++i)
 321         {
 322                 corner = get_corner_position(head, i);
 323                 if(W_Shockwave_Attack_CheckSpread(corner, nearest_on_line, sw_shotorg, attack_endpos))
 324                 {
 325                         WarpZone_TraceLine(sw_shotorg, corner, MOVE_NOMONSTERS, self);
 326                         if(trace_fraction == 1) { return TRUE; } // yes, this corner is clear and we can allow the damage
 327                 }
 328         }
 329
 330         return FALSE;
 331 }
 332
 333 float W_Shockwave_Attack_CheckHit(
 334         float queue,
 335         entity head,
 336         vector final_force,
 337         float final_damage)
 338 {
 339         if(!head) { return FALSE; }
 340         float i;
 341
 342         ++queue;
 343
 344         for(i = 1; i <= queue; ++i)
 345         {
 346                 if(shockwave_hit[i] == head)
 347                 {
 348                         if(vlen(final_force) > vlen(shockwave_hit_force[i])) { shockwave_hit_force[i] = final_force; }
 349                         if(final_damage > shockwave_hit_damage[i]) { shockwave_hit_damage[i] = final_damage; }
 350                         return FALSE;
 351                 }
 352         }
 353
 354         shockwave_hit[queue] = head;
 355         shockwave_hit_force[queue] = final_force;
 356         shockwave_hit_damage[queue] = final_damage;
 357         return TRUE;
 358 }
 359
 360 void W_Shockwave_Attack()
 361 {
 362         // declarations
 363         float multiplier, multiplier_from_accuracy, multiplier_from_distance;
 364         float final_damage;
 365         vector final_force, center, vel;
 366         entity head;
 367
 368         float i, queue = 0;
 369
 370         // set up the shot direction
 371         W_SetupShot(self, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, WEP_CVAR(shockwave, blast_damage));
 372         vector attack_endpos = (w_shotorg + (w_shotdir * WEP_CVAR(shockwave, blast_distance)));
 373         WarpZone_TraceLine(w_shotorg, attack_endpos, MOVE_NOMONSTERS, self);
 374         vector attack_hitpos = trace_endpos;
 375         float distance_to_end = vlen(w_shotorg - attack_endpos);
 376         float distance_to_hit = vlen(w_shotorg - attack_hitpos);
 377         //entity transform = WarpZone_trace_transform;
 378
 379         // do the firing effect now
 380         //SendCSQCShockwaveParticle(attack_endpos); // WEAPONTODO
 381         Damage_DamageInfo(
 382                 attack_hitpos,
 383                 WEP_CVAR(shockwave, blast_splash_damage),
 384                 WEP_CVAR(shockwave, blast_splash_edgedamage),
 385                 WEP_CVAR(shockwave, blast_splash_radius),
 386                 w_shotdir * WEP_CVAR(shockwave, blast_splash_force),
 387                 WEP_SHOCKWAVE,
 388                 0,
 389                 self
 390         );
 391
 392         // splash damage/jumping trace
 393         head = WarpZone_FindRadius(
 394                 attack_hitpos,
 395                 max(
 396                         WEP_CVAR(shockwave, blast_splash_radius),
 397                         WEP_CVAR(shockwave, blast_jump_radius)
 398                 ),
 399                 FALSE
 400         );
 401
 402         while(head)
 403         {
 404                 if(head.takedamage)
 405                 {
 406                         float distance_to_head = vlen(attack_hitpos - head.WarpZone_findradius_nearest);
 407
 408                         if((head == self) && (distance_to_head <= WEP_CVAR(shockwave, blast_jump_radius)))
 409                         {
 410                                 // calculate importance of distance and accuracy for this attack
 411                                 multiplier_from_accuracy = (1 - (distance_to_head ? min(1, (distance_to_head / WEP_CVAR(shockwave, blast_jump_radius))) : 0));
 412                                 multiplier_from_distance = (1 - (distance_to_hit ? min(1, (distance_to_hit / distance_to_end)) : 0));
 413                                 multiplier =
 414                                         max(
 415                                                 WEP_CVAR(shockwave, blast_jump_multiplier_min),
 416                                                 (
 417                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_jump_multiplier_accuracy))
 418                                                         +
 419                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_jump_multiplier_distance))
 420                                                 )
 421                                         );
 422
 423                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 424                                 final_damage =
 425                                         (
 426                                                 (WEP_CVAR(shockwave, blast_jump_damage) * multiplier)
 427                                                 +
 428                                                 (WEP_CVAR(shockwave, blast_jump_edgedamage) * (1 - multiplier))
 429                                         );
 430
 431                                 // figure out the direction of force
 432                                 vel = normalize(combine_to_vector(head.velocity_x, head.velocity_y, 0));
 433                                 vel *=
 434                                         (
 435                                                 bound(0, (vlen(vel) / autocvar_sv_maxspeed), 1)
 436                                                 *
 437                                                 WEP_CVAR(shockwave, blast_jump_force_velocitybias)
 438                                         );
 439
 440                                 final_force = normalize((CENTER_OR_VIEWOFS(head) - attack_hitpos) + vel);
 441
 442                                 // now multiply the direction by force units
 443                                 final_force *= (WEP_CVAR(shockwave, blast_jump_force) * multiplier);
 444                                 final_force_z *= WEP_CVAR(shockwave, blast_jump_force_zscale);
 445
 446                                 // trigger damage with this calculated info
 447                                 Damage(
 448                                         head,
 449                                         self,
 450                                         self,
 451                                         final_damage,
 452                                         WEP_SHOCKWAVE,
 453                                         head.origin,
 454                                         final_force
 455                                 );
 456
 457                                 #ifdef DEBUG_SHOCKWAVE
 458                                 print(sprintf(
 459                                         "SELF HIT: multiplier = %f, damage = %f, force = %f... "
 460                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 461                                         multiplier,
 462                                         final_damage,
 463                                         vlen(final_force),
 464                                         multiplier_from_accuracy,
 465                                         multiplier_from_distance
 466                                 ));
 467                                 #endif
 468                         }
 469                         else if(distance_to_head <= WEP_CVAR(shockwave, blast_splash_radius))
 470                         {
 471                                 multiplier_from_accuracy = (1 - (distance_to_head ? min(1, (distance_to_head / WEP_CVAR(shockwave, blast_splash_radius))) : 0));
 472                                 multiplier_from_distance = (1 - (distance_to_hit ? min(1, (distance_to_hit / distance_to_end)) : 0));
 473                                 multiplier =
 474                                         max(
 475                                                 WEP_CVAR(shockwave, blast_splash_multiplier_min),
 476                                                 (
 477                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_splash_multiplier_accuracy))
 478                                                         +
 479                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_splash_multiplier_distance))
 480                                                 )
 481                                         );
 482
 483                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 484                                 final_damage =
 485                                         (
 486                                                 (WEP_CVAR(shockwave, blast_splash_damage) * multiplier)
 487                                                 +
 488                                                 (WEP_CVAR(shockwave, blast_splash_edgedamage) * (1 - multiplier))
 489                                         );
 490
 491                                 // figure out the direction of force
 492                                 final_force = (w_shotdir * WEP_CVAR(shockwave, blast_splash_force_forwardbias));
 493                                 final_force = normalize((CENTER_OR_VIEWOFS(head) - attack_hitpos) + final_force);
 494                                 //te_lightning2(world, attack_hitpos, (attack_hitpos + (final_force * 200)));
 495
 496                                 // now multiply the direction by force units
 497                                 final_force *= (WEP_CVAR(shockwave, blast_splash_force) * multiplier);
 498                                 final_force_z *= WEP_CVAR(shockwave, blast_force_zscale);
 499
 500                                 // queue damage with this calculated info
 501                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { ++queue; }
 502
 503                                 #ifdef DEBUG_SHOCKWAVE
 504                                 print(sprintf(
 505                                         "SPLASH HIT: multiplier = %f, damage = %f, force = %f... "
 506                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 507                                         multiplier,
 508                                         final_damage,
 509                                         vlen(final_force),
 510                                         multiplier_from_accuracy,
 511                                         multiplier_from_distance
 512                                 ));
 513                                 #endif
 514                         }
 515                 }
 516                 head = head.chain;
 517         }
 518
 519         // cone damage trace
 520         head = WarpZone_FindRadius(w_shotorg, WEP_CVAR(shockwave, blast_distance), FALSE);
 521         while(head)
 522         {
 523                 if((head != self) && head.takedamage)
 524                 {
 525                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 526                         center = CENTER_OR_VIEWOFS(head);
 527
 528                         // find the closest point on the enemy to the center of the attack
 529                         float ang; // angle between shotdir and h
 530                         float h; // hypotenuse, which is the distance between attacker to head
 531                         float a; // adjacent side, which is the distance between attacker and the point on w_shotdir that is closest to head.origin
 532
 533                         h = vlen(center - self.origin);
 534                         ang = acos(dotproduct(normalize(center - self.origin), w_shotdir));
 535                         a = h * cos(ang);
 536                         // WEAPONTODO: replace with simpler method
 537
 538                         vector nearest_on_line = (w_shotorg + a * w_shotdir);
 539                         vector nearest_to_attacker = WarpZoneLib_NearestPointOnBox(center + head.mins, center + head.maxs, nearest_on_line);
 540                         float distance_to_target = vlen(w_shotorg - nearest_to_attacker); // todo: use the findradius function for this
 541
 542                         if((distance_to_target <= WEP_CVAR(shockwave, blast_distance))
 543                                 && (W_Shockwave_Attack_IsVisible(head, nearest_on_line, w_shotorg, attack_endpos)))
 544                         {
 545                                 multiplier_from_accuracy = (1 - W_Shockwave_Attack_CheckSpread(nearest_to_attacker, nearest_on_line, w_shotorg, attack_endpos));
 546                                 multiplier_from_distance = (1 - (distance_to_hit ? min(1, (distance_to_target / distance_to_end)) : 0));
 547                                 multiplier =
 548                                         max(
 549                                                 WEP_CVAR(shockwave, blast_multiplier_min),
 550                                                 (
 551                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_multiplier_accuracy))
 552                                                         +
 553                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_multiplier_distance))
 554                                                 )
 555                                         );
 556
 557                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 558                                 final_damage =
 559                                         (
 560                                                 (WEP_CVAR(shockwave, blast_damage) * multiplier)
 561                                                 +
 562                                                 (WEP_CVAR(shockwave, blast_edgedamage) * (1 - multiplier))
 563                                         );
 564
 565                                 // figure out the direction of force
 566                                 final_force = (w_shotdir * WEP_CVAR(shockwave, blast_force_forwardbias));
 567                                 final_force = normalize((center - nearest_on_line) + final_force);
 568                                 //te_lightning2(world, nearest_on_line, (attack_hitpos + (final_force * 200)));
 569
 570                                 // now multiply the direction by force units
 571                                 final_force *= (WEP_CVAR(shockwave, blast_force) * multiplier);
 572                                 final_force_z *= WEP_CVAR(shockwave, blast_force_zscale);
 573
 574                                 // queue damage with this calculated info
 575                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { ++queue; }
 576
 577                                 #ifdef DEBUG_SHOCKWAVE
 578                                 print(sprintf(
 579                                         "BLAST HIT: multiplier = %f, damage = %f, force = %f... "
 580                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 581                                         multiplier,
 582                                         final_damage,
 583                                         vlen(final_force),
 584                                         multiplier_from_accuracy,
 585                                         multiplier_from_distance
 586                                 ));
 587                                 #endif
 588                         }
 589                 }
 590                 head = head.chain;
 591         }
 592
 593         for(i = 1; i <= queue; ++i)
 594         {
 595                 head = shockwave_hit[i];
 596                 final_force = shockwave_hit_force[i];
 597                 final_damage = shockwave_hit_damage[i];
 598
 599                 Damage(head, self, self, final_damage, WEP_SHOCKWAVE, head.origin, final_force);
 600                 #ifdef DEBUG_SHOCKWAVE
 601                 print(sprintf(
 602                         "SHOCKWAVE by %s: damage = %f, force = %f.\n",
 603                         self.netname,
 604                         final_damage,
 605                         vlen(final_force)
 606                 ));
 607                 #endif
 608
 609                 shockwave_hit[i] = world;
 610                 shockwave_hit_force[i] = '0 0 0';
 611                 shockwave_hit_damage[i] = 0;
 612         }
 613 }
 614
 615 float W_Shockwave(float req)
 616 {
 617         float ammo_amount;
 618         switch(req)
 619         {
 620                 case WR_AIM:
 621                 {
 622                         if(vlen(self.origin - self.enemy.origin) <= WEP_CVAR(shockwave, melee_range))
 623                                 { self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE); }
 624                         else
 625                                 { self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE); }
 626
 627                         return TRUE;
 628                 }
 629                 case WR_THINK:
 630                 {
 631                         if(WEP_CVAR(shockwave, reload_ammo) && self.clip_load < WEP_CVAR(shockwave, pellets_ammo)) // forced reload
 632                         {
 633                                 // don't force reload an empty shockwave if its melee attack is active
 634                                 if(!(WEP_CVAR(shockwave, secondary) && self.ammo_shells < WEP_CVAR(shockwave, pellets_ammo)))
 635                                         WEP_ACTION(self.weapon, WR_RELOAD);
 636                         }
 637                         else
 638                         {
 639                                 if(self.BUTTON_ATCK)
 640                                 {
 641                                         switch(WEP_CVAR(shockwave, primary))
 642                                         {
 643                                                 case 1:
 644                                                 {
 645                                                         if(time >= self.shockwave_pelletstime) // handle refire separately so the secondary can be fired straight after a primary
 646                                                         {
 647                                                                 if(weapon_prepareattack(0, WEP_CVAR(shockwave, pellets_animtime)))
 648                                                                 {
 649                                                                         W_Shockwave_Attack();
 650                                                                         self.shockwave_pelletstime = time + WEP_CVAR(shockwave, pellets_refire) * W_WeaponRateFactor();
 651                                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(shockwave, pellets_animtime), w_ready);
 652                                                                 }
 653                                                         }
 654                                                         break;
 655                                                 }
 656                                                 case 2:
 657                                                 {
 658                                                         if(time >= self.shockwave_pelletstime) // handle refire separately so the secondary can be fired straight after a primary
 659                                                         {
 660                                                                 if(weapon_prepareattack(0, WEP_CVAR(shockwave, pellets_animtime)))
 661                                                                 {
 662                                                                         W_Shockwave_Pellets();
 663                                                                         self.shockwave_pelletstime = time + WEP_CVAR(shockwave, pellets_refire) * W_WeaponRateFactor();
 664                                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(shockwave, pellets_animtime), w_ready);
 665                                                                 }
 666                                                         }
 667                                                         break;
 668                                                 }
 669                                         }
 670                                 }
 671
 672                                 if(self.clip_load >= 0) // we are not currently reloading
 673                                 if(!self.crouch) // no crouchmelee please
 674                                 if(self.BUTTON_ATCK2 && WEP_CVAR(shockwave, secondary))
 675                                 if(weapon_prepareattack(1, WEP_CVAR(shockwave, melee_refire)))
 676                                 {
 677                                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 678                                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shockwave_Melee);
 679                                 }
 680                         }
 681
 682                         return TRUE;
 683                 }
 684                 case WR_INIT:
 685                 {
 686                         precache_model("models/uziflash.md3");
 687                         precache_model("models/weapons/g_shockwave.md3");
 688                         precache_model("models/weapons/v_shockwave.md3");
 689                         precache_model("models/weapons/h_shockwave.iqm");
 690                         precache_sound("misc/itempickup.wav");
 691                         precache_sound("weapons/shockwave_fire.wav");
 692                         precache_sound("weapons/shockwave_melee.wav");
 693                         SHOCKWAVE_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 694                         return TRUE;
 695                 }
 696                 case WR_SETUP:
 697                 {
 698                         self.current_ammo = ammo_shells;
 699                         return TRUE;
 700                 }
 701                 case WR_CHECKAMMO1:
 702                 {
 703                         ammo_amount = self.ammo_shells >= WEP_CVAR(shockwave, pellets_ammo);
 704                         ammo_amount += self.(weapon_load[WEP_SHOCKWAVE]) >= WEP_CVAR(shockwave, pellets_ammo);
 705                         return ammo_amount;
 706                 }
 707                 case WR_CHECKAMMO2:
 708                 {
 709                         // melee attack is always available
 710                         return TRUE;
 711                 }
 712                 case WR_CONFIG:
 713                 {
 714                         SHOCKWAVE_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 715                         return TRUE;
 716                 }
 717                 case WR_RELOAD:
 718                 {
 719                         W_Reload(WEP_CVAR(shockwave, pellets_ammo), "weapons/reload.wav");
 720                         return TRUE;
 721                 }
 722                 case WR_SUICIDEMESSAGE:
 723                 {
 724                         return WEAPON_THINKING_WITH_PORTALS;
 725                 }
 726                 case WR_KILLMESSAGE:
 727                 {
 728                         if(w_deathtype & HITTYPE_SECONDARY)
 729                                 return WEAPON_SHOCKWAVE_MURDER_SLAP;
 730                         else
 731                                 return WEAPON_SHOCKWAVE_MURDER;
 732                 }
 733         }
 734         return TRUE;
 735 }
 736 #endif
 737 #ifdef CSQC
 738 float W_Shockwave(float req)
 739 {
 740         switch(req)
 741         {
 742                 case WR_IMPACTEFFECT:
 743                 {
 744                         vector org2;
 745                         org2 = w_org + w_backoff * 2;
 746                         pointparticles(particleeffectnum("shockwave_impact"), org2, w_backoff * 1000, 1);
 747                         return TRUE;
 748                 }
 749                 case WR_INIT:
 750                 {
 751                         //precache_sound("weapons/ric1.wav");
 752                         //precache_sound("weapons/ric2.wav");
 753                         //precache_sound("weapons/ric3.wav");
 754                         return FALSE;
 755                 }
 756         }
 757         return TRUE;
 758 }
 759 #endif
 760 #endif